CMakeLists.txt

   1 # See docs/CMake.html for instructions about how to build LLVM with CMake.
   2
   3 project(LLVM)
   4 cmake_minimum_required(VERSION 2.6.1)
   5
   6 set(PACKAGE_NAME llvm)
   7 set(PACKAGE_VERSION 2.6svn)
   8 set(PACKAGE_STRING "${PACKAGE_NAME} ${PACKAGE_VERSION}")
   9 set(PACKAGE_BUGREPORT "llvmbugs@cs.uiuc.edu")
  10
  11 if( CMAKE_SOURCE_DIR STREQUAL CMAKE_BINARY_DIR AND NOT MSVC_IDE )
  12   message(FATAL_ERROR "In-source builds are not allowed.
  13 CMake would overwrite the makefiles distributed with LLVM.
  14 Please create a directory and run cmake from there, passing the path
  15 to this source directory as the last argument.
  16 This process created the file `CMakeCache.txt' and the directory `CMakeFiles'.
  17 Please delete them.")
  18 endif()
  19
  20 string(TOUPPER "${CMAKE_BUILD_TYPE}" uppercase_CMAKE_BUILD_TYPE)
  21
  22 include(FindPerl)
  23
  24 set(LLVM_MAIN_SRC_DIR ${CMAKE_CURRENT_SOURCE_DIR})
  25 set(LLVM_MAIN_INCLUDE_DIR ${LLVM_MAIN_SRC_DIR}/include)
  26 set(LLVM_BINARY_DIR ${CMAKE_CURRENT_BINARY_DIR})
  27 set(LLVM_TOOLS_BINARY_DIR ${LLVM_BINARY_DIR}/bin)
  28 set(LLVM_EXAMPLES_BINARY_DIR ${LLVM_BINARY_DIR}/examples)
  29 set(LLVM_LIBDIR_SUFFIX "" CACHE STRING "Define suffix of library directory name (32/64)" )
  30
  31 set(LLVM_ALL_TARGETS
  32   Alpha
  33   ARM
  34   CBackend
  35   CellSPU
  36   CppBackend
  37   IA64
  38   Mips
  39   MSIL
  40   PIC16
  41   PowerPC
  42   Sparc
  43   X86
  44   XCore
  45   )
  46
  47 # List of targets whose asmprinters need to be forced to link
  48 # into executables on some platforms (i.e. Windows):
  49 set(LLVM_ASMPRINTERS_FORCE_LINK X86 PowerPC)
  50
  51 if( MSVC )
  52   set(LLVM_TARGETS_TO_BUILD X86
  53     CACHE STRING "Semicolon-separated list of targets to build, or \"all\".")
  54 else( MSVC )
  55   set(LLVM_TARGETS_TO_BUILD ${LLVM_ALL_TARGETS}
  56     CACHE STRING "Semicolon-separated list of targets to build, or \"all\".")
  57 endif( MSVC )
  58
  59 option(LLVM_ENABLE_THREADS "Use threads if available." ON)
  60
  61 if( uppercase_CMAKE_BUILD_TYPE STREQUAL "RELEASE" )
  62   option(LLVM_ENABLE_ASSERTIONS "Enable assertions" OFF)
  63 else()
  64   option(LLVM_ENABLE_ASSERTIONS "Enable assertions" ON)
  65 endif()
  66
  67 if( LLVM_ENABLE_ASSERTIONS )
  68   add_definitions( -D_DEBUG )
  69   # On Release builds cmake automatically defines NDEBUG, so we
  70   # explicitly undefine it:
  71   if( uppercase_CMAKE_BUILD_TYPE STREQUAL "RELEASE" )
  72     add_definitions( -UNDEBUG )
  73   endif()
  74 else()
  75   if( NOT uppercase_CMAKE_BUILD_TYPE STREQUAL "RELEASE" )
  76     add_definitions( -DNDEBUG )
  77   endif()
  78 endif()
  79
  80 if( LLVM_TARGETS_TO_BUILD STREQUAL "all" )
  81   set( LLVM_TARGETS_TO_BUILD ${LLVM_ALL_TARGETS} )
  82 endif()
  83
  84 set(LLVM_ENUM_TARGETS "")
  85 foreach(c ${LLVM_TARGETS_TO_BUILD})
  86   list(FIND LLVM_ALL_TARGETS ${c} idx)
  87   if( idx LESS 0 )
  88     message(FATAL_ERROR "The target `${c}' does not exists.
  89     It should be one of\n${LLVM_ALL_TARGETS}")
  90   else()
  91     set(LLVM_ENUM_TARGETS "${LLVM_ENUM_TARGETS}LLVM_TARGET(${c})\n")
  92   endif()
  93 endforeach(c)
  94
  95 # Produce llvm/Config/Targets.def
  96 configure_file(
  97   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/Targets.def.in
  98   ${LLVM_BINARY_DIR}/include/llvm/Config/Targets.def
  99   )
 100
 101 set(llvm_builded_incs_dir ${LLVM_BINARY_DIR}/include/llvm)
 102
 103 # The USE_EXPLICIT_DEPENDENCIES variable will be TRUE to indicate that
 104 # we should use the library dependencies explicitly specified in the
 105 # CMakeLists.txt files rather than those determined by
 106 # llvm-config. This value must be true for non-make and IDE
 107 # generators.
 108 if (MSVC_IDE)
 109   set(DEFAULT_USE_EXPLICIT_DEPENDENCIES ON)
 110 elseif (XCODE)
 111   set(DEFAULT_USE_EXPLICIT_DEPENDENCIES ON)
 112 else ()
 113  set(DEFAULT_USE_EXPLICIT_DEPENDENCIES OFF)
 114 endif ()
 115
 116 option(USE_EXPLICIT_DEPENDENCIES
 117   "Use explicit dependencies instead of llvm-config"
 118   ${DEFAULT_USE_EXPLICIT_DEPENDENCIES})
 119 mark_as_advanced(USE_EXPLICIT_DEPENDENCIES)
 120
 121 # Add path for custom modules
 122 set(CMAKE_MODULE_PATH
 123   ${CMAKE_MODULE_PATH}
 124   "${LLVM_MAIN_SRC_DIR}/cmake"
 125   "${LLVM_MAIN_SRC_DIR}/cmake/modules"
 126   )
 127
 128 include(AddLLVMDefinitions)
 129
 130 if(WIN32)
 131   if(CYGWIN)
 132     set(LLVM_ON_WIN32 0)
 133     set(LLVM_ON_UNIX 1)
 134   else(CYGWIN)
 135     set(LLVM_ON_WIN32 1)
 136     set(LLVM_ON_UNIX 0)
 137   endif(CYGWIN)
 138   set(LTDL_SHLIB_EXT ".dll")
 139   set(EXEEXT ".exe")
 140   # Maximum path length is 160 for non-unicode paths
 141   set(MAXPATHLEN 160)
 142 else(WIN32)
 143   if(UNIX)
 144     set(LLVM_ON_WIN32 0)
 145     set(LLVM_ON_UNIX 1)
 146     set(LTDL_SHLIB_EXT ".so")
 147     set(EXEEXT "")
 148     # FIXME: Maximum path length is currently set to 'safe' fixed value
 149     set(MAXPATHLEN 2024)
 150   else(UNIX)
 151     MESSAGE(SEND_ERROR "Unable to determine platform")
 152   endif(UNIX)
 153 endif(WIN32)
 154
 155 if( EXISTS ${LLVM_TOOLS_BINARY_DIR}/llvm-config )
 156   set(HAVE_LLVM_CONFIG 1)
 157 endif( EXISTS ${LLVM_TOOLS_BINARY_DIR}/llvm-config )
 158
 159 include(config-ix)
 160
 161 option(LLVM_ENABLE_PIC "Build Position-Independent Code" OFF)
 162
 163 set(ENABLE_PIC 0)
 164 if( LLVM_ENABLE_PIC )
 165   if( SUPPORTS_FPIC_FLAG )
 166     message(STATUS "Building with -fPIC")
 167     add_llvm_definitions(-fPIC)
 168     set(ENABLE_PIC 1)
 169  else( SUPPORTS_FPIC_FLAG )
 170     message(STATUS "Warning: -fPIC not supported.")
 171   endif()
 172 endif()
 173
 174 set( CMAKE_RUNTIME_OUTPUT_DIRECTORY ${LLVM_TOOLS_BINARY_DIR} )
 175 set( CMAKE_LIBRARY_OUTPUT_DIRECTORY ${LLVM_BINARY_DIR}/lib )
 176 set( CMAKE_ARCHIVE_OUTPUT_DIRECTORY ${LLVM_BINARY_DIR}/lib )
 177
 178 # set(CMAKE_VERBOSE_MAKEFILE true)
 179
 180 add_llvm_definitions( -D__STDC_LIMIT_MACROS )
 181 add_llvm_definitions( -D__STDC_CONSTANT_MACROS )
 182
 183 set(LLVM_PLO_FLAGS "" CACHE
 184   STRING "Flags for creating partially linked objects.")
 185
 186 if( CMAKE_SIZEOF_VOID_P EQUAL 8 AND NOT WIN32 )
 187   # TODO: support other platforms and toolchains.
 188   option(LLVM_BUILD_32_BITS "Build 32 bits executables and libraries." OFF)
 189   if( LLVM_BUILD_32_BITS )
 190     message(STATUS "Building 32 bits executables and libraries.")
 191     add_llvm_definitions( -m32 )
 192     list(APPEND CMAKE_EXE_LINKER_FLAGS -m32)
 193     list(APPEND CMAKE_SHARED_LINKER_FLAGS -m32)
 194     set( LLVM_PLO_FLAGS -melf_i386 ${LLVM_PLO_FLAGS} )
 195   endif( LLVM_BUILD_32_BITS )
 196 endif( CMAKE_SIZEOF_VOID_P EQUAL 8 AND NOT WIN32 )
 197
 198 if( MSVC )
 199   # List of valid CRTs for MSVC
 200   set(MSVC_CRT
 201     MD
 202     MDd)
 203
 204   set(LLVM_USE_CRT "" CACHE STRING "Specify VC++ CRT to use for debug/release configurations.")
 205   add_llvm_definitions( -D_CRT_SECURE_NO_DEPRECATE -D_CRT_SECURE_NO_WARNINGS )
 206   add_llvm_definitions( -D_SCL_SECURE_NO_WARNINGS -DCRT_NONSTDC_NO_WARNINGS )
 207   add_llvm_definitions( -D_SCL_SECURE_NO_DEPRECATE )
 208   add_llvm_definitions( -wd4146 -wd4503 -wd4996 -wd4800 -wd4244 -wd4624 )
 209   add_llvm_definitions( -wd4355 -wd4715 -wd4180 -wd4345 -wd4224 )
 210
 211   if (NOT ${LLVM_USE_CRT} STREQUAL "")
 212     list(FIND MSVC_CRT ${LLVM_USE_CRT} idx)
 213     if (idx LESS 0)
 214       message(FATAL_ERROR "Invalid value for LLVM_USE_CRT: ${LLVM_USE_CRT}. Valid options are one of: ${MSVC_CRT}")
 215     endif (idx LESS 0)
 216     add_llvm_definitions("/${LLVM_USE_CRT}")
 217     message(STATUS "Using VC++ CRT: ${LLVM_USE_CRT}")
 218   endif (NOT ${LLVM_USE_CRT} STREQUAL "")
 219 endif( MSVC )
 220
 221 include_directories( ${LLVM_BINARY_DIR}/include ${LLVM_MAIN_INCLUDE_DIR})
 222
 223 include(AddLLVM)
 224 include(AddPartiallyLinkedObject)
 225 include(TableGen)
 226
 227 add_subdirectory(lib/Support)
 228 add_subdirectory(lib/System)
 229
 230 # Everything else depends on Support and System:
 231 set(LLVM_COMMON_DEPENDS ${LLVM_COMMON_DEPENDS} ${LLVM_LIBS} )
 232
 233 set(LLVM_TABLEGEN "tblgen" CACHE
 234   STRING "Native TableGen executable. Saves building one when cross-compiling.")
 235 # Effective tblgen executable to be used:
 236 set(LLVM_TABLEGEN_EXE ${LLVM_TABLEGEN})
 237
 238 add_subdirectory(utils/TableGen)
 239
 240 if( CMAKE_CROSSCOMPILING )
 241   # This adds a dependency on target `tblgen', so must go after utils/TableGen
 242   include( CrossCompileLLVM )
 243 endif( CMAKE_CROSSCOMPILING )
 244
 245 add_subdirectory(include/llvm)
 246
 247 add_subdirectory(lib/VMCore)
 248 add_subdirectory(lib/CodeGen)
 249 add_subdirectory(lib/CodeGen/SelectionDAG)
 250 add_subdirectory(lib/CodeGen/AsmPrinter)
 251 add_subdirectory(lib/Bitcode/Reader)
 252 add_subdirectory(lib/Bitcode/Writer)
 253 add_subdirectory(lib/Transforms/Utils)
 254 add_subdirectory(lib/Transforms/Instrumentation)
 255 add_subdirectory(lib/Transforms/Scalar)
 256 add_subdirectory(lib/Transforms/IPO)
 257 add_subdirectory(lib/Transforms/Hello)
 258 add_subdirectory(lib/Linker)
 259 add_subdirectory(lib/Analysis)
 260 add_subdirectory(lib/Analysis/IPA)
 261
 262  set(LLVM_ENUM_ASM_PRINTERS "")
 263  foreach(t ${LLVM_TARGETS_TO_BUILD})
 264   message(STATUS "Targeting ${t}")
 265   add_subdirectory(lib/Target/${t})
 266   if( EXISTS ${LLVM_MAIN_SRC_DIR}/lib/Target/${t}/AsmPrinter/CMakeLists.txt )
 267    add_subdirectory(lib/Target/${t}/AsmPrinter)
 268     set(LLVM_ENUM_ASM_PRINTERS
 269         "${LLVM_ENUM_ASM_PRINTERS}LLVM_ASM_PRINTER(${t})\n")
 270  endif( EXISTS ${LLVM_MAIN_SRC_DIR}/lib/Target/${t}/AsmPrinter/CMakeLists.txt )
 271 endforeach(t)
 272
 273 # Produce llvm/Config/AsmPrinters.def
 274 configure_file(
 275   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/AsmPrinters.def.in
 276   ${LLVM_BINARY_DIR}/include/llvm/Config/AsmPrinters.def
 277   )
 278
 279 add_subdirectory(lib/ExecutionEngine)
 280 add_subdirectory(lib/ExecutionEngine/Interpreter)
 281 add_subdirectory(lib/ExecutionEngine/JIT)
 282 add_subdirectory(lib/Target)
 283 add_subdirectory(lib/AsmParser)
 284 add_subdirectory(lib/Debugger)
 285 add_subdirectory(lib/Archive)
 286
 287 add_subdirectory(projects)
 288 add_subdirectory(tools)
 289
 290 add_subdirectory(examples)
 291
 292 install(DIRECTORY include
 293   DESTINATION .
 294   PATTERN ".svn" EXCLUDE
 295   PATTERN "*.cmake" EXCLUDE
 296   PATTERN "*.in" EXCLUDE
 297   )
 298
 299 install(DIRECTORY ${CMAKE_CURRENT_BINARY_DIR}/include
 300   DESTINATION .
 301   )
 302
 303 # TODO: make and install documentation.