CMakeLists.txt

   1 # See docs/CMake.html for instructions about how to build LLVM with CMake.
   2
   3 project(LLVM)
   4 cmake_minimum_required(VERSION 2.8)
   5
   6 # Add path for custom modules
   7 set(CMAKE_MODULE_PATH
   8   ${CMAKE_MODULE_PATH}
   9   "${CMAKE_CURRENT_SOURCE_DIR}/cmake"
  10   "${CMAKE_CURRENT_SOURCE_DIR}/cmake/modules"
  11   )
  12
  13 set(LLVM_VERSION_MAJOR 3)
  14 set(LLVM_VERSION_MINOR 2)
  15
  16 set(PACKAGE_VERSION "${LLVM_VERSION_MAJOR}.${LLVM_VERSION_MINOR}svn")
  17
  18 option(LLVM_USE_FOLDERS "Enable solution folders in Visual Studio. Disable for Express versions." ON)
  19 if ( LLVM_USE_FOLDERS )
  20   set_property(GLOBAL PROPERTY USE_FOLDERS ON)
  21 endif()
  22
  23 include(VersionFromVCS)
  24
  25 option(LLVM_APPEND_VC_REV
  26   "Append the version control system revision id to LLVM version" OFF)
  27
  28 if( LLVM_APPEND_VC_REV )
  29   add_version_info_from_vcs(PACKAGE_VERSION)
  30 endif()
  31
  32 set(PACKAGE_NAME LLVM)
  33 set(PACKAGE_STRING "${PACKAGE_NAME} ${PACKAGE_VERSION}")
  34 set(PACKAGE_BUGREPORT "http://llvm.org/bugs/")
  35
  36 # Sanity check our source directory to make sure that we are not trying to
  37 # generate an in-tree build (unless on MSVC_IDE, where it is ok), and to make
  38 # sure that we don't have any stray generated files lying around in the tree
  39 # (which would end up getting picked up by header search, instead of the correct
  40 # versions).
  41 if( CMAKE_SOURCE_DIR STREQUAL CMAKE_BINARY_DIR AND NOT MSVC_IDE )
  42   message(FATAL_ERROR "In-source builds are not allowed.
  43 CMake would overwrite the makefiles distributed with LLVM.
  44 Please create a directory and run cmake from there, passing the path
  45 to this source directory as the last argument.
  46 This process created the file `CMakeCache.txt' and the directory `CMakeFiles'.
  47 Please delete them.")
  48 endif()
  49 if( NOT CMAKE_SOURCE_DIR STREQUAL CMAKE_BINARY_DIR )
  50   file(GLOB_RECURSE
  51     tablegenned_files_on_include_dir
  52     "${CMAKE_CURRENT_SOURCE_DIR}/include/llvm/*.gen")
  53   file(GLOB_RECURSE
  54     tablegenned_files_on_lib_dir
  55     "${CMAKE_CURRENT_SOURCE_DIR}/lib/Target/*.inc")
  56   if( tablegenned_files_on_include_dir OR tablegenned_files_on_lib_dir)
  57     message(FATAL_ERROR "Apparently there is a previous in-source build,
  58 probably as the result of running `configure' and `make' on
  59 ${CMAKE_CURRENT_SOURCE_DIR}.
  60 This may cause problems. The suspicious files are:
  61 ${tablegenned_files_on_lib_dir}
  62 ${tablegenned_files_on_include_dir}
  63 Please clean the source directory.")
  64   endif()
  65 endif()
  66
  67 string(TOUPPER "${CMAKE_BUILD_TYPE}" uppercase_CMAKE_BUILD_TYPE)
  68
  69 set(LLVM_MAIN_SRC_DIR ${CMAKE_CURRENT_SOURCE_DIR})
  70 set(LLVM_MAIN_INCLUDE_DIR ${LLVM_MAIN_SRC_DIR}/include)
  71 set(LLVM_BINARY_DIR ${CMAKE_CURRENT_BINARY_DIR})
  72 set(LLVM_TOOLS_BINARY_DIR ${LLVM_BINARY_DIR}/bin)
  73 set(LLVM_EXAMPLES_BINARY_DIR ${LLVM_BINARY_DIR}/examples)
  74 set(LLVM_LIBDIR_SUFFIX "" CACHE STRING "Define suffix of library directory name (32/64)" )
  75
  76 set(LLVM_ALL_TARGETS
  77   ARM
  78   CellSPU
  79   CppBackend
  80   Hexagon
  81   Mips
  82   MBlaze
  83   MSP430
  84   NVPTX
  85   PowerPC
  86   PTX
  87   Sparc
  88   X86
  89   XCore
  90   )
  91
  92 # List of targets with JIT support:
  93 set(LLVM_TARGETS_WITH_JIT X86 PowerPC ARM Mips)
  94
  95 if( MSVC )
  96   set(LLVM_TARGETS_TO_BUILD X86
  97     CACHE STRING "Semicolon-separated list of targets to build, or \"all\".")
  98 else( MSVC )
  99   set(LLVM_TARGETS_TO_BUILD "all"
 100     CACHE STRING "Semicolon-separated list of targets to build, or \"all\".")
 101 endif( MSVC )
 102
 103 option(BUILD_SHARED_LIBS
 104   "Build all libraries as shared libraries instead of static" OFF)
 105
 106 option(LLVM_ENABLE_CBE_PRINTF_A "Set to ON if CBE is enabled for printf %a output" ON)
 107 if(LLVM_ENABLE_CBE_PRINTF_A)
 108   set(ENABLE_CBE_PRINTF_A 1)
 109 endif()
 110
 111 option(LLVM_ENABLE_TIMESTAMPS "Enable embedding timestamp information in build" ON)
 112 if(LLVM_ENABLE_TIMESTAMPS)
 113   set(ENABLE_TIMESTAMPS 1)
 114 endif()
 115
 116 option(LLVM_ENABLE_FFI "Use libffi to call external functions from the interpreter" OFF)
 117 set(FFI_LIBRARY_DIR "" CACHE PATH "Additional directory, where CMake should search for libffi.so")
 118 set(FFI_INCLUDE_DIR "" CACHE PATH "Additional directory, where CMake should search for ffi.h or ffi/ffi.h")
 119
 120 set(LLVM_TARGET_ARCH "host"
 121   CACHE STRING "Set target to use for LLVM JIT or use \"host\" for automatic detection.")
 122
 123 option(LLVM_ENABLE_THREADS "Use threads if available." ON)
 124
 125 if( LLVM_TARGETS_TO_BUILD STREQUAL "all" )
 126   set( LLVM_TARGETS_TO_BUILD ${LLVM_ALL_TARGETS} )
 127 endif()
 128
 129 set(LLVM_ENUM_TARGETS "")
 130 foreach(c ${LLVM_TARGETS_TO_BUILD})
 131   list(FIND LLVM_ALL_TARGETS ${c} idx)
 132   if( idx LESS 0 )
 133     message(FATAL_ERROR "The target `${c}' does not exist.
 134     It should be one of\n${LLVM_ALL_TARGETS}")
 135   else()
 136     set(LLVM_ENUM_TARGETS "${LLVM_ENUM_TARGETS}LLVM_TARGET(${c})\n")
 137   endif()
 138 endforeach(c)
 139
 140 set(llvm_builded_incs_dir ${LLVM_BINARY_DIR}/include/llvm)
 141
 142 include(AddLLVMDefinitions)
 143
 144 option(LLVM_ENABLE_PIC "Build Position-Independent Code" ON)
 145
 146 # MSVC has a gazillion warnings with this.
 147 if( MSVC )
 148   option(LLVM_ENABLE_WARNINGS "Enable compiler warnings." OFF)
 149 else( MSVC )
 150   option(LLVM_ENABLE_WARNINGS "Enable compiler warnings." ON)
 151 endif()
 152
 153 option(LLVM_ENABLE_PEDANTIC "Compile with pedantic enabled." ON)
 154 option(LLVM_ENABLE_WERROR "Fail and stop if a warning is triggered." OFF)
 155
 156 if( uppercase_CMAKE_BUILD_TYPE STREQUAL "RELEASE" )
 157   option(LLVM_ENABLE_ASSERTIONS "Enable assertions" OFF)
 158 else()
 159   option(LLVM_ENABLE_ASSERTIONS "Enable assertions" ON)
 160 endif()
 161
 162 option(LLVM_USE_INTEL_JITEVENTS
 163   "Use Intel JIT API to inform Intel(R) VTune(TM) Amplifier XE 2011 about JIT code"
 164   OFF)
 165
 166 if( LLVM_USE_INTEL_JITEVENTS )
 167   # Verify we are on a supported platform
 168   if( CMAKE_SYSTEM_NAME MATCHES "Windows" OR CMAKE_SYSTEM_NAME MATCHES "Linux" )
 169     # Directory where Intel Parallel Amplifier XE 2011 is installed.
 170     if ( WIN32 )
 171       set(LLVM_INTEL_JITEVENTS_DIR $ENV{VTUNE_AMPLIFIER_XE_2011_DIR})
 172     else ( WIN32 )
 173       set(LLVM_INTEL_JITEVENTS_DIR "/opt/intel/vtune_amplifier_xe_2011")
 174     endif ( WIN32 )
 175
 176     # Set include and library search paths for Intel JIT Events API
 177     set(LLVM_INTEL_JITEVENTS_INCDIR "${LLVM_INTEL_JITEVENTS_DIR}/include")
 178
 179     if ( CMAKE_SIZEOF_VOID_P EQUAL 8 )
 180       set(LLVM_INTEL_JITEVENTS_LIBDIR "${LLVM_INTEL_JITEVENTS_DIR}/lib64")
 181     else ( CMAKE_SIZEOF_VOID_P EQUAL 8 )
 182       set(LLVM_INTEL_JITEVENTS_LIBDIR "${LLVM_INTEL_JITEVENTS_DIR}/lib32")
 183     endif ( CMAKE_SIZEOF_VOID_P EQUAL 8 )
 184   else()
 185     message(FATAL_ERROR
 186       "Intel JIT API support is available on Linux and Windows only.")
 187   endif()
 188 endif( LLVM_USE_INTEL_JITEVENTS )
 189
 190 option(LLVM_USE_OPROFILE
 191   "Use opagent JIT interface to inform OProfile about JIT code" OFF)
 192
 193 # If enabled, ierify we are on a platform that supports oprofile.
 194 if( LLVM_USE_OPROFILE )
 195   if( NOT CMAKE_SYSTEM_NAME MATCHES "Linux" )
 196     message(FATAL_ERROR "OProfile support is available on Linux only.")
 197   endif( NOT CMAKE_SYSTEM_NAME MATCHES "Linux" )
 198 endif( LLVM_USE_OPROFILE )
 199
 200 # Define an option controlling whether we should build for 32-bit on 64-bit
 201 # platforms, where supported.
 202 if( CMAKE_SIZEOF_VOID_P EQUAL 8 AND NOT WIN32 )
 203   # TODO: support other platforms and toolchains.
 204   option(LLVM_BUILD_32_BITS "Build 32 bits executables and libraries." OFF)
 205 endif()
 206
 207 # Define the default arguments to use with 'lit', and an option for the user to
 208 # override.
 209 set(LIT_ARGS_DEFAULT "-sv")
 210 if (MSVC OR XCODE)
 211   set(LIT_ARGS_DEFAULT "${LIT_ARGS_DEFAULT} --no-progress-bar")
 212 endif()
 213 set(LLVM_LIT_ARGS "${LIT_ARGS_DEFAULT}" CACHE STRING "Default options for lit")
 214
 215 # On Win32 hosts, provide an option to specify the path to the GnuWin32 tools.
 216 if( WIN32 AND NOT CYGWIN )
 217   set(LLVM_LIT_TOOLS_DIR "" CACHE PATH "Path to GnuWin32 tools")
 218 endif()
 219
 220 # Define options to control the inclusion and default build behavior for
 221 # components which may not strictly be necessary (tools, runtime, examples, and
 222 # tests).
 223 #
 224 # This is primarily to support building smaller or faster project files.
 225 option(LLVM_INCLUDE_TOOLS "Generate build targets for the LLVM tools." ON)
 226 option(LLVM_BUILD_TOOLS
 227   "Build the LLVM tools. If OFF, just generate build targets." ON)
 228
 229 option(LLVM_INCLUDE_RUNTIME "Generate build targets for the LLVM runtimes" ON)
 230 option(LLVM_BUILD_RUNTIME
 231   "Build the LLVM runtime libraries. If OFF, just generate build targets." ON)
 232
 233 option(LLVM_BUILD_EXAMPLES
 234   "Build the LLVM example programs. If OFF, just generate build targets." OFF)
 235 option(LLVM_INCLUDE_EXAMPLES "Generate build targets for the LLVM examples" ON)
 236
 237 option(LLVM_BUILD_TESTS
 238   "Build LLVM unit tests. If OFF, just generate build targets." OFF)
 239 option(LLVM_INCLUDE_TESTS "Generate build targets for the LLVM unit tests." ON)
 240
 241 # All options referred to from HandleLLVMOptions have to be specified
 242 # BEFORE this include, otherwise options will not be correctly set on
 243 # first cmake run
 244 include(config-ix)
 245 include(HandleLLVMOptions)
 246
 247 # Verify that we can find a Python interpreter,
 248 include(FindPythonInterp)
 249 if( NOT PYTHONINTERP_FOUND )
 250   message(FATAL_ERROR
 251 "Unable to find Python interpreter, required for builds and testing.
 252
 253 Please install Python or specify the PYTHON_EXECUTABLE CMake variable.")
 254 endif()
 255
 256 ######
 257 # LLVMBuild Integration
 258 #
 259 # We use llvm-build to generate all the data required by the CMake based
 260 # build system in one swoop:
 261 #
 262 #  - We generate a file (a CMake fragment) in the object root which contains
 263 #    all the definitions that are required by CMake.
 264 #
 265 #  - We generate the library table used by llvm-config.
 266 #
 267 #  - We generate the dependencies for the CMake fragment, so that we will
 268 #    automatically reconfigure outselves.
 269
 270 set(LLVMBUILDTOOL "${LLVM_MAIN_SRC_DIR}/utils/llvm-build/llvm-build")
 271 set(LLVMCONFIGLIBRARYDEPENDENCIESINC
 272   "${LLVM_BINARY_DIR}/tools/llvm-config/LibraryDependencies.inc")
 273 set(LLVMBUILDCMAKEFRAG
 274   "${LLVM_BINARY_DIR}/LLVMBuild.cmake")
 275
 276 # Create the list of optional components that are enabled
 277 if (LLVM_USE_INTEL_JITEVENTS)
 278   set(LLVMOPTIONALCOMPONENTS IntelJITEvents)
 279 endif (LLVM_USE_INTEL_JITEVENTS)
 280 if (LLVM_USE_OPROFILE)
 281   set(LLVMOPTIONALCOMPONENTS ${LLVMOPTIONALCOMPONENTS} OProfileJIT)
 282 endif (LLVM_USE_OPROFILE)
 283
 284 message(STATUS "Constructing LLVMBuild project information")
 285 execute_process(
 286   COMMAND ${PYTHON_EXECUTABLE} ${LLVMBUILDTOOL}
 287             --native-target "${LLVM_NATIVE_ARCH}"
 288             --enable-targets "${LLVM_TARGETS_TO_BUILD}"
 289             --enable-optional-components "${LLVMOPTIONALCOMPONENTS}"
 290             --write-library-table ${LLVMCONFIGLIBRARYDEPENDENCIESINC}
 291             --write-cmake-fragment ${LLVMBUILDCMAKEFRAG}
 292             ERROR_VARIABLE LLVMBUILDOUTPUT
 293             ERROR_VARIABLE LLVMBUILDERRORS
 294             OUTPUT_STRIP_TRAILING_WHITESPACE
 295             ERROR_STRIP_TRAILING_WHITESPACE
 296   RESULT_VARIABLE LLVMBUILDRESULT)
 297
 298 # On Win32, CMake doesn't properly handle piping the default output/error
 299 # streams into the GUI console. So, we explicitly catch and report them.
 300 if( NOT "${LLVMBUILDOUTPUT}" STREQUAL "")
 301   message(STATUS "llvm-build output: ${LLVMBUILDOUTPUT}")
 302 endif()
 303 if( NOT "${LLVMBUILDRESULT}" STREQUAL "0" )
 304   message(FATAL_ERROR
 305     "Unexpected failure executing llvm-build: ${LLVMBUILDERRORS}")
 306 endif()
 307
 308 # Include the generated CMake fragment. This will define properties from the
 309 # LLVMBuild files in a format which is easy to consume from CMake, and will add
 310 # the dependencies so that CMake will reconfigure properly when the LLVMBuild
 311 # files change.
 312 include(${LLVMBUILDCMAKEFRAG})
 313
 314 ######
 315
 316 # Configure all of the various header file fragments LLVM uses which depend on
 317 # configuration variables.
 318 set(LLVM_ENUM_ASM_PRINTERS "")
 319 set(LLVM_ENUM_ASM_PARSERS "")
 320 set(LLVM_ENUM_DISASSEMBLERS "")
 321 foreach(t ${LLVM_TARGETS_TO_BUILD})
 322   set( td ${LLVM_MAIN_SRC_DIR}/lib/Target/${t} )
 323   file(GLOB asmp_file "${td}/*AsmPrinter.cpp")
 324   if( asmp_file )
 325     set(LLVM_ENUM_ASM_PRINTERS
 326       "${LLVM_ENUM_ASM_PRINTERS}LLVM_ASM_PRINTER(${t})\n")
 327   endif()
 328   if( EXISTS ${td}/AsmParser/CMakeLists.txt )
 329     set(LLVM_ENUM_ASM_PARSERS
 330       "${LLVM_ENUM_ASM_PARSERS}LLVM_ASM_PARSER(${t})\n")
 331   endif()
 332   if( EXISTS ${td}/Disassembler/CMakeLists.txt )
 333     set(LLVM_ENUM_DISASSEMBLERS
 334       "${LLVM_ENUM_DISASSEMBLERS}LLVM_DISASSEMBLER(${t})\n")
 335   endif()
 336 endforeach(t)
 337
 338 # Produce the target definition files, which provide a way for clients to easily
 339 # include various classes of targets.
 340 configure_file(
 341   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/AsmPrinters.def.in
 342   ${LLVM_BINARY_DIR}/include/llvm/Config/AsmPrinters.def
 343   )
 344 configure_file(
 345   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/AsmParsers.def.in
 346   ${LLVM_BINARY_DIR}/include/llvm/Config/AsmParsers.def
 347   )
 348 configure_file(
 349   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/Disassemblers.def.in
 350   ${LLVM_BINARY_DIR}/include/llvm/Config/Disassemblers.def
 351   )
 352 configure_file(
 353   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/Targets.def.in
 354   ${LLVM_BINARY_DIR}/include/llvm/Config/Targets.def
 355   )
 356
 357 # Configure the three LLVM configuration header files.
 358 configure_file(
 359   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/config.h.cmake
 360   ${LLVM_BINARY_DIR}/include/llvm/Config/config.h)
 361 configure_file(
 362   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/llvm-config.h.cmake
 363   ${LLVM_BINARY_DIR}/include/llvm/Config/llvm-config.h)
 364 configure_file(
 365   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Support/DataTypes.h.cmake
 366   ${LLVM_BINARY_DIR}/include/llvm/Support/DataTypes.h)
 367
 368 set( CMAKE_RUNTIME_OUTPUT_DIRECTORY ${LLVM_TOOLS_BINARY_DIR} )
 369 set( CMAKE_LIBRARY_OUTPUT_DIRECTORY ${LLVM_BINARY_DIR}/lib )
 370 set( CMAKE_ARCHIVE_OUTPUT_DIRECTORY ${LLVM_BINARY_DIR}/lib )
 371
 372 set(CMAKE_INCLUDE_CURRENT_DIR ON)
 373
 374 include_directories( ${LLVM_BINARY_DIR}/include ${LLVM_MAIN_INCLUDE_DIR})
 375
 376 if( ${CMAKE_SYSTEM_NAME} MATCHES SunOS )
 377    SET(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -include llvm/Support/Solaris.h")
 378 endif( ${CMAKE_SYSTEM_NAME} MATCHES SunOS )
 379
 380 include(AddLLVM)
 381 include(TableGen)
 382
 383 if( MINGW )
 384   # People report that -O3 is unreliable on MinGW. The traditional
 385   # build also uses -O2 for that reason:
 386   llvm_replace_compiler_option(CMAKE_CXX_FLAGS_RELEASE "-O3" "-O2")
 387 endif()
 388
 389 # Put this before tblgen. Else we have a circular dependence.
 390 add_subdirectory(lib/Support)
 391 add_subdirectory(lib/TableGen)
 392
 393 add_subdirectory(utils/TableGen)
 394
 395 add_subdirectory(include/llvm)
 396
 397 add_subdirectory(lib)
 398
 399 add_subdirectory(utils/FileCheck)
 400 add_subdirectory(utils/FileUpdate)
 401 add_subdirectory(utils/count)
 402 add_subdirectory(utils/not)
 403 add_subdirectory(utils/llvm-lit)
 404 add_subdirectory(utils/yaml-bench)
 405
 406 add_subdirectory(projects)
 407
 408 if( LLVM_INCLUDE_TOOLS )
 409   add_subdirectory(tools)
 410 endif()
 411
 412 if( LLVM_INCLUDE_RUNTIME )
 413   add_subdirectory(runtime)
 414 endif()
 415
 416 if( LLVM_INCLUDE_EXAMPLES )
 417   add_subdirectory(examples)
 418 endif()
 419
 420 if( LLVM_INCLUDE_TESTS )
 421   add_subdirectory(test)
 422   add_subdirectory(utils/unittest)
 423   add_subdirectory(unittests)
 424   if (MSVC)
 425     # This utility is used to prevent chrashing tests from calling Dr. Watson on
 426     # Windows.
 427     add_subdirectory(utils/KillTheDoctor)
 428   endif()
 429 endif()
 430
 431 add_subdirectory(cmake/modules)
 432
 433 install(DIRECTORY include/
 434   DESTINATION include
 435   FILES_MATCHING
 436   PATTERN "*.def"
 437   PATTERN "*.h"
 438   PATTERN "*.td"
 439   PATTERN "*.inc"
 440   PATTERN "LICENSE.TXT"
 441   PATTERN ".svn" EXCLUDE
 442   )
 443
 444 install(DIRECTORY ${CMAKE_CURRENT_BINARY_DIR}/include/
 445   DESTINATION include
 446   FILES_MATCHING
 447   PATTERN "*.def"
 448   PATTERN "*.h"
 449   PATTERN "*.gen"
 450   PATTERN "*.inc"
 451   # Exclude include/llvm/CMakeFiles/intrinsics_gen.dir, matched by "*.def"
 452   PATTERN "CMakeFiles" EXCLUDE
 453   PATTERN ".svn" EXCLUDE
 454   )
 455
 456 # TODO: make and install documentation.
 457
 458 set(CPACK_PACKAGE_VENDOR "LLVM")
 459 set(CPACK_PACKAGE_VERSION_MAJOR ${LLVM_VERSION_MAJOR})
 460 set(CPACK_PACKAGE_VERSION_MINOR ${LLVM_VERSION_MINOR})
 461 add_version_info_from_vcs(CPACK_PACKAGE_VERSION_PATCH)
 462 include(CPack)
 463
 464 # Workaround for MSVS10 to avoid the Dialog Hell
 465 # FIXME: This could be removed with future version of CMake.
 466 if(MSVC_VERSION EQUAL 1600)
 467   set(LLVM_SLN_FILENAME "${CMAKE_CURRENT_BINARY_DIR}/LLVM.sln")
 468   if( EXISTS "${LLVM_SLN_FILENAME}" )
 469     file(APPEND "${LLVM_SLN_FILENAME}" "\n# This should be regenerated!\n")
 470   endif()
 471 endif()