lib/Target/PowerPC/PPCInstrAltivec.td

   1 //===-- PPCInstrAltivec.td - The PowerPC Altivec Extension -*- tablegen -*-===//
   2 //
   3 //                     The LLVM Compiler Infrastructure
   4 //
   5 // This file is distributed under the University of Illinois Open Source
   6 // License. See LICENSE.TXT for details.
   7 //
   8 //===----------------------------------------------------------------------===//
   9 //
  10 // This file describes the Altivec extension to the PowerPC instruction set.
  11 //
  12 //===----------------------------------------------------------------------===//
  13
  14 // *********************************** NOTE ***********************************
  15 // ** For POWER8 Little Endian, the VSX swap optimization relies on knowing  **
  16 // ** which VMX and VSX instructions are lane-sensitive and which are not.   **
  17 // ** A lane-sensitive instruction relies, implicitly or explicitly, on      **
  18 // ** whether lanes are numbered from left to right.  An instruction like    **
  19 // ** VADDFP is not lane-sensitive, because each lane of the result vector   **
  20 // ** relies only on the corresponding lane of the source vectors.  However, **
  21 // ** an instruction like VMULESB is lane-sensitive, because "even" and      **
  22 // ** "odd" lanes are different for big-endian and little-endian numbering.  **
  23 // **                                                                        **
  24 // ** When adding new VMX and VSX instructions, please consider whether they **
  25 // ** are lane-sensitive.  If so, they must be added to a switch statement   **
  26 // ** in PPCVSXSwapRemoval::gatherVectorInstructions().                      **
  27 // ****************************************************************************
  28
  29 //===----------------------------------------------------------------------===//
  30 // Altivec transformation functions and pattern fragments.
  31 //
  32
  33 // Since we canonicalize buildvectors to v16i8, all vnots "-1" operands will be
  34 // of that type.
  35 def vnot_ppc : PatFrag<(ops node:$in),
  36                        (xor node:$in, (bitconvert (v16i8 immAllOnesV)))>;
  37
  38 def vpkuhum_shuffle : PatFrag<(ops node:$lhs, node:$rhs),
  39                               (vector_shuffle node:$lhs, node:$rhs), [{
  40   return PPC::isVPKUHUMShuffleMask(cast<ShuffleVectorSDNode>(N), 0, *CurDAG);
  41 }]>;
  42 def vpkuwum_shuffle : PatFrag<(ops node:$lhs, node:$rhs),
  43                               (vector_shuffle node:$lhs, node:$rhs), [{
  44   return PPC::isVPKUWUMShuffleMask(cast<ShuffleVectorSDNode>(N), 0, *CurDAG);
  45 }]>;
  46 def vpkudum_shuffle : PatFrag<(ops node:$lhs, node:$rhs),
  47                               (vector_shuffle node:$lhs, node:$rhs), [{
  48   return PPC::isVPKUDUMShuffleMask(cast<ShuffleVectorSDNode>(N), 0, *CurDAG);
  49 }]>;
  50 def vpkuhum_unary_shuffle : PatFrag<(ops node:$lhs, node:$rhs),
  51                                     (vector_shuffle node:$lhs, node:$rhs), [{
  52   return PPC::isVPKUHUMShuffleMask(cast<ShuffleVectorSDNode>(N), 1, *CurDAG);
  53 }]>;
  54 def vpkuwum_unary_shuffle : PatFrag<(ops node:$lhs, node:$rhs),
  55                                     (vector_shuffle node:$lhs, node:$rhs), [{
  56   return PPC::isVPKUWUMShuffleMask(cast<ShuffleVectorSDNode>(N), 1, *CurDAG);
  57 }]>;
  58 def vpkudum_unary_shuffle : PatFrag<(ops node:$lhs, node:$rhs),
  59                                     (vector_shuffle node:$lhs, node:$rhs), [{
  60   return PPC::isVPKUDUMShuffleMask(cast<ShuffleVectorSDNode>(N), 1, *CurDAG);
  61 }]>;
  62
  63 // These fragments are provided for little-endian, where the inputs must be
  64 // swapped for correct semantics.
  65 def vpkuhum_swapped_shuffle : PatFrag<(ops node:$lhs, node:$rhs),
  66                                       (vector_shuffle node:$lhs, node:$rhs), [{
  67   return PPC::isVPKUHUMShuffleMask(cast<ShuffleVectorSDNode>(N), 2, *CurDAG);
  68 }]>;
  69 def vpkuwum_swapped_shuffle : PatFrag<(ops node:$lhs, node:$rhs),
  70                                       (vector_shuffle node:$lhs, node:$rhs), [{
  71   return PPC::isVPKUWUMShuffleMask(cast<ShuffleVectorSDNode>(N), 2, *CurDAG);
  72 }]>;
  73 def vpkudum_swapped_shuffle : PatFrag<(ops node:$lhs, node:$rhs),
  74                                       (vector_shuffle node:$lhs, node:$rhs), [{
  75   return PPC::isVPKUDUMShuffleMask(cast<ShuffleVectorSDNode>(N), 2, *CurDAG);
  76 }]>;
  77
  78 def vmrglb_shuffle : PatFrag<(ops node:$lhs, node:$rhs),
  79                              (vector_shuffle (v16i8 node:$lhs), node:$rhs), [{
  80   return PPC::isVMRGLShuffleMask(cast<ShuffleVectorSDNode>(N), 1, 0, *CurDAG);
  81 }]>;
  82 def vmrglh_shuffle : PatFrag<(ops node:$lhs, node:$rhs),
  83                              (vector_shuffle (v16i8 node:$lhs), node:$rhs), [{
  84   return PPC::isVMRGLShuffleMask(cast<ShuffleVectorSDNode>(N), 2, 0, *CurDAG);
  85 }]>;
  86 def vmrglw_shuffle : PatFrag<(ops node:$lhs, node:$rhs),
  87                              (vector_shuffle (v16i8 node:$lhs), node:$rhs), [{
  88   return PPC::isVMRGLShuffleMask(cast<ShuffleVectorSDNode>(N), 4, 0, *CurDAG);
  89 }]>;
  90 def vmrghb_shuffle : PatFrag<(ops node:$lhs, node:$rhs),
  91                              (vector_shuffle (v16i8 node:$lhs), node:$rhs), [{
  92   return PPC::isVMRGHShuffleMask(cast<ShuffleVectorSDNode>(N), 1, 0, *CurDAG);
  93 }]>;
  94 def vmrghh_shuffle : PatFrag<(ops node:$lhs, node:$rhs),
  95                              (vector_shuffle (v16i8 node:$lhs), node:$rhs), [{
  96   return PPC::isVMRGHShuffleMask(cast<ShuffleVectorSDNode>(N), 2, 0, *CurDAG);
  97 }]>;
  98 def vmrghw_shuffle : PatFrag<(ops node:$lhs, node:$rhs),
  99                              (vector_shuffle (v16i8 node:$lhs), node:$rhs), [{
 100   return PPC::isVMRGHShuffleMask(cast<ShuffleVectorSDNode>(N), 4, 0, *CurDAG);
 101 }]>;
 102
 103
 104 def vmrglb_unary_shuffle : PatFrag<(ops node:$lhs, node:$rhs),
 105                                (vector_shuffle (v16i8 node:$lhs), node:$rhs), [{
 106   return PPC::isVMRGLShuffleMask(cast<ShuffleVectorSDNode>(N), 1, 1, *CurDAG);
 107 }]>;
 108 def vmrglh_unary_shuffle : PatFrag<(ops node:$lhs, node:$rhs),
 109                                    (vector_shuffle node:$lhs, node:$rhs), [{
 110   return PPC::isVMRGLShuffleMask(cast<ShuffleVectorSDNode>(N), 2, 1, *CurDAG);
 111 }]>;
 112 def vmrglw_unary_shuffle : PatFrag<(ops node:$lhs, node:$rhs),
 113                                    (vector_shuffle node:$lhs, node:$rhs), [{
 114   return PPC::isVMRGLShuffleMask(cast<ShuffleVectorSDNode>(N), 4, 1, *CurDAG);
 115 }]>;
 116 def vmrghb_unary_shuffle : PatFrag<(ops node:$lhs, node:$rhs),
 117                                    (vector_shuffle node:$lhs, node:$rhs), [{
 118   return PPC::isVMRGHShuffleMask(cast<ShuffleVectorSDNode>(N), 1, 1, *CurDAG);
 119 }]>;
 120 def vmrghh_unary_shuffle : PatFrag<(ops node:$lhs, node:$rhs),
 121                                    (vector_shuffle node:$lhs, node:$rhs), [{
 122   return PPC::isVMRGHShuffleMask(cast<ShuffleVectorSDNode>(N), 2, 1, *CurDAG);
 123 }]>;
 124 def vmrghw_unary_shuffle : PatFrag<(ops node:$lhs, node:$rhs),
 125                                    (vector_shuffle node:$lhs, node:$rhs), [{
 126   return PPC::isVMRGHShuffleMask(cast<ShuffleVectorSDNode>(N), 4, 1, *CurDAG);
 127 }]>;
 128
 129
 130 // These fragments are provided for little-endian, where the inputs must be
 131 // swapped for correct semantics.
 132 def vmrglb_swapped_shuffle : PatFrag<(ops node:$lhs, node:$rhs),
 133                                (vector_shuffle (v16i8 node:$lhs), node:$rhs), [{
 134   return PPC::isVMRGLShuffleMask(cast<ShuffleVectorSDNode>(N), 1, 2, *CurDAG);
 135 }]>;
 136 def vmrglh_swapped_shuffle : PatFrag<(ops node:$lhs, node:$rhs),
 137                                    (vector_shuffle node:$lhs, node:$rhs), [{
 138   return PPC::isVMRGLShuffleMask(cast<ShuffleVectorSDNode>(N), 2, 2, *CurDAG);
 139 }]>;
 140 def vmrglw_swapped_shuffle : PatFrag<(ops node:$lhs, node:$rhs),
 141                                    (vector_shuffle node:$lhs, node:$rhs), [{
 142   return PPC::isVMRGLShuffleMask(cast<ShuffleVectorSDNode>(N), 4, 2, *CurDAG);
 143 }]>;
 144 def vmrghb_swapped_shuffle : PatFrag<(ops node:$lhs, node:$rhs),
 145                                    (vector_shuffle node:$lhs, node:$rhs), [{
 146   return PPC::isVMRGHShuffleMask(cast<ShuffleVectorSDNode>(N), 1, 2, *CurDAG);
 147 }]>;
 148 def vmrghh_swapped_shuffle : PatFrag<(ops node:$lhs, node:$rhs),
 149                                    (vector_shuffle node:$lhs, node:$rhs), [{
 150   return PPC::isVMRGHShuffleMask(cast<ShuffleVectorSDNode>(N), 2, 2, *CurDAG);
 151 }]>;
 152 def vmrghw_swapped_shuffle : PatFrag<(ops node:$lhs, node:$rhs),
 153                                    (vector_shuffle node:$lhs, node:$rhs), [{
 154   return PPC::isVMRGHShuffleMask(cast<ShuffleVectorSDNode>(N), 4, 2, *CurDAG);
 155 }]>;
 156
 157
 158 def VSLDOI_get_imm : SDNodeXForm<vector_shuffle, [{
 159   return getI32Imm(PPC::isVSLDOIShuffleMask(N, 0, *CurDAG), SDLoc(N));
 160 }]>;
 161 def vsldoi_shuffle : PatFrag<(ops node:$lhs, node:$rhs),
 162                              (vector_shuffle node:$lhs, node:$rhs), [{
 163   return PPC::isVSLDOIShuffleMask(N, 0, *CurDAG) != -1;
 164 }], VSLDOI_get_imm>;
 165
 166
 167 /// VSLDOI_unary* - These are used to match vsldoi(X,X), which is turned into
 168 /// vector_shuffle(X,undef,mask) by the dag combiner.
 169 def VSLDOI_unary_get_imm : SDNodeXForm<vector_shuffle, [{
 170   return getI32Imm(PPC::isVSLDOIShuffleMask(N, 1, *CurDAG), SDLoc(N));
 171 }]>;
 172 def vsldoi_unary_shuffle : PatFrag<(ops node:$lhs, node:$rhs),
 173                                    (vector_shuffle node:$lhs, node:$rhs), [{
 174   return PPC::isVSLDOIShuffleMask(N, 1, *CurDAG) != -1;
 175 }], VSLDOI_unary_get_imm>;
 176
 177
 178 /// VSLDOI_swapped* - These fragments are provided for little-endian, where
 179 /// the inputs must be swapped for correct semantics.
 180 def VSLDOI_swapped_get_imm : SDNodeXForm<vector_shuffle, [{
 181   return getI32Imm(PPC::isVSLDOIShuffleMask(N, 2, *CurDAG), SDLoc(N));
 182 }]>;
 183 def vsldoi_swapped_shuffle : PatFrag<(ops node:$lhs, node:$rhs),
 184                                      (vector_shuffle node:$lhs, node:$rhs), [{
 185   return PPC::isVSLDOIShuffleMask(N, 2, *CurDAG) != -1;
 186 }], VSLDOI_get_imm>;
 187
 188
 189 // VSPLT*_get_imm xform function: convert vector_shuffle mask to VSPLT* imm.
 190 def VSPLTB_get_imm : SDNodeXForm<vector_shuffle, [{
 191   return getI32Imm(PPC::getVSPLTImmediate(N, 1, *CurDAG), SDLoc(N));
 192 }]>;
 193 def vspltb_shuffle : PatFrag<(ops node:$lhs, node:$rhs),
 194                              (vector_shuffle node:$lhs, node:$rhs), [{
 195   return PPC::isSplatShuffleMask(cast<ShuffleVectorSDNode>(N), 1);
 196 }], VSPLTB_get_imm>;
 197 def VSPLTH_get_imm : SDNodeXForm<vector_shuffle, [{
 198   return getI32Imm(PPC::getVSPLTImmediate(N, 2, *CurDAG), SDLoc(N));
 199 }]>;
 200 def vsplth_shuffle : PatFrag<(ops node:$lhs, node:$rhs),
 201                              (vector_shuffle node:$lhs, node:$rhs), [{
 202   return PPC::isSplatShuffleMask(cast<ShuffleVectorSDNode>(N), 2);
 203 }], VSPLTH_get_imm>;
 204 def VSPLTW_get_imm : SDNodeXForm<vector_shuffle, [{
 205   return getI32Imm(PPC::getVSPLTImmediate(N, 4, *CurDAG), SDLoc(N));
 206 }]>;
 207 def vspltw_shuffle : PatFrag<(ops node:$lhs, node:$rhs),
 208                              (vector_shuffle node:$lhs, node:$rhs), [{
 209   return PPC::isSplatShuffleMask(cast<ShuffleVectorSDNode>(N), 4);
 210 }], VSPLTW_get_imm>;
 211
 212
 213 // VSPLTISB_get_imm xform function: convert build_vector to VSPLTISB imm.
 214 def VSPLTISB_get_imm : SDNodeXForm<build_vector, [{
 215   return PPC::get_VSPLTI_elt(N, 1, *CurDAG);
 216 }]>;
 217 def vecspltisb : PatLeaf<(build_vector), [{
 218   return PPC::get_VSPLTI_elt(N, 1, *CurDAG).getNode() != 0;
 219 }], VSPLTISB_get_imm>;
 220
 221 // VSPLTISH_get_imm xform function: convert build_vector to VSPLTISH imm.
 222 def VSPLTISH_get_imm : SDNodeXForm<build_vector, [{
 223   return PPC::get_VSPLTI_elt(N, 2, *CurDAG);
 224 }]>;
 225 def vecspltish : PatLeaf<(build_vector), [{
 226   return PPC::get_VSPLTI_elt(N, 2, *CurDAG).getNode() != 0;
 227 }], VSPLTISH_get_imm>;
 228
 229 // VSPLTISW_get_imm xform function: convert build_vector to VSPLTISW imm.
 230 def VSPLTISW_get_imm : SDNodeXForm<build_vector, [{
 231   return PPC::get_VSPLTI_elt(N, 4, *CurDAG);
 232 }]>;
 233 def vecspltisw : PatLeaf<(build_vector), [{
 234   return PPC::get_VSPLTI_elt(N, 4, *CurDAG).getNode() != 0;
 235 }], VSPLTISW_get_imm>;
 236
 237 //===----------------------------------------------------------------------===//
 238 // Helpers for defining instructions that directly correspond to intrinsics.
 239
 240 // VA1a_Int_Ty - A VAForm_1a intrinsic definition of specific type.
 241 class VA1a_Int_Ty<bits<6> xo, string opc, Intrinsic IntID, ValueType Ty>
 242   : VAForm_1a<xo, (outs vrrc:$vD), (ins vrrc:$vA, vrrc:$vB, vrrc:$vC),
 243               !strconcat(opc, " $vD, $vA, $vB, $vC"), IIC_VecFP,
 244                        [(set Ty:$vD, (IntID Ty:$vA, Ty:$vB, Ty:$vC))]>;
 245
 246 // VA1a_Int_Ty2 - A VAForm_1a intrinsic definition where the type of the
 247 // inputs doesn't match the type of the output.
 248 class VA1a_Int_Ty2<bits<6> xo, string opc, Intrinsic IntID, ValueType OutTy,
 249                    ValueType InTy>
 250   : VAForm_1a<xo, (outs vrrc:$vD), (ins vrrc:$vA, vrrc:$vB, vrrc:$vC),
 251               !strconcat(opc, " $vD, $vA, $vB, $vC"), IIC_VecFP,
 252                        [(set OutTy:$vD, (IntID InTy:$vA, InTy:$vB, InTy:$vC))]>;
 253
 254 // VA1a_Int_Ty3 - A VAForm_1a intrinsic definition where there are two
 255 // input types and an output type.
 256 class VA1a_Int_Ty3<bits<6> xo, string opc, Intrinsic IntID, ValueType OutTy,
 257                    ValueType In1Ty, ValueType In2Ty>
 258   : VAForm_1a<xo, (outs vrrc:$vD), (ins vrrc:$vA, vrrc:$vB, vrrc:$vC),
 259               !strconcat(opc, " $vD, $vA, $vB, $vC"), IIC_VecFP,
 260                        [(set OutTy:$vD,
 261                          (IntID In1Ty:$vA, In1Ty:$vB, In2Ty:$vC))]>;
 262
 263 // VX1_Int_Ty - A VXForm_1 intrinsic definition of specific type.
 264 class VX1_Int_Ty<bits<11> xo, string opc, Intrinsic IntID, ValueType Ty>
 265   : VXForm_1<xo, (outs vrrc:$vD), (ins vrrc:$vA, vrrc:$vB),
 266              !strconcat(opc, " $vD, $vA, $vB"), IIC_VecFP,
 267              [(set Ty:$vD, (IntID Ty:$vA, Ty:$vB))]>;
 268
 269 // VX1_Int_Ty2 - A VXForm_1 intrinsic definition where the type of the
 270 // inputs doesn't match the type of the output.
 271 class VX1_Int_Ty2<bits<11> xo, string opc, Intrinsic IntID, ValueType OutTy,
 272                   ValueType InTy>
 273   : VXForm_1<xo, (outs vrrc:$vD), (ins vrrc:$vA, vrrc:$vB),
 274              !strconcat(opc, " $vD, $vA, $vB"), IIC_VecFP,
 275              [(set OutTy:$vD, (IntID InTy:$vA, InTy:$vB))]>;
 276
 277 // VX1_Int_Ty3 - A VXForm_1 intrinsic definition where there are two
 278 // input types and an output type.
 279 class VX1_Int_Ty3<bits<11> xo, string opc, Intrinsic IntID, ValueType OutTy,
 280                   ValueType In1Ty, ValueType In2Ty>
 281   : VXForm_1<xo, (outs vrrc:$vD), (ins vrrc:$vA, vrrc:$vB),
 282              !strconcat(opc, " $vD, $vA, $vB"), IIC_VecFP,
 283              [(set OutTy:$vD, (IntID In1Ty:$vA, In2Ty:$vB))]>;
 284
 285 // VX2_Int_SP - A VXForm_2 intrinsic definition of vector single-precision type.
 286 class VX2_Int_SP<bits<11> xo, string opc, Intrinsic IntID>
 287   : VXForm_2<xo, (outs vrrc:$vD), (ins vrrc:$vB),
 288              !strconcat(opc, " $vD, $vB"), IIC_VecFP,
 289              [(set v4f32:$vD, (IntID v4f32:$vB))]>;
 290
 291 // VX2_Int_Ty2 - A VXForm_2 intrinsic definition where the type of the
 292 // inputs doesn't match the type of the output.
 293 class VX2_Int_Ty2<bits<11> xo, string opc, Intrinsic IntID, ValueType OutTy,
 294                   ValueType InTy>
 295   : VXForm_2<xo, (outs vrrc:$vD), (ins vrrc:$vB),
 296              !strconcat(opc, " $vD, $vB"), IIC_VecFP,
 297              [(set OutTy:$vD, (IntID InTy:$vB))]>;
 298
 299 class VXBX_Int_Ty<bits<11> xo, string opc, Intrinsic IntID, ValueType Ty>
 300   : VXForm_BX<xo, (outs vrrc:$vD), (ins vrrc:$vA),
 301              !strconcat(opc, " $vD, $vA"), IIC_VecFP,
 302              [(set Ty:$vD, (IntID Ty:$vA))]>;
 303
 304 class VXCR_Int_Ty<bits<11> xo, string opc, Intrinsic IntID, ValueType Ty>
 305   : VXForm_CR<xo, (outs vrrc:$vD), (ins vrrc:$vA, u1imm:$ST, u4imm:$SIX),
 306               !strconcat(opc, " $vD, $vA, $ST, $SIX"), IIC_VecFP,
 307               [(set Ty:$vD, (IntID Ty:$vA, imm:$ST, imm:$SIX))]>;
 308
 309 //===----------------------------------------------------------------------===//
 310 // Instruction Definitions.
 311
 312 def HasAltivec : Predicate<"PPCSubTarget->hasAltivec()">;
 313 let Predicates = [HasAltivec] in {
 314
 315 def DSS      : DSS_Form<0, 822, (outs), (ins u5imm:$STRM),
 316                         "dss $STRM", IIC_LdStLoad /*FIXME*/, [(int_ppc_altivec_dss imm:$STRM)]>,
 317                         Deprecated<DeprecatedDST> {
 318   let A = 0;
 319   let B = 0;
 320 }
 321
 322 def DSSALL   : DSS_Form<1, 822, (outs), (ins),
 323                         "dssall", IIC_LdStLoad /*FIXME*/, [(int_ppc_altivec_dssall)]>,
 324                         Deprecated<DeprecatedDST> {
 325   let STRM = 0;
 326   let A = 0;
 327   let B = 0;
 328 }
 329
 330 def DST      : DSS_Form<0, 342, (outs), (ins u5imm:$STRM, gprc:$rA, gprc:$rB),
 331                         "dst $rA, $rB, $STRM", IIC_LdStLoad /*FIXME*/,
 332                         [(int_ppc_altivec_dst i32:$rA, i32:$rB, imm:$STRM)]>,
 333                         Deprecated<DeprecatedDST>;
 334
 335 def DSTT     : DSS_Form<1, 342, (outs), (ins u5imm:$STRM, gprc:$rA, gprc:$rB),
 336                         "dstt $rA, $rB, $STRM", IIC_LdStLoad /*FIXME*/,
 337                         [(int_ppc_altivec_dstt i32:$rA, i32:$rB, imm:$STRM)]>,
 338                         Deprecated<DeprecatedDST>;
 339
 340 def DSTST    : DSS_Form<0, 374, (outs), (ins u5imm:$STRM, gprc:$rA, gprc:$rB),
 341                         "dstst $rA, $rB, $STRM", IIC_LdStLoad /*FIXME*/,
 342                         [(int_ppc_altivec_dstst i32:$rA, i32:$rB, imm:$STRM)]>,
 343                         Deprecated<DeprecatedDST>;
 344
 345 def DSTSTT   : DSS_Form<1, 374, (outs), (ins u5imm:$STRM, gprc:$rA, gprc:$rB),
 346                         "dststt $rA, $rB, $STRM", IIC_LdStLoad /*FIXME*/,
 347                         [(int_ppc_altivec_dststt i32:$rA, i32:$rB, imm:$STRM)]>,
 348                         Deprecated<DeprecatedDST>;
 349
 350 let isCodeGenOnly = 1 in {
 351   // The very same instructions as above, but formally matching 64bit registers.
 352   def DST64    : DSS_Form<0, 342, (outs), (ins u5imm:$STRM, g8rc:$rA, gprc:$rB),
 353                           "dst $rA, $rB, $STRM", IIC_LdStLoad /*FIXME*/,
 354                           [(int_ppc_altivec_dst i64:$rA, i32:$rB, imm:$STRM)]>,
 355                           Deprecated<DeprecatedDST>;
 356
 357   def DSTT64   : DSS_Form<1, 342, (outs), (ins u5imm:$STRM, g8rc:$rA, gprc:$rB),
 358                           "dstt $rA, $rB, $STRM", IIC_LdStLoad /*FIXME*/,
 359                           [(int_ppc_altivec_dstt i64:$rA, i32:$rB, imm:$STRM)]>,
 360                           Deprecated<DeprecatedDST>;
 361
 362   def DSTST64  : DSS_Form<0, 374, (outs), (ins u5imm:$STRM, g8rc:$rA, gprc:$rB),
 363                           "dstst $rA, $rB, $STRM", IIC_LdStLoad /*FIXME*/,
 364                           [(int_ppc_altivec_dstst i64:$rA, i32:$rB,
 365                                                   imm:$STRM)]>,
 366                           Deprecated<DeprecatedDST>;
 367
 368   def DSTSTT64 : DSS_Form<1, 374, (outs), (ins u5imm:$STRM, g8rc:$rA, gprc:$rB),
 369                           "dststt $rA, $rB, $STRM", IIC_LdStLoad /*FIXME*/,
 370                           [(int_ppc_altivec_dststt i64:$rA, i32:$rB,
 371                                                    imm:$STRM)]>,
 372                           Deprecated<DeprecatedDST>;
 373 }
 374
 375 def MFVSCR : VXForm_4<1540, (outs vrrc:$vD), (ins),
 376                       "mfvscr $vD", IIC_LdStStore,
 377                       [(set v8i16:$vD, (int_ppc_altivec_mfvscr))]>;
 378 def MTVSCR : VXForm_5<1604, (outs), (ins vrrc:$vB),
 379                       "mtvscr $vB", IIC_LdStLoad,
 380                       [(int_ppc_altivec_mtvscr v4i32:$vB)]>;
 381
 382 let PPC970_Unit = 2 in {  // Loads.
 383 def LVEBX: XForm_1<31,   7, (outs vrrc:$vD), (ins memrr:$src),
 384                    "lvebx $vD, $src", IIC_LdStLoad,
 385                    [(set v16i8:$vD, (int_ppc_altivec_lvebx xoaddr:$src))]>;
 386 def LVEHX: XForm_1<31,  39, (outs vrrc:$vD), (ins memrr:$src),
 387                    "lvehx $vD, $src", IIC_LdStLoad,
 388                    [(set v8i16:$vD, (int_ppc_altivec_lvehx xoaddr:$src))]>;
 389 def LVEWX: XForm_1<31,  71, (outs vrrc:$vD), (ins memrr:$src),
 390                    "lvewx $vD, $src", IIC_LdStLoad,
 391                    [(set v4i32:$vD, (int_ppc_altivec_lvewx xoaddr:$src))]>;
 392 def LVX  : XForm_1<31, 103, (outs vrrc:$vD), (ins memrr:$src),
 393                    "lvx $vD, $src", IIC_LdStLoad,
 394                    [(set v4i32:$vD, (int_ppc_altivec_lvx xoaddr:$src))]>;
 395 def LVXL : XForm_1<31, 359, (outs vrrc:$vD), (ins memrr:$src),
 396                    "lvxl $vD, $src", IIC_LdStLoad,
 397                    [(set v4i32:$vD, (int_ppc_altivec_lvxl xoaddr:$src))]>;
 398 }
 399
 400 def LVSL : XForm_1<31,   6, (outs vrrc:$vD), (ins memrr:$src),
 401                    "lvsl $vD, $src", IIC_LdStLoad,
 402                    [(set v16i8:$vD, (int_ppc_altivec_lvsl xoaddr:$src))]>,
 403                    PPC970_Unit_LSU;
 404 def LVSR : XForm_1<31,  38, (outs vrrc:$vD), (ins memrr:$src),
 405                    "lvsr $vD, $src", IIC_LdStLoad,
 406                    [(set v16i8:$vD, (int_ppc_altivec_lvsr xoaddr:$src))]>,
 407                    PPC970_Unit_LSU;
 408
 409 let PPC970_Unit = 2 in {   // Stores.
 410 def STVEBX: XForm_8<31, 135, (outs), (ins vrrc:$rS, memrr:$dst),
 411                    "stvebx $rS, $dst", IIC_LdStStore,
 412                    [(int_ppc_altivec_stvebx v16i8:$rS, xoaddr:$dst)]>;
 413 def STVEHX: XForm_8<31, 167, (outs), (ins vrrc:$rS, memrr:$dst),
 414                    "stvehx $rS, $dst", IIC_LdStStore,
 415                    [(int_ppc_altivec_stvehx v8i16:$rS, xoaddr:$dst)]>;
 416 def STVEWX: XForm_8<31, 199, (outs), (ins vrrc:$rS, memrr:$dst),
 417                    "stvewx $rS, $dst", IIC_LdStStore,
 418                    [(int_ppc_altivec_stvewx v4i32:$rS, xoaddr:$dst)]>;
 419 def STVX  : XForm_8<31, 231, (outs), (ins vrrc:$rS, memrr:$dst),
 420                    "stvx $rS, $dst", IIC_LdStStore,
 421                    [(int_ppc_altivec_stvx v4i32:$rS, xoaddr:$dst)]>;
 422 def STVXL : XForm_8<31, 487, (outs), (ins vrrc:$rS, memrr:$dst),
 423                    "stvxl $rS, $dst", IIC_LdStStore,
 424                    [(int_ppc_altivec_stvxl v4i32:$rS, xoaddr:$dst)]>;
 425 }
 426
 427 let PPC970_Unit = 5 in {  // VALU Operations.
 428 // VA-Form instructions.  3-input AltiVec ops.
 429 let isCommutable = 1 in {
 430 def VMADDFP : VAForm_1<46, (outs vrrc:$vD), (ins vrrc:$vA, vrrc:$vC, vrrc:$vB),
 431                        "vmaddfp $vD, $vA, $vC, $vB", IIC_VecFP,
 432                        [(set v4f32:$vD,
 433                         (fma v4f32:$vA, v4f32:$vC, v4f32:$vB))]>;
 434
 435 // FIXME: The fma+fneg pattern won't match because fneg is not legal.
 436 def VNMSUBFP: VAForm_1<47, (outs vrrc:$vD), (ins vrrc:$vA, vrrc:$vC, vrrc:$vB),
 437                        "vnmsubfp $vD, $vA, $vC, $vB", IIC_VecFP,
 438                        [(set v4f32:$vD, (fneg (fma v4f32:$vA, v4f32:$vC,
 439                                                   (fneg v4f32:$vB))))]>;
 440
 441 def VMHADDSHS  : VA1a_Int_Ty<32, "vmhaddshs", int_ppc_altivec_vmhaddshs, v8i16>;
 442 def VMHRADDSHS : VA1a_Int_Ty<33, "vmhraddshs", int_ppc_altivec_vmhraddshs,
 443                              v8i16>;
 444 def VMLADDUHM  : VA1a_Int_Ty<34, "vmladduhm", int_ppc_altivec_vmladduhm, v8i16>;
 445 } // isCommutable
 446
 447 def VPERM      : VA1a_Int_Ty3<43, "vperm", int_ppc_altivec_vperm,
 448                               v4i32, v4i32, v16i8>;
 449 def VSEL       : VA1a_Int_Ty<42, "vsel",  int_ppc_altivec_vsel, v4i32>;
 450
 451 // Shuffles.
 452 def VSLDOI  : VAForm_2<44, (outs vrrc:$vD), (ins vrrc:$vA, vrrc:$vB, u5imm:$SH),
 453                        "vsldoi $vD, $vA, $vB, $SH", IIC_VecFP,
 454                        [(set v16i8:$vD,
 455                          (vsldoi_shuffle:$SH v16i8:$vA, v16i8:$vB))]>;
 456
 457 // VX-Form instructions.  AltiVec arithmetic ops.
 458 let isCommutable = 1 in {
 459 def VADDFP : VXForm_1<10, (outs vrrc:$vD), (ins vrrc:$vA, vrrc:$vB),
 460                       "vaddfp $vD, $vA, $vB", IIC_VecFP,
 461                       [(set v4f32:$vD, (fadd v4f32:$vA, v4f32:$vB))]>;
 462
 463 def VADDUBM : VXForm_1<0, (outs vrrc:$vD), (ins vrrc:$vA, vrrc:$vB),
 464                       "vaddubm $vD, $vA, $vB", IIC_VecGeneral,
 465                       [(set v16i8:$vD, (add v16i8:$vA, v16i8:$vB))]>;
 466 def VADDUHM : VXForm_1<64, (outs vrrc:$vD), (ins vrrc:$vA, vrrc:$vB),
 467                       "vadduhm $vD, $vA, $vB", IIC_VecGeneral,
 468                       [(set v8i16:$vD, (add v8i16:$vA, v8i16:$vB))]>;
 469 def VADDUWM : VXForm_1<128, (outs vrrc:$vD), (ins vrrc:$vA, vrrc:$vB),
 470                       "vadduwm $vD, $vA, $vB", IIC_VecGeneral,
 471                       [(set v4i32:$vD, (add v4i32:$vA, v4i32:$vB))]>;
 472
 473 def VADDCUW : VX1_Int_Ty<384, "vaddcuw", int_ppc_altivec_vaddcuw, v4i32>;
 474 def VADDSBS : VX1_Int_Ty<768, "vaddsbs", int_ppc_altivec_vaddsbs, v16i8>;
 475 def VADDSHS : VX1_Int_Ty<832, "vaddshs", int_ppc_altivec_vaddshs, v8i16>;
 476 def VADDSWS : VX1_Int_Ty<896, "vaddsws", int_ppc_altivec_vaddsws, v4i32>;
 477 def VADDUBS : VX1_Int_Ty<512, "vaddubs", int_ppc_altivec_vaddubs, v16i8>;
 478 def VADDUHS : VX1_Int_Ty<576, "vadduhs", int_ppc_altivec_vadduhs, v8i16>;
 479 def VADDUWS : VX1_Int_Ty<640, "vadduws", int_ppc_altivec_vadduws, v4i32>;
 480 } // isCommutable
 481
 482 let isCommutable = 1 in
 483 def VAND : VXForm_1<1028, (outs vrrc:$vD), (ins vrrc:$vA, vrrc:$vB),
 484                     "vand $vD, $vA, $vB", IIC_VecFP,
 485                     [(set v4i32:$vD, (and v4i32:$vA, v4i32:$vB))]>;
 486 def VANDC : VXForm_1<1092, (outs vrrc:$vD), (ins vrrc:$vA, vrrc:$vB),
 487                      "vandc $vD, $vA, $vB", IIC_VecFP,
 488                      [(set v4i32:$vD, (and v4i32:$vA,
 489                                            (vnot_ppc v4i32:$vB)))]>;
 490
 491 def VCFSX  : VXForm_1<842, (outs vrrc:$vD), (ins u5imm:$UIMM, vrrc:$vB),
 492                       "vcfsx $vD, $vB, $UIMM", IIC_VecFP,
 493                       [(set v4f32:$vD,
 494                              (int_ppc_altivec_vcfsx v4i32:$vB, imm:$UIMM))]>;
 495 def VCFUX  : VXForm_1<778, (outs vrrc:$vD), (ins u5imm:$UIMM, vrrc:$vB),
 496                       "vcfux $vD, $vB, $UIMM", IIC_VecFP,
 497                       [(set v4f32:$vD,
 498                              (int_ppc_altivec_vcfux v4i32:$vB, imm:$UIMM))]>;
 499 def VCTSXS : VXForm_1<970, (outs vrrc:$vD), (ins u5imm:$UIMM, vrrc:$vB),
 500                       "vctsxs $vD, $vB, $UIMM", IIC_VecFP,
 501                       [(set v4i32:$vD,
 502                              (int_ppc_altivec_vctsxs v4f32:$vB, imm:$UIMM))]>;
 503 def VCTUXS : VXForm_1<906, (outs vrrc:$vD), (ins u5imm:$UIMM, vrrc:$vB),
 504                       "vctuxs $vD, $vB, $UIMM", IIC_VecFP,
 505                       [(set v4i32:$vD,
 506                              (int_ppc_altivec_vctuxs v4f32:$vB, imm:$UIMM))]>;
 507
 508 // Defines with the UIM field set to 0 for floating-point
 509 // to integer (fp_to_sint/fp_to_uint) conversions and integer
 510 // to floating-point (sint_to_fp/uint_to_fp) conversions.
 511 let isCodeGenOnly = 1, VA = 0 in {
 512 def VCFSX_0 : VXForm_1<842, (outs vrrc:$vD), (ins vrrc:$vB),
 513                        "vcfsx $vD, $vB, 0", IIC_VecFP,
 514                        [(set v4f32:$vD,
 515                              (int_ppc_altivec_vcfsx v4i32:$vB, 0))]>;
 516 def VCTUXS_0 : VXForm_1<906, (outs vrrc:$vD), (ins vrrc:$vB),
 517                         "vctuxs $vD, $vB, 0", IIC_VecFP,
 518                         [(set v4i32:$vD,
 519                                (int_ppc_altivec_vctuxs v4f32:$vB, 0))]>;
 520 def VCFUX_0 : VXForm_1<778, (outs vrrc:$vD), (ins vrrc:$vB),
 521                        "vcfux $vD, $vB, 0", IIC_VecFP,
 522                        [(set v4f32:$vD,
 523                                (int_ppc_altivec_vcfux v4i32:$vB, 0))]>;
 524 def VCTSXS_0 : VXForm_1<970, (outs vrrc:$vD), (ins vrrc:$vB),
 525                       "vctsxs $vD, $vB, 0", IIC_VecFP,
 526                       [(set v4i32:$vD,
 527                              (int_ppc_altivec_vctsxs v4f32:$vB, 0))]>;
 528 }
 529 def VEXPTEFP : VX2_Int_SP<394, "vexptefp", int_ppc_altivec_vexptefp>;
 530 def VLOGEFP  : VX2_Int_SP<458, "vlogefp",  int_ppc_altivec_vlogefp>;
 531
 532 let isCommutable = 1 in {
 533 def VAVGSB : VX1_Int_Ty<1282, "vavgsb", int_ppc_altivec_vavgsb, v16i8>;
 534 def VAVGSH : VX1_Int_Ty<1346, "vavgsh", int_ppc_altivec_vavgsh, v8i16>;
 535 def VAVGSW : VX1_Int_Ty<1410, "vavgsw", int_ppc_altivec_vavgsw, v4i32>;
 536 def VAVGUB : VX1_Int_Ty<1026, "vavgub", int_ppc_altivec_vavgub, v16i8>;
 537 def VAVGUH : VX1_Int_Ty<1090, "vavguh", int_ppc_altivec_vavguh, v8i16>;
 538 def VAVGUW : VX1_Int_Ty<1154, "vavguw", int_ppc_altivec_vavguw, v4i32>;
 539
 540 def VMAXFP : VX1_Int_Ty<1034, "vmaxfp", int_ppc_altivec_vmaxfp, v4f32>;
 541 def VMAXSB : VX1_Int_Ty< 258, "vmaxsb", int_ppc_altivec_vmaxsb, v16i8>;
 542 def VMAXSH : VX1_Int_Ty< 322, "vmaxsh", int_ppc_altivec_vmaxsh, v8i16>;
 543 def VMAXSW : VX1_Int_Ty< 386, "vmaxsw", int_ppc_altivec_vmaxsw, v4i32>;
 544 def VMAXUB : VX1_Int_Ty<   2, "vmaxub", int_ppc_altivec_vmaxub, v16i8>;
 545 def VMAXUH : VX1_Int_Ty<  66, "vmaxuh", int_ppc_altivec_vmaxuh, v8i16>;
 546 def VMAXUW : VX1_Int_Ty< 130, "vmaxuw", int_ppc_altivec_vmaxuw, v4i32>;
 547 def VMINFP : VX1_Int_Ty<1098, "vminfp", int_ppc_altivec_vminfp, v4f32>;
 548 def VMINSB : VX1_Int_Ty< 770, "vminsb", int_ppc_altivec_vminsb, v16i8>;
 549 def VMINSH : VX1_Int_Ty< 834, "vminsh", int_ppc_altivec_vminsh, v8i16>;
 550 def VMINSW : VX1_Int_Ty< 898, "vminsw", int_ppc_altivec_vminsw, v4i32>;
 551 def VMINUB : VX1_Int_Ty< 514, "vminub", int_ppc_altivec_vminub, v16i8>;
 552 def VMINUH : VX1_Int_Ty< 578, "vminuh", int_ppc_altivec_vminuh, v8i16>;
 553 def VMINUW : VX1_Int_Ty< 642, "vminuw", int_ppc_altivec_vminuw, v4i32>;
 554 } // isCommutable
 555
 556 def VMRGHB : VXForm_1< 12, (outs vrrc:$vD), (ins vrrc:$vA, vrrc:$vB),
 557                       "vmrghb $vD, $vA, $vB", IIC_VecFP,
 558                       [(set v16i8:$vD, (vmrghb_shuffle v16i8:$vA, v16i8:$vB))]>;
 559 def VMRGHH : VXForm_1< 76, (outs vrrc:$vD), (ins vrrc:$vA, vrrc:$vB),
 560                       "vmrghh $vD, $vA, $vB", IIC_VecFP,
 561                       [(set v16i8:$vD, (vmrghh_shuffle v16i8:$vA, v16i8:$vB))]>;
 562 def VMRGHW : VXForm_1<140, (outs vrrc:$vD), (ins vrrc:$vA, vrrc:$vB),
 563                       "vmrghw $vD, $vA, $vB", IIC_VecFP,
 564                       [(set v16i8:$vD, (vmrghw_shuffle v16i8:$vA, v16i8:$vB))]>;
 565 def VMRGLB : VXForm_1<268, (outs vrrc:$vD), (ins vrrc:$vA, vrrc:$vB),
 566                       "vmrglb $vD, $vA, $vB", IIC_VecFP,
 567                       [(set v16i8:$vD, (vmrglb_shuffle v16i8:$vA, v16i8:$vB))]>;
 568 def VMRGLH : VXForm_1<332, (outs vrrc:$vD), (ins vrrc:$vA, vrrc:$vB),
 569                       "vmrglh $vD, $vA, $vB", IIC_VecFP,
 570                       [(set v16i8:$vD, (vmrglh_shuffle v16i8:$vA, v16i8:$vB))]>;
 571 def VMRGLW : VXForm_1<396, (outs vrrc:$vD), (ins vrrc:$vA, vrrc:$vB),
 572                       "vmrglw $vD, $vA, $vB", IIC_VecFP,
 573                       [(set v16i8:$vD, (vmrglw_shuffle v16i8:$vA, v16i8:$vB))]>;
 574
 575 def VMSUMMBM : VA1a_Int_Ty3<37, "vmsummbm", int_ppc_altivec_vmsummbm,
 576                             v4i32, v16i8, v4i32>;
 577 def VMSUMSHM : VA1a_Int_Ty3<40, "vmsumshm", int_ppc_altivec_vmsumshm,
 578                             v4i32, v8i16, v4i32>;
 579 def VMSUMSHS : VA1a_Int_Ty3<41, "vmsumshs", int_ppc_altivec_vmsumshs,
 580                             v4i32, v8i16, v4i32>;
 581 def VMSUMUBM : VA1a_Int_Ty3<36, "vmsumubm", int_ppc_altivec_vmsumubm,
 582                             v4i32, v16i8, v4i32>;
 583 def VMSUMUHM : VA1a_Int_Ty3<38, "vmsumuhm", int_ppc_altivec_vmsumuhm,
 584                             v4i32, v8i16, v4i32>;
 585 def VMSUMUHS : VA1a_Int_Ty3<39, "vmsumuhs", int_ppc_altivec_vmsumuhs,
 586                             v4i32, v8i16, v4i32>;
 587
 588 let isCommutable = 1 in {
 589 def VMULESB : VX1_Int_Ty2<776, "vmulesb", int_ppc_altivec_vmulesb,
 590                           v8i16, v16i8>;
 591 def VMULESH : VX1_Int_Ty2<840, "vmulesh", int_ppc_altivec_vmulesh,
 592                           v4i32, v8i16>;
 593 def VMULEUB : VX1_Int_Ty2<520, "vmuleub", int_ppc_altivec_vmuleub,
 594                           v8i16, v16i8>;
 595 def VMULEUH : VX1_Int_Ty2<584, "vmuleuh", int_ppc_altivec_vmuleuh,
 596                           v4i32, v8i16>;
 597 def VMULOSB : VX1_Int_Ty2<264, "vmulosb", int_ppc_altivec_vmulosb,
 598                           v8i16, v16i8>;
 599 def VMULOSH : VX1_Int_Ty2<328, "vmulosh", int_ppc_altivec_vmulosh,
 600                           v4i32, v8i16>;
 601 def VMULOUB : VX1_Int_Ty2<  8, "vmuloub", int_ppc_altivec_vmuloub,
 602                           v8i16, v16i8>;
 603 def VMULOUH : VX1_Int_Ty2< 72, "vmulouh", int_ppc_altivec_vmulouh,
 604                           v4i32, v8i16>;
 605 } // isCommutable
 606
 607 def VREFP     : VX2_Int_SP<266, "vrefp",     int_ppc_altivec_vrefp>;
 608 def VRFIM     : VX2_Int_SP<714, "vrfim",     int_ppc_altivec_vrfim>;
 609 def VRFIN     : VX2_Int_SP<522, "vrfin",     int_ppc_altivec_vrfin>;
 610 def VRFIP     : VX2_Int_SP<650, "vrfip",     int_ppc_altivec_vrfip>;
 611 def VRFIZ     : VX2_Int_SP<586, "vrfiz",     int_ppc_altivec_vrfiz>;
 612 def VRSQRTEFP : VX2_Int_SP<330, "vrsqrtefp", int_ppc_altivec_vrsqrtefp>;
 613
 614 def VSUBCUW : VX1_Int_Ty<1408, "vsubcuw", int_ppc_altivec_vsubcuw, v4i32>;
 615
 616 def VSUBFP  : VXForm_1<74, (outs vrrc:$vD), (ins vrrc:$vA, vrrc:$vB),
 617                       "vsubfp $vD, $vA, $vB", IIC_VecGeneral,
 618                       [(set v4f32:$vD, (fsub v4f32:$vA, v4f32:$vB))]>;
 619 def VSUBUBM : VXForm_1<1024, (outs vrrc:$vD), (ins vrrc:$vA, vrrc:$vB),
 620                       "vsububm $vD, $vA, $vB", IIC_VecGeneral,
 621                       [(set v16i8:$vD, (sub v16i8:$vA, v16i8:$vB))]>;
 622 def VSUBUHM : VXForm_1<1088, (outs vrrc:$vD), (ins vrrc:$vA, vrrc:$vB),
 623                       "vsubuhm $vD, $vA, $vB", IIC_VecGeneral,
 624                       [(set v8i16:$vD, (sub v8i16:$vA, v8i16:$vB))]>;
 625 def VSUBUWM : VXForm_1<1152, (outs vrrc:$vD), (ins vrrc:$vA, vrrc:$vB),
 626                       "vsubuwm $vD, $vA, $vB", IIC_VecGeneral,
 627                       [(set v4i32:$vD, (sub v4i32:$vA, v4i32:$vB))]>;
 628
 629 def VSUBSBS : VX1_Int_Ty<1792, "vsubsbs" , int_ppc_altivec_vsubsbs, v16i8>;
 630 def VSUBSHS : VX1_Int_Ty<1856, "vsubshs" , int_ppc_altivec_vsubshs, v8i16>;
 631 def VSUBSWS : VX1_Int_Ty<1920, "vsubsws" , int_ppc_altivec_vsubsws, v4i32>;
 632 def VSUBUBS : VX1_Int_Ty<1536, "vsububs" , int_ppc_altivec_vsububs, v16i8>;
 633 def VSUBUHS : VX1_Int_Ty<1600, "vsubuhs" , int_ppc_altivec_vsubuhs, v8i16>;
 634 def VSUBUWS : VX1_Int_Ty<1664, "vsubuws" , int_ppc_altivec_vsubuws, v4i32>;
 635
 636 def VSUMSWS : VX1_Int_Ty<1928, "vsumsws" , int_ppc_altivec_vsumsws, v4i32>;
 637 def VSUM2SWS: VX1_Int_Ty<1672, "vsum2sws", int_ppc_altivec_vsum2sws, v4i32>;
 638
 639 def VSUM4SBS: VX1_Int_Ty3<1800, "vsum4sbs", int_ppc_altivec_vsum4sbs,
 640                           v4i32, v16i8, v4i32>;
 641 def VSUM4SHS: VX1_Int_Ty3<1608, "vsum4shs", int_ppc_altivec_vsum4shs,
 642                           v4i32, v8i16, v4i32>;
 643 def VSUM4UBS: VX1_Int_Ty3<1544, "vsum4ubs", int_ppc_altivec_vsum4ubs,
 644                           v4i32, v16i8, v4i32>;
 645
 646 def VNOR : VXForm_1<1284, (outs vrrc:$vD), (ins vrrc:$vA, vrrc:$vB),
 647                     "vnor $vD, $vA, $vB", IIC_VecFP,
 648                     [(set v4i32:$vD, (vnot_ppc (or v4i32:$vA,
 649                                                    v4i32:$vB)))]>;
 650 let isCommutable = 1 in {
 651 def VOR : VXForm_1<1156, (outs vrrc:$vD), (ins vrrc:$vA, vrrc:$vB),
 652                       "vor $vD, $vA, $vB", IIC_VecFP,
 653                       [(set v4i32:$vD, (or v4i32:$vA, v4i32:$vB))]>;
 654 def VXOR : VXForm_1<1220, (outs vrrc:$vD), (ins vrrc:$vA, vrrc:$vB),
 655                       "vxor $vD, $vA, $vB", IIC_VecFP,
 656                       [(set v4i32:$vD, (xor v4i32:$vA, v4i32:$vB))]>;
 657 } // isCommutable
 658
 659 def VRLB   : VX1_Int_Ty<   4, "vrlb", int_ppc_altivec_vrlb, v16i8>;
 660 def VRLH   : VX1_Int_Ty<  68, "vrlh", int_ppc_altivec_vrlh, v8i16>;
 661 def VRLW   : VX1_Int_Ty< 132, "vrlw", int_ppc_altivec_vrlw, v4i32>;
 662
 663 def VSL    : VX1_Int_Ty< 452, "vsl" , int_ppc_altivec_vsl,  v4i32 >;
 664 def VSLO   : VX1_Int_Ty<1036, "vslo", int_ppc_altivec_vslo, v4i32>;
 665
 666 def VSLB   : VX1_Int_Ty< 260, "vslb", int_ppc_altivec_vslb, v16i8>;
 667 def VSLH   : VX1_Int_Ty< 324, "vslh", int_ppc_altivec_vslh, v8i16>;
 668 def VSLW   : VX1_Int_Ty< 388, "vslw", int_ppc_altivec_vslw, v4i32>;
 669
 670 def VSPLTB : VXForm_1<524, (outs vrrc:$vD), (ins u5imm:$UIMM, vrrc:$vB),
 671                       "vspltb $vD, $vB, $UIMM", IIC_VecPerm,
 672                       [(set v16i8:$vD,
 673                         (vspltb_shuffle:$UIMM v16i8:$vB, (undef)))]>;
 674 def VSPLTH : VXForm_1<588, (outs vrrc:$vD), (ins u5imm:$UIMM, vrrc:$vB),
 675                       "vsplth $vD, $vB, $UIMM", IIC_VecPerm,
 676                       [(set v16i8:$vD,
 677                         (vsplth_shuffle:$UIMM v16i8:$vB, (undef)))]>;
 678 def VSPLTW : VXForm_1<652, (outs vrrc:$vD), (ins u5imm:$UIMM, vrrc:$vB),
 679                       "vspltw $vD, $vB, $UIMM", IIC_VecPerm,
 680                       [(set v16i8:$vD,
 681                         (vspltw_shuffle:$UIMM v16i8:$vB, (undef)))]>;
 682
 683 def VSR    : VX1_Int_Ty< 708, "vsr"  , int_ppc_altivec_vsr,  v4i32>;
 684 def VSRO   : VX1_Int_Ty<1100, "vsro" , int_ppc_altivec_vsro, v4i32>;
 685
 686 def VSRAB  : VX1_Int_Ty< 772, "vsrab", int_ppc_altivec_vsrab, v16i8>;
 687 def VSRAH  : VX1_Int_Ty< 836, "vsrah", int_ppc_altivec_vsrah, v8i16>;
 688 def VSRAW  : VX1_Int_Ty< 900, "vsraw", int_ppc_altivec_vsraw, v4i32>;
 689 def VSRB   : VX1_Int_Ty< 516, "vsrb" , int_ppc_altivec_vsrb , v16i8>;
 690 def VSRH   : VX1_Int_Ty< 580, "vsrh" , int_ppc_altivec_vsrh , v8i16>;
 691 def VSRW   : VX1_Int_Ty< 644, "vsrw" , int_ppc_altivec_vsrw , v4i32>;
 692
 693
 694 def VSPLTISB : VXForm_3<780, (outs vrrc:$vD), (ins s5imm:$SIMM),
 695                        "vspltisb $vD, $SIMM", IIC_VecPerm,
 696                        [(set v16i8:$vD, (v16i8 vecspltisb:$SIMM))]>;
 697 def VSPLTISH : VXForm_3<844, (outs vrrc:$vD), (ins s5imm:$SIMM),
 698                        "vspltish $vD, $SIMM", IIC_VecPerm,
 699                        [(set v8i16:$vD, (v8i16 vecspltish:$SIMM))]>;
 700 def VSPLTISW : VXForm_3<908, (outs vrrc:$vD), (ins s5imm:$SIMM),
 701                        "vspltisw $vD, $SIMM", IIC_VecPerm,
 702                        [(set v4i32:$vD, (v4i32 vecspltisw:$SIMM))]>;
 703
 704 // Vector Pack.
 705 def VPKPX   : VX1_Int_Ty2<782, "vpkpx", int_ppc_altivec_vpkpx,
 706                           v8i16, v4i32>;
 707 def VPKSHSS : VX1_Int_Ty2<398, "vpkshss", int_ppc_altivec_vpkshss,
 708                           v16i8, v8i16>;
 709 def VPKSHUS : VX1_Int_Ty2<270, "vpkshus", int_ppc_altivec_vpkshus,
 710                           v16i8, v8i16>;
 711 def VPKSWSS : VX1_Int_Ty2<462, "vpkswss", int_ppc_altivec_vpkswss,
 712                           v16i8, v4i32>;
 713 def VPKSWUS : VX1_Int_Ty2<334, "vpkswus", int_ppc_altivec_vpkswus,
 714                           v8i16, v4i32>;
 715 def VPKUHUM : VXForm_1<14, (outs vrrc:$vD), (ins vrrc:$vA, vrrc:$vB),
 716                        "vpkuhum $vD, $vA, $vB", IIC_VecFP,
 717                        [(set v16i8:$vD,
 718                          (vpkuhum_shuffle v16i8:$vA, v16i8:$vB))]>;
 719 def VPKUHUS : VX1_Int_Ty2<142, "vpkuhus", int_ppc_altivec_vpkuhus,
 720                           v16i8, v8i16>;
 721 def VPKUWUM : VXForm_1<78, (outs vrrc:$vD), (ins vrrc:$vA, vrrc:$vB),
 722                        "vpkuwum $vD, $vA, $vB", IIC_VecFP,
 723                        [(set v16i8:$vD,
 724                          (vpkuwum_shuffle v16i8:$vA, v16i8:$vB))]>;
 725 def VPKUWUS : VX1_Int_Ty2<206, "vpkuwus", int_ppc_altivec_vpkuwus,
 726                           v8i16, v4i32>;
 727
 728 // Vector Unpack.
 729 def VUPKHPX : VX2_Int_Ty2<846, "vupkhpx", int_ppc_altivec_vupkhpx,
 730                           v4i32, v8i16>;
 731 def VUPKHSB : VX2_Int_Ty2<526, "vupkhsb", int_ppc_altivec_vupkhsb,
 732                           v8i16, v16i8>;
 733 def VUPKHSH : VX2_Int_Ty2<590, "vupkhsh", int_ppc_altivec_vupkhsh,
 734                           v4i32, v8i16>;
 735 def VUPKLPX : VX2_Int_Ty2<974, "vupklpx", int_ppc_altivec_vupklpx,
 736                           v4i32, v8i16>;
 737 def VUPKLSB : VX2_Int_Ty2<654, "vupklsb", int_ppc_altivec_vupklsb,
 738                           v8i16, v16i8>;
 739 def VUPKLSH : VX2_Int_Ty2<718, "vupklsh", int_ppc_altivec_vupklsh,
 740                           v4i32, v8i16>;
 741
 742
 743 // Altivec Comparisons.
 744
 745 class VCMP<bits<10> xo, string asmstr, ValueType Ty>
 746   : VXRForm_1<xo, (outs vrrc:$vD), (ins vrrc:$vA, vrrc:$vB), asmstr,
 747               IIC_VecFPCompare,
 748               [(set Ty:$vD, (Ty (PPCvcmp Ty:$vA, Ty:$vB, xo)))]>;
 749 class VCMPo<bits<10> xo, string asmstr, ValueType Ty>
 750   : VXRForm_1<xo, (outs vrrc:$vD), (ins vrrc:$vA, vrrc:$vB), asmstr,
 751               IIC_VecFPCompare,
 752               [(set Ty:$vD, (Ty (PPCvcmp_o Ty:$vA, Ty:$vB, xo)))]> {
 753   let Defs = [CR6];
 754   let RC = 1;
 755 }
 756
 757 // f32 element comparisons.0
 758 def VCMPBFP   : VCMP <966, "vcmpbfp $vD, $vA, $vB"  , v4f32>;
 759 def VCMPBFPo  : VCMPo<966, "vcmpbfp. $vD, $vA, $vB" , v4f32>;
 760 def VCMPEQFP  : VCMP <198, "vcmpeqfp $vD, $vA, $vB" , v4f32>;
 761 def VCMPEQFPo : VCMPo<198, "vcmpeqfp. $vD, $vA, $vB", v4f32>;
 762 def VCMPGEFP  : VCMP <454, "vcmpgefp $vD, $vA, $vB" , v4f32>;
 763 def VCMPGEFPo : VCMPo<454, "vcmpgefp. $vD, $vA, $vB", v4f32>;
 764 def VCMPGTFP  : VCMP <710, "vcmpgtfp $vD, $vA, $vB" , v4f32>;
 765 def VCMPGTFPo : VCMPo<710, "vcmpgtfp. $vD, $vA, $vB", v4f32>;
 766
 767 // i8 element comparisons.
 768 def VCMPEQUB  : VCMP <  6, "vcmpequb $vD, $vA, $vB" , v16i8>;
 769 def VCMPEQUBo : VCMPo<  6, "vcmpequb. $vD, $vA, $vB", v16i8>;
 770 def VCMPGTSB  : VCMP <774, "vcmpgtsb $vD, $vA, $vB" , v16i8>;
 771 def VCMPGTSBo : VCMPo<774, "vcmpgtsb. $vD, $vA, $vB", v16i8>;
 772 def VCMPGTUB  : VCMP <518, "vcmpgtub $vD, $vA, $vB" , v16i8>;
 773 def VCMPGTUBo : VCMPo<518, "vcmpgtub. $vD, $vA, $vB", v16i8>;
 774
 775 // i16 element comparisons.
 776 def VCMPEQUH  : VCMP < 70, "vcmpequh $vD, $vA, $vB" , v8i16>;
 777 def VCMPEQUHo : VCMPo< 70, "vcmpequh. $vD, $vA, $vB", v8i16>;
 778 def VCMPGTSH  : VCMP <838, "vcmpgtsh $vD, $vA, $vB" , v8i16>;
 779 def VCMPGTSHo : VCMPo<838, "vcmpgtsh. $vD, $vA, $vB", v8i16>;
 780 def VCMPGTUH  : VCMP <582, "vcmpgtuh $vD, $vA, $vB" , v8i16>;
 781 def VCMPGTUHo : VCMPo<582, "vcmpgtuh. $vD, $vA, $vB", v8i16>;
 782
 783 // i32 element comparisons.
 784 def VCMPEQUW  : VCMP <134, "vcmpequw $vD, $vA, $vB" , v4i32>;
 785 def VCMPEQUWo : VCMPo<134, "vcmpequw. $vD, $vA, $vB", v4i32>;
 786 def VCMPGTSW  : VCMP <902, "vcmpgtsw $vD, $vA, $vB" , v4i32>;
 787 def VCMPGTSWo : VCMPo<902, "vcmpgtsw. $vD, $vA, $vB", v4i32>;
 788 def VCMPGTUW  : VCMP <646, "vcmpgtuw $vD, $vA, $vB" , v4i32>;
 789 def VCMPGTUWo : VCMPo<646, "vcmpgtuw. $vD, $vA, $vB", v4i32>;
 790
 791 let isCodeGenOnly = 1 in {
 792 def V_SET0B : VXForm_setzero<1220, (outs vrrc:$vD), (ins),
 793                       "vxor $vD, $vD, $vD", IIC_VecFP,
 794                       [(set v16i8:$vD, (v16i8 immAllZerosV))]>;
 795 def V_SET0H : VXForm_setzero<1220, (outs vrrc:$vD), (ins),
 796                       "vxor $vD, $vD, $vD", IIC_VecFP,
 797                       [(set v8i16:$vD, (v8i16 immAllZerosV))]>;
 798 def V_SET0  : VXForm_setzero<1220, (outs vrrc:$vD), (ins),
 799                       "vxor $vD, $vD, $vD", IIC_VecFP,
 800                       [(set v4i32:$vD, (v4i32 immAllZerosV))]>;
 801
 802 let IMM=-1 in {
 803 def V_SETALLONESB : VXForm_3<908, (outs vrrc:$vD), (ins),
 804                       "vspltisw $vD, -1", IIC_VecFP,
 805                       [(set v16i8:$vD, (v16i8 immAllOnesV))]>;
 806 def V_SETALLONESH : VXForm_3<908, (outs vrrc:$vD), (ins),
 807                       "vspltisw $vD, -1", IIC_VecFP,
 808                       [(set v8i16:$vD, (v8i16 immAllOnesV))]>;
 809 def V_SETALLONES  : VXForm_3<908, (outs vrrc:$vD), (ins),
 810                       "vspltisw $vD, -1", IIC_VecFP,
 811                       [(set v4i32:$vD, (v4i32 immAllOnesV))]>;
 812 }
 813 }
 814 } // VALU Operations.
 815
 816 //===----------------------------------------------------------------------===//
 817 // Additional Altivec Patterns
 818 //
 819
 820 // Loads.
 821 def : Pat<(v4i32 (load xoaddr:$src)), (LVX xoaddr:$src)>;
 822
 823 // Stores.
 824 def : Pat<(store v4i32:$rS, xoaddr:$dst),
 825           (STVX $rS, xoaddr:$dst)>;
 826
 827 // Bit conversions.
 828 def : Pat<(v16i8 (bitconvert (v8i16 VRRC:$src))), (v16i8 VRRC:$src)>;
 829 def : Pat<(v16i8 (bitconvert (v4i32 VRRC:$src))), (v16i8 VRRC:$src)>;
 830 def : Pat<(v16i8 (bitconvert (v4f32 VRRC:$src))), (v16i8 VRRC:$src)>;
 831 def : Pat<(v16i8 (bitconvert (v2i64 VRRC:$src))), (v16i8 VRRC:$src)>;
 832 def : Pat<(v16i8 (bitconvert (v1i128 VRRC:$src))), (v16i8 VRRC:$src)>;
 833
 834 def : Pat<(v8i16 (bitconvert (v16i8 VRRC:$src))), (v8i16 VRRC:$src)>;
 835 def : Pat<(v8i16 (bitconvert (v4i32 VRRC:$src))), (v8i16 VRRC:$src)>;
 836 def : Pat<(v8i16 (bitconvert (v4f32 VRRC:$src))), (v8i16 VRRC:$src)>;
 837 def : Pat<(v8i16 (bitconvert (v2i64 VRRC:$src))), (v8i16 VRRC:$src)>;
 838 def : Pat<(v8i16 (bitconvert (v1i128 VRRC:$src))), (v8i16 VRRC:$src)>;
 839
 840 def : Pat<(v4i32 (bitconvert (v16i8 VRRC:$src))), (v4i32 VRRC:$src)>;
 841 def : Pat<(v4i32 (bitconvert (v8i16 VRRC:$src))), (v4i32 VRRC:$src)>;
 842 def : Pat<(v4i32 (bitconvert (v4f32 VRRC:$src))), (v4i32 VRRC:$src)>;
 843 def : Pat<(v4i32 (bitconvert (v2i64 VRRC:$src))), (v4i32 VRRC:$src)>;
 844 def : Pat<(v4i32 (bitconvert (v1i128 VRRC:$src))), (v4i32 VRRC:$src)>;
 845
 846 def : Pat<(v4f32 (bitconvert (v16i8 VRRC:$src))), (v4f32 VRRC:$src)>;
 847 def : Pat<(v4f32 (bitconvert (v8i16 VRRC:$src))), (v4f32 VRRC:$src)>;
 848 def : Pat<(v4f32 (bitconvert (v4i32 VRRC:$src))), (v4f32 VRRC:$src)>;
 849 def : Pat<(v4f32 (bitconvert (v2i64 VRRC:$src))), (v4f32 VRRC:$src)>;
 850 def : Pat<(v4f32 (bitconvert (v1i128 VRRC:$src))), (v4f32 VRRC:$src)>;
 851
 852 def : Pat<(v2i64 (bitconvert (v16i8 VRRC:$src))), (v2i64 VRRC:$src)>;
 853 def : Pat<(v2i64 (bitconvert (v8i16 VRRC:$src))), (v2i64 VRRC:$src)>;
 854 def : Pat<(v2i64 (bitconvert (v4i32 VRRC:$src))), (v2i64 VRRC:$src)>;
 855 def : Pat<(v2i64 (bitconvert (v4f32 VRRC:$src))), (v2i64 VRRC:$src)>;
 856 def : Pat<(v2i64 (bitconvert (v1i128 VRRC:$src))), (v2i64 VRRC:$src)>;
 857
 858 def : Pat<(v1i128 (bitconvert (v16i8 VRRC:$src))), (v1i128 VRRC:$src)>;
 859 def : Pat<(v1i128 (bitconvert (v8i16 VRRC:$src))), (v1i128 VRRC:$src)>;
 860 def : Pat<(v1i128 (bitconvert (v4i32 VRRC:$src))), (v1i128 VRRC:$src)>;
 861 def : Pat<(v1i128 (bitconvert (v4f32 VRRC:$src))), (v1i128 VRRC:$src)>;
 862 def : Pat<(v1i128 (bitconvert (v2i64 VRRC:$src))), (v1i128 VRRC:$src)>;
 863
 864 // Shuffles.
 865
 866 // Match vsldoi(x,x), vpkuwum(x,x), vpkuhum(x,x)
 867 def:Pat<(vsldoi_unary_shuffle:$in v16i8:$vA, undef),
 868         (VSLDOI $vA, $vA, (VSLDOI_unary_get_imm $in))>;
 869 def:Pat<(vpkuwum_unary_shuffle v16i8:$vA, undef),
 870         (VPKUWUM $vA, $vA)>;
 871 def:Pat<(vpkuhum_unary_shuffle v16i8:$vA, undef),
 872         (VPKUHUM $vA, $vA)>;
 873
 874 // Match vsldoi(y,x), vpkuwum(y,x), vpkuhum(y,x), i.e., swapped operands.
 875 // These fragments are matched for little-endian, where the inputs must
 876 // be swapped for correct semantics.
 877 def:Pat<(vsldoi_swapped_shuffle:$in v16i8:$vA, v16i8:$vB),
 878         (VSLDOI $vB, $vA, (VSLDOI_swapped_get_imm $in))>;
 879 def:Pat<(vpkuwum_swapped_shuffle v16i8:$vA, v16i8:$vB),
 880         (VPKUWUM $vB, $vA)>;
 881 def:Pat<(vpkuhum_swapped_shuffle v16i8:$vA, v16i8:$vB),
 882         (VPKUHUM $vB, $vA)>;
 883
 884 // Match vmrg*(x,x)
 885 def:Pat<(vmrglb_unary_shuffle v16i8:$vA, undef),
 886         (VMRGLB $vA, $vA)>;
 887 def:Pat<(vmrglh_unary_shuffle v16i8:$vA, undef),
 888         (VMRGLH $vA, $vA)>;
 889 def:Pat<(vmrglw_unary_shuffle v16i8:$vA, undef),
 890         (VMRGLW $vA, $vA)>;
 891 def:Pat<(vmrghb_unary_shuffle v16i8:$vA, undef),
 892         (VMRGHB $vA, $vA)>;
 893 def:Pat<(vmrghh_unary_shuffle v16i8:$vA, undef),
 894         (VMRGHH $vA, $vA)>;
 895 def:Pat<(vmrghw_unary_shuffle v16i8:$vA, undef),
 896         (VMRGHW $vA, $vA)>;
 897
 898 // Match vmrg*(y,x), i.e., swapped operands.  These fragments
 899 // are matched for little-endian, where the inputs must be
 900 // swapped for correct semantics.
 901 def:Pat<(vmrglb_swapped_shuffle v16i8:$vA, v16i8:$vB),
 902         (VMRGLB $vB, $vA)>;
 903 def:Pat<(vmrglh_swapped_shuffle v16i8:$vA, v16i8:$vB),
 904         (VMRGLH $vB, $vA)>;
 905 def:Pat<(vmrglw_swapped_shuffle v16i8:$vA, v16i8:$vB),
 906         (VMRGLW $vB, $vA)>;
 907 def:Pat<(vmrghb_swapped_shuffle v16i8:$vA, v16i8:$vB),
 908         (VMRGHB $vB, $vA)>;
 909 def:Pat<(vmrghh_swapped_shuffle v16i8:$vA, v16i8:$vB),
 910         (VMRGHH $vB, $vA)>;
 911 def:Pat<(vmrghw_swapped_shuffle v16i8:$vA, v16i8:$vB),
 912         (VMRGHW $vB, $vA)>;
 913
 914 // Logical Operations
 915 def : Pat<(vnot_ppc v4i32:$vA), (VNOR $vA, $vA)>;
 916
 917 def : Pat<(vnot_ppc (or v4i32:$A, v4i32:$B)),
 918           (VNOR $A, $B)>;
 919 def : Pat<(and v4i32:$A, (vnot_ppc v4i32:$B)),
 920           (VANDC $A, $B)>;
 921
 922 def : Pat<(fmul v4f32:$vA, v4f32:$vB),
 923           (VMADDFP $vA, $vB,
 924              (v4i32 (VSLW (V_SETALLONES), (V_SETALLONES))))>;
 925
 926 // Fused multiply add and multiply sub for packed float.  These are represented
 927 // separately from the real instructions above, for operations that must have
 928 // the additional precision, such as Newton-Rhapson (used by divide, sqrt)
 929 def : Pat<(PPCvmaddfp v4f32:$A, v4f32:$B, v4f32:$C),
 930           (VMADDFP $A, $B, $C)>;
 931 def : Pat<(PPCvnmsubfp v4f32:$A, v4f32:$B, v4f32:$C),
 932           (VNMSUBFP $A, $B, $C)>;
 933
 934 def : Pat<(int_ppc_altivec_vmaddfp v4f32:$A, v4f32:$B, v4f32:$C),
 935           (VMADDFP $A, $B, $C)>;
 936 def : Pat<(int_ppc_altivec_vnmsubfp v4f32:$A, v4f32:$B, v4f32:$C),
 937           (VNMSUBFP $A, $B, $C)>;
 938
 939 def : Pat<(PPCvperm v16i8:$vA, v16i8:$vB, v16i8:$vC),
 940           (VPERM $vA, $vB, $vC)>;
 941
 942 def : Pat<(PPCfre v4f32:$A), (VREFP $A)>;
 943 def : Pat<(PPCfrsqrte v4f32:$A), (VRSQRTEFP $A)>;
 944
 945 // Vector shifts
 946 def : Pat<(v16i8 (shl v16i8:$vA, v16i8:$vB)),
 947           (v16i8 (VSLB $vA, $vB))>;
 948 def : Pat<(v8i16 (shl v8i16:$vA, v8i16:$vB)),
 949           (v8i16 (VSLH $vA, $vB))>;
 950 def : Pat<(v4i32 (shl v4i32:$vA, v4i32:$vB)),
 951           (v4i32 (VSLW $vA, $vB))>;
 952
 953 def : Pat<(v16i8 (srl v16i8:$vA, v16i8:$vB)),
 954           (v16i8 (VSRB $vA, $vB))>;
 955 def : Pat<(v8i16 (srl v8i16:$vA, v8i16:$vB)),
 956           (v8i16 (VSRH $vA, $vB))>;
 957 def : Pat<(v4i32 (srl v4i32:$vA, v4i32:$vB)),
 958           (v4i32 (VSRW $vA, $vB))>;
 959
 960 def : Pat<(v16i8 (sra v16i8:$vA, v16i8:$vB)),
 961           (v16i8 (VSRAB $vA, $vB))>;
 962 def : Pat<(v8i16 (sra v8i16:$vA, v8i16:$vB)),
 963           (v8i16 (VSRAH $vA, $vB))>;
 964 def : Pat<(v4i32 (sra v4i32:$vA, v4i32:$vB)),
 965           (v4i32 (VSRAW $vA, $vB))>;
 966
 967 // Float to integer and integer to float conversions
 968 def : Pat<(v4i32 (fp_to_sint v4f32:$vA)),
 969            (VCTSXS_0 $vA)>;
 970 def : Pat<(v4i32 (fp_to_uint v4f32:$vA)),
 971            (VCTUXS_0 $vA)>;
 972 def : Pat<(v4f32 (sint_to_fp v4i32:$vA)),
 973            (VCFSX_0 $vA)>;
 974 def : Pat<(v4f32 (uint_to_fp v4i32:$vA)),
 975            (VCFUX_0 $vA)>;
 976
 977 // Floating-point rounding
 978 def : Pat<(v4f32 (ffloor v4f32:$vA)),
 979           (VRFIM $vA)>;
 980 def : Pat<(v4f32 (fceil v4f32:$vA)),
 981           (VRFIP $vA)>;
 982 def : Pat<(v4f32 (ftrunc v4f32:$vA)),
 983           (VRFIZ $vA)>;
 984 def : Pat<(v4f32 (fnearbyint v4f32:$vA)),
 985           (VRFIN $vA)>;
 986
 987 } // end HasAltivec
 988
 989 def HasP8Altivec : Predicate<"PPCSubTarget->hasP8Altivec()">;
 990 def HasP8Crypto : Predicate<"PPCSubTarget->hasP8Crypto()">;
 991 let Predicates = [HasP8Altivec] in {
 992
 993 let isCommutable = 1 in {
 994 def VMULESW : VX1_Int_Ty2<904, "vmulesw", int_ppc_altivec_vmulesw,
 995                           v2i64, v4i32>;
 996 def VMULEUW : VX1_Int_Ty2<648, "vmuleuw", int_ppc_altivec_vmuleuw,
 997                           v2i64, v4i32>;
 998 def VMULOSW : VX1_Int_Ty2<392, "vmulosw", int_ppc_altivec_vmulosw,
 999                           v2i64, v4i32>;
1000 def VMULOUW : VX1_Int_Ty2<136, "vmulouw", int_ppc_altivec_vmulouw,
1001                           v2i64, v4i32>;
1002 def VMULUWM : VXForm_1<137, (outs vrrc:$vD), (ins vrrc:$vA, vrrc:$vB),
1003                        "vmuluwm $vD, $vA, $vB", IIC_VecGeneral,
1004                        [(set v4i32:$vD, (mul v4i32:$vA, v4i32:$vB))]>;
1005 def VMAXSD : VX1_Int_Ty<450, "vmaxsd", int_ppc_altivec_vmaxsd, v2i64>;
1006 def VMAXUD : VX1_Int_Ty<194, "vmaxud", int_ppc_altivec_vmaxud, v2i64>;
1007 def VMINSD : VX1_Int_Ty<962, "vminsd", int_ppc_altivec_vminsd, v2i64>;
1008 def VMINUD : VX1_Int_Ty<706, "vminud", int_ppc_altivec_vminud, v2i64>;
1009 } // isCommutable
1010
1011 // Vector shifts
1012 def VRLD : VX1_Int_Ty<196, "vrld", int_ppc_altivec_vrld, v2i64>;
1013 def VSLD : VXForm_1<1476, (outs vrrc:$vD), (ins vrrc:$vA, vrrc:$vB),
1014                     "vsld $vD, $vA, $vB", IIC_VecGeneral,
1015                     [(set v2i64:$vD, (shl v2i64:$vA, v2i64:$vB))]>;
1016 def VSRD : VXForm_1<1732, (outs vrrc:$vD), (ins vrrc:$vA, vrrc:$vB),
1017                    "vsrd $vD, $vA, $vB", IIC_VecGeneral,
1018                    [(set v2i64:$vD, (srl v2i64:$vA, v2i64:$vB))]>;
1019 def VSRAD : VXForm_1<964, (outs vrrc:$vD), (ins vrrc:$vA, vrrc:$vB),
1020                     "vsrad $vD, $vA, $vB", IIC_VecGeneral,
1021                     [(set v2i64:$vD, (sra v2i64:$vA, v2i64:$vB))]>;
1022
1023 // Vector Integer Arithmetic Instructions
1024 let isCommutable = 1 in {
1025 def VADDUDM : VXForm_1<192, (outs vrrc:$vD), (ins vrrc:$vA, vrrc:$vB),
1026                        "vaddudm $vD, $vA, $vB", IIC_VecGeneral,
1027                        [(set v2i64:$vD, (add v2i64:$vA, v2i64:$vB))]>;
1028 } // isCommutable
1029
1030 def VSUBUDM : VXForm_1<1216, (outs vrrc:$vD), (ins vrrc:$vA, vrrc:$vB),
1031                        "vsubudm $vD, $vA, $vB", IIC_VecGeneral,
1032                        [(set v2i64:$vD, (sub v2i64:$vA, v2i64:$vB))]>;
1033
1034 // Count Leading Zeros
1035 def VCLZB : VXForm_2<1794, (outs vrrc:$vD), (ins vrrc:$vB),
1036                      "vclzb $vD, $vB", IIC_VecGeneral,
1037                      [(set v16i8:$vD, (ctlz v16i8:$vB))]>;
1038 def VCLZH : VXForm_2<1858, (outs vrrc:$vD), (ins vrrc:$vB),
1039                      "vclzh $vD, $vB", IIC_VecGeneral,
1040                      [(set v8i16:$vD, (ctlz v8i16:$vB))]>;
1041 def VCLZW : VXForm_2<1922, (outs vrrc:$vD), (ins vrrc:$vB),
1042                      "vclzw $vD, $vB", IIC_VecGeneral,
1043                      [(set v4i32:$vD, (ctlz v4i32:$vB))]>;
1044 def VCLZD : VXForm_2<1986, (outs vrrc:$vD), (ins vrrc:$vB),
1045                      "vclzd $vD, $vB", IIC_VecGeneral,
1046                      [(set v2i64:$vD, (ctlz v2i64:$vB))]>;
1047
1048 // Population Count
1049 def VPOPCNTB : VXForm_2<1795, (outs vrrc:$vD), (ins vrrc:$vB),
1050                         "vpopcntb $vD, $vB", IIC_VecGeneral,
1051                         [(set v16i8:$vD, (ctpop v16i8:$vB))]>;
1052 def VPOPCNTH : VXForm_2<1859, (outs vrrc:$vD), (ins vrrc:$vB),
1053                         "vpopcnth $vD, $vB", IIC_VecGeneral,
1054                         [(set v8i16:$vD, (ctpop v8i16:$vB))]>;
1055 def VPOPCNTW : VXForm_2<1923, (outs vrrc:$vD), (ins vrrc:$vB),
1056                         "vpopcntw $vD, $vB", IIC_VecGeneral,
1057                         [(set v4i32:$vD, (ctpop v4i32:$vB))]>;
1058 def VPOPCNTD : VXForm_2<1987, (outs vrrc:$vD), (ins vrrc:$vB),
1059                         "vpopcntd $vD, $vB", IIC_VecGeneral,
1060                         [(set v2i64:$vD, (ctpop v2i64:$vB))]>;
1061
1062 let isCommutable = 1 in {
1063 // FIXME: Use AddedComplexity > 400 to ensure these patterns match before the
1064 //        VSX equivalents. We need to fix this up at some point. Two possible
1065 //        solutions for this problem:
1066 //        1. Disable Altivec patterns that compete with VSX patterns using the
1067 //           !HasVSX predicate. This essentially favours VSX over Altivec, in
1068 //           hopes of reducing register pressure (larger register set using VSX
1069 //           instructions than VMX instructions)
1070 //        2. Employ a more disciplined use of AddedComplexity, which would provide
1071 //           more fine-grained control than option 1. This would be beneficial
1072 //           if we find situations where Altivec is really preferred over VSX.
1073 def VEQV  : VXForm_1<1668, (outs vrrc:$vD), (ins vrrc:$vA, vrrc:$vB),
1074                      "veqv $vD, $vA, $vB", IIC_VecGeneral,
1075                      [(set v4i32:$vD, (vnot_ppc (xor v4i32:$vA, v4i32:$vB)))]>;
1076 def VNAND : VXForm_1<1412, (outs vrrc:$vD), (ins vrrc:$vA, vrrc:$vB),
1077                      "vnand $vD, $vA, $vB", IIC_VecGeneral,
1078                      [(set v4i32:$vD, (vnot_ppc (and v4i32:$vA, v4i32:$vB)))]>;
1079 } // isCommutable
1080
1081 def VORC : VXForm_1<1348, (outs vrrc:$vD), (ins vrrc:$vA, vrrc:$vB),
1082                       "vorc $vD, $vA, $vB", IIC_VecGeneral,
1083                       [(set v4i32:$vD, (or v4i32:$vA,
1084                                            (vnot_ppc v4i32:$vB)))]>;
1085
1086 // i64 element comparisons.
1087 def VCMPEQUD  : VCMP <199, "vcmpequd $vD, $vA, $vB" , v2i64>;
1088 def VCMPEQUDo : VCMPo<199, "vcmpequd. $vD, $vA, $vB", v2i64>;
1089 def VCMPGTSD  : VCMP <967, "vcmpgtsd $vD, $vA, $vB" , v2i64>;
1090 def VCMPGTSDo : VCMPo<967, "vcmpgtsd. $vD, $vA, $vB", v2i64>;
1091 def VCMPGTUD  : VCMP <711, "vcmpgtud $vD, $vA, $vB" , v2i64>;
1092 def VCMPGTUDo : VCMPo<711, "vcmpgtud. $vD, $vA, $vB", v2i64>;
1093
1094 // The cryptography instructions that do not require Category:Vector.Crypto
1095 def VPMSUMB : VX1_Int_Ty<1032, "vpmsumb",
1096                          int_ppc_altivec_crypto_vpmsumb, v16i8>;
1097 def VPMSUMH : VX1_Int_Ty<1096, "vpmsumh",
1098                          int_ppc_altivec_crypto_vpmsumh, v8i16>;
1099 def VPMSUMW : VX1_Int_Ty<1160, "vpmsumw",
1100                          int_ppc_altivec_crypto_vpmsumw, v4i32>;
1101 def VPMSUMD : VX1_Int_Ty<1224, "vpmsumd",
1102                          int_ppc_altivec_crypto_vpmsumd, v2i64>;
1103 def VPERMXOR : VA1a_Int_Ty<45, "vpermxor",
1104                          int_ppc_altivec_crypto_vpermxor, v16i8>;
1105
1106 // Vector doubleword integer pack and unpack.
1107 def VPKSDSS : VX1_Int_Ty2<1486, "vpksdss", int_ppc_altivec_vpksdss,
1108                           v4i32, v2i64>;
1109 def VPKSDUS : VX1_Int_Ty2<1358, "vpksdus", int_ppc_altivec_vpksdus,
1110                           v4i32, v2i64>;
1111 def VPKUDUM : VXForm_1<1102, (outs vrrc:$vD), (ins vrrc:$vA, vrrc:$vB),
1112                        "vpkudum $vD, $vA, $vB", IIC_VecFP,
1113                        [(set v16i8:$vD,
1114                          (vpkudum_shuffle v16i8:$vA, v16i8:$vB))]>;
1115 def VPKUDUS : VX1_Int_Ty2<1230, "vpkudus", int_ppc_altivec_vpkudus,
1116                           v4i32, v2i64>;
1117 def VUPKHSW : VX2_Int_Ty2<1614, "vupkhsw", int_ppc_altivec_vupkhsw,
1118                           v2i64, v4i32>;
1119 def VUPKLSW : VX2_Int_Ty2<1742, "vupklsw", int_ppc_altivec_vupklsw,
1120                           v2i64, v4i32>;
1121
1122 // Shuffle patterns for unary and swapped (LE) vector pack modulo.
1123 def:Pat<(vpkudum_unary_shuffle v16i8:$vA, undef),
1124         (VPKUDUM $vA, $vA)>;
1125 def:Pat<(vpkudum_swapped_shuffle v16i8:$vA, v16i8:$vB),
1126         (VPKUDUM $vB, $vA)>;
1127
1128
1129 } // end HasP8Altivec
1130
1131 // Crypto instructions (from builtins)
1132 let Predicates = [HasP8Crypto] in {
1133 def VSHASIGMAW : VXCR_Int_Ty<1666, "vshasigmaw",
1134                               int_ppc_altivec_crypto_vshasigmaw, v4i32>;
1135 def VSHASIGMAD : VXCR_Int_Ty<1730, "vshasigmad",
1136                               int_ppc_altivec_crypto_vshasigmad, v2i64>;
1137 def VCIPHER : VX1_Int_Ty<1288, "vcipher", int_ppc_altivec_crypto_vcipher,
1138                          v2i64>;
1139 def VCIPHERLAST : VX1_Int_Ty<1289, "vcipherlast",
1140                               int_ppc_altivec_crypto_vcipherlast, v2i64>;
1141 def VNCIPHER : VX1_Int_Ty<1352, "vncipher",
1142                           int_ppc_altivec_crypto_vncipher, v2i64>;
1143 def VNCIPHERLAST : VX1_Int_Ty<1353, "vncipherlast",
1144                               int_ppc_altivec_crypto_vncipherlast, v2i64>;
1145 def VSBOX : VXBX_Int_Ty<1480, "vsbox", int_ppc_altivec_crypto_vsbox, v2i64>;
1146 } // HasP8Crypto