autoconf/configure.ac

   1 dnl === configure.ac --------------------------------------------------------===
   2 dnl                     The LLVM Compiler Infrastructure
   3 dnl
   4 dnl This file is distributed under the University of Illinois Open Source
   5 dnl License. See LICENSE.TXT for details.
   6 dnl
   7 dnl===-----------------------------------------------------------------------===
   8 dnl This is the LLVM configuration script. It is processed by the autoconf
   9 dnl program to produce a script named configure. This script contains the
  10 dnl configuration checks that LLVM needs in order to support multiple platforms.
  11 dnl This file is composed of 10 sections per the recommended organization of
  12 dnl autoconf input defined in the autoconf documentation. As this file evolves,
  13 dnl please keep the various types of checks within their sections. The sections
  14 dnl are as follows:
  15 dnl
  16 dnl SECTION 1: Initialization & Setup
  17 dnl SECTION 2: Architecture, target, and host checks
  18 dnl SECTION 3: Command line arguments for the configure script.
  19 dnl SECTION 4: Check for programs we need and that they are the right version
  20 dnl SECTION 5: Check for libraries
  21 dnl SECTION 6: Check for header files
  22 dnl SECTION 7: Check for types and structures
  23 dnl SECTION 8: Check for specific functions needed
  24 dnl SECTION 9: Additional checks, variables, etc.
  25 dnl SECTION 10: Specify the output files and generate it
  26 dnl
  27 dnl===-----------------------------------------------------------------------===
  28 dnl===
  29 dnl=== SECTION 1: Initialization & Setup
  30 dnl===
  31 dnl===-----------------------------------------------------------------------===
  32 dnl Initialize autoconf and define the package name, version number and
  33 dnl email address for reporting bugs.
  34 AC_INIT([[llvm]],[[2.4svn]],[llvmbugs@cs.uiuc.edu])
  35
  36 dnl Provide a copyright substitution and ensure the copyright notice is included
  37 dnl in the output of --version option of the generated configure script.
  38 AC_SUBST(LLVM_COPYRIGHT,["Copyright (c) 2003-2008 University of Illinois at Urbana-Champaign."])
  39 AC_COPYRIGHT([Copyright (c) 2003-2008 University of Illinois at Urbana-Champaign.])
  40
  41 dnl Indicate that we require autoconf 2.59 or later. Ths is needed because we
  42 dnl use some autoconf macros only available in 2.59.
  43 AC_PREREQ(2.59)
  44
  45 dnl Verify that the source directory is valid. This makes sure that we are
  46 dnl configuring LLVM and not some other package (it validates --srcdir argument)
  47 AC_CONFIG_SRCDIR([lib/VMCore/Module.cpp])
  48
  49 dnl Place all of the extra autoconf files into the config subdirectory. Tell
  50 dnl various tools where the m4 autoconf macros are.
  51 AC_CONFIG_AUX_DIR([autoconf])
  52
  53 dnl Quit if the source directory has already been configured.
  54 dnl NOTE: This relies upon undocumented autoconf behavior.
  55 if test ${srcdir} != "." ; then
  56   if test -f ${srcdir}/include/llvm/Config/config.h ; then
  57     AC_MSG_ERROR([Already configured in ${srcdir}])
  58   fi
  59 fi
  60
  61 dnl Configure all of the projects present in our source tree. While we could
  62 dnl just AC_CONFIG_SUBDIRS on the set of directories in projects that have a
  63 dnl configure script, that usage of the AC_CONFIG_SUBDIRS macro is deprecated.
  64 dnl Instead we match on the known projects.
  65 for i in `ls ${srcdir}/projects`
  66 do
  67   if test -d ${srcdir}/projects/${i} ; then
  68     case ${i} in
  69       CVS) ;;
  70       sample)       AC_CONFIG_SUBDIRS([projects/sample])    ;;
  71       privbracket)  AC_CONFIG_SUBDIRS([projects/privbracket]) ;;
  72       llvm-stacker) AC_CONFIG_SUBDIRS([projects/llvm-stacker]) ;;
  73       # llvm-test is the old name of the test-suite, kept here for backwards
  74       # compatibility
  75       llvm-test)    AC_CONFIG_SUBDIRS([projects/llvm-test]) ;;
  76       test-suite)   AC_CONFIG_SUBDIRS([projects/test-suite]) ;;
  77       llvm-reopt)   AC_CONFIG_SUBDIRS([projects/llvm-reopt]);;
  78       llvm-gcc)     AC_CONFIG_SUBDIRS([projects/llvm-gcc])  ;;
  79       llvm-java)    AC_CONFIG_SUBDIRS([projects/llvm-java]) ;;
  80       llvm-tv)      AC_CONFIG_SUBDIRS([projects/llvm-tv])   ;;
  81       llvm-poolalloc) AC_CONFIG_SUBDIRS([projects/llvm-poolalloc]) ;;
  82       poolalloc)    AC_CONFIG_SUBDIRS([projects/poolalloc]) ;;
  83       llvm-kernel)  AC_CONFIG_SUBDIRS([projects/llvm-kernel]) ;;
  84       *)
  85         AC_MSG_WARN([Unknown project (${i}) won't be configured automatically])
  86         ;;
  87     esac
  88   fi
  89 done
  90
  91 dnl===-----------------------------------------------------------------------===
  92 dnl===
  93 dnl=== SECTION 2: Architecture, target, and host checks
  94 dnl===
  95 dnl===-----------------------------------------------------------------------===
  96
  97 dnl Check the target for which we're compiling and the host that will do the
  98 dnl compilations. This will tell us which LLVM compiler will be used for
  99 dnl compiling SSA into object code. This needs to be done early because
 100 dnl following tests depend on it.
 101 AC_CANONICAL_TARGET
 102
 103 dnl Determine the platform type and cache its value. This helps us configure
 104 dnl the System library to the correct build platform.
 105 AC_CACHE_CHECK([type of operating system we're going to host on],
 106                [llvm_cv_os_type],
 107 [case $host in
 108   *-*-aix*)
 109     llvm_cv_link_all_option="-Wl,--whole-archive"
 110     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 111     llvm_cv_os_type="AIX"
 112     llvm_cv_platform_type="Unix" ;;
 113   *-*-irix*)
 114     llvm_cv_link_all_option="-Wl,--whole-archive"
 115     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 116     llvm_cv_os_type="IRIX"
 117     llvm_cv_platform_type="Unix" ;;
 118   *-*-cygwin*)
 119     llvm_cv_link_all_option="-Wl,--whole-archive"
 120     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 121     llvm_cv_os_type="Cygwin"
 122     llvm_cv_platform_type="Unix" ;;
 123   *-*-darwin*)
 124     llvm_cv_link_all_option="-Wl,-all_load"
 125     llvm_cv_no_link_all_option="-Wl,-noall_load"
 126     llvm_cv_os_type="Darwin"
 127     llvm_cv_platform_type="Unix" ;;
 128   *-*-freebsd*)
 129     llvm_cv_link_all_option="-Wl,--whole-archive"
 130     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 131     llvm_cv_os_type="FreeBSD"
 132     llvm_cv_platform_type="Unix" ;;
 133   *-*-openbsd*)
 134     llvm_cv_link_all_option="-Wl,--whole-archive"
 135     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 136     llvm_cv_os_type="OpenBSD"
 137     llvm_cv_platform_type="Unix" ;;
 138   *-*-netbsd*)
 139     llvm_cv_link_all_option="-Wl,--whole-archive"
 140     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 141     llvm_cv_os_type="NetBSD"
 142     llvm_cv_platform_type="Unix" ;;
 143   *-*-dragonfly*)
 144     llvm_cv_link_all_option="-Wl,--whole-archive"
 145     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 146     llvm_cv_os_type="DragonFly"
 147     llvm_cv_platform_type="Unix" ;;
 148   *-*-hpux*)
 149     llvm_cv_link_all_option="-Wl,--whole-archive"
 150     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 151     llvm_cv_os_type="HP-UX"
 152     llvm_cv_platform_type="Unix" ;;
 153   *-*-interix*)
 154     llvm_cv_link_all_option="-Wl,--whole-archive"
 155     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 156     llvm_cv_os_type="Interix"
 157     llvm_cv_platform_type="Unix" ;;
 158   *-*-linux*)
 159     llvm_cv_link_all_option="-Wl,--whole-archive"
 160     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 161     llvm_cv_os_type="Linux"
 162     llvm_cv_platform_type="Unix" ;;
 163   *-*-solaris*)
 164     llvm_cv_link_all_option="-Wl,-z,allextract"
 165     llvm_cv_no_link_all_option="-Wl,-z,defaultextract"
 166     llvm_cv_os_type="SunOS"
 167     llvm_cv_platform_type="Unix" ;;
 168   *-*-win32*)
 169     llvm_cv_link_all_option="-Wl,--whole-archive"
 170     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 171     llvm_cv_os_type="Win32"
 172     llvm_cv_platform_type="Win32" ;;
 173   *-*-mingw*)
 174     llvm_cv_link_all_option="-Wl,--whole-archive"
 175     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 176     llvm_cv_os_type="MingW"
 177     llvm_cv_platform_type="Win32" ;;
 178   *)
 179     llvm_cv_link_all_option=""
 180     llvm_cv_no_link_all_option=""
 181     llvm_cv_os_type="Unknown"
 182     llvm_cv_platform_type="Unknown" ;;
 183 esac])
 184
 185 dnl Make sure we aren't attempting to configure for an unknown system
 186 if test "$llvm_cv_os_type" = "Unknown" ; then
 187   AC_MSG_ERROR([Operating system is unknown, configure can't continue])
 188 fi
 189
 190 dnl Set the "OS" Makefile variable based on the platform type so the
 191 dnl makefile can configure itself to specific build hosts
 192 AC_SUBST(OS,$llvm_cv_os_type)
 193
 194 dnl Set the LINKALL and NOLINKALL Makefile variables based on the platform
 195 AC_SUBST(LINKALL,$llvm_cv_link_all_option)
 196 AC_SUBST(NOLINKALL,$llvm_cv_no_link_all_option)
 197
 198 dnl Set the "LLVM_ON_*" variables based on llvm_cvs_platform_type
 199 dnl This is used by lib/System to determine the basic kind of implementation
 200 dnl to use.
 201 case $llvm_cv_platform_type in
 202   Unix)
 203     AC_DEFINE([LLVM_ON_UNIX],[1],[Define if this is Unixish platform])
 204     AC_SUBST(LLVM_ON_UNIX,[1])
 205     AC_SUBST(LLVM_ON_WIN32,[0])
 206     ;;
 207   Win32)
 208     AC_DEFINE([LLVM_ON_WIN32],[1],[Define if this is Win32ish platform])
 209     AC_SUBST(LLVM_ON_UNIX,[0])
 210     AC_SUBST(LLVM_ON_WIN32,[1])
 211     ;;
 212 esac
 213
 214 dnl Determine what our target architecture is and configure accordingly.
 215 dnl This will allow Makefiles to make a distinction between the hardware and
 216 dnl the OS.
 217 AC_CACHE_CHECK([target architecture],[llvm_cv_target_arch],
 218 [case $target in
 219   i?86-*)                 llvm_cv_target_arch="x86" ;;
 220   amd64-* | x86_64-*)     llvm_cv_target_arch="x86_64" ;;
 221   sparc*-*)               llvm_cv_target_arch="Sparc" ;;
 222   powerpc*-*)             llvm_cv_target_arch="PowerPC" ;;
 223   alpha*-*)               llvm_cv_target_arch="Alpha" ;;
 224   ia64-*)                 llvm_cv_target_arch="IA64" ;;
 225   arm-*)                  llvm_cv_target_arch="ARM" ;;
 226   mips-*)                 llvm_cv_target_arch="Mips" ;;
 227   pic16-*)                llvm_cv_target_arch="PIC16" ;;
 228   *)                      llvm_cv_target_arch="Unknown" ;;
 229 esac])
 230
 231 if test "$llvm_cv_target_arch" = "Unknown" ; then
 232   AC_MSG_WARN([Configuring LLVM for an unknown target archicture])
 233 fi
 234
 235 dnl Define a substitution, ARCH, for the target architecture
 236 AC_SUBST(ARCH,$llvm_cv_target_arch)
 237
 238 dnl Check for the endianness of the target
 239 AC_C_BIGENDIAN(AC_SUBST([ENDIAN],[big]),AC_SUBST([ENDIAN],[little]))
 240
 241 dnl Check for build platform executable suffix if we're crosscompiling
 242 if test "$cross_compiling" = yes; then
 243   AC_SUBST(LLVM_CROSS_COMPILING, [1])
 244   AC_BUILD_EXEEXT
 245 else
 246   AC_SUBST(LLVM_CROSS_COMPILING, [0])
 247 fi
 248
 249 dnl Check to see if there's a "CVS" (or .svn) directory indicating that this
 250 dnl build is being done from a checkout. This sets up several defaults for the
 251 dnl command line switches. When we build with a CVS directory, we get a
 252 dnl debug with assertions turned on. Without, we assume a source release and we
 253 dnl get an optimized build without assertions. See --enable-optimized and
 254 dnl --enable-assertions below
 255 if test -d "CVS" -o -d "${srcdir}/CVS" -o -d ".svn" -o -d "${srcdir}/.svn"; then
 256   cvsbuild="yes"
 257   optimize="no"
 258   AC_SUBST(CVSBUILD,[[CVSBUILD=1]])
 259 else
 260   cvsbuild="no"
 261   optimize="yes"
 262 fi
 263
 264 dnl===-----------------------------------------------------------------------===
 265 dnl===
 266 dnl=== SECTION 3: Command line arguments for the configure script.
 267 dnl===
 268 dnl===-----------------------------------------------------------------------===
 269
 270 dnl --enable-optimized : check whether they want to do an optimized build:
 271 AC_ARG_ENABLE(optimized, AS_HELP_STRING(
 272  [--enable-optimized,Compile with optimizations enabled (default is NO)]),,enableval=$optimize)
 273 if test ${enableval} = "no" ; then
 274   AC_SUBST(ENABLE_OPTIMIZED,[[]])
 275 else
 276   AC_SUBST(ENABLE_OPTIMIZED,[[ENABLE_OPTIMIZED=1]])
 277 fi
 278
 279 dnl --enable-assertions : check whether they want to turn on assertions or not:
 280 AC_ARG_ENABLE(assertions,AS_HELP_STRING(
 281   [--enable-assertions,Compile with assertion checks enabled (default is YES)]),, enableval="yes")
 282 if test ${enableval} = "yes" ; then
 283   AC_SUBST(DISABLE_ASSERTIONS,[[]])
 284 else
 285   AC_SUBST(DISABLE_ASSERTIONS,[[DISABLE_ASSERTIONS=1]])
 286 fi
 287
 288 dnl --enable-expensive-checks : check whether they want to turn on expensive debug checks:
 289 AC_ARG_ENABLE(expensive-checks,AS_HELP_STRING(
 290   [--enable-expensive-checks,Compile with expensive debug checks enabled (default is NO)]),, enableval="no")
 291 if test ${enableval} = "yes" ; then
 292   AC_SUBST(ENABLE_EXPENSIVE_CHECKS,[[ENABLE_EXPENSIVE_CHECKS=1]])
 293   AC_SUBST(EXPENSIVE_CHECKS,[[yes]])
 294 else
 295   AC_SUBST(ENABLE_EXPENSIVE_CHECKS,[[]])
 296   AC_SUBST(EXPENSIVE_CHECKS,[[no]])
 297 fi
 298
 299 dnl --enable-debug-runtime : should runtime libraries have debug symbols?
 300 AC_ARG_ENABLE(debug-runtime,
 301    AS_HELP_STRING([--enable-debug-runtime,Build runtime libs with debug symbols (default is NO)]),,enableval=no)
 302 if test ${enableval} = "no" ; then
 303   AC_SUBST(DEBUG_RUNTIME,[[]])
 304 else
 305   AC_SUBST(DEBUG_RUNTIME,[[DEBUG_RUNTIME=1]])
 306 fi
 307
 308 dnl --enable-jit: check whether they want to enable the jit
 309 AC_ARG_ENABLE(jit,
 310   AS_HELP_STRING(--enable-jit,
 311                  [Enable Just In Time Compiling (default is YES)]),,
 312   enableval=default)
 313 if test ${enableval} = "no"
 314 then
 315   AC_SUBST(JIT,[[]])
 316 else
 317   case "$llvm_cv_target_arch" in
 318     x86)     AC_SUBST(TARGET_HAS_JIT,1) ;;
 319     Sparc)   AC_SUBST(TARGET_HAS_JIT,0) ;;
 320     PowerPC) AC_SUBST(TARGET_HAS_JIT,1) ;;
 321     x86_64)  AC_SUBST(TARGET_HAS_JIT,1) ;;
 322     Alpha)   AC_SUBST(TARGET_HAS_JIT,1) ;;
 323     IA64)    AC_SUBST(TARGET_HAS_JIT,0) ;;
 324     ARM)     AC_SUBST(TARGET_HAS_JIT,0) ;;
 325     Mips)    AC_SUBST(TARGET_HAS_JIT,0) ;;
 326     PIC16)   AC_SUBST(TARGET_HAS_JIT,0) ;;
 327     *)       AC_SUBST(TARGET_HAS_JIT,0) ;;
 328   esac
 329 fi
 330
 331 dnl Allow enablement of doxygen generated documentation
 332 AC_ARG_ENABLE(doxygen,
 333               AS_HELP_STRING([--enable-doxygen],
 334                              [Build doxygen documentation (default is NO)]),,
 335                              enableval=default)
 336 case "$enableval" in
 337   yes) AC_SUBST(ENABLE_DOXYGEN,[1]) ;;
 338   no)  AC_SUBST(ENABLE_DOXYGEN,[0]) ;;
 339   default) AC_SUBST(ENABLE_DOXYGEN,[0]) ;;
 340   *) AC_MSG_ERROR([Invalid setting for --enable-doxygen. Use "yes" or "no"]) ;;
 341 esac
 342
 343 dnl Allow disablement of threads
 344 AC_ARG_ENABLE(threads,
 345               AS_HELP_STRING([--enable-threads],
 346                              [Use threads if available (default is YES)]),,
 347                              enableval=default)
 348 case "$enableval" in
 349   yes) AC_SUBST(ENABLE_THREADS,[1]) ;;
 350   no)  AC_SUBST(ENABLE_THREADS,[0]) ;;
 351   default) AC_SUBST(ENABLE_THREADS,[1]) ;;
 352   *) AC_MSG_ERROR([Invalid setting for --enable-threads. Use "yes" or "no"]) ;;
 353 esac
 354 AC_DEFINE_UNQUOTED([ENABLE_THREADS],$ENABLE_THREADS,[Define if threads enabled])
 355
 356 dnl Allow building with position independent code
 357 AC_ARG_ENABLE(pic,
 358   AS_HELP_STRING([--enable-pic],
 359                  [Build LLVM with Position Independent Code (default is NO)]),,
 360                  enableval=default)
 361 case "$enableval" in
 362   yes) AC_SUBST(ENABLE_PIC,[1]) ;;
 363   no)  AC_SUBST(ENABLE_PIC,[0]) ;;
 364   default) AC_SUBST(ENABLE_PIC,[0]) ;;
 365   *) AC_MSG_ERROR([Invalid setting for --enable-pic. Use "yes" or "no"]) ;;
 366 esac
 367 AC_DEFINE_UNQUOTED([ENABLE_PIC],$ENABLE_PIC,
 368                    [Define if position independent code is enabled])
 369
 370 dnl Allow specific targets to be specified for building (or not)
 371 TARGETS_TO_BUILD=""
 372 AC_ARG_ENABLE([targets],AS_HELP_STRING([--enable-targets],
 373     [Build specific host targets: all,host-only,{target-name} (default=all)]),,
 374     enableval=all)
 375 case "$enableval" in
 376   all) TARGETS_TO_BUILD="X86 Sparc PowerPC Alpha IA64 ARM Mips CellSPU PIC16 CBackend MSIL CppBackend" ;;
 377   host-only)
 378     case "$llvm_cv_target_arch" in
 379       x86)     TARGETS_TO_BUILD="X86" ;;
 380       x86_64)  TARGETS_TO_BUILD="X86" ;;
 381       Sparc)   TARGETS_TO_BUILD="Sparc" ;;
 382       PowerPC) TARGETS_TO_BUILD="PowerPC" ;;
 383       Alpha)   TARGETS_TO_BUILD="Alpha" ;;
 384       IA64)    TARGETS_TO_BUILD="IA64" ;;
 385       ARM)     TARGETS_TO_BUILD="ARM" ;;
 386       Mips)    TARGETS_TO_BUILD="Mips" ;;
 387       CellSPU|SPU) TARGETS_TO_BUILD="CellSPU" ;;
 388       PIC16)   TARGETS_TO_BUILD="PIC16" ;;
 389       *)       AC_MSG_ERROR([Can not set target to build]) ;;
 390     esac
 391     ;;
 392   *)for a_target in `echo $enableval|sed -e 's/,/ /g' ` ; do
 393       case "$a_target" in
 394         x86)     TARGETS_TO_BUILD="X86 $TARGETS_TO_BUILD" ;;
 395         x86_64)  TARGETS_TO_BUILD="X86 $TARGETS_TO_BUILD" ;;
 396         sparc)   TARGETS_TO_BUILD="Sparc $TARGETS_TO_BUILD" ;;
 397         powerpc) TARGETS_TO_BUILD="PowerPC $TARGETS_TO_BUILD" ;;
 398         alpha)   TARGETS_TO_BUILD="Alpha $TARGETS_TO_BUILD" ;;
 399         ia64)    TARGETS_TO_BUILD="IA64 $TARGETS_TO_BUILD" ;;
 400         arm)     TARGETS_TO_BUILD="ARM $TARGETS_TO_BUILD" ;;
 401         mips)    TARGETS_TO_BUILD="Mips $TARGETS_TO_BUILD" ;;
 402         spu)     TARGETS_TO_BUILD="CellSPU $TARGETS_TO_BUILD" ;;
 403         pic16)   TARGETS_TO_BUILD="PIC16 $TARGETS_TO_BUILD" ;;
 404         cbe)     TARGETS_TO_BUILD="CBackend $TARGETS_TO_BUILD" ;;
 405         msil)    TARGETS_TO_BUILD="MSIL $TARGETS_TO_BUILD" ;;
 406         cpp)     TARGETS_TO_BUILD="CppBackend $TARGETS_TO_BUILD" ;;
 407         *) AC_MSG_ERROR([Unrecognized target $a_target]) ;;
 408       esac
 409   done
 410   ;;
 411 esac
 412 AC_SUBST(TARGETS_TO_BUILD,$TARGETS_TO_BUILD)
 413
 414 dnl Prevent the CBackend from using printf("%a") for floating point so older
 415 dnl C compilers that cannot deal with the 0x0p+0 hex floating point format
 416 dnl can still compile the CBE's output
 417 AC_ARG_ENABLE([cbe-printf-a],AS_HELP_STRING([--enable-cbe-printf-a],
 418   [Enable C Backend output with hex floating point via %a  (default is YES)]),,
 419   enableval=default)
 420 case "$enableval" in
 421   yes) AC_SUBST(ENABLE_CBE_PRINTF_A,[1]) ;;
 422   no)  AC_SUBST(ENABLE_CBE_PRINTF_A,[0]) ;;
 423   default)  AC_SUBST(ENABLE_CBE_PRINTF_A,[1]) ;;
 424   *) AC_MSG_ERROR([Invalid setting for --enable-cbe-printf-a. Use "yes" or "no"]) ;;
 425 esac
 426 AC_DEFINE_UNQUOTED([ENABLE_CBE_PRINTF_A],$ENABLE_CBE_PRINTF_A,
 427                    [Define if CBE is enabled for printf %a output])
 428
 429 dnl Allow a specific llvm-gcc/llvm-g++ pair to be used with this LLVM config.
 430 AC_ARG_WITH(llvmgccdir,
 431   AS_HELP_STRING([--with-llvmgccdir],
 432     [Specify location of llvm-gcc install dir (default searches PATH)]),,
 433     withval=default)
 434 case "$withval" in
 435   default) WITH_LLVMGCCDIR=default ;;
 436   /* | [[A-Za-z]]:[[\\/]]*)      WITH_LLVMGCCDIR=$withval ;;
 437   *) AC_MSG_ERROR([Invalid path for --with-llvmgccdir. Provide full path]) ;;
 438 esac
 439
 440 dnl Allow a specific llvm-gcc compiler to be used with this LLVM config.
 441 AC_ARG_WITH(llvmgcc,
 442   AS_HELP_STRING([--with-llvmgcc],
 443     [Specify location of llvm-gcc driver (default searches PATH)]),
 444     LLVMGCC=$with_llvmgcc
 445       WITH_LLVMGCCDIR="",)
 446
 447 dnl Allow a specific llvm-g++ compiler to be used with this LLVM config.
 448 AC_ARG_WITH(llvmgxx,
 449   AS_HELP_STRING([--with-llvmgxx],
 450     [Specify location of llvm-g++ driver (default searches PATH)]),
 451     LLVMGXX=$with_llvmgxx
 452     WITH_LLVMGCCDIR="",)
 453
 454 if test -n "$LLVMGCC" && test -z "$LLVMGXX"; then
 455    AC_MSG_ERROR([Invalid llvm-g++. Use --with-llvmgxx when --with-llvmgcc is used]);
 456 fi
 457
 458 if test -n "$LLVMGXX" && test -z "$LLVMGCC"; then
 459    AC_MSG_ERROR([Invalid llvm-gcc. Use --with-llvmgcc when --with-llvmgxx is used]);
 460 fi
 461
 462 dnl Specify extra build options
 463 AC_ARG_WITH(extra-options,
 464   AS_HELP_STRING([--with-extra-options],
 465                  [Specify addtional options to compile LLVM with]),,
 466                  withval=default)
 467 case "$withval" in
 468   default) EXTRA_OPTIONS= ;;
 469   *) EXTRA_OPTIONS=$withval ;;
 470 esac
 471 AC_SUBST(EXTRA_OPTIONS,$EXTRA_OPTIONS)
 472
 473 dnl Allow specific bindings to be specified for building (or not)
 474 AC_ARG_ENABLE([bindings],AS_HELP_STRING([--enable-bindings],
 475     [Build specific language bindings: all,auto,none,{binding-name} (default=auto)]),,
 476     enableval=default)
 477 BINDINGS_TO_BUILD=""
 478 case "$enableval" in
 479   yes | default | auto) BINDINGS_TO_BUILD="auto" ;;
 480   all ) BINDINGS_TO_BUILD="ocaml" ;;
 481   none | no) BINDINGS_TO_BUILD="" ;;
 482   *)for a_binding in `echo $enableval|sed -e 's/,/ /g' ` ; do
 483       case "$a_binding" in
 484         ocaml) BINDINGS_TO_BUILD="ocaml $BINDINGS_TO_BUILD" ;;
 485         *) AC_MSG_ERROR([Unrecognized binding $a_binding]) ;;
 486       esac
 487   done
 488   ;;
 489 esac
 490
 491 dnl Allow the ocaml libdir to be overridden. This could go in a configure
 492 dnl script for bindings/ocaml/configure, except that its auto value depends on
 493 dnl OCAMLC, which is found here to support tests.
 494 AC_ARG_WITH([ocaml-libdir],
 495   [AS_HELP_STRING([--with-ocaml-libdir],
 496     [Specify install location for ocaml bindings (default is stdlib)])],
 497   [],
 498   [withval=auto])
 499 case "$withval" in
 500   auto) with_ocaml_libdir="$withval" ;;
 501   /* | [[A-Za-z]]:[[\\/]]*) with_ocaml_libdir="$withval" ;;
 502   *) AC_MSG_ERROR([Invalid path for --with-ocaml-libdir. Provide full path]) ;;
 503 esac
 504
 505 dnl===-----------------------------------------------------------------------===
 506 dnl===
 507 dnl=== SECTION 4: Check for programs we need and that they are the right version
 508 dnl===
 509 dnl===-----------------------------------------------------------------------===
 510
 511 dnl Check for compilation tools
 512 AC_PROG_CPP
 513 AC_PROG_CC(gcc)
 514 AC_PROG_CXX(g++)
 515 AC_PROG_FLEX
 516 AC_PROG_BISON
 517
 518 AC_PROG_NM
 519 AC_SUBST(NM)
 520
 521 dnl Check for the tools that the makefiles require
 522 AC_CHECK_GNU_MAKE
 523 AC_PROG_LN_S
 524 AC_PATH_PROG(CMP, [cmp], [cmp])
 525 AC_PATH_PROG(CP, [cp], [cp])
 526 AC_PATH_PROG(DATE, [date], [date])
 527 AC_PATH_PROG(FIND, [find], [find])
 528 AC_PATH_PROG(GREP, [grep], [grep])
 529 AC_PATH_PROG(MKDIR,[mkdir],[mkdir])
 530 AC_PATH_PROG(MV,   [mv],   [mv])
 531 AC_PROG_RANLIB
 532 AC_PATH_PROG(RM,   [rm],   [rm])
 533 AC_PATH_PROG(SED,  [sed],  [sed])
 534 AC_PATH_PROG(TAR,  [tar],  [gtar])
 535 AC_PATH_PROG(BINPWD,[pwd],  [pwd])
 536
 537 dnl Looking for misc. graph plotting software
 538 AC_PATH_PROG(GRAPHVIZ, [Graphviz], [echo Graphviz])
 539 if test "$GRAPHVIZ" != "echo Graphviz" ; then
 540   AC_DEFINE([HAVE_GRAPHVIZ],[1],[Define if the Graphviz program is available])
 541   dnl If we're targeting for mingw we should emit windows paths, not msys
 542   if test "$llvm_cv_os_type" = "MingW" ; then
 543     GRAPHVIZ=`echo $GRAPHVIZ | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
 544   fi
 545   AC_DEFINE_UNQUOTED([LLVM_PATH_GRAPHVIZ],"$GRAPHVIZ${EXEEXT}",
 546    [Define to path to Graphviz program if found or 'echo Graphviz' otherwise])
 547 fi
 548 AC_PATH_PROG(DOT, [dot], [echo dot])
 549 if test "$DOT" != "echo dot" ; then
 550   AC_DEFINE([HAVE_DOT],[1],[Define if the dot program is available])
 551   dnl If we're targeting for mingw we should emit windows paths, not msys
 552   if test "$llvm_cv_os_type" = "MingW" ; then
 553     DOT=`echo $DOT | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
 554   fi
 555   AC_DEFINE_UNQUOTED([LLVM_PATH_DOT],"$DOT${EXEEXT}",
 556    [Define to path to dot program if found or 'echo dot' otherwise])
 557 fi
 558 AC_PATH_PROGS(GV, [gv gsview32], [echo gv])
 559 if test "$GV" != "echo gv" ; then
 560   AC_DEFINE([HAVE_GV],[1],[Define if the gv program is available])
 561   dnl If we're targeting for mingw we should emit windows paths, not msys
 562   if test "$llvm_cv_os_type" = "MingW" ; then
 563     GV=`echo $GV | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
 564   fi
 565   AC_DEFINE_UNQUOTED([LLVM_PATH_GV],"$GV${EXEEXT}",
 566    [Define to path to gv program if found or 'echo gv' otherwise])
 567 fi
 568 AC_PATH_PROG(DOTTY, [dotty], [echo dotty])
 569 if test "$DOTTY" != "echo dotty" ; then
 570   AC_DEFINE([HAVE_DOTTY],[1],[Define if the dotty program is available])
 571   dnl If we're targeting for mingw we should emit windows paths, not msys
 572   if test "$llvm_cv_os_type" = "MingW" ; then
 573     DOTTY=`echo $DOTTY | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
 574   fi
 575   AC_DEFINE_UNQUOTED([LLVM_PATH_DOTTY],"$DOTTY${EXEEXT}",
 576    [Define to path to dotty program if found or 'echo dotty' otherwise])
 577 fi
 578
 579 dnl Look for a sufficiently recent version of Perl.
 580 LLVM_PROG_PERL([5.006])
 581 AC_SUBST(PERL)
 582 if test x"$PERL" = xnone; then
 583    AC_SUBST(HAVE_PERL,0)
 584    AC_MSG_ERROR([perl is required but was not found, please install it])
 585 else
 586    AC_SUBST(HAVE_PERL,1)
 587 fi
 588
 589 dnl Find the install program
 590 AC_PROG_INSTALL
 591
 592 dnl Checks for documentation and testing tools that we can do without. If these
 593 dnl are not found then they are set to "true" which always succeeds but does
 594 dnl nothing. This just lets the build output show that we could have done
 595 dnl something if the tool was available.
 596 AC_PATH_PROG(BZIP2, [bzip2])
 597 AC_PATH_PROG(DOXYGEN, [doxygen])
 598 AC_PATH_PROG(GROFF, [groff])
 599 AC_PATH_PROG(GZIP, [gzip])
 600 AC_PATH_PROG(POD2HTML, [pod2html])
 601 AC_PATH_PROG(POD2MAN, [pod2man])
 602 AC_PATH_PROG(RUNTEST, [runtest])
 603 DJ_AC_PATH_TCLSH
 604 AC_PATH_PROG(ZIP, [zip])
 605 AC_PATH_PROGS(OCAMLC, [ocamlc.opt ocamlc])
 606 AC_PATH_PROGS(OCAMLOPT, [ocamlopt.opt ocamlopt])
 607 AC_PATH_PROGS(OCAMLDEP, [ocamldep.opt ocamldep])
 608 AC_PATH_PROGS(OCAMLDOC, [ocamldoc.opt ocamldoc])
 609
 610 dnl Determine if the linker supports the -R option.
 611 AC_LINK_USE_R
 612
 613 dnl Check for libtool and the library that has dlopen function (which must come
 614 dnl before the AC_PROG_LIBTOOL check in order to enable dlopening libraries with
 615 dnl libtool).
 616 AC_LIBTOOL_DLOPEN
 617 AC_LIB_LTDL
 618 AC_PROG_LIBTOOL
 619
 620 if test "$lt_cv_dlopen_self" = "yes" ; then
 621   AC_DEFINE([CAN_DLOPEN_SELF],[1],
 622               [Define if dlopen(0) will open the symbols of the program])
 623 fi
 624
 625 if test "$WITH_LLVMGCCDIR" = "default" ; then
 626   LLVMGCC="llvm-gcc${EXEEXT}"
 627   LLVMGXX="llvm-g++${EXEEXT}"
 628   AC_PATH_PROG(LLVMGCC, $LLVMGCC, [])
 629   AC_PATH_PROG(LLVMGXX, $LLVMGXX, [])
 630 else
 631   if test -z "$LLVMGCC"; then
 632     LLVMGCC="$WITH_LLVMGCCDIR/bin/llvm-gcc${EXEEXT}"
 633   fi
 634   if test -z "$LLVMGXX"; then
 635     LLVMGXX="$WITH_LLVMGCCDIR/bin/llvm-g++${EXEEXT}"
 636   fi
 637   AC_SUBST(LLVMGCC,$LLVMGCC)
 638   AC_SUBST(LLVMGXX,$LLVMGXX)
 639 fi
 640
 641 AC_MSG_CHECKING([tool compatibility])
 642
 643 dnl Ensure that compilation tools are GCC or a GNU compatible compiler such as
 644 dnl ICC; we use GCC specific options in the makefiles so the compiler needs
 645 dnl to support those options.
 646 dnl "icc" emits gcc signatures
 647 dnl "icc -no-gcc" emits no gcc signature BUT is still compatible
 648 ICC=no
 649 IXX=no
 650 case $CC in
 651   icc*|icpc*)
 652     ICC=yes
 653     IXX=yes
 654     ;;
 655    *)
 656     ;;
 657 esac
 658
 659 if test "$GCC" != "yes" && test "$ICC" != "yes"
 660 then
 661   AC_MSG_ERROR([gcc|icc required but not found])
 662 fi
 663
 664 dnl Ensure that compilation tools are GCC; we use GCC specific extensions
 665 if test "$GXX" != "yes" && test "$IXX" != "yes"
 666 then
 667   AC_MSG_ERROR([g++|icc required but not found])
 668 fi
 669
 670 dnl Verify that GCC is version 3.0 or higher
 671 if test "$GCC" = "yes"
 672 then
 673   AC_COMPILE_IFELSE([[#if !defined(__GNUC__) || __GNUC__ < 3
 674 #error Unsupported GCC version
 675 #endif
 676 ]], [], [AC_MSG_ERROR([gcc 3.x required, but you have a lower version])])
 677 fi
 678
 679 dnl Check for GNU Make.  We use its extensions, so don't build without it
 680 if test -z "$llvm_cv_gnu_make_command"
 681 then
 682   AC_MSG_ERROR([GNU Make required but not found])
 683 fi
 684
 685 dnl Tool compatibility is okay if we make it here.
 686 AC_MSG_RESULT([ok])
 687
 688 dnl===-----------------------------------------------------------------------===
 689 dnl===
 690 dnl=== SECTION 5: Check for libraries
 691 dnl===
 692 dnl===-----------------------------------------------------------------------===
 693
 694 dnl libelf is for sparc only; we can ignore it if we don't have it
 695 AC_CHECK_LIB(elf, elf_begin)
 696 AC_CHECK_LIB(m,sin)
 697 if test "$llvm_cv_os_type" = "MingW" ; then
 698   AC_CHECK_LIB(imagehlp, main)
 699   AC_CHECK_LIB(psapi, main)
 700 fi
 701
 702 dnl dlopen() is required for plugin support.
 703 AC_SEARCH_LIBS(dlopen,dl,AC_DEFINE([HAVE_DLOPEN],[1],
 704                [Define if dlopen() is available on this platform.]),
 705                AC_MSG_WARN([dlopen() not found - disabling plugin support]))
 706
 707 dnl mallinfo is optional; the code can compile (minus features) without it
 708 AC_SEARCH_LIBS(mallinfo,malloc,AC_DEFINE([HAVE_MALLINFO],[1],
 709                [Define if mallinfo() is available on this platform.]))
 710
 711 dnl pthread locking functions are optional - but llvm will not be thread-safe
 712 dnl without locks.
 713 if test "$ENABLE_THREADS" -eq 1 ; then
 714   AC_CHECK_LIB(pthread,pthread_mutex_init)
 715   AC_SEARCH_LIBS(pthread_mutex_lock,pthread,
 716                  AC_DEFINE([HAVE_PTHREAD_MUTEX_LOCK],[1],
 717                            [Have pthread_mutex_lock]))
 718 fi
 719
 720 dnl Allow extra x86-disassembler library
 721 AC_ARG_WITH(udis86,
 722   AS_HELP_STRING([--with-udis86=<path>],
 723     [Use udis86 external x86 disassembler library]),
 724     [
 725       AC_SUBST(USE_UDIS86, [1])
 726       case "$withval" in
 727         /usr/lib|yes) ;;
 728         *) LDFLAGS="$LDFLAGS -L${withval}" ;;
 729       esac
 730       AC_CHECK_LIB(udis86, ud_init, [], [
 731         echo "Error! You need to have libudis86 around."
 732         exit -1
 733       ])
 734     ],
 735     AC_SUBST(USE_UDIS86, [0]))
 736 AC_DEFINE_UNQUOTED([USE_UDIS86],$USE_UDIS86,
 737                    [Define if use udis86 library])
 738
 739 dnl===-----------------------------------------------------------------------===
 740 dnl===
 741 dnl=== SECTION 6: Check for header files
 742 dnl===
 743 dnl===-----------------------------------------------------------------------===
 744
 745 dnl First, use autoconf provided macros for specific headers that we need
 746 dnl We don't check for ancient stuff or things that are guaranteed to be there
 747 dnl by the C++ standard. We always use the <cfoo> versions of <foo.h> C headers.
 748 dnl Generally we're looking for POSIX headers.
 749 AC_HEADER_DIRENT
 750 AC_HEADER_MMAP_ANONYMOUS
 751 AC_HEADER_STAT
 752 AC_HEADER_STDC
 753 AC_HEADER_SYS_WAIT
 754 AC_HEADER_TIME
 755
 756 AC_CHECK_HEADERS([dlfcn.h execinfo.h fcntl.h inttypes.h limits.h link.h])
 757 AC_CHECK_HEADERS([malloc.h setjmp.h signal.h stdint.h unistd.h utime.h])
 758 AC_CHECK_HEADERS([windows.h])
 759 AC_CHECK_HEADERS([sys/mman.h sys/param.h sys/resource.h sys/time.h])
 760 AC_CHECK_HEADERS([sys/types.h malloc/malloc.h mach/mach.h])
 761 if test "$ENABLE_THREADS" -eq 1 ; then
 762   AC_CHECK_HEADERS(pthread.h,
 763                   AC_SUBST(HAVE_PTHREAD, 1),
 764                    AC_SUBST(HAVE_PTHREAD, 0))
 765 else
 766   AC_SUBST(HAVE_PTHREAD, 0)
 767 fi
 768
 769 dnl===-----------------------------------------------------------------------===
 770 dnl===
 771 dnl=== SECTION 7: Check for types and structures
 772 dnl===
 773 dnl===-----------------------------------------------------------------------===
 774
 775 AC_HUGE_VAL_CHECK
 776 AC_TYPE_PID_T
 777 AC_TYPE_SIZE_T
 778 AC_TYPE_SIGNAL
 779 AC_STRUCT_TM
 780 AC_CHECK_TYPES([int64_t],,AC_MSG_ERROR([Type int64_t required but not found]))
 781 AC_CHECK_TYPES([uint64_t],,
 782          AC_CHECK_TYPES([u_int64_t],,
 783          AC_MSG_ERROR([Type uint64_t or u_int64_t required but not found])))
 784
 785 dnl===-----------------------------------------------------------------------===
 786 dnl===
 787 dnl=== SECTION 8: Check for specific functions needed
 788 dnl===
 789 dnl===-----------------------------------------------------------------------===
 790
 791 AC_CHECK_FUNCS([backtrace ceilf floorf roundf rintf nearbyintf getcwd ])
 792 AC_CHECK_FUNCS([powf fmodf strtof round ])
 793 AC_CHECK_FUNCS([getpagesize getrusage getrlimit setrlimit gettimeofday ])
 794 AC_CHECK_FUNCS([isatty mkdtemp mkstemp ])
 795 AC_CHECK_FUNCS([mktemp realpath sbrk setrlimit strdup strerror strerror_r ])
 796 AC_CHECK_FUNCS([strtoll strtoq sysconf malloc_zone_statistics ])
 797 AC_CHECK_FUNCS([setjmp longjmp sigsetjmp siglongjmp])
 798 AC_C_PRINTF_A
 799 AC_FUNC_ALLOCA
 800 AC_FUNC_RAND48
 801
 802 dnl Check for variations in the Standard C++ library and STL. These macros are
 803 dnl provided by LLVM in the autoconf/m4 directory.
 804 AC_CXX_HAVE_HASH_MAP
 805 AC_CXX_HAVE_HASH_SET
 806 AC_CXX_HAVE_STD_ITERATOR
 807 AC_CXX_HAVE_BI_ITERATOR
 808 AC_CXX_HAVE_FWD_ITERATOR
 809 AC_FUNC_ISNAN
 810 AC_FUNC_ISINF
 811
 812 dnl Check for mmap support.We also need to know if /dev/zero is required to
 813 dnl be opened for allocating RWX memory.
 814 dnl Make sure we aren't attempting to configure for an unknown system
 815 if test "$llvm_cv_platform_type" = "Unix" ; then
 816   AC_FUNC_MMAP
 817   AC_FUNC_MMAP_FILE
 818   AC_NEED_DEV_ZERO_FOR_MMAP
 819
 820   if test "$ac_cv_func_mmap_fixed_mapped" = "no"
 821   then
 822     AC_MSG_WARN([mmap() of a fixed address required but not supported])
 823   fi
 824   if test "$ac_cv_func_mmap_file" = "no"
 825   then
 826     AC_MSG_WARN([mmap() of files required but not found])
 827   fi
 828 fi
 829
 830 dnl===-----------------------------------------------------------------------===
 831 dnl===
 832 dnl=== SECTION 9: Additional checks, variables, etc.
 833 dnl===
 834 dnl===-----------------------------------------------------------------------===
 835
 836 dnl Check, whether __dso_handle is present
 837 AC_CHECK_FUNCS([__dso_handle])
 838
 839 dnl See if the llvm-gcc executable can compile to LLVM assembly
 840 AC_CACHE_CHECK([whether llvm-gcc is sane],[llvm_cv_llvmgcc_sanity],
 841 [llvm_cv_llvmgcc_sanity="no"
 842 if test -x "$LLVMGCC" ; then
 843   cp /dev/null conftest.c
 844   "$LLVMGCC" -emit-llvm -S -o - conftest.c | \
 845       grep 'target datalayout =' > /dev/null 2>&1
 846   if test $? -eq 0 ; then
 847     llvm_cv_llvmgcc_sanity="yes"
 848   fi
 849   rm conftest.c
 850 fi])
 851
 852 dnl Since we have a sane llvm-gcc, identify it and its sub-tools
 853 if test "$llvm_cv_llvmgcc_sanity" = "yes" ; then
 854   AC_MSG_CHECKING([llvm-gcc component support])
 855   llvmcc1path=`"$LLVMGCC" --print-prog-name=cc1`
 856   AC_SUBST(LLVMCC1,$llvmcc1path)
 857   llvmcc1pluspath=`"$LLVMGCC" --print-prog-name=cc1plus`
 858   AC_SUBST(LLVMCC1PLUS,$llvmcc1pluspath)
 859   llvmgccdir=`echo "$llvmcc1path" | sed 's,/libexec/.*,,'`
 860   AC_SUBST(LLVMGCCDIR,$llvmgccdir)
 861   llvmgcclibexec=`echo "$llvmcc1path" | sed 's,/cc1,,'`
 862   AC_SUBST(LLVMGCCLIBEXEC,$llvmgcclibexec)
 863   llvmgccversion=[`"$LLVMGCC" -dumpversion 2>&1 | sed 's/^\([0-9.]*\).*/\1/'`]
 864   llvmgccmajvers=[`echo $llvmgccversion | sed 's/^\([0-9]\).*/\1/'`]
 865   AC_SUBST(LLVMGCC_VERSION,$llvmgccversion)
 866   AC_SUBST(LLVMGCC_MAJVERS,$llvmgccmajvers)
 867   llvmgcclangs=[`"$LLVMGCC" -v --help 2>&1 | grep '^Configured with:' | sed 's/^.*--enable-languages=\([^ -]*\).*/\1/'`]
 868   AC_SUBST(LLVMGCC_LANGS,$llvmgcclangs)
 869   AC_MSG_RESULT([ok])
 870 fi
 871
 872 dnl Propagate the shared library extension that the libltdl checks did to
 873 dnl the Makefiles so we can use it there too
 874 AC_SUBST(SHLIBEXT,$libltdl_cv_shlibext)
 875
 876 # Translate the various configuration directories and other basic
 877 # information into substitutions that will end up in Makefile.config.in
 878 # that these configured values can be used by the makefiles
 879 if test "${prefix}" = "NONE" ; then
 880   prefix="/usr/local"
 881 fi
 882 eval LLVM_PREFIX="${prefix}";
 883 eval LLVM_BINDIR="${prefix}/bin";
 884 eval LLVM_LIBDIR="${prefix}/lib";
 885 eval LLVM_DATADIR="${prefix}/share/llvm";
 886 eval LLVM_DOCSDIR="${prefix}/docs/llvm";
 887 eval LLVM_ETCDIR="${prefix}/etc/llvm";
 888 eval LLVM_INCLUDEDIR="${prefix}/include";
 889 eval LLVM_INFODIR="${prefix}/info";
 890 eval LLVM_MANDIR="${prefix}/man";
 891 LLVM_CONFIGTIME=`date`
 892 AC_SUBST(LLVM_PREFIX)
 893 AC_SUBST(LLVM_BINDIR)
 894 AC_SUBST(LLVM_LIBDIR)
 895 AC_SUBST(LLVM_DATADIR)
 896 AC_SUBST(LLVM_DOCSDIR)
 897 AC_SUBST(LLVM_ETCDIR)
 898 AC_SUBST(LLVM_INCLUDEDIR)
 899 AC_SUBST(LLVM_INFODIR)
 900 AC_SUBST(LLVM_MANDIR)
 901 AC_SUBST(LLVM_CONFIGTIME)
 902
 903 # Place the various directores into the config.h file as #defines so that we
 904 # can know about the installation paths within LLVM.
 905 AC_DEFINE_UNQUOTED(LLVM_PREFIX,"$LLVM_PREFIX",
 906                    [Installation prefix directory])
 907 AC_DEFINE_UNQUOTED(LLVM_BINDIR, "$LLVM_BINDIR",
 908                    [Installation directory for binary executables])
 909 AC_DEFINE_UNQUOTED(LLVM_LIBDIR, "$LLVM_LIBDIR",
 910                    [Installation directory for libraries])
 911 AC_DEFINE_UNQUOTED(LLVM_DATADIR, "$LLVM_DATADIR",
 912                    [Installation directory for data files])
 913 AC_DEFINE_UNQUOTED(LLVM_DOCSDIR, "$LLVM_DOCSDIR",
 914                    [Installation directory for documentation])
 915 AC_DEFINE_UNQUOTED(LLVM_ETCDIR, "$LLVM_ETCDIR",
 916                    [Installation directory for config files])
 917 AC_DEFINE_UNQUOTED(LLVM_INCLUDEDIR, "$LLVM_INCLUDEDIR",
 918                    [Installation directory for include files])
 919 AC_DEFINE_UNQUOTED(LLVM_INFODIR, "$LLVM_INFODIR",
 920                    [Installation directory for .info files])
 921 AC_DEFINE_UNQUOTED(LLVM_MANDIR, "$LLVM_MANDIR",
 922                    [Installation directory for man pages])
 923 AC_DEFINE_UNQUOTED(LLVM_CONFIGTIME, "$LLVM_CONFIGTIME",
 924                    [Time at which LLVM was configured])
 925 AC_DEFINE_UNQUOTED(LLVM_HOSTTRIPLE, "$host",
 926                    [Host triple we were built on])
 927
 928 # Determine which bindings to build.
 929 if test "$BINDINGS_TO_BUILD" = auto ; then
 930   BINDINGS_TO_BUILD=""
 931   if test "x$OCAMLC" != x -a "x$OCAMLDEP" != x ; then
 932     BINDINGS_TO_BUILD="ocaml $BINDINGS_TO_BUILD"
 933   fi
 934 fi
 935 AC_SUBST(BINDINGS_TO_BUILD,$BINDINGS_TO_BUILD)
 936
 937 # This isn't really configurey, but it avoids having to repeat the list in
 938 # other files.
 939 AC_SUBST(ALL_BINDINGS,ocaml)
 940
 941 # Do any work necessary to ensure that bindings have what they need.
 942 binding_prereqs_failed=0
 943 for a_binding in $BINDINGS_TO_BUILD ; do
 944   case "$a_binding" in
 945   ocaml)
 946     if test "x$OCAMLC" = x ; then
 947       AC_MSG_WARN([--enable-bindings=ocaml specified, but ocamlc not found. Try configure OCAMLC=/path/to/ocamlc])
 948       binding_prereqs_failed=1
 949     fi
 950     if test "x$OCAMLDEP" = x ; then
 951       AC_MSG_WARN([--enable-bindings=ocaml specified, but ocamldep not found. Try configure OCAMLDEP=/path/to/ocamldep])
 952       binding_prereqs_failed=1
 953     fi
 954     if test "x$OCAMLOPT" = x ; then
 955       AC_MSG_WARN([--enable-bindings=ocaml specified, but ocamlopt not found. Try configure OCAMLOPT=/path/to/ocamlopt])
 956       dnl ocamlopt is optional!
 957     fi
 958     if test "x$with_ocaml_libdir" != xauto ; then
 959       AC_SUBST(OCAML_LIBDIR,$with_ocaml_libdir)
 960     else
 961       ocaml_stdlib="`"$OCAMLC" -where`"
 962       if test "$LLVM_PREFIX" '<' "$ocaml_stdlib" -a "$ocaml_stdlib" '<' "$LLVM_PREFIX~"
 963       then
 964         # ocaml stdlib is beneath our prefix; use stdlib
 965         AC_SUBST(OCAML_LIBDIR,$ocaml_stdlib)
 966       else
 967         # ocaml stdlib is outside our prefix; use libdir/ocaml
 968         AC_SUBST(OCAML_LIBDIR,$LLVM_LIBDIR/ocaml)
 969       fi
 970     fi
 971     ;;
 972   esac
 973 done
 974 if test "$binding_prereqs_failed" = 1 ; then
 975   AC_MSG_ERROR([Prequisites for bindings not satisfied. Fix them or use configure --disable-bindings.])
 976 fi
 977
 978 dnl Determine if the compiler supports -fvisibility-inlines-hidden.
 979 AC_CXX_USE_VISIBILITY_INLINES_HIDDEN
 980
 981 dnl===-----------------------------------------------------------------------===
 982 dnl===
 983 dnl=== SECTION 10: Specify the output files and generate it
 984 dnl===
 985 dnl===-----------------------------------------------------------------------===
 986
 987 dnl Configure header files
 988 dnl WARNING: dnl If you add or remove any of the following config headers, then
 989 dnl you MUST also update Makefile.rules so that the variable FilesToConfig
 990 dnl contains the same list of files as AC_CONFIG_HEADERS below. This ensures the
 991 dnl files can be updated automatically when their *.in sources change.
 992 AC_CONFIG_HEADERS([include/llvm/Config/config.h])
 993 AC_CONFIG_HEADERS([include/llvm/Support/DataTypes.h])
 994 AC_CONFIG_HEADERS([include/llvm/ADT/hash_map.h])
 995 AC_CONFIG_HEADERS([include/llvm/ADT/hash_set.h])
 996 AC_CONFIG_HEADERS([include/llvm/ADT/iterator.h])
 997
 998 dnl Configure the makefile's configuration data
 999 AC_CONFIG_FILES([Makefile.config])
