CMakeLists.txt

   1 # See docs/CMake.html for instructions about how to build LLVM with CMake.
   2
   3 project(LLVM)
   4 cmake_minimum_required(VERSION 2.6.1)
   5
   6 set(PACKAGE_NAME llvm)
   7 set(PACKAGE_VERSION 2.6svn)
   8 set(PACKAGE_STRING "${PACKAGE_NAME} ${PACKAGE_VERSION}")
   9 set(PACKAGE_BUGREPORT "llvmbugs@cs.uiuc.edu")
  10
  11 if( CMAKE_SOURCE_DIR STREQUAL CMAKE_BINARY_DIR AND NOT MSVC_IDE )
  12   message(FATAL_ERROR "In-source builds are not allowed.
  13 CMake would overwrite the makefiles distributed with LLVM.
  14 Please create a directory and run cmake from there, passing the path
  15 to this source directory as the last argument.
  16 This process created the file `CMakeCache.txt' and the directory `CMakeFiles'.
  17 Please delete them.")
  18 endif()
  19
  20 string(TOUPPER "${CMAKE_BUILD_TYPE}" uppercase_CMAKE_BUILD_TYPE)
  21
  22 include(FindPerl)
  23
  24 set(LLVM_MAIN_SRC_DIR ${CMAKE_CURRENT_SOURCE_DIR})
  25 set(LLVM_MAIN_INCLUDE_DIR ${LLVM_MAIN_SRC_DIR}/include)
  26 set(LLVM_BINARY_DIR ${CMAKE_CURRENT_BINARY_DIR})
  27 set(LLVM_TOOLS_BINARY_DIR ${LLVM_BINARY_DIR}/bin)
  28 set(LLVM_EXAMPLES_BINARY_DIR ${LLVM_BINARY_DIR}/examples)
  29
  30 set(LLVM_ALL_TARGETS
  31   Alpha
  32   ARM
  33   CBackend
  34   CellSPU
  35   CppBackend
  36   IA64
  37   Mips
  38   MSIL
  39   PIC16
  40   PowerPC
  41   Sparc
  42   X86
  43   XCore
  44   )
  45
  46 # List of targets whose asmprinters need to be forced to link
  47 # into executables on some platforms (i.e. Windows):
  48 set(LLVM_ASMPRINTERS_FORCE_LINK X86 PowerPC)
  49
  50 if( MSVC )
  51   set(LLVM_TARGETS_TO_BUILD X86
  52     CACHE STRING "Semicolon-separated list of targets to build, or \"all\".")
  53 else( MSVC )
  54   set(LLVM_TARGETS_TO_BUILD ${LLVM_ALL_TARGETS}
  55     CACHE STRING "Semicolon-separated list of targets to build, or \"all\".")
  56 endif( MSVC )
  57
  58 option(LLVM_ENABLE_THREADS "Use threads if available." ON)
  59
  60 if( uppercase_CMAKE_BUILD_TYPE STREQUAL "RELEASE" )
  61   option(LLVM_ENABLE_ASSERTIONS "Enable assertions" OFF)
  62 else()
  63   option(LLVM_ENABLE_ASSERTIONS "Enable assertions" ON)
  64 endif()
  65
  66 if( LLVM_ENABLE_ASSERTIONS )
  67   add_definitions( -D_DEBUG )
  68   # On Release builds cmake automatically defines NDEBUG, so we
  69   # explicitly undefine it:
  70   if( uppercase_CMAKE_BUILD_TYPE STREQUAL "RELEASE" )
  71     add_definitions( -UNDEBUG )
  72   endif()
  73 else()
  74   if( NOT uppercase_CMAKE_BUILD_TYPE STREQUAL "RELEASE" )
  75     add_definitions( -DNDEBUG )
  76   endif()
  77 endif()
  78
  79 if( LLVM_TARGETS_TO_BUILD STREQUAL "all" )
  80   set( LLVM_TARGETS_TO_BUILD ${LLVM_ALL_TARGETS} )
  81 endif()
  82
  83 foreach(c ${LLVM_TARGETS_TO_BUILD})
  84   list(FIND LLVM_ALL_TARGETS ${c} idx)
  85   if( idx LESS 0 )
  86     message(FATAL_ERROR "The target `${c}' does not exists.
  87     It should be one of\n${LLVM_ALL_TARGETS}")
  88   endif()
  89 endforeach(c)
  90
  91 set(llvm_builded_incs_dir ${LLVM_BINARY_DIR}/include/llvm)
  92
  93 # The USE_EXPLICIT_DEPENDENCIES variable will be TRUE to indicate that
  94 # we should use the library dependencies explicitly specified in the
  95 # CMakeLists.txt files rather than those determined by
  96 # llvm-config. This value must be true for non-make and IDE
  97 # generators.
  98 if (MSVC_IDE)
  99   set(DEFAULT_USE_EXPLICIT_DEPENDENCIES ON)
 100 elseif (XCODE)
 101   set(DEFAULT_USE_EXPLICIT_DEPENDENCIES ON)
 102 else ()
 103  set(DEFAULT_USE_EXPLICIT_DEPENDENCIES OFF)
 104 endif ()
 105
 106 option(USE_EXPLICIT_DEPENDENCIES
 107   "Use explicit dependencies instead of llvm-config"
 108   ${DEFAULT_USE_EXPLICIT_DEPENDENCIES})
 109 mark_as_advanced(USE_EXPLICIT_DEPENDENCIES)
 110
 111 # Add path for custom modules
 112 set(CMAKE_MODULE_PATH
 113   ${CMAKE_MODULE_PATH}
 114   "${LLVM_MAIN_SRC_DIR}/cmake"
 115   "${LLVM_MAIN_SRC_DIR}/cmake/modules"
 116   )
 117
 118 include(AddLLVMDefinitions)
 119
 120 if(WIN32)
 121   if(CYGWIN)
 122     set(LLVM_ON_WIN32 0)
 123     set(LLVM_ON_UNIX 1)
 124   else(CYGWIN)
 125     set(LLVM_ON_WIN32 1)
 126     set(LLVM_ON_UNIX 0)
 127   endif(CYGWIN)
 128   set(LTDL_SHLIB_EXT ".dll")
 129   set(EXEEXT ".exe")
 130   # Maximum path length is 160 for non-unicode paths
 131   set(MAXPATHLEN 160)
 132 else(WIN32)
 133   if(UNIX)
 134     set(LLVM_ON_WIN32 0)
 135     set(LLVM_ON_UNIX 1)
 136     set(LTDL_SHLIB_EXT ".so")
 137     set(EXEEXT "")
 138     # FIXME: Maximum path length is currently set to 'safe' fixed value
 139     set(MAXPATHLEN 2024)
 140   else(UNIX)
 141     MESSAGE(SEND_ERROR "Unable to determine platform")
 142   endif(UNIX)
 143 endif(WIN32)
 144
 145 if( EXISTS ${LLVM_TOOLS_BINARY_DIR}/llvm-config )
 146   set(HAVE_LLVM_CONFIG 1)
 147 endif( EXISTS ${LLVM_TOOLS_BINARY_DIR}/llvm-config )
 148
 149 include(config-ix)
 150
 151 option(LLVM_ENABLE_PIC "Build Position-Independent Code" OFF)
 152
 153 if( LLVM_ENABLE_PIC )
 154   if( SUPPORTS_FPIC_FLAG )
 155     message(STATUS "Building with -fPIC")
 156     add_llvm_definitions(-fPIC)
 157   else( SUPPORTS_FPIC_FLAG )
 158     message(STATUS "Warning: -fPIC not supported.")
 159   endif()
 160 endif()
 161
 162 set( CMAKE_RUNTIME_OUTPUT_DIRECTORY ${LLVM_TOOLS_BINARY_DIR} )
 163 set( CMAKE_LIBRARY_OUTPUT_DIRECTORY ${LLVM_BINARY_DIR}/lib )
 164 set( CMAKE_ARCHIVE_OUTPUT_DIRECTORY ${LLVM_BINARY_DIR}/lib )
 165
 166 # set(CMAKE_VERBOSE_MAKEFILE true)
 167
 168 add_llvm_definitions( -D__STDC_LIMIT_MACROS )
 169 add_llvm_definitions( -D__STDC_CONSTANT_MACROS )
 170
 171 set(LLVM_PLO_FLAGS "" CACHE
 172   STRING "Flags for creating partially linked objects.")
 173
 174 if( CMAKE_SIZEOF_VOID_P EQUAL 8 AND NOT WIN32 )
 175   # TODO: support other platforms and toolchains.
 176   option(LLVM_BUILD_32_BITS "Build 32 bits executables and libraries." OFF)
 177   if( LLVM_BUILD_32_BITS )
 178     message(STATUS "Building 32 bits executables and libraries.")
 179     add_llvm_definitions( -m32 )
 180     list(APPEND CMAKE_EXE_LINKER_FLAGS -m32)
 181     list(APPEND CMAKE_SHARED_LINKER_FLAGS -m32)
 182     set( LLVM_PLO_FLAGS -melf_i386 ${LLVM_PLO_FLAGS} )
 183   endif( LLVM_BUILD_32_BITS )
 184 endif( CMAKE_SIZEOF_VOID_P EQUAL 8 AND NOT WIN32 )
 185
 186 if( MSVC )
 187   add_llvm_definitions( -D_CRT_SECURE_NO_DEPRECATE -D_CRT_SECURE_NO_WARNINGS )
 188   add_llvm_definitions( -D_SCL_SECURE_NO_WARNINGS -DCRT_NONSTDC_NO_WARNINGS )
 189   add_llvm_definitions( -D_SCL_SECURE_NO_DEPRECATE )
 190   add_llvm_definitions( -wd4146 -wd4503 -wd4996 -wd4800 -wd4244 -wd4624 )
 191   add_llvm_definitions( -wd4355 -wd4715 -wd4180 -wd4345 -wd4224 )
 192 endif( MSVC )
 193
 194 include_directories( ${LLVM_BINARY_DIR}/include ${LLVM_MAIN_INCLUDE_DIR})
 195
 196 include(AddLLVM)
 197 include(AddPartiallyLinkedObject)
 198 include(TableGen)
 199
 200 add_subdirectory(lib/Support)
 201 add_subdirectory(lib/System)
 202
 203 # Everything else depends on Support and System:
 204 set(LLVM_COMMON_DEPENDS ${LLVM_COMMON_DEPENDS} ${LLVM_LIBS} )
 205
 206 set(LLVM_TABLEGEN "tblgen" CACHE
 207   STRING "Native TableGen executable. Saves building one when cross-compiling.")
 208
 209 add_subdirectory(utils/TableGen)
 210
 211 if( CMAKE_CROSSCOMPILING )
 212   # This adds a dependency on target `tblgen', so must go after utils/TableGen
 213   include( CrossCompileLLVM )
 214 endif( CMAKE_CROSSCOMPILING )
 215
 216 add_subdirectory(include/llvm)
 217
 218 add_subdirectory(lib/VMCore)
 219 add_subdirectory(lib/CodeGen)
 220 add_subdirectory(lib/CodeGen/SelectionDAG)
 221 add_subdirectory(lib/CodeGen/AsmPrinter)
 222 add_subdirectory(lib/Bitcode/Reader)
 223 add_subdirectory(lib/Bitcode/Writer)
 224 add_subdirectory(lib/Transforms/Utils)
 225 add_subdirectory(lib/Transforms/Instrumentation)
 226 add_subdirectory(lib/Transforms/Scalar)
 227 add_subdirectory(lib/Transforms/IPO)
 228 add_subdirectory(lib/Transforms/Hello)
 229 add_subdirectory(lib/Linker)
 230 add_subdirectory(lib/Analysis)
 231 add_subdirectory(lib/Analysis/IPA)
 232
 233 foreach(t ${LLVM_TARGETS_TO_BUILD})
 234   message(STATUS "Targeting ${t}")
 235   add_subdirectory(lib/Target/${t})
 236   if( EXISTS ${LLVM_MAIN_SRC_DIR}/lib/Target/${t}/AsmPrinter/CMakeLists.txt )
 237     add_subdirectory(lib/Target/${t}/AsmPrinter)
 238   endif( EXISTS ${LLVM_MAIN_SRC_DIR}/lib/Target/${t}/AsmPrinter/CMakeLists.txt )
 239 endforeach(t)
 240
 241 add_subdirectory(lib/ExecutionEngine)
 242 add_subdirectory(lib/ExecutionEngine/Interpreter)
 243 add_subdirectory(lib/ExecutionEngine/JIT)
 244 add_subdirectory(lib/Target)
 245 add_subdirectory(lib/AsmParser)
 246 add_subdirectory(lib/Debugger)
 247 add_subdirectory(lib/Archive)
 248
 249 add_subdirectory(projects)
 250 add_subdirectory(tools)
 251
 252 add_subdirectory(examples)
 253
 254 install(DIRECTORY include
 255   DESTINATION .
 256   PATTERN ".svn" EXCLUDE
 257   PATTERN "*.cmake" EXCLUDE
 258   PATTERN "*.in" EXCLUDE
 259   )
 260
 261 install(DIRECTORY ${CMAKE_CURRENT_BINARY_DIR}/include
 262   DESTINATION .
 263   )
 264
 265 # TODO: make and install documentation.