CMakeLists.txt

   1 # See docs/CMake.html for instructions about how to build LLVM with CMake.
   2
   3 project(LLVM)
   4 cmake_minimum_required(VERSION 2.8)
   5
   6 # Add path for custom modules
   7 set(CMAKE_MODULE_PATH
   8   ${CMAKE_MODULE_PATH}
   9   "${CMAKE_CURRENT_SOURCE_DIR}/cmake"
  10   "${CMAKE_CURRENT_SOURCE_DIR}/cmake/modules"
  11   )
  12
  13 set(LLVM_VERSION_MAJOR 3)
  14 set(LLVM_VERSION_MINOR 1)
  15
  16 set(PACKAGE_VERSION "${LLVM_VERSION_MAJOR}.${LLVM_VERSION_MINOR}svn")
  17
  18 set_property(GLOBAL PROPERTY USE_FOLDERS ON)
  19
  20 include(VersionFromVCS)
  21
  22 option(LLVM_APPEND_VC_REV
  23   "Append the version control system revision id to LLVM version" OFF)
  24
  25 if( LLVM_APPEND_VC_REV )
  26   add_version_info_from_vcs(PACKAGE_VERSION)
  27 endif()
  28
  29 set(PACKAGE_NAME LLVM)
  30 set(PACKAGE_STRING "${PACKAGE_NAME} ${PACKAGE_VERSION}")
  31 set(PACKAGE_BUGREPORT "http://llvm.org/bugs/")
  32
  33 # Sanity check our source directory to make sure that we are not trying to
  34 # generate an in-tree build (unless on MSVC_IDE, where it is ok), and to make
  35 # sure that we don't have any stray generated files lying around in the tree
  36 # (which would end up getting picked up by header search, instead of the correct
  37 # versions).
  38 if( CMAKE_SOURCE_DIR STREQUAL CMAKE_BINARY_DIR AND NOT MSVC_IDE )
  39   message(FATAL_ERROR "In-source builds are not allowed.
  40 CMake would overwrite the makefiles distributed with LLVM.
  41 Please create a directory and run cmake from there, passing the path
  42 to this source directory as the last argument.
  43 This process created the file `CMakeCache.txt' and the directory `CMakeFiles'.
  44 Please delete them.")
  45 endif()
  46 if( NOT CMAKE_SOURCE_DIR STREQUAL CMAKE_BINARY_DIR )
  47   file(GLOB_RECURSE
  48     tablegenned_files_on_include_dir
  49     "${CMAKE_CURRENT_SOURCE_DIR}/include/llvm/*.gen")
  50   file(GLOB_RECURSE
  51     tablegenned_files_on_lib_dir
  52     "${CMAKE_CURRENT_SOURCE_DIR}/lib/Target/*.inc")
  53   if( tablegenned_files_on_include_dir OR tablegenned_files_on_lib_dir)
  54     message(FATAL_ERROR "Apparently there is a previous in-source build,
  55 probably as the result of running `configure' and `make' on
  56 ${CMAKE_CURRENT_SOURCE_DIR}.
  57 This may cause problems. The suspicious files are:
  58 ${tablegenned_files_on_lib_dir}
  59 ${tablegenned_files_on_include_dir}
  60 Please clean the source directory.")
  61   endif()
  62 endif()
  63
  64 string(TOUPPER "${CMAKE_BUILD_TYPE}" uppercase_CMAKE_BUILD_TYPE)
  65
  66 set(LLVM_MAIN_SRC_DIR ${CMAKE_CURRENT_SOURCE_DIR})
  67 set(LLVM_MAIN_INCLUDE_DIR ${LLVM_MAIN_SRC_DIR}/include)
  68 set(LLVM_BINARY_DIR ${CMAKE_CURRENT_BINARY_DIR})
  69 set(LLVM_TOOLS_BINARY_DIR ${LLVM_BINARY_DIR}/bin)
  70 set(LLVM_EXAMPLES_BINARY_DIR ${LLVM_BINARY_DIR}/examples)
  71 set(LLVM_LIBDIR_SUFFIX "" CACHE STRING "Define suffix of library directory name (32/64)" )
  72
  73 set(LLVM_ALL_TARGETS
  74   ARM
  75   CBackend
  76   CellSPU
  77   CppBackend
  78   Hexagon
  79   Mips
  80   MBlaze
  81   MSP430
  82   PowerPC
  83   PTX
  84   Sparc
  85   X86
  86   XCore
  87   )
  88
  89 # List of targets with JIT support:
  90 set(LLVM_TARGETS_WITH_JIT X86 PowerPC ARM Mips)
  91
  92 if( MSVC )
  93   set(LLVM_TARGETS_TO_BUILD X86
  94     CACHE STRING "Semicolon-separated list of targets to build, or \"all\".")
  95 else( MSVC )
  96   set(LLVM_TARGETS_TO_BUILD "all"
  97     CACHE STRING "Semicolon-separated list of targets to build, or \"all\".")
  98 endif( MSVC )
  99
 100 option(BUILD_SHARED_LIBS
 101   "Build all libraries as shared libraries instead of static" OFF)
 102
 103 option(LLVM_ENABLE_CBE_PRINTF_A "Set to ON if CBE is enabled for printf %a output" ON)
 104 if(LLVM_ENABLE_CBE_PRINTF_A)
 105   set(ENABLE_CBE_PRINTF_A 1)
 106 endif()
 107
 108 option(LLVM_ENABLE_TIMESTAMPS "Enable embedding timestamp information in build" ON)
 109 if(LLVM_ENABLE_TIMESTAMPS)
 110   set(ENABLE_TIMESTAMPS 1)
 111 endif()
 112
 113 option(LLVM_ENABLE_FFI "Use libffi to call external functions from the interpreter" OFF)
 114 set(FFI_LIBRARY_DIR "" CACHE PATH "Additional directory, where CMake should search for libffi.so")
 115 set(FFI_INCLUDE_DIR "" CACHE PATH "Additional directory, where CMake should search for ffi.h or ffi/ffi.h")
 116
 117 set(LLVM_TARGET_ARCH "host"
 118   CACHE STRING "Set target to use for LLVM JIT or use \"host\" for automatic detection.")
 119
 120 option(LLVM_ENABLE_THREADS "Use threads if available." ON)
 121
 122 if( LLVM_TARGETS_TO_BUILD STREQUAL "all" )
 123   set( LLVM_TARGETS_TO_BUILD ${LLVM_ALL_TARGETS} )
 124 endif()
 125
 126 set(LLVM_ENUM_TARGETS "")
 127 foreach(c ${LLVM_TARGETS_TO_BUILD})
 128   list(FIND LLVM_ALL_TARGETS ${c} idx)
 129   if( idx LESS 0 )
 130     message(FATAL_ERROR "The target `${c}' does not exist.
 131     It should be one of\n${LLVM_ALL_TARGETS}")
 132   else()
 133     set(LLVM_ENUM_TARGETS "${LLVM_ENUM_TARGETS}LLVM_TARGET(${c})\n")
 134   endif()
 135 endforeach(c)
 136
 137 set(llvm_builded_incs_dir ${LLVM_BINARY_DIR}/include/llvm)
 138
 139 include(AddLLVMDefinitions)
 140
 141 option(LLVM_ENABLE_PIC "Build Position-Independent Code" ON)
 142
 143 # MSVC has a gazillion warnings with this.
 144 if( MSVC )
 145   option(LLVM_ENABLE_WARNINGS "Enable compiler warnings." OFF)
 146 else( MSVC )
 147   option(LLVM_ENABLE_WARNINGS "Enable compiler warnings." ON)
 148 endif()
 149
 150 option(LLVM_ENABLE_PEDANTIC "Compile with pedantic enabled." ON)
 151 option(LLVM_ENABLE_WERROR "Fail and stop if a warning is triggered." OFF)
 152
 153 if( uppercase_CMAKE_BUILD_TYPE STREQUAL "RELEASE" )
 154   option(LLVM_ENABLE_ASSERTIONS "Enable assertions" OFF)
 155 else()
 156   option(LLVM_ENABLE_ASSERTIONS "Enable assertions" ON)
 157 endif()
 158
 159 option(LLVM_USE_INTEL_JITEVENTS
 160   "Use Intel JIT API to inform Intel(R) VTune(TM) Amplifier XE 2011 about JIT code"
 161   OFF)
 162
 163 if( LLVM_USE_INTEL_JITEVENTS )
 164   # Verify we are on a supported platform
 165   if( CMAKE_SYSTEM_NAME MATCHES "Windows" OR CMAKE_SYSTEM_NAME MATCHES "Linux" )
 166     # Directory where Intel Parallel Amplifier XE 2011 is installed.
 167     if ( WIN32 )
 168       set(LLVM_INTEL_JITEVENTS_DIR $ENV{VTUNE_AMPLIFIER_XE_2011_DIR})
 169     else ( WIN32 )
 170       set(LLVM_INTEL_JITEVENTS_DIR "/opt/intel/vtune_amplifier_xe_2011")
 171     endif ( WIN32 )
 172
 173     # Set include and library search paths for Intel JIT Events API
 174     set(LLVM_INTEL_JITEVENTS_INCDIR "${LLVM_INTEL_JITEVENTS_DIR}/include")
 175
 176     if ( CMAKE_SIZEOF_VOID_P EQUAL 8 )
 177       set(LLVM_INTEL_JITEVENTS_LIBDIR "${LLVM_INTEL_JITEVENTS_DIR}/lib64")
 178     else ( CMAKE_SIZEOF_VOID_P EQUAL 8 )
 179       set(LLVM_INTEL_JITEVENTS_LIBDIR "${LLVM_INTEL_JITEVENTS_DIR}/lib32")
 180     endif ( CMAKE_SIZEOF_VOID_P EQUAL 8 )
 181   else()
 182     message(FATAL_ERROR
 183       "Intel JIT API support is available on Linux and Windows only.")
 184   endif()
 185 endif( LLVM_USE_INTEL_JITEVENTS )
 186
 187 option(LLVM_USE_OPROFILE
 188   "Use opagent JIT interface to inform OProfile about JIT code" OFF)
 189
 190 # If enabled, ierify we are on a platform that supports oprofile.
 191 if( LLVM_USE_OPROFILE )
 192   if( NOT CMAKE_SYSTEM_NAME MATCHES "Linux" )
 193     message(FATAL_ERROR "OProfile support is available on Linux only.")
 194   endif( NOT CMAKE_SYSTEM_NAME MATCHES "Linux" )
 195 endif( LLVM_USE_OPROFILE )
 196
 197 # Define an option controlling whether we should build for 32-bit on 64-bit
 198 # platforms, where supported.
 199 if( CMAKE_SIZEOF_VOID_P EQUAL 8 AND NOT WIN32 )
 200   # TODO: support other platforms and toolchains.
 201   option(LLVM_BUILD_32_BITS "Build 32 bits executables and libraries." OFF)
 202 endif()
 203
 204 # Define the default arguments to use with 'lit', and an option for the user to
 205 # override.
 206 set(LIT_ARGS_DEFAULT "-sv")
 207 if (MSVC OR XCODE)
 208   set(LIT_ARGS_DEFAULT "${LIT_ARGS_DEFAULT} --no-progress-bar")
 209 endif()
 210 set(LLVM_LIT_ARGS "${LIT_ARGS_DEFAULT}" CACHE STRING "Default options for lit")
 211
 212 # On Win32 hosts, provide an option to specify the path to the GnuWin32 tools.
 213 if( WIN32 AND NOT CYGWIN )
 214   set(LLVM_LIT_TOOLS_DIR "" CACHE PATH "Path to GnuWin32 tools")
 215 endif()
 216
 217 # On Win32 using MS tools, provide an option to set the number of parallel jobs
 218 # to use.
 219 if( MSVC_IDE AND ( MSVC90 OR MSVC10 ) )
 220   # Only Visual Studio 2008 and 2010 officially supports /MP.  Visual Studio
 221   # 2005 supports it but it is experimental.
 222   set(LLVM_COMPILER_JOBS "0" CACHE STRING
 223     "Number of parallel compiler jobs. 0 means use all processors. Default is 0.")
 224 endif()
 225
 226 # Define options to control the inclusion and default build behavior for
 227 # components which may not strictly be necessary (tools, runtime, examples, and
 228 # tests).
 229 #
 230 # This is primarily to support building smaller or faster project files.
 231 option(LLVM_INCLUDE_TOOLS "Generate build targets for the LLVM tools." ON)
 232 option(LLVM_BUILD_TOOLS
 233   "Build the LLVM tools. If OFF, just generate build targets." ON)
 234
 235 option(LLVM_INCLUDE_RUNTIME "Generate build targets for the LLVM runtimes" ON)
 236 option(LLVM_BUILD_RUNTIME
 237   "Build the LLVM runtime libraries. If OFF, just generate build targets." ON)
 238
 239 option(LLVM_BUILD_EXAMPLES
 240   "Build the LLVM example programs. If OFF, just generate build targets." OFF)
 241 option(LLVM_INCLUDE_EXAMPLES "Generate build targets for the LLVM examples" ON)
 242
 243 option(LLVM_BUILD_TESTS
 244   "Build LLVM unit tests. If OFF, just generate build targets." OFF)
 245 option(LLVM_INCLUDE_TESTS "Generate build targets for the LLVM unit tests." ON)
 246
 247 # All options referred to from HandleLLVMOptions have to be specified
 248 # BEFORE this include, otherwise options will not be correctly set on
 249 # first cmake run
 250 include(config-ix)
 251 include(HandleLLVMOptions)
 252
 253 # Verify that we can find a Python interpreter,
 254 include(FindPythonInterp)
 255 if( NOT PYTHONINTERP_FOUND )
 256   message(FATAL_ERROR
 257 "Unable to find Python interpreter, required for builds and testing.
 258
 259 Please install Python or specify the PYTHON_EXECUTABLE CMake variable.")
 260 endif()
 261
 262 ######
 263 # LLVMBuild Integration
 264 #
 265 # We use llvm-build to generate all the data required by the CMake based
 266 # build system in one swoop:
 267 #
 268 #  - We generate a file (a CMake fragment) in the object root which contains
 269 #    all the definitions that are required by CMake.
 270 #
 271 #  - We generate the library table used by llvm-config.
 272 #
 273 #  - We generate the dependencies for the CMake fragment, so that we will
 274 #    automatically reconfigure outselves.
 275
 276 set(LLVMBUILDTOOL "${LLVM_MAIN_SRC_DIR}/utils/llvm-build/llvm-build")
 277 set(LLVMCONFIGLIBRARYDEPENDENCIESINC
 278   "${LLVM_BINARY_DIR}/tools/llvm-config/LibraryDependencies.inc")
 279 set(LLVMBUILDCMAKEFRAG
 280   "${LLVM_BINARY_DIR}/LLVMBuild.cmake")
 281 message(STATUS "Constructing LLVMBuild project information")
 282 execute_process(
 283   COMMAND ${PYTHON_EXECUTABLE} ${LLVMBUILDTOOL}
 284             --native-target "${LLVM_NATIVE_ARCH}"
 285             --enable-targets "${LLVM_TARGETS_TO_BUILD}"
 286             --write-library-table ${LLVMCONFIGLIBRARYDEPENDENCIESINC}
 287             --write-cmake-fragment ${LLVMBUILDCMAKEFRAG}
 288             ERROR_VARIABLE LLVMBUILDOUTPUT
 289             ERROR_VARIABLE LLVMBUILDERRORS
 290             OUTPUT_STRIP_TRAILING_WHITESPACE
 291             ERROR_STRIP_TRAILING_WHITESPACE
 292   RESULT_VARIABLE LLVMBUILDRESULT)
 293
 294 # On Win32, CMake doesn't properly handle piping the default output/error
 295 # streams into the GUI console. So, we explicitly catch and report them.
 296 if( NOT "${LLVMBUILDOUTPUT}" STREQUAL "")
 297   message(STATUS "llvm-build output: ${LLVMBUILDOUTPUT}")
 298 endif()
 299 if( NOT "${LLVMBUILDRESULT}" STREQUAL "0" )
 300   message(FATAL_ERROR
 301     "Unexpected failure executing llvm-build: ${LLVMBUILDERRORS}")
 302 endif()
 303
 304 # Include the generated CMake fragment. This will define properties from the
 305 # LLVMBuild files in a format which is easy to consume from CMake, and will add
 306 # the dependencies so that CMake will reconfigure properly when the LLVMBuild
 307 # files change.
 308 include(${LLVMBUILDCMAKEFRAG})
 309
 310 ######
 311
 312 # Configure all of the various header file fragments LLVM uses which depend on
 313 # configuration variables.
 314 set(LLVM_ENUM_ASM_PRINTERS "")
 315 set(LLVM_ENUM_ASM_PARSERS "")
 316 set(LLVM_ENUM_DISASSEMBLERS "")
 317 foreach(t ${LLVM_TARGETS_TO_BUILD})
 318   set( td ${LLVM_MAIN_SRC_DIR}/lib/Target/${t} )
 319   file(GLOB asmp_file "${td}/*AsmPrinter.cpp")
 320   if( asmp_file )
 321     set(LLVM_ENUM_ASM_PRINTERS
 322       "${LLVM_ENUM_ASM_PRINTERS}LLVM_ASM_PRINTER(${t})\n")
 323   endif()
 324   if( EXISTS ${td}/AsmParser/CMakeLists.txt )
 325     set(LLVM_ENUM_ASM_PARSERS
 326       "${LLVM_ENUM_ASM_PARSERS}LLVM_ASM_PARSER(${t})\n")
 327   endif()
 328   if( EXISTS ${td}/Disassembler/CMakeLists.txt )
 329     set(LLVM_ENUM_DISASSEMBLERS
 330       "${LLVM_ENUM_DISASSEMBLERS}LLVM_DISASSEMBLER(${t})\n")
 331   endif()
 332 endforeach(t)
 333
 334 # Produce the target definition files, which provide a way for clients to easily
 335 # include various classes of targets.
 336 configure_file(
 337   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/AsmPrinters.def.in
 338   ${LLVM_BINARY_DIR}/include/llvm/Config/AsmPrinters.def
 339   )
 340 configure_file(
 341   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/AsmParsers.def.in
 342   ${LLVM_BINARY_DIR}/include/llvm/Config/AsmParsers.def
 343   )
 344 configure_file(
 345   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/Disassemblers.def.in
 346   ${LLVM_BINARY_DIR}/include/llvm/Config/Disassemblers.def
 347   )
 348 configure_file(
 349   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/Targets.def.in
 350   ${LLVM_BINARY_DIR}/include/llvm/Config/Targets.def
 351   )
 352
 353 # Configure the three LLVM configuration header files.
 354 configure_file(
 355   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/config.h.cmake
 356   ${LLVM_BINARY_DIR}/include/llvm/Config/config.h)
 357 configure_file(
 358   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/llvm-config.h.cmake
 359   ${LLVM_BINARY_DIR}/include/llvm/Config/llvm-config.h)
 360 configure_file(
 361   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Support/DataTypes.h.cmake
 362   ${LLVM_BINARY_DIR}/include/llvm/Support/DataTypes.h)
 363
 364 set( CMAKE_RUNTIME_OUTPUT_DIRECTORY ${LLVM_TOOLS_BINARY_DIR} )
 365 set( CMAKE_LIBRARY_OUTPUT_DIRECTORY ${LLVM_BINARY_DIR}/lib )
 366 set( CMAKE_ARCHIVE_OUTPUT_DIRECTORY ${LLVM_BINARY_DIR}/lib )
 367
 368 set(CMAKE_INCLUDE_CURRENT_DIR ON)
 369
 370 include_directories( ${LLVM_BINARY_DIR}/include ${LLVM_MAIN_INCLUDE_DIR})
 371
 372 if( ${CMAKE_SYSTEM_NAME} MATCHES SunOS )
 373    SET(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -include llvm/Support/Solaris.h")
 374 endif( ${CMAKE_SYSTEM_NAME} MATCHES SunOS )
 375
 376 include(AddLLVM)
 377 include(TableGen)
 378
 379 if( MINGW )
 380   # People report that -O3 is unreliable on MinGW. The traditional
 381   # build also uses -O2 for that reason:
 382   llvm_replace_compiler_option(CMAKE_CXX_FLAGS_RELEASE "-O3" "-O2")
 383 endif()
 384
 385 # Put this before tblgen. Else we have a circular dependence.
 386 add_subdirectory(lib/Support)
 387 add_subdirectory(lib/TableGen)
 388
 389 add_subdirectory(utils/TableGen)
 390
 391 add_subdirectory(include/llvm)
 392
 393 add_subdirectory(lib)
 394
 395 add_subdirectory(utils/FileCheck)
 396 add_subdirectory(utils/FileUpdate)
 397 add_subdirectory(utils/count)
 398 add_subdirectory(utils/not)
 399 add_subdirectory(utils/llvm-lit)
 400 add_subdirectory(utils/json-bench)
 401
 402 add_subdirectory(projects)
 403
 404 if( LLVM_INCLUDE_TOOLS )
 405   add_subdirectory(tools)
 406 endif()
 407
 408 if( LLVM_INCLUDE_RUNTIME )
 409   add_subdirectory(runtime)
 410 endif()
 411
 412 if( LLVM_INCLUDE_EXAMPLES )
 413   add_subdirectory(examples)
 414 endif()
 415
 416 if( LLVM_INCLUDE_TESTS )
 417   add_subdirectory(test)
 418   add_subdirectory(utils/unittest)
 419   add_subdirectory(unittests)
 420   if (MSVC)
 421     # This utility is used to prevent chrashing tests from calling Dr. Watson on
 422     # Windows.
 423     add_subdirectory(utils/KillTheDoctor)
 424   endif()
 425 endif()
 426
 427 add_subdirectory(cmake/modules)
 428
 429 install(DIRECTORY include/
 430   DESTINATION include
 431   FILES_MATCHING
 432   PATTERN "*.def"
 433   PATTERN "*.h"
 434   PATTERN "*.td"
 435   PATTERN "*.inc"
 436   PATTERN "LICENSE.TXT"
 437   PATTERN ".svn" EXCLUDE
 438   )
 439
 440 install(DIRECTORY ${CMAKE_CURRENT_BINARY_DIR}/include/
 441   DESTINATION include
 442   FILES_MATCHING
 443   PATTERN "*.def"
 444   PATTERN "*.h"
 445   PATTERN "*.gen"
 446   PATTERN "*.inc"
 447   # Exclude include/llvm/CMakeFiles/intrinsics_gen.dir, matched by "*.def"
 448   PATTERN "CMakeFiles" EXCLUDE
 449   PATTERN ".svn" EXCLUDE
 450   )
 451
 452 # TODO: make and install documentation.
 453
 454 set(CPACK_PACKAGE_VENDOR "LLVM")
 455 set(CPACK_PACKAGE_VERSION_MAJOR ${LLVM_VERSION_MAJOR})
 456 set(CPACK_PACKAGE_VERSION_MINOR ${LLVM_VERSION_MINOR})
 457 add_version_info_from_vcs(CPACK_PACKAGE_VERSION_PATCH)
 458 include(CPack)
 459
 460 # Workaround for MSVS10 to avoid the Dialog Hell
 461 # FIXME: This could be removed with future version of CMake.
 462 if(MSVC_VERSION EQUAL 1600)
 463   set(LLVM_SLN_FILENAME "${CMAKE_CURRENT_BINARY_DIR}/LLVM.sln")
 464   if( EXISTS "${LLVM_SLN_FILENAME}" )
 465     file(APPEND "${LLVM_SLN_FILENAME}" "\n# This should be regenerated!\n")
 466   endif()
 467 endif()