CMakeLists.txt

   1 project(LLVM)
   2 cmake_minimum_required(VERSION 2.6.1)
   3
   4 set(PACKAGE_NAME llvm)
   5 set(PACKAGE_VERSION svn)
   6 set(PACKAGE_BUGREPORT "llvmbugs@cs.uiuc.edu")
   7
   8 include(FindPerl)
   9
  10 set(LLVM_MAIN_SRC_DIR ${CMAKE_CURRENT_SOURCE_DIR})
  11 set(LLVM_MAIN_INCLUDE_DIR ${LLVM_MAIN_SRC_DIR}/include)
  12 set(LLVM_BINARY_DIR ${CMAKE_CURRENT_BINARY_DIR})
  13 set(LLVM_TOOLS_BINARY_DIR ${LLVM_BINARY_DIR}/bin)
  14 set(LLVM_EXAMPLES_BINARY_DIR ${LLVM_BINARY_DIR}/examples)
  15
  16 if( MSVC )
  17   set(LLVM_TARGETS_TO_BUILD X86
  18     CACHE STRING "Semicolon-separated list of targets to build")
  19 else( MSVC )
  20   set(LLVM_TARGETS_TO_BUILD
  21     Alpha ARM CBackend CellSPU CppBackend IA64 Mips MSIL PIC16 PowerPC Sparc X86
  22     CACHE STRING "Semicolon-separated list of targets to build")
  23 endif( MSVC )
  24
  25 set(llvm_builded_incs_dir ${LLVM_BINARY_DIR}/include/llvm)
  26
  27 # Add path for custom modules
  28 set(CMAKE_MODULE_PATH
  29   ${CMAKE_MODULE_PATH}
  30   "${LLVM_MAIN_SRC_DIR}/cmake"
  31   "${LLVM_MAIN_SRC_DIR}/cmake/modules"
  32   )
  33
  34 if(WIN32)
  35   if(CYGWIN)
  36     set(LLVM_ON_WIN32 0)
  37     set(LLVM_ON_UNIX 1)
  38   else(CYGWIN)
  39     set(LLVM_ON_WIN32 1)
  40     set(LLVM_ON_UNIX 0)
  41   endif(CYGWIN)
  42   set(LTDL_SHLIB_EXT ".dll")
  43   set(EXEEXT ".exe")
  44   # Maximum path length is 160 for non-unicode paths
  45   set(MAXPATHLEN 160)
  46 else(WIN32)
  47   if(UNIX)
  48     set(LLVM_ON_WIN32 0)
  49     set(LLVM_ON_UNIX 1)
  50     set(LTDL_SHLIB_EXT ".so")
  51     set(EXEEXT "")
  52     # FIXME: Maximum path length is currently set to 'safe' fixed value
  53     set(MAXPATHLEN 2024)
  54   else(UNIX)
  55     MESSAGE(SEND_ERROR "Unable to determine platform")
  56   endif(UNIX)
  57 endif(WIN32)
  58
  59 if( EXISTS ${LLVM_TOOLS_BINARY_DIR}/llvm-config )
  60   set(HAVE_LLVM_CONFIG 1)
  61 endif( EXISTS ${LLVM_TOOLS_BINARY_DIR}/llvm-config )
  62 # find_file(HAVE_LLVM_CONFIG llvm-config ${LLVM_TOOLS_BINARY_DIR})
  63 # message(STATUS ${HAVE_LLVM_CONFIG})
  64
  65 include(config-ix)
  66
  67 set( CMAKE_RUNTIME_OUTPUT_DIRECTORY ${LLVM_TOOLS_BINARY_DIR} )
  68 set( CMAKE_LIBRARY_OUTPUT_DIRECTORY ${LLVM_BINARY_DIR}/lib )
  69 set( CMAKE_ARCHIVE_OUTPUT_DIRECTORY ${LLVM_BINARY_DIR}/lib )
  70
  71 # set(CMAKE_VERBOSE_MAKEFILE true)
  72
  73 add_definitions( -D__STDC_LIMIT_MACROS )
  74 add_definitions( -D__STDC_CONSTANT_MACROS )
  75
  76 set(LLVM_PLO_FLAGS "" CACHE
  77   STRING "Flags for creating partially linked objects.")
  78
  79 if( CMAKE_SIZEOF_VOID_P EQUAL 8 AND NOT WIN32 )
  80   # TODO: support other platforms and toolchains.
  81   option(BUILD_32_BITS "Build 32 bits executables and libraries." OFF)
  82   if( BUILD_32_BITS )
  83     message(STATUS "Building 32 bits executables and libraries.")
  84     add_definitions( -m32 )
  85     set( CMAKE_EXE_LINKER_FLAGS "-m32 ${CMAKE_EXE_LINKER_FLAGS}" )
  86     set( CMAKE_LINK_LIBRARY_FLAG "-m32 ${CMAKE_LINK_LIBRARY_FLAG}" )
  87     set( LLVM_PLO_FLAGS -melf_i386 ${LLVM_PLO_FLAGS} )
  88   endif( BUILD_32_BITS )
  89 endif( CMAKE_SIZEOF_VOID_P EQUAL 8 AND NOT WIN32 )
  90
  91 if( MSVC )
  92   add_definitions( -D_CRT_SECURE_NO_DEPRECATE -D_CRT_SECURE_NO_WARNINGS )
  93   add_definitions( -D_SCL_SECURE_NO_WARNINGS -DCRT_NONSTDC_NO_WARNINGS )
  94   add_definitions( -D_SCL_SECURE_NO_DEPRECATE )
  95   add_definitions( -wd4146 -wd4503 -wd4996 -wd4800 -wd4244 -wd4624 )
  96   add_definitions( -wd4355 -wd4715 )
  97 endif( MSVC )
  98
  99 include_directories( ${LLVM_BINARY_DIR}/include ${LLVM_MAIN_INCLUDE_DIR})
 100 #link_directories( d:/dev/lib )
 101
 102 #add_subdirectory(lib)
 103
 104 include(AddLLVM)
 105 include(AddPartiallyLinkedObject)
 106 include(TableGen)
 107
 108 add_subdirectory(lib/Support)
 109 add_subdirectory(lib/System)
 110
 111 # Everything else depends on Support and System:
 112 set(LLVM_COMMON_DEPENDS ${LLVM_COMMON_DEPENDS} ${LLVM_LIBS} )
 113
 114 add_subdirectory(utils/TableGen)
 115
 116 add_custom_command(OUTPUT ${llvm_builded_incs_dir}/Intrinsics.gen
 117   COMMAND tblgen -gen-intrinsic -I ${LLVM_MAIN_INCLUDE_DIR} ${LLVM_MAIN_INCLUDE_DIR}/llvm/Intrinsics.td -o ${llvm_builded_incs_dir}/Intrinsics.gen
 118   DEPENDS tblgen
 119   COMMENT "Building intrinsics.gen...")
 120
 121 add_custom_target(intrinsics_gen ALL
 122   DEPENDS ${llvm_builded_incs_dir}/Intrinsics.gen)
 123
 124 set(LLVM_COMMON_DEPENDS ${LLVM_COMMON_DEPENDS} intrinsics_gen )
 125
 126 add_subdirectory(lib/VMCore)
 127 add_subdirectory(lib/CodeGen)
 128 add_subdirectory(lib/CodeGen/SelectionDAG)
 129 add_subdirectory(lib/CodeGen/AsmPrinter)
 130 add_subdirectory(lib/Bitcode/Reader)
 131 add_subdirectory(lib/Bitcode/Writer)
 132 add_subdirectory(lib/Transforms/Utils)
 133 add_subdirectory(lib/Transforms/Instrumentation)
 134 add_subdirectory(lib/Transforms/Scalar)
 135 add_subdirectory(lib/Transforms/IPO)
 136 add_subdirectory(lib/Transforms/Hello)
 137 add_subdirectory(lib/Linker)
 138 add_subdirectory(lib/Analysis)
 139 add_subdirectory(lib/Analysis/IPA)
 140
 141 foreach(t ${LLVM_TARGETS_TO_BUILD})
 142   message(STATUS "Targeting ${t}")
 143   add_subdirectory(lib/Target/${t})
 144   if( EXISTS ${CMAKE_SOURCE_DIR}/lib/Target/${t}/AsmPrinter/CMakeLists.txt )
 145     add_subdirectory(lib/Target/${t}/AsmPrinter)
 146   endif( EXISTS ${CMAKE_SOURCE_DIR}/lib/Target/${t}/AsmPrinter/CMakeLists.txt )
 147 endforeach(t)
 148
 149 add_subdirectory(lib/ExecutionEngine)
 150 add_subdirectory(lib/ExecutionEngine/Interpreter)
 151 add_subdirectory(lib/ExecutionEngine/JIT)
 152 add_subdirectory(lib/Target)
 153 add_subdirectory(lib/AsmParser)
 154 add_subdirectory(lib/Debugger)
 155 add_subdirectory(lib/Archive)
 156
 157 add_subdirectory(tools)
 158
 159 add_subdirectory(examples)
 160
 161 install(DIRECTORY include
 162   DESTINATION .
 163   PATTERN ".svn" EXCLUDE
 164   PATTERN "*.cmake" EXCLUDE
 165   PATTERN "*.in" EXCLUDE
 166   )
 167
 168 install(DIRECTORY ${CMAKE_CURRENT_BINARY_DIR}/include
 169   DESTINATION .
 170   )
 171
 172 # TODO: make and install documentation.