CMakeLists.txt

   1 # See docs/CMake.html for instructions about how to build LLVM with CMake.
   2
   3 project(LLVM)
   4 cmake_minimum_required(VERSION 2.6.1)
   5
   6 set(PACKAGE_NAME llvm)
   7 set(PACKAGE_VERSION 2.6svn)
   8 set(PACKAGE_STRING "${PACKAGE_NAME} ${PACKAGE_VERSION}")
   9 set(PACKAGE_BUGREPORT "llvmbugs@cs.uiuc.edu")
  10
  11 if( CMAKE_SOURCE_DIR STREQUAL CMAKE_BINARY_DIR AND NOT MSVC_IDE )
  12   message(FATAL_ERROR "In-source builds are not allowed.
  13 CMake would overwrite the makefiles distributed with LLVM.
  14 Please create a directory and run cmake from there, passing the path
  15 to this source directory as the last argument.
  16 This process created the file `CMakeCache.txt' and the directory `CMakeFiles'.
  17 Please delete them.")
  18 endif()
  19
  20 string(TOUPPER "${CMAKE_BUILD_TYPE}" uppercase_CMAKE_BUILD_TYPE)
  21
  22 include(FindPerl)
  23
  24 set(LLVM_MAIN_SRC_DIR ${CMAKE_CURRENT_SOURCE_DIR})
  25 set(LLVM_MAIN_INCLUDE_DIR ${LLVM_MAIN_SRC_DIR}/include)
  26 set(LLVM_BINARY_DIR ${CMAKE_CURRENT_BINARY_DIR})
  27 set(LLVM_TOOLS_BINARY_DIR ${LLVM_BINARY_DIR}/bin)
  28 set(LLVM_EXAMPLES_BINARY_DIR ${LLVM_BINARY_DIR}/examples)
  29
  30 set(LLVM_ALL_TARGETS
  31   Alpha
  32   ARM
  33   CBackend
  34   CellSPU
  35   CppBackend
  36   IA64
  37   Mips
  38   MSIL
  39   PIC16
  40   PowerPC
  41   Sparc
  42   X86
  43   XCore
  44   )
  45
  46 # List of targets whose asmprinters need to be forced to link
  47 # into executables on some platforms (i.e. Windows):
  48 set(LLVM_ASMPRINTERS_FORCE_LINK X86 PowerPC)
  49
  50 if( MSVC )
  51   set(LLVM_TARGETS_TO_BUILD X86
  52     CACHE STRING "Semicolon-separated list of targets to build, or \"all\".")
  53 else( MSVC )
  54   set(LLVM_TARGETS_TO_BUILD ${LLVM_ALL_TARGETS}
  55     CACHE STRING "Semicolon-separated list of targets to build, or \"all\".")
  56 endif( MSVC )
  57
  58 option(LLVM_ENABLE_THREADS "Use threads if available." ON)
  59
  60 if( uppercase_CMAKE_BUILD_TYPE STREQUAL "RELEASE" )
  61   option(LLVM_ENABLE_ASSERTIONS "Enable assertions" OFF)
  62 else()
  63   option(LLVM_ENABLE_ASSERTIONS "Enable assertions" ON)
  64 endif()
  65
  66 if( LLVM_ENABLE_ASSERTIONS )
  67   add_definitions( -D_DEBUG )
  68   # On Release builds cmake automatically defines NDEBUG, so we
  69   # explicitly undefine it:
  70   if( uppercase_CMAKE_BUILD_TYPE STREQUAL "RELEASE" )
  71     add_definitions( -UNDEBUG )
  72   endif()
  73 else()
  74   if( NOT uppercase_CMAKE_BUILD_TYPE STREQUAL "RELEASE" )
  75     add_definitions( -DNDEBUG )
  76   endif()
  77 endif()
  78
  79 if( LLVM_TARGETS_TO_BUILD STREQUAL "all" )
  80   set( LLVM_TARGETS_TO_BUILD ${LLVM_ALL_TARGETS} )
  81 endif()
  82
  83 foreach(c ${LLVM_TARGETS_TO_BUILD})
  84   list(FIND LLVM_ALL_TARGETS ${c} idx)
  85   if( idx LESS 0 )
  86     message(FATAL_ERROR "The target `${c}' does not exists.
  87     It should be one of\n${LLVM_ALL_TARGETS}")
  88   endif()
  89 endforeach(c)
  90
  91 set(llvm_builded_incs_dir ${LLVM_BINARY_DIR}/include/llvm)
  92
  93 # Add path for custom modules
  94 set(CMAKE_MODULE_PATH
  95   ${CMAKE_MODULE_PATH}
  96   "${LLVM_MAIN_SRC_DIR}/cmake"
  97   "${LLVM_MAIN_SRC_DIR}/cmake/modules"
  98   )
  99
 100 include(AddLLVMDefinitions)
 101
 102 if(WIN32)
 103   if(CYGWIN)
 104     set(LLVM_ON_WIN32 0)
 105     set(LLVM_ON_UNIX 1)
 106   else(CYGWIN)
 107     set(LLVM_ON_WIN32 1)
 108     set(LLVM_ON_UNIX 0)
 109   endif(CYGWIN)
 110   set(LTDL_SHLIB_EXT ".dll")
 111   set(EXEEXT ".exe")
 112   # Maximum path length is 160 for non-unicode paths
 113   set(MAXPATHLEN 160)
 114 else(WIN32)
 115   if(UNIX)
 116     set(LLVM_ON_WIN32 0)
 117     set(LLVM_ON_UNIX 1)
 118     set(LTDL_SHLIB_EXT ".so")
 119     set(EXEEXT "")
 120     # FIXME: Maximum path length is currently set to 'safe' fixed value
 121     set(MAXPATHLEN 2024)
 122   else(UNIX)
 123     MESSAGE(SEND_ERROR "Unable to determine platform")
 124   endif(UNIX)
 125 endif(WIN32)
 126
 127 if( EXISTS ${LLVM_TOOLS_BINARY_DIR}/llvm-config )
 128   set(HAVE_LLVM_CONFIG 1)
 129 endif( EXISTS ${LLVM_TOOLS_BINARY_DIR}/llvm-config )
 130
 131 include(config-ix)
 132
 133 option(LLVM_ENABLE_PIC "Build Position-Independent Code" OFF)
 134
 135 if( LLVM_ENABLE_PIC )
 136   if( SUPPORTS_FPIC_FLAG )
 137     message(STATUS "Building with -fPIC")
 138     add_llvm_definitions(-fPIC)
 139   else( SUPPORTS_FPIC_FLAG )
 140     message(STATUS "Warning: -fPIC not supported.")
 141   endif()
 142 endif()
 143
 144 set( CMAKE_RUNTIME_OUTPUT_DIRECTORY ${LLVM_TOOLS_BINARY_DIR} )
 145 set( CMAKE_LIBRARY_OUTPUT_DIRECTORY ${LLVM_BINARY_DIR}/lib )
 146 set( CMAKE_ARCHIVE_OUTPUT_DIRECTORY ${LLVM_BINARY_DIR}/lib )
 147
 148 # set(CMAKE_VERBOSE_MAKEFILE true)
 149
 150 add_llvm_definitions( -D__STDC_LIMIT_MACROS )
 151 add_llvm_definitions( -D__STDC_CONSTANT_MACROS )
 152
 153 set(LLVM_PLO_FLAGS "" CACHE
 154   STRING "Flags for creating partially linked objects.")
 155
 156 if( CMAKE_SIZEOF_VOID_P EQUAL 8 AND NOT WIN32 )
 157   # TODO: support other platforms and toolchains.
 158   option(LLVM_BUILD_32_BITS "Build 32 bits executables and libraries." OFF)
 159   if( LLVM_BUILD_32_BITS )
 160     message(STATUS "Building 32 bits executables and libraries.")
 161     add_llvm_definitions( -m32 )
 162     list(APPEND CMAKE_EXE_LINKER_FLAGS -m32)
 163     list(APPEND CMAKE_SHARED_LINKER_FLAGS -m32)
 164     set( LLVM_PLO_FLAGS -melf_i386 ${LLVM_PLO_FLAGS} )
 165   endif( LLVM_BUILD_32_BITS )
 166 endif( CMAKE_SIZEOF_VOID_P EQUAL 8 AND NOT WIN32 )
 167
 168 if( MSVC )
 169   add_llvm_definitions( -D_CRT_SECURE_NO_DEPRECATE -D_CRT_SECURE_NO_WARNINGS )
 170   add_llvm_definitions( -D_SCL_SECURE_NO_WARNINGS -DCRT_NONSTDC_NO_WARNINGS )
 171   add_llvm_definitions( -D_SCL_SECURE_NO_DEPRECATE )
 172   add_llvm_definitions( -wd4146 -wd4503 -wd4996 -wd4800 -wd4244 -wd4624 )
 173   add_llvm_definitions( -wd4355 -wd4715 -wd4180 -wd4345 -wd4224 )
 174 endif( MSVC )
 175
 176 include_directories( ${LLVM_BINARY_DIR}/include ${LLVM_MAIN_INCLUDE_DIR})
 177
 178 include(AddLLVM)
 179 include(AddPartiallyLinkedObject)
 180 include(TableGen)
 181
 182 add_subdirectory(lib/Support)
 183 add_subdirectory(lib/System)
 184
 185 # Everything else depends on Support and System:
 186 set(LLVM_COMMON_DEPENDS ${LLVM_COMMON_DEPENDS} ${LLVM_LIBS} )
 187
 188 set(LLVM_TABLEGEN "tblgen" CACHE
 189   STRING "Native TableGen executable. Saves building one when cross-compiling.")
 190
 191 add_subdirectory(utils/TableGen)
 192
 193 if( CMAKE_CROSSCOMPILING )
 194   # This adds a dependency on target `tblgen', so must go after utils/TableGen
 195   include( CrossCompileLLVM )
 196 endif( CMAKE_CROSSCOMPILING )
 197
 198 add_subdirectory(include/llvm)
 199
 200 add_subdirectory(lib/VMCore)
 201 add_subdirectory(lib/CodeGen)
 202 add_subdirectory(lib/CodeGen/SelectionDAG)
 203 add_subdirectory(lib/CodeGen/AsmPrinter)
 204 add_subdirectory(lib/Bitcode/Reader)
 205 add_subdirectory(lib/Bitcode/Writer)
 206 add_subdirectory(lib/Transforms/Utils)
 207 add_subdirectory(lib/Transforms/Instrumentation)
 208 add_subdirectory(lib/Transforms/Scalar)
 209 add_subdirectory(lib/Transforms/IPO)
 210 add_subdirectory(lib/Transforms/Hello)
 211 add_subdirectory(lib/Linker)
 212 add_subdirectory(lib/Analysis)
 213 add_subdirectory(lib/Analysis/IPA)
 214
 215 foreach(t ${LLVM_TARGETS_TO_BUILD})
 216   message(STATUS "Targeting ${t}")
 217   add_subdirectory(lib/Target/${t})
 218   if( EXISTS ${LLVM_MAIN_SRC_DIR}/lib/Target/${t}/AsmPrinter/CMakeLists.txt )
 219     add_subdirectory(lib/Target/${t}/AsmPrinter)
 220   endif( EXISTS ${LLVM_MAIN_SRC_DIR}/lib/Target/${t}/AsmPrinter/CMakeLists.txt )
 221 endforeach(t)
 222
 223 add_subdirectory(lib/ExecutionEngine)
 224 add_subdirectory(lib/ExecutionEngine/Interpreter)
 225 add_subdirectory(lib/ExecutionEngine/JIT)
 226 add_subdirectory(lib/Target)
 227 add_subdirectory(lib/AsmParser)
 228 add_subdirectory(lib/Debugger)
 229 add_subdirectory(lib/Archive)
 230
 231 add_subdirectory(projects)
 232 add_subdirectory(tools)
 233
 234 add_subdirectory(examples)
 235
 236 install(DIRECTORY include
 237   DESTINATION .
 238   PATTERN ".svn" EXCLUDE
 239   PATTERN "*.cmake" EXCLUDE
 240   PATTERN "*.in" EXCLUDE
 241   )
 242
 243 install(DIRECTORY ${CMAKE_CURRENT_BINARY_DIR}/include
 244   DESTINATION .
 245   )
 246
 247 # TODO: make and install documentation.