lib/Target/X86/X86.td

   1 //===- X86.td - Target definition file for the Intel X86 ---*- tablegen -*-===//
   2 //
   3 //                     The LLVM Compiler Infrastructure
   4 //
   5 // This file is distributed under the University of Illinois Open Source
   6 // License. See LICENSE.TXT for details.
   7 //
   8 //===----------------------------------------------------------------------===//
   9 //
  10 // This is a target description file for the Intel i386 architecture, referred to
  11 // here as the "X86" architecture.
  12 //
  13 //===----------------------------------------------------------------------===//
  14
  15 // Get the target-independent interfaces which we are implementing...
  16 //
  17 include "llvm/Target/Target.td"
  18
  19 //===----------------------------------------------------------------------===//
  20 // X86 Subtarget state.
  21 //
  22
  23 def Mode64Bit : SubtargetFeature<"64bit-mode", "In64BitMode", "true",
  24                                   "64-bit mode (x86_64)">;
  25
  26 def ModeNaCl  : SubtargetFeature<"nacl-mode", "InNaClMode", "true",
  27                                  "Native Client mode">;
  28
  29 //===----------------------------------------------------------------------===//
  30 // X86 Subtarget features.
  31 //===----------------------------------------------------------------------===//
  32
  33 def FeatureCMOV    : SubtargetFeature<"cmov","HasCMov", "true",
  34                                       "Enable conditional move instructions">;
  35
  36 def FeaturePOPCNT   : SubtargetFeature<"popcnt", "HasPOPCNT", "true",
  37                                        "Support POPCNT instruction">;
  38
  39
  40 def FeatureMMX     : SubtargetFeature<"mmx","X86SSELevel", "MMX",
  41                                       "Enable MMX instructions">;
  42 def FeatureSSE1    : SubtargetFeature<"sse", "X86SSELevel", "SSE1",
  43                                       "Enable SSE instructions",
  44                                       // SSE codegen depends on cmovs, and all
  45                                       // SSE1+ processors support them.
  46                                       [FeatureMMX, FeatureCMOV]>;
  47 def FeatureSSE2    : SubtargetFeature<"sse2", "X86SSELevel", "SSE2",
  48                                       "Enable SSE2 instructions",
  49                                       [FeatureSSE1]>;
  50 def FeatureSSE3    : SubtargetFeature<"sse3", "X86SSELevel", "SSE3",
  51                                       "Enable SSE3 instructions",
  52                                       [FeatureSSE2]>;
  53 def FeatureSSSE3   : SubtargetFeature<"ssse3", "X86SSELevel", "SSSE3",
  54                                       "Enable SSSE3 instructions",
  55                                       [FeatureSSE3]>;
  56 def FeatureSSE41   : SubtargetFeature<"sse41", "X86SSELevel", "SSE41",
  57                                       "Enable SSE 4.1 instructions",
  58                                       [FeatureSSSE3]>;
  59 def FeatureSSE42   : SubtargetFeature<"sse42", "X86SSELevel", "SSE42",
  60                                       "Enable SSE 4.2 instructions",
  61                                       [FeatureSSE41, FeaturePOPCNT]>;
  62 def Feature3DNow   : SubtargetFeature<"3dnow", "X863DNowLevel", "ThreeDNow",
  63                                       "Enable 3DNow! instructions",
  64                                       [FeatureMMX]>;
  65 def Feature3DNowA  : SubtargetFeature<"3dnowa", "X863DNowLevel", "ThreeDNowA",
  66                                       "Enable 3DNow! Athlon instructions",
  67                                       [Feature3DNow]>;
  68 // All x86-64 hardware has SSE2, but we don't mark SSE2 as an implied
  69 // feature, because SSE2 can be disabled (e.g. for compiling OS kernels)
  70 // without disabling 64-bit mode.
  71 def Feature64Bit   : SubtargetFeature<"64bit", "HasX86_64", "true",
  72                                       "Support 64-bit instructions",
  73                                       [FeatureCMOV]>;
  74 def FeatureCMPXCHG16B : SubtargetFeature<"cmpxchg16b", "HasCmpxchg16b", "true",
  75                                       "64-bit with cmpxchg16b",
  76                                       [Feature64Bit]>;
  77 def FeatureSlowBTMem : SubtargetFeature<"slow-bt-mem", "IsBTMemSlow", "true",
  78                                        "Bit testing of memory is slow">;
  79 def FeatureFastUAMem : SubtargetFeature<"fast-unaligned-mem",
  80                                         "IsUAMemFast", "true",
  81                                         "Fast unaligned memory access">;
  82 def FeatureSSE4A   : SubtargetFeature<"sse4a", "HasSSE4A", "true",
  83                                       "Support SSE 4a instructions",
  84                                       [FeaturePOPCNT]>;
  85
  86 def FeatureAVX     : SubtargetFeature<"avx", "HasAVX", "true",
  87                                       "Enable AVX instructions">;
  88 def FeatureCLMUL   : SubtargetFeature<"clmul", "HasCLMUL", "true",
  89                                "Enable carry-less multiplication instructions">;
  90 def FeatureFMA3    : SubtargetFeature<"fma3", "HasFMA3", "true",
  91                                      "Enable three-operand fused multiple-add">;
  92 def FeatureFMA4    : SubtargetFeature<"fma4", "HasFMA4", "true",
  93                                       "Enable four-operand fused multiple-add">;
  94 def FeatureVectorUAMem : SubtargetFeature<"vector-unaligned-mem",
  95                                           "HasVectorUAMem", "true",
  96                  "Allow unaligned memory operands on vector/SIMD instructions">;
  97 def FeatureAES     : SubtargetFeature<"aes", "HasAES", "true",
  98                                       "Enable AES instructions">;
  99 def FeatureMOVBE   : SubtargetFeature<"movbe", "HasMOVBE", "true",
 100                                       "Support MOVBE instruction">;
 101 def FeatureRDRAND  : SubtargetFeature<"rdrand", "HasRDRAND", "true",
 102                                       "Support RDRAND instruction">;
 103
 104 //===----------------------------------------------------------------------===//
 105 // X86 processors supported.
 106 //===----------------------------------------------------------------------===//
 107
 108 class Proc<string Name, list<SubtargetFeature> Features>
 109  : Processor<Name, NoItineraries, Features>;
 110
 111 def : Proc<"generic",         []>;
 112 def : Proc<"i386",            []>;
 113 def : Proc<"i486",            []>;
 114 def : Proc<"i586",            []>;
 115 def : Proc<"pentium",         []>;
 116 def : Proc<"pentium-mmx",     [FeatureMMX]>;
 117 def : Proc<"i686",            []>;
 118 def : Proc<"pentiumpro",      [FeatureCMOV]>;
 119 def : Proc<"pentium2",        [FeatureMMX, FeatureCMOV]>;
 120 def : Proc<"pentium3",        [FeatureSSE1]>;
 121 def : Proc<"pentium3m",       [FeatureSSE1, FeatureSlowBTMem]>;
 122 def : Proc<"pentium-m",       [FeatureSSE2, FeatureSlowBTMem]>;
 123 def : Proc<"pentium4",        [FeatureSSE2]>;
 124 def : Proc<"pentium4m",       [FeatureSSE2, FeatureSlowBTMem]>;
 125 def : Proc<"x86-64",          [FeatureSSE2, Feature64Bit, FeatureSlowBTMem]>;
 126 def : Proc<"yonah",           [FeatureSSE3, FeatureSlowBTMem]>;
 127 def : Proc<"prescott",        [FeatureSSE3, FeatureSlowBTMem]>;
 128 def : Proc<"nocona",          [FeatureSSE3, FeatureCMPXCHG16B,
 129                                FeatureSlowBTMem]>;
 130 def : Proc<"core2",           [FeatureSSSE3, FeatureCMPXCHG16B,
 131                                FeatureSlowBTMem]>;
 132 def : Proc<"penryn",          [FeatureSSE41, FeatureCMPXCHG16B,
 133                                FeatureSlowBTMem]>;
 134 def : Proc<"atom",            [FeatureSSE3,  FeatureCMPXCHG16B,
 135                                FeatureSlowBTMem]>;
 136 // "Arrandale" along with corei3 and corei5
 137 def : Proc<"corei7",          [FeatureSSE42, FeatureCMPXCHG16B,
 138                                FeatureSlowBTMem, FeatureFastUAMem, FeatureAES]>;
 139 def : Proc<"nehalem",         [FeatureSSE42,  FeatureCMPXCHG16B,
 140                                FeatureSlowBTMem, FeatureFastUAMem]>;
 141 // Westmere is a similar machine to nehalem with some additional features.
 142 // Westmere is the corei3/i5/i7 path from nehalem to sandybridge
 143 def : Proc<"westmere",        [FeatureSSE42, FeatureCMPXCHG16B,
 144                                FeatureSlowBTMem, FeatureFastUAMem, FeatureAES,
 145                                FeatureCLMUL]>;
 146 // SSE is not listed here since llvm treats AVX as a reimplementation of SSE,
 147 // rather than a superset.
 148 // FIXME: Disabling AVX for now since it's not ready.
 149 def : Proc<"corei7-avx",      [FeatureSSE42, FeatureCMPXCHG16B,
 150                                FeatureAES, FeatureCLMUL]>;
 151
 152 def : Proc<"k6",              [FeatureMMX]>;
 153 def : Proc<"k6-2",            [Feature3DNow]>;
 154 def : Proc<"k6-3",            [Feature3DNow]>;
 155 def : Proc<"athlon",          [Feature3DNowA, FeatureSlowBTMem]>;
 156 def : Proc<"athlon-tbird",    [Feature3DNowA, FeatureSlowBTMem]>;
 157 def : Proc<"athlon-4",        [FeatureSSE1,   Feature3DNowA, FeatureSlowBTMem]>;
 158 def : Proc<"athlon-xp",       [FeatureSSE1,   Feature3DNowA, FeatureSlowBTMem]>;
 159 def : Proc<"athlon-mp",       [FeatureSSE1,   Feature3DNowA, FeatureSlowBTMem]>;
 160 def : Proc<"k8",              [FeatureSSE2,   Feature3DNowA, Feature64Bit,
 161                                FeatureSlowBTMem]>;
 162 def : Proc<"opteron",         [FeatureSSE2,   Feature3DNowA, Feature64Bit,
 163                                FeatureSlowBTMem]>;
 164 def : Proc<"athlon64",        [FeatureSSE2,   Feature3DNowA, Feature64Bit,
 165                                FeatureSlowBTMem]>;
 166 def : Proc<"athlon-fx",       [FeatureSSE2,   Feature3DNowA, Feature64Bit,
 167                                FeatureSlowBTMem]>;
 168 def : Proc<"k8-sse3",         [FeatureSSE3,   Feature3DNowA, FeatureCMPXCHG16B,
 169                                FeatureSlowBTMem]>;
 170 def : Proc<"opteron-sse3",    [FeatureSSE3,   Feature3DNowA, FeatureCMPXCHG16B,
 171                                FeatureSlowBTMem]>;
 172 def : Proc<"athlon64-sse3",   [FeatureSSE3,   Feature3DNowA, FeatureCMPXCHG16B,
 173                                FeatureSlowBTMem]>;
 174 def : Proc<"amdfam10",        [FeatureSSE3,   FeatureSSE4A,
 175                                Feature3DNowA, FeatureCMPXCHG16B,
 176                                FeatureSlowBTMem]>;
 177 def : Proc<"barcelona",       [FeatureSSE3,   FeatureSSE4A,
 178                                Feature3DNowA, FeatureCMPXCHG16B,
 179                                FeatureSlowBTMem]>;
 180 def : Proc<"istanbul",        [Feature3DNowA, FeatureCMPXCHG16B,
 181                                FeatureSSE4A, Feature3DNowA]>;
 182 def : Proc<"shanghai",        [Feature3DNowA, FeatureCMPXCHG16B, FeatureSSE4A,
 183                                Feature3DNowA]>;
 184
 185 def : Proc<"winchip-c6",      [FeatureMMX]>;
 186 def : Proc<"winchip2",        [Feature3DNow]>;
 187 def : Proc<"c3",              [Feature3DNow]>;
 188 def : Proc<"c3-2",            [FeatureSSE1]>;
 189
 190 //===----------------------------------------------------------------------===//
 191 // Register File Description
 192 //===----------------------------------------------------------------------===//
 193
 194 include "X86RegisterInfo.td"
 195
 196 //===----------------------------------------------------------------------===//
 197 // Instruction Descriptions
 198 //===----------------------------------------------------------------------===//
 199
 200 include "X86InstrInfo.td"
 201
 202 def X86InstrInfo : InstrInfo;
 203
 204 //===----------------------------------------------------------------------===//
 205 // Calling Conventions
 206 //===----------------------------------------------------------------------===//
 207
 208 include "X86CallingConv.td"
 209
 210
 211 //===----------------------------------------------------------------------===//
 212 // Assembly Parser
 213 //===----------------------------------------------------------------------===//
 214
 215 // Currently the X86 assembly parser only supports ATT syntax.
 216 def ATTAsmParser : AsmParser {
 217   string AsmParserClassName = "ATTAsmParser";
 218   int Variant = 0;
 219
 220   // Discard comments in assembly strings.
 221   string CommentDelimiter = "#";
 222
 223   // Recognize hard coded registers.
 224   string RegisterPrefix = "%";
 225 }
 226
 227 //===----------------------------------------------------------------------===//
 228 // Assembly Printers
 229 //===----------------------------------------------------------------------===//
 230
 231 // The X86 target supports two different syntaxes for emitting machine code.
 232 // This is controlled by the -x86-asm-syntax={att|intel}
 233 def ATTAsmWriter : AsmWriter {
 234   string AsmWriterClassName  = "ATTInstPrinter";
 235   int Variant = 0;
 236   bit isMCAsmWriter = 1;
 237 }
 238 def IntelAsmWriter : AsmWriter {
 239   string AsmWriterClassName  = "IntelInstPrinter";
 240   int Variant = 1;
 241   bit isMCAsmWriter = 1;
 242 }
 243
 244 def X86 : Target {
 245   // Information about the instructions...
 246   let InstructionSet = X86InstrInfo;
 247
 248   let AssemblyParsers = [ATTAsmParser];
 249
 250   let AssemblyWriters = [ATTAsmWriter, IntelAsmWriter];
 251 }