test/Transforms/StraightLineStrengthReduce/slsr-mul.ll

   1 ; RUN: opt < %s -slsr -gvn -dce -S | FileCheck %s
   2
   3 target datalayout = "e-i64:64-v16:16-v32:32-n16:32:64"
   4
   5 declare i32 @foo(i32 %a)
   6
   7 define i32 @slsr1(i32 %b, i32 %s) {
   8 ; CHECK-LABEL: @slsr1(
   9   ; v0 = foo(b * s);
  10   %mul0 = mul i32 %b, %s
  11 ; CHECK: mul i32
  12 ; CHECK-NOT: mul i32
  13   %v0 = call i32 @foo(i32 %mul0)
  14
  15   ; v1 = foo((b + 1) * s);
  16   %b1 = add i32 %b, 1
  17   %mul1 = mul i32 %b1, %s
  18   %v1 = call i32 @foo(i32 %mul1)
  19
  20   ; v2 = foo((b + 2) * s);
  21   %b2 = add i32 %b, 2
  22   %mul2 = mul i32 %b2, %s
  23   %v2 = call i32 @foo(i32 %mul2)
  24
  25   ; return v0 + v1 + v2;
  26   %1 = add i32 %v0, %v1
  27   %2 = add i32 %1, %v2
  28   ret i32 %2
  29 }
  30
  31 ; v0 = foo(a * b)
  32 ; v1 = foo((a + 1) * b)
  33 ; v2 = foo(a * (b + 1))
  34 ; v3 = foo((a + 1) * (b + 1))
  35 define i32 @slsr2(i32 %a, i32 %b) {
  36 ; CHECK-LABEL: @slsr2(
  37   %a1 = add i32 %a, 1
  38   %b1 = add i32 %b, 1
  39   %mul0 = mul i32 %a, %b
  40 ; CHECK: mul i32
  41 ; CHECK-NOT: mul i32
  42   %mul1 = mul i32 %a1, %b
  43   %mul2 = mul i32 %a, %b1
  44   %mul3 = mul i32 %a1, %b1
  45
  46   %v0 = call i32 @foo(i32 %mul0)
  47   %v1 = call i32 @foo(i32 %mul1)
  48   %v2 = call i32 @foo(i32 %mul2)
  49   %v3 = call i32 @foo(i32 %mul3)
  50
  51   %1 = add i32 %v0, %v1
  52   %2 = add i32 %1, %v2
  53   %3 = add i32 %2, %v3
  54   ret i32 %3
  55 }
  56
  57 ; The bump is a multiple of the stride.
  58 ;
  59 ; v0 = foo(b * s);
  60 ; v1 = foo((b + 2) * s);
  61 ; v2 = foo((b + 4) * s);
  62 ; return v0 + v1 + v2;
  63 ;
  64 ; ==>
  65 ;
  66 ; mul0 = b * s;
  67 ; v0 = foo(mul0);
  68 ; bump = s * 2;
  69 ; mul1 = mul0 + bump; // GVN ensures mul1 and mul2 use the same bump.
  70 ; v1 = foo(mul1);
  71 ; mul2 = mul1 + bump;
  72 ; v2 = foo(mul2);
  73 ; return v0 + v1 + v2;
  74 define i32 @slsr3(i32 %b, i32 %s) {
  75 ; CHECK-LABEL: @slsr3(
  76   %mul0 = mul i32 %b, %s
  77 ; CHECK: mul i32
  78   %v0 = call i32 @foo(i32 %mul0)
  79
  80   %b1 = add i32 %b, 2
  81   %mul1 = mul i32 %b1, %s
  82 ; CHECK: [[BUMP:%[a-zA-Z0-9]+]] = shl i32 %s, 1
  83 ; CHECK: %mul1 = add i32 %mul0, [[BUMP]]
  84   %v1 = call i32 @foo(i32 %mul1)
  85
  86   %b2 = add i32 %b, 4
  87   %mul2 = mul i32 %b2, %s
  88 ; CHECK: %mul2 = add i32 %mul1, [[BUMP]]
  89   %v2 = call i32 @foo(i32 %mul2)
  90
  91   %1 = add i32 %v0, %v1
  92   %2 = add i32 %1, %v2
  93   ret i32 %2
  94 }
  95
  96 ; Do not rewrite a candidate if its potential basis does not dominate it.
  97 ; v0 = 0;
  98 ; if (cond)
  99 ;   v0 = foo(a * b);
 100 ; v1 = foo((a + 1) * b);
 101 ; return v0 + v1;
 102 define i32 @not_dominate(i1 %cond, i32 %a, i32 %b) {
 103 ; CHECK-LABEL: @not_dominate(
 104 entry:
 105   %a1 = add i32 %a, 1
 106   br i1 %cond, label %then, label %merge
 107
 108 then:
 109   %mul0 = mul i32 %a, %b
 110 ; CHECK: %mul0 = mul i32 %a, %b
 111   %v0 = call i32 @foo(i32 %mul0)
 112   br label %merge
 113
 114 merge:
 115   %v0.phi = phi i32 [ 0, %entry ], [ %mul0, %then ]
 116   %mul1 = mul i32 %a1, %b
 117 ; CHECK: %mul1 = mul i32 %a1, %b
 118   %v1 = call i32 @foo(i32 %mul1)
 119   %sum = add i32 %v0.phi, %v1
 120   ret i32 %sum
 121 }