lib/Target/PowerPC/PPCInstrAltivec.td

   1 //===- PPCInstrAltivec.td - The PowerPC Altivec Extension --*- tablegen -*-===//
   2 //
   3 //                     The LLVM Compiler Infrastructure
   4 //
   5 // This file was developed by Chris Lattner and is distributed under
   6 // the University of Illinois Open Source License. See LICENSE.TXT for details.
   7 //
   8 //===----------------------------------------------------------------------===//
   9 //
  10 // This file describes the Altivec extension to the PowerPC instruction set.
  11 //
  12 //===----------------------------------------------------------------------===//
  13
  14 //===----------------------------------------------------------------------===//
  15 // Altivec transformation functions and pattern fragments.
  16 //
  17
  18 // VSPLT_get_imm xform function: convert vector_shuffle mask to VSPLT* imm.
  19 def VSPLT_get_imm : SDNodeXForm<build_vector, [{
  20   return getI32Imm(PPC::getVSPLTImmediate(N));
  21 }]>;
  22
  23 def VSPLT_shuffle_mask : PatLeaf<(build_vector), [{
  24   return PPC::isSplatShuffleMask(N);
  25 }], VSPLT_get_imm>;
  26
  27
  28 // VSPLTISB_get_imm xform function: convert build_vector to VSPLTISB imm.
  29 def VSPLTISB_get_imm : SDNodeXForm<build_vector, [{
  30   char Val;
  31   PPC::isVecSplatImm(N, 1, &Val);
  32   return getI32Imm(Val);
  33 }]>;
  34 def vecspltisb : PatLeaf<(build_vector), [{
  35   return PPC::isVecSplatImm(N, 1);
  36 }], VSPLTISB_get_imm>;
  37
  38 // VSPLTISH_get_imm xform function: convert build_vector to VSPLTISH imm.
  39 def VSPLTISH_get_imm : SDNodeXForm<build_vector, [{
  40   char Val;
  41   PPC::isVecSplatImm(N, 2, &Val);
  42   return getI32Imm(Val);
  43 }]>;
  44 def vecspltish : PatLeaf<(build_vector), [{
  45   return PPC::isVecSplatImm(N, 2);
  46 }], VSPLTISH_get_imm>;
  47
  48 // VSPLTISW_get_imm xform function: convert build_vector to VSPLTISW imm.
  49 def VSPLTISW_get_imm : SDNodeXForm<build_vector, [{
  50   char Val;
  51   PPC::isVecSplatImm(N, 4, &Val);
  52   return getI32Imm(Val);
  53 }]>;
  54 def vecspltisw : PatLeaf<(build_vector), [{
  55   return PPC::isVecSplatImm(N, 4);
  56 }], VSPLTISW_get_imm>;
  57
  58 class isVDOT {   // vector dot instruction.
  59   list<Register> Defs = [CR6];
  60   bit RC = 1;
  61 }
  62
  63 //===----------------------------------------------------------------------===//
  64 // Helpers for defining instructions that directly correspond to intrinsics.
  65
  66 // VA1a_Int - A VAForm_1a intrinsic definition.
  67 class VA1a_Int<bits<6> xo, string asmstr, Intrinsic IntID>
  68   : VAForm_1a<xo, (ops VRRC:$vD, VRRC:$vA, VRRC:$vB, VRRC:$vC), asmstr, VecFP,
  69                        [(set VRRC:$vD, (IntID VRRC:$vA, VRRC:$vB, VRRC:$vC))]>;
  70
  71 // VX1_Int - A VXForm_1 intrinsic definition.
  72 class VX1_Int<bits<11> xo, string asmstr, Intrinsic IntID>
  73   : VXForm_1<xo, (ops VRRC:$vD, VRRC:$vA, VRRC:$vB), asmstr, VecFP,
  74              [(set VRRC:$vD, (IntID VRRC:$vA, VRRC:$vB))]>;
  75
  76 // VX2_Int - A VXForm_2 intrinsic definition.
  77 class VX2_Int<bits<11> xo, string asmstr, Intrinsic IntID>
  78   : VXForm_2<xo, (ops VRRC:$vD, VRRC:$vB), asmstr, VecFP,
  79              [(set VRRC:$vD, (IntID VRRC:$vB))]>;
  80
  81 //===----------------------------------------------------------------------===//
  82 // Instruction Definitions.
  83
  84 def IMPLICIT_DEF_VRRC : Pseudo<(ops VRRC:$rD), "; $rD = IMPLICIT_DEF_VRRC",
  85                                [(set VRRC:$rD, (v4f32 (undef)))]>;
  86
  87 let isLoad = 1, PPC970_Unit = 2 in {  // Loads.
  88 def LVEBX: XForm_1<31,   7, (ops VRRC:$vD, memrr:$src),
  89                    "lvebx $vD, $src", LdStGeneral,
  90                    [(set VRRC:$vD, (int_ppc_altivec_lvebx xoaddr:$src))]>;
  91 def LVEHX: XForm_1<31,  39, (ops VRRC:$vD, memrr:$src),
  92                    "lvehx $vD, $src", LdStGeneral,
  93                    [(set VRRC:$vD, (int_ppc_altivec_lvehx xoaddr:$src))]>;
  94 def LVEWX: XForm_1<31,  71, (ops VRRC:$vD, memrr:$src),
  95                    "lvewx $vD, $src", LdStGeneral,
  96                    [(set VRRC:$vD, (int_ppc_altivec_lvewx xoaddr:$src))]>;
  97 def LVX  : XForm_1<31, 103, (ops VRRC:$vD, memrr:$src),
  98                    "lvx $vD, $src", LdStGeneral,
  99                    [(set VRRC:$vD, (int_ppc_altivec_lvx xoaddr:$src))]>;
 100 def LVXL : XForm_1<31, 359, (ops VRRC:$vD, memrr:$src),
 101                    "lvxl $vD, $src", LdStGeneral,
 102                    [(set VRRC:$vD, (int_ppc_altivec_lvxl xoaddr:$src))]>;
 103 }
 104
 105 def LVSL : XForm_1<31,   6, (ops VRRC:$vD, memrr:$src),
 106                    "lvsl $vD, $src", LdStGeneral,
 107                    [(set VRRC:$vD, (int_ppc_altivec_lvsl xoaddr:$src))]>,
 108                    PPC970_Unit_LSU;
 109 def LVSR : XForm_1<31,  38, (ops VRRC:$vD, memrr:$src),
 110                    "lvsl $vD, $src", LdStGeneral,
 111                    [(set VRRC:$vD, (int_ppc_altivec_lvsr xoaddr:$src))]>,
 112                    PPC970_Unit_LSU;
 113
 114 let isStore = 1, noResults = 1, PPC970_Unit = 2 in {   // Stores.
 115 def STVEBX: XForm_8<31, 135, (ops VRRC:$rS, memrr:$dst),
 116                    "stvebx $rS, $dst", LdStGeneral,
 117                    [(int_ppc_altivec_stvebx VRRC:$rS, xoaddr:$dst)]>;
 118 def STVEHX: XForm_8<31, 167, (ops VRRC:$rS, memrr:$dst),
 119                    "stvehx $rS, $dst", LdStGeneral,
 120                    [(int_ppc_altivec_stvehx VRRC:$rS, xoaddr:$dst)]>;
 121 def STVEWX: XForm_8<31, 199, (ops VRRC:$rS, memrr:$dst),
 122                    "stvewx $rS, $dst", LdStGeneral,
 123                    [(int_ppc_altivec_stvewx VRRC:$rS, xoaddr:$dst)]>;
 124 def STVX  : XForm_8<31, 231, (ops VRRC:$rS, memrr:$dst),
 125                    "stvx $rS, $dst", LdStGeneral,
 126                    [(int_ppc_altivec_stvx VRRC:$rS, xoaddr:$dst)]>;
 127 def STVXL : XForm_8<31, 487, (ops VRRC:$rS, memrr:$dst),
 128                    "stvxl $rS, $dst", LdStGeneral,
 129                    [(int_ppc_altivec_stvxl VRRC:$rS, xoaddr:$dst)]>;
 130 }
 131
 132 let PPC970_Unit = 5 in {  // VALU Operations.
 133 // VA-Form instructions.  3-input AltiVec ops.
 134 def VMADDFP : VAForm_1<46, (ops VRRC:$vD, VRRC:$vA, VRRC:$vC, VRRC:$vB),
 135                        "vmaddfp $vD, $vA, $vC, $vB", VecFP,
 136                        [(set VRRC:$vD, (fadd (fmul VRRC:$vA, VRRC:$vC),
 137                                              VRRC:$vB))]>,
 138                        Requires<[FPContractions]>;
 139 def VNMSUBFP: VAForm_1<47, (ops VRRC:$vD, VRRC:$vA, VRRC:$vC, VRRC:$vB),
 140                        "vnmsubfp $vD, $vA, $vC, $vB", VecFP,
 141                        [(set VRRC:$vD, (fneg (fsub (fmul VRRC:$vA, VRRC:$vC),
 142                                                    VRRC:$vB)))]>,
 143                        Requires<[FPContractions]>;
 144 def VMHADDSHS  : VA1a_Int<32, "vmhaddshs $vD, $vA, $vB, $vC",
 145                           int_ppc_altivec_vmhaddshs>;
 146 def VMHRADDSHS : VA1a_Int<33, "vmhraddshs $vD, $vA, $vB, $vC",
 147                           int_ppc_altivec_vmhraddshs>;
 148 def VPERM   : VA1a_Int<43, "vperm $vD, $vA, $vB, $vC", int_ppc_altivec_vperm>;
 149 def VSEL    : VA1a_Int<42, "vsel $vD, $vA, $vB, $vC",  int_ppc_altivec_vsel>;
 150
 151 def VSLDOI  : VAForm_2<44, (ops VRRC:$vD, VRRC:$vA, VRRC:$vB, u5imm:$SH),
 152                        "vsldoi $vD, $vA, $vB, $SH", VecFP,
 153                        [(set VRRC:$vD,
 154                              (int_ppc_altivec_vsldoi VRRC:$vA, VRRC:$vB,
 155                                                      imm:$SH))]>;
 156
 157 // VX-Form instructions.  AltiVec arithmetic ops.
 158 def VADDCUW : VXForm_1<384, (ops VRRC:$vD, VRRC:$vA, VRRC:$vB),
 159                        "vaddcuw $vD, $vA, $vB", VecFP,
 160                        [(set VRRC:$vD,
 161                              (int_ppc_altivec_vaddcuw VRRC:$vA, VRRC:$vB))]>;
 162 def VADDFP : VXForm_1<10, (ops VRRC:$vD, VRRC:$vA, VRRC:$vB),
 163                       "vaddfp $vD, $vA, $vB", VecFP,
 164                       [(set VRRC:$vD, (fadd VRRC:$vA, VRRC:$vB))]>;
 165
 166 def VADDUBM : VXForm_1<0, (ops VRRC:$vD, VRRC:$vA, VRRC:$vB),
 167                       "vaddubm $vD, $vA, $vB", VecGeneral,
 168                       [(set VRRC:$vD, (add (v16i8 VRRC:$vA), VRRC:$vB))]>;
 169 def VADDUHM : VXForm_1<64, (ops VRRC:$vD, VRRC:$vA, VRRC:$vB),
 170                       "vadduhm $vD, $vA, $vB", VecGeneral,
 171                       [(set VRRC:$vD, (add (v8i16 VRRC:$vA), VRRC:$vB))]>;
 172 def VADDUWM : VXForm_1<128, (ops VRRC:$vD, VRRC:$vA, VRRC:$vB),
 173                       "vadduwm $vD, $vA, $vB", VecGeneral,
 174                       [(set VRRC:$vD, (add (v4i32 VRRC:$vA), VRRC:$vB))]>;
 175
 176 def VADDSBS : VXForm_1<768, (ops VRRC:$vD, VRRC:$vA, VRRC:$vB),
 177                        "vaddsbs $vD, $vA, $vB", VecFP,
 178                        [(set VRRC:$vD,
 179                              (int_ppc_altivec_vaddsbs VRRC:$vA, VRRC:$vB))]>;
 180 def VADDSHS : VXForm_1<832, (ops VRRC:$vD, VRRC:$vA, VRRC:$vB),
 181                        "vaddshs $vD, $vA, $vB", VecFP,
 182                        [(set VRRC:$vD,
 183                              (int_ppc_altivec_vaddshs VRRC:$vA, VRRC:$vB))]>;
 184 def VADDSWS : VXForm_1<896, (ops VRRC:$vD, VRRC:$vA, VRRC:$vB),
 185                        "vaddsws $vD, $vA, $vB", VecFP,
 186                        [(set VRRC:$vD,
 187                              (int_ppc_altivec_vaddsws VRRC:$vA, VRRC:$vB))]>;
 188
 189 def VADDUBS : VXForm_1<512, (ops VRRC:$vD, VRRC:$vA, VRRC:$vB),
 190                        "vaddubs $vD, $vA, $vB", VecFP,
 191                        [(set VRRC:$vD,
 192                              (int_ppc_altivec_vaddubs VRRC:$vA, VRRC:$vB))]>;
 193 def VADDUHS : VXForm_1<576, (ops VRRC:$vD, VRRC:$vA, VRRC:$vB),
 194                        "vadduhs $vD, $vA, $vB", VecFP,
 195                        [(set VRRC:$vD,
 196                              (int_ppc_altivec_vadduhs VRRC:$vA, VRRC:$vB))]>;
 197 def VADDUWS : VXForm_1<640, (ops VRRC:$vD, VRRC:$vA, VRRC:$vB),
 198                        "vadduws $vD, $vA, $vB", VecFP,
 199                        [(set VRRC:$vD,
 200                              (int_ppc_altivec_vadduws VRRC:$vA, VRRC:$vB))]>;
 201 def VAND : VXForm_1<1028, (ops VRRC:$vD, VRRC:$vA, VRRC:$vB),
 202                     "vand $vD, $vA, $vB", VecFP,
 203                     [(set VRRC:$vD, (and (v4i32 VRRC:$vA), VRRC:$vB))]>;
 204 def VANDC : VXForm_1<1092, (ops VRRC:$vD, VRRC:$vA, VRRC:$vB),
 205                      "vandc $vD, $vA, $vB", VecFP,
 206                      [(set VRRC:$vD, (and (v4i32 VRRC:$vA), (vnot VRRC:$vB)))]>;
 207
 208 def VCFSX  : VXForm_1<842, (ops VRRC:$vD, u5imm:$UIMM, VRRC:$vB),
 209                       "vcfsx $vD, $vB, $UIMM", VecFP,
 210                       [(set VRRC:$vD,
 211                              (int_ppc_altivec_vcfsx VRRC:$vB, imm:$UIMM))]>;
 212 def VCFUX  : VXForm_1<778, (ops VRRC:$vD, u5imm:$UIMM, VRRC:$vB),
 213                       "vcfux $vD, $vB, $UIMM", VecFP,
 214                       [(set VRRC:$vD,
 215                              (int_ppc_altivec_vcfux VRRC:$vB, imm:$UIMM))]>;
 216 def VCTSXS : VXForm_1<970, (ops VRRC:$vD, u5imm:$UIMM, VRRC:$vB),
 217                       "vctsxs $vD, $vB, $UIMM", VecFP,
 218                       []>;
 219 def VCTUXS : VXForm_1<906, (ops VRRC:$vD, u5imm:$UIMM, VRRC:$vB),
 220                       "vctuxs $vD, $vB, $UIMM", VecFP,
 221                       []>;
 222 def VEXPTEFP : VXForm_2<394, (ops VRRC:$vD, VRRC:$vB),
 223                         "vexptefp $vD, $vB", VecFP,
 224                         [(set VRRC:$vD, (int_ppc_altivec_vexptefp VRRC:$vB))]>;
 225 def VLOGEFP  : VXForm_2<458, (ops VRRC:$vD, VRRC:$vB),
 226                         "vlogefp $vD, $vB", VecFP,
 227                         [(set VRRC:$vD, (int_ppc_altivec_vlogefp VRRC:$vB))]>;
 228 def VMAXFP : VXForm_1<1034, (ops VRRC:$vD, VRRC:$vA, VRRC:$vB),
 229                       "vmaxfp $vD, $vA, $vB", VecFP,
 230                       []>;
 231 def VMINFP : VXForm_1<1098, (ops VRRC:$vD, VRRC:$vA, VRRC:$vB),
 232                       "vminfp $vD, $vA, $vB", VecFP,
 233                       []>;
 234
 235 def VMRGHH : VX1_Int<76 , "vmrghh $vD, $vA, $vB", int_ppc_altivec_vmrghh>;
 236 def VMRGHW : VX1_Int<140, "vmrghw $vD, $vA, $vB", int_ppc_altivec_vmrghw>;
 237 def VMRGLH : VX1_Int<332, "vmrglh $vD, $vA, $vB", int_ppc_altivec_vmrglh>;
 238 def VMRGLW : VX1_Int<396, "vmrglw $vD, $vA, $vB", int_ppc_altivec_vmrglw>;
 239
 240 def VMSUMMBM : VA1a_Int<37, "vmsummbm $vD, $vA, $vB, $vC", int_ppc_altivec_vmsummbm>;
 241 def VMSUMSHM : VA1a_Int<40, "vmsumshm $vD, $vA, $vB, $vC", int_ppc_altivec_vmsumshm>;
 242 def VMSUMSHS : VA1a_Int<41, "vmsumshs $vD, $vA, $vB, $vC", int_ppc_altivec_vmsumshs>;
 243 def VMSUMUBM : VA1a_Int<36, "vmsumubm $vD, $vA, $vB, $vC", int_ppc_altivec_vmsumubm>;
 244 def VMSUMUHM : VA1a_Int<38, "vmsumuhm $vD, $vA, $vB, $vC", int_ppc_altivec_vmsumuhm>;
 245 def VMSUMUHS : VA1a_Int<39, "vmsumuhs $vD, $vA, $vB, $vC", int_ppc_altivec_vmsumuhs>;
 246
 247 def VMULESB : VX1_Int<776, "vmulesb $vD, $vA, $vB", int_ppc_altivec_vmulesb>;
 248 def VMULESH : VX1_Int<840, "vmulesh $vD, $vA, $vB", int_ppc_altivec_vmulesh>;
 249 def VMULEUB : VX1_Int<520, "vmuleub $vD, $vA, $vB", int_ppc_altivec_vmuleub>;
 250 def VMULEUH : VX1_Int<584, "vmuleuh $vD, $vA, $vB", int_ppc_altivec_vmuleuh>;
 251 def VMULOSB : VX1_Int<264, "vmulosb $vD, $vA, $vB", int_ppc_altivec_vmulosb>;
 252 def VMULOSH : VX1_Int<328, "vmulosh $vD, $vA, $vB", int_ppc_altivec_vmulosh>;
 253 def VMULOUB : VX1_Int<  8, "vmuloub $vD, $vA, $vB", int_ppc_altivec_vmuloub>;
 254 def VMULOUH : VX1_Int< 72, "vmulouh $vD, $vA, $vB", int_ppc_altivec_vmulouh>;
 255
 256 def VREFP     : VX2_Int<266, "vrefp $vD, $vB",     int_ppc_altivec_vrefp>;
 257 def VRFIM     : VX2_Int<714, "vrfim $vD, $vB",     int_ppc_altivec_vrfim>;
 258 def VRFIN     : VX2_Int<522, "vrfin $vD, $vB",     int_ppc_altivec_vrfin>;
 259 def VRFIP     : VX2_Int<650, "vrfip $vD, $vB",     int_ppc_altivec_vrfip>;
 260 def VRFIZ     : VX2_Int<586, "vrfiz $vD, $vB",     int_ppc_altivec_vrfiz>;
 261 def VRSQRTEFP : VX2_Int<330, "vrsqrtefp $vD, $vB", int_ppc_altivec_vrsqrtefp>;
 262
 263 def VSUBCUW : VX1_Int<74, "vsubcuw $vD, $vA, $vB", int_ppc_altivec_vsubcuw>;
 264
 265 def VSUBFP  : VXForm_1<74, (ops VRRC:$vD, VRRC:$vA, VRRC:$vB),
 266                       "vsubfp $vD, $vA, $vB", VecGeneral,
 267                       [(set VRRC:$vD, (fsub VRRC:$vA, VRRC:$vB))]>;
 268 def VSUBUBM : VXForm_1<1024, (ops VRRC:$vD, VRRC:$vA, VRRC:$vB),
 269                       "vsububm $vD, $vA, $vB", VecGeneral,
 270                       [(set VRRC:$vD, (sub (v16i8 VRRC:$vA), VRRC:$vB))]>;
 271 def VSUBUHM : VXForm_1<1088, (ops VRRC:$vD, VRRC:$vA, VRRC:$vB),
 272                       "vsubuhm $vD, $vA, $vB", VecGeneral,
 273                       [(set VRRC:$vD, (sub (v8i16 VRRC:$vA), VRRC:$vB))]>;
 274 def VSUBUWM : VXForm_1<1152, (ops VRRC:$vD, VRRC:$vA, VRRC:$vB),
 275                       "vsubuwm $vD, $vA, $vB", VecGeneral,
 276                       [(set VRRC:$vD, (sub (v4i32 VRRC:$vA), VRRC:$vB))]>;
 277
 278 def VSUBSBS : VX1_Int<1792, "vsubsbs $vD, $vA, $vB", int_ppc_altivec_vsubsbs>;
 279 def VSUBSHS : VX1_Int<1856, "vsubshs $vD, $vA, $vB", int_ppc_altivec_vsubshs>;
 280 def VSUBSWS : VX1_Int<1920, "vsubsws $vD, $vA, $vB", int_ppc_altivec_vsubsws>;
 281 def VSUBUBS : VX1_Int<1536, "vsububs $vD, $vA, $vB", int_ppc_altivec_vsububs>;
 282 def VSUBUHS : VX1_Int<1600, "vsubuhs $vD, $vA, $vB", int_ppc_altivec_vsubuhs>;
 283 def VSUBUWS : VX1_Int<1664, "vsubuws $vD, $vA, $vB", int_ppc_altivec_vsubuws>;
 284 def VSUMSWS : VX1_Int<1928, "vsumsws $vD, $vA, $vB", int_ppc_altivec_vsumsws>;
 285 def VSUM2SWS: VX1_Int<1672, "vsum2sws $vD, $vA, $vB", int_ppc_altivec_vsum2sws>;
 286 def VSUM4SBS: VX1_Int<1672, "vsum4sbs $vD, $vA, $vB", int_ppc_altivec_vsum4sbs>;
 287 def VSUM4SHS: VX1_Int<1608, "vsum4shs $vD, $vA, $vB", int_ppc_altivec_vsum4shs>;
 288 def VSUM4UBS: VX1_Int<1544, "vsum4ubs $vD, $vA, $vB", int_ppc_altivec_vsum4ubs>;
 289
 290 def VNOR : VXForm_1<1284, (ops VRRC:$vD, VRRC:$vA, VRRC:$vB),
 291                     "vnor $vD, $vA, $vB", VecFP,
 292                     [(set VRRC:$vD, (vnot (or (v4i32 VRRC:$vA), VRRC:$vB)))]>;
 293 def VOR : VXForm_1<1156, (ops VRRC:$vD, VRRC:$vA, VRRC:$vB),
 294                       "vor $vD, $vA, $vB", VecFP,
 295                       [(set VRRC:$vD, (or (v4i32 VRRC:$vA), VRRC:$vB))]>;
 296 def VXOR : VXForm_1<1220, (ops VRRC:$vD, VRRC:$vA, VRRC:$vB),
 297                       "vxor $vD, $vA, $vB", VecFP,
 298                       [(set VRRC:$vD, (xor (v4i32 VRRC:$vA), VRRC:$vB))]>;
 299
 300 def VRLB   : VX1_Int<   4, "vrlb $vD, $vA, $vB", int_ppc_altivec_vrlb>;
 301 def VRLH   : VX1_Int<  68, "vrlh $vD, $vA, $vB", int_ppc_altivec_vrlh>;
 302 def VRLW   : VX1_Int< 132, "vrlw $vD, $vA, $vB", int_ppc_altivec_vrlw>;
 303 def VSLO   : VX1_Int<1036, "vslo $vD, $vA, $vB", int_ppc_altivec_vslo>;
 304 def VSLB   : VX1_Int< 260, "vslb $vD, $vA, $vB", int_ppc_altivec_vslb>;
 305 def VSLH   : VX1_Int< 324, "vslh $vD, $vA, $vB", int_ppc_altivec_vslh>;
 306 def VSLW   : VX1_Int< 388, "vslw $vD, $vA, $vB", int_ppc_altivec_vslw>;
 307
 308 def VSPLTB : VXForm_1<524, (ops VRRC:$vD, u5imm:$UIMM, VRRC:$vB),
 309                       "vspltb $vD, $vB, $UIMM", VecPerm,
 310                       []>;
 311 def VSPLTH : VXForm_1<588, (ops VRRC:$vD, u5imm:$UIMM, VRRC:$vB),
 312                       "vsplth $vD, $vB, $UIMM", VecPerm,
 313                       []>;
 314 def VSPLTW : VXForm_1<652, (ops VRRC:$vD, u5imm:$UIMM, VRRC:$vB),
 315                       "vspltw $vD, $vB, $UIMM", VecPerm,
 316                       [(set VRRC:$vD, (vector_shuffle (v4f32 VRRC:$vB), (undef),
 317                                       VSPLT_shuffle_mask:$UIMM))]>;
 318
 319 def VSR    : VX1_Int< 708, "vsr $vD, $vA, $vB"  , int_ppc_altivec_vsr>;
 320 def VSRO   : VX1_Int<1100, "vsro $vD, $vA, $vB" , int_ppc_altivec_vsro>;
 321 def VSRAB  : VX1_Int< 772, "vsrab $vD, $vA, $vB", int_ppc_altivec_vsrab>;
 322 def VSRAH  : VX1_Int< 836, "vsrah $vD, $vA, $vB", int_ppc_altivec_vsrah>;
 323 def VSRAW  : VX1_Int< 900, "vsraw $vD, $vA, $vB", int_ppc_altivec_vsraw>;
 324 def VSRB   : VX1_Int< 516, "vsrb $vD, $vA, $vB" , int_ppc_altivec_vsrb>;
 325 def VSRH   : VX1_Int< 580, "vsrh $vD, $vA, $vB" , int_ppc_altivec_vsrh>;
 326 def VSRW   : VX1_Int< 644, "vsrw $vD, $vA, $vB" , int_ppc_altivec_vsrw>;
 327
 328
 329 def VSPLTISB : VXForm_3<780, (ops VRRC:$vD, s5imm:$SIMM),
 330                        "vspltisb $vD, $SIMM", VecPerm,
 331                        [(set VRRC:$vD, (v4f32 vecspltisb:$SIMM))]>;
 332 def VSPLTISH : VXForm_3<844, (ops VRRC:$vD, s5imm:$SIMM),
 333                        "vspltish $vD, $SIMM", VecPerm,
 334                        [(set VRRC:$vD, (v4f32 vecspltish:$SIMM))]>;
 335 def VSPLTISW : VXForm_3<908, (ops VRRC:$vD, s5imm:$SIMM),
 336                        "vspltisw $vD, $SIMM", VecPerm,
 337                        [(set VRRC:$vD, (v4f32 vecspltisw:$SIMM))]>;
 338
 339 // Vector Pack.
 340 def VPKPX   : VXForm_1<782, (ops VRRC:$vD, VRRC:$vA, VRRC:$vB),
 341                        "vpkpx $vD, $vA, $vB", VecFP,
 342                        [(set VRRC:$vD,
 343                             (int_ppc_altivec_vpkpx VRRC:$vA, VRRC:$vB))]>;
 344 def VPKSHSS : VXForm_1<398, (ops VRRC:$vD, VRRC:$vA, VRRC:$vB),
 345                        "vpkshss $vD, $vA, $vB", VecFP,
 346                        [(set VRRC:$vD,
 347                             (int_ppc_altivec_vpkshss VRRC:$vA, VRRC:$vB))]>;
 348 def VPKSHUS : VXForm_1<270, (ops VRRC:$vD, VRRC:$vA, VRRC:$vB),
 349                        "vpkshus $vD, $vA, $vB", VecFP,
 350                        [(set VRRC:$vD,
 351                             (int_ppc_altivec_vpkshus VRRC:$vA, VRRC:$vB))]>;
 352 def VPKSWSS : VXForm_1<462, (ops VRRC:$vD, VRRC:$vA, VRRC:$vB),
 353                        "vpkswss $vD, $vA, $vB", VecFP,
 354                        [(set VRRC:$vD,
 355                             (int_ppc_altivec_vpkswss VRRC:$vA, VRRC:$vB))]>;
 356 def VPKSWUS : VXForm_1<334, (ops VRRC:$vD, VRRC:$vA, VRRC:$vB),
 357                        "vpkswus $vD, $vA, $vB", VecFP,
 358                        [(set VRRC:$vD,
 359                             (int_ppc_altivec_vpkswus VRRC:$vA, VRRC:$vB))]>;
 360 def VPKUHUM : VXForm_1<14, (ops VRRC:$vD, VRRC:$vA, VRRC:$vB),
 361                        "vpkuhum $vD, $vA, $vB", VecFP,
 362                        [/*TODO*/]>;
 363 def VPKUHUS : VXForm_1<142, (ops VRRC:$vD, VRRC:$vA, VRRC:$vB),
 364                        "vpkuhus $vD, $vA, $vB", VecFP,
 365                        [(set VRRC:$vD,
 366                             (int_ppc_altivec_vpkuhus VRRC:$vA, VRRC:$vB))]>;
 367 def VPKUWUM : VXForm_1<78, (ops VRRC:$vD, VRRC:$vA, VRRC:$vB),
 368                        "vpkuwum $vD, $vA, $vB", VecFP,
 369                        [/*TODO*/]>;
 370 def VPKUWUS : VXForm_1<206, (ops VRRC:$vD, VRRC:$vA, VRRC:$vB),
 371                        "vpkuwus $vD, $vA, $vB", VecFP,
 372                        [(set VRRC:$vD,
 373                             (int_ppc_altivec_vpkuwus VRRC:$vA, VRRC:$vB))]>;
 374
 375 // Vector Unpack.
 376 def VUPKHPX : VXForm_2<846, (ops VRRC:$vD, VRRC:$vB),
 377                        "vupkhpx $vD, $vB", VecFP,
 378                        [(set VRRC:$vD, (int_ppc_altivec_vupkhpx VRRC:$vB))]>;
 379 def VUPKHSB : VXForm_2<526, (ops VRRC:$vD, VRRC:$vB),
 380                        "vupkhsb $vD, $vB", VecFP,
 381                        [(set VRRC:$vD, (int_ppc_altivec_vupkhsb VRRC:$vB))]>;
 382 def VUPKHSH : VXForm_2<590, (ops VRRC:$vD, VRRC:$vB),
 383                        "vupkhsh $vD, $vB", VecFP,
 384                        [(set VRRC:$vD, (int_ppc_altivec_vupkhsh VRRC:$vB))]>;
 385 def VUPKLPX : VXForm_2<974, (ops VRRC:$vD, VRRC:$vB),
 386                        "vupklpx $vD, $vB", VecFP,
 387                        [(set VRRC:$vD, (int_ppc_altivec_vupklpx VRRC:$vB))]>;
 388 def VUPKLSB : VXForm_2<654, (ops VRRC:$vD, VRRC:$vB),
 389                        "vupklsb $vD, $vB", VecFP,
 390                        [(set VRRC:$vD, (int_ppc_altivec_vupklsb VRRC:$vB))]>;
 391 def VUPKLSH : VXForm_2<718, (ops VRRC:$vD, VRRC:$vB),
 392                        "vupklsh $vD, $vB", VecFP,
 393                        [(set VRRC:$vD, (int_ppc_altivec_vupklsh VRRC:$vB))]>;
 394
 395
 396 // Altivec Comparisons.
 397
 398 class VCMP<bits<10> xo, string asmstr, ValueType Ty>
 399   : VXRForm_1<xo, (ops VRRC:$vD, VRRC:$vA, VRRC:$vB), asmstr, VecFPCompare,
 400               [(set VRRC:$vD, (Ty (PPCvcmp VRRC:$vA, VRRC:$vB, xo)))]>;
 401 class VCMPo<bits<10> xo, string asmstr, ValueType Ty>
 402   : VXRForm_1<xo, (ops VRRC:$vD, VRRC:$vA, VRRC:$vB), asmstr, VecFPCompare,
 403               [(set VRRC:$vD, (Ty (PPCvcmp_o VRRC:$vA, VRRC:$vB, xo)))]>,isVDOT;
 404
 405 // f32 element comparisons.0
 406 def VCMPBFP   : VCMP <966, "vcmpbfp $vD, $vA, $vB"  , v4f32>;
 407 def VCMPBFPo  : VCMPo<966, "vcmpbfp. $vD, $vA, $vB" , v4f32>;
 408 def VCMPEQFP  : VCMP <198, "vcmpeqfp $vD, $vA, $vB" , v4f32>;
 409 def VCMPEQFPo : VCMPo<198, "vcmpeqfp. $vD, $vA, $vB", v4f32>;
 410 def VCMPGEFP  : VCMP <454, "vcmpgefp $vD, $vA, $vB" , v4f32>;
 411 def VCMPGEFPo : VCMPo<454, "vcmpgefp. $vD, $vA, $vB", v4f32>;
 412 def VCMPGTFP  : VCMP <710, "vcmpgtfp $vD, $vA, $vB" , v4f32>;
 413 def VCMPGTFPo : VCMPo<710, "vcmpgtfp. $vD, $vA, $vB", v4f32>;
 414
 415 // i8 element comparisons.
 416 def VCMPEQUB  : VCMP <  6, "vcmpequb $vD, $vA, $vB" , v16i8>;
 417 def VCMPEQUBo : VCMPo<  6, "vcmpequb. $vD, $vA, $vB", v16i8>;
 418 def VCMPGTSB  : VCMP <774, "vcmpgtsb $vD, $vA, $vB" , v16i8>;
 419 def VCMPGTSBo : VCMPo<774, "vcmpgtsb. $vD, $vA, $vB", v16i8>;
 420 def VCMPGTUB  : VCMP <518, "vcmpgtub $vD, $vA, $vB" , v16i8>;
 421 def VCMPGTUBo : VCMPo<518, "vcmpgtub. $vD, $vA, $vB", v16i8>;
 422
 423 // i16 element comparisons.
 424 def VCMPEQUH  : VCMP < 70, "vcmpequh $vD, $vA, $vB" , v8i16>;
 425 def VCMPEQUHo : VCMPo< 70, "vcmpequh. $vD, $vA, $vB", v8i16>;
 426 def VCMPGTSH  : VCMP <838, "vcmpgtsh $vD, $vA, $vB" , v8i16>;
 427 def VCMPGTSHo : VCMPo<838, "vcmpgtsh. $vD, $vA, $vB", v8i16>;
 428 def VCMPGTUH  : VCMP <582, "vcmpgtuh $vD, $vA, $vB" , v8i16>;
 429 def VCMPGTUHo : VCMPo<582, "vcmpgtuh. $vD, $vA, $vB", v8i16>;
 430
 431 // i32 element comparisons.
 432 def VCMPEQUW  : VCMP <134, "vcmpequw $vD, $vA, $vB" , v4i32>;
 433 def VCMPEQUWo : VCMPo<134, "vcmpequw. $vD, $vA, $vB", v4i32>;
 434 def VCMPGTSW  : VCMP <902, "vcmpgtsw $vD, $vA, $vB" , v4i32>;
 435 def VCMPGTSWo : VCMPo<902, "vcmpgtsw. $vD, $vA, $vB", v4i32>;
 436 def VCMPGTUW  : VCMP <646, "vcmpgtuw $vD, $vA, $vB" , v4i32>;
 437 def VCMPGTUWo : VCMPo<646, "vcmpgtuw. $vD, $vA, $vB", v4i32>;
 438
 439 def V_SET0 : VXForm_setzero<1220, (ops VRRC:$vD),
 440                       "vxor $vD, $vD, $vD", VecFP,
 441                       [(set VRRC:$vD, (v4f32 immAllZerosV))]>;
 442 }
 443
 444 //===----------------------------------------------------------------------===//
 445 // Additional Altivec Patterns
 446 //
 447
 448 // Undef/Zero.
 449 def : Pat<(v16i8 (undef)), (v16i8 (IMPLICIT_DEF_VRRC))>;
 450 def : Pat<(v8i16 (undef)), (v8i16 (IMPLICIT_DEF_VRRC))>;
 451 def : Pat<(v4i32 (undef)), (v4i32 (IMPLICIT_DEF_VRRC))>;
 452 def : Pat<(v16i8 immAllZerosV), (v16i8 (V_SET0))>;
 453 def : Pat<(v8i16 immAllZerosV), (v8i16 (V_SET0))>;
 454 def : Pat<(v4i32 immAllZerosV), (v4i32 (V_SET0))>;
 455
 456 // Loads.
 457 def : Pat<(v16i8 (load xoaddr:$src)), (v16i8 (LVX xoaddr:$src))>;
 458 def : Pat<(v8i16 (load xoaddr:$src)), (v8i16 (LVX xoaddr:$src))>;
 459 def : Pat<(v4i32 (load xoaddr:$src)), (v4i32 (LVX xoaddr:$src))>;
 460 def : Pat<(v4f32 (load xoaddr:$src)), (v4f32 (LVX xoaddr:$src))>;
 461
 462 // Stores.
 463 def : Pat<(store (v16i8 VRRC:$rS), xoaddr:$dst),
 464           (STVX (v16i8 VRRC:$rS), xoaddr:$dst)>;
 465 def : Pat<(store (v8i16 VRRC:$rS), xoaddr:$dst),
 466           (STVX (v8i16 VRRC:$rS), xoaddr:$dst)>;
 467 def : Pat<(store (v4i32 VRRC:$rS), xoaddr:$dst),
 468           (STVX (v4i32 VRRC:$rS), xoaddr:$dst)>;
 469 def : Pat<(store (v4f32 VRRC:$rS), xoaddr:$dst),
 470           (STVX (v4f32 VRRC:$rS), xoaddr:$dst)>;
 471
 472 // Bit conversions.
 473 def : Pat<(v16i8 (bitconvert (v8i16 VRRC:$src))), (v16i8 VRRC:$src)>;
 474 def : Pat<(v16i8 (bitconvert (v4i32 VRRC:$src))), (v16i8 VRRC:$src)>;
 475 def : Pat<(v16i8 (bitconvert (v4f32 VRRC:$src))), (v16i8 VRRC:$src)>;
 476
 477 def : Pat<(v8i16 (bitconvert (v16i8 VRRC:$src))), (v8i16 VRRC:$src)>;
 478 def : Pat<(v8i16 (bitconvert (v4i32 VRRC:$src))), (v8i16 VRRC:$src)>;
 479 def : Pat<(v8i16 (bitconvert (v4f32 VRRC:$src))), (v8i16 VRRC:$src)>;
 480
 481 def : Pat<(v4i32 (bitconvert (v16i8 VRRC:$src))), (v4i32 VRRC:$src)>;
 482 def : Pat<(v4i32 (bitconvert (v8i16 VRRC:$src))), (v4i32 VRRC:$src)>;
 483 def : Pat<(v4i32 (bitconvert (v4f32 VRRC:$src))), (v4i32 VRRC:$src)>;
 484
 485 def : Pat<(v4f32 (bitconvert (v16i8 VRRC:$src))), (v4f32 VRRC:$src)>;
 486 def : Pat<(v4f32 (bitconvert (v8i16 VRRC:$src))), (v4f32 VRRC:$src)>;
 487 def : Pat<(v4f32 (bitconvert (v4i32 VRRC:$src))), (v4f32 VRRC:$src)>;
 488
 489 // Immediate vector formation with vsplti*.
 490 def : Pat<(v16i8 vecspltisb:$invec), (v16i8 (VSPLTISB vecspltisb:$invec))>;
 491 def : Pat<(v16i8 vecspltish:$invec), (v16i8 (VSPLTISH vecspltish:$invec))>;
 492 def : Pat<(v16i8 vecspltisw:$invec), (v16i8 (VSPLTISW vecspltisw:$invec))>;
 493
 494 def : Pat<(v8i16 vecspltisb:$invec), (v8i16 (VSPLTISB vecspltisb:$invec))>;
 495 def : Pat<(v8i16 vecspltish:$invec), (v8i16 (VSPLTISH vecspltish:$invec))>;
 496 def : Pat<(v8i16 vecspltisw:$invec), (v8i16 (VSPLTISW vecspltisw:$invec))>;
 497
 498 def : Pat<(v4i32 vecspltisb:$invec), (v4i32 (VSPLTISB vecspltisb:$invec))>;
 499 def : Pat<(v4i32 vecspltish:$invec), (v4i32 (VSPLTISH vecspltish:$invec))>;
 500 def : Pat<(v4i32 vecspltisw:$invec), (v4i32 (VSPLTISW vecspltisw:$invec))>;
 501
 502 // Logical Operations
 503 def : Pat<(v16i8 (and VRRC:$A, VRRC:$B)), (v16i8 (VAND VRRC:$A, VRRC:$B))>;
 504 def : Pat<(v8i16 (and VRRC:$A, VRRC:$B)), (v8i16 (VAND VRRC:$A, VRRC:$B))>;
 505 def : Pat<(v16i8 (or  VRRC:$A, VRRC:$B)), (v16i8 (VOR  VRRC:$A, VRRC:$B))>;
 506 def : Pat<(v8i16 (or  VRRC:$A, VRRC:$B)), (v8i16 (VOR  VRRC:$A, VRRC:$B))>;
 507 def : Pat<(v16i8 (xor VRRC:$A, VRRC:$B)), (v16i8 (VXOR VRRC:$A, VRRC:$B))>;
 508 def : Pat<(v8i16 (xor VRRC:$A, VRRC:$B)), (v8i16 (VXOR VRRC:$A, VRRC:$B))>;
 509 def : Pat<(v16i8 (vnot (or VRRC:$A, VRRC:$B))),(v16i8 (VNOR VRRC:$A, VRRC:$B))>;
 510 def : Pat<(v8i16 (vnot (or VRRC:$A, VRRC:$B))),(v8i16 (VNOR VRRC:$A, VRRC:$B))>;
 511 def : Pat<(v16i8 (and VRRC:$A, (vnot VRRC:$B))),
 512           (v16i8 (VANDC VRRC:$A, VRRC:$B))>;
 513 def : Pat<(v8i16 (and VRRC:$A, (vnot VRRC:$B))),
 514           (v8i16 (VANDC VRRC:$A, VRRC:$B))>;
 515
 516 def : Pat<(fmul VRRC:$vA, VRRC:$vB),
 517           (VMADDFP VRRC:$vA, VRRC:$vB, (V_SET0))>;
 518
 519 // Fused multiply add and multiply sub for packed float.  These are represented
 520 // separately from the real instructions above, for operations that must have
 521 // the additional precision, such as Newton-Rhapson (used by divide, sqrt)
 522 def : Pat<(PPCvmaddfp VRRC:$A, VRRC:$B, VRRC:$C),
 523           (VMADDFP VRRC:$A, VRRC:$B, VRRC:$C)>;
 524 def : Pat<(PPCvnmsubfp VRRC:$A, VRRC:$B, VRRC:$C),
 525           (VNMSUBFP VRRC:$A, VRRC:$B, VRRC:$C)>;
 526
 527 def : Pat<(int_ppc_altivec_vmaddfp VRRC:$A, VRRC:$B, VRRC:$C),
 528           (VMADDFP VRRC:$A, VRRC:$B, VRRC:$C)>;
 529 def : Pat<(int_ppc_altivec_vnmsubfp VRRC:$A, VRRC:$B, VRRC:$C),
 530           (VNMSUBFP VRRC:$A, VRRC:$B, VRRC:$C)>;
 531 def : Pat<(vector_shuffle (v4i32 VRRC:$vB), (undef), VSPLT_shuffle_mask:$UIMM),
 532           (v4i32 (VSPLTW VSPLT_shuffle_mask:$UIMM, VRRC:$vB))>;
 533
 534 def : Pat<(PPCvperm (v4i32 VRRC:$vA), VRRC:$vB, VRRC:$vC),
 535           (v4i32 (VPERM VRRC:$vA, VRRC:$vB, VRRC:$vC))>;
 536 def : Pat<(PPCvperm (v4f32 VRRC:$vA), VRRC:$vB, VRRC:$vC),
 537           (v4f32 (VPERM VRRC:$vA, VRRC:$vB, VRRC:$vC))>;
 538 def : Pat<(PPCvperm (v8i16 VRRC:$vA), VRRC:$vB, VRRC:$vC),
 539           (v8i16 (VPERM VRRC:$vA, VRRC:$vB, VRRC:$vC))>;
 540 def : Pat<(PPCvperm (v16i8 VRRC:$vA), VRRC:$vB, VRRC:$vC),
 541           (v16i8 (VPERM VRRC:$vA, VRRC:$vB, VRRC:$vC))>;