1000
1001 dnl Configure the RPM spec file for LLVM
1002 AC_CONFIG_FILES([llvm.spec])
1003
1004 dnl Configure doxygen's configuration file
1005 AC_CONFIG_FILES([docs/doxygen.cfg])
1006
1007 dnl Do the first stage of configuration for llvm-config.in.
1008 AC_CONFIG_FILES([tools/llvm-config/llvm-config.in])
1009
1010 dnl Do special configuration of Makefiles
1011 AC_CONFIG_COMMANDS([setup],,[llvm_src="${srcdir}"])
1012 AC_CONFIG_MAKEFILE(Makefile)
1013 AC_CONFIG_MAKEFILE(Makefile.common)
1014 AC_CONFIG_MAKEFILE(examples/Makefile)
1015 AC_CONFIG_MAKEFILE(lib/Makefile)
1016 AC_CONFIG_MAKEFILE(runtime/Makefile)
1017 AC_CONFIG_MAKEFILE(test/Makefile)
1018 AC_CONFIG_MAKEFILE(test/Makefile.tests)
1019 AC_CONFIG_MAKEFILE(tools/Makefile)
1020 AC_CONFIG_MAKEFILE(utils/Makefile)
1021 AC_CONFIG_MAKEFILE(projects/Makefile)
1022 AC_CONFIG_MAKEFILE(bindings/Makefile)
1023 AC_CONFIG_MAKEFILE(bindings/ocaml/Makefile.ocaml)
1024
1025 dnl Finally, crank out the output
1026 AC_OUTPUT