CMakeLists.txt

   1 # See docs/CMake.html for instructions about how to build LLVM with CMake.
   2
   3 cmake_minimum_required(VERSION 2.8.12.2)
   4
   5 if (NOT CMAKE_BUILD_TYPE AND NOT CMAKE_CONFIGURATION_TYPES)
   6   message(STATUS "No build type selected, default to Debug")
   7   set(CMAKE_BUILD_TYPE "Debug")
   8 endif()
   9
  10 if(POLICY CMP0022)
  11   cmake_policy(SET CMP0022 NEW) # automatic when 2.8.12 is required
  12 endif()
  13
  14 if (POLICY CMP0051)
  15   # CMake 3.1 and higher include generator expressions of the form
  16   # $<TARGETLIB:obj> in the SOURCES property.  These need to be
  17   # stripped everywhere that access the SOURCES property, so we just
  18   # defer to the OLD behavior of not including generator expressions
  19   # in the output for now.
  20   cmake_policy(SET CMP0051 OLD)
  21 endif()
  22
  23 if(CMAKE_VERSION VERSION_LESS 3.1.20141117)
  24   set(cmake_3_2_USES_TERMINAL)
  25 else()
  26   set(cmake_3_2_USES_TERMINAL USES_TERMINAL)
  27 endif()
  28
  29 project(LLVM C CXX ASM)
  30
  31 # The following only works with the Ninja generator in CMake >= 3.0.
  32 set(LLVM_PARALLEL_COMPILE_JOBS "" CACHE STRING
  33   "Define the maximum number of concurrent compilation jobs.")
  34 if(LLVM_PARALLEL_COMPILE_JOBS)
  35   if(CMAKE_VERSION VERSION_LESS 3.0 OR NOT CMAKE_MAKE_PROGRAM MATCHES "ninja$")
  36     message(WARNING "Job pooling is only available with Ninja generators and CMake 3.0 and later.")
  37   else()
  38     set_property(GLOBAL APPEND PROPERTY JOB_POOLS compile_job_pool=${LLVM_PARALLEL_COMPILE_JOBS})
  39     set(CMAKE_JOB_POOL_COMPILE compile_job_pool)
  40   endif()
  41 endif()
  42
  43 set(LLVM_PARALLEL_LINK_JOBS "" CACHE STRING
  44   "Define the maximum number of concurrent link jobs.")
  45 if(LLVM_PARALLEL_LINK_JOBS)
  46   if(CMAKE_VERSION VERSION_LESS 3.0 OR NOT CMAKE_MAKE_PROGRAM MATCHES "ninja$")
  47     message(WARNING "Job pooling is only available with Ninja generators and CMake 3.0 and later.")
  48   else()
  49     set_property(GLOBAL APPEND PROPERTY JOB_POOLS link_job_pool=${LLVM_PARALLEL_LINK_JOBS})
  50     set(CMAKE_JOB_POOL_LINK link_job_pool)
  51   endif()
  52 endif()
  53
  54 # Add path for custom modules
  55 set(CMAKE_MODULE_PATH
  56   ${CMAKE_MODULE_PATH}
  57   "${CMAKE_CURRENT_SOURCE_DIR}/cmake"
  58   "${CMAKE_CURRENT_SOURCE_DIR}/cmake/modules"
  59   )
  60
  61 set(LLVM_VERSION_MAJOR 3)
  62 set(LLVM_VERSION_MINOR 8)
  63 set(LLVM_VERSION_PATCH 0)
  64 set(LLVM_VERSION_SUFFIX svn)
  65
  66 if (NOT PACKAGE_VERSION)
  67   set(PACKAGE_VERSION
  68     "${LLVM_VERSION_MAJOR}.${LLVM_VERSION_MINOR}.${LLVM_VERSION_PATCH}${LLVM_VERSION_SUFFIX}")
  69 endif()
  70
  71 option(LLVM_INSTALL_UTILS "Include utility binaries in the 'install' target." OFF)
  72
  73 option(LLVM_INSTALL_TOOLCHAIN_ONLY "Only include toolchain files in the 'install' target." OFF)
  74
  75 option(LLVM_USE_FOLDERS "Enable solution folders in Visual Studio. Disable for Express versions." ON)
  76 if ( LLVM_USE_FOLDERS )
  77   set_property(GLOBAL PROPERTY USE_FOLDERS ON)
  78 endif()
  79
  80 include(VersionFromVCS)
  81
  82 option(LLVM_APPEND_VC_REV
  83   "Append the version control system revision id to LLVM version" OFF)
  84
  85 if( LLVM_APPEND_VC_REV )
  86   add_version_info_from_vcs(PACKAGE_VERSION)
  87 endif()
  88
  89 set(PACKAGE_NAME LLVM)
  90 set(PACKAGE_STRING "${PACKAGE_NAME} ${PACKAGE_VERSION}")
  91 set(PACKAGE_BUGREPORT "http://llvm.org/bugs/")
  92
  93 set(BUG_REPORT_URL "${PACKAGE_BUGREPORT}" CACHE STRING
  94   "Default URL where bug reports are to be submitted.")
  95
  96 # Configure CPack.
  97 set(CPACK_PACKAGE_INSTALL_DIRECTORY "LLVM")
  98 set(CPACK_PACKAGE_VENDOR "LLVM")
  99 set(CPACK_PACKAGE_VERSION_MAJOR ${LLVM_VERSION_MAJOR})
 100 set(CPACK_PACKAGE_VERSION_MINOR ${LLVM_VERSION_MINOR})
 101 set(CPACK_PACKAGE_VERSION_PATCH ${LLVM_VERSION_PATCH})
 102 set(CPACK_PACKAGE_VERSION ${PACKAGE_VERSION})
 103 set(CPACK_RESOURCE_FILE_LICENSE "${CMAKE_CURRENT_SOURCE_DIR}/LICENSE.TXT")
 104 set(CPACK_NSIS_COMPRESSOR "/SOLID lzma \r\n SetCompressorDictSize 32")
 105 if(WIN32 AND NOT UNIX)
 106   set(CPACK_PACKAGE_INSTALL_REGISTRY_KEY "LLVM")
 107   set(CPACK_PACKAGE_ICON "${CMAKE_CURRENT_SOURCE_DIR}\\\\cmake\\\\nsis_logo.bmp")
 108   set(CPACK_NSIS_MUI_ICON "${CMAKE_CURRENT_SOURCE_DIR}\\\\cmake\\\\nsis_icon.ico")
 109   set(CPACK_NSIS_MUI_UNIICON "${CMAKE_CURRENT_SOURCE_DIR}\\\\cmake\\\\nsis_icon.ico")
 110   set(CPACK_NSIS_MODIFY_PATH "ON")
 111   set(CPACK_NSIS_ENABLE_UNINSTALL_BEFORE_INSTALL "ON")
 112   set(CPACK_NSIS_EXTRA_INSTALL_COMMANDS
 113     "ExecWait '$INSTDIR/tools/msbuild/install.bat'")
 114   set(CPACK_NSIS_EXTRA_UNINSTALL_COMMANDS
 115     "ExecWait '$INSTDIR/tools/msbuild/uninstall.bat'")
 116   if( CMAKE_CL_64 )
 117     set(CPACK_NSIS_INSTALL_ROOT "$PROGRAMFILES64")
 118   endif()
 119 endif()
 120 include(CPack)
 121
 122 # Sanity check our source directory to make sure that we are not trying to
 123 # generate an in-tree build (unless on MSVC_IDE, where it is ok), and to make
 124 # sure that we don't have any stray generated files lying around in the tree
 125 # (which would end up getting picked up by header search, instead of the correct
 126 # versions).
 127 if( CMAKE_SOURCE_DIR STREQUAL CMAKE_BINARY_DIR AND NOT MSVC_IDE )
 128   message(FATAL_ERROR "In-source builds are not allowed.
 129 CMake would overwrite the makefiles distributed with LLVM.
 130 Please create a directory and run cmake from there, passing the path
 131 to this source directory as the last argument.
 132 This process created the file `CMakeCache.txt' and the directory `CMakeFiles'.
 133 Please delete them.")
 134 endif()
 135 if( NOT CMAKE_SOURCE_DIR STREQUAL CMAKE_BINARY_DIR )
 136   file(GLOB_RECURSE
 137     tablegenned_files_on_include_dir
 138     "${CMAKE_CURRENT_SOURCE_DIR}/include/llvm/*.gen")
 139   file(GLOB_RECURSE
 140     tablegenned_files_on_lib_dir
 141     "${CMAKE_CURRENT_SOURCE_DIR}/lib/Target/*.inc")
 142   if( tablegenned_files_on_include_dir OR tablegenned_files_on_lib_dir)
 143     message(FATAL_ERROR "Apparently there is a previous in-source build,
 144 probably as the result of running `configure' and `make' on
 145 ${CMAKE_CURRENT_SOURCE_DIR}.
 146 This may cause problems. The suspicious files are:
 147 ${tablegenned_files_on_lib_dir}
 148 ${tablegenned_files_on_include_dir}
 149 Please clean the source directory.")
 150   endif()
 151 endif()
 152
 153 string(TOUPPER "${CMAKE_BUILD_TYPE}" uppercase_CMAKE_BUILD_TYPE)
 154
 155 if (NOT uppercase_CMAKE_BUILD_TYPE MATCHES "^(DEBUG|RELEASE|RELWITHDEBINFO|MINSIZEREL)$")
 156   message(FATAL_ERROR "Invalid value for CMAKE_BUILD_TYPE: ${CMAKE_BUILD_TYPE}")
 157 endif()
 158
 159 set(LLVM_LIBDIR_SUFFIX "" CACHE STRING "Define suffix of library directory name (32/64)" )
 160
 161 # They are used as destination of target generators.
 162 set(LLVM_RUNTIME_OUTPUT_INTDIR ${CMAKE_CURRENT_BINARY_DIR}/${CMAKE_CFG_INTDIR}/bin)
 163 set(LLVM_LIBRARY_OUTPUT_INTDIR ${CMAKE_CURRENT_BINARY_DIR}/${CMAKE_CFG_INTDIR}/lib${LLVM_LIBDIR_SUFFIX})
 164 if(WIN32 OR CYGWIN)
 165   # DLL platform -- put DLLs into bin.
 166   set(LLVM_SHLIB_OUTPUT_INTDIR ${LLVM_RUNTIME_OUTPUT_INTDIR})
 167 else()
 168   set(LLVM_SHLIB_OUTPUT_INTDIR ${LLVM_LIBRARY_OUTPUT_INTDIR})
 169 endif()
 170
 171 # Each of them corresponds to llvm-config's.
 172 set(LLVM_TOOLS_BINARY_DIR ${LLVM_RUNTIME_OUTPUT_INTDIR}) # --bindir
 173 set(LLVM_LIBRARY_DIR      ${LLVM_LIBRARY_OUTPUT_INTDIR}) # --libdir
 174 set(LLVM_MAIN_SRC_DIR     ${CMAKE_CURRENT_SOURCE_DIR}  ) # --src-root
 175 set(LLVM_MAIN_INCLUDE_DIR ${LLVM_MAIN_SRC_DIR}/include ) # --includedir
 176 set(LLVM_BINARY_DIR       ${CMAKE_CURRENT_BINARY_DIR}  ) # --prefix
 177
 178 set(LLVM_EXAMPLES_BINARY_DIR ${LLVM_BINARY_DIR}/examples)
 179 set(LLVM_INCLUDE_DIR ${CMAKE_CURRENT_BINARY_DIR}/include)
 180
 181 set(LLVM_ALL_TARGETS
 182   AArch64
 183   AMDGPU
 184   ARM
 185   BPF
 186   CppBackend
 187   Hexagon
 188   Mips
 189   MSP430
 190   NVPTX
 191   PowerPC
 192   Sparc
 193   SystemZ
 194   X86
 195   XCore
 196   )
 197
 198 # List of targets with JIT support:
 199 set(LLVM_TARGETS_WITH_JIT X86 PowerPC AArch64 ARM Mips SystemZ)
 200
 201 set(LLVM_TARGETS_TO_BUILD "all"
 202     CACHE STRING "Semicolon-separated list of targets to build, or \"all\".")
 203
 204 set(LLVM_EXPERIMENTAL_TARGETS_TO_BUILD ""
 205   CACHE STRING "Semicolon-separated list of experimental targets to build.")
 206
 207 option(BUILD_SHARED_LIBS
 208   "Build all libraries as shared libraries instead of static" OFF)
 209
 210 option(LLVM_ENABLE_TIMESTAMPS "Enable embedding timestamp information in build" ON)
 211 if(LLVM_ENABLE_TIMESTAMPS)
 212   set(ENABLE_TIMESTAMPS 1)
 213 endif()
 214
 215 option(LLVM_ENABLE_BACKTRACES "Enable embedding backtraces on crash." ON)
 216 if(LLVM_ENABLE_BACKTRACES)
 217   set(ENABLE_BACKTRACES 1)
 218 endif()
 219
 220 option(LLVM_ENABLE_CRASH_OVERRIDES "Enable crash overrides." ON)
 221 if(LLVM_ENABLE_CRASH_OVERRIDES)
 222   set(ENABLE_CRASH_OVERRIDES 1)
 223 endif()
 224
 225 option(LLVM_ENABLE_FFI "Use libffi to call external functions from the interpreter" OFF)
 226 set(FFI_LIBRARY_DIR "" CACHE PATH "Additional directory, where CMake should search for libffi.so")
 227 set(FFI_INCLUDE_DIR "" CACHE PATH "Additional directory, where CMake should search for ffi.h or ffi/ffi.h")
 228
 229 set(LLVM_TARGET_ARCH "host"
 230   CACHE STRING "Set target to use for LLVM JIT or use \"host\" for automatic detection.")
 231
 232 option(LLVM_ENABLE_TERMINFO "Use terminfo database if available." ON)
 233
 234 option(LLVM_ENABLE_THREADS "Use threads if available." ON)
 235
 236 option(LLVM_ENABLE_ZLIB "Use zlib for compression/decompression if available." ON)
 237
 238 if( LLVM_TARGETS_TO_BUILD STREQUAL "all" )
 239   set( LLVM_TARGETS_TO_BUILD ${LLVM_ALL_TARGETS} )
 240 endif()
 241
 242 set(LLVM_TARGETS_TO_BUILD
 243    ${LLVM_TARGETS_TO_BUILD}
 244    ${LLVM_EXPERIMENTAL_TARGETS_TO_BUILD})
 245 list(REMOVE_DUPLICATES LLVM_TARGETS_TO_BUILD)
 246
 247 include(AddLLVMDefinitions)
 248
 249 option(LLVM_ENABLE_PIC "Build Position-Independent Code" ON)
 250 option(LLVM_ENABLE_WARNINGS "Enable compiler warnings." ON)
 251 option(LLVM_ENABLE_MODULES "Compile with C++ modules enabled." OFF)
 252 option(LLVM_ENABLE_CXX1Y "Compile with C++1y enabled." OFF)
 253 option(LLVM_ENABLE_LIBCXX "Use libc++ if available." OFF)
 254 option(LLVM_ENABLE_LIBCXXABI "Use libc++abi when using libc++." OFF)
 255 option(LLVM_ENABLE_PEDANTIC "Compile with pedantic enabled." ON)
 256 option(LLVM_ENABLE_WERROR "Fail and stop if a warning is triggered." OFF)
 257
 258 if( NOT uppercase_CMAKE_BUILD_TYPE STREQUAL "DEBUG" )
 259   option(LLVM_ENABLE_ASSERTIONS "Enable assertions" OFF)
 260 else()
 261   option(LLVM_ENABLE_ASSERTIONS "Enable assertions" ON)
 262 endif()
 263
 264 set(LLVM_ABI_BREAKING_CHECKS "WITH_ASSERTS" CACHE STRING
 265   "Enable abi-breaking checks.  Can be WITH_ASSERTS, FORCE_ON or FORCE_OFF.")
 266
 267 option(LLVM_FORCE_USE_OLD_HOST_TOOLCHAIN
 268        "Set to ON to force using an old, unsupported host toolchain." OFF)
 269
 270 option(LLVM_USE_INTEL_JITEVENTS
 271   "Use Intel JIT API to inform Intel(R) VTune(TM) Amplifier XE 2011 about JIT code"
 272   OFF)
 273
 274 if( LLVM_USE_INTEL_JITEVENTS )
 275   # Verify we are on a supported platform
 276   if( NOT CMAKE_SYSTEM_NAME MATCHES "Windows" AND NOT CMAKE_SYSTEM_NAME MATCHES "Linux" )
 277     message(FATAL_ERROR
 278       "Intel JIT API support is available on Linux and Windows only.")
 279   endif()
 280 endif( LLVM_USE_INTEL_JITEVENTS )
 281
 282 option(LLVM_USE_OPROFILE
 283   "Use opagent JIT interface to inform OProfile about JIT code" OFF)
 284
 285 # If enabled, verify we are on a platform that supports oprofile.
 286 if( LLVM_USE_OPROFILE )
 287   if( NOT CMAKE_SYSTEM_NAME MATCHES "Linux" )
 288     message(FATAL_ERROR "OProfile support is available on Linux only.")
 289   endif( NOT CMAKE_SYSTEM_NAME MATCHES "Linux" )
 290 endif( LLVM_USE_OPROFILE )
 291
 292 set(LLVM_USE_SANITIZER "" CACHE STRING
 293   "Define the sanitizer used to build binaries and tests.")
 294
 295 option(LLVM_USE_SPLIT_DWARF
 296   "Use -gsplit-dwarf when compiling llvm." OFF)
 297
 298 option(WITH_POLLY "Build LLVM with Polly" ON)
 299 option(LINK_POLLY_INTO_TOOLS "Static link Polly into tools" OFF)
 300
 301 # Define an option controlling whether we should build for 32-bit on 64-bit
 302 # platforms, where supported.
 303 if( CMAKE_SIZEOF_VOID_P EQUAL 8 AND NOT WIN32 )
 304   # TODO: support other platforms and toolchains.
 305   option(LLVM_BUILD_32_BITS "Build 32 bits executables and libraries." OFF)
 306 endif()
 307
 308 # Define the default arguments to use with 'lit', and an option for the user to
 309 # override.
 310 set(LIT_ARGS_DEFAULT "-sv")
 311 if (MSVC OR XCODE)
 312   set(LIT_ARGS_DEFAULT "${LIT_ARGS_DEFAULT} --no-progress-bar")
 313 endif()
 314 set(LLVM_LIT_ARGS "${LIT_ARGS_DEFAULT}" CACHE STRING "Default options for lit")
 315
 316 # On Win32 hosts, provide an option to specify the path to the GnuWin32 tools.
 317 if( WIN32 AND NOT CYGWIN )
 318   set(LLVM_LIT_TOOLS_DIR "" CACHE PATH "Path to GnuWin32 tools")
 319 endif()
 320
 321 # Define options to control the inclusion and default build behavior for
 322 # components which may not strictly be necessary (tools, examples, and tests).
 323 #
 324 # This is primarily to support building smaller or faster project files.
 325 option(LLVM_INCLUDE_TOOLS "Generate build targets for the LLVM tools." ON)
 326 option(LLVM_BUILD_TOOLS
 327   "Build the LLVM tools. If OFF, just generate build targets." ON)
 328
 329 option(LLVM_INCLUDE_UTILS "Generate build targets for the LLVM utils." ON)
 330
 331 option(LLVM_BUILD_RUNTIME
 332   "Build the LLVM runtime libraries." ON)
 333 option(LLVM_BUILD_EXAMPLES
 334   "Build the LLVM example programs. If OFF, just generate build targets." OFF)
 335 option(LLVM_INCLUDE_EXAMPLES "Generate build targets for the LLVM examples" ON)
 336
 337 option(LLVM_BUILD_TESTS
 338   "Build LLVM unit tests. If OFF, just generate build targets." OFF)
 339 option(LLVM_INCLUDE_TESTS "Generate build targets for the LLVM unit tests." ON)
 340
 341 option (LLVM_BUILD_DOCS "Build the llvm documentation." OFF)
 342 option (LLVM_INCLUDE_DOCS "Generate build targets for llvm documentation." ON)
 343 option (LLVM_ENABLE_DOXYGEN "Use doxygen to generate llvm API documentation." OFF)
 344 option (LLVM_ENABLE_SPHINX "Use Sphinx to generate llvm documentation." OFF)
 345
 346 option (LLVM_BUILD_EXTERNAL_COMPILER_RT
 347   "Build compiler-rt as an external project." OFF)
 348
 349 option(LLVM_BUILD_LLVM_DYLIB "Build libllvm dynamic library" OFF)
 350 option(LLVM_DYLIB_EXPORT_ALL "Export all symbols from libLLVM.dylib (default is C API only" OFF)
 351 option(LLVM_DISABLE_LLVM_DYLIB_ATEXIT "Disable llvm-shlib's atexit destructors." ON)
 352 if(LLVM_DISABLE_LLVM_DYLIB_ATEXIT)
 353   set(DISABLE_LLVM_DYLIB_ATEXIT 1)
 354 endif()
 355
 356 option(LLVM_OPTIMIZED_TABLEGEN "Force TableGen to be built with optimization" OFF)
 357 if(CMAKE_CROSSCOMPILING OR (LLVM_OPTIMIZED_TABLEGEN AND LLVM_ENABLE_ASSERTIONS))
 358   set(LLVM_USE_HOST_TOOLS ON)
 359 endif()
 360
 361 # All options referred to from HandleLLVMOptions have to be specified
 362 # BEFORE this include, otherwise options will not be correctly set on
 363 # first cmake run
 364 include(config-ix)
 365
 366 # By default, we target the host, but this can be overridden at CMake
 367 # invocation time.
 368 set(LLVM_DEFAULT_TARGET_TRIPLE "${LLVM_HOST_TRIPLE}" CACHE STRING
 369   "Default target for which LLVM will generate code." )
 370 set(TARGET_TRIPLE "${LLVM_DEFAULT_TARGET_TRIPLE}")
 371
 372 include(HandleLLVMOptions)
 373
 374 # Verify that we can find a Python 2 interpreter.  Python 3 is unsupported.
 375 # FIXME: We should support systems with only Python 3, but that requires work
 376 # on LLDB.
 377 set(Python_ADDITIONAL_VERSIONS 2.7)
 378 include(FindPythonInterp)
 379 if( NOT PYTHONINTERP_FOUND )
 380   message(FATAL_ERROR
 381 "Unable to find Python interpreter, required for builds and testing.
 382
 383 Please install Python or specify the PYTHON_EXECUTABLE CMake variable.")
 384 endif()
 385
 386 if( ${PYTHON_VERSION_STRING} VERSION_LESS 2.7 )
 387   message(FATAL_ERROR "Python 2.7 or newer is required")
 388 endif()
 389
 390 ######
 391 # LLVMBuild Integration
 392 #
 393 # We use llvm-build to generate all the data required by the CMake based
 394 # build system in one swoop:
 395 #
 396 #  - We generate a file (a CMake fragment) in the object root which contains
 397 #    all the definitions that are required by CMake.
 398 #
 399 #  - We generate the library table used by llvm-config.
 400 #
 401 #  - We generate the dependencies for the CMake fragment, so that we will
 402 #    automatically reconfigure outselves.
 403
 404 set(LLVMBUILDTOOL "${LLVM_MAIN_SRC_DIR}/utils/llvm-build/llvm-build")
 405 set(LLVMCONFIGLIBRARYDEPENDENCIESINC
 406   "${LLVM_BINARY_DIR}/tools/llvm-config/LibraryDependencies.inc")
 407 set(LLVMBUILDCMAKEFRAG
 408   "${LLVM_BINARY_DIR}/LLVMBuild.cmake")
 409
 410 # Create the list of optional components that are enabled
 411 if (LLVM_USE_INTEL_JITEVENTS)
 412   set(LLVMOPTIONALCOMPONENTS IntelJITEvents)
 413 endif (LLVM_USE_INTEL_JITEVENTS)
 414 if (LLVM_USE_OPROFILE)
 415   set(LLVMOPTIONALCOMPONENTS ${LLVMOPTIONALCOMPONENTS} OProfileJIT)
 416 endif (LLVM_USE_OPROFILE)
 417
 418 message(STATUS "Constructing LLVMBuild project information")
 419 execute_process(
 420   COMMAND ${PYTHON_EXECUTABLE} ${LLVMBUILDTOOL}
 421             --native-target "${LLVM_NATIVE_ARCH}"
 422             --enable-targets "${LLVM_TARGETS_TO_BUILD}"
 423             --enable-optional-components "${LLVMOPTIONALCOMPONENTS}"
 424             --write-library-table ${LLVMCONFIGLIBRARYDEPENDENCIESINC}
 425             --write-cmake-fragment ${LLVMBUILDCMAKEFRAG}
 426             OUTPUT_VARIABLE LLVMBUILDOUTPUT
 427             ERROR_VARIABLE LLVMBUILDERRORS
 428             OUTPUT_STRIP_TRAILING_WHITESPACE
 429             ERROR_STRIP_TRAILING_WHITESPACE
 430   RESULT_VARIABLE LLVMBUILDRESULT)
 431
 432 # On Win32, CMake doesn't properly handle piping the default output/error
 433 # streams into the GUI console. So, we explicitly catch and report them.
 434 if( NOT "${LLVMBUILDOUTPUT}" STREQUAL "")
 435   message(STATUS "llvm-build output: ${LLVMBUILDOUTPUT}")
 436 endif()
 437 if( NOT "${LLVMBUILDRESULT}" STREQUAL "0" )
 438   message(FATAL_ERROR
 439     "Unexpected failure executing llvm-build: ${LLVMBUILDERRORS}")
 440 endif()
 441
 442 # Include the generated CMake fragment. This will define properties from the
 443 # LLVMBuild files in a format which is easy to consume from CMake, and will add
 444 # the dependencies so that CMake will reconfigure properly when the LLVMBuild
 445 # files change.
 446 include(${LLVMBUILDCMAKEFRAG})
 447
 448 ######
 449
 450 # Configure all of the various header file fragments LLVM uses which depend on
 451 # configuration variables.
 452 set(LLVM_ENUM_TARGETS "")
 453 set(LLVM_ENUM_ASM_PRINTERS "")
 454 set(LLVM_ENUM_ASM_PARSERS "")
 455 set(LLVM_ENUM_DISASSEMBLERS "")
 456 foreach(t ${LLVM_TARGETS_TO_BUILD})
 457   set( td ${LLVM_MAIN_SRC_DIR}/lib/Target/${t} )
 458
 459   list(FIND LLVM_ALL_TARGETS ${t} idx)
 460   list(FIND LLVM_EXPERIMENTAL_TARGETS_TO_BUILD ${t} idy)
 461   if( idx LESS 0 AND idy LESS 0 )
 462     message(FATAL_ERROR "The target `${t}' does not exist.
 463     It should be one of\n${LLVM_ALL_TARGETS}")
 464   else()
 465     set(LLVM_ENUM_TARGETS "${LLVM_ENUM_TARGETS}LLVM_TARGET(${t})\n")
 466   endif()
 467
 468   file(GLOB asmp_file "${td}/*AsmPrinter.cpp")
 469   if( asmp_file )
 470     set(LLVM_ENUM_ASM_PRINTERS
 471       "${LLVM_ENUM_ASM_PRINTERS}LLVM_ASM_PRINTER(${t})\n")
 472   endif()
 473   if( EXISTS ${td}/AsmParser/CMakeLists.txt )
 474     set(LLVM_ENUM_ASM_PARSERS
 475       "${LLVM_ENUM_ASM_PARSERS}LLVM_ASM_PARSER(${t})\n")
 476   endif()
 477   if( EXISTS ${td}/Disassembler/CMakeLists.txt )
 478     set(LLVM_ENUM_DISASSEMBLERS
 479       "${LLVM_ENUM_DISASSEMBLERS}LLVM_DISASSEMBLER(${t})\n")
 480   endif()
 481 endforeach(t)
 482
 483 # Produce the target definition files, which provide a way for clients to easily
 484 # include various classes of targets.
 485 configure_file(
 486   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/AsmPrinters.def.in
 487   ${LLVM_INCLUDE_DIR}/llvm/Config/AsmPrinters.def
 488   )
 489 configure_file(
 490   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/AsmParsers.def.in
 491   ${LLVM_INCLUDE_DIR}/llvm/Config/AsmParsers.def
 492   )
 493 configure_file(
 494   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/Disassemblers.def.in
 495   ${LLVM_INCLUDE_DIR}/llvm/Config/Disassemblers.def
 496   )
 497 configure_file(
 498   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/Targets.def.in
 499   ${LLVM_INCLUDE_DIR}/llvm/Config/Targets.def
 500   )
 501
 502 # Configure the three LLVM configuration header files.
 503 configure_file(
 504   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/config.h.cmake
 505   ${LLVM_INCLUDE_DIR}/llvm/Config/config.h)
 506 configure_file(
 507   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/llvm-config.h.cmake
 508   ${LLVM_INCLUDE_DIR}/llvm/Config/llvm-config.h)
 509 configure_file(
 510   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Support/DataTypes.h.cmake
 511   ${LLVM_INCLUDE_DIR}/llvm/Support/DataTypes.h)
 512
 513 # They are not referenced. See set_output_directory().
 514 set( CMAKE_RUNTIME_OUTPUT_DIRECTORY ${LLVM_BINARY_DIR}/bin )
 515 set( CMAKE_LIBRARY_OUTPUT_DIRECTORY ${LLVM_BINARY_DIR}/lib${LLVM_LIBDIR_SUFFIX} )
 516 set( CMAKE_ARCHIVE_OUTPUT_DIRECTORY ${LLVM_BINARY_DIR}/lib${LLVM_LIBDIR_SUFFIX} )
 517
 518 set(CMAKE_BUILD_WITH_INSTALL_RPATH ON)
 519 if (APPLE)
 520   set(CMAKE_INSTALL_NAME_DIR "@rpath")
 521   set(CMAKE_INSTALL_RPATH "@executable_path/../lib")
 522 else(UNIX)
 523   if(NOT DEFINED CMAKE_INSTALL_RPATH)
 524     set(CMAKE_INSTALL_RPATH "\$ORIGIN/../lib${LLVM_LIBDIR_SUFFIX}")
 525     if (${CMAKE_SYSTEM_NAME} MATCHES FreeBSD OR ${CMAKE_SYSTEM_NAME} MATCHES DragonFly)
 526       set(CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} -Wl,-z,origin")
 527       set(CMAKE_SHARED_LINKER_FLAGS "${CMAKE_SHARED_LINKER_FLAGS} -Wl,-z,origin")
 528     endif()
 529   endif(NOT DEFINED CMAKE_INSTALL_RPATH)
 530 endif()
 531
 532 # Work around a broken bfd ld behavior. When linking a binary with a
 533 # foo.so library, it will try to find any library that foo.so uses and
 534 # check its symbols. This is wasteful (the check was done when foo.so
 535 # was created) and can fail since it is not the dynamic linker and
 536 # doesn't know how to handle search paths correctly.
 537 if (UNIX AND NOT APPLE AND NOT ${CMAKE_SYSTEM_NAME} MATCHES "SunOS")
 538   set(CMAKE_EXE_LINKER_FLAGS
 539       "${CMAKE_EXE_LINKER_FLAGS} -Wl,-allow-shlib-undefined")
 540 endif()
 541
 542 set(CMAKE_INCLUDE_CURRENT_DIR ON)
 543
 544 include_directories( ${LLVM_INCLUDE_DIR} ${LLVM_MAIN_INCLUDE_DIR})
 545
 546 # when crosscompiling import the executable targets from a file
 547 if(LLVM_USE_HOST_TOOLS)
 548   include(CrossCompile)
 549 endif(LLVM_USE_HOST_TOOLS)
 550
 551 if( ${CMAKE_SYSTEM_NAME} MATCHES FreeBSD OR ${CMAKE_SYSTEM_NAME} MATCHES DragonFly )
 552   # On FreeBSD, /usr/local/* is not used by default. In order to build LLVM
 553   # with libxml2, iconv.h, etc., we must add /usr/local paths.
 554   include_directories("/usr/local/include")
 555   link_directories("/usr/local/lib")
 556 endif( ${CMAKE_SYSTEM_NAME} MATCHES FreeBSD OR ${CMAKE_SYSTEM_NAME} MATCHES DragonFly )
 557
 558 if( ${CMAKE_SYSTEM_NAME} MATCHES SunOS )
 559    SET(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -include llvm/Support/Solaris.h")
 560 endif( ${CMAKE_SYSTEM_NAME} MATCHES SunOS )
 561
 562 # Make sure we don't get -rdynamic in every binary. For those that need it,
 563 # use export_executable_symbols(target).
 564 set(CMAKE_SHARED_LIBRARY_LINK_CXX_FLAGS "")
 565
 566 include(AddLLVM)
 567 include(TableGen)
 568
 569 if( MINGW )
 570   # People report that -O3 is unreliable on MinGW. The traditional
 571   # build also uses -O2 for that reason:
 572   llvm_replace_compiler_option(CMAKE_CXX_FLAGS_RELEASE "-O3" "-O2")
 573 endif()
 574
 575 # Put this before tblgen. Else we have a circular dependence.
 576 add_subdirectory(lib/Support)
 577 add_subdirectory(lib/TableGen)
 578
 579 add_subdirectory(utils/TableGen)
 580
 581 add_subdirectory(include/llvm)
 582
 583 add_subdirectory(lib)
 584
 585 if( LLVM_INCLUDE_UTILS )
 586   add_subdirectory(utils/FileCheck)
 587   add_subdirectory(utils/PerfectShuffle)
 588   add_subdirectory(utils/count)
 589   add_subdirectory(utils/not)
 590   add_subdirectory(utils/llvm-lit)
 591   add_subdirectory(utils/yaml-bench)
 592 else()
 593   if ( LLVM_INCLUDE_TESTS )
 594     message(FATAL_ERROR "Including tests when not building utils will not work.
 595     Either set LLVM_INCLUDE_UTILS to On, or set LLVM_INCLDE_TESTS to Off.")
 596   endif()
 597 endif()
 598
 599 if(LLVM_INCLUDE_TESTS)
 600   add_subdirectory(utils/unittest)
 601 endif()
 602
 603 foreach( binding ${LLVM_BINDINGS_LIST} )
 604   if( EXISTS "${LLVM_MAIN_SRC_DIR}/bindings/${binding}/CMakeLists.txt" )
 605     add_subdirectory(bindings/${binding})
 606   endif()
 607 endforeach()
 608
 609 add_subdirectory(projects)
 610
 611 if(WITH_POLLY)
 612   if(NOT EXISTS ${LLVM_MAIN_SRC_DIR}/tools/polly/CMakeLists.txt)
 613     set(WITH_POLLY OFF)
 614   endif()
 615 endif(WITH_POLLY)
 616
 617 if( LLVM_INCLUDE_TOOLS )
 618   add_subdirectory(tools)
 619 endif()
 620
 621 if( LLVM_INCLUDE_EXAMPLES )
 622   add_subdirectory(examples)
 623 endif()
 624
 625 if( LLVM_INCLUDE_TESTS )
 626   add_subdirectory(test)
 627   add_subdirectory(unittests)
 628   if (MSVC)
 629     # This utility is used to prevent crashing tests from calling Dr. Watson on
 630     # Windows.
 631     add_subdirectory(utils/KillTheDoctor)
 632   endif()
 633
 634   # Add a global check rule now that all subdirectories have been traversed
 635   # and we know the total set of lit testsuites.
 636   get_property(LLVM_LIT_TESTSUITES GLOBAL PROPERTY LLVM_LIT_TESTSUITES)
 637   get_property(LLVM_LIT_PARAMS GLOBAL PROPERTY LLVM_LIT_PARAMS)
 638   get_property(LLVM_LIT_DEPENDS GLOBAL PROPERTY LLVM_LIT_DEPENDS)
 639   get_property(LLVM_LIT_EXTRA_ARGS GLOBAL PROPERTY LLVM_LIT_EXTRA_ARGS)
 640   add_lit_target(check-all
 641     "Running all regression tests"
 642     ${LLVM_LIT_TESTSUITES}
 643     PARAMS ${LLVM_LIT_PARAMS}
 644     DEPENDS ${LLVM_LIT_DEPENDS}
 645     ARGS ${LLVM_LIT_EXTRA_ARGS}
 646     )
 647 endif()
 648
 649 if (LLVM_INCLUDE_DOCS)
 650   add_subdirectory(docs)
 651 endif()
 652
 653 add_subdirectory(cmake/modules)
 654
 655 if (NOT LLVM_INSTALL_TOOLCHAIN_ONLY)
 656   install(DIRECTORY include/llvm include/llvm-c
 657     DESTINATION include
 658     COMPONENT llvm-headers
 659     FILES_MATCHING
 660     PATTERN "*.def"
 661     PATTERN "*.h"
 662     PATTERN "*.td"
 663     PATTERN "*.inc"
 664     PATTERN "LICENSE.TXT"
 665     PATTERN ".svn" EXCLUDE
 666     )
 667
 668   install(DIRECTORY ${LLVM_INCLUDE_DIR}/llvm
 669     DESTINATION include
 670     COMPONENT llvm-headers
 671     FILES_MATCHING
 672     PATTERN "*.def"
 673     PATTERN "*.h"
 674     PATTERN "*.gen"
 675     PATTERN "*.inc"
 676     # Exclude include/llvm/CMakeFiles/intrinsics_gen.dir, matched by "*.def"
 677     PATTERN "CMakeFiles" EXCLUDE
 678     PATTERN "config.h" EXCLUDE
 679     PATTERN ".svn" EXCLUDE
 680     )
 681
 682   if (NOT CMAKE_CONFIGURATION_TYPES)
 683     add_custom_target(installhdrs
 684                       DEPENDS ${name}
 685                       COMMAND "${CMAKE_COMMAND}"
 686                               -DCMAKE_INSTALL_COMPONENT=llvm-headers
 687                               -P "${CMAKE_BINARY_DIR}/cmake_install.cmake")
 688   endif()
 689 endif()