CMakeLists.txt

   1 # See docs/CMake.html for instructions about how to build LLVM with CMake.
   2
   3 project(LLVM)
   4 cmake_minimum_required(VERSION 2.6.1)
   5
   6 set(PACKAGE_NAME llvm)
   7 set(PACKAGE_VERSION 2.6svn)
   8 set(PACKAGE_STRING "${PACKAGE_NAME} ${PACKAGE_VERSION}")
   9 set(PACKAGE_BUGREPORT "llvmbugs@cs.uiuc.edu")
  10
  11 if( CMAKE_SOURCE_DIR STREQUAL CMAKE_BINARY_DIR AND NOT MSVC_IDE )
  12   message(FATAL_ERROR "In-source builds are not allowed.
  13 CMake would overwrite the makefiles distributed with LLVM.
  14 Please create a directory and run cmake from there, passing the path
  15 to this source directory as the last argument.
  16 This process created the file `CMakeCache.txt' and the directory `CMakeFiles'.
  17 Please delete them.")
  18 endif()
  19
  20 string(TOUPPER "${CMAKE_BUILD_TYPE}" uppercase_CMAKE_BUILD_TYPE)
  21
  22 include(FindPerl)
  23
  24 set(LLVM_MAIN_SRC_DIR ${CMAKE_CURRENT_SOURCE_DIR})
  25 set(LLVM_MAIN_INCLUDE_DIR ${LLVM_MAIN_SRC_DIR}/include)
  26 set(LLVM_BINARY_DIR ${CMAKE_CURRENT_BINARY_DIR})
  27 set(LLVM_TOOLS_BINARY_DIR ${LLVM_BINARY_DIR}/bin)
  28 set(LLVM_EXAMPLES_BINARY_DIR ${LLVM_BINARY_DIR}/examples)
  29 set(LLVM_LIBDIR_SUFFIX "" CACHE STRING "Define suffix of library directory name (32/64)" )
  30
  31 set(LLVM_ALL_TARGETS
  32   Alpha
  33   ARM
  34   CBackend
  35   CellSPU
  36   CppBackend
  37   IA64
  38   Mips
  39   MSIL
  40   PIC16
  41   PowerPC
  42   Sparc
  43   X86
  44   XCore
  45   )
  46
  47 # List of targets whose asmprinters need to be forced to link
  48 # into executables on some platforms (i.e. Windows):
  49 set(LLVM_ASMPRINTERS_FORCE_LINK X86 PowerPC)
  50
  51 if( MSVC )
  52   set(LLVM_TARGETS_TO_BUILD X86
  53     CACHE STRING "Semicolon-separated list of targets to build, or \"all\".")
  54 else( MSVC )
  55   set(LLVM_TARGETS_TO_BUILD ${LLVM_ALL_TARGETS}
  56     CACHE STRING "Semicolon-separated list of targets to build, or \"all\".")
  57 endif( MSVC )
  58
  59 option(LLVM_ENABLE_THREADS "Use threads if available." ON)
  60
  61 if( uppercase_CMAKE_BUILD_TYPE STREQUAL "RELEASE" )
  62   option(LLVM_ENABLE_ASSERTIONS "Enable assertions" OFF)
  63 else()
  64   option(LLVM_ENABLE_ASSERTIONS "Enable assertions" ON)
  65 endif()
  66
  67 if( LLVM_ENABLE_ASSERTIONS )
  68   add_definitions( -D_DEBUG )
  69   # On Release builds cmake automatically defines NDEBUG, so we
  70   # explicitly undefine it:
  71   if( uppercase_CMAKE_BUILD_TYPE STREQUAL "RELEASE" )
  72     add_definitions( -UNDEBUG )
  73   endif()
  74 else()
  75   if( NOT uppercase_CMAKE_BUILD_TYPE STREQUAL "RELEASE" )
  76     add_definitions( -DNDEBUG )
  77   endif()
  78 endif()
  79
  80 if( LLVM_TARGETS_TO_BUILD STREQUAL "all" )
  81   set( LLVM_TARGETS_TO_BUILD ${LLVM_ALL_TARGETS} )
  82 endif()
  83
  84 set(LLVM_ENUM_TARGETS "")
  85 foreach(c ${LLVM_TARGETS_TO_BUILD})
  86   list(FIND LLVM_ALL_TARGETS ${c} idx)
  87   if( idx LESS 0 )
  88     message(FATAL_ERROR "The target `${c}' does not exists.
  89     It should be one of\n${LLVM_ALL_TARGETS}")
  90   else()
  91     set(LLVM_ENUM_TARGETS "${LLVM_ENUM_TARGETS}LLVM_TARGET(${c})\n")
  92   endif()
  93 endforeach(c)
  94
  95 # Produce llvm/Config/Targets.def
  96 configure_file(
  97   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/Targets.def.in
  98   ${LLVM_BINARY_DIR}/include/llvm/Config/Targets.def
  99   )
 100
 101 set(llvm_builded_incs_dir ${LLVM_BINARY_DIR}/include/llvm)
 102
 103 # Add path for custom modules
 104 set(CMAKE_MODULE_PATH
 105   ${CMAKE_MODULE_PATH}
 106   "${LLVM_MAIN_SRC_DIR}/cmake"
 107   "${LLVM_MAIN_SRC_DIR}/cmake/modules"
 108   )
 109
 110 include(AddLLVMDefinitions)
 111
 112 if(WIN32)
 113   if(CYGWIN)
 114     set(LLVM_ON_WIN32 0)
 115     set(LLVM_ON_UNIX 1)
 116   else(CYGWIN)
 117     set(LLVM_ON_WIN32 1)
 118     set(LLVM_ON_UNIX 0)
 119   endif(CYGWIN)
 120   set(LTDL_SHLIB_EXT ".dll")
 121   set(EXEEXT ".exe")
 122   # Maximum path length is 160 for non-unicode paths
 123   set(MAXPATHLEN 160)
 124 else(WIN32)
 125   if(UNIX)
 126     set(LLVM_ON_WIN32 0)
 127     set(LLVM_ON_UNIX 1)
 128     set(LTDL_SHLIB_EXT ".so")
 129     set(EXEEXT "")
 130     # FIXME: Maximum path length is currently set to 'safe' fixed value
 131     set(MAXPATHLEN 2024)
 132   else(UNIX)
 133     MESSAGE(SEND_ERROR "Unable to determine platform")
 134   endif(UNIX)
 135 endif(WIN32)
 136
 137 if( EXISTS ${LLVM_TOOLS_BINARY_DIR}/llvm-config )
 138   set(HAVE_LLVM_CONFIG 1)
 139 endif( EXISTS ${LLVM_TOOLS_BINARY_DIR}/llvm-config )
 140
 141 include(config-ix)
 142
 143 option(LLVM_ENABLE_PIC "Build Position-Independent Code" OFF)
 144
 145 set(ENABLE_PIC 0)
 146 if( LLVM_ENABLE_PIC )
 147   if( SUPPORTS_FPIC_FLAG )
 148     message(STATUS "Building with -fPIC")
 149     add_llvm_definitions(-fPIC)
 150     set(ENABLE_PIC 1)
 151  else( SUPPORTS_FPIC_FLAG )
 152     message(STATUS "Warning: -fPIC not supported.")
 153   endif()
 154 endif()
 155
 156 set( CMAKE_RUNTIME_OUTPUT_DIRECTORY ${LLVM_TOOLS_BINARY_DIR} )
 157 set( CMAKE_LIBRARY_OUTPUT_DIRECTORY ${LLVM_BINARY_DIR}/lib )
 158 set( CMAKE_ARCHIVE_OUTPUT_DIRECTORY ${LLVM_BINARY_DIR}/lib )
 159
 160 # set(CMAKE_VERBOSE_MAKEFILE true)
 161
 162 add_llvm_definitions( -D__STDC_LIMIT_MACROS )
 163 add_llvm_definitions( -D__STDC_CONSTANT_MACROS )
 164
 165 if( CMAKE_SIZEOF_VOID_P EQUAL 8 AND NOT WIN32 )
 166   # TODO: support other platforms and toolchains.
 167   option(LLVM_BUILD_32_BITS "Build 32 bits executables and libraries." OFF)
 168   if( LLVM_BUILD_32_BITS )
 169     message(STATUS "Building 32 bits executables and libraries.")
 170     add_llvm_definitions( -m32 )
 171     list(APPEND CMAKE_EXE_LINKER_FLAGS -m32)
 172     list(APPEND CMAKE_SHARED_LINKER_FLAGS -m32)
 173     set( LLVM_PLO_FLAGS -melf_i386 ${LLVM_PLO_FLAGS} )
 174   endif( LLVM_BUILD_32_BITS )
 175 endif( CMAKE_SIZEOF_VOID_P EQUAL 8 AND NOT WIN32 )
 176
 177 if( MSVC )
 178   # List of valid CRTs for MSVC
 179   set(MSVC_CRT
 180     MD
 181     MDd)
 182
 183   set(LLVM_USE_CRT "" CACHE STRING "Specify VC++ CRT to use for debug/release configurations.")
 184   add_llvm_definitions( -D_CRT_SECURE_NO_DEPRECATE -D_CRT_SECURE_NO_WARNINGS )
 185   add_llvm_definitions( -D_SCL_SECURE_NO_WARNINGS -DCRT_NONSTDC_NO_WARNINGS )
 186   add_llvm_definitions( -D_SCL_SECURE_NO_DEPRECATE )
 187   add_llvm_definitions( -wd4146 -wd4503 -wd4996 -wd4800 -wd4244 -wd4624 )
 188   add_llvm_definitions( -wd4355 -wd4715 -wd4180 -wd4345 -wd4224 )
 189
 190   if (NOT ${LLVM_USE_CRT} STREQUAL "")
 191     list(FIND MSVC_CRT ${LLVM_USE_CRT} idx)
 192     if (idx LESS 0)
 193       message(FATAL_ERROR "Invalid value for LLVM_USE_CRT: ${LLVM_USE_CRT}. Valid options are one of: ${MSVC_CRT}")
 194     endif (idx LESS 0)
 195     add_llvm_definitions("/${LLVM_USE_CRT}")
 196     message(STATUS "Using VC++ CRT: ${LLVM_USE_CRT}")
 197   endif (NOT ${LLVM_USE_CRT} STREQUAL "")
 198 endif( MSVC )
 199
 200 include_directories( ${LLVM_BINARY_DIR}/include ${LLVM_MAIN_INCLUDE_DIR})
 201
 202 include(AddLLVM)
 203 include(TableGen)
 204
 205 add_subdirectory(lib/Support)
 206 add_subdirectory(lib/System)
 207
 208 # Everything else depends on Support and System:
 209 set(LLVM_COMMON_DEPENDS ${LLVM_COMMON_DEPENDS} ${LLVM_LIBS} )
 210
 211 set(LLVM_TABLEGEN "tblgen" CACHE
 212   STRING "Native TableGen executable. Saves building one when cross-compiling.")
 213 # Effective tblgen executable to be used:
 214 set(LLVM_TABLEGEN_EXE ${LLVM_TABLEGEN})
 215
 216 add_subdirectory(utils/TableGen)
 217
 218 if( CMAKE_CROSSCOMPILING )
 219   # This adds a dependency on target `tblgen', so must go after utils/TableGen
 220   include( CrossCompileLLVM )
 221 endif( CMAKE_CROSSCOMPILING )
 222
 223 add_subdirectory(include/llvm)
 224
 225 add_subdirectory(lib/VMCore)
 226 add_subdirectory(lib/CodeGen)
 227 add_subdirectory(lib/CodeGen/SelectionDAG)
 228 add_subdirectory(lib/CodeGen/AsmPrinter)
 229 add_subdirectory(lib/Bitcode/Reader)
 230 add_subdirectory(lib/Bitcode/Writer)
 231 add_subdirectory(lib/Transforms/Utils)
 232 add_subdirectory(lib/Transforms/Instrumentation)
 233 add_subdirectory(lib/Transforms/Scalar)
 234 add_subdirectory(lib/Transforms/IPO)
 235 add_subdirectory(lib/Transforms/Hello)
 236 add_subdirectory(lib/Linker)
 237 add_subdirectory(lib/Analysis)
 238 add_subdirectory(lib/Analysis/IPA)
 239 add_subdirectory(lib/MC)
 240
 241  set(LLVM_ENUM_ASM_PRINTERS "")
 242  foreach(t ${LLVM_TARGETS_TO_BUILD})
 243   message(STATUS "Targeting ${t}")
 244   add_subdirectory(lib/Target/${t})
 245   if( EXISTS ${LLVM_MAIN_SRC_DIR}/lib/Target/${t}/AsmPrinter/CMakeLists.txt )
 246    add_subdirectory(lib/Target/${t}/AsmPrinter)
 247     set(LLVM_ENUM_ASM_PRINTERS
 248         "${LLVM_ENUM_ASM_PRINTERS}LLVM_ASM_PRINTER(${t})\n")
 249  endif( EXISTS ${LLVM_MAIN_SRC_DIR}/lib/Target/${t}/AsmPrinter/CMakeLists.txt )
 250 endforeach(t)
 251
 252 # Produce llvm/Config/AsmPrinters.def
 253 configure_file(
 254   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/AsmPrinters.def.in
 255   ${LLVM_BINARY_DIR}/include/llvm/Config/AsmPrinters.def
 256   )
 257
 258 add_subdirectory(lib/ExecutionEngine)
 259 add_subdirectory(lib/ExecutionEngine/Interpreter)
 260 add_subdirectory(lib/ExecutionEngine/JIT)
 261 add_subdirectory(lib/Target)
 262 add_subdirectory(lib/AsmParser)
 263 add_subdirectory(lib/Debugger)
 264 add_subdirectory(lib/Archive)
 265
 266 add_subdirectory(projects)
 267 add_subdirectory(tools)
 268
 269 option(LLVM_EXAMPLES "Build LLVM example programs." OFF)
 270 if (LLVM_EXAMPLES)
 271   add_subdirectory(examples)
 272 endif ()
 273
 274 install(DIRECTORY include
 275   DESTINATION .
 276   PATTERN ".svn" EXCLUDE
 277   PATTERN "*.cmake" EXCLUDE
 278   PATTERN "*.in" EXCLUDE
 279   )
 280
 281 install(DIRECTORY ${CMAKE_CURRENT_BINARY_DIR}/include
 282   DESTINATION .
 283   )
 284
 285 # TODO: make and install documentation.