tools/llvm-config/llvm-config.in.in

   1 #!@PERL@
   2 ##===- tools/llvm-config ---------------------------------------*- perl -*-===##
   3 #
   4 #                     The LLVM Compiler Infrastructure
   5 #
   6 # This file was developed by Eric Kidd and is distributed under
   7 # the University of Illinois Open Source License. See LICENSE.TXT for details.
   8 #
   9 ##===----------------------------------------------------------------------===##
  10 #
  11 # Synopsis: Prints out compiler options needed to build against an installed
  12 #           copy of LLVM.
  13 #
  14 # Syntax:   llvm-config OPTIONS... [COMPONENTS...]
  15 #
  16 ##===----------------------------------------------------------------------===##
  17
  18 use 5.006;
  19 use strict;
  20 use warnings;
  21
  22 #---- begin autoconf values ----
  23 my $PACKAGE_NAME        = q{@PACKAGE_NAME@};
  24 my $VERSION             = q{@PACKAGE_VERSION@};
  25 my $PREFIX              = q{@LLVM_PREFIX@};
  26 my $LLVM_CONFIGTIME     = q{@LLVM_CONFIGTIME@};
  27 my $LLVM_SRC_ROOT       = q{@abs_top_srcdir@};
  28 my $LLVM_OBJ_ROOT       = q{@abs_top_builddir@};
  29 my $LLVM_ON_WIN32       = q{@LLVM_ON_WIN32@};
  30 my $LLVM_ON_UNIX        = q{@LLVM_ON_UNIX@};
  31 my $LLVMGCCDIR          = q{@LLVMGCCDIR@};
  32 my $LLVMGCC             = q{@LLVMGCC@};
  33 my $LLVMGXX             = q{@LLVMGXX@};
  34 my $LLVMGCC_VERSION     = q{@LLVMGCC_VERSION@};
  35 my $LLVMGCC_MAJVERS     = q{@LLVMGCC_MAJVERS@};
  36 my $ENDIAN              = q{@ENDIAN@};
  37 my $SHLIBEXT            = q{@SHLIBEXT@};
  38 my $EXEEXT              = q{@EXEEXT@};
  39 my $OS                  = q{@OS@};
  40 my $ARCH                = lc(q{@ARCH@});
  41 my $TARGET_TRIPLE       = q{@target@};
  42 my $TARGETS_TO_BUILD    = q{@TARGETS_TO_BUILD@};
  43 my $TARGET_HAS_JIT      = q{@TARGET_HAS_JIT@};
  44 my @TARGETS_BUILT       = map { lc($_) } qw{@TARGETS_TO_BUILD@};
  45 #---- end autoconf values ----
  46
  47 # Must pretend x86_64 architecture is really x86, otherwise the native backend
  48 # won't get linked in.
  49 $ARCH = "x86" if $ARCH eq "x86_64";
  50
  51 #---- begin Makefile values ----
  52 my $CPPFLAGS            = q{@LLVM_CPPFLAGS@};
  53 my $CFLAGS              = q{@LLVM_CFLAGS@};
  54 my $CXXFLAGS            = q{@LLVM_CXXFLAGS@};
  55 my $LDFLAGS             = q{@LLVM_LDFLAGS@};
  56 my $SYSTEM_LIBS         = q{@LIBS@};
  57 my $LLVM_BUILDMODE      = q{@LLVM_BUILDMODE@};
  58 #---- end Makefile values ----
  59
  60 # Figure out where llvm-config is being run from.  Primarily, we care if it has
  61 # been installed, or is running from the build directory, which changes the
  62 # locations of some files.
  63
  64 # Convert the current executable name into its directory (e.g. ".").
  65 my ($RUN_DIR) = ($0 =~ /^(.*)\/.*$/);
  66
  67 # Turn the directory into an absolute directory on the file system, also pop up
  68 # from "bin" into the build or prefix dir.
  69 my $ABS_RUN_DIR = `cd $RUN_DIR/..; pwd`;
  70 chomp($ABS_RUN_DIR);
  71
  72 # Compute the absolute object directory build, e.g. "foo/llvm/Debug".
  73 my $ABS_OBJ_ROOT = "$LLVM_OBJ_ROOT/$LLVM_BUILDMODE";
  74 $ABS_OBJ_ROOT = `cd $ABS_OBJ_ROOT; pwd` if (-d $ABS_OBJ_ROOT);
  75 chomp($ABS_OBJ_ROOT);
  76
  77 my $INCLUDEDIR = "$ABS_RUN_DIR/include";
  78 my $LIBDIR     = "$ABS_RUN_DIR/lib";
  79 my $BINDIR     = "$ABS_RUN_DIR/bin";
  80 if ($ABS_RUN_DIR eq $ABS_OBJ_ROOT) {
  81   # If we are running out of the build directory, the include dir is in the
  82   # srcdir.
  83   $INCLUDEDIR = "$LLVM_SRC_ROOT/include";
  84 } else {
  85   # If installed, ignore the prefix the tree was configured with, use the
  86   # current prefix.
  87   $PREFIX = $ABS_RUN_DIR;
  88 }
  89
  90 sub usage;
  91 sub fix_library_names (@);
  92 sub fix_library_files (@);
  93 sub expand_dependencies (@);
  94 sub name_map_entries;
  95
  96 # Parse our command-line arguments.
  97 usage if @ARGV == 0;
  98 my @components;
  99 my $has_opt = 0;
 100 my $want_libs = 0;
 101 my $want_libnames = 0;
 102 my $want_libfiles = 0;
 103 my $want_components = 0;
 104 foreach my $arg (@ARGV) {
 105     if ($arg =~ /^-/) {
 106         if ($arg eq "--version") {
 107             $has_opt = 1; print "$VERSION\n";
 108         } elsif ($arg eq "--prefix") {
 109             $has_opt = 1; print "$PREFIX\n";
 110         } elsif ($arg eq "--bindir") {
 111             $has_opt = 1; print "$BINDIR\n";
 112         } elsif ($arg eq "--includedir") {
 113             $has_opt = 1; print "$INCLUDEDIR\n";
 114         } elsif ($arg eq "--libdir") {
 115             $has_opt = 1; print "$LIBDIR\n";
 116         } elsif ($arg eq "--cppflags") {
 117             $has_opt = 1; print "-I$INCLUDEDIR $CPPFLAGS\n";
 118         } elsif ($arg eq "--cflags") {
 119             $has_opt = 1; print "-I$INCLUDEDIR $CFLAGS\n";
 120         } elsif ($arg eq "--cxxflags") {
 121             $has_opt = 1; print "-I$INCLUDEDIR $CXXFLAGS\n";
 122         } elsif ($arg eq "--ldflags") {
 123             $has_opt = 1; print "-L$LIBDIR $LDFLAGS $SYSTEM_LIBS\n";
 124         } elsif ($arg eq "--libs") {
 125             $has_opt = 1; $want_libs = 1;
 126         } elsif ($arg eq "--libnames") {
 127             $has_opt = 1; $want_libnames = 1;
 128         } elsif ($arg eq "--libfiles") {
 129             $has_opt = 1; $want_libfiles = 1;
 130         } elsif ($arg eq "--components") {
 131             $has_opt = 1; print join(' ', name_map_entries), "\n";
 132         } elsif ($arg eq "--targets-built") {
 133             $has_opt = 1; print join(' ', @TARGETS_BUILT), "\n";
 134         } elsif ($arg eq "--host-target") {
 135             $has_opt = 1; print "$TARGET_TRIPLE\n";
 136         } elsif ($arg eq "--build-mode") {
 137             $has_opt = 1; print "$LLVM_BUILDMODE\n";
 138         } elsif ($arg eq "--obj-root") {
 139             $has_opt = 1; print `cd $LLVM_OBJ_ROOT/; pwd`;
 140         } elsif ($arg eq "--src-root") {
 141             $has_opt = 1; print `cd $LLVM_SRC_ROOT/; pwd`;
 142         } else {
 143             usage();
 144         }
 145     } else {
 146         push @components, $arg;
 147     }
 148 }
 149
 150 # If no options were specified, fail.
 151 usage unless $has_opt;
 152
 153 # If no components were specified, default to 'all'.
 154 if (@components == 0) {
 155     push @components, 'all';
 156 }
 157
 158 # Force component names to lower case.
 159 @components = map lc, @components;
 160
 161 # Handle any arguments which require building our dependency graph.
 162 if ($want_libs || $want_libnames || $want_libfiles) {
 163     my @libs = expand_dependencies(@components);
 164     print join(' ', fix_library_names(@libs)), "\n" if ($want_libs);
 165     print join(' ',  @libs), "\n" if ($want_libnames);
 166     print join(' ', fix_library_files(@libs)), "\n" if ($want_libfiles);
 167 }
 168
 169 exit 0;
 170
 171 #==========================================================================
 172 #  Support Routines
 173 #==========================================================================
 174
 175 sub usage {
 176     print STDERR <<__EOD__;
 177 Usage: llvm-config <OPTION>... [<COMPONENT>...]
 178
 179 Get various configuration information needed to compile programs which use
 180 LLVM.  Typically called from 'configure' scripts.  Examples:
 181   llvm-config --cxxflags
 182   llvm-config --ldflags
 183   llvm-config --libs engine bcreader scalaropts
 184
 185 Options:
 186   --version          Print LLVM version.
 187   --prefix           Print the installation prefix.
 188   --src-root         Print the source root LLVM was built from.
 189   --obj-root         Print the object root used to build LLVM.
 190   --bindir           Directory containing LLVM executables.
 191   --includedir       Directory containing LLVM headers.
 192   --libdir           Directory containing LLVM libraries.
 193   --cppflags         C preprocessor flags for files that include LLVM headers.
 194   --cflags           C compiler flags for files that include LLVM headers.
 195   --cxxflags         C++ compiler flags for files that include LLVM headers.
 196   --ldflags          Print Linker flags.
 197   --libs             Libraries needed to link against LLVM components.
 198   --libnames         Bare library names for in-tree builds.
 199   --libfiles         Fully qualified library filenames for makefile depends.
 200   --components       List of all possible components.
 201   --targets-built    List of all targets currently built.
 202   --host-target      Target triple used to configure LLVM.
 203   --build-mode       Print build mode of LLVM tree (e.g. Debug or Release).
 204 Typical components:
 205   all                All LLVM libraries (default).
 206   backend            Either a native backend or the C backend.
 207   engine             Either a native JIT or a bytecode interpreter.
 208 __EOD__
 209     exit(1);
 210 }
 211
 212 # Use -lfoo instead of libfoo.a whenever possible, and add directories to
 213 # files which can't be found using -L.
 214 sub fix_library_names (@) {
 215     my @libs = @_;
 216     my @result;
 217     foreach my $lib (@libs) {
 218         # Transform the bare library name appropriately.
 219         my ($basename) = ($lib =~ /^lib([^.]*)\.a/);
 220         if (defined $basename) {
 221             push @result, "-l$basename";
 222         } else {
 223             push @result, "$LIBDIR/$lib";
 224         }
 225     }
 226     return @result;
 227 }
 228
 229 # Turn the list of libraries into a list of files.
 230 sub fix_library_files(@) {
 231     my @libs = @_;
 232     my @result;
 233     foreach my $lib (@libs) {
 234         # Transform the bare library name into a filename.
 235         push @result, "$LIBDIR/$lib";
 236     }
 237     return @result;
 238 }
 239
 240 #==========================================================================
 241 #  Library Dependency Analysis
 242 #==========================================================================
 243 #  Given a few human-readable library names, find all their dependencies
 244 #  and sort them into an order which the linker will like.  If we packed
 245 #  our libraries into fewer archives, we could make the linker do much
 246 #  of this work for us.
 247 #
 248 #  Libraries have two different types of names in this code: Human-friendly
 249 #  "component" names entered on the command-line, and the raw file names
 250 #  we use internally (and ultimately pass to the linker).
 251 #
 252 #  To understand this code, you'll need a working knowledge of Perl 5,
 253 #  and possibly some quality time with 'man perlref'.
 254
 255 sub load_dependencies;
 256 sub build_name_map;
 257 sub have_native_backend;
 258 sub find_best_engine;
 259 sub expand_names (@);
 260 sub find_all_required_sets (@);
 261 sub find_all_required_sets_helper ($$@);
 262
 263 # Each "set" contains one or more libraries which must be included as a
 264 # group (due to cyclic dependencies).  Sets are represented as a Perl array
 265 # reference pointing to a list of internal library names.
 266 my @SETS;
 267
 268 # Various mapping tables.
 269 my %LIB_TO_SET_MAP; # Maps internal library names to their sets.
 270 my %SET_DEPS;       # Maps sets to a list of libraries they depend on.
 271 my %NAME_MAP;       # Maps human-entered names to internal names.
 272
 273 # Have our dependencies been loaded yet?
 274 my $DEPENDENCIES_LOADED = 0;
 275
 276 # Given a list of human-friendly component names, translate them into a
 277 # complete set of linker arguments.
 278 sub expand_dependencies (@) {
 279     my @libs = @_;
 280     load_dependencies;
 281     my @required_sets = find_all_required_sets(expand_names(@libs));
 282     my @sorted_sets = topologically_sort_sets(@required_sets);
 283
 284     # Expand the library sets into libraries.
 285     my @result;
 286     foreach my $set (@sorted_sets) { push @result, @{$set}; }
 287     return @result;
 288 }
 289
 290 # Load in the raw dependency data stored at the end of this file.
 291 sub load_dependencies {
 292     return if $DEPENDENCIES_LOADED;
 293     $DEPENDENCIES_LOADED = 1;
 294     while (<DATA>) {
 295         # Parse our line.
 296         my ($libs, $deps) = /^\s*([^:]+):\s*(.*)\s*$/;
 297         die "Malformed dependency data" unless defined $deps;
 298         my @libs = split(' ', $libs);
 299         my @deps = split(' ', $deps);
 300
 301         # Record our dependency data.
 302         my $set = \@libs;
 303         push @SETS, $set;
 304         foreach my $lib (@libs) { $LIB_TO_SET_MAP{$lib} = $set; }
 305         $SET_DEPS{$set} = \@deps;
 306     }
 307     build_name_map;
 308 }
 309
 310 # Build a map converting human-friendly component names into internal
 311 # library names.
 312 sub build_name_map {
 313     # Add entries for all the actual libraries.
 314     foreach my $set (@SETS) {
 315         foreach my $lib (sort @$set) {
 316             my $short_name = $lib;
 317             $short_name =~ s/^(lib)?LLVM([^.]*)\..*$/$2/;
 318             $short_name =~ tr/A-Z/a-z/;
 319             $NAME_MAP{$short_name} = [$lib];
 320         }
 321     }
 322
 323     # Add virtual entries.
 324     $NAME_MAP{'native'}  = have_native_backend() ? [$ARCH] : [];
 325     $NAME_MAP{'backend'} = have_native_backend() ? ['native'] : ['cbackend'];
 326     $NAME_MAP{'engine'}  = find_best_engine;
 327     $NAME_MAP{'all'}     = [name_map_entries];   # Must be last.
 328 }
 329
 330 # Return true if we have a native backend to use.
 331 sub have_native_backend {
 332     my %BUILT;
 333     foreach my $target (@TARGETS_BUILT) { $BUILT{$target} = 1; }
 334     return defined $NAME_MAP{$ARCH} && defined $BUILT{$ARCH};
 335 }
 336
 337 # Find a working subclass of ExecutionEngine for this platform.
 338 sub find_best_engine {
 339     if (have_native_backend && $TARGET_HAS_JIT) {
 340         return ['jit', 'native'];
 341     } else {
 342         return ['interpreter'];
 343     }
 344 }
 345
 346 # Get all the human-friendly component names.
 347 sub name_map_entries {
 348     load_dependencies;
 349     return sort keys %NAME_MAP;
 350 }
 351
 352 # Map human-readable names to internal library names.
 353 sub expand_names (@) {
 354     my @names = @_;
 355     my @result;
 356     foreach my $name (@names) {
 357         if (defined $LIB_TO_SET_MAP{$name}) {
 358             # We've hit bottom: An actual library name.
 359             push @result, $name;
 360         } elsif (defined $NAME_MAP{$name}) {
 361             # We've found a short name to expand.
 362             push @result, expand_names(@{$NAME_MAP{$name}});
 363         } else {
 364             print STDERR "llvm-config: unknown component name: $name\n";
 365             exit(1);
 366         }
 367     }
 368     return @result;
 369 }
 370
 371 # Given a list of internal library names, return all sets of libraries which
 372 # will need to be included by the linker (in no particular order).
 373 sub find_all_required_sets (@) {
 374     my @libs = @_;
 375     my %sets_added;
 376     my @result;
 377     find_all_required_sets_helper(\%sets_added, \@result, @libs);
 378     return @result;
 379 }
 380
 381 # Recursive closures are pretty broken in Perl, so we're going to separate
 382 # this function from find_all_required_sets and pass in the state we need
 383 # manually, as references.  Yes, this is fairly unpleasant.
 384 sub find_all_required_sets_helper ($$@) {
 385     my ($sets_added, $result, @libs) = @_;
 386     foreach my $lib (@libs) {
 387         my $set = $LIB_TO_SET_MAP{$lib};
 388         next if defined $$sets_added{$set};
 389         $$sets_added{$set} = 1;
 390         push @$result, $set;
 391         find_all_required_sets_helper($sets_added, $result, @{$SET_DEPS{$set}});
 392     }
 393 }
 394
 395 # Print a list of sets, with a label.  Used for debugging.
 396 sub print_sets ($@) {
 397     my ($label, @sets) = @_;
 398     my @output;
 399     foreach my $set (@sets) { push @output, join(',', @$set); }
 400     print "$label: ", join(';', @output), "\n";
 401 }
 402
 403 # Returns true if $lib is a key in $added.
 404 sub has_lib_been_added ($$) {
 405     my ($added, $lib) = @_;
 406     return defined $$added{$LIB_TO_SET_MAP{$lib}};
 407 }
 408
 409 # Returns true if all the dependencies of $set appear in $added.
 410 sub have_all_deps_been_added ($$) {
 411     my ($added, $set) = @_;
 412     #print_sets("  Checking", $set);
 413     #print_sets("     Wants", $SET_DEPS{$set});
 414     foreach my $lib (@{$SET_DEPS{$set}}) {
 415         return 0 unless has_lib_been_added($added, $lib);
 416     }
 417     return 1;
 418 }
 419
 420 # Given a list of sets, topologically sort them using dependencies.
 421 sub topologically_sort_sets (@) {
 422     my @sets = @_;
 423     my %added;
 424     my @result;
 425     SCAN: while (@sets) { # We'll delete items from @sets as we go.
 426         #print_sets("So far", reverse(@result));
 427         #print_sets("Remaining", @sets);
 428         for (my $i = 0; $i < @sets; ++$i) {
 429             my $set = $sets[$i];
 430             if (have_all_deps_been_added(\%added, $set)) {
 431                 push @result, $set;
 432                 $added{$set} = 1;
 433                 #print "Removing $i.\n";
 434                 splice(@sets, $i, 1);
 435                 next SCAN; # Restart our scan.
 436             }
 437         }
 438         die "Can't find a library with no dependencies";
 439     }
 440     return reverse(@result);
 441 }
 442
 443 # Our library dependency data will be added after the '__END__' token, and will
 444 # be read through the magic <DATA> filehandle.
 445 __END__