autoconf/configure.ac

   1 dnl === configure.ac --------------------------------------------------------===
   2 dnl                     The LLVM Compiler Infrastructure
   3 dnl
   4 dnl This file is distributed under the University of Illinois Open Source
   5 dnl License. See LICENSE.TXT for details.
   6 dnl
   7 dnl===-----------------------------------------------------------------------===
   8 dnl This is the LLVM configuration script. It is processed by the autoconf
   9 dnl program to produce a script named configure. This script contains the
  10 dnl configuration checks that LLVM needs in order to support multiple platforms.
  11 dnl This file is composed of 10 sections per the recommended organization of
  12 dnl autoconf input defined in the autoconf documentation. As this file evolves,
  13 dnl please keep the various types of checks within their sections. The sections
  14 dnl are as follows:
  15 dnl
  16 dnl SECTION 1: Initialization & Setup
  17 dnl SECTION 2: Architecture, target, and host checks
  18 dnl SECTION 3: Command line arguments for the configure script.
  19 dnl SECTION 4: Check for programs we need and that they are the right version
  20 dnl SECTION 5: Check for libraries
  21 dnl SECTION 6: Check for header files
  22 dnl SECTION 7: Check for types and structures
  23 dnl SECTION 8: Check for specific functions needed
  24 dnl SECTION 9: Additional checks, variables, etc.
  25 dnl SECTION 10: Specify the output files and generate it
  26 dnl
  27 dnl===-----------------------------------------------------------------------===
  28 dnl===
  29 dnl=== SECTION 1: Initialization & Setup
  30 dnl===
  31 dnl===-----------------------------------------------------------------------===
  32 dnl Initialize autoconf and define the package name, version number and
  33 dnl address for reporting bugs.
  34
  35 AC_INIT([LLVM],[3.7.0svn],[http://llvm.org/bugs/])
  36
  37 LLVM_VERSION_MAJOR=3
  38 LLVM_VERSION_MINOR=7
  39 LLVM_VERSION_PATCH=0
  40 LLVM_VERSION_SUFFIX=svn
  41
  42 AC_DEFINE_UNQUOTED([LLVM_VERSION_MAJOR], $LLVM_VERSION_MAJOR, [Major version of the LLVM API])
  43 AC_DEFINE_UNQUOTED([LLVM_VERSION_MINOR], $LLVM_VERSION_MINOR, [Minor version of the LLVM API])
  44 AC_DEFINE_UNQUOTED([LLVM_VERSION_PATCH], $LLVM_VERSION_PATCH, [Patch version of the LLVM API])
  45 AC_DEFINE_UNQUOTED([LLVM_VERSION_STRING], "$PACKAGE_VERSION", [LLVM version string])
  46
  47 AC_SUBST([LLVM_VERSION_MAJOR])
  48 AC_SUBST([LLVM_VERSION_MINOR])
  49 AC_SUBST([LLVM_VERSION_PATCH])
  50 AC_SUBST([LLVM_VERSION_SUFFIX])
  51
  52 dnl Provide a copyright substitution and ensure the copyright notice is included
  53 dnl in the output of --version option of the generated configure script.
  54 AC_SUBST(LLVM_COPYRIGHT,["Copyright (c) 2003-2014 University of Illinois at Urbana-Champaign."])
  55 AC_COPYRIGHT([Copyright (c) 2003-2014 University of Illinois at Urbana-Champaign.])
  56
  57 dnl Indicate that we require autoconf 2.60 or later.
  58 AC_PREREQ(2.60)
  59
  60 dnl Verify that the source directory is valid. This makes sure that we are
  61 dnl configuring LLVM and not some other package (it validates --srcdir argument)
  62 AC_CONFIG_SRCDIR([lib/IR/Module.cpp])
  63
  64 dnl Place all of the extra autoconf files into the config subdirectory. Tell
  65 dnl various tools where the m4 autoconf macros are.
  66 AC_CONFIG_AUX_DIR([autoconf])
  67
  68 dnl Quit if the source directory has already been configured.
  69 dnl NOTE: This relies upon undocumented autoconf behavior.
  70 if test ${srcdir} != "." ; then
  71   if test -f ${srcdir}/include/llvm/Config/config.h ; then
  72     AC_MSG_ERROR([Already configured in ${srcdir}])
  73   fi
  74 fi
  75
  76 dnl Default to empty (i.e. assigning the null string to) CFLAGS and CXXFLAGS,
  77 dnl instead of the autoconf default (for example, '-g -O2' for CC=gcc).
  78 : ${CFLAGS=}
  79 : ${CXXFLAGS=}
  80
  81 dnl We need to check for the compiler up here to avoid anything else
  82 dnl starting with a different one.
  83 AC_PROG_CC(clang gcc)
  84 AC_PROG_CXX(clang++ g++)
  85 AC_PROG_CPP
  86
  87 dnl If CXX is Clang, check that it can find and parse C++ standard library
  88 dnl headers.
  89 if test "$CXX" = "clang++" ; then
  90   AC_MSG_CHECKING([whether clang works])
  91   AC_LANG_PUSH([C++])
  92   dnl Note that space between 'include' and '(' is required.  There's a broken
  93   dnl regex in aclocal that otherwise will think that we call m4's include
  94   dnl builtin.
  95   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <limits>
  96 #if __has_include (<cxxabi.h>)
  97 #include <cxxabi.h>
  98 #endif
  99 #if __has_include (<unwind.h>)
 100 #include <unwind.h>
 101 #endif
 102 ]])],
 103 [
 104   AC_MSG_RESULT([yes])
 105 ],
 106 [
 107   AC_MSG_RESULT([no])
 108   AC_MSG_ERROR([Selected compiler could not find or parse C++ standard library headers.  Rerun with CC=c-compiler CXX=c++-compiler ./configure ...])
 109 ])
 110   AC_LANG_POP([C++])
 111 fi
 112
 113 dnl Set up variables that track whether the host compiler is GCC or Clang where
 114 dnl we can effectively sanity check them. We don't try to sanity check all the
 115 dnl other possible compilers.
 116 AC_MSG_CHECKING([whether GCC or Clang is our host compiler])
 117 AC_LANG_PUSH([C++])
 118 llvm_cv_cxx_compiler=unknown
 119 AC_COMPILE_IFELSE([AC_LANG_SOURCE([[#if ! __clang__
 120                                     #error
 121                                     #endif
 122                                     ]])],
 123                   llvm_cv_cxx_compiler=clang,
 124                   [AC_COMPILE_IFELSE([AC_LANG_SOURCE([[#if ! __GNUC__
 125                                                        #error
 126                                                        #endif
 127                                                        ]])],
 128                                      llvm_cv_cxx_compiler=gcc, [])])
 129 AC_LANG_POP([C++])
 130 AC_MSG_RESULT([${llvm_cv_cxx_compiler}])
 131
 132 dnl Configure all of the projects present in our source tree. While we could
 133 dnl just AC_CONFIG_SUBDIRS on the set of directories in projects that have a
 134 dnl configure script, that usage of the AC_CONFIG_SUBDIRS macro is deprecated.
 135 dnl Instead we match on the known projects.
 136
 137 dnl
 138 dnl One tricky part of doing this is that some projects depend upon other
 139 dnl projects.  For example, several projects rely upon the LLVM test suite.
 140 dnl We want to configure those projects first so that their object trees are
 141 dnl created before running the configure scripts of projects that depend upon
 142 dnl them.
 143 dnl
 144
 145 dnl Several projects use the LLVM test suite, so configure it next.
 146 if test -d ${srcdir}/projects/test-suite ; then
 147   AC_CONFIG_SUBDIRS([projects/test-suite])
 148 fi
 149
 150 dnl llvm-test is the old name of the test-suite, kept here for backwards
 151 dnl compatibility
 152 if test -d ${srcdir}/projects/llvm-test ; then
 153   AC_CONFIG_SUBDIRS([projects/llvm-test])
 154 fi
 155
 156 dnl Some projects use poolalloc; configure that next
 157 if test -d ${srcdir}/projects/poolalloc ; then
 158   AC_CONFIG_SUBDIRS([projects/poolalloc])
 159 fi
 160
 161 if test -d ${srcdir}/projects/llvm-poolalloc ; then
 162   AC_CONFIG_SUBDIRS([projects/llvm-poolalloc])
 163 fi
 164
 165 dnl Check for all other projects
 166 for i in `ls ${srcdir}/projects`
 167 do
 168   if test -d ${srcdir}/projects/${i} ; then
 169     case ${i} in
 170       safecode)     AC_CONFIG_SUBDIRS([projects/safecode]) ;;
 171       compiler-rt)       ;;
 172       test-suite)     ;;
 173       llvm-test)      ;;
 174       poolalloc)      ;;
 175       llvm-poolalloc) ;;
 176       *)
 177         AC_MSG_WARN([Unknown project (${i}) won't be configured automatically])
 178         ;;
 179     esac
 180   fi
 181 done
 182
 183 dnl Disable the build of polly, even if it is checked out into tools/polly.
 184 AC_ARG_ENABLE(polly,
 185               AS_HELP_STRING([--enable-polly],
 186                              [Use polly if available (default is YES)]),,
 187                              enableval=default)
 188 case "$enableval" in
 189   yes) AC_SUBST(ENABLE_POLLY,[1]) ;;
 190   no)  AC_SUBST(ENABLE_POLLY,[0]) ;;
 191   default) AC_SUBST(ENABLE_POLLY,[1]) ;;
 192   *) AC_MSG_ERROR([Invalid setting for --enable-polly. Use "yes" or "no"]) ;;
 193 esac
 194
 195
 196 dnl Check if polly is checked out into tools/polly and configure it if
 197 dnl available.
 198 if (test -d ${srcdir}/tools/polly) && (test $ENABLE_POLLY -eq 1) ; then
 199   AC_SUBST(LLVM_HAS_POLLY,1)
 200   AC_CONFIG_SUBDIRS([tools/polly])
 201 fi
 202
 203 dnl===-----------------------------------------------------------------------===
 204 dnl===
 205 dnl=== SECTION 2: Architecture, target, and host checks
 206 dnl===
 207 dnl===-----------------------------------------------------------------------===
 208
 209 dnl Check the target for which we're compiling and the host that will do the
 210 dnl compilations. This will tell us which LLVM compiler will be used for
 211 dnl compiling SSA into object code. This needs to be done early because
 212 dnl following tests depend on it.
 213 AC_CANONICAL_TARGET
 214
 215 dnl Determine the platform type and cache its value. This helps us configure
 216 dnl the System library to the correct build platform.
 217 AC_CACHE_CHECK([type of operating system we're going to host on],
 218                [llvm_cv_os_type],
 219 [case $host in
 220   *-*-aix*)
 221     llvm_cv_link_all_option="-Wl,--whole-archive"
 222     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 223     llvm_cv_os_type="AIX"
 224     llvm_cv_platform_type="Unix" ;;
 225   *-*-irix*)
 226     llvm_cv_link_all_option="-Wl,--whole-archive"
 227     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 228     llvm_cv_os_type="IRIX"
 229     llvm_cv_platform_type="Unix" ;;
 230   *-*-cygwin*)
 231     llvm_cv_link_all_option="-Wl,--whole-archive"
 232     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 233     llvm_cv_os_type="Cygwin"
 234     llvm_cv_platform_type="Unix" ;;
 235   *-*-darwin*)
 236     llvm_cv_link_all_option="-Wl,-all_load"
 237     llvm_cv_no_link_all_option="-Wl,-noall_load"
 238     llvm_cv_os_type="Darwin"
 239     llvm_cv_platform_type="Unix" ;;
 240   *-*-minix*)
 241     llvm_cv_link_all_option="-Wl,-all_load"
 242     llvm_cv_no_link_all_option="-Wl,-noall_load"
 243     llvm_cv_os_type="Minix"
 244     llvm_cv_platform_type="Unix" ;;
 245   *-*-freebsd*)
 246     llvm_cv_link_all_option="-Wl,--whole-archive"
 247     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 248     llvm_cv_os_type="FreeBSD"
 249     llvm_cv_platform_type="Unix" ;;
 250   *-*-kfreebsd-gnu)
 251     llvm_cv_link_all_option="-Wl,--whole-archive"
 252     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 253     llvm_cv_os_type="GNU/kFreeBSD"
 254     llvm_cv_platform_type="Unix" ;;
 255   *-*-openbsd*)
 256     llvm_cv_link_all_option="-Wl,--whole-archive"
 257     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 258     llvm_cv_os_type="OpenBSD"
 259     llvm_cv_platform_type="Unix" ;;
 260   *-*-netbsd*)
 261     llvm_cv_link_all_option="-Wl,--whole-archive"
 262     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 263     llvm_cv_os_type="NetBSD"
 264     llvm_cv_platform_type="Unix" ;;
 265   *-*-dragonfly*)
 266     llvm_cv_link_all_option="-Wl,--whole-archive"
 267     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 268     llvm_cv_os_type="DragonFly"
 269     llvm_cv_platform_type="Unix" ;;
 270   *-*-hpux*)
 271     llvm_cv_link_all_option="-Wl,--whole-archive"
 272     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 273     llvm_cv_os_type="HP-UX"
 274     llvm_cv_platform_type="Unix" ;;
 275   *-*-interix*)
 276     llvm_cv_link_all_option="-Wl,--whole-archive"
 277     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 278     llvm_cv_os_type="Interix"
 279     llvm_cv_platform_type="Unix" ;;
 280   *-*-linux*)
 281     llvm_cv_link_all_option="-Wl,--whole-archive"
 282     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 283     llvm_cv_os_type="Linux"
 284     llvm_cv_platform_type="Unix" ;;
 285   *-*-gnu*)
 286     llvm_cv_link_all_option="-Wl,--whole-archive"
 287     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 288     llvm_cv_os_type="GNU"
 289     llvm_cv_platform_type="Unix" ;;
 290   *-*-solaris*)
 291     llvm_cv_link_all_option="-Wl,-z,allextract"
 292     llvm_cv_no_link_all_option="-Wl,-z,defaultextract"
 293     llvm_cv_os_type="SunOS"
 294     llvm_cv_platform_type="Unix" ;;
 295   *-*-win32*)
 296     llvm_cv_link_all_option="-Wl,--whole-archive"
 297     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 298     llvm_cv_os_type="Win32"
 299     llvm_cv_platform_type="Win32" ;;
 300   *-*-mingw*)
 301     llvm_cv_link_all_option="-Wl,--whole-archive"
 302     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 303     llvm_cv_os_type="MingW"
 304     llvm_cv_platform_type="Win32" ;;
 305   *-*-haiku*)
 306     llvm_cv_link_all_option="-Wl,--whole-archive"
 307     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 308     llvm_cv_os_type="Haiku"
 309     llvm_cv_platform_type="Unix" ;;
 310   *-unknown-eabi*)
 311     llvm_cv_link_all_option="-Wl,--whole-archive"
 312     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 313     llvm_cv_os_type="Freestanding"
 314     llvm_cv_platform_type="Unix" ;;
 315   *-unknown-elf*)
 316     llvm_cv_link_all_option="-Wl,--whole-archive"
 317     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 318     llvm_cv_os_type="Freestanding"
 319     llvm_cv_platform_type="Unix" ;;
 320   *)
 321     llvm_cv_link_all_option=""
 322     llvm_cv_no_link_all_option=""
 323     llvm_cv_os_type="Unknown"
 324     llvm_cv_platform_type="Unknown" ;;
 325 esac])
 326
 327 AC_CACHE_CHECK([type of operating system we're going to target],
 328                [llvm_cv_target_os_type],
 329 [case $target in
 330   *-*-aix*)
 331     llvm_cv_target_os_type="AIX" ;;
 332   *-*-irix*)
 333     llvm_cv_target_os_type="IRIX" ;;
 334   *-*-cygwin*)
 335     llvm_cv_target_os_type="Cygwin" ;;
 336   *-*-darwin*)
 337     llvm_cv_target_os_type="Darwin" ;;
 338   *-*-minix*)
 339     llvm_cv_target_os_type="Minix" ;;
 340   *-*-freebsd*)
 341     llvm_cv_target_os_type="FreeBSD" ;;
 342   *-*-kfreebsd-gnu)
 343     llvm_cv_target_os_type="GNU/kFreeBSD" ;;
 344   *-*-openbsd*)
 345     llvm_cv_target_os_type="OpenBSD" ;;
 346   *-*-netbsd*)
 347     llvm_cv_target_os_type="NetBSD" ;;
 348   *-*-dragonfly*)
 349     llvm_cv_target_os_type="DragonFly" ;;
 350   *-*-hpux*)
 351     llvm_cv_target_os_type="HP-UX" ;;
 352   *-*-interix*)
 353     llvm_cv_target_os_type="Interix" ;;
 354   *-*-linux*)
 355     llvm_cv_target_os_type="Linux" ;;
 356   *-*-gnu*)
 357     llvm_cv_target_os_type="GNU" ;;
 358   *-*-solaris*)
 359     llvm_cv_target_os_type="SunOS" ;;
 360   *-*-win32*)
 361     llvm_cv_target_os_type="Win32" ;;
 362   *-*-mingw*)
 363     llvm_cv_target_os_type="MingW" ;;
 364   *-*-haiku*)
 365     llvm_cv_target_os_type="Haiku" ;;
 366   *-*-rtems*)
 367     llvm_cv_target_os_type="RTEMS" ;;
 368   *-*-nacl*)
 369     llvm_cv_target_os_type="NativeClient" ;;
 370   *-unknown-eabi*)
 371     llvm_cv_target_os_type="Freestanding" ;;
 372   *-*-ps4)
 373     llvm_cv_target_os_type="PS4" ;;
 374   *)
 375     llvm_cv_target_os_type="Unknown" ;;
 376 esac])
 377
 378 dnl Make sure we aren't attempting to configure for an unknown system
 379 if test "$llvm_cv_os_type" = "Unknown" ; then
 380   AC_MSG_ERROR([Operating system is unknown, configure can't continue])
 381 fi
 382
 383 dnl Set the "OS" Makefile variable based on the platform type so the
 384 dnl makefile can configure itself to specific build hosts
 385 AC_SUBST(OS,$llvm_cv_os_type)
 386 AC_SUBST(HOST_OS,$llvm_cv_os_type)
 387 AC_SUBST(TARGET_OS,$llvm_cv_target_os_type)
 388
 389 dnl Set the LINKALL and NOLINKALL Makefile variables based on the platform
 390 AC_SUBST(LINKALL,$llvm_cv_link_all_option)
 391 AC_SUBST(NOLINKALL,$llvm_cv_no_link_all_option)
 392
 393 dnl Set the "LLVM_ON_*" variables based on llvm_cv_platform_type
 394 dnl This is used by lib/Support to determine the basic kind of implementation
 395 dnl to use.
 396 case $llvm_cv_platform_type in
 397   Unix)
 398     AC_DEFINE([LLVM_ON_UNIX],[1],[Define if this is Unixish platform])
 399     AC_SUBST(LLVM_ON_UNIX,[1])
 400     AC_SUBST(LLVM_ON_WIN32,[0])
 401     ;;
 402   Win32)
 403     AC_DEFINE([LLVM_ON_WIN32],[1],[Define if this is Win32ish platform])
 404     AC_SUBST(LLVM_ON_UNIX,[0])
 405     AC_SUBST(LLVM_ON_WIN32,[1])
 406     ;;
 407 esac
 408
 409 dnl Determine what our target architecture is and configure accordingly.
 410 dnl This will allow Makefiles to make a distinction between the hardware and
 411 dnl the OS.
 412 AC_CACHE_CHECK([target architecture],[llvm_cv_target_arch],
 413 [case $target in
 414   i?86-*)                 llvm_cv_target_arch="x86" ;;
 415   amd64-* | x86_64-*)     llvm_cv_target_arch="x86_64" ;;
 416   sparc*-*)               llvm_cv_target_arch="Sparc" ;;
 417   powerpc*-*)             llvm_cv_target_arch="PowerPC" ;;
 418   arm64*-*)               llvm_cv_target_arch="AArch64" ;;
 419   arm*-*)                 llvm_cv_target_arch="ARM" ;;
 420   aarch64*-*)             llvm_cv_target_arch="AArch64" ;;
 421   mips-* | mips64-*)      llvm_cv_target_arch="Mips" ;;
 422   mipsel-* | mips64el-*)  llvm_cv_target_arch="Mips" ;;
 423   xcore-*)                llvm_cv_target_arch="XCore" ;;
 424   msp430-*)               llvm_cv_target_arch="MSP430" ;;
 425   hexagon-*)              llvm_cv_target_arch="Hexagon" ;;
 426   nvptx-*)                llvm_cv_target_arch="NVPTX" ;;
 427   s390x-*)                llvm_cv_target_arch="SystemZ" ;;
 428   *)                      llvm_cv_target_arch="Unknown" ;;
 429 esac])
 430
 431 if test "$llvm_cv_target_arch" = "Unknown" ; then
 432   AC_MSG_WARN([Configuring LLVM for an unknown target archicture])
 433 fi
 434
 435 dnl Determine the LLVM native architecture for the target
 436 case "$llvm_cv_target_arch" in
 437     x86)     LLVM_NATIVE_ARCH="X86" ;;
 438     x86_64)  LLVM_NATIVE_ARCH="X86" ;;
 439     *)       LLVM_NATIVE_ARCH="$llvm_cv_target_arch" ;;
 440 esac
 441
 442 dnl Define a substitution, ARCH, for the target architecture
 443 AC_SUBST(ARCH,$llvm_cv_target_arch)
 444 AC_SUBST(LLVM_NATIVE_ARCH,$LLVM_NATIVE_ARCH)
 445
 446 dnl Determine what our host architecture.
 447 dnl This will allow MCJIT regress tests runs only for supported
 448 dnl platforms.
 449 case $host in
 450   i?86-*)                 host_arch="x86" ;;
 451   amd64-* | x86_64-*)     host_arch="x86_64" ;;
 452   sparc*-*)               host_arch="Sparc" ;;
 453   powerpc*-*)             host_arch="PowerPC" ;;
 454   arm64*-*)               host_arch="AArch64" ;;
 455   arm*-*)                 host_arch="ARM" ;;
 456   aarch64*-*)             host_arch="AArch64" ;;
 457   mips-* | mips64-*)      host_arch="Mips" ;;
 458   mipsel-* | mips64el-*)  host_arch="Mips" ;;
 459   xcore-*)                host_arch="XCore" ;;
 460   msp430-*)               host_arch="MSP430" ;;
 461   hexagon-*)              host_arch="Hexagon" ;;
 462   s390x-*)                host_arch="SystemZ" ;;
 463   *)                      host_arch="Unknown" ;;
 464 esac
 465
 466 if test "$host_arch" = "Unknown" ; then
 467   AC_MSG_WARN([Configuring LLVM for an unknown host archicture])
 468 fi
 469
 470 AC_SUBST(HOST_ARCH,$host_arch)
 471
 472 dnl Check for build platform executable suffix if we're cross-compiling
 473 if test "$cross_compiling" = yes; then
 474   AC_SUBST(LLVM_CROSS_COMPILING, [1])
 475   AC_BUILD_EXEEXT
 476   ac_build_prefix=${build_alias}-
 477   AC_CHECK_PROG(BUILD_CXX, ${ac_build_prefix}g++, ${ac_build_prefix}g++)
 478   if test -z "$BUILD_CXX"; then
 479      AC_CHECK_PROG(BUILD_CXX, g++, g++)
 480      if test -z "$BUILD_CXX"; then
 481        AC_CHECK_PROG(BUILD_CXX, c++, c++, , , /usr/ucb/c++)
 482      fi
 483   fi
 484 else
 485   AC_SUBST(LLVM_CROSS_COMPILING, [0])
 486 fi
 487
 488 dnl Check to see if there's a .svn or .git directory indicating that this
 489 dnl build is being done from a checkout. This sets up several defaults for
 490 dnl the command line switches. When we build with a checkout directory,
 491 dnl we get a debug with assertions turned on. Without, we assume a source
 492 dnl release and we get an optimized build without assertions.
 493 dnl See --enable-optimized and --enable-assertions below
 494 if test -d ".svn" -o -d "${srcdir}/.svn" -o -d ".git" -o -d "${srcdir}/.git"; then
 495   cvsbuild="yes"
 496   optimize="no"
 497   AC_SUBST(CVSBUILD,[[CVSBUILD=1]])
 498 else
 499   cvsbuild="no"
 500   optimize="yes"
 501 fi
 502
 503 dnl===-----------------------------------------------------------------------===
 504 dnl===
 505 dnl=== SECTION 3: Command line arguments for the configure script.
 506 dnl===
 507 dnl===-----------------------------------------------------------------------===
 508
 509 dnl --enable-libcpp : check whether or not to use libc++ on the command line
 510 AC_ARG_ENABLE(libcpp,
 511               AS_HELP_STRING([--enable-libcpp],
 512                              [Use libc++ if available (default is NO)]),,
 513                              enableval=default)
 514 case "$enableval" in
 515   yes) AC_SUBST(ENABLE_LIBCPP,[1]) ;;
 516   no)  AC_SUBST(ENABLE_LIBCPP,[0]) ;;
 517   default) AC_SUBST(ENABLE_LIBCPP,[0]);;
 518   *) AC_MSG_ERROR([Invalid setting for --enable-libcpp. Use "yes" or "no"]) ;;
 519 esac
 520
 521 dnl Check both GCC and Clang for sufficiently modern versions. These checks can
 522 dnl be bypassed by passing a flag if necessary on a platform. We have to do
 523 dnl these checks here so that we have the configuration of the standard C++
 524 dnl library finished.
 525 AC_ARG_ENABLE(compiler-version-checks,
 526               AS_HELP_STRING([--enable-compiler-version-checks],
 527                              [Check the version of the host compiler (default is YES)]),,
 528                              enableval=default)
 529 case "$enableval" in
 530   no)
 531     ;;
 532   yes|default)
 533     AC_LANG_PUSH([C++])
 534     case "$llvm_cv_cxx_compiler" in
 535     clang)
 536       AC_MSG_CHECKING([whether Clang is new enough])
 537       AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 538 #if __clang_major__ < 3 || (__clang_major__ == 3 && __clang_minor__ < 1)
 539 #error This version of Clang is too old to build LLVM
 540 #endif
 541 ]])],
 542           [AC_MSG_RESULT([yes])],
 543           [AC_MSG_RESULT([no])
 544            AC_MSG_ERROR([
 545 The selected Clang compiler is not new enough to build LLVM. Please upgrade to
 546 Clang 3.1. You may pass --disable-compiler-version-checks to configure to
 547 bypass these sanity checks.])])
 548
 549       dnl Note that libstdc++4.6 is known broken for C++11 builds. The errors
 550       dnl are sometimes deeply confusing though. Here we test for an obvious
 551       dnl incomplete feature in 4.6's standard library that was completed in
 552       dnl 4.7's. We also have to disable this test if 'ENABLE_LIBCPP' is set
 553       dnl because the enable flags don't actually fix CXXFLAGS, they rely on
 554       dnl that happening in the Makefile.
 555       if test "$ENABLE_LIBCPP" -eq 0 ; then
 556         AC_MSG_CHECKING([whether Clang will select a modern C++ standard library])
 557         llvm_cv_old_cxxflags="$CXXFLAGS"
 558         CXXFLAGS="$CXXFLAGS -std=c++0x"
 559         AC_LINK_IFELSE([AC_LANG_SOURCE([[
 560 #include <atomic>
 561 std::atomic<float> x(0.0f);
 562 int main() { return (float)x; }
 563 ]])],
 564             [AC_MSG_RESULT([yes])],
 565             [AC_MSG_RESULT([no])
 566              AC_MSG_ERROR([
 567 We detected a missing feature in the standard C++ library that was known to be
 568 missing in libstdc++4.6 and implemented in libstdc++4.7. There are numerous
 569 C++11 problems with 4.6's library, and we don't support GCCs or libstdc++ older
 570 than 4.7. You will need to update your system and ensure Clang uses the newer
 571 standard library.
 572
 573 If this error is incorrect or you need to force things to work, you may pass
 574 '--disable-compiler-version-checks' to configure to bypass this test.])])
 575         CXXFLAGS="$llvm_cv_old_cxxflags"
 576       fi
 577       ;;
 578     gcc)
 579       AC_MSG_CHECKING([whether GCC is new enough])
 580       AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 581 #if __GNUC__ < 4 || (__GNUC__ == 4 && __GNUC_MINOR__ < 7)
 582 #error This version of GCC is too old to build LLVM
 583 #endif
 584 ]])],
 585           [AC_MSG_RESULT([yes])],
 586           [AC_MSG_RESULT([no])
 587            AC_MSG_ERROR([
 588 The selected GCC C++ compiler is not new enough to build LLVM. Please upgrade
 589 to GCC 4.7. You may pass --disable-compiler-version-checks to configure to
 590 bypass these sanity checks.])])
 591       ;;
 592     unknown)
 593       ;;
 594     esac
 595     AC_LANG_POP([C++])
 596     ;;
 597   *)
 598     AC_MSG_ERROR([Invalid setting for --enable-compiler-version-checks. Use "yes" or "no"])
 599     ;;
 600 esac
 601
 602 dnl --enable-cxx1y : check whether or not to use -std=c++1y on the command line
 603 AC_ARG_ENABLE(cxx1y,
 604               AS_HELP_STRING([--enable-cxx1y],
 605                              [Use c++1y if available (default is NO)]),,
 606                              enableval=default)
 607 case "$enableval" in
 608   yes) AC_SUBST(ENABLE_CXX1Y,[1]) ;;
 609   no)  AC_SUBST(ENABLE_CXX1Y,[0]) ;;
 610   default) AC_SUBST(ENABLE_CXX1Y,[0]);;
 611   *) AC_MSG_ERROR([Invalid setting for --enable-cxx1y. Use "yes" or "no"]) ;;
 612 esac
 613
 614 dnl --enable-split-dwarf : check whether or not to use -gsplit-dwarf on the command
 615 dnl line
 616 AC_ARG_ENABLE(split-dwarf,
 617               AS_HELP_STRING([--enable-split-dwarf],
 618                              [Use split-dwarf if available (default is NO)]),,
 619                              enableval=default)
 620 case "$enableval" in
 621   yes) AC_SUBST(ENABLE_SPLIT_DWARF,[1]) ;;
 622   no)  AC_SUBST(ENABLE_SPLIT_DWARF,[0]) ;;
 623   default) AC_SUBST(ENABLE_SPLIT_DWARF,[0]);;
 624   *) AC_MSG_ERROR([Invalid setting for --enable-split-dwarf. Use "yes" or "no"]) ;;
 625 esac
 626
 627 dnl --enable-clang-arcmt: check whether to enable clang arcmt
 628 clang_arcmt="yes"
 629 AC_ARG_ENABLE(clang-arcmt,
 630               AS_HELP_STRING([--enable-clang-arcmt],
 631                              [Enable building of clang ARCMT (default is YES)]),
 632                              clang_arcmt="$enableval",
 633                              enableval="yes")
 634 case "$enableval" in
 635   yes) AC_SUBST(ENABLE_CLANG_ARCMT,[1]) ;;
 636   no)  AC_SUBST(ENABLE_CLANG_ARCMT,[0]) ;;
 637   default) AC_SUBST(ENABLE_CLANG_ARCMT,[1]);;
 638   *) AC_MSG_ERROR([Invalid setting for --enable-clang-arcmt. Use "yes" or "no"]) ;;
 639 esac
 640
 641 dnl --enable-clang-plugin-support: check whether to enable plugins in clang
 642 clang_plugin_support="yes"
 643 AC_ARG_ENABLE(clang-plugin-support,
 644               AS_HELP_STRING([--enable-clang-plugin-support],
 645                              [Enable plugin support in clang (default is YES)]),
 646                              clang_plugin_support="$enableval",
 647                              enableval="yes")
 648 case "$enableval" in
 649   yes) AC_SUBST(CLANG_PLUGIN_SUPPORT,[1]) ;;
 650   no)  AC_SUBST(CLANG_PLUGIN_SUPPORT,[0]) ;;
 651   default) AC_SUBST(CLANG_PLUGIN_SUPPORT,[1]);;
 652   *) AC_MSG_ERROR([Invalid setting for --enable-clang-plugin-support. Use "yes" or "no"]) ;;
 653 esac
 654
 655 dnl --enable-clang-static-analyzer: check whether to enable static-analyzer
 656 clang_static_analyzer="yes"
 657 AC_ARG_ENABLE(clang-static-analyzer,
 658               AS_HELP_STRING([--enable-clang-static-analyzer],
 659                              [Enable building of clang Static Analyzer (default is YES)]),
 660                              clang_static_analyzer="$enableval",
 661                              enableval="yes")
 662 case "$enableval" in
 663   yes) AC_SUBST(ENABLE_CLANG_STATIC_ANALYZER,[1]) ;;
 664   no)
 665     if test ${clang_arcmt} != "no" ; then
 666       AC_MSG_ERROR([Cannot enable clang ARC Migration Tool while disabling static analyzer.])
 667     fi
 668     AC_SUBST(ENABLE_CLANG_STATIC_ANALYZER,[0])
 669     ;;
 670   default) AC_SUBST(ENABLE_CLANG_STATIC_ANALYZER,[1]);;
 671   *) AC_MSG_ERROR([Invalid setting for --enable-clang-static-analyzer. Use "yes" or "no"]) ;;
 672 esac
 673
 674 dnl --enable-optimized : check whether they want to do an optimized build:
 675 AC_ARG_ENABLE(optimized, AS_HELP_STRING(
 676  --enable-optimized,[Compile with optimizations enabled (default is NO)]),,enableval=$optimize)
 677 if test ${enableval} = "no" ; then
 678   AC_SUBST(ENABLE_OPTIMIZED,[[]])
 679 else
 680   AC_SUBST(ENABLE_OPTIMIZED,[[ENABLE_OPTIMIZED=1]])
 681 fi
 682
 683 dnl --enable-profiling : check whether they want to do a profile build:
 684 AC_ARG_ENABLE(profiling, AS_HELP_STRING(
 685  --enable-profiling,[Compile with profiling enabled (default is NO)]),,enableval="no")
 686 if test ${enableval} = "no" ; then
 687   AC_SUBST(ENABLE_PROFILING,[[]])
 688 else
 689   AC_SUBST(ENABLE_PROFILING,[[ENABLE_PROFILING=1]])
 690 fi
 691
 692 dnl --enable-assertions : check whether they want to turn on assertions or not:
 693 AC_ARG_ENABLE(assertions,AS_HELP_STRING(
 694   --enable-assertions,[Compile with assertion checks enabled (default is YES)]),, enableval="yes")
 695 if test ${enableval} = "yes" ; then
 696   AC_SUBST(DISABLE_ASSERTIONS,[[]])
 697 else
 698   AC_SUBST(DISABLE_ASSERTIONS,[[DISABLE_ASSERTIONS=1]])
 699 fi
 700
 701 dnl --enable-werror : check whether we want Werror on by default
 702 AC_ARG_ENABLE(werror,AS_HELP_STRING(
 703   --enable-werror,[Compile with -Werror enabled (default is NO)]),, enableval="no")
 704 case "$enableval" in
 705   yes) AC_SUBST(ENABLE_WERROR,[1]) ;;
 706   no)  AC_SUBST(ENABLE_WERROR,[0]) ;;
 707   default) AC_SUBST(ENABLE_WERROR,[0]);;
 708   *) AC_MSG_ERROR([Invalid setting for --enable-werror. Use "yes" or "no"]) ;;
 709 esac
 710
 711 dnl --enable-expensive-checks : check whether they want to turn on expensive debug checks:
 712 AC_ARG_ENABLE(expensive-checks,AS_HELP_STRING(
 713   --enable-expensive-checks,[Compile with expensive debug checks enabled (default is NO)]),, enableval="no")
 714 if test ${enableval} = "yes" ; then
 715   AC_SUBST(ENABLE_EXPENSIVE_CHECKS,[[ENABLE_EXPENSIVE_CHECKS=1]])
 716   AC_SUBST(EXPENSIVE_CHECKS,[[yes]])
 717 else
 718   AC_SUBST(ENABLE_EXPENSIVE_CHECKS,[[]])
 719   AC_SUBST(EXPENSIVE_CHECKS,[[no]])
 720 fi
 721
 722 dnl --enable-debug-runtime : should runtime libraries have debug symbols?
 723 AC_ARG_ENABLE(debug-runtime,
 724    AS_HELP_STRING(--enable-debug-runtime,[Build runtime libs with debug symbols (default is NO)]),,enableval=no)
 725 if test ${enableval} = "no" ; then
 726   AC_SUBST(DEBUG_RUNTIME,[[]])
 727 else
 728   AC_SUBST(DEBUG_RUNTIME,[[DEBUG_RUNTIME=1]])
 729 fi
 730
 731 dnl --enable-debug-symbols : should even optimized compiler libraries
 732 dnl have debug symbols?
 733 AC_ARG_ENABLE(debug-symbols,
 734    AS_HELP_STRING(--enable-debug-symbols,[Build compiler with debug symbols (default is NO if optimization is on and YES if it's off)]),,enableval=no)
 735 if test ${enableval} = "no" ; then
 736   AC_SUBST(DEBUG_SYMBOLS,[[]])
 737 else
 738   AC_SUBST(DEBUG_SYMBOLS,[[DEBUG_SYMBOLS=1]])
 739 fi
 740
 741 dnl --enable-keep-symbols : do not strip installed executables
 742 AC_ARG_ENABLE(keep-symbols,
 743    AS_HELP_STRING(--enable-keep-symbols,[Do not strip installed executables)]),,enableval=no)
 744 if test ${enableval} = "no" ; then
 745   AC_SUBST(KEEP_SYMBOLS,[[]])
 746 else
 747   AC_SUBST(KEEP_SYMBOLS,[[KEEP_SYMBOLS=1]])
 748 fi
 749
 750 dnl --enable-jit: check whether they want to enable the jit
 751 AC_ARG_ENABLE(jit,
 752   AS_HELP_STRING(--enable-jit,
 753                  [Enable Just In Time Compiling (default is YES)]),,
 754   enableval=default)
 755 if test ${enableval} = "no"
 756 then
 757   AC_SUBST(JIT,[[]])
 758 else
 759   case "$llvm_cv_target_arch" in
 760     x86)         AC_SUBST(TARGET_HAS_JIT,1) ;;
 761     Sparc)       AC_SUBST(TARGET_HAS_JIT,0) ;;
 762     PowerPC)     AC_SUBST(TARGET_HAS_JIT,1) ;;
 763     x86_64)      AC_SUBST(TARGET_HAS_JIT,1) ;;
 764     ARM)         AC_SUBST(TARGET_HAS_JIT,1) ;;
 765     Mips)        AC_SUBST(TARGET_HAS_JIT,1) ;;
 766     XCore)       AC_SUBST(TARGET_HAS_JIT,0) ;;
 767     MSP430)      AC_SUBST(TARGET_HAS_JIT,0) ;;
 768     Hexagon)     AC_SUBST(TARGET_HAS_JIT,0) ;;
 769     NVPTX)       AC_SUBST(TARGET_HAS_JIT,0) ;;
 770     SystemZ)     AC_SUBST(TARGET_HAS_JIT,1) ;;
 771     *)           AC_SUBST(TARGET_HAS_JIT,0) ;;
 772   esac
 773 fi
 774
 775 TARGETS_WITH_JIT="ARM AArch64 Mips PowerPC SystemZ X86"
 776 AC_SUBST(TARGETS_WITH_JIT,$TARGETS_WITH_JIT)
 777
 778 dnl Allow enablement of building and installing docs
 779 AC_ARG_ENABLE(docs,
 780               AS_HELP_STRING([--enable-docs],
 781                              [Build documents (default is YES)]),,
 782                              enableval=default)
 783 case "$enableval" in
 784   yes) AC_SUBST(ENABLE_DOCS,[1]) ;;
 785   no)  AC_SUBST(ENABLE_DOCS,[0]) ;;
 786   default) AC_SUBST(ENABLE_DOCS,[1]) ;;
 787   *) AC_MSG_ERROR([Invalid setting for --enable-docs. Use "yes" or "no"]) ;;
 788 esac
 789
 790 dnl Allow enablement of doxygen generated documentation
 791 AC_ARG_ENABLE(doxygen,
 792               AS_HELP_STRING([--enable-doxygen],
 793                              [Build doxygen documentation (default is NO)]),,
 794                              enableval=default)
 795 case "$enableval" in
 796   yes) AC_SUBST(ENABLE_DOXYGEN,[1]) ;;
 797   no)  AC_SUBST(ENABLE_DOXYGEN,[0]) ;;
 798   default) AC_SUBST(ENABLE_DOXYGEN,[0]) ;;
 799   *) AC_MSG_ERROR([Invalid setting for --enable-doxygen. Use "yes" or "no"]) ;;
 800 esac
 801
 802 dnl Allow disablement of threads
 803 AC_ARG_ENABLE(threads,
 804               AS_HELP_STRING([--enable-threads],
 805                              [Use threads if available (default is YES)]),,
 806                              enableval=default)
 807 case "$enableval" in
 808   yes) AC_SUBST(LLVM_ENABLE_THREADS,[1]) ;;
 809   no)  AC_SUBST(LLVM_ENABLE_THREADS,[0]) ;;
 810   default) AC_SUBST(LLVM_ENABLE_THREADS,[1]) ;;
 811   *) AC_MSG_ERROR([Invalid setting for --enable-threads. Use "yes" or "no"]) ;;
 812 esac
 813 AC_DEFINE_UNQUOTED([LLVM_ENABLE_THREADS],$LLVM_ENABLE_THREADS,
 814                    [Define if threads enabled])
 815
 816 dnl Allow disablement of pthread.h
 817 AC_ARG_ENABLE(pthreads,
 818               AS_HELP_STRING([--enable-pthreads],
 819                              [Use pthreads if available (default is YES)]),,
 820                              enableval=default)
 821 case "$enableval" in
 822   yes) AC_SUBST(ENABLE_PTHREADS,[1]) ;;
 823   no)  AC_SUBST(ENABLE_PTHREADS,[0]) ;;
 824   default) AC_SUBST(ENABLE_PTHREADS,[1]) ;;
 825   *) AC_MSG_ERROR([Invalid setting for --enable-pthreads. Use "yes" or "no"]) ;;
 826 esac
 827
 828 dnl Allow disablement of zlib
 829 AC_ARG_ENABLE(zlib,
 830               AS_HELP_STRING([--enable-zlib],
 831                              [Use zlib for compression/decompression if
 832                               available (default is YES)]),,
 833                               enableval=default)
 834 case "$enableval" in
 835   yes) AC_SUBST(LLVM_ENABLE_ZLIB,[1]) ;;
 836   no)  AC_SUBST(LLVM_ENABLE_ZLIB,[0]) ;;
 837   default) AC_SUBST(LLVM_ENABLE_ZLIB,[1]) ;;
 838   *) AC_MSG_ERROR([Invalid setting for --enable-zlib. Use "yes" or "no"]) ;;
 839 esac
 840 AC_DEFINE_UNQUOTED([LLVM_ENABLE_ZLIB],$LLVM_ENABLE_ZLIB,
 841                    [Define if zlib is enabled])
 842
 843 dnl Allow building without position independent code
 844 AC_ARG_ENABLE(pic,
 845   AS_HELP_STRING([--enable-pic],
 846                  [Build LLVM with Position Independent Code (default is YES)]),,
 847                  enableval=default)
 848 case "$enableval" in
 849   yes) AC_SUBST(ENABLE_PIC,[1]) ;;
 850   no)  AC_SUBST(ENABLE_PIC,[0]) ;;
 851   default) AC_SUBST(ENABLE_PIC,[1]) ;;
 852   *) AC_MSG_ERROR([Invalid setting for --enable-pic. Use "yes" or "no"]) ;;
 853 esac
 854 AC_DEFINE_UNQUOTED([ENABLE_PIC],$ENABLE_PIC,
 855                    [Define if position independent code is enabled])
 856
 857 dnl Allow building a shared library and linking tools against it.
 858 AC_ARG_ENABLE(shared,
 859   AS_HELP_STRING([--enable-shared],
 860                  [Build a shared library and link tools against it (default is NO)]),,
 861                  enableval=default)
 862 case "$enableval" in
 863   yes) AC_SUBST(ENABLE_SHARED,[1]) ;;
 864   no)  AC_SUBST(ENABLE_SHARED,[0]) ;;
 865   default) AC_SUBST(ENABLE_SHARED,[0]) ;;
 866   *) AC_MSG_ERROR([Invalid setting for --enable-shared. Use "yes" or "no"]) ;;
 867 esac
 868
 869 dnl Allow libstdc++ is embedded in LLVM.dll.
 870 AC_ARG_ENABLE(embed-stdcxx,
 871   AS_HELP_STRING([--enable-embed-stdcxx],
 872                  [Build a shared library with embedded libstdc++ for Win32 DLL (default is NO)]),,
 873                  enableval=default)
 874 case "$enableval" in
 875   yes) AC_SUBST(ENABLE_EMBED_STDCXX,[1]) ;;
 876   no)  AC_SUBST(ENABLE_EMBED_STDCXX,[0]) ;;
 877   default) AC_SUBST(ENABLE_EMBED_STDCXX,[0]) ;;
 878   *) AC_MSG_ERROR([Invalid setting for --enable-embed-stdcxx. Use "yes" or "no"]) ;;
 879 esac
 880
 881 dnl Enable embedding timestamp information into build.
 882 AC_ARG_ENABLE(timestamps,
 883   AS_HELP_STRING([--enable-timestamps],
 884                  [Enable embedding timestamp information in build (default is YES)]),,
 885                  enableval=default)
 886 case "$enableval" in
 887   yes) AC_SUBST(ENABLE_TIMESTAMPS,[1]) ;;
 888   no)  AC_SUBST(ENABLE_TIMESTAMPS,[0]) ;;
 889   default) AC_SUBST(ENABLE_TIMESTAMPS,[1]) ;;
 890   *) AC_MSG_ERROR([Invalid setting for --enable-timestamps. Use "yes" or "no"]) ;;
 891 esac
 892 AC_DEFINE_UNQUOTED([ENABLE_TIMESTAMPS],$ENABLE_TIMESTAMPS,
 893                    [Define if timestamp information (e.g., __DATE__) is allowed])
 894
 895 dnl Enable support for showing backtraces.
 896 AC_ARG_ENABLE(backtraces, AS_HELP_STRING(
 897   [--enable-backtraces],
 898   [Enable embedding backtraces on crash (default is YES)]),
 899   [case "$enableval" in
 900     yes) llvm_cv_enable_backtraces="yes" ;;
 901     no)  llvm_cv_enable_backtraces="no"  ;;
 902     *) AC_MSG_ERROR([Invalid setting for --enable-backtraces. Use "yes" or "no"]) ;;
 903   esac],
 904   llvm_cv_enable_backtraces="yes")
 905 if test "$llvm_cv_enable_backtraces" = "yes" ; then
 906   AC_DEFINE([ENABLE_BACKTRACES],[1],
 907             [Define if you want backtraces on crash])
 908 fi
 909
 910 dnl Enable installing platform specific signal handling overrides, for improved
 911 dnl CrashRecovery support or interaction with crash reporting software. This
 912 dnl support may be inappropriate for some clients embedding LLVM as a library.
 913 AC_ARG_ENABLE(crash-overrides, AS_HELP_STRING(
 914   [--enable-crash-overrides],
 915   [Enable crash handling overrides (default is YES)]),
 916   [case "$enableval" in
 917     yes) llvm_cv_enable_crash_overrides="yes" ;;
 918     no)  llvm_cv_enable_crash_overrides="no"  ;;
 919     *) AC_MSG_ERROR([Invalid setting for --enable-crash-overrides. Use "yes" or "no"]) ;;
 920   esac],
 921   llvm_cv_enable_crash_overrides="yes")
 922 if test "$llvm_cv_enable_crash_overrides" = "yes" ; then
 923   AC_DEFINE([ENABLE_CRASH_OVERRIDES],[1],
 924             [Define to enable crash handling overrides])
 925 fi
 926
 927 dnl List all possible targets
 928 ALL_TARGETS="X86 Sparc PowerPC ARM AArch64 Mips XCore MSP430 CppBackend NVPTX Hexagon SystemZ R600"
 929 AC_SUBST(ALL_TARGETS,$ALL_TARGETS)
 930
 931 dnl Allow specific targets to be specified for building (or not)
 932 TARGETS_TO_BUILD=""
 933 AC_ARG_ENABLE([targets],AS_HELP_STRING([--enable-targets],
 934     [Build specific host targets: all or target1,target2,... Valid targets are:
 935      host, x86, x86_64, sparc, powerpc, arm64, arm, aarch64, mips, hexagon,
 936      xcore, msp430, nvptx, systemz, r600, and cpp (default=all)]),,
 937     enableval=all)
 938 if test "$enableval" = host-only ; then
 939   enableval=host
 940 fi
 941 case "$enableval" in
 942   all) TARGETS_TO_BUILD="$ALL_TARGETS" ;;
 943   *)for a_target in `echo $enableval|sed -e 's/,/ /g' ` ; do
 944       case "$a_target" in
 945         x86)      TARGETS_TO_BUILD="X86 $TARGETS_TO_BUILD" ;;
 946         x86_64)   TARGETS_TO_BUILD="X86 $TARGETS_TO_BUILD" ;;
 947         sparc)    TARGETS_TO_BUILD="Sparc $TARGETS_TO_BUILD" ;;
 948         powerpc)  TARGETS_TO_BUILD="PowerPC $TARGETS_TO_BUILD" ;;
 949         aarch64)  TARGETS_TO_BUILD="AArch64 $TARGETS_TO_BUILD" ;;
 950         arm64)    TARGETS_TO_BUILD="AArch64 $TARGETS_TO_BUILD" ;;
 951         arm)      TARGETS_TO_BUILD="ARM $TARGETS_TO_BUILD" ;;
 952         mips)     TARGETS_TO_BUILD="Mips $TARGETS_TO_BUILD" ;;
 953         mipsel)   TARGETS_TO_BUILD="Mips $TARGETS_TO_BUILD" ;;
 954         mips64)   TARGETS_TO_BUILD="Mips $TARGETS_TO_BUILD" ;;
 955         mips64el) TARGETS_TO_BUILD="Mips $TARGETS_TO_BUILD" ;;
 956         xcore)    TARGETS_TO_BUILD="XCore $TARGETS_TO_BUILD" ;;
 957         msp430)   TARGETS_TO_BUILD="MSP430 $TARGETS_TO_BUILD" ;;
 958         cpp)      TARGETS_TO_BUILD="CppBackend $TARGETS_TO_BUILD" ;;
 959         hexagon)  TARGETS_TO_BUILD="Hexagon $TARGETS_TO_BUILD" ;;
 960         nvptx)    TARGETS_TO_BUILD="NVPTX $TARGETS_TO_BUILD" ;;
 961         systemz)  TARGETS_TO_BUILD="SystemZ $TARGETS_TO_BUILD" ;;
 962         r600)     TARGETS_TO_BUILD="R600 $TARGETS_TO_BUILD" ;;
 963         host) case "$llvm_cv_target_arch" in
 964             x86)         TARGETS_TO_BUILD="X86 $TARGETS_TO_BUILD" ;;
 965             x86_64)      TARGETS_TO_BUILD="X86 $TARGETS_TO_BUILD" ;;
 966             Sparc)       TARGETS_TO_BUILD="Sparc $TARGETS_TO_BUILD" ;;
 967             PowerPC)     TARGETS_TO_BUILD="PowerPC $TARGETS_TO_BUILD" ;;
 968             AArch64)     TARGETS_TO_BUILD="AArch64 $TARGETS_TO_BUILD" ;;
 969             ARM)         TARGETS_TO_BUILD="ARM $TARGETS_TO_BUILD" ;;
 970             Mips)        TARGETS_TO_BUILD="Mips $TARGETS_TO_BUILD" ;;
 971             XCore)       TARGETS_TO_BUILD="XCore $TARGETS_TO_BUILD" ;;
 972             MSP430)      TARGETS_TO_BUILD="MSP430 $TARGETS_TO_BUILD" ;;
 973             Hexagon)     TARGETS_TO_BUILD="Hexagon $TARGETS_TO_BUILD" ;;
 974             NVPTX)       TARGETS_TO_BUILD="NVPTX $TARGETS_TO_BUILD" ;;
 975             SystemZ)     TARGETS_TO_BUILD="SystemZ $TARGETS_TO_BUILD" ;;
 976             *)       AC_MSG_ERROR([Can not set target to build]) ;;
 977           esac ;;
 978         *) AC_MSG_ERROR([Unrecognized target $a_target]) ;;
 979       esac
 980   done
 981   ;;
 982 esac
 983
 984 AC_ARG_ENABLE([experimental-targets],AS_HELP_STRING([--enable-experimental-targets],
 985     [Build experimental host targets: disable or target1,target2,...
 986      (default=disable)]),,
 987     enableval=disable)
 988
 989 if test ${enableval} != "disable"
 990 then
 991   TARGETS_TO_BUILD="$enableval $TARGETS_TO_BUILD"
 992 fi
 993
 994 AC_SUBST(TARGETS_TO_BUILD,$TARGETS_TO_BUILD)
 995
 996 dnl Determine whether we are building LLVM support for the native architecture.
 997 dnl If so, define LLVM_NATIVE_ARCH to that LLVM target.
 998 for a_target in $TARGETS_TO_BUILD; do
 999   if test "$a_target" = "$LLVM_NATIVE_ARCH"; then
