CMakeLists.txt

   1 # See docs/CMake.html for instructions about how to build LLVM with CMake.
   2
   3 project(LLVM)
   4 cmake_minimum_required(VERSION 2.8)
   5
   6 # Add path for custom modules
   7 set(CMAKE_MODULE_PATH
   8   ${CMAKE_MODULE_PATH}
   9   "${CMAKE_CURRENT_SOURCE_DIR}/cmake"
  10   "${CMAKE_CURRENT_SOURCE_DIR}/cmake/modules"
  11   )
  12
  13 set(LLVM_VERSION_MAJOR 3)
  14 set(LLVM_VERSION_MINOR 4)
  15
  16 set(PACKAGE_VERSION "${LLVM_VERSION_MAJOR}.${LLVM_VERSION_MINOR}svn")
  17
  18 option(LLVM_USE_FOLDERS "Enable solution folders in Visual Studio. Disable for Express versions." ON)
  19 if ( LLVM_USE_FOLDERS )
  20   set_property(GLOBAL PROPERTY USE_FOLDERS ON)
  21 endif()
  22
  23 include(VersionFromVCS)
  24
  25 option(LLVM_APPEND_VC_REV
  26   "Append the version control system revision id to LLVM version" OFF)
  27
  28 if( LLVM_APPEND_VC_REV )
  29   add_version_info_from_vcs(PACKAGE_VERSION)
  30 endif()
  31
  32 set(PACKAGE_NAME LLVM)
  33 set(PACKAGE_STRING "${PACKAGE_NAME} ${PACKAGE_VERSION}")
  34 set(PACKAGE_BUGREPORT "http://llvm.org/bugs/")
  35
  36 # Sanity check our source directory to make sure that we are not trying to
  37 # generate an in-tree build (unless on MSVC_IDE, where it is ok), and to make
  38 # sure that we don't have any stray generated files lying around in the tree
  39 # (which would end up getting picked up by header search, instead of the correct
  40 # versions).
  41 if( CMAKE_SOURCE_DIR STREQUAL CMAKE_BINARY_DIR AND NOT MSVC_IDE )
  42   message(FATAL_ERROR "In-source builds are not allowed.
  43 CMake would overwrite the makefiles distributed with LLVM.
  44 Please create a directory and run cmake from there, passing the path
  45 to this source directory as the last argument.
  46 This process created the file `CMakeCache.txt' and the directory `CMakeFiles'.
  47 Please delete them.")
  48 endif()
  49 if( NOT CMAKE_SOURCE_DIR STREQUAL CMAKE_BINARY_DIR )
  50   file(GLOB_RECURSE
  51     tablegenned_files_on_include_dir
  52     "${CMAKE_CURRENT_SOURCE_DIR}/include/llvm/*.gen")
  53   file(GLOB_RECURSE
  54     tablegenned_files_on_lib_dir
  55     "${CMAKE_CURRENT_SOURCE_DIR}/lib/Target/*.inc")
  56   if( tablegenned_files_on_include_dir OR tablegenned_files_on_lib_dir)
  57     message(FATAL_ERROR "Apparently there is a previous in-source build,
  58 probably as the result of running `configure' and `make' on
  59 ${CMAKE_CURRENT_SOURCE_DIR}.
  60 This may cause problems. The suspicious files are:
  61 ${tablegenned_files_on_lib_dir}
  62 ${tablegenned_files_on_include_dir}
  63 Please clean the source directory.")
  64   endif()
  65 endif()
  66
  67 string(TOUPPER "${CMAKE_BUILD_TYPE}" uppercase_CMAKE_BUILD_TYPE)
  68
  69 set(LLVM_MAIN_SRC_DIR ${CMAKE_CURRENT_SOURCE_DIR})
  70 set(LLVM_MAIN_INCLUDE_DIR ${LLVM_MAIN_SRC_DIR}/include)
  71 set(LLVM_BINARY_DIR ${CMAKE_CURRENT_BINARY_DIR})
  72 set(LLVM_TOOLS_BINARY_DIR ${LLVM_BINARY_DIR}/bin)
  73 set(LLVM_EXAMPLES_BINARY_DIR ${LLVM_BINARY_DIR}/examples)
  74 set(LLVM_LIBDIR_SUFFIX "" CACHE STRING "Define suffix of library directory name (32/64)" )
  75
  76 set(LLVM_ALL_TARGETS
  77   AArch64
  78   ARM
  79   CppBackend
  80   Hexagon
  81   Mips
  82   MSP430
  83   NVPTX
  84   PowerPC
  85   R600
  86   Sparc
  87   SystemZ
  88   X86
  89   XCore
  90   )
  91
  92 # List of targets with JIT support:
  93 set(LLVM_TARGETS_WITH_JIT X86 PowerPC AArch64 ARM Mips SystemZ)
  94
  95 set(LLVM_TARGETS_TO_BUILD "all"
  96     CACHE STRING "Semicolon-separated list of targets to build, or \"all\".")
  97
  98 set(LLVM_EXPERIMENTAL_TARGETS_TO_BUILD ""
  99   CACHE STRING "Semicolon-separated list of experimental targets to build.")
 100
 101 option(BUILD_SHARED_LIBS
 102   "Build all libraries as shared libraries instead of static" OFF)
 103
 104 option(LLVM_ENABLE_CBE_PRINTF_A "Set to ON if CBE is enabled for printf %a output" ON)
 105 if(LLVM_ENABLE_CBE_PRINTF_A)
 106   set(ENABLE_CBE_PRINTF_A 1)
 107 endif()
 108
 109 option(LLVM_ENABLE_TIMESTAMPS "Enable embedding timestamp information in build" ON)
 110 if(LLVM_ENABLE_TIMESTAMPS)
 111   set(ENABLE_TIMESTAMPS 1)
 112 endif()
 113
 114 option(LLVM_ENABLE_BACKTRACES "Enable embedding backtraces on crash." ON)
 115 if(LLVM_ENABLE_BACKTRACES)
 116   set(ENABLE_BACKTRACES 1)
 117 endif()
 118
 119 option(LLVM_ENABLE_FFI "Use libffi to call external functions from the interpreter" OFF)
 120 set(FFI_LIBRARY_DIR "" CACHE PATH "Additional directory, where CMake should search for libffi.so")
 121 set(FFI_INCLUDE_DIR "" CACHE PATH "Additional directory, where CMake should search for ffi.h or ffi/ffi.h")
 122
 123 set(LLVM_TARGET_ARCH "host"
 124   CACHE STRING "Set target to use for LLVM JIT or use \"host\" for automatic detection.")
 125
 126 option(LLVM_ENABLE_THREADS "Use threads if available." ON)
 127
 128 option(LLVM_ENABLE_ZLIB "Use zlib for compression/decompression if available." ON)
 129
 130 if( LLVM_TARGETS_TO_BUILD STREQUAL "all" )
 131   set( LLVM_TARGETS_TO_BUILD ${LLVM_ALL_TARGETS} )
 132 endif()
 133
 134 set(LLVM_TARGETS_TO_BUILD
 135    ${LLVM_TARGETS_TO_BUILD}
 136    ${LLVM_EXPERIMENTAL_TARGETS_TO_BUILD})
 137 list(REMOVE_DUPLICATES LLVM_TARGETS_TO_BUILD)
 138
 139 set(llvm_builded_incs_dir ${LLVM_BINARY_DIR}/include/llvm)
 140
 141 include(AddLLVMDefinitions)
 142
 143 option(LLVM_ENABLE_PIC "Build Position-Independent Code" ON)
 144
 145 # MSVC has a gazillion warnings with this.
 146 if( MSVC )
 147   option(LLVM_ENABLE_WARNINGS "Enable compiler warnings." OFF)
 148 else( MSVC )
 149   option(LLVM_ENABLE_WARNINGS "Enable compiler warnings." ON)
 150 endif()
 151
 152 option(LLVM_ENABLE_PEDANTIC "Compile with pedantic enabled." ON)
 153 option(LLVM_ENABLE_WERROR "Fail and stop if a warning is triggered." OFF)
 154
 155 if( NOT uppercase_CMAKE_BUILD_TYPE STREQUAL "DEBUG" )
 156   option(LLVM_ENABLE_ASSERTIONS "Enable assertions" OFF)
 157 else()
 158   option(LLVM_ENABLE_ASSERTIONS "Enable assertions" ON)
 159 endif()
 160
 161 option(LLVM_USE_INTEL_JITEVENTS
 162   "Use Intel JIT API to inform Intel(R) VTune(TM) Amplifier XE 2011 about JIT code"
 163   OFF)
 164
 165 if( LLVM_USE_INTEL_JITEVENTS )
 166   # Verify we are on a supported platform
 167   if( NOT CMAKE_SYSTEM_NAME MATCHES "Windows" AND NOT CMAKE_SYSTEM_NAME MATCHES "Linux" )
 168     message(FATAL_ERROR
 169       "Intel JIT API support is available on Linux and Windows only.")
 170   endif()
 171 endif( LLVM_USE_INTEL_JITEVENTS )
 172
 173 option(LLVM_USE_OPROFILE
 174   "Use opagent JIT interface to inform OProfile about JIT code" OFF)
 175
 176 # If enabled, verify we are on a platform that supports oprofile.
 177 if( LLVM_USE_OPROFILE )
 178   if( NOT CMAKE_SYSTEM_NAME MATCHES "Linux" )
 179     message(FATAL_ERROR "OProfile support is available on Linux only.")
 180   endif( NOT CMAKE_SYSTEM_NAME MATCHES "Linux" )
 181 endif( LLVM_USE_OPROFILE )
 182
 183 set(LLVM_USE_SANITIZER "" CACHE STRING
 184   "Define the sanitizer used to build binaries and tests.")
 185
 186 # Define an option controlling whether we should build for 32-bit on 64-bit
 187 # platforms, where supported.
 188 if( CMAKE_SIZEOF_VOID_P EQUAL 8 AND NOT WIN32 )
 189   # TODO: support other platforms and toolchains.
 190   option(LLVM_BUILD_32_BITS "Build 32 bits executables and libraries." OFF)
 191 endif()
 192
 193 # Define the default arguments to use with 'lit', and an option for the user to
 194 # override.
 195 set(LIT_ARGS_DEFAULT "-sv")
 196 if (MSVC OR XCODE)
 197   set(LIT_ARGS_DEFAULT "${LIT_ARGS_DEFAULT} --no-progress-bar")
 198 endif()
 199 set(LLVM_LIT_ARGS "${LIT_ARGS_DEFAULT}" CACHE STRING "Default options for lit")
 200
 201 # On Win32 hosts, provide an option to specify the path to the GnuWin32 tools.
 202 if( WIN32 AND NOT CYGWIN )
 203   set(LLVM_LIT_TOOLS_DIR "" CACHE PATH "Path to GnuWin32 tools")
 204 endif()
 205
 206 # Define options to control the inclusion and default build behavior for
 207 # components which may not strictly be necessary (tools, runtime, examples, and
 208 # tests).
 209 #
 210 # This is primarily to support building smaller or faster project files.
 211 option(LLVM_INCLUDE_TOOLS "Generate build targets for the LLVM tools." ON)
 212 option(LLVM_BUILD_TOOLS
 213   "Build the LLVM tools. If OFF, just generate build targets." ON)
 214
 215 option(LLVM_INCLUDE_RUNTIME "Generate build targets for the LLVM runtimes" ON)
 216 option(LLVM_BUILD_RUNTIME
 217   "Build the LLVM runtime libraries. If OFF, just generate build targets." ON)
 218
 219 option(LLVM_BUILD_EXAMPLES
 220   "Build the LLVM example programs. If OFF, just generate build targets." OFF)
 221 option(LLVM_INCLUDE_EXAMPLES "Generate build targets for the LLVM examples" ON)
 222
 223 option(LLVM_BUILD_TESTS
 224   "Build LLVM unit tests. If OFF, just generate build targets." OFF)
 225 option(LLVM_INCLUDE_TESTS "Generate build targets for the LLVM unit tests." ON)
 226
 227 # All options referred to from HandleLLVMOptions have to be specified
 228 # BEFORE this include, otherwise options will not be correctly set on
 229 # first cmake run
 230 include(config-ix)
 231
 232 # By default, we target the host, but this can be overridden at CMake
 233 # invocation time.
 234 set(LLVM_DEFAULT_TARGET_TRIPLE "${LLVM_HOST_TRIPLE}" CACHE STRING
 235   "Default target for which LLVM will generate code." )
 236 set(TARGET_TRIPLE "${LLVM_DEFAULT_TARGET_TRIPLE}")
 237
 238 include(HandleLLVMOptions)
 239
 240 # Verify that we can find a Python 2 interpreter.  Python 3 is unsupported.
 241 set(Python_ADDITIONAL_VERSIONS 2.7 2.6 2.5 2.4)
 242 include(FindPythonInterp)
 243 if( NOT PYTHONINTERP_FOUND )
 244   message(FATAL_ERROR
 245 "Unable to find Python interpreter, required for builds and testing.
 246
 247 Please install Python or specify the PYTHON_EXECUTABLE CMake variable.")
 248 endif()
 249
 250 ######
 251 # LLVMBuild Integration
 252 #
 253 # We use llvm-build to generate all the data required by the CMake based
 254 # build system in one swoop:
 255 #
 256 #  - We generate a file (a CMake fragment) in the object root which contains
 257 #    all the definitions that are required by CMake.
 258 #
 259 #  - We generate the library table used by llvm-config.
 260 #
 261 #  - We generate the dependencies for the CMake fragment, so that we will
 262 #    automatically reconfigure outselves.
 263
 264 set(LLVMBUILDTOOL "${LLVM_MAIN_SRC_DIR}/utils/llvm-build/llvm-build")
 265 set(LLVMCONFIGLIBRARYDEPENDENCIESINC
 266   "${LLVM_BINARY_DIR}/tools/llvm-config/LibraryDependencies.inc")
 267 set(LLVMBUILDCMAKEFRAG
 268   "${LLVM_BINARY_DIR}/LLVMBuild.cmake")
 269
 270 # Create the list of optional components that are enabled
 271 if (LLVM_USE_INTEL_JITEVENTS)
 272   set(LLVMOPTIONALCOMPONENTS IntelJITEvents)
 273 endif (LLVM_USE_INTEL_JITEVENTS)
 274 if (LLVM_USE_OPROFILE)
 275   set(LLVMOPTIONALCOMPONENTS ${LLVMOPTIONALCOMPONENTS} OProfileJIT)
 276 endif (LLVM_USE_OPROFILE)
 277
 278 message(STATUS "Constructing LLVMBuild project information")
 279 execute_process(
 280   COMMAND ${PYTHON_EXECUTABLE} ${LLVMBUILDTOOL}
 281             --native-target "${LLVM_NATIVE_ARCH}"
 282             --enable-targets "${LLVM_TARGETS_TO_BUILD}"
 283             --enable-optional-components "${LLVMOPTIONALCOMPONENTS}"
 284             --write-library-table ${LLVMCONFIGLIBRARYDEPENDENCIESINC}
 285             --write-cmake-fragment ${LLVMBUILDCMAKEFRAG}
 286             ERROR_VARIABLE LLVMBUILDOUTPUT
 287             ERROR_VARIABLE LLVMBUILDERRORS
 288             OUTPUT_STRIP_TRAILING_WHITESPACE
 289             ERROR_STRIP_TRAILING_WHITESPACE
 290   RESULT_VARIABLE LLVMBUILDRESULT)
 291
 292 # On Win32, CMake doesn't properly handle piping the default output/error
 293 # streams into the GUI console. So, we explicitly catch and report them.
 294 if( NOT "${LLVMBUILDOUTPUT}" STREQUAL "")
 295   message(STATUS "llvm-build output: ${LLVMBUILDOUTPUT}")
 296 endif()
 297 if( NOT "${LLVMBUILDRESULT}" STREQUAL "0" )
 298   message(FATAL_ERROR
 299     "Unexpected failure executing llvm-build: ${LLVMBUILDERRORS}")
 300 endif()
 301
 302 # Include the generated CMake fragment. This will define properties from the
 303 # LLVMBuild files in a format which is easy to consume from CMake, and will add
 304 # the dependencies so that CMake will reconfigure properly when the LLVMBuild
 305 # files change.
 306 include(${LLVMBUILDCMAKEFRAG})
 307
 308 ######
 309
 310 # Configure all of the various header file fragments LLVM uses which depend on
 311 # configuration variables.
 312 set(LLVM_ENUM_TARGETS "")
 313 set(LLVM_ENUM_ASM_PRINTERS "")
 314 set(LLVM_ENUM_ASM_PARSERS "")
 315 set(LLVM_ENUM_DISASSEMBLERS "")
 316 foreach(t ${LLVM_TARGETS_TO_BUILD})
 317   set( td ${LLVM_MAIN_SRC_DIR}/lib/Target/${t} )
 318
 319   list(FIND LLVM_ALL_TARGETS ${t} idx)
 320   list(FIND LLVM_EXPERIMENTAL_TARGETS_TO_BUILD ${t} idy)
 321   if( idx LESS 0 AND idy LESS 0 )
 322     message(FATAL_ERROR "The target `${t}' does not exist.
 323     It should be one of\n${LLVM_ALL_TARGETS}")
 324   else()
 325     set(LLVM_ENUM_TARGETS "${LLVM_ENUM_TARGETS}LLVM_TARGET(${t})\n")
 326   endif()
 327
 328   file(GLOB asmp_file "${td}/*AsmPrinter.cpp")
 329   if( asmp_file )
 330     set(LLVM_ENUM_ASM_PRINTERS
 331       "${LLVM_ENUM_ASM_PRINTERS}LLVM_ASM_PRINTER(${t})\n")
 332   endif()
 333   if( EXISTS ${td}/AsmParser/CMakeLists.txt )
 334     set(LLVM_ENUM_ASM_PARSERS
 335       "${LLVM_ENUM_ASM_PARSERS}LLVM_ASM_PARSER(${t})\n")
 336   endif()
 337   if( EXISTS ${td}/Disassembler/CMakeLists.txt )
 338     set(LLVM_ENUM_DISASSEMBLERS
 339       "${LLVM_ENUM_DISASSEMBLERS}LLVM_DISASSEMBLER(${t})\n")
 340   endif()
 341 endforeach(t)
 342
 343 # Produce the target definition files, which provide a way for clients to easily
 344 # include various classes of targets.
 345 configure_file(
 346   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/AsmPrinters.def.in
 347   ${LLVM_BINARY_DIR}/include/llvm/Config/AsmPrinters.def
 348   )
 349 configure_file(
 350   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/AsmParsers.def.in
 351   ${LLVM_BINARY_DIR}/include/llvm/Config/AsmParsers.def
 352   )
 353 configure_file(
 354   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/Disassemblers.def.in
 355   ${LLVM_BINARY_DIR}/include/llvm/Config/Disassemblers.def
 356   )
 357 configure_file(
 358   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/Targets.def.in
 359   ${LLVM_BINARY_DIR}/include/llvm/Config/Targets.def
 360   )
 361
 362 # Configure the three LLVM configuration header files.
 363 configure_file(
 364   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/config.h.cmake
 365   ${LLVM_BINARY_DIR}/include/llvm/Config/config.h)
 366 configure_file(
 367   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/llvm-config.h.cmake
 368   ${LLVM_BINARY_DIR}/include/llvm/Config/llvm-config.h)
 369 configure_file(
 370   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Support/DataTypes.h.cmake
 371   ${LLVM_BINARY_DIR}/include/llvm/Support/DataTypes.h)
 372
 373 set( CMAKE_RUNTIME_OUTPUT_DIRECTORY ${LLVM_TOOLS_BINARY_DIR} )
 374 set( CMAKE_LIBRARY_OUTPUT_DIRECTORY ${LLVM_BINARY_DIR}/lib )
 375 set( CMAKE_ARCHIVE_OUTPUT_DIRECTORY ${LLVM_BINARY_DIR}/lib )
 376
 377 set(CMAKE_INCLUDE_CURRENT_DIR ON)
 378
 379 include_directories( ${LLVM_BINARY_DIR}/include ${LLVM_MAIN_INCLUDE_DIR})
 380
 381 if( ${CMAKE_SYSTEM_NAME} MATCHES FreeBSD )
 382   # On FreeBSD, /usr/local/* is not used by default. In order to build LLVM
 383   # with libxml2, iconv.h, etc., we must add /usr/local paths.
 384   include_directories("/usr/local/include")
 385   link_directories("/usr/local/lib")
 386 endif( ${CMAKE_SYSTEM_NAME} MATCHES FreeBSD )
 387
 388 if( ${CMAKE_SYSTEM_NAME} MATCHES SunOS )
 389    SET(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -include llvm/Support/Solaris.h")
 390 endif( ${CMAKE_SYSTEM_NAME} MATCHES SunOS )
 391
 392 # Make sure we don't get -rdynamic in every binary. For those that need it,
 393 # use set_target_properties(target PROPERTIES ENABLE_EXPORTS 1)
 394 set(CMAKE_SHARED_LIBRARY_LINK_CXX_FLAGS "")
 395
 396 include(AddLLVM)
 397 include(TableGen)
 398
 399 if( MINGW )
 400   # People report that -O3 is unreliable on MinGW. The traditional
 401   # build also uses -O2 for that reason:
 402   llvm_replace_compiler_option(CMAKE_CXX_FLAGS_RELEASE "-O3" "-O2")
 403 endif()
 404
 405 # Put this before tblgen. Else we have a circular dependence.
 406 add_subdirectory(lib/Support)
 407 add_subdirectory(lib/TableGen)
 408
 409 add_subdirectory(utils/TableGen)
 410
 411 add_subdirectory(include/llvm)
 412
 413 add_subdirectory(lib)
 414
 415 add_subdirectory(utils/FileCheck)
 416 add_subdirectory(utils/FileUpdate)
 417 add_subdirectory(utils/count)
 418 add_subdirectory(utils/not)
 419 add_subdirectory(utils/llvm-lit)
 420 add_subdirectory(utils/yaml-bench)
 421
 422 add_subdirectory(projects)
 423
 424 if( LLVM_INCLUDE_TOOLS )
 425   add_subdirectory(tools)
 426 endif()
 427
 428 if( LLVM_INCLUDE_RUNTIME )
 429   add_subdirectory(runtime)
 430 endif()
 431
 432 if( LLVM_INCLUDE_EXAMPLES )
 433   add_subdirectory(examples)
 434 endif()
 435
 436 if( LLVM_INCLUDE_TESTS )
 437   add_subdirectory(test)
 438   add_subdirectory(utils/unittest)
 439   add_subdirectory(unittests)
 440   if (MSVC)
 441     # This utility is used to prevent crashing tests from calling Dr. Watson on
 442     # Windows.
 443     add_subdirectory(utils/KillTheDoctor)
 444   endif()
 445
 446   # Add a global check rule now that all subdirectories have been traversed
 447   # and we know the total set of lit testsuites.
 448   get_property(LLVM_LIT_TESTSUITES GLOBAL PROPERTY LLVM_LIT_TESTSUITES)
 449   get_property(LLVM_LIT_PARAMS GLOBAL PROPERTY LLVM_LIT_PARAMS)
 450   get_property(LLVM_LIT_DEPENDS GLOBAL PROPERTY LLVM_LIT_DEPENDS)
 451   get_property(LLVM_LIT_EXTRA_ARGS GLOBAL PROPERTY LLVM_LIT_EXTRA_ARGS)
 452   add_lit_target(check-all
 453     "Running all regression tests"
 454     ${LLVM_LIT_TESTSUITES}
 455     PARAMS ${LLVM_LIT_PARAMS}
 456     DEPENDS ${LLVM_LIT_DEPENDS}
 457     ARGS ${LLVM_LIT_EXTRA_ARGS}
 458     )
 459 endif()
 460
 461 add_subdirectory(cmake/modules)
 462
 463 install(DIRECTORY include/
 464   DESTINATION include
 465   FILES_MATCHING
 466   PATTERN "*.def"
 467   PATTERN "*.h"
 468   PATTERN "*.td"
 469   PATTERN "*.inc"
 470   PATTERN "LICENSE.TXT"
 471   PATTERN ".svn" EXCLUDE
 472   )
 473
 474 install(DIRECTORY ${CMAKE_CURRENT_BINARY_DIR}/include/
 475   DESTINATION include
 476   FILES_MATCHING
 477   PATTERN "*.def"
 478   PATTERN "*.h"
 479   PATTERN "*.gen"
 480   PATTERN "*.inc"
 481   # Exclude include/llvm/CMakeFiles/intrinsics_gen.dir, matched by "*.def"
 482   PATTERN "CMakeFiles" EXCLUDE
 483   PATTERN ".svn" EXCLUDE
 484   )
 485
 486 # TODO: make and install documentation.
 487
 488 set(CPACK_PACKAGE_VENDOR "LLVM")
 489 set(CPACK_PACKAGE_VERSION_MAJOR ${LLVM_VERSION_MAJOR})
 490 set(CPACK_PACKAGE_VERSION_MINOR ${LLVM_VERSION_MINOR})
 491 add_version_info_from_vcs(CPACK_PACKAGE_VERSION_PATCH)
 492 include(CPack)
 493
 494 # Workaround for MSVS10 to avoid the Dialog Hell
 495 # FIXME: This could be removed with future version of CMake.
 496 if(MSVC_VERSION EQUAL 1600)
 497   set(LLVM_SLN_FILENAME "${CMAKE_CURRENT_BINARY_DIR}/LLVM.sln")
 498   if( EXISTS "${LLVM_SLN_FILENAME}" )
 499     file(APPEND "${LLVM_SLN_FILENAME}" "\n# This should be regenerated!\n")
 500   endif()
 501 endif()