autoconf/configure.ac

   1 dnl === configure.ac --------------------------------------------------------===
   2 dnl                     The LLVM Compiler Infrastructure
   3 dnl
   4 dnl This file was developed by the LLVM research group and is distributed under
   5 dnl the University of Illinois Open Source License. See LICENSE.TXT for details.
   6 dnl
   7 dnl===-----------------------------------------------------------------------===
   8 dnl This is the LLVM configuration script. It is processed by the autoconf
   9 dnl program to produce a script named configure. This script contains the
  10 dnl configuration checks that LLVM needs in order to support multiple platforms.
  11 dnl This file is composed of 10 sections per the recommended organization of
  12 dnl autoconf input defined in the autoconf documentation. As this file evolves,
  13 dnl please keep the various types of checks within their sections. The sections
  14 dnl are as follows:
  15 dnl
  16 dnl SECTION 1: Initialization & Setup
  17 dnl SECTION 2: Architecture, target, and host checks
  18 dnl SECTION 3: Command line arguments for the configure script.
  19 dnl SECTION 4: Check for programs we need and that they are the right version
  20 dnl SECTION 5: Check for libraries
  21 dnl SECTION 6: Check for header files
  22 dnl SECTION 7: Check for types and structures
  23 dnl SECTION 8: Check for specific functions needed
  24 dnl SECTION 9: Additional checks, variables, etc.
  25 dnl SECTION 10: Specify the output files and generate it
  26 dnl
  27 dnl===-----------------------------------------------------------------------===
  28 dnl===
  29 dnl=== SECTION 1: Initialization & Setup
  30 dnl===
  31 dnl===-----------------------------------------------------------------------===
  32 dnl Initialize autoconf and define the package name, version number and
  33 dnl email address for reporting bugs.
  34 AC_INIT([[llvm]],[[1.9cvs]],[llvmbugs@cs.uiuc.edu])
  35
  36 dnl Provide a copyright substitution and ensure the copyright notice is included
  37 dnl in the output of --version option of the generated configure script.
  38 AC_SUBST(LLVM_COPYRIGHT,["Copyright (c) 2003-2005 University of Illinois at Urbana-Champaign."])
  39 AC_COPYRIGHT([Copyright (c) 2003-2005 University of Illinois at Urbana-Champaign.])
  40
  41 dnl Indicate that we require autoconf 2.59 or later. Ths is needed because we
  42 dnl use some autoconf macros only available in 2.59.
  43 AC_PREREQ(2.59)
  44
  45 dnl Verify that the source directory is valid. This makes sure that we are
  46 dnl configuring LLVM and not some other package (it validates --srcdir argument)
  47 AC_CONFIG_SRCDIR([lib/VMCore/Module.cpp])
  48
  49 dnl Place all of the extra autoconf files into the config subdirectory. Tell
  50 dnl various tools where the m4 autoconf macros are.
  51 AC_CONFIG_AUX_DIR([autoconf])
  52
  53 dnl Quit if the source directory has already been configured.
  54 dnl NOTE: This relies upon undocumented autoconf behavior.
  55 if test ${srcdir} != "." ; then
  56   if test -f ${srcdir}/include/llvm/Config/config.h ; then
  57     AC_MSG_ERROR([Already configured in ${srcdir}])
  58   fi
  59 fi
  60
  61 dnl Configure all of the projects present in our source tree. While we could
  62 dnl just AC_CONFIG_SUBDIRS on the set of directories in projects that have a
  63 dnl configure script, that usage of the AC_CONFIG_SUBDIRS macro is deprecated.
  64 dnl Instead we match on the known projects.
  65 for i in `ls ${srcdir}/projects`
  66 do
  67   if test -d ${srcdir}/projects/${i} ; then
  68     case ${i} in
  69       "CVS") ;;
  70       "sample")       AC_CONFIG_SUBDIRS([projects/sample])    ;;
  71       "Stacker")      AC_CONFIG_SUBDIRS([projects/Stacker])   ;;
  72       "privbracket")  AC_CONFIG_SUBDIRS([projects/privbracket]) ;;
  73       "llvm-test")    AC_CONFIG_SUBDIRS([projects/llvm-test]) ;;
  74       "llvm-reopt")   AC_CONFIG_SUBDIRS([projects/llvm-reopt]);;
  75       "llvm-gcc")     AC_CONFIG_SUBDIRS([projects/llvm-gcc])  ;;
  76       "llvm-java")    AC_CONFIG_SUBDIRS([projects/llvm-java]) ;;
  77       "llvm-tv")      AC_CONFIG_SUBDIRS([projects/llvm-tv])   ;;
  78       "llvm-poolalloc") AC_CONFIG_SUBDIRS([projects/llvm-poolalloc]) ;;
  79       "llvm-kernel")  AC_CONFIG_SUBDIRS([projects/llvm-kernel]) ;;
  80       *)
  81         AC_MSG_WARN([Unknown project (${i}) won't be configured automatically])
  82         ;;
  83     esac
  84   fi
  85 done
  86
  87 dnl===-----------------------------------------------------------------------===
  88 dnl===
  89 dnl=== SECTION 2: Architecture, target, and host checks
  90 dnl===
  91 dnl===-----------------------------------------------------------------------===
  92
  93 dnl Check the target for which we're compiling and the host that will do the
  94 dnl compilations. This will tell us which LLVM compiler will be used for
  95 dnl compiling SSA into object code. This needs to be done early because
  96 dnl following tests depend on it.
  97 AC_CANONICAL_TARGET
  98
  99 dnl Determine the platform type and cache its value. This helps us configure
 100 dnl the System library to the correct build platform.
 101 AC_CACHE_CHECK([type of operating system we're going to host on],
 102                [llvm_cv_os_type],
 103 [case $host in
 104   *-*-aix*)
 105     llvm_cv_os_type="AIX"
 106     llvm_cv_platform_type="Unix" ;;
 107   *-*-cygwin*)
 108     llvm_cv_os_type="Cygwin"
 109     llvm_cv_platform_type="Unix" ;;
 110   *-*-darwin*)
 111     llvm_cv_os_type="Darwin"
 112     llvm_cv_platform_type="Unix" ;;
 113   *-*-freebsd*)
 114     llvm_cv_os_type="FreeBSD"
 115     llvm_cv_platform_type="Unix" ;;
 116   *-*-openbsd*)
 117     llvm_cv_os_type="OpenBSD"
 118     llvm_cv_platform_type="Unix" ;;
 119   *-*-hpux*)
 120     llvm_cv_os_type="HP-UX"
 121     llvm_cv_platform_type="Unix" ;;
 122   *-*-interix*)
 123     llvm_cv_os_type="Interix"
 124     llvm_cv_platform_type="Unix" ;;
 125   *-*-linux*)
 126     llvm_cv_os_type="Linux"
 127     llvm_cv_platform_type="Unix" ;;
 128   *-*-solaris*)
 129     llvm_cv_os_type="SunOS"
 130     llvm_cv_platform_type="Unix" ;;
 131   *-*-win32*)
 132     llvm_cv_os_type="Win32"
 133     llvm_cv_platform_type="Win32" ;;
 134   *-*-mingw*)
 135     llvm_cv_os_type="MingW"
 136     llvm_cv_platform_type="Win32" ;;
 137   *)
 138     llvm_cv_os_type="Unknown"
 139     llvm_cv_platform_type="Unknown" ;;
 140 esac])
 141
 142 dnl Make sure we aren't attempting to configure for an unknown system
 143 if test "$llvm_cv_os_type" = "Unknown" ; then
 144   AC_MSG_ERROR([Operating system is unknown, configure can't continue])
 145 fi
 146
 147 dnl Set the "OS" Makefile variable based on the platform type so the
 148 dnl makefile can configure itself to specific build hosts
 149 AC_SUBST(OS,$llvm_cv_os_type)
 150
 151 dnl Set the "LLVM_ON_*" variables based on llvm_cvs_platform_type
 152 dnl This is used by lib/System to determine the basic kind of implementation
 153 dnl to use.
 154 case $llvm_cv_platform_type in
 155   Unix)
 156     AC_DEFINE([LLVM_ON_UNIX],[1],[Define if this is Unixish platform])
 157     AC_SUBST(LLVM_ON_UNIX,[1])
 158     AC_SUBST(LLVM_ON_WIN32,[0])
 159     ;;
 160   Win32)
 161     AC_DEFINE([LLVM_ON_WIN32],[1],[Define if this is Win32ish platform])
 162     AC_SUBST(LLVM_ON_UNIX,[0])
 163     AC_SUBST(LLVM_ON_WIN32,[1])
 164     ;;
 165 esac
 166
 167 dnl Determine what our target architecture is and configure accordingly.
 168 dnl This will allow Makefiles to make a distinction between the hardware and
 169 dnl the OS.
 170 AC_CACHE_CHECK([target architecture],[llvm_cv_target_arch],
 171 [case $target in
 172   i?86-*)                 llvm_cv_target_arch="x86" ;;
 173   amd64-* | x86_64-*)     llvm_cv_target_arch="x86_64" ;;
 174   sparc*-*)               llvm_cv_target_arch="Sparc" ;;
 175   powerpc*-*)             llvm_cv_target_arch="PowerPC" ;;
 176   alpha*-*)               llvm_cv_target_arch="Alpha" ;;
 177   ia64-*)                 llvm_cv_target_arch="IA64" ;;
 178   *)                      llvm_cv_target_arch="Unknown" ;;
 179 esac])
 180
 181 if test "$llvm_cv_target_arch" = "Unknown" ; then
 182   AC_MSG_WARN([Configuring LLVM for an unknown target archicture])
 183 fi
 184
 185 dnl Define a substitution, ARCH, for the target architecture
 186 AC_SUBST(ARCH,$llvm_cv_target_arch)
 187
 188 dnl Check for the endianness of the target
 189 AC_C_BIGENDIAN(AC_SUBST([ENDIAN],[big]),AC_SUBST([ENDIAN],[little]))
 190
 191 dnl Check for build platform executable suffix if we're crosscompiling
 192 if test "$cross_compiling" = yes; then
 193   AC_SUBST(LLVM_CROSS_COMPILING, [1])
 194   AC_BUILD_EXEEXT
 195 else
 196   AC_SUBST(LLVM_CROSS_COMPILING, [0])
 197 fi
 198
 199 dnl Check to see if there's a "CVS" directory indicating that this build is
 200 dnl being done from a CVS checkout. This sets up several defaults for the
 201 dnl command line switches. When we build with a CVS directory, we get a
 202 dnl debug with assertions turned on. Without, we assume a source release and we
 203 dnl get an optimized build without assertions. See --enable-optimized and
 204 dnl --enable-assertions below
 205 if test -d "CVS" -o -d "${srcdir}/CVS"; then
 206   cvsbuild="yes"
 207   optimize="no"
 208   AC_SUBST(CVSBUILD,[[CVSBUILD=1]])
 209 else
 210   cvsbuild="no"
 211   optimize="yes"
 212 fi
 213
 214 dnl===-----------------------------------------------------------------------===
 215 dnl===
 216 dnl=== SECTION 3: Command line arguments for the configure script.
 217 dnl===
 218 dnl===-----------------------------------------------------------------------===
 219
 220 dnl --enable-optimized : check whether they want to do an optimized build:
 221 AC_ARG_ENABLE(optimized, AS_HELP_STRING(
 222  [--enable-optimized,Compile with optimizations enabled (default is NO)]),,enableval=$optimize)
 223 if test ${enableval} = "no" ; then
 224   AC_SUBST(ENABLE_OPTIMIZED,[[]])
 225 else
 226   AC_SUBST(ENABLE_OPTIMIZED,[[ENABLE_OPTIMIZED=1]])
 227 fi
 228
 229 dnl --enable-assertions : check whether they want to turn on assertions or not:
 230 AC_ARG_ENABLE(assertions,AS_HELP_STRING(
 231   [--enable-assertions,Compile with assertion checks enabled (default is YES)]),, enableval="yes")
 232 if test ${enableval} = "yes" ; then
 233   AC_SUBST(DISABLE_ASSERTIONS,[[]])
 234 else
 235   AC_SUBST(DISABLE_ASSERTIONS,[[DISABLE_ASSERTIONS=1]])
 236 fi
 237
 238 dnl --enable-debug-runtime : should runtime libraries have debug symbols?
 239 AC_ARG_ENABLE(debug-runtime,
 240    AS_HELP_STRING([--enable-debug-runtime,Build runtime libs with debug symbols (default is NO)]),,enableval=no)
 241 if test ${enableval} = "no" ; then
 242   AC_SUBST(DEBUG_RUNTIME,[[]])
 243 else
 244   AC_SUBST(DEBUG_RUNTIME,[[DEBUG_RUNTIME=1]])
 245 fi
 246
 247 dnl --enable-jit: check whether they want to enable the jit
 248 AC_ARG_ENABLE(jit,
 249   AS_HELP_STRING(--enable-jit,
 250                  [Enable Just In Time Compiling (default is YES)]),,
 251   enableval=default)
 252 if test ${enableval} = "no"
 253 then
 254   AC_SUBST(JIT,[[]])
 255 else
 256   case "$llvm_cv_target_arch" in
 257     x86)     AC_SUBST(TARGET_HAS_JIT,1) ;;
 258     Sparc)   AC_SUBST(TARGET_HAS_JIT,1) ;;
 259     PowerPC) AC_SUBST(TARGET_HAS_JIT,1) ;;
 260     x86_64)  AC_SUBST(TARGET_HAS_JIT,0) ;;
 261     Alpha)   AC_SUBST(TARGET_HAS_JIT,1) ;;
 262     IA64)    AC_SUBST(TARGET_HAS_JIT,0) ;;
 263     *)       AC_SUBST(TARGET_HAS_JIT,0) ;;
 264   esac
 265 fi
 266
 267 dnl Allow enablement of doxygen generated documentation
 268 AC_ARG_ENABLE(doxygen,
 269               AS_HELP_STRING([--enable-doxygen],
 270                              [Build doxygen documentation (default is NO)]),,
 271                              enableval=default)
 272 case "$enableval" in
 273   yes) AC_SUBST(ENABLE_DOXYGEN,[1]) ;;
 274   no)  AC_SUBST(ENABLE_DOXYGEN,[0]) ;;
 275   default) AC_SUBST(ENABLE_DOXYGEN,[0]) ;;
 276   *) AC_MSG_ERROR([Invalid setting for --enable-doxygen. Use "yes" or "no"]) ;;
 277 esac
 278
 279 dnl Allow disablement of threads
 280 AC_ARG_ENABLE(threads,
 281               AS_HELP_STRING([--enable-threads],
 282                              [Use threads if available (default is YES)]),,
 283                              enableval=yes)
 284 case "$enableval" in
 285   yes) AC_SUBST(ENABLE_THREADS,[1]) ;;
 286   no)  AC_SUBST(ENABLE_THREADS,[0]) ;;
 287   *) AC_MSG_ERROR([Invalid setting for --enable-threads. Use "yes" or "no"]) ;;
 288 esac
 289 AC_DEFINE_UNQUOTED([ENABLE_THREADS],$ENABLE_THREADS,[Define if threads enabled])
 290
 291 dnl Allow specific targets to be specified for building (or not)
 292 TARGETS_TO_BUILD=""
 293 AC_ARG_ENABLE([targets],AS_HELP_STRING([--enable-targets],
 294     [Build specific host targets: all,host-only,{target-name} (default=all)]),,
 295     enableval=all)
 296 case "$enableval" in
 297   all) TARGETS_TO_BUILD="X86 Sparc PowerPC Alpha IA64 ARM" ;;
 298   host-only)
 299     case "$llvm_cv_target_arch" in
 300       x86)     TARGETS_TO_BUILD="X86" ;;
 301       x86_64)  TARGETS_TO_BUILD="X86" ;;
 302       Sparc)   TARGETS_TO_BUILD="Sparc" ;;
 303       PowerPC) TARGETS_TO_BUILD="PowerPC" ;;
 304       Alpha)   TARGETS_TO_BUILD="Alpha" ;;
 305       IA64)    TARGETS_TO_BUILD="IA64" ;;
 306       *)       AC_MSG_ERROR([Can not set target to build]) ;;
 307     esac
 308     ;;
 309   *)for a_target in `echo $enableval|sed -e 's/,/ /g' ` ; do
 310       case "$a_target" in
 311         x86)     TARGETS_TO_BUILD="X86 $TARGETS_TO_BUILD" ;;
 312         x86_64)  TARGETS_TO_BUILD="X86 $TARGETS_TO_BUILD" ;;
 313         sparc)   TARGETS_TO_BUILD="Sparc $TARGETS_TO_BUILD" ;;
 314         powerpc) TARGETS_TO_BUILD="PowerPC $TARGETS_TO_BUILD" ;;
 315         alpha)   TARGETS_TO_BUILD="Alpha $TARGETS_TO_BUILD" ;;
 316         ia64)    TARGETS_TO_BUILD="IA64 $TARGETS_TO_BUILD" ;;
 317         *) AC_MSG_ERROR([Unrecognized target $a_target]) ;;
 318       esac
 319   done
 320   ;;
 321 esac
 322 TARGETS_TO_BUILD="CBackend $TARGETS_TO_BUILD"
 323 AC_SUBST(TARGETS_TO_BUILD,$TARGETS_TO_BUILD)
 324
 325 dnl Allow a specific llvm-gcc/llvm-g++ pair to be used with this LLVM config.
 326 AC_ARG_WITH(llvmgccdir,
 327   AS_HELP_STRING([--with-llvmgccdir],
 328     [Specify location of llvm-gcc install dir (default searches PATH)]),,
 329     withval=default)
 330 case "$withval" in
 331   default) WITH_LLVMGCCDIR=default ;;
 332   /* | [[A-Za-z]]:[[\\/]]*)      WITH_LLVMGCCDIR=$withval ;;
 333   *) AC_MSG_ERROR([Invalid path for --with-llvmgccdir. Provide full path]) ;;
 334 esac
 335
 336 dnl Specify extra build options
 337 AC_ARG_WITH(extra-options,
 338   AS_HELP_STRING([--with-extra-options],
 339                  [Specify addtional options to compile LLVM with]),,
 340                  extraopts=default)
 341 case "$extraopts" in
 342   default) EXTRA_OPTIONS= ;;
 343   *) EXTRA_OPTIONS=$extraopts ;;
 344 esac
 345 AC_SUBST(EXTRA_OPTIONS,$EXTRA_OPTIONS)
 346
 347 dnl===-----------------------------------------------------------------------===
 348 dnl===
 349 dnl=== SECTION 4: Check for programs we need and that they are the right version
 350 dnl===
 351 dnl===-----------------------------------------------------------------------===
 352
 353 dnl Check for compilation tools
 354 AC_PROG_CPP
 355 AC_PROG_CC(gcc)
 356 AC_PROG_CXX(g++)
 357 AC_PROG_FLEX
 358 AC_PROG_BISON
 359
 360 AC_PROG_NM
 361 AC_SUBST(NM)
 362
 363 dnl Check for the tools that the makefiles require
 364 AC_CHECK_GNU_MAKE
 365 AC_PROG_LN_S
 366 AC_PATH_PROG(CMP, [cmp], [cmp])
 367 AC_PATH_PROG(CP, [cp], [cp])
 368 AC_PATH_PROG(DATE, [date], [date])
 369 AC_PATH_PROG(FIND, [find], [find])
 370 AC_PATH_PROG(GREP, [grep], [grep])
 371 AC_PATH_PROG(MKDIR,[mkdir],[mkdir])
 372 AC_PATH_PROG(MV,   [mv],   [mv])
 373 AC_PROG_RANLIB
 374 AC_PATH_PROG(RM,   [rm],   [rm])
 375 AC_PATH_PROG(SED,  [sed],  [sed])
 376 AC_PATH_PROG(TAR,  [tar],  [gtar])
 377
 378 dnl Looking for misc. graph plotting software
 379 AC_PATH_PROG(GRAPHVIZ, [Graphviz], [echo Graphviz])
 380 if test "$GRAPHVIZ" != "echo Graphviz" ; then
 381   AC_DEFINE([HAVE_GRAPHVIZ],[1],[Define if the Graphviz program is available])
 382   dnl If we're targeting for mingw we should emit windows paths, not msys
 383   if test "$llvm_cv_os_type" == "MingW" ; then
 384     GRAPHVIZ=`echo $GRAPHVIZ | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
 385   fi
 386   AC_DEFINE_UNQUOTED([LLVM_PATH_GRAPHVIZ],"$GRAPHVIZ${EXEEXT}",
 387    [Define to path to Graphviz program if found or 'echo Graphviz' otherwise])
 388 fi
 389 AC_PATH_PROG(DOT, [dot], [echo dot])
 390 if test "$DOT" != "echo dot" ; then
 391   AC_DEFINE([HAVE_DOT],[1],[Define if the dot program is available])
 392   dnl If we're targeting for mingw we should emit windows paths, not msys
 393   if test "$llvm_cv_os_type" == "MingW" ; then
 394     DOT=`echo $DOT | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
 395   fi
 396   AC_DEFINE_UNQUOTED([LLVM_PATH_DOT],"$DOT${EXEEXT}",
 397    [Define to path to dot program if found or 'echo dot' otherwise])
 398 fi
 399 AC_PATH_PROGS(GV, [gv gsview32], [echo gv])
 400 if test "$GV" != "echo gv" ; then
 401   AC_DEFINE([HAVE_GV],[1],[Define if the gv program is available])
 402   dnl If we're targeting for mingw we should emit windows paths, not msys
 403   if test "$llvm_cv_os_type" == "MingW" ; then
 404     GV=`echo $GV | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
 405   fi
 406   AC_DEFINE_UNQUOTED([LLVM_PATH_GV],"$GV${EXEEXT}",
 407    [Define to path to gv program if found or 'echo gv' otherwise])
 408 fi
 409 AC_PATH_PROG(DOTTY, [dotty], [echo dotty])
 410 if test "$DOTTY" != "echo dotty" ; then
 411   AC_DEFINE([HAVE_DOTTY],[1],[Define if the dotty program is available])
 412   dnl If we're targeting for mingw we should emit windows paths, not msys
 413   if test "$llvm_cv_os_type" == "MingW" ; then
 414     DOTTY=`echo $DOTTY | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
 415   fi
 416   AC_DEFINE_UNQUOTED([LLVM_PATH_DOTTY],"$DOTTY${EXEEXT}",
 417    [Define to path to dotty program if found or 'echo dotty' otherwise])
 418 fi
 419
 420 dnl Look for a sufficiently recent version of Perl.
 421 LLVM_PROG_PERL([5.006])
 422 AC_SUBST(PERL)
 423 if test x"$PERL" = xnone; then
 424    AC_SUBST(HAVE_PERL,0)
 425 else
 426    AC_SUBST(HAVE_PERL,1)
 427 fi
 428
 429 dnl Find the install program
 430 AC_PROG_INSTALL
 431
 432 dnl Checks for documentation and testing tools that we can do without. If these
 433 dnl are not found then they are set to "true" which always succeeds but does
 434 dnl nothing. This just lets the build output show that we could have done
 435 dnl something if the tool was available.
 436 AC_PATH_PROG(BZIP2,[bzip2],[echo "Skipped: bzip2 not found"])
 437 AC_PATH_PROG(DOXYGEN,[doxygen],[echo "Skipped: doxygen not found"])
 438 AC_PATH_PROG(ETAGS,[etags],[echo "Skipped: etags not found"])
 439 AC_PATH_PROG(GROFF,[groff],[echo "Skipped: groff not found"])
 440 AC_PATH_PROG(GZIP,[gzip],[echo "Skipped: gzip not found"])
 441 AC_PATH_PROG(POD2HTML,[pod2html],[echo "Skipped: pod2html not found"])
 442 AC_PATH_PROG(POD2MAN,[pod2man],[echo "Skipped: pod2man not found"])
 443 AC_PATH_PROG(RUNTEST,[runtest],[echo "Skipped: runtest not found"])
 444 DJ_AC_PATH_TCLSH
 445 AC_PATH_PROG(ZIP,[zip],[echo "Skipped: zip not found"])
 446
 447 dnl Determine if the linker supports the -R option.
 448 AC_LINK_USE_R
 449
 450 dnl Check for libtool and the library that has dlopen function (which must come
 451 dnl before the AC_PROG_LIBTOOL check in order to enable dlopening libraries with
 452 dnl libtool).
 453 AC_LIBTOOL_DLOPEN
 454 AC_LIB_LTDL
 455 AC_PROG_LIBTOOL
 456
 457 if test "$lt_cv_dlopen_self" = "yes" ; then
 458   AC_DEFINE([CAN_DLOPEN_SELF],[1],
 459               [Define if dlopen(0) will open the symbols of the program])
 460 fi
 461
 462 dnl Check if we know how to tell etags we are using C++:
 463 etags_version=`$ETAGS --version 2>&1`
 464 case "$etags_version" in
 465         *[Ee]xuberant*) ETAGSFLAGS="--language-force=c++" ;;
 466         *GNU\ Emacs*) ETAGSFLAGS="-l c++" ;;
 467         *) ETAGSFLAGS="" ;;
 468 esac
 469 AC_SUBST(ETAGSFLAGS,$ETAGSFLAGS)
 470
 471 if test "$WITH_LLVMGCCDIR" = "default" ; then
 472   LLVMGCC="llvm-gcc${EXEEXT}"
 473   LLVMGXX="llvm-g++${EXEEXT}"
 474   AC_PATH_PROG(LLVMGCC, $LLVMGCC, [])
 475   AC_PATH_PROG(LLVMGXX, $LLVMGXX, [])
 476 else
 477   LLVMGCC="$WITH_LLVMGCCDIR/bin/llvm-gcc${EXEEXT}"
 478   LLVMGXX="$WITH_LLVMGCCDIR/bin/llvm-g++${EXEEXT}"
 479   AC_SUBST(LLVMGCC,$LLVMGCC)
 480   AC_SUBST(LLVMGXX,$LLVMGXX)
 481 fi
 482
 483 AC_MSG_CHECKING([tool compatibility])
 484
 485 dnl Ensure that compilation tools are GCC or a GNU compatible compiler such as
 486 dnl ICC; we use GCC specific options in the makefiles so the compiler needs
 487 dnl to support those options.
 488 dnl "icc" emits gcc signatures
 489 dnl "icc -no-gcc" emits no gcc signature BUT is still compatible
 490 ICC=no
 491 IXX=no
 492 case $CC in
 493   icc*|icpc*)
 494     ICC=yes
 495     IXX=yes
 496     ;;
 497    *)
 498     ;;
 499 esac
 500
 501 if test "$GCC" != "yes" && test "$ICC" != "yes"
 502 then
 503   AC_MSG_ERROR([gcc|icc required but not found])
 504 fi
 505
 506 dnl Ensure that compilation tools are GCC; we use GCC specific extensions
 507 if test "$GXX" != "yes" && test "$IXX" != "yes"
 508 then
 509   AC_MSG_ERROR([g++|icc required but not found])
 510 fi
 511
 512 dnl Verify that GCC is version 3.0 or higher
 513 if test "$GCC" = "yes"
 514 then
 515   gccmajor=`$CC --version | head -n 1 | sed 's/[[^0-9]]*\([[0-9.]]\).*/\1/'`
 516   if test "$gccmajor" -lt "3"
 517   then
 518     AC_MSG_ERROR([gcc 3.x required, but you have a lower version])
 519   fi
 520 fi
 521
 522 dnl Check for GNU Make.  We use its extensions, so don't build without it
 523 if test -z "$llvm_cv_gnu_make_command"
 524 then
 525   AC_MSG_ERROR([GNU Make required but not found])
 526 fi
 527
 528 dnl Tool compatibility is okay if we make it here.
 529 AC_MSG_RESULT([ok])
 530
 531 dnl===-----------------------------------------------------------------------===
 532 dnl===
 533 dnl=== SECTION 5: Check for libraries
 534 dnl===
 535 dnl===-----------------------------------------------------------------------===
 536
 537 dnl libelf is for sparc only; we can ignore it if we don't have it
 538 AC_CHECK_LIB(elf, elf_begin)
 539 AC_CHECK_LIB(m,sin)
 540 if test "$llvm_cv_os_type" == "MingW" ; then
 541   AC_CHECK_LIB(imagehlp, main)
 542   AC_CHECK_LIB(psapi, main)
 543 fi
 544
 545 dnl lt_dlopen may be required for plugin support.
 546 AC_SEARCH_LIBS(lt_dlopen,ltdl,AC_DEFINE([HAVE_LT_DLOPEN],[1],
 547               [Define if lt_dlopen() is available on this platform]),
 548               AC_MSG_WARN([lt_dlopen() not found - plugin support might
 549                            not be available]))
 550
 551 dnl dlopen() is required for plugin support.
 552 AC_SEARCH_LIBS(dlopen,dl,AC_DEFINE([HAVE_DLOPEN],[1],
 553                [Define if dlopen() is available on this platform.]),
 554                AC_MSG_WARN([dlopen() not found - disabling plugin support]))
 555
 556 dnl mallinfo is optional; the code can compile (minus features) without it
 557 AC_SEARCH_LIBS(mallinfo,malloc,AC_DEFINE([HAVE_MALLINFO],[1],
 558                [Define if mallinfo() is available on this platform.]))
 559
 560 dnl pthread locking functions are optional - but llvm will not be thread-safe
 561 dnl without locks.
 562 if test "$ENABLE_THREADS" -eq 1 ; then
 563   AC_CHECK_LIB(pthread,pthread_mutex_init)
 564   AC_SEARCH_LIBS(pthread_mutex_lock,pthread,
 565                  AC_DEFINE([HAVE_PTHREAD_MUTEX_LOCK],[1],
 566                            [Have pthread_mutex_lock]))
 567 fi
 568
 569 dnl===-----------------------------------------------------------------------===
 570 dnl===
 571 dnl=== SECTION 6: Check for header files
 572 dnl===
 573 dnl===-----------------------------------------------------------------------===
 574
 575 dnl First, use autoconf provided macros for specific headers that we need
 576 dnl We don't check for ancient stuff or things that are guaranteed to be there
 577 dnl by the C++ standard. We always use the <cfoo> versions of <foo.h> C headers.
 578 dnl Generally we're looking for POSIX headers.
 579 AC_HEADER_DIRENT
 580 AC_HEADER_MMAP_ANONYMOUS
 581 AC_HEADER_STAT
 582 AC_HEADER_STDC
 583 AC_HEADER_SYS_WAIT
 584 AC_HEADER_TIME
 585
 586 AC_CHECK_HEADERS([dlfcn.h execinfo.h fcntl.h inttypes.h limits.h link.h])
 587 AC_CHECK_HEADERS([malloc.h setjmp.h signal.h stdint.h unistd.h utime.h])
 588 AC_CHECK_HEADERS([windows.h sys/mman.h sys/param.h sys/resource.h sys/time.h])
 589 AC_CHECK_HEADERS([sys/types.h malloc/malloc.h])
 590 if test "$ENABLE_THREADS" -eq 1 ; then
 591   AC_CHECK_HEADERS(pthread.h)
 592 fi
 593
 594 dnl===-----------------------------------------------------------------------===
 595 dnl===
 596 dnl=== SECTION 7: Check for types and structures
 597 dnl===
 598 dnl===-----------------------------------------------------------------------===
 599
 600 AC_TYPE_PID_T
 601 AC_TYPE_SIZE_T
 602 AC_TYPE_SIGNAL
 603 AC_STRUCT_TM
 604 AC_CHECK_TYPES([int64_t],,AC_MSG_ERROR([Type int64_t required but not found]))
 605 AC_CHECK_TYPES([uint64_t],,
 606          AC_CHECK_TYPES([u_int64_t],,
 607          AC_MSG_ERROR([Type uint64_t or u_int64_t required but not found])))
 608
 609 dnl===-----------------------------------------------------------------------===
 610 dnl===
 611 dnl=== SECTION 8: Check for specific functions needed
 612 dnl===
 613 dnl===-----------------------------------------------------------------------===
 614
 615 AC_CHECK_FUNCS([backtrace ceilf floorf roundf rintf nearbyintf getcwd ])
 616 AC_CHECK_FUNCS([getpagesize getrusage gettimeofday isatty mkdtemp mkstemp ])
 617 AC_CHECK_FUNCS([mktemp realpath sbrk setrlimit strdup strerror strerror_r ])
 618 AC_CHECK_FUNCS([strtoll strtoq sysconf malloc_zone_statistics ])
 619 AC_CHECK_FUNCS([_setjmp _longjmp setjmp longjmp sigsetjmp siglongjmp])
 620 AC_C_PRINTF_A
 621 AC_FUNC_ALLOCA
 622 AC_FUNC_RAND48
 623
 624 dnl Check for variations in the Standard C++ library and STL. These macros are
 625 dnl provided by LLVM in the autoconf/m4 directory.
 626 AC_CXX_HAVE_HASH_MAP
 627 AC_CXX_HAVE_HASH_SET
 628 AC_CXX_HAVE_STD_ITERATOR
 629 AC_CXX_HAVE_BI_ITERATOR
 630 AC_CXX_HAVE_FWD_ITERATOR
 631 AC_FUNC_ISNAN
 632 AC_FUNC_ISINF
 633
 634 dnl Check for mmap and mprotect support. We need both to do the JIT and for
 635 dnl bytecode loading, etc. We also need to know if /dev/zero is required to
 636 dnl be opened for allocating RWX memory.
 637 AC_FUNC_MMAP
 638 AC_FUNC_MMAP_FILE
 639 AC_NEED_DEV_ZERO_FOR_MMAP
 640 AC_CHECK_FUNC(mprotect,,
 641               AC_MSG_ERROR([Function mprotect() required but not found]))
 642
 643 if test "$ac_cv_func_mmap_fixed_mapped" = "no"
 644 then
 645   AC_MSG_WARN([mmap() of a fixed address required but not supported])
 646 fi
 647 if test "$ac_cv_func_mmap_file" = "no"
 648 then
 649   AC_MSG_WARN([mmap() of files required but not found])
 650 fi
 651
 652 dnl===-----------------------------------------------------------------------===
 653 dnl===
 654 dnl=== SECTION 9: Additional checks, variables, etc.
 655 dnl===
 656 dnl===-----------------------------------------------------------------------===
 657
 658 dnl See if the llvm-gcc executable can compile to LLVM assembly
 659 AC_CACHE_CHECK([whether llvm-gcc is sane],[llvm_cv_llvmgcc_sanity],
 660 [llvm_cv_llvmgcc_sanity="no"
 661 if test -x "$LLVMGCC" ; then
 662   cp /dev/null conftest.c
 663   "$LLVMGCC" -emit-llvm -S -o - conftest.c | grep implementation > /dev/null 2>&1
 664   if test $? -eq 0 ; then
 665     llvm_cv_llvmgcc_sanity="yes"
 666   fi
 667   rm conftest.c
 668 fi])
 669
 670 dnl Since we have a sane llvm-gcc, identify it and its sub-tools
 671 if test "$llvm_cv_llvmgcc_sanity" = "yes" ; then
 672   llvmcc1path=`"$LLVMGCC" --print-prog-name=cc1`
 673   AC_SUBST(LLVMCC1,$llvmcc1path)
 674   llvmcc1pluspath=`"$LLVMGCC" --print-prog-name=cc1plus`
 675   AC_SUBST(LLVMCC1PLUS,$llvmcc1pluspath)
 676   llvmgccdir=`echo "$llvmcc1path" | sed 's,/libexec/.*,,'`
 677   AC_SUBST(LLVMGCCDIR,$llvmgccdir)
 678   llvmgccversion=[`"$LLVMGCC" -dumpversion 2>&1 | sed 's/^\([0-9.]*\).*/\1/'`]
 679   llvmgccmajvers=[`echo $llvmgccversion | sed 's/^\([0-9]\).*/\1/'`]
 680   AC_SUBST(LLVMGCC_VERSION,$llvmgccversion)
 681   AC_SUBST(LLVMGCC_MAJVERS,$llvmgccmajvers)
 682 fi
 683
 684 dnl Propagate the shared library extension that the libltdl checks did to
 685 dnl the Makefiles so we can use it there too
 686 AC_SUBST(SHLIBEXT,$libltdl_cv_shlibext)
 687
 688 # Translate the various configuration directories and other basic
 689 # information into substitutions that will end up in Makefile.config.in
 690 # that these configured values can be used by the makefiles
 691 if test "${prefix}" == "NONE" ; then
 692   prefix="/usr/local"
 693 fi
 694 eval LLVM_PREFIX="${prefix}";
 695 eval LLVM_BINDIR="${prefix}/bin";
 696 eval LLVM_LIBDIR="${prefix}/lib";
 697 eval LLVM_DATADIR="${prefix}/share/llvm";
 698 eval LLVM_DOCSDIR="${prefix}/docs/llvm";
 699 eval LLVM_ETCDIR="${prefix}/etc/llvm";
 700 eval LLVM_INCLUDEDIR="${prefix}/include";
 701 eval LLVM_INFODIR="${prefix}/info";
 702 eval LLVM_MANDIR="${prefix}/man";
 703 LLVM_CONFIGTIME=`date`
 704 AC_SUBST(LLVM_PREFIX)
 705 AC_SUBST(LLVM_BINDIR)
 706 AC_SUBST(LLVM_LIBDIR)
 707 AC_SUBST(LLVM_DATADIR)
 708 AC_SUBST(LLVM_DOCSDIR)
 709 AC_SUBST(LLVM_ETCDIR)
 710 AC_SUBST(LLVM_INCLUDEDIR)
 711 AC_SUBST(LLVM_INFODIR)
 712 AC_SUBST(LLVM_MANDIR)
 713 AC_SUBST(LLVM_CONFIGTIME)
 714
 715 # Place the various directores into the config.h file as #defines so that we
 716 # can know about the installation paths within LLVM.
 717 AC_DEFINE_UNQUOTED(LLVM_PREFIX,"$LLVM_PREFIX",
 718                    [Installation prefix directory])
 719 AC_DEFINE_UNQUOTED(LLVM_BINDIR, "$LLVM_BINDIR",
 720                    [Installation directory for binary executables])
 721 AC_DEFINE_UNQUOTED(LLVM_LIBDIR, "$LLVM_LIBDIR",
 722                    [Installation directory for libraries])
 723 AC_DEFINE_UNQUOTED(LLVM_DATADIR, "$LLVM_DATADIR",
 724                    [Installation directory for data files])
 725 AC_DEFINE_UNQUOTED(LLVM_DATADIR, "$LLVM_DOCSDIR",
 726                    [Installation directory for documentation])
 727 AC_DEFINE_UNQUOTED(LLVM_ETCDIR, "$LLVM_ETCDIR",
 728                    [Installation directory for config files])
 729 AC_DEFINE_UNQUOTED(LLVM_INCLUDEDIR, "$LLVM_INCLUDEDIR",
 730                    [Installation directory for include files])
 731 AC_DEFINE_UNQUOTED(LLVM_INFODIR, "$LLVM_INFODIR",
 732                    [Installation directory for .info files])
 733 AC_DEFINE_UNQUOTED(LLVM_MANDIR, "$LLVM_MANDIR",
 734                    [Installation directory for man pages])
 735 AC_DEFINE_UNQUOTED(LLVM_CONFIGTIME, "$LLVM_CONFIGTIME",
 736                    [Time at which LLVM was configured])
 737
 738 dnl===-----------------------------------------------------------------------===
 739 dnl===
 740 dnl=== SECTION 10: Specify the output files and generate it
 741 dnl===
 742 dnl===-----------------------------------------------------------------------===
 743
 744 dnl Configure header files
 745 dnl WARNING: dnl If you add or remove any of the following config headers, then
 746 dnl you MUST also update Makefile.rules so that the variable FilesToConfig
 747 dnl contains the same list of files as AC_CONFIG_HEADERS below. This ensures the
 748 dnl files can be updated automatically when their *.in sources change.
 749 AC_CONFIG_HEADERS([include/llvm/Config/config.h])
 750 AC_CONFIG_HEADERS([include/llvm/Support/DataTypes.h])
 751 AC_CONFIG_HEADERS([include/llvm/ADT/hash_map])
 752 AC_CONFIG_HEADERS([include/llvm/ADT/hash_set])
 753 AC_CONFIG_HEADERS([include/llvm/ADT/iterator])
 754
 755 dnl Configure the makefile's configuration data
 756 AC_CONFIG_FILES([Makefile.config])
 757
 758 dnl Configure doxygen's configuration file
 759 AC_CONFIG_FILES([docs/doxygen.cfg])
 760
 761 dnl Do the first stage of configuration for llvm-config.in.
 762 AC_CONFIG_FILES([tools/llvm-config/llvm-config.in])
 763
 764 dnl Do special configuration of Makefiles
 765 AC_CONFIG_COMMANDS([setup],,[llvm_src="${srcdir}"])
 766 AC_CONFIG_MAKEFILE(Makefile)
 767 AC_CONFIG_MAKEFILE(Makefile.common)
 768 AC_CONFIG_MAKEFILE(examples/Makefile)
 769 AC_CONFIG_MAKEFILE(lib/Makefile)
 770 AC_CONFIG_MAKEFILE(runtime/Makefile)
 771 AC_CONFIG_MAKEFILE(test/Makefile)
 772 AC_CONFIG_MAKEFILE(test/Makefile.tests)
 773 AC_CONFIG_MAKEFILE(tools/Makefile)
 774 AC_CONFIG_MAKEFILE(utils/Makefile)
 775 AC_CONFIG_MAKEFILE(projects/Makefile)
 776
 777 dnl Finally, crank out the output
 778 AC_OUTPUT
 779
 780 dnl Warn loudly if llvm-gcc was not obviously working
 781 if test "$llvm_cv_llvmgcc_sanity" = "no" ; then
 782  AC_MSG_WARN([***** llvm-gcc/llvm-g++ was not found, or does not appear to be ])
 783  AC_MSG_WARN([***** working. Please make sure you have llvmgcc and llvmg++ in])
 784  AC_MSG_WARN([***** your path before configuring LLVM. The runtime libraries])
 785  AC_MSG_WARN([***** (llvm/runtime) will not be built but you should be able to])
 786  AC_MSG_WARN([***** build the llvm tools.])
 787 fi