test/CodeGen/X86/switch.ll

   1 ; RUN: llc -mtriple=x86_64-linux-gnu %s -o - | FileCheck %s
   2 ; RUN: llc -mtriple=x86_64-linux-gnu %s -o - -O0 | FileCheck --check-prefix=NOOPT %s
   3
   4 declare void @g(i32)
   5
   6 define void @basic(i32 %x) {
   7 entry:
   8   switch i32 %x, label %return [
   9     i32 3, label %bb0
  10     i32 1, label %bb1
  11     i32 4, label %bb1
  12     i32 5, label %bb2
  13   ]
  14 bb0: tail call void @g(i32 0) br label %return
  15 bb1: tail call void @g(i32 1) br label %return
  16 bb2: tail call void @g(i32 1) br label %return
  17 return: ret void
  18
  19 ; Lowered as a jump table, both with and without optimization.
  20 ; CHECK-LABEL: basic
  21 ; CHECK: decl
  22 ; CHECK: cmpl $4
  23 ; CHECK: ja
  24 ; CHECK: jmpq *.LJTI
  25 ; NOOPT-LABEL: basic
  26 ; NOOPT: decl
  27 ; NOOPT: subl $4
  28 ; NOOPT: ja
  29 ; NOOPT: movq .LJTI
  30 ; NOOPT: jmpq
  31 }
  32
  33
  34 define void @simple_ranges(i32 %x) {
  35 entry:
  36   switch i32 %x, label %return [
  37     i32 0, label %bb0
  38     i32 1, label %bb0
  39     i32 2, label %bb0
  40     i32 3, label %bb0
  41     i32 100, label %bb1
  42     i32 101, label %bb1
  43     i32 102, label %bb1
  44     i32 103, label %bb1
  45   ]
  46 bb0: tail call void @g(i32 0) br label %return
  47 bb1: tail call void @g(i32 1) br label %return
  48 return: ret void
  49
  50 ; Should be lowered to two range checks.
  51 ; CHECK-LABEL: simple_ranges
  52 ; CHECK: leal -100
  53 ; CHECK: cmpl $4
  54 ; CHECK: jae
  55 ; CHECK: cmpl $3
  56 ; CHECK: ja
  57
  58 ; We do this even at -O0, because it's cheap and makes codegen faster.
  59 ; NOOPT-LABEL: simple_ranges
  60 ; NOOPT: subl $4
  61 ; NOOPT: jb
  62 ; NOOPT: addl $-100
  63 ; NOOPT: subl $4
  64 ; NOOPT: jb
  65 }
  66
  67
  68 define void @jt_is_better(i32 %x) {
  69 entry:
  70   switch i32 %x, label %return [
  71     i32 0, label %bb0
  72     i32 2, label %bb0
  73     i32 4, label %bb0
  74     i32 1, label %bb1
  75     i32 3, label %bb1
  76     i32 5, label %bb1
  77
  78     i32 6, label %bb2
  79     i32 7, label %bb3
  80     i32 8, label %bb4
  81   ]
  82 bb0: tail call void @g(i32 0) br label %return
  83 bb1: tail call void @g(i32 1) br label %return
  84 bb2: tail call void @g(i32 2) br label %return
  85 bb3: tail call void @g(i32 3) br label %return
  86 bb4: tail call void @g(i32 4) br label %return
  87 return: ret void
  88
  89 ; Cases 0-5 could be lowered with two bit tests,
  90 ; but with 6-8, the whole switch is suitable for a jump table.
  91 ; CHECK-LABEL: jt_is_better
  92 ; CHECK: cmpl $8
  93 ; CHECK: jbe
  94 ; CHECK: jmpq *.LJTI
  95 }
  96
  97
  98 define void @bt_is_better(i32 %x) {
  99 entry:
 100   switch i32 %x, label %return [
 101     i32 0, label %bb0
 102     i32 3, label %bb0
 103     i32 6, label %bb0
 104     i32 1, label %bb1
 105     i32 4, label %bb1
 106     i32 7, label %bb1
 107     i32 2, label %bb2
 108     i32 5, label %bb2
 109     i32 8, label %bb2
 110
 111   ]
 112 bb0: tail call void @g(i32 0) br label %return
 113 bb1: tail call void @g(i32 1) br label %return
 114 bb2: tail call void @g(i32 2) br label %return
 115 return: ret void
 116
 117 ; This could be lowered as a jump table, but bit tests is more efficient.
 118 ; CHECK-LABEL: bt_is_better
 119 ; 73 = 2^0 + 2^3 + 2^6
 120 ; CHECK: movl $73
 121 ; CHECK: btl
 122 ; 146 = 2^1 + 2^4 + 2^7
 123 ; CHECK: movl $146
 124 ; CHECK: btl
 125 ; 292 = 2^2 + 2^5 + 2^8
 126 ; CHECK: movl $292
 127 ; CHECK: btl
 128 }
 129
 130
 131 define void @optimal_pivot1(i32 %x) {
 132 entry:
 133   switch i32 %x, label %return [
 134     i32 100, label %bb0
 135     i32 200, label %bb1
 136     i32 300, label %bb0
 137     i32 400, label %bb1
 138     i32 500, label %bb0
 139     i32 600, label %bb1
 140
 141   ]
 142 bb0: tail call void @g(i32 0) br label %return
 143 bb1: tail call void @g(i32 1) br label %return
 144 return: ret void
 145
 146 ; Should pivot around 400 for two subtrees of equal size.
 147 ; CHECK-LABEL: optimal_pivot1
 148 ; CHECK-NOT: cmpl
 149 ; CHECK: cmpl $399
 150 }
 151
 152
 153 define void @optimal_pivot2(i32 %x) {
 154 entry:
 155   switch i32 %x, label %return [
 156     i32 100, label %bb0   i32 101, label %bb1   i32 102, label %bb2   i32 103, label %bb3
 157     i32 200, label %bb0   i32 201, label %bb1   i32 202, label %bb2   i32 203, label %bb3
 158     i32 300, label %bb0   i32 301, label %bb1   i32 302, label %bb2   i32 303, label %bb3
 159     i32 400, label %bb0   i32 401, label %bb1   i32 402, label %bb2   i32 403, label %bb3
 160
 161   ]
 162 bb0: tail call void @g(i32 0) br label %return
 163 bb1: tail call void @g(i32 1) br label %return
 164 bb2: tail call void @g(i32 2) br label %return
 165 bb3: tail call void @g(i32 3) br label %return
 166 return: ret void
 167
 168 ; Should pivot around 300 for two subtrees with two jump tables each.
 169 ; CHECK-LABEL: optimal_pivot2
 170 ; CHECK-NOT: cmpl
 171 ; CHECK: cmpl $299
 172 ; CHECK: jmpq *.LJTI
 173 ; CHECK: jmpq *.LJTI
 174 ; CHECK: jmpq *.LJTI
 175 ; CHECK: jmpq *.LJTI
 176 }
 177
 178
 179 define void @optimal_jump_table1(i32 %x) {
 180 entry:
 181   switch i32 %x, label %return [
 182     i32 0,  label %bb0
 183     i32 5,  label %bb1
 184     i32 6,  label %bb2
 185     i32 12, label %bb3
 186     i32 13, label %bb4
 187     i32 15, label %bb5
 188   ]
 189 bb0: tail call void @g(i32 0) br label %return
 190 bb1: tail call void @g(i32 1) br label %return
 191 bb2: tail call void @g(i32 2) br label %return
 192 bb3: tail call void @g(i32 3) br label %return
 193 bb4: tail call void @g(i32 4) br label %return
 194 bb5: tail call void @g(i32 5) br label %return
 195 return: ret void
 196
 197 ; Splitting in the largest gap (between 6 and 12) would yield suboptimal result.
 198 ; Expecting a jump table from 5 to 15.
 199 ; CHECK-LABEL: optimal_jump_table1
 200 ; CHECK: leal -5
 201 ; CHECK: cmpl $10
 202 ; CHECK: jmpq *.LJTI
 203
 204 ; At -O0, we don't build jump tables for only parts of a switch.
 205 ; NOOPT-LABEL: optimal_jump_table1
 206 ; NOOPT: testl %edi, %edi
 207 ; NOOPT: je
 208 ; NOOPT: subl $5, %eax
 209 ; NOOPT: je
 210 ; NOOPT: subl $6, %eax
 211 ; NOOPT: je
 212 ; NOOPT: subl $12, %eax
 213 ; NOOPT: je
 214 ; NOOPT: subl $13, %eax
 215 ; NOOPT: je
 216 ; NOOPT: subl $15, %eax
 217 ; NOOPT: je
 218 }
 219
 220
 221 define void @optimal_jump_table2(i32 %x) {
 222 entry:
 223   switch i32 %x, label %return [
 224     i32 0,  label %bb0
 225     i32 1,  label %bb1
 226     i32 2,  label %bb2
 227     i32 9,  label %bb3
 228     i32 14, label %bb4
 229     i32 15, label %bb5
 230   ]
 231 bb0: tail call void @g(i32 0) br label %return
 232 bb1: tail call void @g(i32 1) br label %return
 233 bb2: tail call void @g(i32 2) br label %return
 234 bb3: tail call void @g(i32 3) br label %return
 235 bb4: tail call void @g(i32 4) br label %return
 236 bb5: tail call void @g(i32 5) br label %return
 237 return: ret void
 238
 239 ; Partitioning the cases to the minimum number of dense sets is not good enough.
 240 ; This can be partitioned as {0,1,2,9},{14,15} or {0,1,2},{9,14,15}. The former
 241 ; should be preferred. Expecting a table from 0-9.
 242 ; CHECK-LABEL: optimal_jump_table2
 243 ; CHECK: cmpl $9
 244 ; CHECK: jmpq *.LJTI
 245 }
 246
 247
 248 define void @optimal_jump_table3(i32 %x) {
 249 entry:
 250   switch i32 %x, label %return [
 251     i32 1,  label %bb0
 252     i32 2,  label %bb1
 253     i32 3,  label %bb2
 254     i32 10, label %bb3
 255     i32 13, label %bb0
 256     i32 14, label %bb1
 257     i32 15, label %bb2
 258     i32 20, label %bb3
 259     i32 25, label %bb4
 260   ]
 261 bb0: tail call void @g(i32 0) br label %return
 262 bb1: tail call void @g(i32 1) br label %return
 263 bb2: tail call void @g(i32 2) br label %return
 264 bb3: tail call void @g(i32 3) br label %return
 265 bb4: tail call void @g(i32 4) br label %return
 266 return: ret void
 267
 268 ; Splitting to maximize left-right density sum and gap size would split this
 269 ; between 3 and 10, and then between 20 and 25. It's better to build a table
 270 ; from 1-20.
 271 ; CHECK-LABEL: optimal_jump_table3
 272 ; CHECK: leal -1
 273 ; CHECK: cmpl $19
 274 ; CHECK: jmpq *.LJTI
 275 }
 276
 277 %struct.S = type { %struct.S*, i32 }
 278 define void @phi_node_trouble(%struct.S* %s) {
 279 entry:
 280   br label %header
 281 header:
 282   %ptr = phi %struct.S* [ %s, %entry ], [ %next, %loop ]
 283   %bool = icmp eq %struct.S* %ptr, null
 284   br i1 %bool, label %exit, label %loop
 285 loop:
 286   %nextptr = getelementptr inbounds %struct.S, %struct.S* %ptr, i64 0, i32 0
 287   %next = load %struct.S*, %struct.S** %nextptr
 288   %xptr = getelementptr inbounds %struct.S, %struct.S* %next, i64 0, i32 1
 289   %x = load i32, i32* %xptr
 290   switch i32 %x, label %exit [
 291     i32 4, label %header
 292     i32 36, label %exit2
 293     i32 69, label %exit2
 294     i32 25, label %exit2
 295   ]
 296 exit:
 297   ret void
 298 exit2:
 299   ret void
 300
 301 ; This will be lowered to a comparison with 4 and then bit tests. Make sure
 302 ; that the phi node in %header gets a value from the comparison block.
 303 ; CHECK-LABEL: phi_node_trouble
 304 ; CHECK: movq (%[[REG1:[a-z]+]]), %[[REG1]]
 305 ; CHECK: movl 8(%[[REG1]]), %[[REG2:[a-z]+]]
 306 ; CHECK: cmpl $4, %[[REG2]]
 307 }
 308
 309
 310 define void @default_only(i32 %x) {
 311 entry:
 312   br label %sw
 313 return:
 314   ret void
 315 sw:
 316   switch i32 %x, label %return [
 317   ]
 318
 319 ; Branch directly to the default.
 320 ; (In optimized builds the switch is removed earlier.)
 321 ; NOOPT-LABEL: default_only
 322 ; NOOPT: .[[L:[A-Z0-9_]+]]:
 323 ; NOOPT-NEXT: retq
 324 ; NOOPT: jmp .[[L]]
 325 }
 326
 327
 328 define void @int_max_table_cluster(i8 %x) {
 329 entry:
 330   switch i8 %x, label %return [
 331     i8 0, label %bb0 i8 1, label %bb0 i8 2, label %bb0 i8 3, label %bb0
 332     i8 4, label %bb0 i8 5, label %bb0 i8 6, label %bb0 i8 7, label %bb0
 333     i8 8, label %bb0 i8 9, label %bb0 i8 10, label %bb0 i8 11, label %bb0
 334     i8 12, label %bb0 i8 13, label %bb0 i8 14, label %bb0 i8 15, label %bb0
 335     i8 16, label %bb0 i8 17, label %bb0 i8 18, label %bb0 i8 19, label %bb0
 336     i8 20, label %bb0 i8 21, label %bb0 i8 22, label %bb0 i8 23, label %bb0
 337     i8 24, label %bb0 i8 25, label %bb0 i8 26, label %bb0 i8 27, label %bb0
 338     i8 28, label %bb0 i8 29, label %bb0 i8 30, label %bb0 i8 31, label %bb0
 339     i8 32, label %bb0 i8 33, label %bb0 i8 34, label %bb0 i8 35, label %bb0
 340     i8 36, label %bb0 i8 37, label %bb0 i8 38, label %bb0 i8 39, label %bb0
 341     i8 40, label %bb0 i8 41, label %bb0 i8 42, label %bb0 i8 43, label %bb0
 342     i8 44, label %bb0 i8 45, label %bb0 i8 46, label %bb0 i8 47, label %bb0
 343     i8 48, label %bb0 i8 49, label %bb0 i8 50, label %bb0 i8 51, label %bb0
 344     i8 52, label %bb0 i8 53, label %bb0 i8 54, label %bb0 i8 55, label %bb0
 345     i8 56, label %bb0 i8 57, label %bb0 i8 58, label %bb0 i8 59, label %bb0
 346     i8 60, label %bb0 i8 61, label %bb0 i8 62, label %bb0 i8 63, label %bb0
 347     i8 64, label %bb0 i8 65, label %bb0 i8 66, label %bb0 i8 67, label %bb0
 348     i8 68, label %bb0 i8 69, label %bb0 i8 70, label %bb0 i8 71, label %bb0
 349     i8 72, label %bb0 i8 73, label %bb0 i8 74, label %bb0 i8 75, label %bb0
 350     i8 76, label %bb0 i8 77, label %bb0 i8 78, label %bb0 i8 79, label %bb0
 351     i8 80, label %bb0 i8 81, label %bb0 i8 82, label %bb0 i8 83, label %bb0
 352     i8 84, label %bb0 i8 85, label %bb0 i8 86, label %bb0 i8 87, label %bb0
 353     i8 88, label %bb0 i8 89, label %bb0 i8 90, label %bb0 i8 91, label %bb0
 354     i8 92, label %bb0 i8 93, label %bb0 i8 94, label %bb0 i8 95, label %bb0
 355     i8 96, label %bb0 i8 97, label %bb0 i8 98, label %bb0 i8 99, label %bb0
 356     i8 100, label %bb0 i8 101, label %bb0 i8 102, label %bb0 i8 103, label %bb0
 357     i8 104, label %bb0 i8 105, label %bb0 i8 106, label %bb0 i8 107, label %bb0
 358     i8 108, label %bb0 i8 109, label %bb0 i8 110, label %bb0 i8 111, label %bb0
 359     i8 112, label %bb0 i8 113, label %bb0 i8 114, label %bb0 i8 115, label %bb0
 360     i8 116, label %bb0 i8 117, label %bb0 i8 118, label %bb0 i8 119, label %bb0
 361     i8 120, label %bb0 i8 121, label %bb0 i8 122, label %bb0 i8 123, label %bb0
 362     i8 124, label %bb0 i8 125, label %bb0 i8 126, label %bb0 i8 127, label %bb0
 363     i8 -64, label %bb1 i8 -63, label %bb1 i8 -62, label %bb1 i8 -61, label %bb1
 364     i8 -60, label %bb1 i8 -59, label %bb1 i8 -58, label %bb1 i8 -57, label %bb1
 365     i8 -56, label %bb1 i8 -55, label %bb1 i8 -54, label %bb1 i8 -53, label %bb1
 366     i8 -52, label %bb1 i8 -51, label %bb1 i8 -50, label %bb1 i8 -49, label %bb1
 367     i8 -48, label %bb1 i8 -47, label %bb1 i8 -46, label %bb1 i8 -45, label %bb1
 368     i8 -44, label %bb1 i8 -43, label %bb1 i8 -42, label %bb1 i8 -41, label %bb1
 369     i8 -40, label %bb1 i8 -39, label %bb1 i8 -38, label %bb1 i8 -37, label %bb1
 370     i8 -36, label %bb1 i8 -35, label %bb1 i8 -34, label %bb1 i8 -33, label %bb1
 371     i8 -32, label %bb2 i8 -31, label %bb2 i8 -30, label %bb2 i8 -29, label %bb2
 372     i8 -28, label %bb2 i8 -27, label %bb2 i8 -26, label %bb2 i8 -25, label %bb2
 373     i8 -24, label %bb2 i8 -23, label %bb2 i8 -22, label %bb2 i8 -21, label %bb2
 374     i8 -20, label %bb2 i8 -19, label %bb2 i8 -18, label %bb2 i8 -17, label %bb2
 375     i8 -16, label %bb3 i8 -15, label %bb3 i8 -14, label %bb3 i8 -13, label %bb3
 376     i8 -12, label %bb3 i8 -11, label %bb3 i8 -10, label %bb3 i8 -9, label %bb3
 377   ]
 378 bb0: tail call void @g(i32 0) br label %return
 379 bb1: tail call void @g(i32 1) br label %return
 380 bb2: tail call void @g(i32 1) br label %return
 381 bb3: tail call void @g(i32 1) br label %return
 382 return: ret void
 383
 384 ; Don't infloop on jump tables where the upper bound is the max value of the
 385 ; input type (in this case 127).
 386 ; CHECK-LABEL: int_max_table_cluster
 387 ; CHECK: jmpq *.LJTI
 388 }
 389
 390
 391 define void @bt_order_by_weight(i32 %x) {
 392 entry:
 393   switch i32 %x, label %return [
 394     i32 0, label %bb0
 395     i32 3, label %bb0
 396     i32 6, label %bb0
 397     i32 1, label %bb1
 398     i32 4, label %bb1
 399     i32 7, label %bb1
 400     i32 2, label %bb2
 401     i32 5, label %bb2
 402     i32 8, label %bb2
 403     i32 9, label %bb2
 404   ], !prof !1
 405 bb0: tail call void @g(i32 0) br label %return
 406 bb1: tail call void @g(i32 1) br label %return
 407 bb2: tail call void @g(i32 2) br label %return
 408 return: ret void
 409
 410 ; Cases 1,4,7 have a very large branch weight (which shouldn't overflow), so
 411 ; their bit test should come first. 0,3,6 and 2,5,8,9 both have a weight of 12,
 412 ; but the latter set has more cases, so should be tested for earlier.
 413
 414 ; CHECK-LABEL: bt_order_by_weight
 415 ; 146 = 2^1 + 2^4 + 2^7
 416 ; CHECK: movl $146
 417 ; CHECK: btl
 418 ; 292 = 2^2 + 2^5 + 2^8 + 2^9
 419 ; CHECK: movl $804
 420 ; CHECK: btl
 421 ; 73 = 2^0 + 2^3 + 2^6
 422 ; CHECK: movl $73
 423 ; CHECK: btl
 424 }
 425
 426 !1 = !{!"branch_weights",
 427        ; Default:
 428        i32 1,
 429        ; Cases 0,3,6:
 430        i32 4, i32 4, i32 4,
 431        ; Cases 1,4,7:
 432        i32 4294967295, i32 2, i32 4294967295,
 433        ; Cases 2,5,8,9:
 434        i32 3, i32 3, i32 3, i32 3}
 435
 436 define void @order_by_weight_and_fallthrough(i32 %x) {
 437 entry:
 438   switch i32 %x, label %return [
 439     i32 100, label %bb1
 440     i32 200, label %bb0
 441     i32 300, label %bb0
 442   ], !prof !2
 443 bb0: tail call void @g(i32 0) br label %return
 444 bb1: tail call void @g(i32 1) br label %return
 445 return: ret void
 446
 447 ; Case 200 has the highest weight and should come first. 100 and 300 have the
 448 ; same weight, but 300 goes to the 'next' block, so should be last.
 449 ; CHECK-LABEL: order_by_weight_and_fallthrough
 450 ; CHECK: cmpl $200
 451 ; CHECK: cmpl $100
 452 ; CHECK: cmpl $300
 453 }
 454
 455 !2 = !{!"branch_weights",
 456        ; Default:
 457        i32 1,
 458        ; Case 100:
 459        i32 10,
 460        ; Case 200:
 461        i32 1000,
 462        ; Case 300:
 463        i32 10}
 464
 465
 466 define void @zero_weight_tree(i32 %x) {
 467 entry:
 468   switch i32 %x, label %return [
 469     i32 0,  label %bb0
 470     i32 10, label %bb1
 471     i32 20, label %bb2
 472     i32 30, label %bb3
 473     i32 40, label %bb4
 474     i32 50, label %bb5
 475   ], !prof !3
 476 bb0: tail call void @g(i32 0) br label %return
 477 bb1: tail call void @g(i32 1) br label %return
 478 bb2: tail call void @g(i32 2) br label %return
 479 bb3: tail call void @g(i32 3) br label %return
 480 bb4: tail call void @g(i32 4) br label %return
 481 bb5: tail call void @g(i32 5) br label %return
 482 return: ret void
 483
 484 ; Make sure to pick a pivot in the middle also with zero-weight cases.
 485 ; CHECK-LABEL: zero_weight_tree
 486 ; CHECK-NOT: cmpl
 487 ; CHECK: cmpl $29
 488 }
 489
 490 !3 = !{!"branch_weights", i32 1, i32 10, i32 0, i32 0, i32 0, i32 0, i32 10}
 491
 492
 493 define void @left_leaning_weight_balanced_tree(i32 %x) {
 494 entry:
 495   switch i32 %x, label %return [
 496     i32 0,  label %bb0
 497     i32 10, label %bb1
 498     i32 20, label %bb2
 499     i32 30, label %bb3
 500     i32 40, label %bb4
 501     i32 50, label %bb5
 502     i32 60, label %bb6
 503     i32 70, label %bb6
 504   ], !prof !4
 505 bb0: tail call void @g(i32 0) br label %return
 506 bb1: tail call void @g(i32 1) br label %return
 507 bb2: tail call void @g(i32 2) br label %return
 508 bb3: tail call void @g(i32 3) br label %return
 509 bb4: tail call void @g(i32 4) br label %return
 510 bb5: tail call void @g(i32 5) br label %return
 511 bb6: tail call void @g(i32 6) br label %return
 512 bb7: tail call void @g(i32 7) br label %return
 513 return: ret void
 514
 515 ; Without branch probabilities, the pivot would be 40, since that would yield
 516 ; equal-sized sub-trees. When taking weights into account, case 70 becomes the
 517 ; pivot. Since there is room for 3 cases in a leaf, cases 50 and 60 are also
 518 ; included in the right-hand side because that doesn't reduce their rank.
 519
 520 ; CHECK-LABEL: left_leaning_weight_balanced_tree
 521 ; CHECK-NOT: cmpl
 522 ; CHECK: cmpl $49
 523 }
 524
 525 !4 = !{!"branch_weights", i32 1, i32 10, i32 1, i32 1, i32 1, i32 1, i32 1, i32 1, i32 1000}
 526
 527
 528 define void @left_leaning_weight_balanced_tree2(i32 %x) {
 529 entry:
 530   switch i32 %x, label %return [
 531     i32 0,  label %bb0
 532     i32 10, label %bb1
 533     i32 20, label %bb2
 534     i32 30, label %bb3
 535     i32 40, label %bb4
 536     i32 50, label %bb5
 537     i32 60, label %bb6
 538     i32 70, label %bb6
 539   ], !prof !5
 540 bb0: tail call void @g(i32 0) br label %return
 541 bb1: tail call void @g(i32 1) br label %return
 542 bb2: tail call void @g(i32 2) br label %return
 543 bb3: tail call void @g(i32 3) br label %return
 544 bb4: tail call void @g(i32 4) br label %return
 545 bb5: tail call void @g(i32 5) br label %return
 546 bb6: tail call void @g(i32 6) br label %return
 547 bb7: tail call void @g(i32 7) br label %return
 548 return: ret void
 549
 550 ; Same as the previous test, except case 50 has higher rank to the left than it
 551 ; would have on the right. Case 60 would have the same rank on both sides, so is
 552 ; moved into the leaf.
 553
 554 ; CHECK-LABEL: left_leaning_weight_balanced_tree2
 555 ; CHECK-NOT: cmpl
 556 ; CHECK: cmpl $59
 557 }
 558
 559 !5 = !{!"branch_weights", i32 1, i32 10, i32 1, i32 1, i32 1, i32 1, i32 90, i32 70, i32 1000}
 560
 561
 562 define void @right_leaning_weight_balanced_tree(i32 %x) {
 563 entry:
 564   switch i32 %x, label %return [
 565     i32 0,  label %bb0
 566     i32 10, label %bb1
 567     i32 20, label %bb2
 568     i32 30, label %bb3
 569     i32 40, label %bb4
 570     i32 50, label %bb5
 571     i32 60, label %bb6
 572     i32 70, label %bb6
 573   ], !prof !6
 574 bb0: tail call void @g(i32 0) br label %return
 575 bb1: tail call void @g(i32 1) br label %return
 576 bb2: tail call void @g(i32 2) br label %return
 577 bb3: tail call void @g(i32 3) br label %return
 578 bb4: tail call void @g(i32 4) br label %return
 579 bb5: tail call void @g(i32 5) br label %return
 580 bb6: tail call void @g(i32 6) br label %return
 581 bb7: tail call void @g(i32 7) br label %return
 582 return: ret void
 583
 584 ; Analogous to left_leaning_weight_balanced_tree.
 585
 586 ; CHECK-LABEL: right_leaning_weight_balanced_tree
 587 ; CHECK-NOT: cmpl
 588 ; CHECK: cmpl $19
 589 }
 590
 591 !6 = !{!"branch_weights", i32 1, i32 1000, i32 1, i32 1, i32 1, i32 1, i32 1, i32 1, i32 10}
 592
 593
 594 define void @jump_table_affects_balance(i32 %x) {
 595 entry:
 596   switch i32 %x, label %return [
 597     ; Jump table:
 598     i32 0,  label %bb0
 599     i32 1,  label %bb1
 600     i32 2,  label %bb2
 601     i32 3,  label %bb3
 602
 603     i32 100, label %bb0
 604     i32 200, label %bb1
 605     i32 300, label %bb2
 606   ]
 607 bb0: tail call void @g(i32 0) br label %return
 608 bb1: tail call void @g(i32 1) br label %return
 609 bb2: tail call void @g(i32 2) br label %return
 610 bb3: tail call void @g(i32 3) br label %return
 611 return: ret void
 612
 613 ; CHECK-LABEL: jump_table_affects_balance
 614 ; If the tree were balanced based on number of clusters, {0-3,100} would go on
 615 ; the left and {200,300} on the right. However, the jump table weights as much
 616 ; as its components, so 100 is selected as the pivot.
 617 ; CHECK-NOT: cmpl
 618 ; CHECK: cmpl $99
 619 }
 620
 621
 622 define void @pr23738(i4 %x) {
 623 entry:
 624   switch i4 %x, label %bb0 [
 625     i4 0, label %bb1
 626     i4 1, label %bb1
 627     i4 -5, label %bb1
 628   ]
 629 bb0: tail call void @g(i32 0) br label %return
 630 bb1: tail call void @g(i32 1) br label %return
 631 return: ret void
 632 ; Don't assert due to truncating the bitwidth (64) to i4 when checking
 633 ; that the bit-test range fits in a word.
 634 }