CMakeLists.txt

   1 # See docs/CMake.html for instructions about how to build LLVM with CMake.
   2
   3 project(LLVM)
   4 cmake_minimum_required(VERSION 2.8)
   5
   6 # Add path for custom modules
   7 set(CMAKE_MODULE_PATH
   8   ${CMAKE_MODULE_PATH}
   9   "${CMAKE_CURRENT_SOURCE_DIR}/cmake"
  10   "${CMAKE_CURRENT_SOURCE_DIR}/cmake/modules"
  11   )
  12
  13 set(LLVM_VERSION_MAJOR 3)
  14 set(LLVM_VERSION_MINOR 4)
  15
  16 set(PACKAGE_VERSION "${LLVM_VERSION_MAJOR}.${LLVM_VERSION_MINOR}svn")
  17
  18 option(LLVM_INSTALL_TOOLCHAIN_ONLY "Only include toolchain files in the 'install' target." OFF)
  19
  20 option(LLVM_USE_FOLDERS "Enable solution folders in Visual Studio. Disable for Express versions." ON)
  21 if ( LLVM_USE_FOLDERS )
  22   set_property(GLOBAL PROPERTY USE_FOLDERS ON)
  23 endif()
  24
  25 include(VersionFromVCS)
  26
  27 option(LLVM_APPEND_VC_REV
  28   "Append the version control system revision id to LLVM version" OFF)
  29
  30 if( LLVM_APPEND_VC_REV )
  31   add_version_info_from_vcs(PACKAGE_VERSION)
  32 endif()
  33
  34 set(PACKAGE_NAME LLVM)
  35 set(PACKAGE_STRING "${PACKAGE_NAME} ${PACKAGE_VERSION}")
  36 set(PACKAGE_BUGREPORT "http://llvm.org/bugs/")
  37
  38 # Configure CPack.
  39 set(CPACK_PACKAGE_VENDOR "LLVM")
  40 set(CPACK_PACKAGE_VERSION_MAJOR ${LLVM_VERSION_MAJOR})
  41 set(CPACK_PACKAGE_VERSION_MINOR ${LLVM_VERSION_MINOR})
  42 if( LLVM_APPEND_VC_REV )
  43   add_version_info_from_vcs(CPACK_PACKAGE_VERSION_PATCH)
  44 else()
  45   set(CPACK_PACKAGE_VERSION_PATCH "svn")
  46 endif()
  47 set(CPACK_RESOURCE_FILE_LICENSE "${CMAKE_CURRENT_SOURCE_DIR}/LICENSE.TXT")
  48 if(WIN32 AND NOT UNIX)
  49   set(CPACK_PACKAGE_ICON "${CMAKE_CURRENT_SOURCE_DIR}\\\\cmake\\\\nsis_logo.bmp")
  50   set(CPACK_NSIS_MODIFY_PATH "ON")
  51   set(CPACK_NSIS_ENABLE_UNINSTALL_BEFORE_INSTALL "ON")
  52   set(CPACK_NSIS_EXTRA_INSTALL_COMMANDS
  53     "ExecWait '$INSTDIR/tools/msbuild/install.bat'")
  54   set(CPACK_NSIS_EXTRA_UNINSTALL_COMMANDS
  55     "ExecWait '$INSTDIR/tools/msbuild/uninstall.bat'")
  56 endif()
  57 include(CPack)
  58
  59 # Sanity check our source directory to make sure that we are not trying to
  60 # generate an in-tree build (unless on MSVC_IDE, where it is ok), and to make
  61 # sure that we don't have any stray generated files lying around in the tree
  62 # (which would end up getting picked up by header search, instead of the correct
  63 # versions).
  64 if( CMAKE_SOURCE_DIR STREQUAL CMAKE_BINARY_DIR AND NOT MSVC_IDE )
  65   message(FATAL_ERROR "In-source builds are not allowed.
  66 CMake would overwrite the makefiles distributed with LLVM.
  67 Please create a directory and run cmake from there, passing the path
  68 to this source directory as the last argument.
  69 This process created the file `CMakeCache.txt' and the directory `CMakeFiles'.
  70 Please delete them.")
  71 endif()
  72 if( NOT CMAKE_SOURCE_DIR STREQUAL CMAKE_BINARY_DIR )
  73   file(GLOB_RECURSE
  74     tablegenned_files_on_include_dir
  75     "${CMAKE_CURRENT_SOURCE_DIR}/include/llvm/*.gen")
  76   file(GLOB_RECURSE
  77     tablegenned_files_on_lib_dir
  78     "${CMAKE_CURRENT_SOURCE_DIR}/lib/Target/*.inc")
  79   if( tablegenned_files_on_include_dir OR tablegenned_files_on_lib_dir)
  80     message(FATAL_ERROR "Apparently there is a previous in-source build,
  81 probably as the result of running `configure' and `make' on
  82 ${CMAKE_CURRENT_SOURCE_DIR}.
  83 This may cause problems. The suspicious files are:
  84 ${tablegenned_files_on_lib_dir}
  85 ${tablegenned_files_on_include_dir}
  86 Please clean the source directory.")
  87   endif()
  88 endif()
  89
  90 string(TOUPPER "${CMAKE_BUILD_TYPE}" uppercase_CMAKE_BUILD_TYPE)
  91
  92 set(LLVM_MAIN_SRC_DIR ${CMAKE_CURRENT_SOURCE_DIR})
  93 set(LLVM_MAIN_INCLUDE_DIR ${LLVM_MAIN_SRC_DIR}/include)
  94 set(LLVM_BINARY_DIR ${CMAKE_CURRENT_BINARY_DIR})
  95 set(LLVM_TOOLS_BINARY_DIR ${LLVM_BINARY_DIR}/bin)
  96 set(LLVM_EXAMPLES_BINARY_DIR ${LLVM_BINARY_DIR}/examples)
  97 set(LLVM_LIBDIR_SUFFIX "" CACHE STRING "Define suffix of library directory name (32/64)" )
  98
  99 set(LLVM_ALL_TARGETS
 100   AArch64
 101   ARM
 102   CppBackend
 103   Hexagon
 104   Mips
 105   MSP430
 106   NVPTX
 107   PowerPC
 108   R600
 109   Sparc
 110   SystemZ
 111   X86
 112   XCore
 113   )
 114
 115 # List of targets with JIT support:
 116 set(LLVM_TARGETS_WITH_JIT X86 PowerPC AArch64 ARM Mips SystemZ)
 117
 118 set(LLVM_TARGETS_TO_BUILD "all"
 119     CACHE STRING "Semicolon-separated list of targets to build, or \"all\".")
 120
 121 set(LLVM_EXPERIMENTAL_TARGETS_TO_BUILD ""
 122   CACHE STRING "Semicolon-separated list of experimental targets to build.")
 123
 124 option(BUILD_SHARED_LIBS
 125   "Build all libraries as shared libraries instead of static" OFF)
 126
 127 option(LLVM_ENABLE_CBE_PRINTF_A "Set to ON if CBE is enabled for printf %a output" ON)
 128 if(LLVM_ENABLE_CBE_PRINTF_A)
 129   set(ENABLE_CBE_PRINTF_A 1)
 130 endif()
 131
 132 option(LLVM_ENABLE_TIMESTAMPS "Enable embedding timestamp information in build" ON)
 133 if(LLVM_ENABLE_TIMESTAMPS)
 134   set(ENABLE_TIMESTAMPS 1)
 135 endif()
 136
 137 option(LLVM_ENABLE_BACKTRACES "Enable embedding backtraces on crash." ON)
 138 if(LLVM_ENABLE_BACKTRACES)
 139   set(ENABLE_BACKTRACES 1)
 140 endif()
 141
 142 option(LLVM_ENABLE_FFI "Use libffi to call external functions from the interpreter" OFF)
 143 set(FFI_LIBRARY_DIR "" CACHE PATH "Additional directory, where CMake should search for libffi.so")
 144 set(FFI_INCLUDE_DIR "" CACHE PATH "Additional directory, where CMake should search for ffi.h or ffi/ffi.h")
 145
 146 set(LLVM_TARGET_ARCH "host"
 147   CACHE STRING "Set target to use for LLVM JIT or use \"host\" for automatic detection.")
 148
 149 option(LLVM_ENABLE_TERMINFO "Use terminfo database if available." ON)
 150
 151 option(LLVM_ENABLE_THREADS "Use threads if available." ON)
 152
 153 option(LLVM_ENABLE_ZLIB "Use zlib for compression/decompression if available." ON)
 154
 155 if( LLVM_TARGETS_TO_BUILD STREQUAL "all" )
 156   set( LLVM_TARGETS_TO_BUILD ${LLVM_ALL_TARGETS} )
 157 endif()
 158
 159 set(LLVM_TARGETS_TO_BUILD
 160    ${LLVM_TARGETS_TO_BUILD}
 161    ${LLVM_EXPERIMENTAL_TARGETS_TO_BUILD})
 162 list(REMOVE_DUPLICATES LLVM_TARGETS_TO_BUILD)
 163
 164 set(llvm_builded_incs_dir ${LLVM_BINARY_DIR}/include/llvm)
 165
 166 include(AddLLVMDefinitions)
 167
 168 option(LLVM_ENABLE_PIC "Build Position-Independent Code" ON)
 169
 170 # MSVC has a gazillion warnings with this.
 171 if( MSVC )
 172   option(LLVM_ENABLE_WARNINGS "Enable compiler warnings." OFF)
 173 else( MSVC )
 174   option(LLVM_ENABLE_WARNINGS "Enable compiler warnings." ON)
 175 endif()
 176
 177 option(LLVM_ENABLE_PEDANTIC "Compile with pedantic enabled." ON)
 178 option(LLVM_ENABLE_WERROR "Fail and stop if a warning is triggered." OFF)
 179
 180 if( NOT uppercase_CMAKE_BUILD_TYPE STREQUAL "DEBUG" )
 181   option(LLVM_ENABLE_ASSERTIONS "Enable assertions" OFF)
 182 else()
 183   option(LLVM_ENABLE_ASSERTIONS "Enable assertions" ON)
 184 endif()
 185
 186 option(LLVM_USE_INTEL_JITEVENTS
 187   "Use Intel JIT API to inform Intel(R) VTune(TM) Amplifier XE 2011 about JIT code"
 188   OFF)
 189
 190 if( LLVM_USE_INTEL_JITEVENTS )
 191   # Verify we are on a supported platform
 192   if( NOT CMAKE_SYSTEM_NAME MATCHES "Windows" AND NOT CMAKE_SYSTEM_NAME MATCHES "Linux" )
 193     message(FATAL_ERROR
 194       "Intel JIT API support is available on Linux and Windows only.")
 195   endif()
 196 endif( LLVM_USE_INTEL_JITEVENTS )
 197
 198 option(LLVM_USE_OPROFILE
 199   "Use opagent JIT interface to inform OProfile about JIT code" OFF)
 200
 201 # If enabled, verify we are on a platform that supports oprofile.
 202 if( LLVM_USE_OPROFILE )
 203   if( NOT CMAKE_SYSTEM_NAME MATCHES "Linux" )
 204     message(FATAL_ERROR "OProfile support is available on Linux only.")
 205   endif( NOT CMAKE_SYSTEM_NAME MATCHES "Linux" )
 206 endif( LLVM_USE_OPROFILE )
 207
 208 set(LLVM_USE_SANITIZER "" CACHE STRING
 209   "Define the sanitizer used to build binaries and tests.")
 210
 211 option(LLVM_USE_SPLIT_DWARF
 212   "Use -gsplit-dwarf when compiling llvm." OFF)
 213
 214 # Define an option controlling whether we should build for 32-bit on 64-bit
 215 # platforms, where supported.
 216 if( CMAKE_SIZEOF_VOID_P EQUAL 8 AND NOT WIN32 )
 217   # TODO: support other platforms and toolchains.
 218   option(LLVM_BUILD_32_BITS "Build 32 bits executables and libraries." OFF)
 219 endif()
 220
 221 # Define the default arguments to use with 'lit', and an option for the user to
 222 # override.
 223 set(LIT_ARGS_DEFAULT "-sv")
 224 if (MSVC OR XCODE)
 225   set(LIT_ARGS_DEFAULT "${LIT_ARGS_DEFAULT} --no-progress-bar")
 226 endif()
 227 set(LLVM_LIT_ARGS "${LIT_ARGS_DEFAULT}" CACHE STRING "Default options for lit")
 228
 229 # On Win32 hosts, provide an option to specify the path to the GnuWin32 tools.
 230 if( WIN32 AND NOT CYGWIN )
 231   set(LLVM_LIT_TOOLS_DIR "" CACHE PATH "Path to GnuWin32 tools")
 232 endif()
 233
 234 # Define options to control the inclusion and default build behavior for
 235 # components which may not strictly be necessary (tools, runtime, examples, and
 236 # tests).
 237 #
 238 # This is primarily to support building smaller or faster project files.
 239 option(LLVM_INCLUDE_TOOLS "Generate build targets for the LLVM tools." ON)
 240 option(LLVM_BUILD_TOOLS
 241   "Build the LLVM tools. If OFF, just generate build targets." ON)
 242
 243 option(LLVM_INCLUDE_RUNTIME "Generate build targets for the LLVM runtimes" ON)
 244 option(LLVM_BUILD_RUNTIME
 245   "Build the LLVM runtime libraries. If OFF, just generate build targets." ON)
 246
 247 option(LLVM_BUILD_EXAMPLES
 248   "Build the LLVM example programs. If OFF, just generate build targets." OFF)
 249 option(LLVM_INCLUDE_EXAMPLES "Generate build targets for the LLVM examples" ON)
 250
 251 option(LLVM_BUILD_TESTS
 252   "Build LLVM unit tests. If OFF, just generate build targets." OFF)
 253 option(LLVM_INCLUDE_TESTS "Generate build targets for the LLVM unit tests." ON)
 254
 255 option (LLVM_BUILD_DOCS "Build the llvm documentation." OFF)
 256 option (LLVM_INCLUDE_DOCS "Generate build targets for llvm documentation." ON)
 257 option (LLVM_ENABLE_DOXYGEN "Use doxygen to generate llvm documentation." OFF)
 258
 259 # All options referred to from HandleLLVMOptions have to be specified
 260 # BEFORE this include, otherwise options will not be correctly set on
 261 # first cmake run
 262 include(config-ix)
 263
 264 # By default, we target the host, but this can be overridden at CMake
 265 # invocation time.
 266 set(LLVM_DEFAULT_TARGET_TRIPLE "${LLVM_HOST_TRIPLE}" CACHE STRING
 267   "Default target for which LLVM will generate code." )
 268 set(TARGET_TRIPLE "${LLVM_DEFAULT_TARGET_TRIPLE}")
 269
 270 include(HandleLLVMOptions)
 271
 272 # Verify that we can find a Python 2 interpreter.  Python 3 is unsupported.
 273 set(Python_ADDITIONAL_VERSIONS 2.7 2.6 2.5 2.4)
 274 include(FindPythonInterp)
 275 if( NOT PYTHONINTERP_FOUND )
 276   message(FATAL_ERROR
 277 "Unable to find Python interpreter, required for builds and testing.
 278
 279 Please install Python or specify the PYTHON_EXECUTABLE CMake variable.")
 280 endif()
 281
 282 ######
 283 # LLVMBuild Integration
 284 #
 285 # We use llvm-build to generate all the data required by the CMake based
 286 # build system in one swoop:
 287 #
 288 #  - We generate a file (a CMake fragment) in the object root which contains
 289 #    all the definitions that are required by CMake.
 290 #
 291 #  - We generate the library table used by llvm-config.
 292 #
 293 #  - We generate the dependencies for the CMake fragment, so that we will
 294 #    automatically reconfigure outselves.
 295
 296 set(LLVMBUILDTOOL "${LLVM_MAIN_SRC_DIR}/utils/llvm-build/llvm-build")
 297 set(LLVMCONFIGLIBRARYDEPENDENCIESINC
 298   "${LLVM_BINARY_DIR}/tools/llvm-config/LibraryDependencies.inc")
 299 set(LLVMBUILDCMAKEFRAG
 300   "${LLVM_BINARY_DIR}/LLVMBuild.cmake")
 301
 302 # Create the list of optional components that are enabled
 303 if (LLVM_USE_INTEL_JITEVENTS)
 304   set(LLVMOPTIONALCOMPONENTS IntelJITEvents)
 305 endif (LLVM_USE_INTEL_JITEVENTS)
 306 if (LLVM_USE_OPROFILE)
 307   set(LLVMOPTIONALCOMPONENTS ${LLVMOPTIONALCOMPONENTS} OProfileJIT)
 308 endif (LLVM_USE_OPROFILE)
 309
 310 message(STATUS "Constructing LLVMBuild project information")
 311 execute_process(
 312   COMMAND ${PYTHON_EXECUTABLE} ${LLVMBUILDTOOL}
 313             --native-target "${LLVM_NATIVE_ARCH}"
 314             --enable-targets "${LLVM_TARGETS_TO_BUILD}"
 315             --enable-optional-components "${LLVMOPTIONALCOMPONENTS}"
 316             --write-library-table ${LLVMCONFIGLIBRARYDEPENDENCIESINC}
 317             --write-cmake-fragment ${LLVMBUILDCMAKEFRAG}
 318             OUTPUT_VARIABLE LLVMBUILDOUTPUT
 319             ERROR_VARIABLE LLVMBUILDERRORS
 320             OUTPUT_STRIP_TRAILING_WHITESPACE
 321             ERROR_STRIP_TRAILING_WHITESPACE
 322   RESULT_VARIABLE LLVMBUILDRESULT)
 323
 324 # On Win32, CMake doesn't properly handle piping the default output/error
 325 # streams into the GUI console. So, we explicitly catch and report them.
 326 if( NOT "${LLVMBUILDOUTPUT}" STREQUAL "")
 327   message(STATUS "llvm-build output: ${LLVMBUILDOUTPUT}")
 328 endif()
 329 if( NOT "${LLVMBUILDRESULT}" STREQUAL "0" )
 330   message(FATAL_ERROR
 331     "Unexpected failure executing llvm-build: ${LLVMBUILDERRORS}")
 332 endif()
 333
 334 # Include the generated CMake fragment. This will define properties from the
 335 # LLVMBuild files in a format which is easy to consume from CMake, and will add
 336 # the dependencies so that CMake will reconfigure properly when the LLVMBuild
 337 # files change.
 338 include(${LLVMBUILDCMAKEFRAG})
 339
 340 ######
 341
 342 # Configure all of the various header file fragments LLVM uses which depend on
 343 # configuration variables.
 344 set(LLVM_ENUM_TARGETS "")
 345 set(LLVM_ENUM_ASM_PRINTERS "")
 346 set(LLVM_ENUM_ASM_PARSERS "")
 347 set(LLVM_ENUM_DISASSEMBLERS "")
 348 foreach(t ${LLVM_TARGETS_TO_BUILD})
 349   set( td ${LLVM_MAIN_SRC_DIR}/lib/Target/${t} )
 350
 351   list(FIND LLVM_ALL_TARGETS ${t} idx)
 352   list(FIND LLVM_EXPERIMENTAL_TARGETS_TO_BUILD ${t} idy)
 353   if( idx LESS 0 AND idy LESS 0 )
 354     message(FATAL_ERROR "The target `${t}' does not exist.
 355     It should be one of\n${LLVM_ALL_TARGETS}")
 356   else()
 357     set(LLVM_ENUM_TARGETS "${LLVM_ENUM_TARGETS}LLVM_TARGET(${t})\n")
 358   endif()
 359
 360   file(GLOB asmp_file "${td}/*AsmPrinter.cpp")
 361   if( asmp_file )
 362     set(LLVM_ENUM_ASM_PRINTERS
 363       "${LLVM_ENUM_ASM_PRINTERS}LLVM_ASM_PRINTER(${t})\n")
 364   endif()
 365   if( EXISTS ${td}/AsmParser/CMakeLists.txt )
 366     set(LLVM_ENUM_ASM_PARSERS
 367       "${LLVM_ENUM_ASM_PARSERS}LLVM_ASM_PARSER(${t})\n")
 368   endif()
 369   if( EXISTS ${td}/Disassembler/CMakeLists.txt )
 370     set(LLVM_ENUM_DISASSEMBLERS
 371       "${LLVM_ENUM_DISASSEMBLERS}LLVM_DISASSEMBLER(${t})\n")
 372   endif()
 373 endforeach(t)
 374
 375 # Produce the target definition files, which provide a way for clients to easily
 376 # include various classes of targets.
 377 configure_file(
 378   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/AsmPrinters.def.in
 379   ${LLVM_BINARY_DIR}/include/llvm/Config/AsmPrinters.def
 380   )
 381 configure_file(
 382   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/AsmParsers.def.in
 383   ${LLVM_BINARY_DIR}/include/llvm/Config/AsmParsers.def
 384   )
 385 configure_file(
 386   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/Disassemblers.def.in
 387   ${LLVM_BINARY_DIR}/include/llvm/Config/Disassemblers.def
 388   )
 389 configure_file(
 390   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/Targets.def.in
 391   ${LLVM_BINARY_DIR}/include/llvm/Config/Targets.def
 392   )
 393
 394 # Configure the three LLVM configuration header files.
 395 configure_file(
 396   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/config.h.cmake
 397   ${LLVM_BINARY_DIR}/include/llvm/Config/config.h)
 398 configure_file(
 399   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/llvm-config.h.cmake
 400   ${LLVM_BINARY_DIR}/include/llvm/Config/llvm-config.h)
 401 configure_file(
 402   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Support/DataTypes.h.cmake
 403   ${LLVM_BINARY_DIR}/include/llvm/Support/DataTypes.h)
 404
 405 set( CMAKE_RUNTIME_OUTPUT_DIRECTORY ${LLVM_TOOLS_BINARY_DIR} )
 406 set( CMAKE_LIBRARY_OUTPUT_DIRECTORY ${LLVM_BINARY_DIR}/lib )
 407 set( CMAKE_ARCHIVE_OUTPUT_DIRECTORY ${LLVM_BINARY_DIR}/lib )
 408
 409 set(CMAKE_INCLUDE_CURRENT_DIR ON)
 410
 411 include_directories( ${LLVM_BINARY_DIR}/include ${LLVM_MAIN_INCLUDE_DIR})
 412
 413 if( ${CMAKE_SYSTEM_NAME} MATCHES FreeBSD )
 414   # On FreeBSD, /usr/local/* is not used by default. In order to build LLVM
 415   # with libxml2, iconv.h, etc., we must add /usr/local paths.
 416   include_directories("/usr/local/include")
 417   link_directories("/usr/local/lib")
 418 endif( ${CMAKE_SYSTEM_NAME} MATCHES FreeBSD )
 419
 420 if( ${CMAKE_SYSTEM_NAME} MATCHES SunOS )
 421    SET(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -include llvm/Support/Solaris.h")
 422 endif( ${CMAKE_SYSTEM_NAME} MATCHES SunOS )
 423
 424 # Make sure we don't get -rdynamic in every binary. For those that need it,
 425 # use set_target_properties(target PROPERTIES ENABLE_EXPORTS 1)
 426 set(CMAKE_SHARED_LIBRARY_LINK_CXX_FLAGS "")
 427
 428 include(AddLLVM)
 429 include(TableGen)
 430
 431 if( MINGW )
 432   # People report that -O3 is unreliable on MinGW. The traditional
 433   # build also uses -O2 for that reason:
 434   llvm_replace_compiler_option(CMAKE_CXX_FLAGS_RELEASE "-O3" "-O2")
 435 endif()
 436
 437 # Put this before tblgen. Else we have a circular dependence.
 438 add_subdirectory(lib/Support)
 439 add_subdirectory(lib/TableGen)
 440
 441 add_subdirectory(utils/TableGen)
 442
 443 add_subdirectory(include/llvm)
 444
 445 add_subdirectory(lib)
 446
 447 add_subdirectory(utils/FileCheck)
 448 add_subdirectory(utils/FileUpdate)
 449 add_subdirectory(utils/count)
 450 add_subdirectory(utils/not)
 451 add_subdirectory(utils/llvm-lit)
 452 add_subdirectory(utils/yaml-bench)
 453
 454 add_subdirectory(projects)
 455
 456 if( LLVM_INCLUDE_TOOLS )
 457   add_subdirectory(tools)
 458 endif()
 459
 460 if( LLVM_INCLUDE_RUNTIME )
 461   add_subdirectory(runtime)
 462 endif()
 463
 464 if( LLVM_INCLUDE_EXAMPLES )
 465   add_subdirectory(examples)
 466 endif()
 467
 468 if( LLVM_INCLUDE_TESTS )
 469   add_subdirectory(test)
 470   add_subdirectory(utils/unittest)
 471   add_subdirectory(unittests)
 472   if (MSVC)
 473     # This utility is used to prevent crashing tests from calling Dr. Watson on
 474     # Windows.
 475     add_subdirectory(utils/KillTheDoctor)
 476   endif()
 477
 478   # Add a global check rule now that all subdirectories have been traversed
 479   # and we know the total set of lit testsuites.
 480   get_property(LLVM_LIT_TESTSUITES GLOBAL PROPERTY LLVM_LIT_TESTSUITES)
 481   get_property(LLVM_LIT_PARAMS GLOBAL PROPERTY LLVM_LIT_PARAMS)
 482   get_property(LLVM_LIT_DEPENDS GLOBAL PROPERTY LLVM_LIT_DEPENDS)
 483   get_property(LLVM_LIT_EXTRA_ARGS GLOBAL PROPERTY LLVM_LIT_EXTRA_ARGS)
 484   add_lit_target(check-all
 485     "Running all regression tests"
 486     ${LLVM_LIT_TESTSUITES}
 487     PARAMS ${LLVM_LIT_PARAMS}
 488     DEPENDS ${LLVM_LIT_DEPENDS}
 489     ARGS ${LLVM_LIT_EXTRA_ARGS}
 490     )
 491 endif()
 492
 493 if (LLVM_INCLUDE_DOCS)
 494   add_subdirectory(docs)
 495 endif()
 496
 497 add_subdirectory(cmake/modules)
 498
 499 if (NOT LLVM_INSTALL_TOOLCHAIN_ONLY)
 500   install(DIRECTORY include/
 501     DESTINATION include
 502     FILES_MATCHING
 503     PATTERN "*.def"
 504     PATTERN "*.h"
 505     PATTERN "*.td"
 506     PATTERN "*.inc"
 507     PATTERN "LICENSE.TXT"
 508     PATTERN ".svn" EXCLUDE
 509     )
 510
 511   install(DIRECTORY ${CMAKE_CURRENT_BINARY_DIR}/include/
 512     DESTINATION include
 513     FILES_MATCHING
 514     PATTERN "*.def"
 515     PATTERN "*.h"
 516     PATTERN "*.gen"
 517     PATTERN "*.inc"
 518     # Exclude include/llvm/CMakeFiles/intrinsics_gen.dir, matched by "*.def"
 519     PATTERN "CMakeFiles" EXCLUDE
 520     PATTERN ".svn" EXCLUDE
 521     )
 522 endif()
 523
 524 # Workaround for MSVS10 to avoid the Dialog Hell
 525 # FIXME: This could be removed with future version of CMake.
 526 if(MSVC_VERSION EQUAL 1600)
 527   set(LLVM_SLN_FILENAME "${CMAKE_CURRENT_BINARY_DIR}/LLVM.sln")
 528   if( EXISTS "${LLVM_SLN_FILENAME}" )
 529     file(APPEND "${LLVM_SLN_FILENAME}" "\n# This should be regenerated!\n")
 530   endif()
 531 endif()