CMakeLists.txt

   1 project(LLVM)
   2 cmake_minimum_required(VERSION 2.6.1)
   3
   4 set(PACKAGE_NAME llvm)
   5 set(PACKAGE_VERSION svn)
   6 set(PACKAGE_BUGREPORT "llvmbugs@cs.uiuc.edu")
   7
   8 include(FindPerl)
   9
  10 set(LLVM_MAIN_SRC_DIR ${CMAKE_CURRENT_SOURCE_DIR})
  11 set(LLVM_MAIN_INCLUDE_DIR ${LLVM_MAIN_SRC_DIR}/include)
  12 set(LLVM_BINARY_DIR ${CMAKE_CURRENT_BINARY_DIR})
  13 set(LLVM_TOOLS_BINARY_DIR ${LLVM_BINARY_DIR}/bin)
  14 set(LLVM_EXAMPLES_BINARY_DIR ${LLVM_BINARY_DIR}/examples)
  15
  16 if( MSVC )
  17   set(LLVM_TARGETS_TO_BUILD X86
  18     CACHE STRING "Semicolon-separated list of targets to build")
  19 else( MSVC )
  20   set(LLVM_TARGETS_TO_BUILD
  21     Alpha ARM CBackend CellSPU CppBackend IA64 Mips MSIL PIC16 PowerPC Sparc X86
  22     CACHE STRING "Semicolon-separated list of targets to build")
  23 endif( MSVC )
  24
  25 set(llvm_builded_incs_dir ${LLVM_BINARY_DIR}/include/llvm)
  26
  27 # Add path for custom modules
  28 set(CMAKE_MODULE_PATH
  29   ${CMAKE_MODULE_PATH}
  30   "${LLVM_MAIN_SRC_DIR}/cmake"
  31   "${LLVM_MAIN_SRC_DIR}/cmake/modules"
  32   )
  33
  34 if(WIN32)
  35   if(CYGWIN)
  36     set(LLVM_ON_WIN32 0)
  37     set(LLVM_ON_UNIX 1)
  38   else(CYGWIN)
  39     set(LLVM_ON_WIN32 1)
  40     set(LLVM_ON_UNIX 0)
  41   endif(CYGWIN)
  42   set(LTDL_SHLIB_EXT ".dll")
  43   set(EXEEXT ".exe")
  44   # Maximum path length is 160 for non-unicode paths
  45   set(MAXPATHLEN 160)
  46 else(WIN32)
  47   if(UNIX)
  48     set(LLVM_ON_WIN32 0)
  49     set(LLVM_ON_UNIX 1)
  50     set(LTDL_SHLIB_EXT ".so")
  51     set(EXEEXT "")
  52     # FIXME: Maximum path length is currently set to 'safe' fixed value
  53     set(MAXPATHLEN 2024)
  54   else(UNIX)
  55     MESSAGE(SEND_ERROR "Unable to determine platform")
  56   endif(UNIX)
  57 endif(WIN32)
  58
  59 if( EXISTS ${LLVM_TOOLS_BINARY_DIR}/llvm-config )
  60   set(HAVE_LLVM_CONFIG 1)
  61 endif( EXISTS ${LLVM_TOOLS_BINARY_DIR}/llvm-config )
  62 # find_file(HAVE_LLVM_CONFIG llvm-config ${LLVM_TOOLS_BINARY_DIR})
  63 # message(STATUS ${HAVE_LLVM_CONFIG})
  64
  65 include(config-ix)
  66
  67 set( CMAKE_RUNTIME_OUTPUT_DIRECTORY ${LLVM_TOOLS_BINARY_DIR} )
  68 set( CMAKE_LIBRARY_OUTPUT_DIRECTORY ${LLVM_BINARY_DIR}/lib )
  69 set( CMAKE_ARCHIVE_OUTPUT_DIRECTORY ${LLVM_BINARY_DIR}/lib )
  70
  71 # set(CMAKE_VERBOSE_MAKEFILE true)
  72
  73 add_definitions( -D__STDC_LIMIT_MACROS )
  74 add_definitions( -D__STDC_CONSTANT_MACROS )
  75
  76 if( MSVC )
  77   add_definitions( -D_CRT_SECURE_NO_DEPRECATE -D_CRT_SECURE_NO_WARNINGS )
  78   add_definitions( -D_SCL_SECURE_NO_WARNINGS -DCRT_NONSTDC_NO_WARNINGS )
  79   add_definitions( -D_SCL_SECURE_NO_DEPRECATE )
  80   add_definitions( -wd4146 -wd4503 -wd4996 -wd4800 -wd4244 -wd4624 )
  81   add_definitions( -wd4355 -wd4715 )
  82 endif( MSVC )
  83
  84 include_directories( ${LLVM_BINARY_DIR}/include ${LLVM_MAIN_INCLUDE_DIR})
  85 #link_directories( d:/dev/lib )
  86
  87 #add_subdirectory(lib)
  88
  89 include(AddLLVM)
  90 include(AddPartiallyLinkedObject)
  91 include(TableGen)
  92
  93 add_subdirectory(lib/Support)
  94 add_subdirectory(lib/System)
  95
  96 # Everything else depends on Support and System:
  97 set(LLVM_COMMON_DEPENDS ${LLVM_COMMON_DEPENDS} ${LLVM_LIBS} )
  98
  99 add_subdirectory(utils/TableGen)
 100
 101 add_custom_command(OUTPUT ${llvm_builded_incs_dir}/Intrinsics.gen
 102   COMMAND tblgen -gen-intrinsic -I ${LLVM_MAIN_INCLUDE_DIR} ${LLVM_MAIN_INCLUDE_DIR}/llvm/Intrinsics.td -o ${llvm_builded_incs_dir}/Intrinsics.gen
 103   DEPENDS tblgen
 104   COMMENT "Building intrinsics.gen...")
 105
 106 add_custom_target(intrinsics_gen ALL
 107   DEPENDS ${llvm_builded_incs_dir}/Intrinsics.gen)
 108
 109 set(LLVM_COMMON_DEPENDS ${LLVM_COMMON_DEPENDS} intrinsics_gen )
 110
 111 add_subdirectory(lib/VMCore)
 112 add_subdirectory(lib/CodeGen)
 113 add_subdirectory(lib/CodeGen/SelectionDAG)
 114 add_subdirectory(lib/CodeGen/AsmPrinter)
 115 add_subdirectory(lib/Bitcode/Reader)
 116 add_subdirectory(lib/Bitcode/Writer)
 117 add_subdirectory(lib/Transforms/Utils)
 118 add_subdirectory(lib/Transforms/Instrumentation)
 119 add_subdirectory(lib/Transforms/Scalar)
 120 add_subdirectory(lib/Transforms/IPO)
 121 add_subdirectory(lib/Transforms/Hello)
 122 add_subdirectory(lib/Linker)
 123 add_subdirectory(lib/Analysis)
 124 add_subdirectory(lib/Analysis/IPA)
 125
 126 foreach(t ${LLVM_TARGETS_TO_BUILD})
 127   message(STATUS "Targeting ${t}")
 128   add_subdirectory(lib/Target/${t})
 129   if( EXISTS ${CMAKE_SOURCE_DIR}/lib/Target/${t}/AsmPrinter/CMakeLists.txt )
 130     add_subdirectory(lib/Target/${t}/AsmPrinter)
 131   endif( EXISTS ${CMAKE_SOURCE_DIR}/lib/Target/${t}/AsmPrinter/CMakeLists.txt )
 132 endforeach(t)
 133
 134 add_subdirectory(lib/ExecutionEngine)
 135 add_subdirectory(lib/ExecutionEngine/Interpreter)
 136 add_subdirectory(lib/ExecutionEngine/JIT)
 137 add_subdirectory(lib/Target)
 138 add_subdirectory(lib/AsmParser)
 139 add_subdirectory(lib/Debugger)
 140 add_subdirectory(lib/Archive)
 141
 142 add_subdirectory(tools)
 143
 144 add_subdirectory(examples)
 145
 146 install(DIRECTORY include
 147   DESTINATION .
 148   PATTERN ".svn" EXCLUDE
 149   PATTERN "*.cmake" EXCLUDE
 150   PATTERN "*.in" EXCLUDE
 151   )
 152
 153 install(DIRECTORY ${CMAKE_CURRENT_BINARY_DIR}/include
 154   DESTINATION .
 155   )
 156
 157 # TODO: make and install documentation.