1000     AC_DEFINE_UNQUOTED(LLVM_NATIVE_ARCH, $LLVM_NATIVE_ARCH,
1001       [LLVM architecture name for the native architecture, if available])
1002     LLVM_NATIVE_TARGET="LLVMInitialize${LLVM_NATIVE_ARCH}Target"
1003     LLVM_NATIVE_TARGETINFO="LLVMInitialize${LLVM_NATIVE_ARCH}TargetInfo"
1004     LLVM_NATIVE_TARGETMC="LLVMInitialize${LLVM_NATIVE_ARCH}TargetMC"
1005     LLVM_NATIVE_ASMPRINTER="LLVMInitialize${LLVM_NATIVE_ARCH}AsmPrinter"
1006     if test -f ${srcdir}/lib/Target/${LLVM_NATIVE_ARCH}/AsmParser/Makefile ; then
1007       LLVM_NATIVE_ASMPARSER="LLVMInitialize${LLVM_NATIVE_ARCH}AsmParser"
1008     fi
1009     if test -f ${srcdir}/lib/Target/${LLVM_NATIVE_ARCH}/Disassembler/Makefile ; then
1010       LLVM_NATIVE_DISASSEMBLER="LLVMInitialize${LLVM_NATIVE_ARCH}Disassembler"
1011     fi
1012     AC_DEFINE_UNQUOTED(LLVM_NATIVE_TARGET, $LLVM_NATIVE_TARGET,
1013       [LLVM name for the native Target init function, if available])
1014     AC_DEFINE_UNQUOTED(LLVM_NATIVE_TARGETINFO, $LLVM_NATIVE_TARGETINFO,
1015       [LLVM name for the native TargetInfo init function, if available])
1016     AC_DEFINE_UNQUOTED(LLVM_NATIVE_TARGETMC, $LLVM_NATIVE_TARGETMC,
1017       [LLVM name for the native target MC init function, if available])
1018     AC_DEFINE_UNQUOTED(LLVM_NATIVE_ASMPRINTER, $LLVM_NATIVE_ASMPRINTER,
1019       [LLVM name for the native AsmPrinter init function, if available])
1020     if test -f ${srcdir}/lib/Target/${LLVM_NATIVE_ARCH}/AsmParser/Makefile ; then
1021       AC_DEFINE_UNQUOTED(LLVM_NATIVE_ASMPARSER, $LLVM_NATIVE_ASMPARSER,
1022        [LLVM name for the native AsmParser init function, if available])
1023     fi
1024     if test -f ${srcdir}/lib/Target/${LLVM_NATIVE_ARCH}/Disassembler/Makefile ; then
1025       AC_DEFINE_UNQUOTED(LLVM_NATIVE_DISASSEMBLER, $LLVM_NATIVE_DISASSEMBLER,
1026        [LLVM name for the native Disassembler init function, if available])
1027     fi
1028   fi
1029 done
1030
1031 dnl Build the LLVM_TARGET and LLVM_... macros for Targets.def and the individual
1032 dnl target feature def files.
1033 LLVM_ENUM_TARGETS=""
1034 LLVM_ENUM_ASM_PRINTERS=""
1035 LLVM_ENUM_ASM_PARSERS=""
1036 LLVM_ENUM_DISASSEMBLERS=""
1037 for target_to_build in $TARGETS_TO_BUILD; do
1038   LLVM_ENUM_TARGETS="LLVM_TARGET($target_to_build) $LLVM_ENUM_TARGETS"
1039   if test -f ${srcdir}/lib/Target/${target_to_build}/*AsmPrinter.cpp ; then
1040     LLVM_ENUM_ASM_PRINTERS="LLVM_ASM_PRINTER($target_to_build) $LLVM_ENUM_ASM_PRINTERS";
1041   fi
1042   if test -f ${srcdir}/lib/Target/${target_to_build}/AsmParser/Makefile ; then
1043     LLVM_ENUM_ASM_PARSERS="LLVM_ASM_PARSER($target_to_build) $LLVM_ENUM_ASM_PARSERS";
1044   fi
1045   if test -f ${srcdir}/lib/Target/${target_to_build}/Disassembler/Makefile ; then
1046     LLVM_ENUM_DISASSEMBLERS="LLVM_DISASSEMBLER($target_to_build) $LLVM_ENUM_DISASSEMBLERS";
1047   fi
1048 done
1049 AC_SUBST(LLVM_ENUM_TARGETS)
1050 AC_SUBST(LLVM_ENUM_ASM_PRINTERS)
1051 AC_SUBST(LLVM_ENUM_ASM_PARSERS)
1052 AC_SUBST(LLVM_ENUM_DISASSEMBLERS)
1053
1054 dnl Override the option to use for optimized builds.
1055 AC_ARG_WITH(optimize-option,
1056   AS_HELP_STRING([--with-optimize-option],
1057                  [Select the compiler options to use for optimized builds]),,
1058                  withval=default)
1059 AC_MSG_CHECKING([optimization flags])
1060 case "$withval" in
1061   default)
1062     case "$llvm_cv_os_type" in
1063     FreeBSD) optimize_option=-O2 ;;
1064     MingW) optimize_option=-O2 ;;
1065     *)     optimize_option=-O3 ;;
1066     esac ;;
1067   *) optimize_option="$withval" ;;
1068 esac
1069 AC_SUBST(OPTIMIZE_OPTION,$optimize_option)
1070 AC_MSG_RESULT([$optimize_option])
1071
1072 dnl Specify extra build options
1073 AC_ARG_WITH(extra-options,
1074   AS_HELP_STRING([--with-extra-options],
1075                  [Specify additional options to compile LLVM with]),,
1076                  withval=default)
1077 case "$withval" in
1078   default) EXTRA_OPTIONS= ;;
1079   *) EXTRA_OPTIONS=$withval ;;
1080 esac
1081 AC_SUBST(EXTRA_OPTIONS,$EXTRA_OPTIONS)
1082
1083 dnl Specify extra linker build options
1084 AC_ARG_WITH(extra-ld-options,
1085   AS_HELP_STRING([--with-extra-ld-options],
1086                  [Specify additional options to link LLVM with]),,
1087                  withval=default)
1088 case "$withval" in
1089   default) EXTRA_LD_OPTIONS= ;;
1090   *) EXTRA_LD_OPTIONS=$withval ;;
1091 esac
1092 AC_SUBST(EXTRA_LD_OPTIONS,$EXTRA_LD_OPTIONS)
1093
1094 dnl Allow specific bindings to be specified for building (or not)
1095 AC_ARG_ENABLE([bindings],AS_HELP_STRING([--enable-bindings],
1096     [Build specific language bindings: all,auto,none,{binding-name} (default=auto)]),,
1097     enableval=default)
1098 BINDINGS_TO_BUILD=""
1099 case "$enableval" in
1100   yes | default | auto) BINDINGS_TO_BUILD="auto" ;;
1101   all ) BINDINGS_TO_BUILD="ocaml" ;;
1102   none | no) BINDINGS_TO_BUILD="" ;;
1103   *)for a_binding in `echo $enableval|sed -e 's/,/ /g' ` ; do
1104       case "$a_binding" in
1105         ocaml) BINDINGS_TO_BUILD="ocaml $BINDINGS_TO_BUILD" ;;
1106         *) AC_MSG_ERROR([Unrecognized binding $a_binding]) ;;
1107       esac
1108   done
1109   ;;
1110 esac
1111
1112 dnl Allow the ocaml libdir to be overridden. This could go in a configure
1113 dnl script for bindings/ocaml/configure, except that its auto value depends on
1114 dnl OCAMLC, which is found here to support tests.
1115 AC_ARG_WITH([ocaml-libdir],
1116   [AS_HELP_STRING([--with-ocaml-libdir],
1117     [Specify install location for ocaml bindings (default is stdlib)])],
1118   [],
1119   [withval=auto])
1120 case "$withval" in
1121   auto) with_ocaml_libdir="$withval" ;;
1122   /* | [[A-Za-z]]:[[\\/]]*) with_ocaml_libdir="$withval" ;;
1123   *) AC_MSG_ERROR([Invalid path for --with-ocaml-libdir. Provide full path]) ;;
1124 esac
1125
1126 AC_ARG_WITH(clang-srcdir,
1127   AS_HELP_STRING([--with-clang-srcdir],
1128     [Directory to the out-of-tree Clang source]),,
1129     withval="-")
1130 case "$withval" in
1131   -) clang_src_root="" ;;
1132   /* | [[A-Za-z]]:[[\\/]]*) clang_src_root="$withval" ;;
1133   *) clang_src_root="$ac_pwd/$withval" ;;
1134 esac
1135 AC_SUBST(CLANG_SRC_ROOT,[$clang_src_root])
1136
1137 AC_ARG_WITH(clang-resource-dir,
1138   AS_HELP_STRING([--with-clang-resource-dir],
1139     [Relative directory from the Clang binary for resource files]),,
1140     withval="")
1141 AC_DEFINE_UNQUOTED(CLANG_RESOURCE_DIR,"$withval",
1142                    [Relative directory for resource files])
1143
1144 AC_ARG_WITH(c-include-dirs,
1145   AS_HELP_STRING([--with-c-include-dirs],
1146     [Colon separated list of directories clang will search for headers]),,
1147     withval="")
1148 AC_DEFINE_UNQUOTED(C_INCLUDE_DIRS,"$withval",
1149                    [Directories clang will search for headers])
1150
1151 # Clang normally uses the system c++ headers and libraries. With this option,
1152 # clang will use the ones provided by a gcc installation instead. This option should
1153 # be passed the same value that was used with --prefix when configuring gcc.
1154 AC_ARG_WITH(gcc-toolchain,
1155   AS_HELP_STRING([--with-gcc-toolchain],
1156     [Directory where gcc is installed.]),,
1157     withval="")
1158 AC_DEFINE_UNQUOTED(GCC_INSTALL_PREFIX,"$withval",
1159                    [Directory where gcc is installed.])
1160
1161 AC_ARG_WITH(default-sysroot,
1162   AS_HELP_STRING([--with-default-sysroot],
1163     [Add --sysroot=<path> to all compiler invocations.]),,
1164     withval="")
1165 AC_DEFINE_UNQUOTED(DEFAULT_SYSROOT,"$withval",
1166                    [Default <path> to all compiler invocations for --sysroot=<path>.])
1167
1168 dnl Allow linking of LLVM with GPLv3 binutils code.
1169 AC_ARG_WITH(binutils-include,
1170   AS_HELP_STRING([--with-binutils-include],
1171     [Specify path to binutils/include/ containing plugin-api.h file for gold plugin.]),,
1172   withval=default)
1173 case "$withval" in
1174   default) WITH_BINUTILS_INCDIR=default ;;
1175   /* | [[A-Za-z]]:[[\\/]]*)      WITH_BINUTILS_INCDIR=$withval ;;
1176   *) AC_MSG_ERROR([Invalid path for --with-binutils-include. Provide full path]) ;;
1177 esac
1178 if test "x$WITH_BINUTILS_INCDIR" != xdefault ; then
1179   AC_SUBST(BINUTILS_INCDIR,$WITH_BINUTILS_INCDIR)
1180   if test ! -f "$WITH_BINUTILS_INCDIR/plugin-api.h"; then
1181      echo "$WITH_BINUTILS_INCDIR/plugin-api.h"
1182      AC_MSG_ERROR([Invalid path to directory containing plugin-api.h.]);
1183   fi
1184 fi
1185
1186 dnl Specify the URL where bug reports should be submitted.
1187 AC_ARG_WITH(bug-report-url,
1188   AS_HELP_STRING([--with-bug-report-url],
1189     [Specify the URL where bug reports should be submitted (default=http://llvm.org/bugs/)]),,
1190     withval="http://llvm.org/bugs/")
1191 AC_DEFINE_UNQUOTED(BUG_REPORT_URL,"$withval",
1192                    [Bug report URL.])
1193
1194 dnl --enable-terminfo: check whether the user wants to control use of terminfo:
1195 AC_ARG_ENABLE(terminfo,AS_HELP_STRING(
1196   [--enable-terminfo],
1197   [Query the terminfo database if available (default is YES)]),
1198   [case "$enableval" in
1199     yes) llvm_cv_enable_terminfo="yes" ;;
1200     no)  llvm_cv_enable_terminfo="no"  ;;
1201     *) AC_MSG_ERROR([Invalid setting for --enable-terminfo. Use "yes" or "no"]) ;;
1202   esac],
1203   llvm_cv_enable_terminfo="yes")
1204 case "$llvm_cv_enable_terminfo" in
1205   yes) AC_SUBST(ENABLE_TERMINFO,[1]) ;;
1206   no)  AC_SUBST(ENABLE_TERMINFO,[0]) ;;
1207 esac
1208
1209 dnl --enable-libedit: check whether the user wants to turn off libedit.
1210 AC_ARG_ENABLE(libedit,AS_HELP_STRING(
1211   [--enable-libedit],
1212   [Use libedit if available (default is YES)]),
1213   [case "$enableval" in
1214     yes) llvm_cv_enable_libedit="yes" ;;
1215     no)  llvm_cv_enable_libedit="no"  ;;
1216     *) AC_MSG_ERROR([Invalid setting for --enable-libedit. Use "yes" or "no"]) ;;
1217   esac],
1218   llvm_cv_enable_libedit="yes")
1219
1220 dnl --enable-libffi : check whether the user wants to turn off libffi:
1221 AC_ARG_ENABLE(libffi,AS_HELP_STRING(
1222   --enable-libffi,[Check for the presence of libffi (default is NO)]),
1223   [case "$enableval" in
1224     yes) llvm_cv_enable_libffi="yes" ;;
1225     no)  llvm_cv_enable_libffi="no"  ;;
1226     *) AC_MSG_ERROR([Invalid setting for --enable-libffi. Use "yes" or "no"]) ;;
1227   esac],
1228   llvm_cv_enable_libffi=no)
1229
1230 AC_ARG_WITH(internal-prefix,
1231   AS_HELP_STRING([--with-internal-prefix],
1232     [Installation directory for internal files]),,
1233     withval="")
1234 AC_SUBST(INTERNAL_PREFIX,[$withval])
1235
1236 dnl===-----------------------------------------------------------------------===
1237 dnl===
1238 dnl=== SECTION 4: Check for programs we need and that they are the right version
1239 dnl===
1240 dnl===-----------------------------------------------------------------------===
1241
1242 dnl Check for the tools that the makefiles require
1243 AC_CHECK_GNU_MAKE
1244 AC_PROG_LN_S
1245 AC_PATH_PROG(NM, [nm], [nm])
1246 AC_PATH_PROG(CMP, [cmp], [cmp])
1247 AC_PATH_PROG(CP, [cp], [cp])
1248 AC_PATH_PROG(DATE, [date], [date])
1249 AC_PATH_PROG(FIND, [find], [find])
1250 AC_PATH_PROG(GREP, [grep], [grep])
1251 AC_PATH_PROG(MKDIR,[mkdir],[mkdir])
1252 AC_PATH_PROG(MV,   [mv],   [mv])
1253 AC_PROG_RANLIB
1254 AC_CHECK_TOOL(AR, ar, false)
1255 AC_PATH_PROG(RM,   [rm],   [rm])
1256 AC_PATH_PROG(SED,  [sed],  [sed])
1257 AC_PATH_PROG(TAR,  [tar],  [gtar])
1258 AC_PATH_PROG(BINPWD,[pwd],  [pwd])
1259
1260 dnl Looking for misc. graph plotting software
1261 AC_PATH_PROG(DOT, [dot], [echo dot])
1262 if test "$DOT" != "echo dot" ; then
1263   AC_DEFINE([HAVE_DOT],[1],[Define if the dot program is available])
1264   dnl If we're targeting for mingw we should emit windows paths, not msys
1265   if test "$llvm_cv_os_type" = "MingW" ; then
1266     DOT=`echo $DOT | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
1267   fi
1268   AC_DEFINE_UNQUOTED([LLVM_PATH_DOT],"$DOT${EXEEXT}",
1269    [Define to path to dot program if found or 'echo dot' otherwise])
1270 fi
1271
1272 dnl Find the install program
1273 AC_PROG_INSTALL
1274 dnl Prepend src dir to install path dir if it's a relative path
1275 dnl This is a hack for installs that take place in something other
1276 dnl than the top level.
1277 case "$INSTALL" in
1278  [[\\/$]]* | ?:[[\\/]]* ) ;;
1279  *)  INSTALL="\\\$(TOPSRCDIR)/$INSTALL" ;;
1280 esac
1281
1282 dnl Checks for documentation and testing tools that we can do without. If these
1283 dnl are not found then they are set to "true" which always succeeds but does
1284 dnl nothing. This just lets the build output show that we could have done
1285 dnl something if the tool was available.
1286 AC_PATH_PROG(BZIP2, [bzip2])
1287 AC_PATH_PROG(CAT, [cat])
1288 AC_PATH_PROG(DOXYGEN, [doxygen])
1289 AC_PATH_PROG(GROFF, [groff])
1290 AC_PATH_PROG(GZIPBIN, [gzip])
1291 AC_PATH_PROG(PDFROFF, [pdfroff])
1292 AC_PATH_PROG(ZIP, [zip])
1293 AC_PATH_PROG(GO, [go])
1294 AC_PATH_PROGS(OCAMLFIND, [ocamlfind])
1295 AC_PATH_PROGS(GAS, [gas as])
1296
1297 dnl Get the version of the linker in use.
1298 AC_LINK_GET_VERSION
1299
1300 dnl Determine whether the linker supports the -R option.
1301 AC_LINK_USE_R
1302
1303 dnl Determine whether the compiler supports the -rdynamic option.
1304 AC_LINK_EXPORT_DYNAMIC
1305
1306 dnl Determine whether the linker supports the --version-script option.
1307 AC_LINK_VERSION_SCRIPT
1308
1309 AC_CHECK_HEADERS([errno.h])
1310
1311 case "$llvm_cv_os_type" in
1312   Cygwin|MingW|Win32) llvm_shlib_ext=.dll ;;
1313   Darwin) llvm_shlib_ext=.dylib ;;
1314   *) llvm_shlib_ext=.so ;;
1315 esac
1316
1317 AC_DEFINE_UNQUOTED([LTDL_SHLIB_EXT], ["$llvm_shlib_ext"], [The shared library extension])
1318
1319 AC_MSG_CHECKING([tool compatibility])
1320
1321 dnl Ensure that compilation tools are GCC or a GNU compatible compiler such as
1322 dnl ICC; we use GCC specific options in the makefiles so the compiler needs
1323 dnl to support those options.
1324 dnl "icc" emits gcc signatures
1325 dnl "icc -no-gcc" emits no gcc signature BUT is still compatible
1326 ICC=no
1327 IXX=no
1328 case $CC in
1329   icc*|icpc*)
1330     ICC=yes
1331     IXX=yes
1332     ;;
1333    *)
1334     ;;
1335 esac
1336
1337 if test "$GCC" != "yes" && test "$ICC" != "yes"
1338 then
1339   AC_MSG_ERROR([gcc|icc required but not found])
1340 fi
1341
1342 dnl Ensure that compilation tools are compatible with GCC extensions
1343 if test "$GXX" != "yes" && test "$IXX" != "yes"
1344 then
1345   AC_MSG_ERROR([g++|clang++|icc required but not found])
1346 fi
1347
1348 dnl Verify that GCC is version 3.0 or higher
1349 if test "$GCC" = "yes"
1350 then
1351   AC_COMPILE_IFELSE(
1352 [
1353   AC_LANG_SOURCE([[
1354     #if !defined(__GNUC__) || __GNUC__ < 3
1355     #error Unsupported GCC version
1356     #endif
1357   ]])
1358 ],
1359 [], [AC_MSG_ERROR([gcc 3.x required, but you have a lower version])])
1360 fi
1361
1362 dnl Check for GNU Make.  We use its extensions, so don't build without it
1363 if test -z "$llvm_cv_gnu_make_command"
1364 then
1365   AC_MSG_ERROR([GNU Make required but not found])
1366 fi
1367
1368 dnl Tool compatibility is okay if we make it here.
1369 AC_MSG_RESULT([ok])
1370
1371 dnl Check optional compiler flags.
1372 AC_MSG_CHECKING([optional compiler flags])
1373 CXX_FLAG_CHECK(NO_VARIADIC_MACROS, [-Wno-variadic-macros])
1374 CXX_FLAG_CHECK(NO_MISSING_FIELD_INITIALIZERS, [-Wno-missing-field-initializers])
1375 CXX_FLAG_CHECK(COVERED_SWITCH_DEFAULT, [-Wcovered-switch-default])
1376
1377 dnl GCC's potential uninitialized use analysis is weak and presents lots of
1378 dnl false positives, so disable it.
1379 NO_UNINITIALIZED=
1380 NO_MAYBE_UNINITIALIZED=
1381 if test "$GXX" = "yes"
1382 then
1383   CXX_FLAG_CHECK(NO_MAYBE_UNINITIALIZED, [-Wno-maybe-uninitialized])
1384   dnl gcc 4.7 introduced -Wmaybe-uninitialized to distinguish cases which are
1385   dnl known to be uninitialized from cases which might be uninitialized.  We
1386   dnl still want to catch the first kind of errors.
1387   if test -z "$NO_MAYBE_UNINITIALIZED"
1388   then
1389     CXX_FLAG_CHECK(NO_UNINITIALIZED, [-Wno-uninitialized])
1390   fi
1391 fi
1392
1393 dnl Check for misbehaving -Wcomment (gcc-4.7 has this) and maybe add
1394 dnl -Wno-comment to the flags.
1395 no_comment=
1396 llvm_cv_old_cxxflags="$CXXFLAGS"
1397 CXXFLAGS="$CXXFLAGS -Wcomment -Werror"
1398 AC_COMPILE_IFELSE(
1399 [
1400   AC_LANG_SOURCE([[// Comment \o\
1401 // Another comment
1402 int main() { return 0; }
1403   ]])
1404 ],
1405 [
1406   no_comment=-Wno-comment
1407 ],
1408 [])
1409 AC_SUBST(NO_COMMENT, [$no_comment])
1410 CXXFLAGS="$llvm_cv_old_cxxflags"
1411
1412 AC_MSG_RESULT([$NO_VARIADIC_MACROS $NO_MISSING_FIELD_INITIALIZERS $COVERED_SWITCH_DEFAULT $NO_UNINITIALIZED $NO_MAYBE_UNINITIALIZED $NO_COMMENT])
1413
1414 AC_ARG_WITH([python],
1415             [AS_HELP_STRING([--with-python], [path to python])],
1416             [PYTHON="$withval"])
1417
1418 if test -n "$PYTHON" && test -x "$PYTHON" ; then
1419   AC_MSG_CHECKING([for python])
1420   AC_MSG_RESULT([user defined: $with_python])
1421 else
1422   if test -n "$PYTHON" ; then
1423     AC_MSG_WARN([specified python ($PYTHON) is not usable, searching path])
1424   fi
1425
1426   AC_PATH_PROG([PYTHON], [python python2 python27],
1427                [AC_MSG_RESULT([not found])
1428                 AC_MSG_ERROR([could not find python 2.7 or higher])])
1429 fi
1430
1431 AC_MSG_CHECKING([for python >= 2.7])
1432 ac_python_version=`$PYTHON -V 2>&1 | cut -d' ' -f2`
1433 ac_python_version_major=`echo $ac_python_version | cut -d'.' -f1`
1434 ac_python_version_minor=`echo $ac_python_version | cut -d'.' -f2`
1435 ac_python_version_patch=`echo $ac_python_version | cut -d'.' -f3`
1436 if test "$ac_python_version_major" -gt "2" || \
1437    (test "$ac_python_version_major" -eq "2" && \
1438     test "$ac_python_version_minor" -ge "7") ; then
1439   AC_MSG_RESULT([$PYTHON ($ac_python_version)])
1440 else
1441   AC_MSG_RESULT([not found])
1442   AC_MSG_FAILURE([found python $ac_python_version ($PYTHON); required >= 2.7])
1443 fi
1444
1445 dnl===-----------------------------------------------------------------------===
1446 dnl===
1447 dnl=== SECTION 5: Check for libraries
1448 dnl===
1449 dnl===-----------------------------------------------------------------------===
1450
1451 AC_CHECK_LIB(m,sin)
1452 if test "$llvm_cv_os_type" = "MingW" ; then
1453   AC_CHECK_LIB(imagehlp, main)
1454   AC_CHECK_LIB(psapi, main)
1455   AC_CHECK_LIB(shell32, main)
1456 fi
1457
1458 dnl dlopen() is required for plugin support.
1459 AC_SEARCH_LIBS(dlopen,dl,LLVM_DEFINE_SUBST([HAVE_DLOPEN],[1],
1460                [Define if dlopen() is available on this platform.]),
1461                AC_MSG_WARN([dlopen() not found - disabling plugin support]))
1462
1463 dnl Search for the clock_gettime() function. Note that we rely on the POSIX
1464 dnl macros to detect whether clock_gettime is available, this just finds the
1465 dnl right libraries to link with.
1466 AC_SEARCH_LIBS(clock_gettime,rt)
1467
1468 dnl The curses library is optional; used for querying terminal info
1469 if test "$llvm_cv_enable_terminfo" = "yes" ; then
1470   dnl We need the has_color functionality in curses for it to be useful.
1471   AC_SEARCH_LIBS(setupterm,tinfo terminfo curses ncurses ncursesw,
1472                  LLVM_DEFINE_SUBST([HAVE_TERMINFO],[1],
1473                                    [Define if the setupterm() function is supported this platform.]))
1474 fi
1475
1476 dnl The libedit library is optional; used by lib/LineEditor
1477 if test "$llvm_cv_enable_libedit" = "yes" ; then
1478   AC_SEARCH_LIBS(el_init,edit,
1479                  AC_DEFINE([HAVE_LIBEDIT],[1],
1480                            [Define if libedit is available on this platform.]))
1481 fi
1482
1483 dnl libffi is optional; used to call external functions from the interpreter
1484 if test "$llvm_cv_enable_libffi" = "yes" ; then
1485   AC_SEARCH_LIBS(ffi_call,ffi,AC_DEFINE([HAVE_FFI_CALL],[1],
1486                  [Define if libffi is available on this platform.]),
1487                  AC_MSG_ERROR([libffi not found - configure without --enable-libffi to compile without it]))
1488 fi
1489
1490 dnl mallinfo is optional; the code can compile (minus features) without it
1491 AC_SEARCH_LIBS(mallinfo,malloc,AC_DEFINE([HAVE_MALLINFO],[1],
1492                [Define if mallinfo() is available on this platform.]))
1493
1494 dnl pthread locking functions are optional - but llvm will not be thread-safe
1495 dnl without locks.
1496 if test "$LLVM_ENABLE_THREADS" -eq 1 && test "$ENABLE_PTHREADS" -eq 1 ; then
1497   AC_CHECK_LIB(pthread, pthread_mutex_init)
1498   AC_SEARCH_LIBS(pthread_mutex_lock,pthread,
1499                  AC_DEFINE([HAVE_PTHREAD_MUTEX_LOCK],[1],
1500                            [Have pthread_mutex_lock]))
1501   AC_SEARCH_LIBS(pthread_rwlock_init,pthread,
1502                  AC_DEFINE([HAVE_PTHREAD_RWLOCK_INIT],[1],
1503                  [Have pthread_rwlock_init]))
1504   AC_SEARCH_LIBS(pthread_getspecific,pthread,
1505                  AC_DEFINE([HAVE_PTHREAD_GETSPECIFIC],[1],
1506                  [Have pthread_getspecific]))
1507 fi
1508
1509 dnl zlib is optional; used for compression/uncompression
1510 if test "$LLVM_ENABLE_ZLIB" -eq 1 ; then
1511   AC_CHECK_LIB(z, compress2)
1512 fi
1513
1514 dnl Allow OProfile support for JIT output.
1515 AC_ARG_WITH(oprofile,
1516   AS_HELP_STRING([--with-oprofile=<prefix>],
1517     [Tell OProfile >= 0.9.4 how to symbolize JIT output]),
1518     [
1519       AC_SUBST(USE_OPROFILE, [1])
1520       case "$withval" in
1521         /usr|yes) llvm_cv_oppath=/usr/lib/oprofile ;;
1522         no) llvm_cv_oppath=
1523             AC_SUBST(USE_OPROFILE, [0]) ;;
1524         *) llvm_cv_oppath="${withval}/lib/oprofile"
1525            CPPFLAGS="-I${withval}/include";;
1526       esac
1527       case $llvm_cv_os_type in
1528         Linux)
1529           if test -n "$llvm_cv_oppath" ; then
1530             LIBS="$LIBS -lopagent -L${llvm_cv_oppath} -Wl,-rpath,${llvm_cv_oppath}"
1531             dnl Work around http://bugs.debian.org/cgi-bin/bugreport.cgi?bug=537744:
1532             dnl libbfd is not included properly in libopagent in some Debian
1533             dnl versions.  If libbfd isn't found at all, we assume opagent works
1534             dnl anyway.
1535             AC_SEARCH_LIBS(bfd_init, bfd, [], [])
1536             AC_SEARCH_LIBS(op_open_agent, opagent, [], [
1537               echo "Error! You need to have libopagent around."
1538               exit -1
1539             ])
1540             AC_CHECK_HEADER([opagent.h], [], [
1541               echo "Error! You need to have opagent.h around."
1542               exit -1
1543               ])
1544           fi ;;
1545         *)
1546           AC_MSG_ERROR([OProfile support is available on Linux only.]) ;;
1547       esac
1548     ],
1549     [
1550       AC_SUBST(USE_OPROFILE, [0])
1551     ])
1552 AC_DEFINE_UNQUOTED([LLVM_USE_OPROFILE],$USE_OPROFILE,
1553                    [Define if we have the oprofile JIT-support library])
1554
1555 dnl Enable support for Intel JIT Events API.
1556 AC_ARG_WITH(intel-jitevents,
1557   AS_HELP_STRING([--with-intel-jitevents  Notify Intel JIT profiling API of generated code]),
1558     [
1559        case "$withval" in
1560           yes) AC_SUBST(USE_INTEL_JITEVENTS,[1]);;
1561           no)  AC_SUBST(USE_INTEL_JITEVENTS,[0]);;
1562           *) AC_MSG_ERROR([Invalid setting for --with-intel-jitevents. Use "yes" or "no"]);;
1563        esac
1564
1565       case $llvm_cv_os_type in
1566         Linux|Win32|Cygwin|MingW) ;;
1567         *) AC_MSG_ERROR([Intel JIT API support is available on Linux and Windows only.]);;
1568       esac
1569
1570       case "$llvm_cv_target_arch" in
1571         x86|x86_64) ;;
1572         *) AC_MSG_ERROR([Target architecture $llvm_cv_target_arch does not support Intel JIT Events API.]);;
1573       esac
1574     ],
1575     [
1576       AC_SUBST(USE_INTEL_JITEVENTS, [0])
1577     ])
1578 AC_DEFINE_UNQUOTED([LLVM_USE_INTEL_JITEVENTS],$USE_INTEL_JITEVENTS,
1579                    [Define if we have the Intel JIT API runtime support library])
1580
1581 dnl Check for libxml2
1582 dnl Right now we're just checking for the existence, we could also check for a
1583 dnl particular version via --version on xml2-config
1584 AC_CHECK_PROGS(XML2CONFIG, xml2-config)
1585
1586 AC_MSG_CHECKING(for libxml2 includes)
1587 if test "x$XML2CONFIG" = "x"; then
1588  AC_MSG_RESULT(xml2-config not found)
1589 else
1590  LIBXML2_INC=`$XML2CONFIG --cflags`
1591  AC_MSG_RESULT($LIBXML2_INC)
1592  AC_CHECK_LIB(xml2, xmlReadFile,[AC_DEFINE([CLANG_HAVE_LIBXML],1,[Define if we have libxml2])
1593                                 LIBXML2_LIBS="-lxml2"])
1594 fi
1595 AC_SUBST(LIBXML2_LIBS)
1596 AC_SUBST(LIBXML2_INC)
1597
1598 dnl===-----------------------------------------------------------------------===
1599 dnl===
1600 dnl=== SECTION 6: Check for header files
1601 dnl===
1602 dnl===-----------------------------------------------------------------------===
1603
1604 dnl First, use autoconf provided macros for specific headers that we need
1605 dnl We don't check for ancient stuff or things that are guaranteed to be there
1606 dnl by the C++ standard. We always use the <cfoo> versions of <foo.h> C headers.
1607 dnl Generally we're looking for POSIX headers.
1608 AC_HEADER_DIRENT
1609 AC_HEADER_MMAP_ANONYMOUS
1610 AC_HEADER_STAT
1611 AC_HEADER_SYS_WAIT
1612 AC_HEADER_TIME
1613
1614 AC_LANG_PUSH([C++])
1615 dnl size_t must be defined before including cxxabi.h on FreeBSD 10.0.
1616 AC_CHECK_HEADERS([cxxabi.h], [], [],
1617 [#include <stddef.h>
1618 ])
1619 AC_LANG_POP([C++])
1620
1621 AC_CHECK_HEADERS([dlfcn.h execinfo.h fcntl.h inttypes.h link.h])
1622 AC_CHECK_HEADERS([malloc.h setjmp.h signal.h stdint.h termios.h unistd.h])
1623 AC_CHECK_HEADERS([utime.h])
1624 AC_CHECK_HEADERS([sys/mman.h sys/param.h sys/resource.h sys/time.h sys/uio.h])
1625 AC_CHECK_HEADERS([sys/ioctl.h malloc/malloc.h mach/mach.h])
1626 AC_CHECK_HEADERS([valgrind/valgrind.h])
1627 AC_CHECK_HEADERS([fenv.h])
1628 AC_CHECK_DECLS([FE_ALL_EXCEPT, FE_INEXACT], [], [], [[#include <fenv.h>]])
1629 if test "$LLVM_ENABLE_THREADS" -eq 1 && test "$ENABLE_PTHREADS" -eq 1 ; then
1630   AC_CHECK_HEADERS(pthread.h,
1631                    AC_SUBST(HAVE_PTHREAD, 1),
1632                    AC_SUBST(HAVE_PTHREAD, 0))
1633 else
1634   AC_SUBST(HAVE_PTHREAD, 0)
1635 fi
1636 if test "$LLVM_ENABLE_ZLIB" -eq 1 ; then
1637   AC_CHECK_HEADERS(zlib.h,
1638                    AC_SUBST(HAVE_LIBZ, 1),
1639                    AC_SUBST(HAVE_LIBZ, 0))
1640 else
1641   AC_SUBST(HAVE_LIBZ, 0)
1642 fi
1643
1644 dnl Try to find ffi.h.
1645 if test "$llvm_cv_enable_libffi" = "yes" ; then
1646   AC_CHECK_HEADERS([ffi.h ffi/ffi.h])
1647 fi
1648
1649 dnl Try to find Darwin specific crash reporting libraries.
1650 AC_CHECK_HEADERS([CrashReporterClient.h])
1651
1652 dnl Try to find Darwin specific crash reporting global.
1653 AC_MSG_CHECKING([__crashreporter_info__])
1654 AC_LINK_IFELSE(
1655 [
1656   AC_LANG_SOURCE([[
1657     extern const char *__crashreporter_info__;
1658     int main() {
1659       __crashreporter_info__ = "test";
1660       return 0;
1661     }
1662   ]])
1663 ],
1664 [
1665   AC_MSG_RESULT([yes])
1666   AC_DEFINE([HAVE_CRASHREPORTER_INFO], [1], [can use __crashreporter_info__])
1667 ],
1668 [
1669   AC_MSG_RESULT([no])
1670   AC_DEFINE([HAVE_CRASHREPORTER_INFO], [0], [can use __crashreporter_info__])
1671 ])
1672
1673 dnl===-----------------------------------------------------------------------===
1674 dnl===
1675 dnl=== SECTION 7: Check for types and structures
1676 dnl===
1677 dnl===-----------------------------------------------------------------------===
1678
1679 AC_HUGE_VAL_CHECK
1680 AC_TYPE_PID_T
1681 AC_TYPE_SIZE_T
1682 AC_DEFINE_UNQUOTED([RETSIGTYPE],[void],[Define as the return type of signal handlers (`int' or `void').])
1683 AC_STRUCT_TM
1684 AC_CHECK_TYPES([int64_t],,AC_MSG_ERROR([Type int64_t required but not found]))
1685 AC_CHECK_TYPES([uint64_t],,
1686          AC_CHECK_TYPES([u_int64_t],,
1687          AC_MSG_ERROR([Type uint64_t or u_int64_t required but not found])))
1688
1689 dnl===-----------------------------------------------------------------------===
1690 dnl===
1691 dnl=== SECTION 8: Check for specific functions needed
1692 dnl===
1693 dnl===-----------------------------------------------------------------------===
1694
1695 AC_CHECK_FUNCS([backtrace ceilf floorf roundf rintf nearbyintf getcwd ])
1696 AC_CHECK_FUNCS([powf fmodf strtof round ])
1697 AC_CHECK_FUNCS([log log2 log10 exp exp2])
1698 AC_CHECK_FUNCS([getpagesize getrusage getrlimit setrlimit gettimeofday ])
1699 AC_CHECK_FUNCS([isatty mkdtemp mkstemp ])
1700 AC_CHECK_FUNCS([mktemp posix_spawn pread realpath sbrk setrlimit ])
1701 AC_CHECK_FUNCS([strerror strerror_r setenv ])
1702 AC_CHECK_FUNCS([strtoll strtoq sysconf malloc_zone_statistics ])
1703 AC_CHECK_FUNCS([setjmp longjmp sigsetjmp siglongjmp writev])
1704 AC_CHECK_FUNCS([futimes futimens])
1705 AC_C_PRINTF_A
1706 AC_FUNC_RAND48
1707
1708 dnl Check for arc4random accessible via AC_INCLUDES_DEFAULT.
1709 AC_CHECK_DECLS([arc4random])
1710
1711 dnl Check the declaration "Secure API" on Windows environments.
1712 AC_CHECK_DECLS([strerror_s])
1713
1714 dnl Check symbols in libgcc.a for JIT on Mingw.
1715 if test "$llvm_cv_os_type" = "MingW" ; then
1716   AC_CHECK_LIB(gcc,_alloca,AC_DEFINE([HAVE__ALLOCA],[1],[Have host's _alloca]))
1717   AC_CHECK_LIB(gcc,__alloca,AC_DEFINE([HAVE___ALLOCA],[1],[Have host's __alloca]))
1718   AC_CHECK_LIB(gcc,__chkstk,AC_DEFINE([HAVE___CHKSTK],[1],[Have host's __chkstk]))
1719   AC_CHECK_LIB(gcc,___chkstk,AC_DEFINE([HAVE____CHKSTK],[1],[Have host's ___chkstk]))
1720
1721   AC_CHECK_LIB(gcc,__ashldi3,AC_DEFINE([HAVE___ASHLDI3],[1],[Have host's __ashldi3]))
1722   AC_CHECK_LIB(gcc,__ashrdi3,AC_DEFINE([HAVE___ASHRDI3],[1],[Have host's __ashrdi3]))
1723   AC_CHECK_LIB(gcc,__divdi3,AC_DEFINE([HAVE___DIVDI3],[1],[Have host's __divdi3]))
1724   AC_CHECK_LIB(gcc,__fixdfdi,AC_DEFINE([HAVE___FIXDFDI],[1],[Have host's __fixdfdi]))
1725   AC_CHECK_LIB(gcc,__fixsfdi,AC_DEFINE([HAVE___FIXSFDI],[1],[Have host's __fixsfdi]))
1726   AC_CHECK_LIB(gcc,__floatdidf,AC_DEFINE([HAVE___FLOATDIDF],[1],[Have host's __floatdidf]))
1727   AC_CHECK_LIB(gcc,__lshrdi3,AC_DEFINE([HAVE___LSHRDI3],[1],[Have host's __lshrdi3]))
1728   AC_CHECK_LIB(gcc,__moddi3,AC_DEFINE([HAVE___MODDI3],[1],[Have host's __moddi3]))
1729   AC_CHECK_LIB(gcc,__udivdi3,AC_DEFINE([HAVE___UDIVDI3],[1],[Have host's __udivdi3]))
1730   AC_CHECK_LIB(gcc,__umoddi3,AC_DEFINE([HAVE___UMODDI3],[1],[Have host's __umoddi3]))
1731
1732   AC_CHECK_LIB(gcc,__main,AC_DEFINE([HAVE___MAIN],[1],[Have host's __main]))
1733   AC_CHECK_LIB(gcc,__cmpdi2,AC_DEFINE([HAVE___CMPDI2],[1],[Have host's __cmpdi2]))
1734 fi
1735
1736 dnl Check Win32 API EnumerateLoadedModules.
1737 if test "$llvm_cv_os_type" = "MingW" ; then
1738   AC_MSG_CHECKING([whether EnumerateLoadedModules() accepts new decl])
1739   AC_COMPILE_IFELSE(
1740 [
1741   AC_LANG_SOURCE([[
1742     #include <windows.h>
1743     #include <imagehlp.h>
1744     extern void foo(PENUMLOADED_MODULES_CALLBACK);
1745     extern void foo(BOOL(CALLBACK*)(PCSTR,ULONG_PTR,ULONG,PVOID));
1746   ]])
1747 ],
1748 [
1749   AC_MSG_RESULT([yes])
1750   llvm_cv_win32_elmcb_pcstr="PCSTR"
1751 ],
1752 [
1753   AC_MSG_RESULT([no])
1754   llvm_cv_win32_elmcb_pcstr="PSTR"
1755 ])
1756   AC_DEFINE_UNQUOTED([WIN32_ELMCB_PCSTR],$llvm_cv_win32_elmcb_pcstr,[Type of 1st arg on ELM Callback])
1757 fi
1758
1759 dnl Check for variations in the Standard C++ library and STL. These macros are
1760 dnl provided by LLVM in the autoconf/m4 directory.
1761 AC_FUNC_ISNAN
1762 AC_FUNC_ISINF
1763
1764 dnl Check for mmap support.We also need to know if /dev/zero is required to
1765 dnl be opened for allocating RWX memory.
1766 dnl Make sure we aren't attempting to configure for an unknown system
1767 if test "$llvm_cv_platform_type" = "Unix" ; then
1768   AC_FUNC_MMAP
1769   AC_FUNC_MMAP_FILE
1770   AC_NEED_DEV_ZERO_FOR_MMAP
1771
1772   if test "$ac_cv_func_mmap_fixed_mapped" = "no"
1773   then
1774     AC_MSG_WARN([mmap() of a fixed address required but not supported])
1775   fi
1776   if test "$ac_cv_func_mmap_file" = "no"
1777   then
1778     AC_MSG_WARN([mmap() of files required but not found])
1779   fi
1780 fi
1781
1782 dnl atomic builtins are required for threading support.
1783 AC_MSG_CHECKING(for GCC atomic builtins)
1784 dnl Since we'll be using these atomic builtins in C++ files we should test
1785 dnl the C++ compiler.
1786 AC_LANG_PUSH([C++])
1787 AC_LINK_IFELSE(
1788 [
1789   AC_LANG_SOURCE([[
1790     int main() {
1791       volatile unsigned long val = 1;
1792       __sync_synchronize();
1793       __sync_val_compare_and_swap(&val, 1, 0);
1794       __sync_add_and_fetch(&val, 1);
1795       __sync_sub_and_fetch(&val, 1);
1796       return 0;
1797     }
1798   ]])
1799 ],
1800 [
1801   AC_MSG_RESULT([yes])
1802   AC_DEFINE([LLVM_HAS_ATOMICS], [1], [Has gcc/MSVC atomic intrinsics])
1803 ],
1804 [
1805   AC_MSG_RESULT([no])
1806   AC_DEFINE([LLVM_HAS_ATOMICS], [0], [Has gcc/MSVC atomic intrinsics])
1807   AC_MSG_WARN([LLVM will be built thread-unsafe because atomic builtins are missing])
1808 ])
1809 AC_LANG_POP([C++])
1810
1811 dnl===-----------------------------------------------------------------------===
1812 dnl===
1813 dnl=== SECTION 9: Additional checks, variables, etc.
1814 dnl===
1815 dnl===-----------------------------------------------------------------------===
1816
1817 dnl Handle 32-bit linux systems running a 64-bit kernel.
1818 dnl This has to come after section 4 because it invokes the compiler.
1819 if test "$llvm_cv_os_type" = "Linux" -a "$llvm_cv_target_arch" = "x86_64" ; then
1820   AC_IS_LINUX_MIXED
1821   if test "$llvm_cv_linux_mixed" = "yes"; then
1822     llvm_cv_target_arch="x86"
1823     ARCH="x86"
1824   fi
1825 fi
1826
1827 dnl Check whether __dso_handle is present
1828 AC_CHECK_FUNCS([__dso_handle])
1829
1830 dnl Propagate the shared library extension that the libltdl checks did to
1831 dnl the Makefiles so we can use it there too
1832 AC_SUBST(SHLIBEXT,$llvm_shlib_ext)
1833
1834 dnl Translate the various configuration directories and other basic
1835 dnl information into substitutions that will end up in Makefile.config.in
1836 dnl that these configured values can be used by the makefiles
1837 if test "${prefix}" = "NONE" ; then
1838   prefix="/usr/local"
1839 fi
1840 eval LLVM_PREFIX="${prefix}";
1841 eval LLVM_BINDIR="${prefix}/bin";
1842 eval LLVM_DATADIR="${prefix}/share/llvm";
1843 eval LLVM_DOCSDIR="${prefix}/share/doc/llvm";
1844 eval LLVM_ETCDIR="${prefix}/etc/llvm";
1845 eval LLVM_INCLUDEDIR="${prefix}/include";
1846 eval LLVM_INFODIR="${prefix}/info";
1847 eval LLVM_MANDIR="${prefix}/man";
1848 LLVM_CONFIGTIME=`date`
1849 AC_SUBST(LLVM_PREFIX)
1850 AC_SUBST(LLVM_BINDIR)
1851 AC_SUBST(LLVM_DATADIR)
1852 AC_SUBST(LLVM_DOCSDIR)
1853 AC_SUBST(LLVM_ETCDIR)
1854 AC_SUBST(LLVM_INCLUDEDIR)
1855 AC_SUBST(LLVM_INFODIR)
1856 AC_SUBST(LLVM_MANDIR)
1857 AC_SUBST(LLVM_CONFIGTIME)
1858
1859 dnl Disable embedding timestamps in the build directory, with ENABLE_TIMESTAMPS.
1860 if test "${ENABLE_TIMESTAMPS}" = "0"; then
1861   LLVM_CONFIGTIME="(timestamp not enabled)"
1862 fi
1863
1864 dnl Place the various directories into the config.h file as #defines so that we
1865 dnl can know about the installation paths within LLVM.
1866 AC_DEFINE_UNQUOTED(LLVM_PREFIX,"$LLVM_PREFIX",
1867                    [Installation prefix directory])
1868 AC_DEFINE_UNQUOTED(LLVM_BINDIR, "$LLVM_BINDIR",
1869                    [Installation directory for binary executables])
1870 AC_DEFINE_UNQUOTED(LLVM_DATADIR, "$LLVM_DATADIR",
1871                    [Installation directory for data files])
1872 AC_DEFINE_UNQUOTED(LLVM_DOCSDIR, "$LLVM_DOCSDIR",
1873                    [Installation directory for documentation])
1874 AC_DEFINE_UNQUOTED(LLVM_ETCDIR, "$LLVM_ETCDIR",
1875                    [Installation directory for config files])
1876 AC_DEFINE_UNQUOTED(LLVM_INCLUDEDIR, "$LLVM_INCLUDEDIR",
1877                    [Installation directory for include files])
1878 AC_DEFINE_UNQUOTED(LLVM_INFODIR, "$LLVM_INFODIR",
1879                    [Installation directory for .info files])
1880 AC_DEFINE_UNQUOTED(LLVM_MANDIR, "$LLVM_MANDIR",
1881                    [Installation directory for man pages])
1882 AC_DEFINE_UNQUOTED(LLVM_CONFIGTIME, "$LLVM_CONFIGTIME",
1883                    [Time at which LLVM was configured])
1884 AC_DEFINE_UNQUOTED(LLVM_HOST_TRIPLE, "$host",
1885                    [Host triple LLVM will be executed on])
1886 AC_DEFINE_UNQUOTED(LLVM_DEFAULT_TARGET_TRIPLE, "$target",
1887                    [Target triple LLVM will generate code for by default])
1888
1889 dnl Determine which bindings to build.
1890 if test "$BINDINGS_TO_BUILD" = auto ; then
1891   BINDINGS_TO_BUILD=""
1892   if test "x$OCAMLFIND" != x ; then
1893     BINDINGS_TO_BUILD="ocaml $BINDINGS_TO_BUILD"
1894   fi
1895   if test "x$GO" != x ; then
1896     if $GO run ${srcdir}/bindings/go/conftest.go ; then
1897       BINDINGS_TO_BUILD="go $BINDINGS_TO_BUILD"
1898     fi
1899   fi
1900 fi
1901 AC_SUBST(BINDINGS_TO_BUILD,$BINDINGS_TO_BUILD)
1902
1903 dnl Do any work necessary to ensure that bindings have what they need.
1904 binding_prereqs_failed=0
1905 for a_binding in $BINDINGS_TO_BUILD ; do
1906   case "$a_binding" in
1907   ocaml)
1908     if test "x$OCAMLFIND" = x ; then
1909       AC_MSG_WARN([--enable-bindings=ocaml specified, but ocamlfind not found. Try configure OCAMLFIND=/path/to/ocamlfind])
1910       binding_prereqs_failed=1
1911     fi
1912
1913     if $OCAMLFIND opt -version >/dev/null 2>/dev/null ; then
1914       HAVE_OCAMLOPT=1
1915     else
1916       HAVE_OCAMLOPT=0
1917     fi
1918     AC_SUBST(HAVE_OCAMLOPT)
1919
1920     if ! $OCAMLFIND query ctypes >/dev/null 2>/dev/null; then
1921       AC_MSG_WARN([--enable-bindings=ocaml specified, but ctypes is not installed])
1922       binding_prereqs_failed=1
1923     fi
1924
1925     if $OCAMLFIND query oUnit >/dev/null 2>/dev/null; then
1926       HAVE_OCAML_OUNIT=1
1927     else
1928       HAVE_OCAML_OUNIT=0
1929       AC_MSG_WARN([--enable-bindings=ocaml specified, but OUnit 2 is not installed. Tests will not run])
1930       dnl oUnit is optional!
1931     fi
1932     AC_SUBST(HAVE_OCAML_OUNIT)
1933
1934     if test "x$with_ocaml_libdir" != xauto ; then
1935       AC_SUBST(OCAML_LIBDIR,$with_ocaml_libdir)
1936     else
1937       ocaml_stdlib="`"$OCAMLFIND" ocamlc -where`"
1938       if test "$LLVM_PREFIX" '<' "$ocaml_stdlib" -a "$ocaml_stdlib" '<' "$LLVM_PREFIX~"
1939       then
1940         # ocaml stdlib is beneath our prefix; use stdlib
1941         AC_SUBST(OCAML_LIBDIR,$ocaml_stdlib)
1942       else
1943         # ocaml stdlib is outside our prefix; use libdir/ocaml
1944         AC_SUBST(OCAML_LIBDIR,${prefix}/lib/ocaml)
1945       fi
1946     fi
1947     ;;
1948   go)
1949     if test "x$GO" = x ; then
1950       AC_MSG_WARN([--enable-bindings=go specified, but go not found. Try configure GO=/path/to/go])
1951       binding_prereqs_failed=1
1952     else
1953       if $GO run ${srcdir}/bindings/go/conftest.go ; then
1954         :
1955       else
1956         AC_MSG_WARN([--enable-bindings=go specified, but need at least Go 1.2. Try configure GO=/path/to/go])
1957         binding_prereqs_failed=1
1958       fi
1959     fi
1960     ;;
1961   esac
1962 done
1963 if test "$binding_prereqs_failed" = 1 ; then
1964   AC_MSG_ERROR([Prequisites for bindings not satisfied. Fix them or use configure --disable-bindings.])
1965 fi
1966
1967 dnl Determine whether the compiler supports -fvisibility-inlines-hidden.
1968 AC_CXX_USE_VISIBILITY_INLINES_HIDDEN
1969
1970 dnl Determine linker rpath flag
1971 if test "$llvm_cv_link_use_r" = "yes" ; then
1972   RPATH="-Wl,-R"
1973 else
1974   RPATH="-Wl,-rpath"
1975 fi
1976 AC_SUBST(RPATH)
1977
1978 dnl Determine linker rdynamic flag
1979 if test "$llvm_cv_link_use_export_dynamic" = "yes" ; then
1980   RDYNAMIC="-rdynamic"
1981 else
1982   RDYNAMIC=""
1983 fi
1984 AC_SUBST(RDYNAMIC)
1985
1986 dnl===-----------------------------------------------------------------------===
1987 dnl===
1988 dnl=== SECTION 10: Specify the output files and generate it
1989 dnl===
1990 dnl===-----------------------------------------------------------------------===
1991
1992 dnl Configure header files
1993 dnl WARNING: dnl If you add or remove any of the following config headers, then
1994 dnl you MUST also update Makefile so that the variable FilesToConfig
1995 dnl contains the same list of files as AC_CONFIG_HEADERS below. This ensures the
1996 dnl files can be updated automatically when their *.in sources change.
1997 AC_CONFIG_HEADERS([include/llvm/Config/config.h include/llvm/Config/llvm-config.h])
1998 AH_TOP([#ifndef CONFIG_H
1999 #define CONFIG_H])
2000 AH_BOTTOM([#endif])
2001
2002 AC_CONFIG_FILES([include/llvm/Config/Targets.def])
2003 AC_CONFIG_FILES([include/llvm/Config/AsmPrinters.def])
2004 AC_CONFIG_FILES([include/llvm/Config/AsmParsers.def])
2005 AC_CONFIG_FILES([include/llvm/Config/Disassemblers.def])
2006 AC_CONFIG_HEADERS([include/llvm/Support/DataTypes.h])
2007
2008 dnl Configure the makefile's configuration data
2009 AC_CONFIG_FILES([Makefile.config])
2010
2011 dnl Configure the RPM spec file for LLVM
2012 AC_CONFIG_FILES([llvm.spec])
2013
2014 dnl Configure doxygen's configuration file
2015 AC_CONFIG_FILES([docs/doxygen.cfg])
2016
2017 dnl Configure clang, if present
2018 if test "${clang_src_root}" = ""; then
2019   clang_src_root="$srcdir/tools/clang"
2020 fi
2021 if test -f ${clang_src_root}/README.txt; then
2022   dnl Clang supports build systems which use the multilib libdir suffix.
2023   dnl The autoconf system doesn't support this so stub out that variable.
2024   AC_DEFINE_UNQUOTED(CLANG_LIBDIR_SUFFIX,"",
2025                      [Multilib suffix for libdir.])
2026
2027   dnl Use variables to stay under 80 columns.
2028   configh="include/clang/Config/config.h"
2029   doxy="docs/doxygen.cfg"
2030   AC_CONFIG_HEADERS([tools/clang/${configh}:${clang_src_root}/${configh}.in])
2031   AC_CONFIG_FILES([tools/clang/${doxy}:${clang_src_root}/${doxy}.in])
2032 fi
2033
2034 dnl OCaml findlib META file
2035 AC_CONFIG_FILES([bindings/ocaml/llvm/META.llvm])
2036
2037 dnl Add --program-prefix value to Makefile.rules. Already an ARG variable.
2038 test "x$program_prefix" = "xNONE" && program_prefix=""
2039 AC_SUBST([program_prefix])
2040
2041
2042 dnl Do special configuration of Makefiles
2043 AC_CONFIG_COMMANDS([setup],,[llvm_src="${srcdir}"])
2044 AC_CONFIG_MAKEFILE(Makefile)
2045 AC_CONFIG_MAKEFILE(Makefile.common)
2046 AC_CONFIG_MAKEFILE(examples/Makefile)
2047 AC_CONFIG_MAKEFILE(lib/Makefile)
2048 AC_CONFIG_MAKEFILE(test/Makefile)
2049 AC_CONFIG_MAKEFILE(test/Makefile.tests)
2050 AC_CONFIG_MAKEFILE(unittests/Makefile)
2051 AC_CONFIG_MAKEFILE(tools/Makefile)
2052 AC_CONFIG_MAKEFILE(utils/Makefile)
2053 AC_CONFIG_MAKEFILE(projects/Makefile)
2054 AC_CONFIG_MAKEFILE(bindings/Makefile)
2055 AC_CONFIG_MAKEFILE(bindings/ocaml/Makefile.ocaml)
2056
2057 dnl Finally, crank out the output
2058 AC_OUTPUT