CMakeLists.txt

   1 # See docs/CMake.html for instructions about how to build LLVM with CMake.
   2
   3 project(LLVM)
   4 cmake_minimum_required(VERSION 2.6.1)
   5
   6 set(PACKAGE_NAME llvm)
   7 set(PACKAGE_VERSION 2.6svn)
   8 set(PACKAGE_STRING "${PACKAGE_NAME} ${PACKAGE_VERSION}")
   9 set(PACKAGE_BUGREPORT "llvmbugs@cs.uiuc.edu")
  10
  11 if( CMAKE_SOURCE_DIR STREQUAL CMAKE_BINARY_DIR AND NOT MSVC_IDE )
  12   message(FATAL_ERROR "In-source builds are not allowed.
  13 CMake would overwrite the makefiles distributed with LLVM.
  14 Please create a directory and run cmake from there, passing the path
  15 to this source directory as the last argument.
  16 This process created the file `CMakeCache.txt' and the directory `CMakeFiles'.
  17 Please delete them.")
  18 endif()
  19
  20 string(TOUPPER "${CMAKE_BUILD_TYPE}" uppercase_CMAKE_BUILD_TYPE)
  21
  22 include(FindPerl)
  23
  24 set(LLVM_MAIN_SRC_DIR ${CMAKE_CURRENT_SOURCE_DIR})
  25 set(LLVM_MAIN_INCLUDE_DIR ${LLVM_MAIN_SRC_DIR}/include)
  26 set(LLVM_BINARY_DIR ${CMAKE_CURRENT_BINARY_DIR})
  27 set(LLVM_TOOLS_BINARY_DIR ${LLVM_BINARY_DIR}/bin)
  28 set(LLVM_EXAMPLES_BINARY_DIR ${LLVM_BINARY_DIR}/examples)
  29
  30 set(LLVM_ALL_TARGETS
  31   Alpha
  32   ARM
  33   CBackend
  34   CellSPU
  35   CppBackend
  36   IA64
  37   Mips
  38   MSIL
  39   PIC16
  40   PowerPC
  41   Sparc
  42   X86
  43   XCore
  44   )
  45
  46 # List of targets whose asmprinters need to be forced to link
  47 # into executables on some platforms (i.e. Windows):
  48 set(LLVM_ASMPRINTERS_FORCE_LINK X86 PowerPC)
  49
  50 if( MSVC )
  51   set(LLVM_TARGETS_TO_BUILD X86
  52     CACHE STRING "Semicolon-separated list of targets to build, or \"all\".")
  53 else( MSVC )
  54   set(LLVM_TARGETS_TO_BUILD ${LLVM_ALL_TARGETS}
  55     CACHE STRING "Semicolon-separated list of targets to build, or \"all\".")
  56 endif( MSVC )
  57
  58 option(LLVM_ENABLE_THREADS "Use threads if available." ON)
  59
  60 if( uppercase_CMAKE_BUILD_TYPE STREQUAL "RELEASE" )
  61   option(LLVM_ENABLE_ASSERTIONS "Enable assertions" OFF)
  62 else()
  63   option(LLVM_ENABLE_ASSERTIONS "Enable assertions" ON)
  64 endif()
  65
  66 if( LLVM_ENABLE_ASSERTIONS )
  67   add_definitions( -D_DEBUG )
  68   # On Release builds cmake automatically defines NDEBUG, so we
  69   # explicitly undefine it:
  70   if( uppercase_CMAKE_BUILD_TYPE STREQUAL "RELEASE" )
  71     add_definitions( -UNDEBUG )
  72   endif()
  73 else()
  74   if( NOT uppercase_CMAKE_BUILD_TYPE STREQUAL "RELEASE" )
  75     add_definitions( -DNDEBUG )
  76   endif()
  77 endif()
  78
  79 if( LLVM_TARGETS_TO_BUILD STREQUAL "all" )
  80   set( LLVM_TARGETS_TO_BUILD ${LLVM_ALL_TARGETS} )
  81 endif()
  82
  83 foreach(c ${LLVM_TARGETS_TO_BUILD})
  84   list(FIND LLVM_ALL_TARGETS ${c} idx)
  85   if( idx LESS 0 )
  86     message(FATAL_ERROR "The target `${c}' does not exists.
  87     It should be one of\n${LLVM_ALL_TARGETS}")
  88   endif()
  89 endforeach(c)
  90
  91 set(llvm_builded_incs_dir ${LLVM_BINARY_DIR}/include/llvm)
  92
  93 # The USE_EXPLICIT_DEPENDENCIES variable will be TRUE to indicate that
  94 # we should use the library dependencies explicitly specified in the
  95 # CMakeLists.txt files rather than those determined by
  96 # llvm-config. This value must be true for non-make and IDE
  97 # generators.
  98 if (MSVC_IDE)
  99   set(DEFAULT_USE_EXPLICIT_DEPENDENCIES ON)
 100 elseif (XCODE)
 101   set(DEFAULT_USE_EXPLICIT_DEPENDENCIES ON)
 102 else ()
 103  set(DEFAULT_USE_EXPLICIT_DEPENDENCIES OFF)
 104 endif ()
 105
 106 option(USE_EXPLICIT_DEPENDENCIES
 107   "Use explicit dependencies instead of llvm-config"
 108   ${DEFAULT_USE_EXPLICIT_DEPENDENCIES})
 109 mark_as_advanced(USE_EXPLICIT_DEPENDENCIES)
 110
 111 # Add path for custom modules
 112 set(CMAKE_MODULE_PATH
 113   ${CMAKE_MODULE_PATH}
 114   "${LLVM_MAIN_SRC_DIR}/cmake"
 115   "${LLVM_MAIN_SRC_DIR}/cmake/modules"
 116   )
 117
 118 include(AddLLVMDefinitions)
 119
 120 if(WIN32)
 121   if(CYGWIN)
 122     set(LLVM_ON_WIN32 0)
 123     set(LLVM_ON_UNIX 1)
 124   else(CYGWIN)
 125     set(LLVM_ON_WIN32 1)
 126     set(LLVM_ON_UNIX 0)
 127   endif(CYGWIN)
 128   set(LTDL_SHLIB_EXT ".dll")
 129   set(EXEEXT ".exe")
 130   # Maximum path length is 160 for non-unicode paths
 131   set(MAXPATHLEN 160)
 132 else(WIN32)
 133   if(UNIX)
 134     set(LLVM_ON_WIN32 0)
 135     set(LLVM_ON_UNIX 1)
 136     set(LTDL_SHLIB_EXT ".so")
 137     set(EXEEXT "")
 138     # FIXME: Maximum path length is currently set to 'safe' fixed value
 139     set(MAXPATHLEN 2024)
 140   else(UNIX)
 141     MESSAGE(SEND_ERROR "Unable to determine platform")
 142   endif(UNIX)
 143 endif(WIN32)
 144
 145 if( EXISTS ${LLVM_TOOLS_BINARY_DIR}/llvm-config )
 146   set(HAVE_LLVM_CONFIG 1)
 147 endif( EXISTS ${LLVM_TOOLS_BINARY_DIR}/llvm-config )
 148
 149 include(config-ix)
 150
 151 option(LLVM_ENABLE_PIC "Build Position-Independent Code" OFF)
 152
 153 set(ENABLE_PIC 0)
 154 if( LLVM_ENABLE_PIC )
 155   if( SUPPORTS_FPIC_FLAG )
 156     message(STATUS "Building with -fPIC")
 157     add_llvm_definitions(-fPIC)
 158     set(ENABLE_PIC 1)
 159  else( SUPPORTS_FPIC_FLAG )
 160     message(STATUS "Warning: -fPIC not supported.")
 161   endif()
 162 endif()
 163
 164 set( CMAKE_RUNTIME_OUTPUT_DIRECTORY ${LLVM_TOOLS_BINARY_DIR} )
 165 set( CMAKE_LIBRARY_OUTPUT_DIRECTORY ${LLVM_BINARY_DIR}/lib )
 166 set( CMAKE_ARCHIVE_OUTPUT_DIRECTORY ${LLVM_BINARY_DIR}/lib )
 167
 168 # set(CMAKE_VERBOSE_MAKEFILE true)
 169
 170 add_llvm_definitions( -D__STDC_LIMIT_MACROS )
 171 add_llvm_definitions( -D__STDC_CONSTANT_MACROS )
 172
 173 set(LLVM_PLO_FLAGS "" CACHE
 174   STRING "Flags for creating partially linked objects.")
 175
 176 if( CMAKE_SIZEOF_VOID_P EQUAL 8 AND NOT WIN32 )
 177   # TODO: support other platforms and toolchains.
 178   option(LLVM_BUILD_32_BITS "Build 32 bits executables and libraries." OFF)
 179   if( LLVM_BUILD_32_BITS )
 180     message(STATUS "Building 32 bits executables and libraries.")
 181     add_llvm_definitions( -m32 )
 182     list(APPEND CMAKE_EXE_LINKER_FLAGS -m32)
 183     list(APPEND CMAKE_SHARED_LINKER_FLAGS -m32)
 184     set( LLVM_PLO_FLAGS -melf_i386 ${LLVM_PLO_FLAGS} )
 185   endif( LLVM_BUILD_32_BITS )
 186 endif( CMAKE_SIZEOF_VOID_P EQUAL 8 AND NOT WIN32 )
 187
 188 if( MSVC )
 189   add_llvm_definitions( -D_CRT_SECURE_NO_DEPRECATE -D_CRT_SECURE_NO_WARNINGS )
 190   add_llvm_definitions( -D_SCL_SECURE_NO_WARNINGS -DCRT_NONSTDC_NO_WARNINGS )
 191   add_llvm_definitions( -D_SCL_SECURE_NO_DEPRECATE )
 192   add_llvm_definitions( -wd4146 -wd4503 -wd4996 -wd4800 -wd4244 -wd4624 )
 193   add_llvm_definitions( -wd4355 -wd4715 -wd4180 -wd4345 -wd4224 )
 194 endif( MSVC )
 195
 196 include_directories( ${LLVM_BINARY_DIR}/include ${LLVM_MAIN_INCLUDE_DIR})
 197
 198 include(AddLLVM)
 199 include(AddPartiallyLinkedObject)
 200 include(TableGen)
 201
 202 add_subdirectory(lib/Support)
 203 add_subdirectory(lib/System)
 204
 205 # Everything else depends on Support and System:
 206 set(LLVM_COMMON_DEPENDS ${LLVM_COMMON_DEPENDS} ${LLVM_LIBS} )
 207
 208 set(LLVM_TABLEGEN "tblgen" CACHE
 209   STRING "Native TableGen executable. Saves building one when cross-compiling.")
 210
 211 add_subdirectory(utils/TableGen)
 212
 213 if( CMAKE_CROSSCOMPILING )
 214   # This adds a dependency on target `tblgen', so must go after utils/TableGen
 215   include( CrossCompileLLVM )
 216 endif( CMAKE_CROSSCOMPILING )
 217
 218 add_subdirectory(include/llvm)
 219
 220 add_subdirectory(lib/VMCore)
 221 add_subdirectory(lib/CodeGen)
 222 add_subdirectory(lib/CodeGen/SelectionDAG)
 223 add_subdirectory(lib/CodeGen/AsmPrinter)
 224 add_subdirectory(lib/Bitcode/Reader)
 225 add_subdirectory(lib/Bitcode/Writer)
 226 add_subdirectory(lib/Transforms/Utils)
 227 add_subdirectory(lib/Transforms/Instrumentation)
 228 add_subdirectory(lib/Transforms/Scalar)
 229 add_subdirectory(lib/Transforms/IPO)
 230 add_subdirectory(lib/Transforms/Hello)
 231 add_subdirectory(lib/Linker)
 232 add_subdirectory(lib/Analysis)
 233 add_subdirectory(lib/Analysis/IPA)
 234
 235 foreach(t ${LLVM_TARGETS_TO_BUILD})
 236   message(STATUS "Targeting ${t}")
 237   add_subdirectory(lib/Target/${t})
 238   if( EXISTS ${LLVM_MAIN_SRC_DIR}/lib/Target/${t}/AsmPrinter/CMakeLists.txt )
 239     add_subdirectory(lib/Target/${t}/AsmPrinter)
 240   endif( EXISTS ${LLVM_MAIN_SRC_DIR}/lib/Target/${t}/AsmPrinter/CMakeLists.txt )
 241 endforeach(t)
 242
 243 add_subdirectory(lib/ExecutionEngine)
 244 add_subdirectory(lib/ExecutionEngine/Interpreter)
 245 add_subdirectory(lib/ExecutionEngine/JIT)
 246 add_subdirectory(lib/Target)
 247 add_subdirectory(lib/AsmParser)
 248 add_subdirectory(lib/Debugger)
 249 add_subdirectory(lib/Archive)
 250
 251 add_subdirectory(projects)
 252 add_subdirectory(tools)
 253
 254 add_subdirectory(examples)
 255
 256 install(DIRECTORY include
 257   DESTINATION .
 258   PATTERN ".svn" EXCLUDE
 259   PATTERN "*.cmake" EXCLUDE
 260   PATTERN "*.in" EXCLUDE
 261   )
 262
 263 install(DIRECTORY ${CMAKE_CURRENT_BINARY_DIR}/include
 264   DESTINATION .
 265   )
 266
 267 # TODO: make and install documentation.