lib/Target/X86/X86InstrFormats.td

   1 //===-- X86InstrFormats.td - X86 Instruction Formats -------*- tablegen -*-===//
   2 //
   3 //                     The LLVM Compiler Infrastructure
   4 //
   5 // This file is distributed under the University of Illinois Open Source
   6 // License. See LICENSE.TXT for details.
   7 //
   8 //===----------------------------------------------------------------------===//
   9
  10 //===----------------------------------------------------------------------===//
  11 // X86 Instruction Format Definitions.
  12 //
  13
  14 // Format specifies the encoding used by the instruction.  This is part of the
  15 // ad-hoc solution used to emit machine instruction encodings by our machine
  16 // code emitter.
  17 class Format<bits<6> val> {
  18   bits<6> Value = val;
  19 }
  20
  21 def Pseudo     : Format<0>; def RawFrm     : Format<1>;
  22 def AddRegFrm  : Format<2>; def MRMDestReg : Format<3>;
  23 def MRMDestMem : Format<4>; def MRMSrcReg  : Format<5>;
  24 def MRMSrcMem  : Format<6>;
  25 def MRM0r  : Format<16>; def MRM1r  : Format<17>; def MRM2r  : Format<18>;
  26 def MRM3r  : Format<19>; def MRM4r  : Format<20>; def MRM5r  : Format<21>;
  27 def MRM6r  : Format<22>; def MRM7r  : Format<23>;
  28 def MRM0m  : Format<24>; def MRM1m  : Format<25>; def MRM2m  : Format<26>;
  29 def MRM3m  : Format<27>; def MRM4m  : Format<28>; def MRM5m  : Format<29>;
  30 def MRM6m  : Format<30>; def MRM7m  : Format<31>;
  31 def MRMInitReg : Format<32>;
  32 def MRM_C1 : Format<33>;
  33 def MRM_C2 : Format<34>;
  34 def MRM_C3 : Format<35>;
  35 def MRM_C4 : Format<36>;
  36 def MRM_C8 : Format<37>;
  37 def MRM_C9 : Format<38>;
  38 def MRM_E8 : Format<39>;
  39 def MRM_F0 : Format<40>;
  40 def MRM_F8 : Format<41>;
  41 def MRM_F9 : Format<42>;
  42 def RawFrmImm8 : Format<43>;
  43 def RawFrmImm16 : Format<44>;
  44 def MRM_D0 : Format<45>;
  45 def MRM_D1 : Format<46>;
  46 def MRM_D4 : Format<47>;
  47 def MRM_D8 : Format<48>;
  48 def MRM_D9 : Format<49>;
  49 def MRM_DA : Format<50>;
  50 def MRM_DB : Format<51>;
  51 def MRM_DC : Format<52>;
  52 def MRM_DD : Format<53>;
  53 def MRM_DE : Format<54>;
  54 def MRM_DF : Format<55>;
  55
  56 // ImmType - This specifies the immediate type used by an instruction. This is
  57 // part of the ad-hoc solution used to emit machine instruction encodings by our
  58 // machine code emitter.
  59 class ImmType<bits<3> val> {
  60   bits<3> Value = val;
  61 }
  62 def NoImm      : ImmType<0>;
  63 def Imm8       : ImmType<1>;
  64 def Imm8PCRel  : ImmType<2>;
  65 def Imm16      : ImmType<3>;
  66 def Imm16PCRel : ImmType<4>;
  67 def Imm32      : ImmType<5>;
  68 def Imm32PCRel : ImmType<6>;
  69 def Imm64      : ImmType<7>;
  70
  71 // FPFormat - This specifies what form this FP instruction has.  This is used by
  72 // the Floating-Point stackifier pass.
  73 class FPFormat<bits<3> val> {
  74   bits<3> Value = val;
  75 }
  76 def NotFP      : FPFormat<0>;
  77 def ZeroArgFP  : FPFormat<1>;
  78 def OneArgFP   : FPFormat<2>;
  79 def OneArgFPRW : FPFormat<3>;
  80 def TwoArgFP   : FPFormat<4>;
  81 def CompareFP  : FPFormat<5>;
  82 def CondMovFP  : FPFormat<6>;
  83 def SpecialFP  : FPFormat<7>;
  84
  85 // Class specifying the SSE execution domain, used by the SSEDomainFix pass.
  86 // Keep in sync with tables in X86InstrInfo.cpp.
  87 class Domain<bits<2> val> {
  88   bits<2> Value = val;
  89 }
  90 def GenericDomain   : Domain<0>;
  91 def SSEPackedSingle : Domain<1>;
  92 def SSEPackedDouble : Domain<2>;
  93 def SSEPackedInt    : Domain<3>;
  94
  95 // Prefix byte classes which are used to indicate to the ad-hoc machine code
  96 // emitter that various prefix bytes are required.
  97 class OpSize { bit hasOpSizePrefix = 1; }
  98 class AdSize { bit hasAdSizePrefix = 1; }
  99 class REX_W  { bit hasREX_WPrefix = 1; }
 100 class LOCK   { bit hasLockPrefix = 1; }
 101 class SegFS  { bits<2> SegOvrBits = 1; }
 102 class SegGS  { bits<2> SegOvrBits = 2; }
 103 class TB     { bits<5> Prefix = 1; }
 104 class REP    { bits<5> Prefix = 2; }
 105 class D8     { bits<5> Prefix = 3; }
 106 class D9     { bits<5> Prefix = 4; }
 107 class DA     { bits<5> Prefix = 5; }
 108 class DB     { bits<5> Prefix = 6; }
 109 class DC     { bits<5> Prefix = 7; }
 110 class DD     { bits<5> Prefix = 8; }
 111 class DE     { bits<5> Prefix = 9; }
 112 class DF     { bits<5> Prefix = 10; }
 113 class XD     { bits<5> Prefix = 11; }
 114 class XS     { bits<5> Prefix = 12; }
 115 class T8     { bits<5> Prefix = 13; }
 116 class TA     { bits<5> Prefix = 14; }
 117 class A6     { bits<5> Prefix = 15; }
 118 class A7     { bits<5> Prefix = 16; }
 119 class T8XD   { bits<5> Prefix = 17; }
 120 class T8XS   { bits<5> Prefix = 18; }
 121 class TAXD   { bits<5> Prefix = 19; }
 122 class XOP8   { bits<5> Prefix = 20; }
 123 class XOP9   { bits<5> Prefix = 21; }
 124 class VEX    { bit hasVEXPrefix = 1; }
 125 class VEX_W  { bit hasVEX_WPrefix = 1; }
 126 class VEX_4V : VEX { bit hasVEX_4VPrefix = 1; }
 127 class VEX_4VOp3 : VEX { bit hasVEX_4VOp3Prefix = 1; }
 128 class VEX_I8IMM { bit hasVEX_i8ImmReg = 1; }
 129 class VEX_L  { bit hasVEX_L = 1; }
 130 class VEX_LIG { bit ignoresVEX_L = 1; }
 131 class Has3DNow0F0FOpcode  { bit has3DNow0F0FOpcode = 1; }
 132 class MemOp4 { bit hasMemOp4Prefix = 1; }
 133 class XOP { bit hasXOP_Prefix = 1; }
 134 class X86Inst<bits<8> opcod, Format f, ImmType i, dag outs, dag ins,
 135               string AsmStr,
 136               InstrItinClass itin,
 137               Domain d = GenericDomain>
 138   : Instruction {
 139   let Namespace = "X86";
 140
 141   bits<8> Opcode = opcod;
 142   Format Form = f;
 143   bits<6> FormBits = Form.Value;
 144   ImmType ImmT = i;
 145
 146   dag OutOperandList = outs;
 147   dag InOperandList = ins;
 148   string AsmString = AsmStr;
 149
 150   // If this is a pseudo instruction, mark it isCodeGenOnly.
 151   let isCodeGenOnly = !eq(!cast<string>(f), "Pseudo");
 152
 153   let Itinerary = itin;
 154
 155   //
 156   // Attributes specific to X86 instructions...
 157   //
 158   bit hasOpSizePrefix = 0;  // Does this inst have a 0x66 prefix?
 159   bit hasAdSizePrefix = 0;  // Does this inst have a 0x67 prefix?
 160
 161   bits<5> Prefix = 0;       // Which prefix byte does this inst have?
 162   bit hasREX_WPrefix  = 0;  // Does this inst require the REX.W prefix?
 163   FPFormat FPForm = NotFP;  // What flavor of FP instruction is this?
 164   bit hasLockPrefix = 0;    // Does this inst have a 0xF0 prefix?
 165   bits<2> SegOvrBits = 0;   // Segment override prefix.
 166   Domain ExeDomain = d;
 167   bit hasVEXPrefix = 0;     // Does this inst require a VEX prefix?
 168   bit hasVEX_WPrefix = 0;   // Does this inst set the VEX_W field?
 169   bit hasVEX_4VPrefix = 0;  // Does this inst require the VEX.VVVV field?
 170   bit hasVEX_4VOp3Prefix = 0;  // Does this inst require the VEX.VVVV field to
 171                                // encode the third operand?
 172   bit hasVEX_i8ImmReg = 0;  // Does this inst require the last source register
 173                             // to be encoded in a immediate field?
 174   bit hasVEX_L = 0;         // Does this inst use large (256-bit) registers?
 175   bit ignoresVEX_L = 0;     // Does this instruction ignore the L-bit
 176   bit has3DNow0F0FOpcode =0;// Wacky 3dNow! encoding?
 177   bit hasMemOp4Prefix = 0;  // Same bit as VEX_W, but used for swapping operands
 178   bit hasXOP_Prefix = 0;    // Does this inst require an XOP prefix?
 179
 180   // TSFlags layout should be kept in sync with X86InstrInfo.h.
 181   let TSFlags{5-0}   = FormBits;
 182   let TSFlags{6}     = hasOpSizePrefix;
 183   let TSFlags{7}     = hasAdSizePrefix;
 184   let TSFlags{12-8}  = Prefix;
 185   let TSFlags{13}    = hasREX_WPrefix;
 186   let TSFlags{16-14} = ImmT.Value;
 187   let TSFlags{19-17} = FPForm.Value;
 188   let TSFlags{20}    = hasLockPrefix;
 189   let TSFlags{22-21} = SegOvrBits;
 190   let TSFlags{24-23} = ExeDomain.Value;
 191   let TSFlags{32-25} = Opcode;
 192   let TSFlags{33}    = hasVEXPrefix;
 193   let TSFlags{34}    = hasVEX_WPrefix;
 194   let TSFlags{35}    = hasVEX_4VPrefix;
 195   let TSFlags{36}    = hasVEX_4VOp3Prefix;
 196   let TSFlags{37}    = hasVEX_i8ImmReg;
 197   let TSFlags{38}    = hasVEX_L;
 198   let TSFlags{39}    = ignoresVEX_L;
 199   let TSFlags{40}    = has3DNow0F0FOpcode;
 200   let TSFlags{41}    = hasMemOp4Prefix;
 201   let TSFlags{42}    = hasXOP_Prefix;
 202 }
 203
 204 class PseudoI<dag oops, dag iops, list<dag> pattern>
 205   : X86Inst<0, Pseudo, NoImm, oops, iops, "", NoItinerary> {
 206   let Pattern = pattern;
 207 }
 208
 209 class I<bits<8> o, Format f, dag outs, dag ins, string asm,
 210         list<dag> pattern, InstrItinClass itin = IIC_DEFAULT,
 211         Domain d = GenericDomain>
 212   : X86Inst<o, f, NoImm, outs, ins, asm, itin, d> {
 213   let Pattern = pattern;
 214   let CodeSize = 3;
 215 }
 216 class Ii8 <bits<8> o, Format f, dag outs, dag ins, string asm,
 217            list<dag> pattern, InstrItinClass itin = IIC_DEFAULT,
 218            Domain d = GenericDomain>
 219   : X86Inst<o, f, Imm8, outs, ins, asm, itin, d> {
 220   let Pattern = pattern;
 221   let CodeSize = 3;
 222 }
 223 class Ii8PCRel<bits<8> o, Format f, dag outs, dag ins, string asm,
 224                list<dag> pattern, InstrItinClass itin = IIC_DEFAULT>
 225   : X86Inst<o, f, Imm8PCRel, outs, ins, asm, itin> {
 226   let Pattern = pattern;
 227   let CodeSize = 3;
 228 }
 229 class Ii16<bits<8> o, Format f, dag outs, dag ins, string asm,
 230            list<dag> pattern, InstrItinClass itin = IIC_DEFAULT>
 231   : X86Inst<o, f, Imm16, outs, ins, asm, itin> {
 232   let Pattern = pattern;
 233   let CodeSize = 3;
 234 }
 235 class Ii32<bits<8> o, Format f, dag outs, dag ins, string asm,
 236            list<dag> pattern, InstrItinClass itin = IIC_DEFAULT>
 237   : X86Inst<o, f, Imm32, outs, ins, asm, itin> {
 238   let Pattern = pattern;
 239   let CodeSize = 3;
 240 }
 241
 242 class Ii16PCRel<bits<8> o, Format f, dag outs, dag ins, string asm,
 243            list<dag> pattern, InstrItinClass itin = IIC_DEFAULT>
 244            : X86Inst<o, f, Imm16PCRel, outs, ins, asm, itin> {
 245   let Pattern = pattern;
 246   let CodeSize = 3;
 247 }
 248
 249 class Ii32PCRel<bits<8> o, Format f, dag outs, dag ins, string asm,
 250            list<dag> pattern, InstrItinClass itin = IIC_DEFAULT>
 251   : X86Inst<o, f, Imm32PCRel, outs, ins, asm, itin> {
 252   let Pattern = pattern;
 253   let CodeSize = 3;
 254 }
 255
 256 // FPStack Instruction Templates:
 257 // FPI - Floating Point Instruction template.
 258 class FPI<bits<8> o, Format F, dag outs, dag ins, string asm,
 259           InstrItinClass itin = IIC_DEFAULT>
 260   : I<o, F, outs, ins, asm, [], itin> {}
 261
 262 // FpI_ - Floating Point Pseudo Instruction template. Not Predicated.
 263 class FpI_<dag outs, dag ins, FPFormat fp, list<dag> pattern,
 264            InstrItinClass itin = IIC_DEFAULT>
 265   : X86Inst<0, Pseudo, NoImm, outs, ins, "", itin> {
 266   let FPForm = fp;
 267   let Pattern = pattern;
 268 }
 269
 270 // Templates for instructions that use a 16- or 32-bit segmented address as
 271 //  their only operand: lcall (FAR CALL) and ljmp (FAR JMP)
 272 //
 273 //   Iseg16 - 16-bit segment selector, 16-bit offset
 274 //   Iseg32 - 16-bit segment selector, 32-bit offset
 275
 276 class Iseg16 <bits<8> o, Format f, dag outs, dag ins, string asm,
 277               list<dag> pattern, InstrItinClass itin = IIC_DEFAULT>
 278       : X86Inst<o, f, Imm16, outs, ins, asm, itin> {
 279   let Pattern = pattern;
 280   let CodeSize = 3;
 281 }
 282
 283 class Iseg32 <bits<8> o, Format f, dag outs, dag ins, string asm,
 284               list<dag> pattern, InstrItinClass itin = IIC_DEFAULT>
 285       : X86Inst<o, f, Imm32, outs, ins, asm, itin> {
 286   let Pattern = pattern;
 287   let CodeSize = 3;
 288 }
 289
 290 // SI - SSE 1 & 2 scalar instructions
 291 class SI<bits<8> o, Format F, dag outs, dag ins, string asm,
 292          list<dag> pattern, InstrItinClass itin = IIC_DEFAULT>
 293       : I<o, F, outs, ins, asm, pattern, itin> {
 294   let Predicates = !if(hasVEXPrefix /* VEX */, [HasAVX],
 295             !if(!eq(Prefix, 12 /* XS */), [HasSSE1], [HasSSE2]));
 296
 297   // AVX instructions have a 'v' prefix in the mnemonic
 298   let AsmString = !if(hasVEXPrefix, !strconcat("v", asm), asm);
 299 }
 300
 301 // SIi8 - SSE 1 & 2 scalar instructions
 302 class SIi8<bits<8> o, Format F, dag outs, dag ins, string asm,
 303            list<dag> pattern, InstrItinClass itin = IIC_DEFAULT>
 304       : Ii8<o, F, outs, ins, asm, pattern, itin> {
 305   let Predicates = !if(hasVEXPrefix /* VEX */, [HasAVX],
 306             !if(!eq(Prefix, 12 /* XS */), [HasSSE1], [HasSSE2]));
 307
 308   // AVX instructions have a 'v' prefix in the mnemonic
 309   let AsmString = !if(hasVEXPrefix, !strconcat("v", asm), asm);
 310 }
 311
 312 // PI - SSE 1 & 2 packed instructions
 313 class PI<bits<8> o, Format F, dag outs, dag ins, string asm, list<dag> pattern,
 314          InstrItinClass itin, Domain d>
 315       : I<o, F, outs, ins, asm, pattern, itin, d> {
 316   let Predicates = !if(hasVEXPrefix /* VEX */, [HasAVX],
 317         !if(hasOpSizePrefix /* OpSize */, [HasSSE2], [HasSSE1]));
 318
 319   // AVX instructions have a 'v' prefix in the mnemonic
 320   let AsmString = !if(hasVEXPrefix, !strconcat("v", asm), asm);
 321 }
 322
 323 // PIi8 - SSE 1 & 2 packed instructions with immediate
 324 class PIi8<bits<8> o, Format F, dag outs, dag ins, string asm,
 325            list<dag> pattern, InstrItinClass itin, Domain d>
 326       : Ii8<o, F, outs, ins, asm, pattern, itin, d> {
 327   let Predicates = !if(hasVEX_4VPrefix /* VEX */, [HasAVX],
 328         !if(hasOpSizePrefix /* OpSize */, [HasSSE2], [HasSSE1]));
 329
 330   // AVX instructions have a 'v' prefix in the mnemonic
 331   let AsmString = !if(hasVEX_4VPrefix, !strconcat("v", asm), asm);
 332 }
 333
 334 // SSE1 Instruction Templates:
 335 //
 336 //   SSI   - SSE1 instructions with XS prefix.
 337 //   PSI   - SSE1 instructions with TB prefix.
 338 //   PSIi8 - SSE1 instructions with ImmT == Imm8 and TB prefix.
 339 //   VSSI  - SSE1 instructions with XS prefix in AVX form.
 340 //   VPSI  - SSE1 instructions with TB prefix in AVX form.
 341
 342 class SSI<bits<8> o, Format F, dag outs, dag ins, string asm,
 343           list<dag> pattern, InstrItinClass itin = IIC_DEFAULT>
 344       : I<o, F, outs, ins, asm, pattern, itin>, XS, Requires<[HasSSE1]>;
 345 class SSIi8<bits<8> o, Format F, dag outs, dag ins, string asm,
 346             list<dag> pattern, InstrItinClass itin = IIC_DEFAULT>
 347       : Ii8<o, F, outs, ins, asm, pattern, itin>, XS, Requires<[HasSSE1]>;
 348 class PSI<bits<8> o, Format F, dag outs, dag ins, string asm,
 349           list<dag> pattern, InstrItinClass itin = IIC_DEFAULT>
 350       : I<o, F, outs, ins, asm, pattern, itin, SSEPackedSingle>, TB,
 351         Requires<[HasSSE1]>;
 352 class PSIi8<bits<8> o, Format F, dag outs, dag ins, string asm,
 353             list<dag> pattern, InstrItinClass itin = IIC_DEFAULT>
 354       : Ii8<o, F, outs, ins, asm, pattern, itin, SSEPackedSingle>, TB,
 355         Requires<[HasSSE1]>;
 356 class VSSI<bits<8> o, Format F, dag outs, dag ins, string asm,
 357            list<dag> pattern, InstrItinClass itin = IIC_DEFAULT>
 358       : I<o, F, outs, ins, !strconcat("v", asm), pattern, itin>, XS,
 359         Requires<[HasAVX]>;
 360 class VPSI<bits<8> o, Format F, dag outs, dag ins, string asm,
 361            list<dag> pattern, InstrItinClass itin = IIC_DEFAULT>
 362       : I<o, F, outs, ins, !strconcat("v", asm), pattern, itin, SSEPackedSingle>, TB,
 363         Requires<[HasAVX]>;
 364
 365 // SSE2 Instruction Templates:
 366 //
 367 //   SDI    - SSE2 instructions with XD prefix.
 368 //   SDIi8  - SSE2 instructions with ImmT == Imm8 and XD prefix.
 369 //   SSDIi8 - SSE2 instructions with ImmT == Imm8 and XS prefix.
 370 //   PDI    - SSE2 instructions with TB and OpSize prefixes.
 371 //   PDIi8  - SSE2 instructions with ImmT == Imm8 and TB and OpSize prefixes.
 372 //   VSDI   - SSE2 instructions with XD prefix in AVX form.
 373 //   VPDI   - SSE2 instructions with TB and OpSize prefixes in AVX form.
 374
 375 class SDI<bits<8> o, Format F, dag outs, dag ins, string asm,
 376           list<dag> pattern, InstrItinClass itin = IIC_DEFAULT>
 377       : I<o, F, outs, ins, asm, pattern, itin>, XD, Requires<[HasSSE2]>;
 378 class SDIi8<bits<8> o, Format F, dag outs, dag ins, string asm,
 379             list<dag> pattern, InstrItinClass itin = IIC_DEFAULT>
 380       : Ii8<o, F, outs, ins, asm, pattern, itin>, XD, Requires<[HasSSE2]>;
 381 class SSDIi8<bits<8> o, Format F, dag outs, dag ins, string asm,
 382              list<dag> pattern>
 383       : Ii8<o, F, outs, ins, asm, pattern>, XS, Requires<[HasSSE2]>;
 384 class PDI<bits<8> o, Format F, dag outs, dag ins, string asm,
 385           list<dag> pattern, InstrItinClass itin = IIC_DEFAULT>
 386       : I<o, F, outs, ins, asm, pattern, itin, SSEPackedDouble>, TB, OpSize,
 387         Requires<[HasSSE2]>;
 388 class PDIi8<bits<8> o, Format F, dag outs, dag ins, string asm,
 389             list<dag> pattern, InstrItinClass itin = IIC_DEFAULT>
 390       : Ii8<o, F, outs, ins, asm, pattern, itin, SSEPackedDouble>, TB, OpSize,
 391         Requires<[HasSSE2]>;
 392 class VSDI<bits<8> o, Format F, dag outs, dag ins, string asm,
 393            list<dag> pattern, InstrItinClass itin = IIC_DEFAULT>
 394       : I<o, F, outs, ins, !strconcat("v", asm), pattern, itin>, XD,
 395         Requires<[HasAVX]>;
 396 class VPDI<bits<8> o, Format F, dag outs, dag ins, string asm,
 397            list<dag> pattern, InstrItinClass itin = IIC_DEFAULT>
 398       : I<o, F, outs, ins, !strconcat("v", asm), pattern, itin, SSEPackedDouble>, TB,
 399         OpSize, Requires<[HasAVX]>;
 400
 401 // SSE3 Instruction Templates:
 402 //
 403 //   S3I   - SSE3 instructions with TB and OpSize prefixes.
 404 //   S3SI  - SSE3 instructions with XS prefix.
 405 //   S3DI  - SSE3 instructions with XD prefix.
 406
 407 class S3SI<bits<8> o, Format F, dag outs, dag ins, string asm,
 408            list<dag> pattern, InstrItinClass itin = IIC_DEFAULT>
 409       : I<o, F, outs, ins, asm, pattern, itin, SSEPackedSingle>, XS,
 410         Requires<[HasSSE3]>;
 411 class S3DI<bits<8> o, Format F, dag outs, dag ins, string asm,
 412            list<dag> pattern, InstrItinClass itin = IIC_DEFAULT>
 413       : I<o, F, outs, ins, asm, pattern, itin, SSEPackedDouble>, XD,
 414         Requires<[HasSSE3]>;
 415 class S3I<bits<8> o, Format F, dag outs, dag ins, string asm,
 416           list<dag> pattern, InstrItinClass itin = IIC_DEFAULT>
 417       : I<o, F, outs, ins, asm, pattern, itin, SSEPackedDouble>, TB, OpSize,
 418         Requires<[HasSSE3]>;
 419
 420
 421 // SSSE3 Instruction Templates:
 422 //
 423 //   SS38I - SSSE3 instructions with T8 prefix.
 424 //   SS3AI - SSSE3 instructions with TA prefix.
 425 //
 426 // Note: SSSE3 instructions have 64-bit and 128-bit versions. The 64-bit version
 427 // uses the MMX registers. The 64-bit versions are grouped with the MMX
 428 // classes. They need to be enabled even if AVX is enabled.
 429
 430 class SS38I<bits<8> o, Format F, dag outs, dag ins, string asm,
 431             list<dag> pattern, InstrItinClass itin = IIC_DEFAULT>
 432       : I<o, F, outs, ins, asm, pattern, itin, SSEPackedInt>, T8,
 433         Requires<[HasSSSE3]>;
 434 class SS3AI<bits<8> o, Format F, dag outs, dag ins, string asm,
 435             list<dag> pattern, InstrItinClass itin = IIC_DEFAULT>
 436       : Ii8<o, F, outs, ins, asm, pattern, itin, SSEPackedInt>, TA,
 437         Requires<[HasSSSE3]>;
 438
 439 // SSE4.1 Instruction Templates:
 440 //
 441 //   SS48I - SSE 4.1 instructions with T8 prefix.
 442 //   SS41AIi8 - SSE 4.1 instructions with TA prefix and ImmT == Imm8.
 443 //
 444 class SS48I<bits<8> o, Format F, dag outs, dag ins, string asm,
 445             list<dag> pattern, InstrItinClass itin = IIC_DEFAULT>
 446       : I<o, F, outs, ins, asm, pattern, itin, SSEPackedInt>, T8,
 447         Requires<[HasSSE41]>;
 448 class SS4AIi8<bits<8> o, Format F, dag outs, dag ins, string asm,
 449             list<dag> pattern, InstrItinClass itin = IIC_DEFAULT>
 450       : Ii8<o, F, outs, ins, asm, pattern, itin, SSEPackedInt>, TA,
 451         Requires<[HasSSE41]>;
 452
 453 // SSE4.2 Instruction Templates:
 454 //
 455 //   SS428I - SSE 4.2 instructions with T8 prefix.
 456 class SS428I<bits<8> o, Format F, dag outs, dag ins, string asm,
 457              list<dag> pattern, InstrItinClass itin = IIC_DEFAULT>
 458       : I<o, F, outs, ins, asm, pattern, itin, SSEPackedInt>, T8,
 459         Requires<[HasSSE42]>;
 460
 461 //   SS42FI - SSE 4.2 instructions with T8XD prefix.
 462 class SS42FI<bits<8> o, Format F, dag outs, dag ins, string asm,
 463              list<dag> pattern, InstrItinClass itin = IIC_DEFAULT>
 464       : I<o, F, outs, ins, asm, pattern, itin>, T8XD, Requires<[HasSSE42]>;
 465
 466 //   SS42AI = SSE 4.2 instructions with TA prefix
 467 class SS42AI<bits<8> o, Format F, dag outs, dag ins, string asm,
 468              list<dag> pattern, InstrItinClass itin = IIC_DEFAULT>
 469       : Ii8<o, F, outs, ins, asm, pattern, itin, SSEPackedInt>, TA,
 470         Requires<[HasSSE42]>;
 471
 472 // AVX Instruction Templates:
 473 //   Instructions introduced in AVX (no SSE equivalent forms)
 474 //
 475 //   AVX8I - AVX instructions with T8 and OpSize prefix.
 476 //   AVXAIi8 - AVX instructions with TA, OpSize prefix and ImmT = Imm8.
 477 class AVX8I<bits<8> o, Format F, dag outs, dag ins, string asm,
 478             list<dag> pattern, InstrItinClass itin = IIC_DEFAULT>
 479       : I<o, F, outs, ins, asm, pattern, itin, SSEPackedInt>, T8, OpSize,
 480         Requires<[HasAVX]>;
 481 class AVXAIi8<bits<8> o, Format F, dag outs, dag ins, string asm,
 482               list<dag> pattern, InstrItinClass itin = IIC_DEFAULT>
 483       : Ii8<o, F, outs, ins, asm, pattern, itin, SSEPackedInt>, TA, OpSize,
 484         Requires<[HasAVX]>;
 485
 486 // AVX2 Instruction Templates:
 487 //   Instructions introduced in AVX2 (no SSE equivalent forms)
 488 //
 489 //   AVX28I - AVX2 instructions with T8 and OpSize prefix.
 490 //   AVX2AIi8 - AVX2 instructions with TA, OpSize prefix and ImmT = Imm8.
 491 class AVX28I<bits<8> o, Format F, dag outs, dag ins, string asm,
 492             list<dag> pattern, InstrItinClass itin = IIC_DEFAULT>
 493       : I<o, F, outs, ins, asm, pattern, itin, SSEPackedInt>, T8, OpSize,
 494         Requires<[HasAVX2]>;
 495 class AVX2AIi8<bits<8> o, Format F, dag outs, dag ins, string asm,
 496               list<dag> pattern, InstrItinClass itin = IIC_DEFAULT>
 497       : Ii8<o, F, outs, ins, asm, pattern, itin, SSEPackedInt>, TA, OpSize,
 498         Requires<[HasAVX2]>;
 499
 500 // AES Instruction Templates:
 501 //
 502 // AES8I
 503 // These use the same encoding as the SSE4.2 T8 and TA encodings.
 504 class AES8I<bits<8> o, Format F, dag outs, dag ins, string asm,
 505             list<dag>pattern, InstrItinClass itin = IIC_DEFAULT>
 506       : I<o, F, outs, ins, asm, pattern, itin, SSEPackedInt>, T8,
 507         Requires<[HasAES]>;
 508
 509 class AESAI<bits<8> o, Format F, dag outs, dag ins, string asm,
 510             list<dag> pattern, InstrItinClass itin = IIC_DEFAULT>
 511       : Ii8<o, F, outs, ins, asm, pattern, itin, SSEPackedInt>, TA,
 512         Requires<[HasAES]>;
 513
 514 // CLMUL Instruction Templates
 515 class CLMULIi8<bits<8> o, Format F, dag outs, dag ins, string asm,
 516                list<dag>pattern, InstrItinClass itin = IIC_DEFAULT>
 517       : Ii8<o, F, outs, ins, asm, pattern, itin, SSEPackedInt>, TA,
 518         OpSize, Requires<[HasCLMUL]>;
 519
 520 class AVXCLMULIi8<bits<8> o, Format F, dag outs, dag ins, string asm,
 521                   list<dag>pattern, InstrItinClass itin = IIC_DEFAULT>
 522       : Ii8<o, F, outs, ins, asm, pattern, itin, SSEPackedInt>, TA,
 523         OpSize, VEX_4V, Requires<[HasAVX, HasCLMUL]>;
 524
 525 // FMA3 Instruction Templates
 526 class FMA3<bits<8> o, Format F, dag outs, dag ins, string asm,
 527            list<dag>pattern, InstrItinClass itin = IIC_DEFAULT>
 528       : I<o, F, outs, ins, asm, pattern, itin>, T8,
 529         OpSize, VEX_4V, Requires<[HasFMA3]>;
 530
 531 // FMA4 Instruction Templates
 532 class FMA4<bits<8> o, Format F, dag outs, dag ins, string asm,
 533            list<dag>pattern, InstrItinClass itin = IIC_DEFAULT>
 534       : I<o, F, outs, ins, asm, pattern, itin, SSEPackedInt>, TA,
 535         OpSize, VEX_4V, VEX_I8IMM, Requires<[HasFMA4]>;
 536
 537 // XOP 2, 3 and 4 Operand Instruction Template
 538 class IXOP<bits<8> o, Format F, dag outs, dag ins, string asm,
 539            list<dag> pattern, InstrItinClass itin = IIC_DEFAULT>
 540       : I<o, F, outs, ins, asm, pattern, itin, SSEPackedDouble>,
 541          XOP, XOP9, Requires<[HasXOP]>;
 542
 543 // XOP 2, 3 and 4 Operand Instruction Templates with imm byte
 544 class IXOPi8<bits<8> o, Format F, dag outs, dag ins, string asm,
 545            list<dag> pattern, InstrItinClass itin = IIC_DEFAULT>
 546       : Ii8<o, F, outs, ins, asm, pattern, itin, SSEPackedDouble>,
 547          XOP, XOP8, Requires<[HasXOP]>;
 548
 549 //  XOP 5 operand instruction (VEX encoding!)
 550 class IXOP5<bits<8> o, Format F, dag outs, dag ins, string asm,
 551            list<dag>pattern, InstrItinClass itin = IIC_DEFAULT>
 552       : Ii8<o, F, outs, ins, asm, pattern, itin, SSEPackedInt>, TA,
 553         OpSize, VEX_4V, VEX_I8IMM, Requires<[HasXOP]>;
 554
 555 // X86-64 Instruction templates...
 556 //
 557
 558 class RI<bits<8> o, Format F, dag outs, dag ins, string asm,
 559          list<dag> pattern, InstrItinClass itin = IIC_DEFAULT>
 560       : I<o, F, outs, ins, asm, pattern, itin>, REX_W;
 561 class RIi8 <bits<8> o, Format F, dag outs, dag ins, string asm,
 562             list<dag> pattern, InstrItinClass itin = IIC_DEFAULT>
 563       : Ii8<o, F, outs, ins, asm, pattern, itin>, REX_W;
 564 class RIi32 <bits<8> o, Format F, dag outs, dag ins, string asm,
 565              list<dag> pattern, InstrItinClass itin = IIC_DEFAULT>
 566       : Ii32<o, F, outs, ins, asm, pattern, itin>, REX_W;
 567
 568 class RIi64<bits<8> o, Format f, dag outs, dag ins, string asm,
 569             list<dag> pattern, InstrItinClass itin = IIC_DEFAULT>
 570   : X86Inst<o, f, Imm64, outs, ins, asm, itin>, REX_W {
 571   let Pattern = pattern;
 572   let CodeSize = 3;
 573 }
 574
 575 class RSSI<bits<8> o, Format F, dag outs, dag ins, string asm,
 576            list<dag> pattern, InstrItinClass itin = IIC_DEFAULT>
 577       : SSI<o, F, outs, ins, asm, pattern, itin>, REX_W;
 578 class RSDI<bits<8> o, Format F, dag outs, dag ins, string asm,
 579            list<dag> pattern, InstrItinClass itin = IIC_DEFAULT>
 580       : SDI<o, F, outs, ins, asm, pattern, itin>, REX_W;
 581 class RPDI<bits<8> o, Format F, dag outs, dag ins, string asm,
 582            list<dag> pattern, InstrItinClass itin = IIC_DEFAULT>
 583       : PDI<o, F, outs, ins, asm, pattern, itin>, REX_W;
 584 class VRPDI<bits<8> o, Format F, dag outs, dag ins, string asm,
 585            list<dag> pattern, InstrItinClass itin = IIC_DEFAULT>
 586       : VPDI<o, F, outs, ins, asm, pattern, itin>, VEX_W;
 587
 588 // MMX Instruction templates
 589 //
 590
 591 // MMXI   - MMX instructions with TB prefix.
 592 // MMXI64 - MMX instructions with TB prefix valid only in 64 bit mode.
 593 // MMX2I  - MMX / SSE2 instructions with TB and OpSize prefixes.
 594 // MMXIi8 - MMX instructions with ImmT == Imm8 and TB prefix.
 595 // MMXIi8 - MMX instructions with ImmT == Imm8 and TB prefix.
 596 // MMXID  - MMX instructions with XD prefix.
 597 // MMXIS  - MMX instructions with XS prefix.
 598 class MMXI<bits<8> o, Format F, dag outs, dag ins, string asm,
 599            list<dag> pattern, InstrItinClass itin = IIC_DEFAULT>
 600       : I<o, F, outs, ins, asm, pattern, itin>, TB, Requires<[HasMMX]>;
 601 class MMXI64<bits<8> o, Format F, dag outs, dag ins, string asm,
 602              list<dag> pattern, InstrItinClass itin = IIC_DEFAULT>
 603       : I<o, F, outs, ins, asm, pattern, itin>, TB, Requires<[HasMMX,In64BitMode]>;
 604 class MMXRI<bits<8> o, Format F, dag outs, dag ins, string asm,
 605             list<dag> pattern, InstrItinClass itin = IIC_DEFAULT>
 606       : I<o, F, outs, ins, asm, pattern, itin>, TB, REX_W, Requires<[HasMMX]>;
 607 class MMX2I<bits<8> o, Format F, dag outs, dag ins, string asm,
 608             list<dag> pattern, InstrItinClass itin = IIC_DEFAULT>
 609       : I<o, F, outs, ins, asm, pattern, itin>, TB, OpSize, Requires<[HasMMX]>;
 610 class MMXIi8<bits<8> o, Format F, dag outs, dag ins, string asm,
 611              list<dag> pattern, InstrItinClass itin = IIC_DEFAULT>
 612       : Ii8<o, F, outs, ins, asm, pattern, itin>, TB, Requires<[HasMMX]>;
 613 class MMXID<bits<8> o, Format F, dag outs, dag ins, string asm,
 614             list<dag> pattern, InstrItinClass itin = IIC_DEFAULT>
 615       : Ii8<o, F, outs, ins, asm, pattern, itin>, XD, Requires<[HasMMX]>;
 616 class MMXIS<bits<8> o, Format F, dag outs, dag ins, string asm,
 617             list<dag> pattern, InstrItinClass itin = IIC_DEFAULT>
 618       : Ii8<o, F, outs, ins, asm, pattern, itin>, XS, Requires<[HasMMX]>;