test/CodeGen/WinEH/cppeh-frame-vars.ll

   1 ; RUN: opt -mtriple=x86_64-pc-windows-msvc -winehprepare -S -o - < %s | FileCheck %s
   2
   3 ; This test is based on the following code:
   4 ;
   5 ; struct SomeData {
   6 ;   int a;
   7 ;   int b;
   8 ; };
   9 ;
  10 ; void may_throw();
  11 ; void does_not_throw(int i);
  12 ; void dump(int *, int, SomeData&);
  13 ;
  14 ; void test() {
  15 ;   int NumExceptions = 0;
  16 ;   int ExceptionVal[10];
  17 ;   SomeData Data = { 0, 0 };
  18 ;
  19 ;   for (int i = 0; i < 10; ++i) {
  20 ;     try {
  21 ;       may_throw();
  22 ;       Data.a += i;
  23 ;     }
  24 ;     catch (int e) {
  25 ;       ExceptionVal[NumExceptions] = e;
  26 ;       ++NumExceptions;
  27 ;       if (e == i)
  28 ;         Data.b += e;
  29 ;       else
  30 ;         Data.a += e;
  31 ;     }
  32 ;     does_not_throw(NumExceptions);
  33 ;   }
  34 ;   dump(ExceptionVal, NumExceptions, Data);
  35 ; }
  36
  37 ; ModuleID = 'cppeh-frame-vars.cpp'
  38 target datalayout = "e-m:e-i64:64-f80:128-n8:16:32:64-S128"
  39 target triple = "x86_64-pc-windows-msvc"
  40
  41 %rtti.TypeDescriptor2 = type { i8**, i8*, [3 x i8] }
  42 %struct.SomeData = type { i32, i32 }
  43
  44 ; This structure should be declared for the frame allocation block.
  45 ; CHECK: %"struct.\01?test@@YAXXZ.ehdata" = type { i32, i8*, i32, i32, [10 x i32], i32, %struct.SomeData }
  46
  47 $"\01??_R0H@8" = comdat any
  48
  49 @"\01??_7type_info@@6B@" = external constant i8*
  50 @"\01??_R0H@8" = linkonce_odr global %rtti.TypeDescriptor2 { i8** @"\01??_7type_info@@6B@", i8* null, [3 x i8] c".H\00" }, comdat
  51
  52 ; The function entry should be rewritten like this.
  53 ; CHECK: define void @"\01?test@@YAXXZ"() #0 {
  54 ; CHECK: entry:
  55 ; CHECK:   %frame.alloc = call i8* @llvm.frameallocate(i32 80)
  56 ; CHECK:   %eh.data = bitcast i8* %frame.alloc to %"struct.\01?test@@YAXXZ.ehdata"*
  57 ; CHECK-NOT:  %NumExceptions = alloca i32, align 4
  58 ; CHECK:   %NumExceptions = getelementptr inbounds %"struct.\01?test@@YAXXZ.ehdata", %"struct.\01?test@@YAXXZ.ehdata"* %eh.data, i32 0, i32 3
  59 ; CHECK-NOT:  %ExceptionVal = alloca [10 x i32], align 16
  60 ; CHECK:   %ExceptionVal = getelementptr inbounds %"struct.\01?test@@YAXXZ.ehdata", %"struct.\01?test@@YAXXZ.ehdata"* %eh.data, i32 0, i32 4
  61 ; CHECK-NOT:  %Data = alloca %struct.SomeData, align 4
  62 ; CHECK:   %Data = getelementptr inbounds %"struct.\01?test@@YAXXZ.ehdata", %"struct.\01?test@@YAXXZ.ehdata"* %eh.data, i32 0, i32 6
  63 ; CHECK:   %i = getelementptr inbounds %"struct.\01?test@@YAXXZ.ehdata", %"struct.\01?test@@YAXXZ.ehdata"* %eh.data, i32 0, i32 5
  64 ; CHECK:   %exn.slot = alloca i8*
  65 ; CHECK:   %ehselector.slot = alloca i32
  66 ; CHECK-NOT:  %e = alloca i32, align 4
  67 ; CHECK:   %e = getelementptr inbounds %"struct.\01?test@@YAXXZ.ehdata", %"struct.\01?test@@YAXXZ.ehdata"* %eh.data, i32 0, i32 2
  68
  69 ; Function Attrs: uwtable
  70 define void @"\01?test@@YAXXZ"() #0 {
  71 entry:
  72   %NumExceptions = alloca i32, align 4
  73   %ExceptionVal = alloca [10 x i32], align 16
  74   %Data = alloca %struct.SomeData, align 4
  75   %i = alloca i32, align 4
  76   %exn.slot = alloca i8*
  77   %ehselector.slot = alloca i32
  78   %e = alloca i32, align 4
  79   store i32 0, i32* %NumExceptions, align 4
  80   %tmp = bitcast %struct.SomeData* %Data to i8*
  81   call void @llvm.memset(i8* %tmp, i8 0, i64 8, i32 4, i1 false)
  82   store i32 0, i32* %i, align 4
  83   br label %for.cond
  84
  85 for.cond:                                         ; preds = %for.inc, %entry
  86   %tmp1 = load i32, i32* %i, align 4
  87   %cmp = icmp slt i32 %tmp1, 10
  88   br i1 %cmp, label %for.body, label %for.end
  89
  90 for.body:                                         ; preds = %for.cond
  91   invoke void @"\01?may_throw@@YAXXZ"()
  92           to label %invoke.cont unwind label %lpad
  93
  94 invoke.cont:                                      ; preds = %for.body
  95   %tmp2 = load i32, i32* %i, align 4
  96   %a = getelementptr inbounds %struct.SomeData, %struct.SomeData* %Data, i32 0, i32 0
  97   %tmp3 = load i32, i32* %a, align 4
  98   %add = add nsw i32 %tmp3, %tmp2
  99   store i32 %add, i32* %a, align 4
 100   br label %try.cont
 101
 102 lpad:                                             ; preds = %for.body
 103   %tmp4 = landingpad { i8*, i32 } personality i8* bitcast (i32 (...)* @__CxxFrameHandler3 to i8*)
 104           catch i8* bitcast (%rtti.TypeDescriptor2* @"\01??_R0H@8" to i8*)
 105   %tmp5 = extractvalue { i8*, i32 } %tmp4, 0
 106   store i8* %tmp5, i8** %exn.slot
 107   %tmp6 = extractvalue { i8*, i32 } %tmp4, 1
 108   store i32 %tmp6, i32* %ehselector.slot
 109   br label %catch.dispatch
 110
 111 catch.dispatch:                                   ; preds = %lpad
 112   %sel = load i32, i32* %ehselector.slot
 113   %tmp7 = call i32 @llvm.eh.typeid.for(i8* bitcast (%rtti.TypeDescriptor2* @"\01??_R0H@8" to i8*)) #1
 114   %matches = icmp eq i32 %sel, %tmp7
 115   br i1 %matches, label %catch, label %eh.resume
 116
 117 catch:                                            ; preds = %catch.dispatch
 118   %exn = load i8*, i8** %exn.slot
 119   %e.i8 = bitcast i32* %e to i8*
 120   call void @llvm.eh.begincatch(i8* %exn, i8* %e.i8) #1
 121   %tmp11 = load i32, i32* %e, align 4
 122   %tmp12 = load i32, i32* %NumExceptions, align 4
 123   %idxprom = sext i32 %tmp12 to i64
 124   %arrayidx = getelementptr inbounds [10 x i32], [10 x i32]* %ExceptionVal, i32 0, i64 %idxprom
 125   store i32 %tmp11, i32* %arrayidx, align 4
 126   %tmp13 = load i32, i32* %NumExceptions, align 4
 127   %inc = add nsw i32 %tmp13, 1
 128   store i32 %inc, i32* %NumExceptions, align 4
 129   %tmp14 = load i32, i32* %e, align 4
 130   %tmp15 = load i32, i32* %i, align 4
 131   %cmp1 = icmp eq i32 %tmp14, %tmp15
 132   br i1 %cmp1, label %if.then, label %if.else
 133
 134 if.then:                                          ; preds = %catch
 135   %tmp16 = load i32, i32* %e, align 4
 136   %b = getelementptr inbounds %struct.SomeData, %struct.SomeData* %Data, i32 0, i32 1
 137   %tmp17 = load i32, i32* %b, align 4
 138   %add2 = add nsw i32 %tmp17, %tmp16
 139   store i32 %add2, i32* %b, align 4
 140   br label %if.end
 141
 142 if.else:                                          ; preds = %catch
 143   %tmp18 = load i32, i32* %e, align 4
 144   %a3 = getelementptr inbounds %struct.SomeData, %struct.SomeData* %Data, i32 0, i32 0
 145   %tmp19 = load i32, i32* %a3, align 4
 146   %add4 = add nsw i32 %tmp19, %tmp18
 147   store i32 %add4, i32* %a3, align 4
 148   br label %if.end
 149
 150 if.end:                                           ; preds = %if.else, %if.then
 151   call void @llvm.eh.endcatch() #1
 152   br label %try.cont
 153
 154 try.cont:                                         ; preds = %if.end, %invoke.cont
 155   %tmp20 = load i32, i32* %NumExceptions, align 4
 156   call void @"\01?does_not_throw@@YAXH@Z"(i32 %tmp20)
 157   br label %for.inc
 158
 159 for.inc:                                          ; preds = %try.cont
 160   %tmp21 = load i32, i32* %i, align 4
 161   %inc5 = add nsw i32 %tmp21, 1
 162   store i32 %inc5, i32* %i, align 4
 163   br label %for.cond
 164
 165 for.end:                                          ; preds = %for.cond
 166   %tmp22 = load i32, i32* %NumExceptions, align 4
 167   %arraydecay = getelementptr inbounds [10 x i32], [10 x i32]* %ExceptionVal, i32 0, i32 0
 168   call void @"\01?dump@@YAXPEAHHAEAUSomeData@@@Z"(i32* %arraydecay, i32 %tmp22, %struct.SomeData* dereferenceable(8) %Data)
 169   ret void
 170
 171 eh.resume:                                        ; preds = %catch.dispatch
 172   %exn6 = load i8*, i8** %exn.slot
 173   %sel7 = load i32, i32* %ehselector.slot
 174   %lpad.val = insertvalue { i8*, i32 } undef, i8* %exn6, 0
 175   %lpad.val8 = insertvalue { i8*, i32 } %lpad.val, i32 %sel7, 1
 176   resume { i8*, i32 } %lpad.val8
 177 }
 178
 179 ; The following catch handler should be outlined.
 180 ; CHECK-LABEL: define internal i8* @"\01?test@@YAXXZ.catch"(i8*, i8*) {
 181 ; CHECK: entry:
 182 ; CHECK:   %eh.alloc = call i8* @llvm.framerecover(i8* bitcast (void ()* @"\01?test@@YAXXZ" to i8*), i8* %1)
 183 ; CHECK:   %eh.data = bitcast i8* %eh.alloc to %"struct.\01?test@@YAXXZ.ehdata"*
 184 ; CHECK:   %e = getelementptr inbounds %"struct.\01?test@@YAXXZ.ehdata", %"struct.\01?test@@YAXXZ.ehdata"* %eh.data, i32 0, i32 2
 185 ; CHECK:   %NumExceptions = getelementptr inbounds %"struct.\01?test@@YAXXZ.ehdata", %"struct.\01?test@@YAXXZ.ehdata"* %eh.data, i32 0, i32 3
 186 ; CHECK:   %ExceptionVal = getelementptr inbounds %"struct.\01?test@@YAXXZ.ehdata", %"struct.\01?test@@YAXXZ.ehdata"* %eh.data, i32 0, i32 4
 187 ; CHECK:   %i = getelementptr inbounds %"struct.\01?test@@YAXXZ.ehdata", %"struct.\01?test@@YAXXZ.ehdata"* %eh.data, i32 0, i32 5
 188 ; CHECK:   %Data = getelementptr inbounds %"struct.\01?test@@YAXXZ.ehdata", %"struct.\01?test@@YAXXZ.ehdata"* %eh.data, i32 0, i32 6
 189 ; CHECK:   %tmp11 = load i32, i32* %e, align 4
 190 ; CHECK:   %tmp12 = load i32, i32* %NumExceptions, align 4
 191 ; CHECK:   %idxprom = sext i32 %tmp12 to i64
 192 ; CHECK:   %arrayidx = getelementptr inbounds [10 x i32], [10 x i32]* %ExceptionVal, i32 0, i64 %idxprom
 193 ; CHECK:   store i32 %tmp11, i32* %arrayidx, align 4
 194 ; CHECK:   %tmp13 = load i32, i32* %NumExceptions, align 4
 195 ; CHECK:   %inc = add nsw i32 %tmp13, 1
 196 ; CHECK:   store i32 %inc, i32* %NumExceptions, align 4
 197 ; CHECK:   %tmp14 = load i32, i32* %e, align 4
 198 ; CHECK:   %tmp15 = load i32, i32* %i, align 4
 199 ; CHECK:   %cmp1 = icmp eq i32 %tmp14, %tmp15
 200 ; CHECK:   br i1 %cmp1, label %if.then, label %if.else
 201 ;
 202 ; CHECK: if.then:                                          ; preds = %entry
 203 ; CHECK:   %tmp16 = load i32, i32* %e, align 4
 204 ; CHECK:   %b = getelementptr inbounds %struct.SomeData, %struct.SomeData* %Data, i32 0, i32 1
 205 ; CHECK:   %tmp17 = load i32, i32* %b, align 4
 206 ; CHECK:   %add2 = add nsw i32 %tmp17, %tmp16
 207 ; CHECK:   store i32 %add2, i32* %b, align 4
 208 ; CHECK:   br label %if.end
 209 ;
 210 ; CHECK: if.else:                                          ; preds = %entry
 211 ; CHECK:   %tmp18 = load i32, i32* %e, align 4
 212 ; CHECK:   %a3 = getelementptr inbounds %struct.SomeData, %struct.SomeData* %Data, i32 0, i32 0
 213 ; CHECK:   %tmp19 = load i32, i32* %a3, align 4
 214 ; CHECK:   %add4 = add nsw i32 %tmp19, %tmp18
 215 ; CHECK:   store i32 %add4, i32* %a3, align 4
 216 ; CHECK:   br label %if.end
 217 ;
 218 ; CHECK: if.end:                                           ; preds = %if.else, %if.then
 219 ; CHECK:   ret i8* blockaddress(@"\01?test@@YAXXZ", %try.cont)
 220 ; CHECK: }
 221
 222
 223
 224
 225
 226
 227 ; Function Attrs: nounwind
 228 declare void @llvm.memset(i8* nocapture, i8, i64, i32, i1) #1
 229
 230 declare void @"\01?may_throw@@YAXXZ"() #2
 231
 232 declare i32 @__CxxFrameHandler3(...)
 233
 234 ; Function Attrs: nounwind readnone
 235 declare i32 @llvm.eh.typeid.for(i8*) #3
 236
 237 declare void @llvm.eh.begincatch(i8*, i8*)
 238
 239 declare void @llvm.eh.endcatch()
 240
 241 declare void @"\01?does_not_throw@@YAXH@Z"(i32) #2
 242
 243 declare void @"\01?dump@@YAXPEAHHAEAUSomeData@@@Z"(i32*, i32, %struct.SomeData* dereferenceable(8)) #2
 244
 245 attributes #0 = { uwtable "less-precise-fpmad"="false" "no-frame-pointer-elim"="false" "no-infs-fp-math"="false" "no-nans-fp-math"="false" "stack-protector-buffer-size"="8" "unsafe-fp-math"="false" "use-soft-float"="false" }
 246 attributes #1 = { nounwind }
 247 attributes #2 = { "less-precise-fpmad"="false" "no-frame-pointer-elim"="false" "no-infs-fp-math"="false" "no-nans-fp-math"="false" "stack-protector-buffer-size"="8" "unsafe-fp-math"="false" "use-soft-float"="false" }
 248 attributes #3 = { nounwind readnone }
 249
 250 !llvm.module.flags = !{!0}
 251 !llvm.ident = !{!1}
 252
 253 !0 = !{i32 1, !"PIC Level", i32 2}
 254 !1 = !{!"clang version 3.7.0 (trunk 228868)"}