autoconf/configure.ac

   1 dnl Autoconf requirements
   2 dnl AC_INIT(package, version, bug-report-address)
   3 dnl information on the package
   4 dnl checks for programs
   5 dnl checks for libraries
   6 dnl checks for header files
   7 dnl checks for types
   8 dnl checks for structures
   9 dnl checks for compiler characteristics
  10 dnl checks for library functions
  11 dnl checks for system services
  12 dnl AC_CONFIG_FILES([file...])
  13 dnl AC_OUTPUT
  14
  15 dnl **************************************************************************
  16 dnl * Initialize
  17 dnl **************************************************************************
  18 AC_INIT([[[LLVM]]],[[[1.0]]],[llvmbugs@cs.uiuc.edu])
  19
  20 dnl Place all of the extra autoconf files into the config subdirectory
  21 AC_CONFIG_AUX_DIR([autoconf])
  22
  23 dnl Quit if the source directory has already been configured.
  24 dnl NOTE: This relies upon undocumented autoconf behavior.
  25 if test ${srcdir} != "."
  26 then
  27         if test -f ${srcdir}/include/Config/config.h
  28         then
  29                 AC_MSG_ERROR([Already configured in ${srcdir}])
  30         fi
  31 fi
  32
  33 dnl Configure a header file
  34 AC_CONFIG_HEADERS(include/Config/config.h)
  35 AC_CONFIG_MAKEFILE(Makefile)
  36 AC_CONFIG_MAKEFILE(Makefile.common)
  37 AC_CONFIG_MAKEFILE(Makefile.rules)
  38 AC_CONFIG_MAKEFILE(lib/Makefile)
  39 AC_CONFIG_MAKEFILE(lib/Analysis/Makefile)
  40 AC_CONFIG_MAKEFILE(lib/Analysis/DataStructure/Makefile)
  41 AC_CONFIG_MAKEFILE(lib/Analysis/IPA/Makefile)
  42 AC_CONFIG_MAKEFILE(lib/Analysis/LiveVar/Makefile)
  43 AC_CONFIG_MAKEFILE(lib/AsmParser/Makefile)
  44 AC_CONFIG_MAKEFILE(lib/Bytecode/Makefile)
  45 AC_CONFIG_MAKEFILE(lib/Bytecode/Reader/Makefile)
  46 AC_CONFIG_MAKEFILE(lib/Bytecode/Writer/Makefile)
  47 AC_CONFIG_MAKEFILE(lib/CWriter/Makefile)
  48 AC_CONFIG_MAKEFILE(lib/CodeGen/Makefile)
  49 AC_CONFIG_MAKEFILE(lib/CodeGen/InstrSched/Makefile)
  50 AC_CONFIG_MAKEFILE(lib/CodeGen/InstrSelection/Makefile)
  51 AC_CONFIG_MAKEFILE(lib/CodeGen/ModuloScheduling/Makefile)
  52 AC_CONFIG_MAKEFILE(lib/CodeGen/RegAlloc/Makefile)
  53 AC_CONFIG_MAKEFILE(lib/CodeGen/SelectionDAG/Makefile)
  54 AC_CONFIG_MAKEFILE(lib/ExecutionEngine/Makefile)
  55 AC_CONFIG_MAKEFILE(lib/ExecutionEngine/Interpreter/Makefile)
  56 AC_CONFIG_MAKEFILE(lib/ExecutionEngine/JIT/Makefile)
  57 AC_CONFIG_MAKEFILE(lib/Target/Makefile)
  58 AC_CONFIG_MAKEFILE(lib/Target/Sparc/Makefile)
  59 AC_CONFIG_MAKEFILE(lib/Target/X86/Makefile)
  60 AC_CONFIG_MAKEFILE(lib/Transforms/Makefile)
  61 AC_CONFIG_MAKEFILE(lib/Transforms/Hello/Makefile)
  62 AC_CONFIG_MAKEFILE(lib/Transforms/IPO/Makefile)
  63 AC_CONFIG_MAKEFILE(lib/Transforms/Instrumentation/Makefile)
  64 AC_CONFIG_MAKEFILE(lib/Transforms/Instrumentation/ProfilePaths/Makefile)
  65 AC_CONFIG_MAKEFILE(lib/Transforms/Scalar/Makefile)
  66 AC_CONFIG_MAKEFILE(lib/Transforms/Utils/Makefile)
  67 AC_CONFIG_MAKEFILE(lib/VMCore/Makefile)
  68 AC_CONFIG_MAKEFILE(runtime/Makefile)
  69 AC_CONFIG_MAKEFILE(runtime/GCCLibraries/Makefile)
  70 AC_CONFIG_MAKEFILE(runtime/GCCLibraries/crtend/Makefile)
  71 AC_CONFIG_MAKEFILE(runtime/GCCLibraries/libc/Makefile)
  72 AC_CONFIG_MAKEFILE(runtime/GCCLibraries/libcurses/Makefile)
  73 AC_CONFIG_MAKEFILE(runtime/GCCLibraries/libg/Makefile)
  74 AC_CONFIG_MAKEFILE(runtime/GCCLibraries/libgcc/Makefile)
  75 AC_CONFIG_MAKEFILE(runtime/GCCLibraries/libm/Makefile)
  76 AC_CONFIG_MAKEFILE(runtime/GCCLibraries/libmalloc/Makefile)
  77 AC_CONFIG_MAKEFILE(runtime/GCCLibraries/libtermcap/Makefile)
  78 AC_CONFIG_MAKEFILE(runtime/GCCLibraries/libucb/Makefile)
  79 AC_CONFIG_MAKEFILE(runtime/GCCLibraries/libutempter/Makefile)
  80 AC_CONFIG_MAKEFILE(runtime/GCCLibraries/libutil/Makefile)
  81 AC_CONFIG_MAKEFILE(runtime/libdummy/Makefile)
  82 AC_CONFIG_MAKEFILE(runtime/libtrace/Makefile)
  83 AC_CONFIG_MAKEFILE(test/Makefile)
  84 AC_CONFIG_MAKEFILE(test/Makefile.tests)
  85 AC_CONFIG_MAKEFILE(test/QMTestDB/QMTest/llvm.py)
  86 AC_CONFIG_MAKEFILE(test/Programs/Makefile)
  87 AC_CONFIG_MAKEFILE(test/Programs/Makefile.programs)
  88 AC_CONFIG_MAKEFILE(test/Programs/TEST.aa.Makefile)
  89 AC_CONFIG_MAKEFILE(test/Programs/TEST.dsgraph.report)
  90 AC_CONFIG_MAKEFILE(test/Programs/TEST.micro.report)
  91 AC_CONFIG_MAKEFILE(test/Programs/TEST.aa.report)
  92 AC_CONFIG_MAKEFILE(test/Programs/TEST.example.Makefile)
  93 AC_CONFIG_MAKEFILE(test/Programs/TEST.nightly.Makefile)
  94 AC_CONFIG_MAKEFILE(test/Programs/TEST.buildrepo.Makefile)
  95 AC_CONFIG_MAKEFILE(test/Programs/TEST.jit.Makefile)
  96 AC_CONFIG_MAKEFILE(test/Programs/TEST.nightly.report)
  97 AC_CONFIG_MAKEFILE(test/Programs/TEST.dsgraph.Makefile)
  98 AC_CONFIG_MAKEFILE(test/Programs/TEST.jit.report)
  99 AC_CONFIG_MAKEFILE(test/Programs/TEST.typesafe.Makefile)
 100 AC_CONFIG_MAKEFILE(test/Programs/TEST.dsgraph.gnuplot)
 101 AC_CONFIG_MAKEFILE(test/Programs/TEST.micro.Makefile)
 102 AC_CONFIG_MAKEFILE(test/Programs/External/Makefile)
 103 AC_CONFIG_MAKEFILE(test/Programs/External/SPEC/Makefile)
 104 AC_CONFIG_MAKEFILE(test/Programs/External/SPEC/Makefile.spec)
 105 AC_CONFIG_MAKEFILE(test/Programs/External/SPEC/CFP2000/Makefile)
 106 AC_CONFIG_MAKEFILE(test/Programs/External/SPEC/CFP2000/179.art/Makefile)
 107 AC_CONFIG_MAKEFILE(test/Programs/External/SPEC/CFP2000/183.equake/Makefile)
 108 AC_CONFIG_MAKEFILE(test/Programs/External/SPEC/CFP2000/188.ammp/Makefile)
 109 AC_CONFIG_MAKEFILE(test/Programs/External/SPEC/CINT2000/Makefile)
 110 AC_CONFIG_MAKEFILE(test/Programs/External/SPEC/CINT2000/164.gzip/Makefile)
 111 AC_CONFIG_MAKEFILE(test/Programs/External/SPEC/CINT2000/175.vpr/Makefile)
 112 AC_CONFIG_MAKEFILE(test/Programs/External/SPEC/CINT2000/176.gcc/Makefile)
 113 AC_CONFIG_MAKEFILE(test/Programs/External/SPEC/CINT2000/181.mcf/Makefile)
 114 AC_CONFIG_MAKEFILE(test/Programs/External/SPEC/CINT2000/186.crafty/Makefile)
 115 AC_CONFIG_MAKEFILE(test/Programs/External/SPEC/CINT2000/197.parser/Makefile)
 116 AC_CONFIG_MAKEFILE(test/Programs/External/SPEC/CINT2000/254.gap/Makefile)
 117 AC_CONFIG_MAKEFILE(test/Programs/External/SPEC/CINT2000/255.vortex/Makefile)
 118 AC_CONFIG_MAKEFILE(test/Programs/External/SPEC/CINT2000/256.bzip2/Makefile)
 119 AC_CONFIG_MAKEFILE(test/Programs/External/SPEC/CINT2000/300.twolf/Makefile)
 120 AC_CONFIG_MAKEFILE(test/Programs/LLVMSource/Makefile)
 121 AC_CONFIG_MAKEFILE(test/Programs/MultiSource/Makefile)
 122 AC_CONFIG_MAKEFILE(test/Programs/MultiSource/Makefile.multisrc)
 123 AC_CONFIG_MAKEFILE(test/Programs/MultiSource/Applications/Makefile)
 124 AC_CONFIG_MAKEFILE(test/Programs/MultiSource/Applications/Burg/Makefile)
 125 AC_CONFIG_MAKEFILE(test/Programs/MultiSource/Applications/aha/Makefile)
 126 AC_CONFIG_MAKEFILE(test/Programs/MultiSource/Applications/sgefa/Makefile)
 127 AC_CONFIG_MAKEFILE(test/Programs/MultiSource/Benchmarks/Makefile)
 128 AC_CONFIG_MAKEFILE(test/Programs/MultiSource/Benchmarks/Fhourstones/Makefile)
 129 AC_CONFIG_MAKEFILE(test/Programs/MultiSource/Benchmarks/McCat/Makefile)
 130 AC_CONFIG_MAKEFILE(test/Programs/MultiSource/Benchmarks/McCat/01-qbsort/Makefile)
 131 AC_CONFIG_MAKEFILE(test/Programs/MultiSource/Benchmarks/McCat/03-testtrie/Makefile)
 132 AC_CONFIG_MAKEFILE(test/Programs/MultiSource/Benchmarks/McCat/04-bisect/Makefile)
 133 AC_CONFIG_MAKEFILE(test/Programs/MultiSource/Benchmarks/McCat/05-eks/Makefile)
 134 AC_CONFIG_MAKEFILE(test/Programs/MultiSource/Benchmarks/McCat/08-main/Makefile)
 135 AC_CONFIG_MAKEFILE(test/Programs/MultiSource/Benchmarks/McCat/09-vor/Makefile)
 136 AC_CONFIG_MAKEFILE(test/Programs/MultiSource/Benchmarks/McCat/12-IOtest/Makefile)
 137 AC_CONFIG_MAKEFILE(test/Programs/MultiSource/Benchmarks/McCat/15-trie/Makefile)
 138 AC_CONFIG_MAKEFILE(test/Programs/MultiSource/Benchmarks/McCat/17-bintr/Makefile)
 139 AC_CONFIG_MAKEFILE(test/Programs/MultiSource/Benchmarks/McCat/18-imp/Makefile)
 140 AC_CONFIG_MAKEFILE(test/Programs/MultiSource/Benchmarks/Olden/Makefile)
 141 AC_CONFIG_MAKEFILE(test/Programs/MultiSource/Benchmarks/Olden/bh/Makefile)
 142 AC_CONFIG_MAKEFILE(test/Programs/MultiSource/Benchmarks/Olden/bisort/Makefile)
 143 AC_CONFIG_MAKEFILE(test/Programs/MultiSource/Benchmarks/Olden/em3d/Makefile)
 144 AC_CONFIG_MAKEFILE(test/Programs/MultiSource/Benchmarks/Olden/health/Makefile)
 145 AC_CONFIG_MAKEFILE(test/Programs/MultiSource/Benchmarks/Olden/mst/Makefile)
 146 AC_CONFIG_MAKEFILE(test/Programs/MultiSource/Benchmarks/Olden/perimeter/Makefile)
 147 AC_CONFIG_MAKEFILE(test/Programs/MultiSource/Benchmarks/Olden/power/Makefile)
 148 AC_CONFIG_MAKEFILE(test/Programs/MultiSource/Benchmarks/Olden/treeadd/Makefile)
 149 AC_CONFIG_MAKEFILE(test/Programs/MultiSource/Benchmarks/Olden/tsp/Makefile)
 150 AC_CONFIG_MAKEFILE(test/Programs/MultiSource/Benchmarks/Olden/voronoi/Makefile)
 151 AC_CONFIG_MAKEFILE(test/Programs/MultiSource/Benchmarks/OptimizerEval/Makefile)
 152 AC_CONFIG_MAKEFILE(test/Programs/MultiSource/Benchmarks/Ptrdist/Makefile)
 153 AC_CONFIG_MAKEFILE(test/Programs/MultiSource/Benchmarks/Ptrdist/anagram/Makefile)
 154 AC_CONFIG_MAKEFILE(test/Programs/MultiSource/Benchmarks/Ptrdist/bc/Makefile)
 155 AC_CONFIG_MAKEFILE(test/Programs/MultiSource/Benchmarks/Ptrdist/ft/Makefile)
 156 AC_CONFIG_MAKEFILE(test/Programs/MultiSource/Benchmarks/Ptrdist/ks/Makefile)
 157 AC_CONFIG_MAKEFILE(test/Programs/MultiSource/Benchmarks/Ptrdist/yacr2/Makefile)
 158 AC_CONFIG_MAKEFILE(test/Programs/MultiSource/Benchmarks/llubenchmark/Makefile)
 159 AC_CONFIG_MAKEFILE(test/Programs/MultiSource/Benchmarks/sim/Makefile)
 160 AC_CONFIG_MAKEFILE(test/Programs/NoSource/Makefile)
 161 AC_CONFIG_MAKEFILE(test/Programs/NoSource/Flex/Makefile)
 162 AC_CONFIG_MAKEFILE(test/Programs/NoSource/Larn/Makefile)
 163 AC_CONFIG_MAKEFILE(test/Programs/NoSource/Moria-5.5.2/Makefile)
 164 AC_CONFIG_MAKEFILE(test/Programs/NoSource/Povray31/Makefile)
 165 AC_CONFIG_MAKEFILE(test/Programs/NoSource/m4/Makefile)
 166 AC_CONFIG_MAKEFILE(test/Programs/SingleSource/Makefile)
 167 AC_CONFIG_MAKEFILE(test/Programs/SingleSource/Makefile.singlesrc)
 168 AC_CONFIG_MAKEFILE(test/Programs/SingleSource/Gizmos/Makefile)
 169 AC_CONFIG_MAKEFILE(test/Programs/SingleSource/Benchmarks/Makefile)
 170 AC_CONFIG_MAKEFILE(test/Programs/SingleSource/Benchmarks/Dhrystone/Makefile)
 171 AC_CONFIG_MAKEFILE(test/Programs/SingleSource/Benchmarks/Shootout/Makefile)
 172 AC_CONFIG_MAKEFILE(test/Programs/SingleSource/Benchmarks/Stanford/Makefile)
 173 AC_CONFIG_MAKEFILE(test/Programs/SingleSource/Benchmarks/Misc/Makefile)
 174 AC_CONFIG_MAKEFILE(test/Programs/SingleSource/CustomChecked/Makefile)
 175 AC_CONFIG_MAKEFILE(test/Programs/SingleSource/UnitTests/Makefile)
 176 AC_CONFIG_MAKEFILE(test/Programs/SingleSource/UnitTests/SetjmpLongjmp/Makefile)
 177 AC_CONFIG_MAKEFILE(test/Programs/SingleSource/Regression/Makefile)
 178 AC_CONFIG_MAKEFILE(test/Programs/SingleSource/Regression/C/Makefile)
 179 AC_CONFIG_MAKEFILE(test/Programs/SingleSource/Regression/C++/Makefile)
 180 AC_CONFIG_MAKEFILE(test/Programs/SingleSource/Regression/C++/EH/Makefile)
 181 AC_CONFIG_MAKEFILE(test/Programs/SingleSource/Regression/C++/CompileFail/Makefile)
 182 AC_CONFIG_MAKEFILE(tools/Makefile)
 183 AC_CONFIG_MAKEFILE(tools/analyze/Makefile)
 184 AC_CONFIG_MAKEFILE(tools/bugpoint/Makefile)
 185 AC_CONFIG_MAKEFILE(tools/extract/Makefile)
 186 AC_CONFIG_MAKEFILE(tools/gccas/Makefile)
 187 AC_CONFIG_MAKEFILE(tools/gccld/Makefile)
 188 AC_CONFIG_MAKEFILE(tools/llc/Makefile)
 189 AC_CONFIG_MAKEFILE(tools/llee/Makefile)
 190 AC_CONFIG_MAKEFILE(tools/lli/Makefile)
 191 AC_CONFIG_MAKEFILE(tools/llvm-ar/Makefile)
 192 AC_CONFIG_MAKEFILE(tools/llvm-as/Makefile)
 193 AC_CONFIG_MAKEFILE(tools/llvm-dis/Makefile)
 194 AC_CONFIG_MAKEFILE(tools/llvm-link/Makefile)
 195 AC_CONFIG_MAKEFILE(tools/opt/Makefile)
 196 AC_CONFIG_MAKEFILE(www/docs/Makefile)
 197 AC_CONFIG_MAKEFILE(projects/Makefile)
 198 AC_CONFIG_MAKEFILE(projects/sample/Makefile)
 199 AC_CONFIG_MAKEFILE(projects/sample/Makefile.common)
 200 AC_CONFIG_MAKEFILE(projects/sample/Makefile.config)
 201 AC_CONFIG_MAKEFILE(projects/sample/lib/Makefile)
 202 AC_CONFIG_MAKEFILE(projects/sample/lib/sample/Makefile)
 203 AC_CONFIG_MAKEFILE(projects/sample/tools/Makefile)
 204 AC_CONFIG_MAKEFILE(projects/sample/tools/sample/Makefile)
 205 AC_CONFIG_MAKEFILE(projects/ModuleMaker/Makefile)
 206 AC_CONFIG_MAKEFILE(projects/ModuleMaker/Makefile.common)
 207 AC_CONFIG_MAKEFILE(projects/ModuleMaker/tools/Makefile)
 208 AC_CONFIG_MAKEFILE(projects/ModuleMaker/tools/ModuleMaker/Makefile)
 209 AC_CONFIG_MAKEFILE(support/Makefile)
 210 AC_CONFIG_MAKEFILE(support/lib/Makefile)
 211 AC_CONFIG_MAKEFILE(support/lib/Support/Makefile)
 212 AC_CONFIG_MAKEFILE(support/tools/Makefile)
 213 AC_CONFIG_MAKEFILE(support/tools/Burg/Makefile)
 214 AC_CONFIG_MAKEFILE(support/tools/Burg/Doc/Makefile)
 215 AC_CONFIG_MAKEFILE(support/tools/TableGen/Makefile)
 216
 217 dnl **************************************************************************
 218 dnl * Determine which system we are building on
 219 dnl **************************************************************************
 220
 221 dnl Check the install program (needs to be done before canonical stuff)
 222 AC_PROG_INSTALL
 223
 224 dnl Check which host for which we're compiling.  This will tell us which LLVM
 225 dnl compiler will be used for compiling SSA into object code.
 226 AC_CANONICAL_TARGET
 227
 228 dnl
 229 dnl Now, for some of our own magic:
 230 dnl We will use the build machine information to set some variables.
 231 dnl
 232 case $build in
 233         *i*86*)  AC_SUBST(OS,[Linux])
 234                  AC_SUBST(LLVMGCCDIR,[/home/vadve/lattner/local/x86/llvm-gcc/])
 235                  ;;
 236
 237         *sparc*) AC_SUBST(OS,[SunOS])
 238                  AC_SUBST(LLVMGCCDIR,[/home/vadve/lattner/local/sparc/llvm-gcc/])
 239                  ;;
 240
 241         *)       AC_SUBST(OS,[Unknown])
 242                  ;;
 243 esac
 244
 245 dnl
 246 dnl If we are targetting a Sparc machine running Solaris, pretend that it is
 247 dnl V9, since that is all that we support at the moment, and autoconf will only
 248 dnl tell us we're a sparc.
 249 dnl
 250 case $target in
 251         *sparc*solaris*)  AC_SUBST(target,[[sparcv9-sun-solaris2.8]])
 252                           ;;
 253 esac
 254
 255 dnl
 256 dnl Determine what our target architecture is and configure accordingly.
 257 dnl This will allow Makefiles to make a distinction between the hardware and
 258 dnl the OS.
 259 dnl
 260 case $target in
 261         *i*86*)           AC_SUBST(ARCH,[x86])
 262                           ;;
 263         *sparc*solaris*)  AC_SUBST(ARCH,[Sparc])
 264                           ;;
 265 esac
 266
 267 dnl **************************************************************************
 268 dnl * Check for programs.
 269 dnl **************************************************************************
 270
 271 dnl Check for compilation tools
 272 AC_PROG_CXX
 273 AC_PROG_CC(gcc)
 274 AC_PROG_CPP
 275
 276 dnl Ensure that compilation tools are GCC; we use GCC specific extensions
 277 if test "$GCC" != "yes"
 278 then
 279         AC_MSG_ERROR([gcc required but not found])
 280 fi
 281
 282 if test "$GXX" != "yes"
 283 then
 284         AC_MSG_ERROR([g++ required but not found])
 285 fi
 286
 287 dnl Verify that GCC is version 3.0 or higher
 288 gccmajor=`$CC --version | head -n 1 | awk '{print $NF;}' | cut -d. -f1`
 289 if test "$gccmajor" -lt "3"
 290 then
 291         AC_MSG_ERROR([gcc 3.x required])
 292 fi
 293
 294 dnl Check for GNU Make.  We use its extensions to, so don't build without it
 295 CHECK_GNU_MAKE
 296 if test -z "$_cv_gnu_make_command"
 297 then
 298         AC_MSG_ERROR([GNU Make required but not found])
 299 fi
 300
 301 dnl Check for compiler-compiler tools (reminds me of Little Caesar's Pizza)
 302 AC_PROG_FLEX
 303 AC_PROG_BISON
 304
 305 dnl Check for libtool
 306 AC_PROG_LIBTOOL
 307
 308 dnl Check for our special programs
 309 AC_PATH_PROG(RPWD,[pwd],[false])
 310 if test ${RPWD} = "false"
 311 then
 312         AC_MSG_ERROR([pwd required but not found])
 313 fi
 314
 315 AC_PATH_PROG(AR,[ar],[false])
 316 if test ${AR} = "false"
 317 then
 318         AC_MSG_ERROR([ar required but not found])
 319 fi
 320
 321 AC_PATH_PROG(SED,[sed],[false])
 322 if test ${SED} = "false"
 323 then
 324         AC_MSG_ERROR([sed required but not found])
 325 fi
 326
 327 AC_PATH_PROG(RM,[rm],[false])
 328 if test ${RM} = "false"
 329 then
 330         AC_MSG_ERROR([rm required but not found])
 331 fi
 332
 333 AC_PATH_PROG(ECHO,[echo],[false])
 334 if test ${ECHO} = "false"
 335 then
 336         AC_MSG_ERROR([echo required but not found])
 337 fi
 338
 339 AC_PATH_PROG(MKDIR,[mkdir],[false])
 340 if test ${MKDIR} = "false"
 341 then
 342         AC_MSG_ERROR([mkdir required but not found])
 343 fi
 344
 345 AC_PATH_PROG(DATE,[date],[false])
 346 if test ${DATE} = "false"
 347 then
 348         AC_MSG_ERROR([date required but not found])
 349 fi
 350
 351 AC_PATH_PROG(MV,[mv],[false])
 352 if test ${MV} = "false"
 353 then
 354         AC_MSG_ERROR([mv required but not found])
 355 fi
 356
 357 AC_PATH_PROG(DOT,[dot],[false])
 358
 359 AC_PATH_PROG(ETAGS,[etags],[false])
 360
 361 AC_PATH_PROG(PURIFY,[purify],[false])
 362
 363 AC_PATH_PROG(PYTHON,[python],[false])
 364 if test ${PYTHON} = "false"
 365 then
 366         AC_MSG_WARN([python required but not found])
 367 fi
 368
 369 AC_PATH_PROG(QMTEST,[qmtest],[false])
 370 if test ${QMTEST} = "false"
 371 then
 372         AC_MSG_WARN([qmtest required but not found])
 373 fi
 374
 375 dnl Verify that the version of python available is high enough for qmtest
 376 pyversion=`$PYTHON -V 2>&1 | cut -d\  -f2`
 377 pymajor=`echo $pyversion | cut -d. -f1`
 378 pyminor=`echo $pyversion | cut -d. -f2`
 379
 380 if test "$pymajor" -ge "2"
 381 then
 382         if test "$pymajor" -eq "2"
 383         then
 384                 if test "$pyminor" -lt "2"
 385                 then
 386                         AC_MSG_ERROR([Python 2.2 or greater required])
 387                 fi
 388         fi
 389 else
 390         AC_MSG_ERROR([Python 2.2 or greater required])
 391 fi
 392
 393 dnl Verify that the source directory is valid
 394 AC_CONFIG_SRCDIR(["Makefile.config.in"])
 395
 396 dnl **************************************************************************
 397 dnl * Check for libraries.
 398 dnl **************************************************************************
 399
 400 dnl libelf is for sparc only; we can ignore it if we don't have it
 401 AC_CHECK_LIB(elf, elf_begin)
 402
 403 dnl dlopen() is required.  If we don't find it, quit.
 404 AC_SEARCH_LIBS(dlopen,dl,,AC_MSG_ERROR([dlopen() required but not found]))
 405
 406 dnl mallinfo is optional; the code can compile (minus features) without it
 407 AC_SEARCH_LIBS(mallinfo,malloc,AC_DEFINE([HAVE_MALLINFO],[1]))
 408
 409 dnl
 410 dnl The math libraries are used by the test code, but not by the actual LLVM
 411 dnl code.
 412 dnl
 413 dnl AC_CHECK_LIB(m, cos)
 414
 415 dnl **************************************************************************
 416 dnl * Checks for header files.
 417 dnl *   Chances are, if the standard C or POSIX type header files are missing,
 418 dnl *   then LLVM just isn't going to compile.  However, it is possible that
 419 dnl *   the necessary functions/macros will be included from other
 420 dnl *   (non-standard and non-obvious) header files.
 421 dnl *
 422 dnl *   So, we'll be gracious, give it a chance, and try to go on without
 423 dnl *   them.
 424 dnl **************************************************************************
 425 AC_HEADER_STDC
 426 AC_HEADER_SYS_WAIT
 427
 428 dnl Check for ANSI C/POSIX header files
 429 AC_CHECK_HEADERS(assert.h fcntl.h limits.h sys/time.h unistd.h errno.h signal.h math.h)
 430
 431 dnl Check for system specific header files
 432 AC_CHECK_HEADERS(malloc.h strings.h sys/mman.h sys/resource.h)
 433
 434 dnl Check for header files associated with dlopen and friends
 435 AC_CHECK_HEADERS(dlfcn.h link.h)
 436
 437 dnl **************************************************************************
 438 dnl * Checks for typedefs, structures, and compiler characteristics.
 439 dnl **************************************************************************
 440
 441 dnl Check for const and inline keywords
 442 AC_C_CONST
 443 AC_C_INLINE
 444
 445 dnl Check for machine endian-ness
 446 AC_C_BIGENDIAN(AC_DEFINE([ENDIAN_BIG]),AC_DEFINE(ENDIAN_LITTLE))
 447
 448 dnl Check for types
 449 AC_TYPE_PID_T
 450 AC_TYPE_SIZE_T
 451 AC_CHECK_TYPES([int64_t],,AC_MSG_ERROR([Type int64_t required but not found]))
 452 AC_CHECK_TYPES([uint64_t],,AC_MSG_ERROR([Type uint64_t required but not found]))
 453 AC_HEADER_TIME
 454 AC_STRUCT_TM
 455
 456 dnl Check for C++ extensions
 457 AC_CXX_HAVE_EXT_HASH_MAP
 458 AC_CXX_HAVE_EXT_HASH_SET
 459 AC_CXX_HAVE_EXT_SLIST
 460 AC_CXX_HAVE_STD_ITERATOR
 461 AC_CXX_HAVE_BI_ITERATOR
 462 AC_CXX_HAVE_FWD_ITERATOR
 463
 464 dnl **************************************************************************
 465 dnl * Checks for library functions.
 466 dnl **************************************************************************
 467 AC_FUNC_ALLOCA
 468 AC_PROG_GCC_TRADITIONAL
 469 AC_FUNC_MEMCMP
 470 AC_FUNC_MMAP
 471 AC_FUNC_MMAP_FILE
 472 if test ${ac_cv_func_mmap_file} = "no"
 473 then
 474         AC_MSG_ERROR([mmap() of files required but not found])
 475 fi
 476 AC_HEADER_MMAP_ANONYMOUS
 477 AC_TYPE_SIGNAL
 478 AC_CHECK_FUNCS(getcwd gettimeofday strcspn strdup strerror strspn strstr strtod strtol)
 479
 480 dnl
 481 dnl Need to check mmap for MAP_PRIVATE, MAP_ANONYMOUS, MAP_ANON, MAP_FIXED
 482 dnl MAP_FIXED is only needed for Sparc
 483 dnl MAP_ANON is used for Sparc and BSD
 484 dnl Everyone should have MAP_PRIVATE
 485 dnl
 486
 487 dnl Check for certain functions (even if we've already found them) so that we
 488 dnl can quit with an error if they are unavailable.
 489 dnl
 490 dnl As the code is made more portable (i.e. less reliant on these functions,
 491 dnl these checks should go away.
 492 AC_CHECK_FUNC(mmap,,AC_MSG_ERROR([Function mmap() required but not found]))
 493 AC_CHECK_FUNC(mprotect,,AC_MSG_ERROR([Function mprotect() required but not found]))
 494
 495 dnl **************************************************************************
 496 dnl * Enable various compile-time options
 497 dnl **************************************************************************
 498
 499 dnl Purify Option
 500 AC_ARG_ENABLE(purify,AC_HELP_STRING([--enable-purify],[Compile with purify (default is NO)]),,enableval="no")
 501 if test ${enableval} = "no"
 502 then
 503         AC_SUBST(ENABLE_PURIFY,[[]])
 504 else
 505         AC_SUBST(ENABLE_PURIFY,[[ENABLE_PURIFY=1]])
 506 fi
 507
 508 dnl Optimized Option
 509 AC_ARG_ENABLE(optimized,AC_HELP_STRING([--enable-optimized],[Compile with optimizations enabled (default is NO)]),,enableval=no)
 510 if test ${enableval} = "no"
 511 then
 512         AC_SUBST(ENABLE_OPTIMIZED,[[]])
 513 else
 514         AC_SUBST(ENABLE_OPTIMIZED,[[ENABLE_OPTIMIZED=1]])
 515 fi
 516
 517 dnl Spec Benchmarks
 518 AC_ARG_ENABLE(spec,AC_HELP_STRING([--enable-spec],[Compile SPEC benchmarks (default is NO)]),,enableval=no)
 519 if test ${enableval} = "no"
 520 then
 521         AC_SUBST(USE_SPEC,[[]])
 522 else
 523         AC_SUBST(USE_SPEC,[[USE_SPEC=1]])
 524 fi
 525
 526 dnl Precompiled Bytecode Option
 527 AC_ARG_ENABLE(precompiled_bytecode,AC_HELP_STRING([--enable-precompiled_bytecode],[Use pre-compiled bytecode (default is NO)]),,enableval=no)
 528 if test ${enableval} = "no"
 529 then
 530         AC_SUBST(UPB,[[]])
 531 else
 532         AC_SUBST(UPB,[[USE_PRECOMPILED_BYTECODE=1]])
 533 fi
 534
 535
 536 dnl LLC Diff Option
 537 AC_ARG_ENABLE(llc_diffs,AC_HELP_STRING([--enable-llc_diffs],[Enable LLC Diffs when testing (default is YES)]),,enableval=yes)
 538 if test ${enableval} = "no"
 539 then
 540         AC_SUBST(DISABLE_LLC_DIFFS,[DISABLE_LLC_DIFFS:=1])
 541 else
 542         AC_SUBST(DISABLE_LLC_DIFFS,[[]])
 543 fi
 544
 545 dnl JIT Option
 546 AC_ARG_ENABLE(jit,AC_HELP_STRING([--enable-jit],[Enable Just In Time Compiling (default is YES)]),,enableval=default)
 547
 548 if test ${enableval} = "no"
 549 then
 550         AC_SUBST(JIT,[[]])
 551 else
 552         case $target in
 553                 *i*86*)
 554                         AC_SUBST(JIT,[[TARGET_HAS_JIT=1]])
 555                         ;;
 556                 *sparc*)
 557                         AC_SUBST(JIT,[[TARGET_HAS_JIT=1]])
 558                         ;;
 559                 *)
 560                         AC_SUBST(JIT,[[]])
 561                         ;;
 562         esac
 563 fi
 564
 565 dnl **************************************************************************
 566 dnl * Set the location of various third-party software packages
 567 dnl **************************************************************************
 568
 569 dnl Location of SPEC benchmarks
 570 AC_ARG_WITH(spec,AC_HELP_STRING([--with-spec],[Location of SPEC benchmarks]),AC_SUBST(SPEC_ROOT,[$withval]),AC_SUBST(SPEC_ROOT,[/home/vadve/shared/benchmarks/speccpu2000/benchspec]))
 571
 572 dnl Location of the LLVM C front end
 573 AC_ARG_WITH(llvmgccdir,AC_HELP_STRING([--with-llvmgccdir],[Location of LLVM GCC front-end]),AC_SUBST(LLVMGCCDIR,[$withval]))
 574
 575 dnl Location of the bytecode repository
 576 AC_ARG_WITH(bcrepos,AC_HELP_STRING([--with-bcrepos],[Location of Bytecode Repository]),AC_SUBST(BCR,[$withval]),AC_SUBST(BCR,[/home/vadve/lattner/LLVMPrograms]))
 577
 578 dnl Location of PAPI
 579 AC_ARG_WITH(papi,AC_HELP_STRING([--with-papi],[Location of PAPI]),AC_SUBST(PAPIDIR,[$withval]),AC_SUBST(PAPIDIR,[/home/vadve/shared/Sparc/papi-2.3.4.1]))
 580
 581 dnl Location of the purify program
 582 AC_ARG_WITH(purify,AC_HELP_STRING([--with-purify],[Location of purify program]),AC_SUBST(PURIFY,[$withval]))
 583
 584 dnl **************************************************************************
 585 dnl * Configure other software packages (via AC_CONFIG_SUBDIRS)
 586 dnl **************************************************************************
 587
 588 dnl **************************************************************************
 589 dnl * Create the output files
 590 dnl **************************************************************************
 591 AC_OUTPUT(Makefile.config)