CMakeLists.txt

   1 project(LLVM)
   2 cmake_minimum_required(VERSION 2.6.1)
   3
   4 set(PACKAGE_NAME llvm)
   5 set(PACKAGE_VERSION svn)
   6 set(PACKAGE_BUGREPORT "llvmbugs@cs.uiuc.edu")
   7
   8 if( CMAKE_SOURCE_DIR STREQUAL CMAKE_BINARY_DIR AND NOT MSVC_IDE )
   9   message(FATAL_ERROR "In-source builds are not allowed.
  10 CMake would overwrite the makefiles distributed with LLVM.
  11 Please create a directory and run cmake from there, passing the path
  12 to this source directory as the last argument.
  13 This process created the file `CMakeCache.txt' and the directory `CMakeFiles'.
  14 Please delete them.")
  15 endif()
  16
  17 include(FindPerl)
  18
  19 set(LLVM_MAIN_SRC_DIR ${CMAKE_CURRENT_SOURCE_DIR})
  20 set(LLVM_MAIN_INCLUDE_DIR ${LLVM_MAIN_SRC_DIR}/include)
  21 set(LLVM_BINARY_DIR ${CMAKE_CURRENT_BINARY_DIR})
  22 set(LLVM_TOOLS_BINARY_DIR ${LLVM_BINARY_DIR}/bin)
  23 set(LLVM_EXAMPLES_BINARY_DIR ${LLVM_BINARY_DIR}/examples)
  24
  25 set(LLVM_ALL_TARGETS
  26   Alpha
  27   ARM
  28   CBackend
  29   CellSPU
  30   CppBackend
  31   IA64
  32   Mips
  33   MSIL
  34   PIC16
  35   PowerPC
  36   Sparc
  37   X86
  38   XCore
  39   )
  40
  41 if( MSVC )
  42   set(LLVM_TARGETS_TO_BUILD X86
  43     CACHE STRING "Semicolon-separated list of targets to build, or \"all\".")
  44 else( MSVC )
  45   set(LLVM_TARGETS_TO_BUILD ${LLVM_ALL_TARGETS}
  46     CACHE STRING "Semicolon-separated list of targets to build, or \"all\".")
  47 endif( MSVC )
  48
  49 if( LLVM_TARGETS_TO_BUILD STREQUAL "all" )
  50   set( LLVM_TARGETS_TO_BUILD ${LLVM_ALL_TARGETS} )
  51 endif()
  52
  53 foreach(c ${LLVM_TARGETS_TO_BUILD})
  54   list(FIND LLVM_ALL_TARGETS ${c} idx)
  55   if( idx LESS 0 )
  56     message(FATAL_ERROR "The target `${c}' does not exists.
  57     It should be one of\n${LLVM_ALL_TARGETS}")
  58   endif()
  59 endforeach(c)
  60
  61 set(llvm_builded_incs_dir ${LLVM_BINARY_DIR}/include/llvm)
  62
  63 # Add path for custom modules
  64 set(CMAKE_MODULE_PATH
  65   ${CMAKE_MODULE_PATH}
  66   "${LLVM_MAIN_SRC_DIR}/cmake"
  67   "${LLVM_MAIN_SRC_DIR}/cmake/modules"
  68   )
  69
  70 if(WIN32)
  71   if(CYGWIN)
  72     set(LLVM_ON_WIN32 0)
  73     set(LLVM_ON_UNIX 1)
  74   else(CYGWIN)
  75     set(LLVM_ON_WIN32 1)
  76     set(LLVM_ON_UNIX 0)
  77   endif(CYGWIN)
  78   set(LTDL_SHLIB_EXT ".dll")
  79   set(EXEEXT ".exe")
  80   # Maximum path length is 160 for non-unicode paths
  81   set(MAXPATHLEN 160)
  82 else(WIN32)
  83   if(UNIX)
  84     set(LLVM_ON_WIN32 0)
  85     set(LLVM_ON_UNIX 1)
  86     set(LTDL_SHLIB_EXT ".so")
  87     set(EXEEXT "")
  88     # FIXME: Maximum path length is currently set to 'safe' fixed value
  89     set(MAXPATHLEN 2024)
  90   else(UNIX)
  91     MESSAGE(SEND_ERROR "Unable to determine platform")
  92   endif(UNIX)
  93 endif(WIN32)
  94
  95 if( EXISTS ${LLVM_TOOLS_BINARY_DIR}/llvm-config )
  96   set(HAVE_LLVM_CONFIG 1)
  97 endif( EXISTS ${LLVM_TOOLS_BINARY_DIR}/llvm-config )
  98
  99 include(config-ix)
 100
 101 set( CMAKE_RUNTIME_OUTPUT_DIRECTORY ${LLVM_TOOLS_BINARY_DIR} )
 102 set( CMAKE_LIBRARY_OUTPUT_DIRECTORY ${LLVM_BINARY_DIR}/lib )
 103 set( CMAKE_ARCHIVE_OUTPUT_DIRECTORY ${LLVM_BINARY_DIR}/lib )
 104
 105 # set(CMAKE_VERBOSE_MAKEFILE true)
 106
 107 add_definitions( -D__STDC_LIMIT_MACROS )
 108 add_definitions( -D__STDC_CONSTANT_MACROS )
 109
 110 set(LLVM_PLO_FLAGS "" CACHE
 111   STRING "Flags for creating partially linked objects.")
 112
 113 if( CMAKE_SIZEOF_VOID_P EQUAL 8 AND NOT WIN32 )
 114   # TODO: support other platforms and toolchains.
 115   option(BUILD_32_BITS "Build 32 bits executables and libraries." OFF)
 116   if( BUILD_32_BITS )
 117     message(STATUS "Building 32 bits executables and libraries.")
 118     add_definitions( -m32 )
 119     set( CMAKE_EXE_LINKER_FLAGS "-m32 ${CMAKE_EXE_LINKER_FLAGS}" )
 120     set( CMAKE_LINK_LIBRARY_FLAG "-m32 ${CMAKE_LINK_LIBRARY_FLAG}" )
 121     set( LLVM_PLO_FLAGS -melf_i386 ${LLVM_PLO_FLAGS} )
 122   endif( BUILD_32_BITS )
 123 endif( CMAKE_SIZEOF_VOID_P EQUAL 8 AND NOT WIN32 )
 124
 125 if( MSVC )
 126   add_definitions( -D_CRT_SECURE_NO_DEPRECATE -D_CRT_SECURE_NO_WARNINGS )
 127   add_definitions( -D_SCL_SECURE_NO_WARNINGS -DCRT_NONSTDC_NO_WARNINGS )
 128   add_definitions( -D_SCL_SECURE_NO_DEPRECATE )
 129   add_definitions( -wd4146 -wd4503 -wd4996 -wd4800 -wd4244 -wd4624 )
 130   add_definitions( -wd4355 -wd4715 )
 131 endif( MSVC )
 132
 133 include_directories( ${LLVM_BINARY_DIR}/include ${LLVM_MAIN_INCLUDE_DIR})
 134
 135 include(AddLLVM)
 136 include(AddPartiallyLinkedObject)
 137 include(TableGen)
 138
 139 add_subdirectory(lib/Support)
 140 add_subdirectory(lib/System)
 141
 142 # Everything else depends on Support and System:
 143 set(LLVM_COMMON_DEPENDS ${LLVM_COMMON_DEPENDS} ${LLVM_LIBS} )
 144
 145 set(LLVM_TABLEGEN "tblgen" CACHE
 146   STRING "Native TableGen executable. Saves building one when cross-compiling.")
 147
 148 add_subdirectory(utils/TableGen)
 149
 150 if( CMAKE_CROSSCOMPILING )
 151   # This adds a dependency on target `tblgen', so must go after utils/TableGen
 152   include( CrossCompileLLVM )
 153 endif( CMAKE_CROSSCOMPILING )
 154
 155 add_subdirectory(include/llvm)
 156
 157 add_subdirectory(lib/VMCore)
 158 add_subdirectory(lib/CodeGen)
 159 add_subdirectory(lib/CodeGen/SelectionDAG)
 160 add_subdirectory(lib/CodeGen/AsmPrinter)
 161 add_subdirectory(lib/Bitcode/Reader)
 162 add_subdirectory(lib/Bitcode/Writer)
 163 add_subdirectory(lib/Transforms/Utils)
 164 add_subdirectory(lib/Transforms/Instrumentation)
 165 add_subdirectory(lib/Transforms/Scalar)
 166 add_subdirectory(lib/Transforms/IPO)
 167 add_subdirectory(lib/Transforms/Hello)
 168 add_subdirectory(lib/Linker)
 169 add_subdirectory(lib/Analysis)
 170 add_subdirectory(lib/Analysis/IPA)
 171
 172 foreach(t ${LLVM_TARGETS_TO_BUILD})
 173   message(STATUS "Targeting ${t}")
 174   add_subdirectory(lib/Target/${t})
 175   if( EXISTS ${LLVM_MAIN_SRC_DIR}/lib/Target/${t}/AsmPrinter/CMakeLists.txt )
 176     add_subdirectory(lib/Target/${t}/AsmPrinter)
 177   endif( EXISTS ${LLVM_MAIN_SRC_DIR}/lib/Target/${t}/AsmPrinter/CMakeLists.txt )
 178 endforeach(t)
 179
 180 add_subdirectory(lib/ExecutionEngine)
 181 add_subdirectory(lib/ExecutionEngine/Interpreter)
 182 add_subdirectory(lib/ExecutionEngine/JIT)
 183 add_subdirectory(lib/Target)
 184 add_subdirectory(lib/AsmParser)
 185 add_subdirectory(lib/Debugger)
 186 add_subdirectory(lib/Archive)
 187
 188 add_subdirectory(tools)
 189
 190 add_subdirectory(examples)
 191
 192 install(DIRECTORY include
 193   DESTINATION .
 194   PATTERN ".svn" EXCLUDE
 195   PATTERN "*.cmake" EXCLUDE
 196   PATTERN "*.in" EXCLUDE
 197   )
 198
 199 install(DIRECTORY ${CMAKE_CURRENT_BINARY_DIR}/include
 200   DESTINATION .
 201   )
 202
 203 # TODO: make and install documentation.