projects/sample/autoconf/configure.ac

   1 dnl **************************************************************************
   2 dnl * Initialize
   3 dnl **************************************************************************
   4 AC_INIT([[[SAMPLE]]],[[[x.xx]]],[bugs@yourdomain])
   5
   6 dnl Identify where LLVM source tree is
   7 LLVM_SRC_ROOT="../.."
   8 LLVM_OBJ_ROOT="../.."
   9
  10 dnl Find absolute paths to LLVM source and object trees
  11 LLVM_ABS_SRC_ROOT="`cd $srcdir ; cd $LLVM_SRC_ROOT ; pwd`"
  12 LLVM_ABS_OBJ_ROOT="`cd $LLVM_OBJ_ROOT ; pwd`"
  13
  14 dnl Tell autoconf that this is an LLVM project being configured
  15 dnl This provides the --with-llvmsrc and --with-llvmobj options
  16 LLVM_CONFIG_PROJECT($LLVM_ABS_SRC_ROOT,$LLVM_ABS_OBJ_ROOT)
  17
  18 dnl Try and find an llvm-config in the build directory. We are only using this
  19 dnl to detect the package level LLVM information (currently just the version),
  20 dnl so we just whatever one we find regardless of build mode.
  21 AC_MSG_CHECKING([llvm-config])
  22 llvm_config_path="`ls -1 $llvm_obj/*/bin/llvm-config 2> /dev/null | head -1`"
  23 if ! test -f "$llvm_config_path" ; then
  24    llvm_config_path="no"
  25 fi
  26 AC_MSG_RESULT([$llvm_config_path])
  27
  28 dnl Determine the LLVM version, which may be required by the current Makefile
  29 dnl rules.
  30 AC_MSG_CHECKING([LLVM package version])
  31 if test "$llvm_config_path" != no ; then
  32   llvm_package_version=`$llvm_config_path --version`
  33 else
  34   llvm_package_version="unknown";
  35 fi
  36 AC_MSG_RESULT([$llvm_package_version])
  37 AC_SUBST(LLVM_VERSION, [$llvm_package_version])
  38
  39 dnl Verify that the source directory is valid
  40 AC_CONFIG_SRCDIR(["Makefile.common.in"])
  41
  42 dnl Place all of the extra autoconf files into the config subdirectory. Tell
  43 dnl various tools where the m4 autoconf macros are.
  44 AC_CONFIG_AUX_DIR([autoconf])
  45
  46 dnl **************************************************************************
  47 dnl Begin LLVM configure.ac Import
  48 dnl **************************************************************************
  49 dnl
  50 dnl Derived from LLVM's configure.ac. This was imported directly here so that we
  51 dnl could reuse LLVM's build infrastructure without introducing a direct source
  52 dnl dependency on the LLVM files.
  53
  54 dnl We need to check for the compiler up here to avoid anything else
  55 dnl starting with a different one.
  56 AC_PROG_CC(clang llvm-gcc gcc)
  57 AC_PROG_CXX(clang++ llvm-g++ g++)
  58 AC_PROG_CPP
  59
  60 dnl Configure all of the projects present in our source tree. While we could
  61 dnl just AC_CONFIG_SUBDIRS on the set of directories in projects that have a
  62 dnl configure script, that usage of the AC_CONFIG_SUBDIRS macro is deprecated.
  63 dnl Instead we match on the known projects.
  64
  65 dnl
  66 dnl One tricky part of doing this is that some projects depend upon other
  67 dnl projects.  For example, several projects rely upon the LLVM test suite.
  68 dnl We want to configure those projects first so that their object trees are
  69 dnl created before running the configure scripts of projects that depend upon
  70 dnl them.
  71 dnl
  72
  73 dnl Disable the build of polly, even if it is checked out into tools/polly.
  74 AC_ARG_ENABLE(polly,
  75               AS_HELP_STRING([--enable-polly],
  76                              [Use polly if available (default is YES)]),,
  77                              enableval=default)
  78 case "$enableval" in
  79   yes) AC_SUBST(ENABLE_POLLY,[1]) ;;
  80   no)  AC_SUBST(ENABLE_POLLY,[0]) ;;
  81   default) AC_SUBST(ENABLE_POLLY,[1]) ;;
  82   *) AC_MSG_ERROR([Invalid setting for --enable-polly. Use "yes" or "no"]) ;;
  83 esac
  84
  85
  86 dnl Check if polly is checked out into tools/polly and configure it if
  87 dnl available.
  88 if (test -d ${srcdir}/tools/polly) && (test $ENABLE_POLLY -eq 1) ; then
  89   AC_SUBST(LLVM_HAS_POLLY,1)
  90   AC_CONFIG_SUBDIRS([tools/polly])
  91 fi
  92
  93 dnl===-----------------------------------------------------------------------===
  94 dnl===
  95 dnl=== SECTION 2: Architecture, target, and host checks
  96 dnl===
  97 dnl===-----------------------------------------------------------------------===
  98
  99 dnl Check the target for which we're compiling and the host that will do the
 100 dnl compilations. This will tell us which LLVM compiler will be used for
 101 dnl compiling SSA into object code. This needs to be done early because
 102 dnl following tests depend on it.
 103 AC_CANONICAL_TARGET
 104
 105 dnl Determine the platform type and cache its value. This helps us configure
 106 dnl the System library to the correct build platform.
 107 AC_CACHE_CHECK([type of operating system we're going to host on],
 108                [llvm_cv_os_type],
 109 [case $host in
 110   *-*-aix*)
 111     llvm_cv_link_all_option="-Wl,--whole-archive"
 112     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 113     llvm_cv_os_type="AIX"
 114     llvm_cv_platform_type="Unix" ;;
 115   *-*-irix*)
 116     llvm_cv_link_all_option="-Wl,--whole-archive"
 117     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 118     llvm_cv_os_type="IRIX"
 119     llvm_cv_platform_type="Unix" ;;
 120   *-*-cygwin*)
 121     llvm_cv_link_all_option="-Wl,--whole-archive"
 122     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 123     llvm_cv_os_type="Cygwin"
 124     llvm_cv_platform_type="Unix" ;;
 125   *-*-darwin*)
 126     llvm_cv_link_all_option="-Wl,-all_load"
 127     llvm_cv_no_link_all_option="-Wl,-noall_load"
 128     llvm_cv_os_type="Darwin"
 129     llvm_cv_platform_type="Unix" ;;
 130   *-*-minix*)
 131     llvm_cv_link_all_option="-Wl,-all_load"
 132     llvm_cv_no_link_all_option="-Wl,-noall_load"
 133     llvm_cv_os_type="Minix"
 134     llvm_cv_platform_type="Unix" ;;
 135   *-*-freebsd* | *-*-kfreebsd-gnu)
 136     llvm_cv_link_all_option="-Wl,--whole-archive"
 137     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 138     llvm_cv_os_type="FreeBSD"
 139     llvm_cv_platform_type="Unix" ;;
 140   *-*-openbsd*)
 141     llvm_cv_link_all_option="-Wl,--whole-archive"
 142     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 143     llvm_cv_os_type="OpenBSD"
 144     llvm_cv_platform_type="Unix" ;;
 145   *-*-netbsd*)
 146     llvm_cv_link_all_option="-Wl,--whole-archive"
 147     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 148     llvm_cv_os_type="NetBSD"
 149     llvm_cv_platform_type="Unix" ;;
 150   *-*-dragonfly*)
 151     llvm_cv_link_all_option="-Wl,--whole-archive"
 152     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 153     llvm_cv_os_type="DragonFly"
 154     llvm_cv_platform_type="Unix" ;;
 155   *-*-hpux*)
 156     llvm_cv_link_all_option="-Wl,--whole-archive"
 157     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 158     llvm_cv_os_type="HP-UX"
 159     llvm_cv_platform_type="Unix" ;;
 160   *-*-interix*)
 161     llvm_cv_link_all_option="-Wl,--whole-archive"
 162     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 163     llvm_cv_os_type="Interix"
 164     llvm_cv_platform_type="Unix" ;;
 165   *-*-linux*)
 166     llvm_cv_link_all_option="-Wl,--whole-archive"
 167     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 168     llvm_cv_os_type="Linux"
 169     llvm_cv_platform_type="Unix" ;;
 170   *-*-gnu*)
 171     llvm_cv_link_all_option="-Wl,--whole-archive"
 172     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 173     llvm_cv_os_type="GNU"
 174     llvm_cv_platform_type="Unix" ;;
 175   *-*-solaris*)
 176     llvm_cv_link_all_option="-Wl,-z,allextract"
 177     llvm_cv_no_link_all_option="-Wl,-z,defaultextract"
 178     llvm_cv_os_type="SunOS"
 179     llvm_cv_platform_type="Unix" ;;
 180   *-*-auroraux*)
 181     llvm_cv_link_all_option="-Wl,-z,allextract"
 182     llvm_cv_link_all_option="-Wl,-z,defaultextract"
 183     llvm_cv_os_type="AuroraUX"
 184     llvm_cv_platform_type="Unix" ;;
 185   *-*-win32*)
 186     llvm_cv_link_all_option="-Wl,--whole-archive"
 187     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 188     llvm_cv_os_type="Win32"
 189     llvm_cv_platform_type="Win32" ;;
 190   *-*-mingw*)
 191     llvm_cv_link_all_option="-Wl,--whole-archive"
 192     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 193     llvm_cv_os_type="MingW"
 194     llvm_cv_platform_type="Win32" ;;
 195   *-*-haiku*)
 196     llvm_cv_link_all_option="-Wl,--whole-archive"
 197     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 198     llvm_cv_os_type="Haiku"
 199     llvm_cv_platform_type="Unix" ;;
 200   *-unknown-eabi*)
 201     llvm_cv_link_all_option="-Wl,--whole-archive"
 202     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 203     llvm_cv_os_type="Freestanding"
 204     llvm_cv_platform_type="Unix" ;;
 205   *-unknown-elf*)
 206     llvm_cv_link_all_option="-Wl,--whole-archive"
 207     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 208     llvm_cv_os_type="Freestanding"
 209     llvm_cv_platform_type="Unix" ;;
 210   *)
 211     llvm_cv_link_all_option=""
 212     llvm_cv_no_link_all_option=""
 213     llvm_cv_os_type="Unknown"
 214     llvm_cv_platform_type="Unknown" ;;
 215 esac])
 216
 217 AC_CACHE_CHECK([type of operating system we're going to target],
 218                [llvm_cv_target_os_type],
 219 [case $target in
 220   *-*-aix*)
 221     llvm_cv_target_os_type="AIX" ;;
 222   *-*-irix*)
 223     llvm_cv_target_os_type="IRIX" ;;
 224   *-*-cygwin*)
 225     llvm_cv_target_os_type="Cygwin" ;;
 226   *-*-darwin*)
 227     llvm_cv_target_os_type="Darwin" ;;
 228   *-*-minix*)
 229     llvm_cv_target_os_type="Minix" ;;
 230   *-*-freebsd* | *-*-kfreebsd-gnu)
 231     llvm_cv_target_os_type="FreeBSD" ;;
 232   *-*-openbsd*)
 233     llvm_cv_target_os_type="OpenBSD" ;;
 234   *-*-netbsd*)
 235     llvm_cv_target_os_type="NetBSD" ;;
 236   *-*-dragonfly*)
 237     llvm_cv_target_os_type="DragonFly" ;;
 238   *-*-hpux*)
 239     llvm_cv_target_os_type="HP-UX" ;;
 240   *-*-interix*)
 241     llvm_cv_target_os_type="Interix" ;;
 242   *-*-linux*)
 243     llvm_cv_target_os_type="Linux" ;;
 244   *-*-gnu*)
 245     llvm_cv_target_os_type="GNU" ;;
 246   *-*-solaris*)
 247     llvm_cv_target_os_type="SunOS" ;;
 248   *-*-auroraux*)
 249     llvm_cv_target_os_type="AuroraUX" ;;
 250   *-*-win32*)
 251     llvm_cv_target_os_type="Win32" ;;
 252   *-*-mingw*)
 253     llvm_cv_target_os_type="MingW" ;;
 254   *-*-haiku*)
 255     llvm_cv_target_os_type="Haiku" ;;
 256   *-*-rtems*)
 257     llvm_cv_target_os_type="RTEMS" ;;
 258   *-*-nacl*)
 259     llvm_cv_target_os_type="NativeClient" ;;
 260   *-unknown-eabi*)
 261     llvm_cv_target_os_type="Freestanding" ;;
 262   *)
 263     llvm_cv_target_os_type="Unknown" ;;
 264 esac])
 265
 266 dnl Make sure we aren't attempting to configure for an unknown system
 267 if test "$llvm_cv_os_type" = "Unknown" ; then
 268   AC_MSG_ERROR([Operating system is unknown, configure can't continue])
 269 fi
 270
 271 dnl Set the "OS" Makefile variable based on the platform type so the
 272 dnl makefile can configure itself to specific build hosts
 273 AC_SUBST(OS,$llvm_cv_os_type)
 274 AC_SUBST(HOST_OS,$llvm_cv_os_type)
 275 AC_SUBST(TARGET_OS,$llvm_cv_target_os_type)
 276
 277 dnl Set the LINKALL and NOLINKALL Makefile variables based on the platform
 278 AC_SUBST(LINKALL,$llvm_cv_link_all_option)
 279 AC_SUBST(NOLINKALL,$llvm_cv_no_link_all_option)
 280
 281 dnl Set the "LLVM_ON_*" variables based on llvm_cv_platform_type
 282 dnl This is used by lib/Support to determine the basic kind of implementation
 283 dnl to use.
 284 case $llvm_cv_platform_type in
 285   Unix)
 286     AC_DEFINE([LLVM_ON_UNIX],[1],[Define if this is Unixish platform])
 287     AC_SUBST(LLVM_ON_UNIX,[1])
 288     AC_SUBST(LLVM_ON_WIN32,[0])
 289     ;;
 290   Win32)
 291     AC_DEFINE([LLVM_ON_WIN32],[1],[Define if this is Win32ish platform])
 292     AC_SUBST(LLVM_ON_UNIX,[0])
 293     AC_SUBST(LLVM_ON_WIN32,[1])
 294     ;;
 295 esac
 296
 297 dnl Determine what our target architecture is and configure accordingly.
 298 dnl This will allow Makefiles to make a distinction between the hardware and
 299 dnl the OS.
 300 AC_CACHE_CHECK([target architecture],[llvm_cv_target_arch],
 301 [case $target in
 302   i?86-*)                 llvm_cv_target_arch="x86" ;;
 303   amd64-* | x86_64-*)     llvm_cv_target_arch="x86_64" ;;
 304   sparc*-*)               llvm_cv_target_arch="Sparc" ;;
 305   powerpc*-*)             llvm_cv_target_arch="PowerPC" ;;
 306   arm*-*)                 llvm_cv_target_arch="ARM" ;;
 307   aarch64*-*)             llvm_cv_target_arch="AArch64" ;;
 308   mips-* | mips64-*)      llvm_cv_target_arch="Mips" ;;
 309   mipsel-* | mips64el-*)  llvm_cv_target_arch="Mips" ;;
 310   xcore-*)                llvm_cv_target_arch="XCore" ;;
 311   msp430-*)               llvm_cv_target_arch="MSP430" ;;
 312   hexagon-*)              llvm_cv_target_arch="Hexagon" ;;
 313   mblaze-*)               llvm_cv_target_arch="MBlaze" ;;
 314   nvptx-*)                llvm_cv_target_arch="NVPTX" ;;
 315   *)                      llvm_cv_target_arch="Unknown" ;;
 316 esac])
 317
 318 if test "$llvm_cv_target_arch" = "Unknown" ; then
 319   AC_MSG_WARN([Configuring LLVM for an unknown target archicture])
 320 fi
 321
 322 # Determine the LLVM native architecture for the target
 323 case "$llvm_cv_target_arch" in
 324     x86)     LLVM_NATIVE_ARCH="X86" ;;
 325     x86_64)  LLVM_NATIVE_ARCH="X86" ;;
 326     *)       LLVM_NATIVE_ARCH="$llvm_cv_target_arch" ;;
 327 esac
 328
 329 dnl Define a substitution, ARCH, for the target architecture
 330 AC_SUBST(ARCH,$llvm_cv_target_arch)
 331
 332 dnl Check for the endianness of the target
 333 AC_C_BIGENDIAN(AC_SUBST([ENDIAN],[big]),AC_SUBST([ENDIAN],[little]))
 334
 335 dnl Check for build platform executable suffix if we're crosscompiling
 336 if test "$cross_compiling" = yes; then
 337   AC_SUBST(LLVM_CROSS_COMPILING, [1])
 338   AC_BUILD_EXEEXT
 339   ac_build_prefix=${build_alias}-
 340   AC_CHECK_PROG(BUILD_CXX, ${ac_build_prefix}g++, ${ac_build_prefix}g++)
 341   if test -z "$BUILD_CXX"; then
 342      AC_CHECK_PROG(BUILD_CXX, g++, g++)
 343      if test -z "$BUILD_CXX"; then
 344        AC_CHECK_PROG(BUILD_CXX, c++, c++, , , /usr/ucb/c++)
 345      fi
 346   fi
 347 else
 348   AC_SUBST(LLVM_CROSS_COMPILING, [0])
 349 fi
 350
 351 dnl Check to see if there's a .svn or .git directory indicating that this
 352 dnl build is being done from a checkout. This sets up several defaults for
 353 dnl the command line switches. When we build with a checkout directory,
 354 dnl we get a debug with assertions turned on. Without, we assume a source
 355 dnl release and we get an optimized build without assertions.
 356 dnl See --enable-optimized and --enable-assertions below
 357 if test -d ".svn" -o -d "${srcdir}/.svn" -o -d ".git" -o -d "${srcdir}/.git"; then
 358   cvsbuild="yes"
 359   optimize="no"
 360   AC_SUBST(CVSBUILD,[[CVSBUILD=1]])
 361 else
 362   cvsbuild="no"
 363   optimize="yes"
 364 fi
 365
 366 dnl===-----------------------------------------------------------------------===
 367 dnl===
 368 dnl=== SECTION 3: Command line arguments for the configure script.
 369 dnl===
 370 dnl===-----------------------------------------------------------------------===
 371
 372 dnl --enable-libcpp : check whether or not to use libc++ on the command line
 373 AC_ARG_ENABLE(libcpp,
 374               AS_HELP_STRING([--enable-libcpp],
 375                              [Use libc++ if available (default is NO)]),,
 376                              enableval=default)
 377 case "$enableval" in
 378   yes) AC_SUBST(ENABLE_LIBCPP,[1]) ;;
 379   no)  AC_SUBST(ENABLE_LIBCPP,[0]) ;;
 380   default) AC_SUBST(ENABLE_LIBCPP,[0]);;
 381   *) AC_MSG_ERROR([Invalid setting for --enable-libcpp. Use "yes" or "no"]) ;;
 382 esac
 383
 384 dnl --enable-cxx11 : check whether or not to use -std=c++11 on the command line
 385 AC_ARG_ENABLE(cxx11,
 386               AS_HELP_STRING([--enable-cxx11],
 387                              [Use c++11 if available (default is NO)]),,
 388                              enableval=default)
 389 case "$enableval" in
 390   yes) AC_SUBST(ENABLE_CXX11,[1]) ;;
 391   no)  AC_SUBST(ENABLE_CXX11,[0]) ;;
 392   default) AC_SUBST(ENABLE_CXX11,[0]);;
 393   *) AC_MSG_ERROR([Invalid setting for --enable-cxx11. Use "yes" or "no"]) ;;
 394 esac
 395
 396 dnl --enable-optimized : check whether they want to do an optimized build:
 397 AC_ARG_ENABLE(optimized, AS_HELP_STRING(
 398  --enable-optimized,[Compile with optimizations enabled (default is NO)]),,enableval=$optimize)
 399 if test ${enableval} = "no" ; then
 400   AC_SUBST(ENABLE_OPTIMIZED,[[]])
 401 else
 402   AC_SUBST(ENABLE_OPTIMIZED,[[ENABLE_OPTIMIZED=1]])
 403 fi
 404
 405 dnl --enable-profiling : check whether they want to do a profile build:
 406 AC_ARG_ENABLE(profiling, AS_HELP_STRING(
 407  --enable-profiling,[Compile with profiling enabled (default is NO)]),,enableval="no")
 408 if test ${enableval} = "no" ; then
 409   AC_SUBST(ENABLE_PROFILING,[[]])
 410 else
 411   AC_SUBST(ENABLE_PROFILING,[[ENABLE_PROFILING=1]])
 412 fi
 413
 414 dnl --enable-assertions : check whether they want to turn on assertions or not:
 415 AC_ARG_ENABLE(assertions,AS_HELP_STRING(
 416   --enable-assertions,[Compile with assertion checks enabled (default is YES)]),, enableval="yes")
 417 if test ${enableval} = "yes" ; then
 418   AC_SUBST(DISABLE_ASSERTIONS,[[]])
 419 else
 420   AC_SUBST(DISABLE_ASSERTIONS,[[DISABLE_ASSERTIONS=1]])
 421 fi
 422
 423 dnl --enable-werror : check whether we want Werror on by default
 424 AC_ARG_ENABLE(werror,AS_HELP_STRING(
 425   --enable-werror,[Compile with -Werror enabled (default is NO)]),, enableval="no")
 426 case "$enableval" in
 427   yes) AC_SUBST(ENABLE_WERROR,[1]) ;;
 428   no)  AC_SUBST(ENABLE_WERROR,[0]) ;;
 429   default) AC_SUBST(ENABLE_WERROR,[0]);;
 430   *) AC_MSG_ERROR([Invalid setting for --enable-werror. Use "yes" or "no"]) ;;
 431 esac
 432
 433 dnl --enable-expensive-checks : check whether they want to turn on expensive debug checks:
 434 AC_ARG_ENABLE(expensive-checks,AS_HELP_STRING(
 435   --enable-expensive-checks,[Compile with expensive debug checks enabled (default is NO)]),, enableval="no")
 436 if test ${enableval} = "yes" ; then
 437   AC_SUBST(ENABLE_EXPENSIVE_CHECKS,[[ENABLE_EXPENSIVE_CHECKS=1]])
 438   AC_SUBST(EXPENSIVE_CHECKS,[[yes]])
 439 else
 440   AC_SUBST(ENABLE_EXPENSIVE_CHECKS,[[]])
 441   AC_SUBST(EXPENSIVE_CHECKS,[[no]])
 442 fi
 443
 444 dnl --enable-debug-runtime : should runtime libraries have debug symbols?
 445 AC_ARG_ENABLE(debug-runtime,
 446    AS_HELP_STRING(--enable-debug-runtime,[Build runtime libs with debug symbols (default is NO)]),,enableval=no)
 447 if test ${enableval} = "no" ; then
 448   AC_SUBST(DEBUG_RUNTIME,[[]])
 449 else
 450   AC_SUBST(DEBUG_RUNTIME,[[DEBUG_RUNTIME=1]])
 451 fi
 452
 453 dnl --enable-debug-symbols : should even optimized compiler libraries
 454 dnl have debug symbols?
 455 AC_ARG_ENABLE(debug-symbols,
 456    AS_HELP_STRING(--enable-debug-symbols,[Build compiler with debug symbols (default is NO if optimization is on and YES if it's off)]),,enableval=no)
 457 if test ${enableval} = "no" ; then
 458   AC_SUBST(DEBUG_SYMBOLS,[[]])
 459 else
 460   AC_SUBST(DEBUG_SYMBOLS,[[DEBUG_SYMBOLS=1]])
 461 fi
 462
 463 dnl --enable-jit: check whether they want to enable the jit
 464 AC_ARG_ENABLE(jit,
 465   AS_HELP_STRING(--enable-jit,
 466                  [Enable Just In Time Compiling (default is YES)]),,
 467   enableval=default)
 468 if test ${enableval} = "no"
 469 then
 470   AC_SUBST(JIT,[[]])
 471 else
 472   case "$llvm_cv_target_arch" in
 473     x86)         AC_SUBST(TARGET_HAS_JIT,1) ;;
 474     Sparc)       AC_SUBST(TARGET_HAS_JIT,0) ;;
 475     PowerPC)     AC_SUBST(TARGET_HAS_JIT,1) ;;
 476     x86_64)      AC_SUBST(TARGET_HAS_JIT,1) ;;
 477     ARM)         AC_SUBST(TARGET_HAS_JIT,1) ;;
 478     AArch64)     AC_SUBST(TARGET_HAS_JIT,0) ;;
 479     Mips)        AC_SUBST(TARGET_HAS_JIT,1) ;;
 480     XCore)       AC_SUBST(TARGET_HAS_JIT,0) ;;
 481     MSP430)      AC_SUBST(TARGET_HAS_JIT,0) ;;
 482     Hexagon)     AC_SUBST(TARGET_HAS_JIT,0) ;;
 483     MBlaze)      AC_SUBST(TARGET_HAS_JIT,0) ;;
 484     NVPTX)       AC_SUBST(TARGET_HAS_JIT,0) ;;
 485     *)           AC_SUBST(TARGET_HAS_JIT,0) ;;
 486   esac
 487 fi
 488
 489 dnl Allow enablement of building and installing docs
 490 AC_ARG_ENABLE(docs,
 491               AS_HELP_STRING([--enable-docs],
 492                              [Build documents (default is YES)]),,
 493                              enableval=default)
 494 case "$enableval" in
 495   yes) AC_SUBST(ENABLE_DOCS,[1]) ;;
 496   no)  AC_SUBST(ENABLE_DOCS,[0]) ;;
 497   default) AC_SUBST(ENABLE_DOCS,[1]) ;;
 498   *) AC_MSG_ERROR([Invalid setting for --enable-docs. Use "yes" or "no"]) ;;
 499 esac
 500
 501 dnl Allow enablement of doxygen generated documentation
 502 AC_ARG_ENABLE(doxygen,
 503               AS_HELP_STRING([--enable-doxygen],
 504                              [Build doxygen documentation (default is NO)]),,
 505                              enableval=default)
 506 case "$enableval" in
 507   yes) AC_SUBST(ENABLE_DOXYGEN,[1]) ;;
 508   no)  AC_SUBST(ENABLE_DOXYGEN,[0]) ;;
 509   default) AC_SUBST(ENABLE_DOXYGEN,[0]) ;;
 510   *) AC_MSG_ERROR([Invalid setting for --enable-doxygen. Use "yes" or "no"]) ;;
 511 esac
 512
 513 dnl Allow disablement of threads
 514 AC_ARG_ENABLE(threads,
 515               AS_HELP_STRING([--enable-threads],
 516                              [Use threads if available (default is YES)]),,
 517                              enableval=default)
 518 case "$enableval" in
 519   yes) AC_SUBST(ENABLE_THREADS,[1]) ;;
 520   no)  AC_SUBST(ENABLE_THREADS,[0]) ;;
 521   default) AC_SUBST(ENABLE_THREADS,[1]) ;;
 522   *) AC_MSG_ERROR([Invalid setting for --enable-threads. Use "yes" or "no"]) ;;
 523 esac
 524 AC_DEFINE_UNQUOTED([ENABLE_THREADS],$ENABLE_THREADS,[Define if threads enabled])
 525
 526 dnl Allow disablement of pthread.h
 527 AC_ARG_ENABLE(pthreads,
 528               AS_HELP_STRING([--enable-pthreads],
 529                              [Use pthreads if available (default is YES)]),,
 530                              enableval=default)
 531 case "$enableval" in
 532   yes) AC_SUBST(ENABLE_PTHREADS,[1]) ;;
 533   no)  AC_SUBST(ENABLE_PTHREADS,[0]) ;;
 534   default) AC_SUBST(ENABLE_PTHREADS,[1]) ;;
 535   *) AC_MSG_ERROR([Invalid setting for --enable-pthreads. Use "yes" or "no"]) ;;
 536 esac
 537
 538 dnl Allow building without position independent code
 539 AC_ARG_ENABLE(pic,
 540   AS_HELP_STRING([--enable-pic],
 541                  [Build LLVM with Position Independent Code (default is YES)]),,
 542                  enableval=default)
 543 case "$enableval" in
 544   yes) AC_SUBST(ENABLE_PIC,[1]) ;;
 545   no)  AC_SUBST(ENABLE_PIC,[0]) ;;
 546   default) AC_SUBST(ENABLE_PIC,[1]) ;;
 547   *) AC_MSG_ERROR([Invalid setting for --enable-pic. Use "yes" or "no"]) ;;
 548 esac
 549 AC_DEFINE_UNQUOTED([ENABLE_PIC],$ENABLE_PIC,
 550                    [Define if position independent code is enabled])
 551
 552 dnl Allow building a shared library and linking tools against it.
 553 AC_ARG_ENABLE(shared,
 554   AS_HELP_STRING([--enable-shared],
 555                  [Build a shared library and link tools against it (default is NO)]),,
 556                  enableval=default)
 557 case "$enableval" in
 558   yes) AC_SUBST(ENABLE_SHARED,[1]) ;;
 559   no)  AC_SUBST(ENABLE_SHARED,[0]) ;;
 560   default) AC_SUBST(ENABLE_SHARED,[0]) ;;
 561   *) AC_MSG_ERROR([Invalid setting for --enable-shared. Use "yes" or "no"]) ;;
 562 esac
 563
 564 dnl Allow libstdc++ is embedded in LLVM.dll.
 565 AC_ARG_ENABLE(embed-stdcxx,
 566   AS_HELP_STRING([--enable-embed-stdcxx],
 567                  [Build a shared library with embedded libstdc++ for Win32 DLL (default is YES)]),,
 568                  enableval=default)
 569 case "$enableval" in
 570   yes) AC_SUBST(ENABLE_EMBED_STDCXX,[1]) ;;
 571   no)  AC_SUBST(ENABLE_EMBED_STDCXX,[0]) ;;
 572   default) AC_SUBST(ENABLE_EMBED_STDCXX,[1]) ;;
 573   *) AC_MSG_ERROR([Invalid setting for --enable-embed-stdcxx. Use "yes" or "no"]) ;;
 574 esac
 575
 576 dnl Enable embedding timestamp information into build.
 577 AC_ARG_ENABLE(timestamps,
 578   AS_HELP_STRING([--enable-timestamps],
 579                  [Enable embedding timestamp information in build (default is YES)]),,
 580                  enableval=default)
 581 case "$enableval" in
 582   yes) AC_SUBST(ENABLE_TIMESTAMPS,[1]) ;;
 583   no)  AC_SUBST(ENABLE_TIMESTAMPS,[0]) ;;
 584   default) AC_SUBST(ENABLE_TIMESTAMPS,[1]) ;;
 585   *) AC_MSG_ERROR([Invalid setting for --enable-timestamps. Use "yes" or "no"]) ;;
 586 esac
 587 AC_DEFINE_UNQUOTED([ENABLE_TIMESTAMPS],$ENABLE_TIMESTAMPS,
 588                    [Define if timestamp information (e.g., __DATE___) is allowed])
 589
 590 dnl Allow specific targets to be specified for building (or not)
 591 TARGETS_TO_BUILD=""
 592 AC_ARG_ENABLE([targets],AS_HELP_STRING([--enable-targets],
 593     [Build specific host targets: all or target1,target2,... Valid targets are:
 594      host, x86, x86_64, sparc, powerpc, arm, mips, spu, hexagon,
 595      xcore, msp430, nvptx, and cpp (default=all)]),,
 596     enableval=all)
 597 if test "$enableval" = host-only ; then
 598   enableval=host
 599 fi
 600 case "$enableval" in
 601   all) TARGETS_TO_BUILD="X86 Sparc PowerPC ARM AArch64 Mips XCore MSP430 Hexagon CppBackend MBlaze NVPTX" ;;
 602   *)for a_target in `echo $enableval|sed -e 's/,/ /g' ` ; do
 603       case "$a_target" in
 604         x86)      TARGETS_TO_BUILD="X86 $TARGETS_TO_BUILD" ;;
 605         x86_64)   TARGETS_TO_BUILD="X86 $TARGETS_TO_BUILD" ;;
 606         sparc)    TARGETS_TO_BUILD="Sparc $TARGETS_TO_BUILD" ;;
 607         powerpc)  TARGETS_TO_BUILD="PowerPC $TARGETS_TO_BUILD" ;;
 608         arm)      TARGETS_TO_BUILD="ARM $TARGETS_TO_BUILD" ;;
 609         aarch64)  TARGETS_TO_BUILD="AArch64 $TARGETS_TO_BUILD" ;;
 610         mips)     TARGETS_TO_BUILD="Mips $TARGETS_TO_BUILD" ;;
 611         xcore)    TARGETS_TO_BUILD="XCore $TARGETS_TO_BUILD" ;;
 612         msp430)   TARGETS_TO_BUILD="MSP430 $TARGETS_TO_BUILD" ;;
 613         hexagon)  TARGETS_TO_BUILD="Hexagon $TARGETS_TO_BUILD" ;;
 614         cpp)      TARGETS_TO_BUILD="CppBackend $TARGETS_TO_BUILD" ;;
 615         mblaze)   TARGETS_TO_BUILD="MBlaze $TARGETS_TO_BUILD" ;;
 616         nvptx)    TARGETS_TO_BUILD="NVPTX $TARGETS_TO_BUILD" ;;
 617         host) case "$llvm_cv_target_arch" in
 618             x86)         TARGETS_TO_BUILD="X86 $TARGETS_TO_BUILD" ;;
 619             x86_64)      TARGETS_TO_BUILD="X86 $TARGETS_TO_BUILD" ;;
 620             Sparc)       TARGETS_TO_BUILD="Sparc $TARGETS_TO_BUILD" ;;
 621             PowerPC)     TARGETS_TO_BUILD="PowerPC $TARGETS_TO_BUILD" ;;
 622             ARM)         TARGETS_TO_BUILD="ARM $TARGETS_TO_BUILD" ;;
 623             AArch64)     TARGETS_TO_BUILD="AArch64 $TARGETS_TO_BUILD" ;;
 624             Mips)        TARGETS_TO_BUILD="Mips $TARGETS_TO_BUILD" ;;
 625             MBlaze)      TARGETS_TO_BUILD="MBlaze $TARGETS_TO_BUILD" ;;
 626             XCore)       TARGETS_TO_BUILD="XCore $TARGETS_TO_BUILD" ;;
 627             MSP430)      TARGETS_TO_BUILD="MSP430 $TARGETS_TO_BUILD" ;;
 628             Hexagon)     TARGETS_TO_BUILD="Hexagon $TARGETS_TO_BUILD" ;;
 629             NVPTX)       TARGETS_TO_BUILD="NVPTX $TARGETS_TO_BUILD" ;;
 630             *)       AC_MSG_ERROR([Can not set target to build]) ;;
 631           esac ;;
 632         *) AC_MSG_ERROR([Unrecognized target $a_target]) ;;
 633       esac
 634   done
 635   ;;
 636 esac
 637 AC_SUBST(TARGETS_TO_BUILD,$TARGETS_TO_BUILD)
 638
 639 # Determine whether we are building LLVM support for the native architecture.
 640 # If so, define LLVM_NATIVE_ARCH to that LLVM target.
 641 for a_target in $TARGETS_TO_BUILD; do
 642   if test "$a_target" = "$LLVM_NATIVE_ARCH"; then
 643     AC_DEFINE_UNQUOTED(LLVM_NATIVE_ARCH, $LLVM_NATIVE_ARCH,
 644       [LLVM architecture name for the native architecture, if available])
 645     LLVM_NATIVE_TARGET="LLVMInitialize${LLVM_NATIVE_ARCH}Target"
 646     LLVM_NATIVE_TARGETINFO="LLVMInitialize${LLVM_NATIVE_ARCH}TargetInfo"
 647     LLVM_NATIVE_TARGETMC="LLVMInitialize${LLVM_NATIVE_ARCH}TargetMC"
 648     LLVM_NATIVE_ASMPRINTER="LLVMInitialize${LLVM_NATIVE_ARCH}AsmPrinter"
 649     if test -f ${srcdir}/lib/Target/${LLVM_NATIVE_ARCH}/AsmParser/Makefile ; then
 650       LLVM_NATIVE_ASMPARSER="LLVMInitialize${LLVM_NATIVE_ARCH}AsmParser"
 651     fi
 652     if test -f ${srcdir}/lib/Target/${LLVM_NATIVE_ARCH}/Disassembler/Makefile ; then
 653       LLVM_NATIVE_DISASSEMBLER="LLVMInitialize${LLVM_NATIVE_ARCH}Disassembler"
 654     fi
 655     AC_DEFINE_UNQUOTED(LLVM_NATIVE_TARGET, $LLVM_NATIVE_TARGET,
 656       [LLVM name for the native Target init function, if available])
 657     AC_DEFINE_UNQUOTED(LLVM_NATIVE_TARGETINFO, $LLVM_NATIVE_TARGETINFO,
 658       [LLVM name for the native TargetInfo init function, if available])
 659     AC_DEFINE_UNQUOTED(LLVM_NATIVE_TARGETMC, $LLVM_NATIVE_TARGETMC,
 660       [LLVM name for the native target MC init function, if available])
 661     AC_DEFINE_UNQUOTED(LLVM_NATIVE_ASMPRINTER, $LLVM_NATIVE_ASMPRINTER,
 662       [LLVM name for the native AsmPrinter init function, if available])
 663     if test -f ${srcdir}/lib/Target/${LLVM_NATIVE_ARCH}/AsmParser/Makefile ; then
 664       AC_DEFINE_UNQUOTED(LLVM_NATIVE_ASMPARSER, $LLVM_NATIVE_ASMPARSER,
 665        [LLVM name for the native AsmParser init function, if available])
 666     fi
 667     if test -f ${srcdir}/lib/Target/${LLVM_NATIVE_ARCH}/Disassembler/Makefile ; then
 668       AC_DEFINE_UNQUOTED(LLVM_NATIVE_DISASSEMBLER, $LLVM_NATIVE_DISASSEMBLER,
 669        [LLVM name for the native Disassembler init function, if available])
 670     fi
 671   fi
 672 done
 673
 674 # Build the LLVM_TARGET and LLVM_... macros for Targets.def and the individual
 675 # target feature def files.
 676 LLVM_ENUM_TARGETS=""
 677 LLVM_ENUM_ASM_PRINTERS=""
 678 LLVM_ENUM_ASM_PARSERS=""
 679 LLVM_ENUM_DISASSEMBLERS=""
 680 for target_to_build in $TARGETS_TO_BUILD; do
 681   LLVM_ENUM_TARGETS="LLVM_TARGET($target_to_build) $LLVM_ENUM_TARGETS"
 682   if test -f ${srcdir}/lib/Target/${target_to_build}/*AsmPrinter.cpp ; then
 683     LLVM_ENUM_ASM_PRINTERS="LLVM_ASM_PRINTER($target_to_build) $LLVM_ENUM_ASM_PRINTERS";
 684   fi
 685   if test -f ${srcdir}/lib/Target/${target_to_build}/AsmParser/Makefile ; then
 686     LLVM_ENUM_ASM_PARSERS="LLVM_ASM_PARSER($target_to_build) $LLVM_ENUM_ASM_PARSERS";
 687   fi
 688   if test -f ${srcdir}/lib/Target/${target_to_build}/Disassembler/Makefile ; then
 689     LLVM_ENUM_DISASSEMBLERS="LLVM_DISASSEMBLER($target_to_build) $LLVM_ENUM_DISASSEMBLERS";
 690   fi
 691 done
 692 AC_SUBST(LLVM_ENUM_TARGETS)
 693 AC_SUBST(LLVM_ENUM_ASM_PRINTERS)
 694 AC_SUBST(LLVM_ENUM_ASM_PARSERS)
 695 AC_SUBST(LLVM_ENUM_DISASSEMBLERS)
 696
 697 dnl Override the option to use for optimized builds.
 698 AC_ARG_WITH(optimize-option,
 699   AS_HELP_STRING([--with-optimize-option],
 700                  [Select the compiler options to use for optimized builds]),,
 701                  withval=default)
 702 AC_MSG_CHECKING([optimization flags])
 703 case "$withval" in
 704   default)
 705     case "$llvm_cv_os_type" in
 706     FreeBSD) optimize_option=-O2 ;;
 707     MingW) optimize_option=-O2 ;;
 708     *)     optimize_option=-O3 ;;
 709     esac ;;
 710   *) optimize_option="$withval" ;;
 711 esac
 712 AC_SUBST(OPTIMIZE_OPTION,$optimize_option)
 713 AC_MSG_RESULT([$optimize_option])
 714
 715 dnl Specify extra build options
 716 AC_ARG_WITH(extra-options,
 717   AS_HELP_STRING([--with-extra-options],
 718                  [Specify additional options to compile LLVM with]),,
 719                  withval=default)
 720 case "$withval" in
 721   default) EXTRA_OPTIONS= ;;
 722   *) EXTRA_OPTIONS=$withval ;;
 723 esac
 724 AC_SUBST(EXTRA_OPTIONS,$EXTRA_OPTIONS)
 725
 726 dnl Specify extra linker build options
 727 AC_ARG_WITH(extra-ld-options,
 728   AS_HELP_STRING([--with-extra-ld-options],
 729                  [Specify additional options to link LLVM with]),,
 730                  withval=default)
 731 case "$withval" in
 732   default) EXTRA_LD_OPTIONS= ;;
 733   *) EXTRA_LD_OPTIONS=$withval ;;
 734 esac
 735 AC_SUBST(EXTRA_LD_OPTIONS,$EXTRA_LD_OPTIONS)
 736
 737 dnl Allow specific bindings to be specified for building (or not)
 738 AC_ARG_ENABLE([bindings],AS_HELP_STRING([--enable-bindings],
 739     [Build specific language bindings: all,auto,none,{binding-name} (default=auto)]),,
 740     enableval=default)
 741 BINDINGS_TO_BUILD=""
 742 case "$enableval" in
 743   yes | default | auto) BINDINGS_TO_BUILD="auto" ;;
 744   all ) BINDINGS_TO_BUILD="ocaml" ;;
 745   none | no) BINDINGS_TO_BUILD="" ;;
 746   *)for a_binding in `echo $enableval|sed -e 's/,/ /g' ` ; do
 747       case "$a_binding" in
 748         ocaml) BINDINGS_TO_BUILD="ocaml $BINDINGS_TO_BUILD" ;;
 749         *) AC_MSG_ERROR([Unrecognized binding $a_binding]) ;;
 750       esac
 751   done
 752   ;;
 753 esac
 754
 755 dnl Allow the ocaml libdir to be overridden. This could go in a configure
 756 dnl script for bindings/ocaml/configure, except that its auto value depends on
 757 dnl OCAMLC, which is found here to support tests.
 758 AC_ARG_WITH([ocaml-libdir],
 759   [AS_HELP_STRING([--with-ocaml-libdir],
 760     [Specify install location for ocaml bindings (default is stdlib)])],
 761   [],
 762   [withval=auto])
 763 case "$withval" in
 764   auto) with_ocaml_libdir="$withval" ;;
 765   /* | [[A-Za-z]]:[[\\/]]*) with_ocaml_libdir="$withval" ;;
 766   *) AC_MSG_ERROR([Invalid path for --with-ocaml-libdir. Provide full path]) ;;
 767 esac
 768
 769 AC_ARG_WITH(clang-resource-dir,
 770   AS_HELP_STRING([--with-clang-resource-dir],
 771     [Relative directory from the Clang binary for resource files]),,
 772     withval="")
 773 AC_DEFINE_UNQUOTED(CLANG_RESOURCE_DIR,"$withval",
 774                    [Relative directory for resource files])
 775
 776 AC_ARG_WITH(c-include-dirs,
 777   AS_HELP_STRING([--with-c-include-dirs],
 778     [Colon separated list of directories clang will search for headers]),,
 779     withval="")
 780 AC_DEFINE_UNQUOTED(C_INCLUDE_DIRS,"$withval",
 781                    [Directories clang will search for headers])
 782
 783 # Clang normally uses the system c++ headers and libraries. With this option,
 784 # clang will use the ones provided by a gcc installation instead. This option should
 785 # be passed the same value that was used with --prefix when configuring gcc.
 786 AC_ARG_WITH(gcc-toolchain,
 787   AS_HELP_STRING([--with-gcc-toolchain],
 788     [Directory where gcc is installed.]),,
 789     withval="")
 790 AC_DEFINE_UNQUOTED(GCC_INSTALL_PREFIX,"$withval",
 791                    [Directory where gcc is installed.])
 792
 793 dnl Allow linking of LLVM with GPLv3 binutils code.
 794 AC_ARG_WITH(binutils-include,
 795   AS_HELP_STRING([--with-binutils-include],
 796     [Specify path to binutils/include/ containing plugin-api.h file for gold plugin.]),,
 797   withval=default)
 798 case "$withval" in
 799   default) WITH_BINUTILS_INCDIR=default ;;
 800   /* | [[A-Za-z]]:[[\\/]]*)      WITH_BINUTILS_INCDIR=$withval ;;
 801   *) AC_MSG_ERROR([Invalid path for --with-binutils-include. Provide full path]) ;;
 802 esac
 803 if test "x$WITH_BINUTILS_INCDIR" != xdefault ; then
 804   AC_SUBST(BINUTILS_INCDIR,$WITH_BINUTILS_INCDIR)
 805   if test ! -f "$WITH_BINUTILS_INCDIR/plugin-api.h"; then
 806      echo "$WITH_BINUTILS_INCDIR/plugin-api.h"
 807      AC_MSG_ERROR([Invalid path to directory containing plugin-api.h.]);
 808   fi
 809 fi
 810
 811 dnl Specify the URL where bug reports should be submitted.
 812 AC_ARG_WITH(bug-report-url,
 813   AS_HELP_STRING([--with-bug-report-url],
 814     [Specify the URL where bug reports should be submitted (default=http://llvm.org/bugs/)]),,
 815     withval="http://llvm.org/bugs/")
 816 AC_DEFINE_UNQUOTED(BUG_REPORT_URL,"$withval",
 817                    [Bug report URL.])
 818
 819 dnl --enable-libffi : check whether the user wants to turn off libffi:
 820 AC_ARG_ENABLE(libffi,AS_HELP_STRING(
 821   --enable-libffi,[Check for the presence of libffi (default is NO)]),
 822   [case "$enableval" in
 823     yes) llvm_cv_enable_libffi="yes" ;;
 824     no)  llvm_cv_enable_libffi="no"  ;;
 825     *) AC_MSG_ERROR([Invalid setting for --enable-libffi. Use "yes" or "no"]) ;;
 826   esac],
 827   llvm_cv_enable_libffi=no)
 828
 829 dnl===-----------------------------------------------------------------------===
 830 dnl===
 831 dnl=== SECTION 4: Check for programs we need and that they are the right version
 832 dnl===
 833 dnl===-----------------------------------------------------------------------===
 834
 835 AC_PROG_NM
 836 AC_SUBST(NM)
 837
 838 dnl Check for the tools that the makefiles require
 839 AC_CHECK_GNU_MAKE
 840 AC_PROG_LN_S
 841 AC_PATH_PROG(CMP, [cmp], [cmp])
 842 AC_PATH_PROG(CP, [cp], [cp])
 843 AC_PATH_PROG(DATE, [date], [date])
 844 AC_PATH_PROG(FIND, [find], [find])
 845 AC_PATH_PROG(GREP, [grep], [grep])
 846 AC_PATH_PROG(MKDIR,[mkdir],[mkdir])
 847 AC_PATH_PROG(MV,   [mv],   [mv])
 848 AC_PROG_RANLIB
 849 AC_CHECK_TOOL(AR, ar, false)
 850 AC_PATH_PROG(RM,   [rm],   [rm])
 851 AC_PATH_PROG(SED,  [sed],  [sed])
 852 AC_PATH_PROG(TAR,  [tar],  [gtar])
 853 AC_PATH_PROG(BINPWD,[pwd],  [pwd])
 854
 855 dnl Looking for misc. graph plotting software
 856 AC_PATH_PROG(GRAPHVIZ, [Graphviz], [echo Graphviz])
 857 if test "$GRAPHVIZ" != "echo Graphviz" ; then
 858   AC_DEFINE([HAVE_GRAPHVIZ],[1],[Define if the Graphviz program is available])
 859   dnl If we're targeting for mingw we should emit windows paths, not msys
 860   if test "$llvm_cv_os_type" = "MingW" ; then
 861     GRAPHVIZ=`echo $GRAPHVIZ | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
 862   fi
 863   AC_DEFINE_UNQUOTED([LLVM_PATH_GRAPHVIZ],"$GRAPHVIZ${EXEEXT}",
 864    [Define to path to Graphviz program if found or 'echo Graphviz' otherwise])
 865 fi
 866 AC_PATH_PROG(DOT, [dot], [echo dot])
 867 if test "$DOT" != "echo dot" ; then
 868   AC_DEFINE([HAVE_DOT],[1],[Define if the dot program is available])
 869   dnl If we're targeting for mingw we should emit windows paths, not msys
 870   if test "$llvm_cv_os_type" = "MingW" ; then
 871     DOT=`echo $DOT | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
 872   fi
 873   AC_DEFINE_UNQUOTED([LLVM_PATH_DOT],"$DOT${EXEEXT}",
 874    [Define to path to dot program if found or 'echo dot' otherwise])
 875 fi
 876 AC_PATH_PROG(FDP, [fdp], [echo fdp])
 877 if test "$FDP" != "echo fdp" ; then
 878   AC_DEFINE([HAVE_FDP],[1],[Define if the neat program is available])
 879   dnl If we're targeting for mingw we should emit windows paths, not msys
 880   if test "$llvm_cv_os_type" = "MingW" ; then
 881     FDP=`echo $FDP | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
 882   fi
 883   AC_DEFINE_UNQUOTED([LLVM_PATH_FDP],"$FDP${EXEEXT}",
 884    [Define to path to fdp program if found or 'echo fdp' otherwise])
 885 fi
 886 AC_PATH_PROG(NEATO, [neato], [echo neato])
 887 if test "$NEATO" != "echo neato" ; then
 888   AC_DEFINE([HAVE_NEATO],[1],[Define if the neat program is available])
 889   dnl If we're targeting for mingw we should emit windows paths, not msys
 890   if test "$llvm_cv_os_type" = "MingW" ; then
 891     NEATO=`echo $NEATO | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
 892   fi
 893   AC_DEFINE_UNQUOTED([LLVM_PATH_NEATO],"$NEATO${EXEEXT}",
 894    [Define to path to neato program if found or 'echo neato' otherwise])
 895 fi
 896 AC_PATH_PROG(TWOPI, [twopi], [echo twopi])
 897 if test "$TWOPI" != "echo twopi" ; then
 898   AC_DEFINE([HAVE_TWOPI],[1],[Define if the neat program is available])
 899   dnl If we're targeting for mingw we should emit windows paths, not msys
 900   if test "$llvm_cv_os_type" = "MingW" ; then
 901     TWOPI=`echo $TWOPI | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
 902   fi
 903   AC_DEFINE_UNQUOTED([LLVM_PATH_TWOPI],"$TWOPI${EXEEXT}",
 904    [Define to path to twopi program if found or 'echo twopi' otherwise])
 905 fi
 906 AC_PATH_PROG(CIRCO, [circo], [echo circo])
 907 if test "$CIRCO" != "echo circo" ; then
 908   AC_DEFINE([HAVE_CIRCO],[1],[Define if the neat program is available])
 909   dnl If we're targeting for mingw we should emit windows paths, not msys
 910   if test "$llvm_cv_os_type" = "MingW" ; then
 911     CIRCO=`echo $CIRCO | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
 912   fi
 913   AC_DEFINE_UNQUOTED([LLVM_PATH_CIRCO],"$CIRCO${EXEEXT}",
 914    [Define to path to circo program if found or 'echo circo' otherwise])
 915 fi
 916 AC_PATH_PROGS(GV, [gv gsview32], [echo gv])
 917 if test "$GV" != "echo gv" ; then
 918   AC_DEFINE([HAVE_GV],[1],[Define if the gv program is available])
 919   dnl If we're targeting for mingw we should emit windows paths, not msys
 920   if test "$llvm_cv_os_type" = "MingW" ; then
 921     GV=`echo $GV | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
 922   fi
 923   AC_DEFINE_UNQUOTED([LLVM_PATH_GV],"$GV${EXEEXT}",
 924    [Define to path to gv program if found or 'echo gv' otherwise])
 925 fi
 926 AC_PATH_PROG(DOTTY, [dotty], [echo dotty])
 927 if test "$DOTTY" != "echo dotty" ; then
 928   AC_DEFINE([HAVE_DOTTY],[1],[Define if the dotty program is available])
 929   dnl If we're targeting for mingw we should emit windows paths, not msys
 930   if test "$llvm_cv_os_type" = "MingW" ; then
 931     DOTTY=`echo $DOTTY | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
 932   fi
 933   AC_DEFINE_UNQUOTED([LLVM_PATH_DOTTY],"$DOTTY${EXEEXT}",
 934    [Define to path to dotty program if found or 'echo dotty' otherwise])
 935 fi
 936 AC_PATH_PROG(XDOT_PY, [xdot.py], [echo xdot.py])
 937 if test "$XDOT_PY" != "echo xdot.py" ; then
 938   AC_DEFINE([HAVE_XDOT_PY],[1],[Define if the xdot.py program is available])
 939   dnl If we're targeting for mingw we should emit windows paths, not msys
 940   if test "$llvm_cv_os_type" = "MingW" ; then
 941     XDOT_PY=`echo $XDOT_PY | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
 942   fi
 943   AC_DEFINE_UNQUOTED([LLVM_PATH_XDOT_PY],"$XDOT_PY${EXEEXT}",
 944    [Define to path to xdot.py program if found or 'echo xdot.py' otherwise])
 945 fi
 946
 947 dnl Find the install program
 948 AC_PROG_INSTALL
 949 dnl Prepend src dir to install path dir if it's a relative path
 950 dnl This is a hack for installs that take place in something other
 951 dnl than the top level.
 952 case "$INSTALL" in
 953  [[\\/$]]* | ?:[[\\/]]* ) ;;
 954  *)  INSTALL="\\\$(TOPSRCDIR)/$INSTALL" ;;
 955 esac
 956
 957 dnl Checks for documentation and testing tools that we can do without. If these
 958 dnl are not found then they are set to "true" which always succeeds but does
 959 dnl nothing. This just lets the build output show that we could have done
 960 dnl something if the tool was available.
 961 AC_PATH_PROG(BZIP2, [bzip2])
 962 AC_PATH_PROG(CAT, [cat])
 963 AC_PATH_PROG(DOXYGEN, [doxygen])
 964 AC_PATH_PROG(GROFF, [groff])
 965 AC_PATH_PROG(GZIPBIN, [gzip])
 966 AC_PATH_PROG(POD2HTML, [pod2html])
 967 AC_PATH_PROG(POD2MAN, [pod2man])
 968 AC_PATH_PROG(PDFROFF, [pdfroff])
 969 AC_PATH_PROG(RUNTEST, [runtest])
 970 DJ_AC_PATH_TCLSH
 971 AC_PATH_PROG(ZIP, [zip])
 972 AC_PATH_PROGS(OCAMLC, [ocamlc])
 973 AC_PATH_PROGS(OCAMLOPT, [ocamlopt])
 974 AC_PATH_PROGS(OCAMLDEP, [ocamldep])
 975 AC_PATH_PROGS(OCAMLDOC, [ocamldoc])
 976 AC_PATH_PROGS(GAS, [gas as])
 977
 978 dnl Get the version of the linker in use.
 979 AC_LINK_GET_VERSION
 980
 981 dnl Determine whether the linker supports the -R option.
 982 AC_LINK_USE_R
 983
 984 dnl Determine whether the linker supports the -export-dynamic option.
 985 AC_LINK_EXPORT_DYNAMIC
 986
 987 dnl Determine whether the linker supports the --version-script option.
 988 AC_LINK_VERSION_SCRIPT
 989
 990 dnl Check for libtool and the library that has dlopen function (which must come
 991 dnl before the AC_PROG_LIBTOOL check in order to enable dlopening libraries with
 992 dnl libtool).
 993 AC_LIBTOOL_DLOPEN
 994 AC_LIB_LTDL
 995
 996 AC_MSG_CHECKING([tool compatibility])
 997
 998 dnl Ensure that compilation tools are GCC or a GNU compatible compiler such as
 999 dnl ICC; we use GCC specific options in the makefiles so the compiler needs
1000 dnl to support those options.
1001 dnl "icc" emits gcc signatures
1002 dnl "icc -no-gcc" emits no gcc signature BUT is still compatible
1003 ICC=no
1004 IXX=no
1005 case $CC in
1006   icc*|icpc*)
1007     ICC=yes
1008     IXX=yes
1009     ;;
1010    *)
1011     ;;
1012 esac
1013
1014 if test "$GCC" != "yes" && test "$ICC" != "yes"
1015 then
1016   AC_MSG_ERROR([gcc|icc required but not found])
1017 fi
1018
1019 dnl Ensure that compilation tools are compatible with GCC extensions
1020 if test "$GXX" != "yes" && test "$IXX" != "yes"
1021 then
1022   AC_MSG_ERROR([g++|clang++|icc required but not found])
1023 fi
1024
1025 dnl Verify that GCC is version 3.0 or higher
1026 if test "$GCC" = "yes"
1027 then
1028   AC_COMPILE_IFELSE([[#if !defined(__GNUC__) || __GNUC__ < 3
1029 #error Unsupported GCC version
1030 #endif
1031 ]], [], [AC_MSG_ERROR([gcc 3.x required, but you have a lower version])])
1032 fi
1033
1034 dnl Check for GNU Make.  We use its extensions, so don't build without it
1035 if test -z "$llvm_cv_gnu_make_command"
1036 then
1037   AC_MSG_ERROR([GNU Make required but not found])
1038 fi
1039
1040 dnl Tool compatibility is okay if we make it here.
1041 AC_MSG_RESULT([ok])
1042
1043 dnl Check optional compiler flags.
1044 AC_MSG_CHECKING([optional compiler flags])
1045 CXX_FLAG_CHECK(NO_VARIADIC_MACROS, [-Wno-variadic-macros])
1046 CXX_FLAG_CHECK(NO_MISSING_FIELD_INITIALIZERS, [-Wno-missing-field-initializers])
1047 CXX_FLAG_CHECK(COVERED_SWITCH_DEFAULT, [-Wcovered-switch-default])
1048 AC_MSG_RESULT([$NO_VARIADIC_MACROS $NO_MISSING_FIELD_INITIALIZERS $COVERED_SWITCH_DEFAULT])
1049
1050 dnl===-----------------------------------------------------------------------===
1051 dnl===
1052 dnl=== SECTION 5: Check for libraries
1053 dnl===
1054 dnl===-----------------------------------------------------------------------===
1055
1056 AC_CHECK_LIB(m,sin)
1057 if test "$llvm_cv_os_type" = "MingW" ; then
1058   AC_CHECK_LIB(imagehlp, main)
1059   AC_CHECK_LIB(psapi, main)
1060 fi
1061
1062 dnl dlopen() is required for plugin support.
1063 AC_SEARCH_LIBS(dlopen,dl,AC_DEFINE([HAVE_DLOPEN],[1],
1064                [Define if dlopen() is available on this platform.]),
1065                AC_MSG_WARN([dlopen() not found - disabling plugin support]))
1066
1067 dnl libffi is optional; used to call external functions from the interpreter
1068 if test "$llvm_cv_enable_libffi" = "yes" ; then
1069   AC_SEARCH_LIBS(ffi_call,ffi,AC_DEFINE([HAVE_FFI_CALL],[1],
1070                  [Define if libffi is available on this platform.]),
1071                  AC_MSG_ERROR([libffi not found - configure without --enable-libffi to compile without it]))
1072 fi
1073
1074 dnl mallinfo is optional; the code can compile (minus features) without it
1075 AC_SEARCH_LIBS(mallinfo,malloc,AC_DEFINE([HAVE_MALLINFO],[1],
1076                [Define if mallinfo() is available on this platform.]))
1077
1078 dnl pthread locking functions are optional - but llvm will not be thread-safe
1079 dnl without locks.
1080 if test "$ENABLE_THREADS" -eq 1 && test "$ENABLE_PTHREADS" -eq 1 ; then
1081   AC_CHECK_LIB(pthread, pthread_mutex_init)
1082   AC_SEARCH_LIBS(pthread_mutex_lock,pthread,
1083                  AC_DEFINE([HAVE_PTHREAD_MUTEX_LOCK],[1],
1084                            [Have pthread_mutex_lock]))
1085   AC_SEARCH_LIBS(pthread_rwlock_init,pthread,
1086                  AC_DEFINE([HAVE_PTHREAD_RWLOCK_INIT],[1],
1087                  [Have pthread_rwlock_init]))
1088   AC_SEARCH_LIBS(pthread_getspecific,pthread,
1089                  AC_DEFINE([HAVE_PTHREAD_GETSPECIFIC],[1],
1090                  [Have pthread_getspecific]))
1091 fi
1092
1093 dnl Allow extra x86-disassembler library
1094 AC_ARG_WITH(udis86,
1095   AS_HELP_STRING([--with-udis86=<path>],
1096     [Use udis86 external x86 disassembler library]),
1097     [
1098       AC_SUBST(USE_UDIS86, [1])
1099       case "$withval" in
1100         /usr/lib|yes) ;;
1101         *) LDFLAGS="$LDFLAGS -L${withval}" ;;
1102       esac
1103       AC_CHECK_LIB(udis86, ud_init, [], [
1104         echo "Error! You need to have libudis86 around."
1105         exit -1
1106       ])
1107     ],
1108     AC_SUBST(USE_UDIS86, [0]))
1109 AC_DEFINE_UNQUOTED([USE_UDIS86],$USE_UDIS86,
1110                    [Define if use udis86 library])
1111
1112 dnl Allow OProfile support for JIT output.
1113 AC_ARG_WITH(oprofile,
1114   AS_HELP_STRING([--with-oprofile=<prefix>],
1115     [Tell OProfile >= 0.9.4 how to symbolize JIT output]),
1116     [
1117       AC_SUBST(USE_OPROFILE, [1])
1118       case "$withval" in
1119         /usr|yes) llvm_cv_oppath=/usr/lib/oprofile ;;
1120         no) llvm_cv_oppath=
1121             AC_SUBST(USE_OPROFILE, [0]) ;;
1122         *) llvm_cv_oppath="${withval}/lib/oprofile"
1123            CPPFLAGS="-I${withval}/include";;
1124       esac
1125       if test -n "$llvm_cv_oppath" ; then
1126         LIBS="$LIBS -L${llvm_cv_oppath} -Wl,-rpath,${llvm_cv_oppath}"
1127         dnl Work around http://bugs.debian.org/cgi-bin/bugreport.cgi?bug=537744:
1128         dnl libbfd is not included properly in libopagent in some Debian
1129         dnl versions.  If libbfd isn't found at all, we assume opagent works
1130         dnl anyway.
1131         AC_SEARCH_LIBS(bfd_init, bfd, [], [])
1132         AC_SEARCH_LIBS(op_open_agent, opagent, [], [
1133           echo "Error! You need to have libopagent around."
1134           exit -1
1135         ])
1136         AC_CHECK_HEADER([opagent.h], [], [
1137           echo "Error! You need to have opagent.h around."
1138           exit -1
1139           ])
1140       fi
1141     ],
1142     [
1143       AC_SUBST(USE_OPROFILE, [0])
1144     ])
1145 AC_DEFINE_UNQUOTED([USE_OPROFILE],$USE_OPROFILE,
1146                    [Define if we have the oprofile JIT-support library])
1147
1148 dnl===-----------------------------------------------------------------------===
1149 dnl===
1150 dnl=== SECTION 6: Check for header files
1151 dnl===
1152 dnl===-----------------------------------------------------------------------===
1153
1154 dnl First, use autoconf provided macros for specific headers that we need
1155 dnl We don't check for ancient stuff or things that are guaranteed to be there
1156 dnl by the C++ standard. We always use the <cfoo> versions of <foo.h> C headers.
1157 dnl Generally we're looking for POSIX headers.
1158 AC_HEADER_DIRENT
1159 AC_HEADER_MMAP_ANONYMOUS
1160 AC_HEADER_STAT
1161 AC_HEADER_SYS_WAIT
1162 AC_HEADER_TIME
1163
1164 AC_CHECK_HEADERS([dlfcn.h execinfo.h fcntl.h inttypes.h limits.h link.h])
1165 AC_CHECK_HEADERS([malloc.h setjmp.h signal.h stdint.h termios.h unistd.h])
1166 AC_CHECK_HEADERS([utime.h windows.h])
1167 AC_CHECK_HEADERS([sys/mman.h sys/param.h sys/resource.h sys/time.h sys/uio.h])
1168 AC_CHECK_HEADERS([sys/types.h sys/ioctl.h malloc/malloc.h mach/mach.h])
1169 AC_CHECK_HEADERS([valgrind/valgrind.h])
1170 AC_CHECK_HEADERS([fenv.h])
1171 if test "$ENABLE_THREADS" -eq 1 && test "$ENABLE_PTHREADS" -eq 1 ; then
1172   AC_CHECK_HEADERS(pthread.h,
1173                    AC_SUBST(HAVE_PTHREAD, 1),
1174                    AC_SUBST(HAVE_PTHREAD, 0))
1175 else
1176   AC_SUBST(HAVE_PTHREAD, 0)
1177 fi
1178
1179 dnl Try to find ffi.h.
1180 if test "$llvm_cv_enable_libffi" = "yes" ; then
1181   AC_CHECK_HEADERS([ffi.h ffi/ffi.h])
1182 fi
1183
1184 dnl Try to find Darwin specific crash reporting libraries.
1185 AC_CHECK_HEADERS([CrashReporterClient.h])
1186
1187 dnl Try to find Darwin specific crash reporting global.
1188 AC_MSG_CHECKING([__crashreporter_info__])
1189 AC_LINK_IFELSE(
1190   AC_LANG_SOURCE(
1191     [[extern const char *__crashreporter_info__;
1192       int main() {
1193         __crashreporter_info__ = "test";
1194         return 0;
1195       }
1196     ]]),
1197   AC_MSG_RESULT(yes)
1198   AC_DEFINE(HAVE_CRASHREPORTER_INFO, 1, Can use __crashreporter_info__),
1199   AC_MSG_RESULT(no)
1200   AC_DEFINE(HAVE_CRASHREPORTER_INFO, 0,
1201             Define if __crashreporter_info__ exists.))
1202
1203 dnl===-----------------------------------------------------------------------===
1204 dnl===
1205 dnl=== SECTION 7: Check for types and structures
1206 dnl===
1207 dnl===-----------------------------------------------------------------------===
1208
1209 AC_HUGE_VAL_CHECK
1210 AC_TYPE_PID_T
1211 AC_TYPE_SIZE_T
1212 AC_DEFINE_UNQUOTED([RETSIGTYPE],[void],[Define as the return type of signal handlers (`int' or `void').])
1213 AC_STRUCT_TM
1214 AC_CHECK_TYPES([int64_t],,AC_MSG_ERROR([Type int64_t required but not found]))
1215 AC_CHECK_TYPES([uint64_t],,
1216          AC_CHECK_TYPES([u_int64_t],,
1217          AC_MSG_ERROR([Type uint64_t or u_int64_t required but not found])))
1218
1219 dnl===-----------------------------------------------------------------------===
1220 dnl===
1221 dnl=== SECTION 8: Check for specific functions needed
1222 dnl===
1223 dnl===-----------------------------------------------------------------------===
1224
1225 AC_CHECK_FUNCS([backtrace ceilf floorf roundf rintf nearbyintf getcwd ])
1226 AC_CHECK_FUNCS([powf fmodf strtof round ])
1227 AC_CHECK_FUNCS([getpagesize getrusage getrlimit setrlimit gettimeofday ])
1228 AC_CHECK_FUNCS([isatty mkdtemp mkstemp ])
1229 AC_CHECK_FUNCS([mktemp posix_spawn realpath sbrk setrlimit strdup ])
1230 AC_CHECK_FUNCS([strerror strerror_r setenv ])
1231 AC_CHECK_FUNCS([strtoll strtoq sysconf malloc_zone_statistics ])
1232 AC_CHECK_FUNCS([setjmp longjmp sigsetjmp siglongjmp writev])
1233 AC_C_PRINTF_A
1234 AC_FUNC_RAND48
1235
1236 dnl Check the declaration "Secure API" on Windows environments.
1237 AC_CHECK_DECLS([strerror_s])
1238
1239 dnl Check symbols in libgcc.a for JIT on Mingw.
1240 if test "$llvm_cv_os_type" = "MingW" ; then
1241   AC_CHECK_LIB(gcc,_alloca,AC_DEFINE([HAVE__ALLOCA],[1],[Have host's _alloca]))
1242   AC_CHECK_LIB(gcc,__alloca,AC_DEFINE([HAVE___ALLOCA],[1],[Have host's __alloca]))
1243   AC_CHECK_LIB(gcc,__chkstk,AC_DEFINE([HAVE___CHKSTK],[1],[Have host's __chkstk]))
1244   AC_CHECK_LIB(gcc,___chkstk,AC_DEFINE([HAVE____CHKSTK],[1],[Have host's ___chkstk]))
1245
1246   AC_CHECK_LIB(gcc,__ashldi3,AC_DEFINE([HAVE___ASHLDI3],[1],[Have host's __ashldi3]))
1247   AC_CHECK_LIB(gcc,__ashrdi3,AC_DEFINE([HAVE___ASHRDI3],[1],[Have host's __ashrdi3]))
1248   AC_CHECK_LIB(gcc,__divdi3,AC_DEFINE([HAVE___DIVDI3],[1],[Have host's __divdi3]))
1249   AC_CHECK_LIB(gcc,__fixdfdi,AC_DEFINE([HAVE___FIXDFDI],[1],[Have host's __fixdfdi]))
1250   AC_CHECK_LIB(gcc,__fixsfdi,AC_DEFINE([HAVE___FIXSFDI],[1],[Have host's __fixsfdi]))
1251   AC_CHECK_LIB(gcc,__floatdidf,AC_DEFINE([HAVE___FLOATDIDF],[1],[Have host's __floatdidf]))
1252   AC_CHECK_LIB(gcc,__lshrdi3,AC_DEFINE([HAVE___LSHRDI3],[1],[Have host's __lshrdi3]))
1253   AC_CHECK_LIB(gcc,__moddi3,AC_DEFINE([HAVE___MODDI3],[1],[Have host's __moddi3]))
1254   AC_CHECK_LIB(gcc,__udivdi3,AC_DEFINE([HAVE___UDIVDI3],[1],[Have host's __udivdi3]))
1255   AC_CHECK_LIB(gcc,__umoddi3,AC_DEFINE([HAVE___UMODDI3],[1],[Have host's __umoddi3]))
1256
1257   AC_CHECK_LIB(gcc,__main,AC_DEFINE([HAVE___MAIN],[1],[Have host's __main]))
1258   AC_CHECK_LIB(gcc,__cmpdi2,AC_DEFINE([HAVE___CMPDI2],[1],[Have host's __cmpdi2]))
1259 fi
1260
1261 dnl Check Win32 API EnumerateLoadedModules.
1262 if test "$llvm_cv_os_type" = "MingW" ; then
1263   AC_MSG_CHECKING([whether EnumerateLoadedModules() accepts new decl])
1264   AC_COMPILE_IFELSE([[#include <windows.h>
1265 #include <imagehlp.h>
1266 extern void foo(PENUMLOADED_MODULES_CALLBACK);
1267 extern void foo(BOOL(CALLBACK*)(PCSTR,ULONG_PTR,ULONG,PVOID));]],
1268 [
1269   AC_MSG_RESULT([yes])
1270   llvm_cv_win32_elmcb_pcstr="PCSTR"
1271 ],
1272 [
1273   AC_MSG_RESULT([no])
1274   llvm_cv_win32_elmcb_pcstr="PSTR"
1275 ])
1276   AC_DEFINE_UNQUOTED([WIN32_ELMCB_PCSTR],$llvm_cv_win32_elmcb_pcstr,[Type of 1st arg on ELM Callback])
1277 fi
1278
1279 dnl Check for variations in the Standard C++ library and STL. These macros are
1280 dnl provided by LLVM in the autoconf/m4 directory.
1281 AC_FUNC_ISNAN
1282 AC_FUNC_ISINF
1283
1284 dnl Check for mmap support.We also need to know if /dev/zero is required to
1285 dnl be opened for allocating RWX memory.
1286 dnl Make sure we aren't attempting to configure for an unknown system
1287 if test "$llvm_cv_platform_type" = "Unix" ; then
1288   AC_FUNC_MMAP
1289   AC_FUNC_MMAP_FILE
1290   AC_NEED_DEV_ZERO_FOR_MMAP
1291
1292   if test "$ac_cv_func_mmap_fixed_mapped" = "no"
1293   then
1294     AC_MSG_WARN([mmap() of a fixed address required but not supported])
1295   fi
1296   if test "$ac_cv_func_mmap_file" = "no"
1297   then
1298     AC_MSG_WARN([mmap() of files required but not found])
1299   fi
1300 fi
1301
1302 dnl atomic builtins are required for threading support.
1303 AC_MSG_CHECKING(for GCC atomic builtins)
1304 dnl Since we'll be using these atomic builtins in C++ files we should test
1305 dnl the C++ compiler.
1306 AC_LANG_PUSH([C++])
1307 AC_LINK_IFELSE(
1308   AC_LANG_SOURCE(
1309     [[int main() {
1310         volatile unsigned long val = 1;
1311         __sync_synchronize();
1312         __sync_val_compare_and_swap(&val, 1, 0);
1313         __sync_add_and_fetch(&val, 1);
1314         __sync_sub_and_fetch(&val, 1);
1315         return 0;
1316       }
1317     ]]),
1318   AC_LANG_POP([C++])
1319   AC_MSG_RESULT(yes)
1320   AC_DEFINE(LLVM_HAS_ATOMICS, 1, Has gcc/MSVC atomic intrinsics),
1321   AC_MSG_RESULT(no)
1322   AC_DEFINE(LLVM_HAS_ATOMICS, 0, Has gcc/MSVC atomic intrinsics)
1323   AC_MSG_WARN([LLVM will be built thread-unsafe because atomic builtins are missing]))
1324
1325 dnl===-----------------------------------------------------------------------===
1326 dnl===
1327 dnl=== SECTION 9: Additional checks, variables, etc.
1328 dnl===
1329 dnl===-----------------------------------------------------------------------===
1330
1331 dnl Handle 32-bit linux systems running a 64-bit kernel.
1332 dnl This has to come after section 4 because it invokes the compiler.
1333 if test "$llvm_cv_os_type" = "Linux" -a "$llvm_cv_target_arch" = "x86_64" ; then
1334   AC_IS_LINUX_MIXED
1335   if test "$llvm_cv_linux_mixed" = "yes"; then
1336     llvm_cv_target_arch="x86"
1337     ARCH="x86"
1338   fi
1339 fi
1340
1341 dnl Check whether __dso_handle is present
1342 AC_CHECK_FUNCS([__dso_handle])
1343
1344 dnl Propagate the shared library extension that the libltdl checks did to
1345 dnl the Makefiles so we can use it there too
1346 AC_SUBST(SHLIBEXT,$libltdl_cv_shlibext)
1347
1348 dnl Propagate the run-time library path variable that the libltdl
1349 dnl checks found to the Makefiles so we can use it there too
1350 AC_SUBST(SHLIBPATH_VAR,$libltdl_cv_shlibpath_var)
1351
1352 # Translate the various configuration directories and other basic
1353 # information into substitutions that will end up in Makefile.config.in
1354 # that these configured values can be used by the makefiles
1355 if test "${prefix}" = "NONE" ; then
1356   prefix="/usr/local"
1357 fi
1358 eval LLVM_PREFIX="${prefix}";
1359 eval LLVM_BINDIR="${prefix}/bin";
1360 eval LLVM_LIBDIR="${prefix}/lib";
1361 eval LLVM_DATADIR="${prefix}/share/llvm";
1362 eval LLVM_DOCSDIR="${prefix}/share/doc/llvm";
1363 eval LLVM_ETCDIR="${prefix}/etc/llvm";
1364 eval LLVM_INCLUDEDIR="${prefix}/include";
1365 eval LLVM_INFODIR="${prefix}/info";
1366 eval LLVM_MANDIR="${prefix}/man";
1367 LLVM_CONFIGTIME=`date`
1368 AC_SUBST(LLVM_PREFIX)
1369 AC_SUBST(LLVM_BINDIR)
1370 AC_SUBST(LLVM_LIBDIR)
1371 AC_SUBST(LLVM_DATADIR)
1372 AC_SUBST(LLVM_DOCSDIR)
1373 AC_SUBST(LLVM_ETCDIR)
1374 AC_SUBST(LLVM_INCLUDEDIR)
1375 AC_SUBST(LLVM_INFODIR)
1376 AC_SUBST(LLVM_MANDIR)
1377 AC_SUBST(LLVM_CONFIGTIME)
1378
1379 # Place the various directores into the config.h file as #defines so that we
1380 # can know about the installation paths within LLVM.
1381 AC_DEFINE_UNQUOTED(LLVM_PREFIX,"$LLVM_PREFIX",
1382                    [Installation prefix directory])
1383 AC_DEFINE_UNQUOTED(LLVM_BINDIR, "$LLVM_BINDIR",
1384                    [Installation directory for binary executables])
1385 AC_DEFINE_UNQUOTED(LLVM_LIBDIR, "$LLVM_LIBDIR",
1386                    [Installation directory for libraries])
1387 AC_DEFINE_UNQUOTED(LLVM_DATADIR, "$LLVM_DATADIR",
1388                    [Installation directory for data files])
1389 AC_DEFINE_UNQUOTED(LLVM_DOCSDIR, "$LLVM_DOCSDIR",
1390                    [Installation directory for documentation])
1391 AC_DEFINE_UNQUOTED(LLVM_ETCDIR, "$LLVM_ETCDIR",
1392                    [Installation directory for config files])
1393 AC_DEFINE_UNQUOTED(LLVM_INCLUDEDIR, "$LLVM_INCLUDEDIR",
1394                    [Installation directory for include files])
1395 AC_DEFINE_UNQUOTED(LLVM_INFODIR, "$LLVM_INFODIR",
1396                    [Installation directory for .info files])
1397 AC_DEFINE_UNQUOTED(LLVM_MANDIR, "$LLVM_MANDIR",
1398                    [Installation directory for man pages])
1399 AC_DEFINE_UNQUOTED(LLVM_CONFIGTIME, "$LLVM_CONFIGTIME",
1400                    [Time at which LLVM was configured])
1401 AC_DEFINE_UNQUOTED(LLVM_DEFAULT_TARGET_TRIPLE, "$target",
1402                    [Target triple LLVM will generate code for by default])
1403
1404 # Determine which bindings to build.
1405 if test "$BINDINGS_TO_BUILD" = auto ; then
1406   BINDINGS_TO_BUILD=""
1407   if test "x$OCAMLC" != x -a "x$OCAMLDEP" != x ; then
1408     BINDINGS_TO_BUILD="ocaml $BINDINGS_TO_BUILD"
1409   fi
1410 fi
1411 AC_SUBST(BINDINGS_TO_BUILD,$BINDINGS_TO_BUILD)
1412
1413 # This isn't really configurey, but it avoids having to repeat the list in
1414 # other files.
1415 AC_SUBST(ALL_BINDINGS,ocaml)
1416
1417 # Do any work necessary to ensure that bindings have what they need.
1418 binding_prereqs_failed=0
1419 for a_binding in $BINDINGS_TO_BUILD ; do
1420   case "$a_binding" in
1421   ocaml)
1422     if test "x$OCAMLC" = x ; then
1423       AC_MSG_WARN([--enable-bindings=ocaml specified, but ocamlc not found. Try configure OCAMLC=/path/to/ocamlc])
1424       binding_prereqs_failed=1
1425     fi
1426     if test "x$OCAMLDEP" = x ; then
1427       AC_MSG_WARN([--enable-bindings=ocaml specified, but ocamldep not found. Try configure OCAMLDEP=/path/to/ocamldep])
1428       binding_prereqs_failed=1
1429     fi
1430     if test "x$OCAMLOPT" = x ; then
1431       AC_MSG_WARN([--enable-bindings=ocaml specified, but ocamlopt not found. Try configure OCAMLOPT=/path/to/ocamlopt])
1432       dnl ocamlopt is optional!
1433     fi
1434     if test "x$with_ocaml_libdir" != xauto ; then
1435       AC_SUBST(OCAML_LIBDIR,$with_ocaml_libdir)
1436     else
1437       ocaml_stdlib="`"$OCAMLC" -where`"
1438       if test "$LLVM_PREFIX" '<' "$ocaml_stdlib" -a "$ocaml_stdlib" '<' "$LLVM_PREFIX~"
1439       then
1440         # ocaml stdlib is beneath our prefix; use stdlib
1441         AC_SUBST(OCAML_LIBDIR,$ocaml_stdlib)
1442       else
1443         # ocaml stdlib is outside our prefix; use libdir/ocaml
1444         AC_SUBST(OCAML_LIBDIR,$LLVM_LIBDIR/ocaml)
1445       fi
1446     fi
1447     ;;
1448   esac
1449 done
1450 if test "$binding_prereqs_failed" = 1 ; then
1451   AC_MSG_ERROR([Prequisites for bindings not satisfied. Fix them or use configure --disable-bindings.])
1452 fi
1453
1454 dnl Determine whether the compiler supports -fvisibility-inlines-hidden.
1455 AC_CXX_USE_VISIBILITY_INLINES_HIDDEN
1456
1457 dnl Determine linker rpath flag
1458 if test "$llvm_cv_link_use_r" = "yes" ; then
1459   RPATH="-Wl,-R"
1460 else
1461   RPATH="-Wl,-rpath"
1462 fi
1463 AC_SUBST(RPATH)
1464
1465 dnl Determine linker rdynamic flag
1466 if test "$llvm_cv_link_use_export_dynamic" = "yes" ; then
1467   RDYNAMIC="-Wl,-export-dynamic"
1468 else
1469   RDYNAMIC=""
1470 fi
1471 AC_SUBST(RDYNAMIC)
1472
1473 dnl===-----------------------------------------------------------------------===
1474 dnl===
1475 dnl=== SECTION 10: Specify the output files and generate it
1476 dnl===
1477 dnl===-----------------------------------------------------------------------===
1478
1479 dnl **************************************************************************
1480 dnl End LLVM configure.ac Import
1481 dnl **************************************************************************
1482
1483 dnl Configure a common Makefile
1484 AC_CONFIG_FILES(Makefile.common)
1485 AC_CONFIG_FILES(Makefile.llvm.config)
1486
1487 dnl Configure project makefiles
1488 dnl List every Makefile that exists within your source tree
1489 AC_CONFIG_MAKEFILE(Makefile)
1490 AC_CONFIG_MAKEFILE(lib/Makefile)
1491 AC_CONFIG_MAKEFILE(lib/sample/Makefile)
1492 AC_CONFIG_MAKEFILE(tools/Makefile)
1493 AC_CONFIG_MAKEFILE(tools/sample/Makefile)
1494
1495 dnl This must be last
1496 AC_OUTPUT