lib/Target/Mips/Mips32r6InstrInfo.td

   1 //=- Mips32r6InstrInfo.td - Mips32r6 Instruction Information -*- tablegen -*-=//
   2 //
   3 //                     The LLVM Compiler Infrastructure
   4 //
   5 // This file is distributed under the University of Illinois Open Source
   6 // License. See LICENSE.TXT for details.
   7 //
   8 //===----------------------------------------------------------------------===//
   9 //
  10 // This file describes Mips32r6 instructions.
  11 //
  12 //===----------------------------------------------------------------------===//
  13
  14 include "Mips32r6InstrFormats.td"
  15
  16 // Notes about removals/changes from MIPS32r6:
  17 // Unclear: ssnop
  18 // Reencoded: cache, pref
  19 // Reencoded: clo, clz
  20 // Reencoded: jr -> jalr
  21 // Reencoded: jr.hb -> jalr.hb
  22 // Reencoded: ldc2
  23 // Reencoded: ll, sc
  24 // Reencoded: lwc2
  25 // Reencoded: sdbbp
  26 // Reencoded: sdc2
  27 // Reencoded: swc2
  28 // Removed: bc1any2, bc1any4
  29 // Removed: bc2[ft]
  30 // Removed: bc2f, bc2t
  31 // Removed: bgezal
  32 // Removed: bltzal
  33 // Removed: c.cond.fmt, bc1[ft]
  34 // Removed: div, divu
  35 // Removed: jalx
  36 // Removed: ldxc1
  37 // Removed: luxc1
  38 // Removed: lwxc1
  39 // Removed: madd.[ds], nmadd.[ds], nmsub.[ds], sub.[ds]
  40 // Removed: mfhi, mflo, mthi, mtlo, madd, maddu, msub, msubu, mul
  41 // Removed: movf, movt
  42 // Removed: movf.fmt, movt.fmt, movn.fmt, movz.fmt
  43 // Removed: movn, movz
  44 // Removed: mult, multu
  45 // Removed: prefx
  46 // Removed: sdxc1
  47 // Removed: suxc1
  48 // Removed: swxc1
  49 // Rencoded: [ls][wd]c2
  50
  51 def brtarget21 : Operand<OtherVT> {
  52   let EncoderMethod = "getBranchTarget21OpValue";
  53   let OperandType = "OPERAND_PCREL";
  54   let DecoderMethod = "DecodeBranchTarget21";
  55   let ParserMatchClass = MipsJumpTargetAsmOperand;
  56 }
  57
  58 def brtarget26 : Operand<OtherVT> {
  59   let EncoderMethod = "getBranchTarget26OpValue";
  60   let OperandType = "OPERAND_PCREL";
  61   let DecoderMethod = "DecodeBranchTarget26";
  62   let ParserMatchClass = MipsJumpTargetAsmOperand;
  63 }
  64
  65 def jmpoffset16 : Operand<OtherVT> {
  66   let EncoderMethod = "getJumpOffset16OpValue";
  67   let ParserMatchClass = MipsJumpTargetAsmOperand;
  68 }
  69
  70 def calloffset16 : Operand<iPTR> {
  71   let EncoderMethod = "getJumpOffset16OpValue";
  72   let ParserMatchClass = MipsJumpTargetAsmOperand;
  73 }
  74
  75 //===----------------------------------------------------------------------===//
  76 //
  77 // Instruction Encodings
  78 //
  79 //===----------------------------------------------------------------------===//
  80
  81 class ADDIUPC_ENC : PCREL19_FM<OPCODE2_ADDIUPC>;
  82 class ALIGN_ENC  : SPECIAL3_ALIGN_FM<OPCODE6_ALIGN>;
  83 class ALUIPC_ENC : PCREL16_FM<OPCODE5_ALUIPC>;
  84 class AUI_ENC    : AUI_FM;
  85 class AUIPC_ENC  : PCREL16_FM<OPCODE5_AUIPC>;
  86
  87 class BALC_ENC  : BRANCH_OFF26_FM<0b111010>;
  88 class BC_ENC    : BRANCH_OFF26_FM<0b110010>;
  89 class BEQC_ENC  : CMP_BRANCH_2R_OFF16_FM<OPGROUP_ADDI>,
  90                   DecodeDisambiguates<"AddiGroupBranch">;
  91 class BEQZALC_ENC : CMP_BRANCH_1R_RT_OFF16_FM<OPGROUP_ADDI>,
  92                     DecodeDisambiguatedBy<"DaddiGroupBranch">;
  93 class BNEC_ENC  : CMP_BRANCH_2R_OFF16_FM<OPGROUP_DADDI>,
  94                   DecodeDisambiguates<"DaddiGroupBranch">;
  95 class BNEZALC_ENC : CMP_BRANCH_1R_RT_OFF16_FM<OPGROUP_DADDI>,
  96                     DecodeDisambiguatedBy<"DaddiGroupBranch">;
  97
  98 class BLTZC_ENC : CMP_BRANCH_1R_BOTH_OFF16_FM<OPGROUP_BGTZL>,
  99                   DecodeDisambiguates<"BgtzlGroupBranch">;
 100 class BGEZC_ENC : CMP_BRANCH_1R_BOTH_OFF16_FM<OPGROUP_BLEZL>,
 101                   DecodeDisambiguates<"BlezlGroupBranch">;
 102 class BGTZALC_ENC : CMP_BRANCH_1R_RT_OFF16_FM<OPGROUP_BGTZ>,
 103                     DecodeDisambiguatedBy<"BgtzGroupBranch">;
 104
 105 class BLEZC_ENC : CMP_BRANCH_1R_RT_OFF16_FM<OPGROUP_BLEZL>,
 106                   DecodeDisambiguatedBy<"BlezlGroupBranch">;
 107 class BLTZALC_ENC : CMP_BRANCH_1R_BOTH_OFF16_FM<OPGROUP_BGTZ>,
 108                     DecodeDisambiguates<"BgtzGroupBranch">;
 109 class BGTZC_ENC : CMP_BRANCH_1R_RT_OFF16_FM<OPGROUP_BGTZL>,
 110                   DecodeDisambiguatedBy<"BgtzlGroupBranch">;
 111
 112 class BEQZC_ENC : CMP_BRANCH_OFF21_FM<0b110110>;
 113 class BGEZALC_ENC : CMP_BRANCH_1R_BOTH_OFF16_FM<OPGROUP_BLEZ>;
 114 class BNEZC_ENC : CMP_BRANCH_OFF21_FM<0b111110>;
 115
 116 class BC1EQZ_ENC : COP1_BCCZ_FM<OPCODE5_BC1EQZ>;
 117 class BC1NEZ_ENC : COP1_BCCZ_FM<OPCODE5_BC1NEZ>;
 118 class BC2EQZ_ENC : COP2_BCCZ_FM<OPCODE5_BC2EQZ>;
 119 class BC2NEZ_ENC : COP2_BCCZ_FM<OPCODE5_BC2NEZ>;
 120
 121 class JIALC_ENC : JMP_IDX_COMPACT_FM<0b111110>;
 122 class JIC_ENC   : JMP_IDX_COMPACT_FM<0b110110>;
 123 class JR_HB_R6_ENC : JR_HB_R6_FM<OPCODE6_JALR>;
 124 class BITSWAP_ENC : SPECIAL3_2R_FM<OPCODE6_BITSWAP>;
 125 class BLEZALC_ENC : CMP_BRANCH_1R_RT_OFF16_FM<OPGROUP_BLEZ>;
 126 class BNVC_ENC   : CMP_BRANCH_2R_OFF16_FM<OPGROUP_DADDI>,
 127                    DecodeDisambiguatedBy<"DaddiGroupBranch">;
 128 class BOVC_ENC   : CMP_BRANCH_2R_OFF16_FM<OPGROUP_ADDI>,
 129                    DecodeDisambiguatedBy<"AddiGroupBranch">;
 130 class DIV_ENC    : SPECIAL_3R_FM<0b00010, 0b011010>;
 131 class DIVU_ENC   : SPECIAL_3R_FM<0b00010, 0b011011>;
 132 class MOD_ENC    : SPECIAL_3R_FM<0b00011, 0b011010>;
 133 class MODU_ENC   : SPECIAL_3R_FM<0b00011, 0b011011>;
 134 class MUH_ENC    : SPECIAL_3R_FM<0b00011, 0b011000>;
 135 class MUHU_ENC   : SPECIAL_3R_FM<0b00011, 0b011001>;
 136 class MUL_R6_ENC : SPECIAL_3R_FM<0b00010, 0b011000>;
 137 class MULU_ENC   : SPECIAL_3R_FM<0b00010, 0b011001>;
 138
 139 class MADDF_S_ENC  : COP1_3R_FM<0b011000, FIELD_FMT_S>;
 140 class MADDF_D_ENC  : COP1_3R_FM<0b011000, FIELD_FMT_D>;
 141 class MSUBF_S_ENC  : COP1_3R_FM<0b011001, FIELD_FMT_S>;
 142 class MSUBF_D_ENC  : COP1_3R_FM<0b011001, FIELD_FMT_D>;
 143
 144 class SEL_D_ENC  : COP1_3R_FM<0b010000, FIELD_FMT_D>;
 145 class SEL_S_ENC  : COP1_3R_FM<0b010000, FIELD_FMT_S>;
 146
 147 class SELEQZ_ENC : SPECIAL_3R_FM<0b00000, 0b110101>;
 148 class SELNEZ_ENC : SPECIAL_3R_FM<0b00000, 0b110111>;
 149
 150 class LWPC_ENC   : PCREL19_FM<OPCODE2_LWPC>;
 151 class LWUPC_ENC  : PCREL19_FM<OPCODE2_LWUPC>;
 152
 153 class MAX_S_ENC : COP1_3R_FM<0b011101, FIELD_FMT_S>;
 154 class MAX_D_ENC : COP1_3R_FM<0b011101, FIELD_FMT_D>;
 155 class MIN_S_ENC : COP1_3R_FM<0b011100, FIELD_FMT_S>;
 156 class MIN_D_ENC : COP1_3R_FM<0b011100, FIELD_FMT_D>;
 157
 158 class MAXA_S_ENC : COP1_3R_FM<0b011111, FIELD_FMT_S>;
 159 class MAXA_D_ENC : COP1_3R_FM<0b011111, FIELD_FMT_D>;
 160 class MINA_S_ENC : COP1_3R_FM<0b011110, FIELD_FMT_S>;
 161 class MINA_D_ENC : COP1_3R_FM<0b011110, FIELD_FMT_D>;
 162
 163 class SELEQZ_S_ENC : COP1_3R_FM<0b010100, FIELD_FMT_S>;
 164 class SELEQZ_D_ENC : COP1_3R_FM<0b010100, FIELD_FMT_D>;
 165 class SELNEZ_S_ENC : COP1_3R_FM<0b010111, FIELD_FMT_S>;
 166 class SELNEZ_D_ENC : COP1_3R_FM<0b010111, FIELD_FMT_D>;
 167
 168 class RINT_S_ENC : COP1_2R_FM<0b011010, FIELD_FMT_S>;
 169 class RINT_D_ENC : COP1_2R_FM<0b011010, FIELD_FMT_D>;
 170 class CLASS_S_ENC : COP1_2R_FM<0b011011, FIELD_FMT_S>;
 171 class CLASS_D_ENC : COP1_2R_FM<0b011011, FIELD_FMT_D>;
 172
 173 class CMP_CONDN_DESC_BASE<string CondStr, string Typestr, RegisterOperand FGROpnd> {
 174   dag OutOperandList = (outs FGROpnd:$fd);
 175   dag InOperandList = (ins FGROpnd:$fs, FGROpnd:$ft);
 176   string AsmString = !strconcat("cmp.", CondStr, ".", Typestr, "\t$fd, $fs, $ft");
 177   list<dag> Pattern = [];
 178 }
 179
 180 //===----------------------------------------------------------------------===//
 181 //
 182 // Instruction Multiclasses
 183 //
 184 //===----------------------------------------------------------------------===//
 185
 186 multiclass CMP_CC_M <FIELD_CMP_FORMAT Format, string Typestr,
 187                      RegisterOperand FGROpnd>{
 188   def CMP_F_#NAME : COP1_CMP_CONDN_FM<Format, FIELD_CMP_COND_F>,
 189                     CMP_CONDN_DESC_BASE<"f", Typestr, FGROpnd>,
 190                     ISA_MIPS32R6;
 191   def CMP_UN_#NAME : COP1_CMP_CONDN_FM<Format, FIELD_CMP_COND_UN>,
 192                      CMP_CONDN_DESC_BASE<"un", Typestr, FGROpnd>,
 193                      ISA_MIPS32R6;
 194   def CMP_EQ_#NAME : COP1_CMP_CONDN_FM<Format, FIELD_CMP_COND_EQ>,
 195                      CMP_CONDN_DESC_BASE<"eq", Typestr, FGROpnd>,
 196                      ISA_MIPS32R6;
 197   def CMP_UEQ_#NAME : COP1_CMP_CONDN_FM<Format, FIELD_CMP_COND_UEQ>,
 198                       CMP_CONDN_DESC_BASE<"ueq", Typestr, FGROpnd>,
 199                       ISA_MIPS32R6;
 200   def CMP_OLT_#NAME : COP1_CMP_CONDN_FM<Format, FIELD_CMP_COND_OLT>,
 201                       CMP_CONDN_DESC_BASE<"olt", Typestr, FGROpnd>,
 202                       ISA_MIPS32R6;
 203   def CMP_ULT_#NAME : COP1_CMP_CONDN_FM<Format, FIELD_CMP_COND_ULT>,
 204                       CMP_CONDN_DESC_BASE<"ult", Typestr, FGROpnd>,
 205                       ISA_MIPS32R6;
 206   def CMP_OLE_#NAME : COP1_CMP_CONDN_FM<Format, FIELD_CMP_COND_OLE>,
 207                       CMP_CONDN_DESC_BASE<"ole", Typestr, FGROpnd>,
 208                       ISA_MIPS32R6;
 209   def CMP_ULE_#NAME : COP1_CMP_CONDN_FM<Format, FIELD_CMP_COND_ULE>,
 210                       CMP_CONDN_DESC_BASE<"ule", Typestr, FGROpnd>,
 211                       ISA_MIPS32R6;
 212   def CMP_SF_#NAME : COP1_CMP_CONDN_FM<Format, FIELD_CMP_COND_SF>,
 213                      CMP_CONDN_DESC_BASE<"sf", Typestr, FGROpnd>,
 214                      ISA_MIPS32R6;
 215   def CMP_NGLE_#NAME : COP1_CMP_CONDN_FM<Format, FIELD_CMP_COND_NGLE>,
 216                        CMP_CONDN_DESC_BASE<"ngle", Typestr, FGROpnd>,
 217                        ISA_MIPS32R6;
 218   def CMP_SEQ_#NAME : COP1_CMP_CONDN_FM<Format, FIELD_CMP_COND_SEQ>,
 219                       CMP_CONDN_DESC_BASE<"seq", Typestr, FGROpnd>,
 220                       ISA_MIPS32R6;
 221   def CMP_NGL_#NAME : COP1_CMP_CONDN_FM<Format, FIELD_CMP_COND_NGL>,
 222                       CMP_CONDN_DESC_BASE<"ngl", Typestr, FGROpnd>,
 223                       ISA_MIPS32R6;
 224   def CMP_LT_#NAME : COP1_CMP_CONDN_FM<Format, FIELD_CMP_COND_LT>,
 225                      CMP_CONDN_DESC_BASE<"lt", Typestr, FGROpnd>,
 226                      ISA_MIPS32R6;
 227   def CMP_NGE_#NAME : COP1_CMP_CONDN_FM<Format, FIELD_CMP_COND_NGE>,
 228                       CMP_CONDN_DESC_BASE<"nge", Typestr, FGROpnd>,
 229                       ISA_MIPS32R6;
 230   def CMP_LE_#NAME : COP1_CMP_CONDN_FM<Format, FIELD_CMP_COND_LE>,
 231                      CMP_CONDN_DESC_BASE<"le", Typestr, FGROpnd>,
 232                      ISA_MIPS32R6;
 233   def CMP_NGT_#NAME : COP1_CMP_CONDN_FM<Format, FIELD_CMP_COND_NGT>,
 234                       CMP_CONDN_DESC_BASE<"ngt", Typestr, FGROpnd>,
 235                       ISA_MIPS32R6;
 236 }
 237
 238 //===----------------------------------------------------------------------===//
 239 //
 240 // Instruction Descriptions
 241 //
 242 //===----------------------------------------------------------------------===//
 243
 244 class PCREL_DESC_BASE<string instr_asm, RegisterOperand GPROpnd,
 245                       Operand ImmOpnd> {
 246   dag OutOperandList = (outs GPROpnd:$rs);
 247   dag InOperandList = (ins ImmOpnd:$imm);
 248   string AsmString = !strconcat(instr_asm, "\t$rs, $imm");
 249   list<dag> Pattern = [];
 250 }
 251
 252 class ADDIUPC_DESC : PCREL_DESC_BASE<"addiupc", GPR32Opnd, simm19_lsl2>;
 253 class LWPC_DESC: PCREL_DESC_BASE<"lwpc", GPR32Opnd, simm19_lsl2>;
 254 class LWUPC_DESC: PCREL_DESC_BASE<"lwupc", GPR32Opnd, simm19_lsl2>;
 255
 256 class ALIGN_DESC_BASE<string instr_asm, RegisterOperand GPROpnd,
 257                       Operand ImmOpnd> {
 258   dag OutOperandList = (outs GPROpnd:$rd);
 259   dag InOperandList = (ins GPROpnd:$rs, GPROpnd:$rt, ImmOpnd:$bp);
 260   string AsmString = !strconcat(instr_asm, "\t$rd, $rs, $rt, $bp");
 261   list<dag> Pattern = [];
 262 }
 263
 264 class ALIGN_DESC : ALIGN_DESC_BASE<"align", GPR32Opnd, uimm2>;
 265
 266 class ALUIPC_DESC_BASE<string instr_asm, RegisterOperand GPROpnd> {
 267   dag OutOperandList = (outs GPROpnd:$rs);
 268   dag InOperandList = (ins simm16:$imm);
 269   string AsmString = !strconcat(instr_asm, "\t$rs, $imm");
 270   list<dag> Pattern = [];
 271 }
 272
 273 class ALUIPC_DESC : ALUIPC_DESC_BASE<"aluipc", GPR32Opnd>;
 274 class AUIPC_DESC : ALUIPC_DESC_BASE<"auipc", GPR32Opnd>;
 275
 276 class AUI_DESC_BASE<string instr_asm, RegisterOperand GPROpnd> {
 277   dag OutOperandList = (outs GPROpnd:$rs);
 278   dag InOperandList = (ins GPROpnd:$rt, simm16:$imm);
 279   string AsmString = !strconcat(instr_asm, "\t$rs, $rt, $imm");
 280   list<dag> Pattern = [];
 281 }
 282
 283 class AUI_DESC : AUI_DESC_BASE<"aui", GPR32Opnd>;
 284
 285 class BRANCH_DESC_BASE {
 286   bit isBranch = 1;
 287   bit isTerminator = 1;
 288   bit hasDelaySlot = 0;
 289 }
 290
 291 class BC_DESC_BASE<string instr_asm, DAGOperand opnd> : BRANCH_DESC_BASE {
 292   dag InOperandList = (ins opnd:$offset);
 293   dag OutOperandList = (outs);
 294   string AsmString = !strconcat(instr_asm, "\t$offset");
 295   bit isBarrier = 1;
 296 }
 297
 298 class CMP_BC_DESC_BASE<string instr_asm, DAGOperand opnd,
 299                        RegisterOperand GPROpnd> : BRANCH_DESC_BASE {
 300   dag InOperandList = (ins GPROpnd:$rs, GPROpnd:$rt, opnd:$offset);
 301   dag OutOperandList = (outs);
 302   string AsmString = !strconcat(instr_asm, "\t$rs, $rt, $offset");
 303   list<Register> Defs = [AT];
 304 }
 305
 306 class CMP_CBR_EQNE_Z_DESC_BASE<string instr_asm, DAGOperand opnd,
 307                                RegisterOperand GPROpnd> : BRANCH_DESC_BASE {
 308   dag InOperandList = (ins GPROpnd:$rs, opnd:$offset);
 309   dag OutOperandList = (outs);
 310   string AsmString = !strconcat(instr_asm, "\t$rs, $offset");
 311   list<Register> Defs = [AT];
 312 }
 313
 314 class CMP_CBR_RT_Z_DESC_BASE<string instr_asm, DAGOperand opnd,
 315                              RegisterOperand GPROpnd> : BRANCH_DESC_BASE {
 316   dag InOperandList = (ins GPROpnd:$rt, opnd:$offset);
 317   dag OutOperandList = (outs);
 318   string AsmString = !strconcat(instr_asm, "\t$rt, $offset");
 319   list<Register> Defs = [AT];
 320 }
 321
 322 class BALC_DESC : BC_DESC_BASE<"balc", brtarget26> {
 323   bit isCall = 1;
 324   list<Register> Defs = [RA];
 325 }
 326
 327 class BC_DESC : BC_DESC_BASE<"bc", brtarget26>;
 328 class BEQC_DESC : CMP_BC_DESC_BASE<"beqc", brtarget, GPR32Opnd>;
 329 class BNEC_DESC : CMP_BC_DESC_BASE<"bnec", brtarget, GPR32Opnd>;
 330
 331 class BLTZC_DESC : CMP_CBR_RT_Z_DESC_BASE<"bltzc", brtarget, GPR32Opnd>;
 332 class BGEZC_DESC : CMP_CBR_RT_Z_DESC_BASE<"bgezc", brtarget, GPR32Opnd>;
 333
 334 class BLEZC_DESC : CMP_CBR_RT_Z_DESC_BASE<"blezc", brtarget, GPR32Opnd>;
 335 class BGTZC_DESC : CMP_CBR_RT_Z_DESC_BASE<"bgtzc", brtarget, GPR32Opnd>;
 336
 337 class BEQZC_DESC : CMP_CBR_EQNE_Z_DESC_BASE<"beqzc", brtarget21, GPR32Opnd>;
 338 class BNEZC_DESC : CMP_CBR_EQNE_Z_DESC_BASE<"bnezc", brtarget21, GPR32Opnd>;
 339
 340 class COP1_BCCZ_DESC_BASE<string instr_asm> : BRANCH_DESC_BASE {
 341   dag InOperandList = (ins FGR64Opnd:$ft, brtarget:$offset);
 342   dag OutOperandList = (outs);
 343   string AsmString = instr_asm;
 344   bit hasDelaySlot = 1;
 345 }
 346
 347 class BC1EQZ_DESC : COP1_BCCZ_DESC_BASE<"bc1eqz $ft, $offset">;
 348 class BC1NEZ_DESC : COP1_BCCZ_DESC_BASE<"bc1nez $ft, $offset">;
 349
 350 class COP2_BCCZ_DESC_BASE<string instr_asm> : BRANCH_DESC_BASE {
 351   dag InOperandList = (ins COP2Opnd:$ct, brtarget:$offset);
 352   dag OutOperandList = (outs);
 353   string AsmString = instr_asm;
 354   bit hasDelaySlot = 1;
 355 }
 356
 357 class BC2EQZ_DESC : COP2_BCCZ_DESC_BASE<"bc2eqz $ct, $offset">;
 358 class BC2NEZ_DESC : COP2_BCCZ_DESC_BASE<"bc2nez $ct, $offset">;
 359
 360 class BOVC_DESC   : CMP_BC_DESC_BASE<"bovc", brtarget, GPR32Opnd>;
 361 class BNVC_DESC   : CMP_BC_DESC_BASE<"bnvc", brtarget, GPR32Opnd>;
 362
 363 class JMP_IDX_COMPACT_DESC_BASE<string opstr, DAGOperand opnd,
 364                                 RegisterOperand GPROpnd> {
 365   dag InOperandList = (ins GPROpnd:$rt, opnd:$offset);
 366   string AsmString = !strconcat(opstr, "\t$rt, $offset");
 367   list<dag> Pattern = [];
 368   bit isTerminator = 1;
 369   bit hasDelaySlot = 0;
 370   string DecoderMethod = "DecodeSimm16";
 371 }
 372
 373 class JIALC_DESC : JMP_IDX_COMPACT_DESC_BASE<"jialc", calloffset16,
 374                                              GPR32Opnd> {
 375   bit isCall = 1;
 376   list<Register> Defs = [RA];
 377 }
 378
 379 class JIC_DESC : JMP_IDX_COMPACT_DESC_BASE<"jic", jmpoffset16, GPR32Opnd> {
 380   bit isBarrier = 1;
 381   list<Register> Defs = [AT];
 382 }
 383
 384 class JR_HB_R6_DESC : JR_HB_DESC_BASE<"jr.hb", GPR32Opnd> {
 385   bit isBranch = 1;
 386   bit isIndirectBranch = 1;
 387   bit hasDelaySlot = 1;
 388   bit isTerminator=1;
 389   bit isBarrier=1;
 390 }
 391
 392 class BITSWAP_DESC_BASE<string instr_asm, RegisterOperand GPROpnd> {
 393   dag OutOperandList = (outs GPROpnd:$rd);
 394   dag InOperandList = (ins GPROpnd:$rt);
 395   string AsmString = !strconcat(instr_asm, "\t$rd, $rt");
 396   list<dag> Pattern = [];
 397 }
 398
 399 class BITSWAP_DESC : BITSWAP_DESC_BASE<"bitswap", GPR32Opnd>;
 400
 401 class DIVMOD_DESC_BASE<string instr_asm, RegisterOperand GPROpnd> {
 402   dag OutOperandList = (outs GPROpnd:$rd);
 403   dag InOperandList = (ins GPROpnd:$rs, GPROpnd:$rt);
 404   string AsmString = !strconcat(instr_asm, "\t$rd, $rs, $rt");
 405   list<dag> Pattern = [];
 406 }
 407
 408 class DIV_DESC  : DIVMOD_DESC_BASE<"div", GPR32Opnd>;
 409 class DIVU_DESC : DIVMOD_DESC_BASE<"divu", GPR32Opnd>;
 410 class MOD_DESC  : DIVMOD_DESC_BASE<"mod", GPR32Opnd>;
 411 class MODU_DESC : DIVMOD_DESC_BASE<"modu", GPR32Opnd>;
 412
 413 class BEQZALC_DESC : CMP_CBR_RT_Z_DESC_BASE<"beqzalc", brtarget, GPR32Opnd> {
 414   list<Register> Defs = [RA];
 415 }
 416
 417 class BGEZALC_DESC : CMP_CBR_RT_Z_DESC_BASE<"bgezalc", brtarget, GPR32Opnd> {
 418   list<Register> Defs = [RA];
 419 }
 420
 421 class BGTZALC_DESC : CMP_CBR_RT_Z_DESC_BASE<"bgtzalc", brtarget, GPR32Opnd> {
 422   list<Register> Defs = [RA];
 423 }
 424
 425 class BLEZALC_DESC : CMP_CBR_RT_Z_DESC_BASE<"blezalc", brtarget, GPR32Opnd> {
 426   list<Register> Defs = [RA];
 427 }
 428
 429 class BLTZALC_DESC : CMP_CBR_RT_Z_DESC_BASE<"bltzalc", brtarget, GPR32Opnd> {
 430   list<Register> Defs = [RA];
 431 }
 432
 433 class BNEZALC_DESC : CMP_CBR_RT_Z_DESC_BASE<"bnezalc", brtarget, GPR32Opnd> {
 434   list<Register> Defs = [RA];
 435 }
 436 class MUL_R6_DESC_BASE<string instr_asm, RegisterOperand GPROpnd> {
 437   dag OutOperandList = (outs GPROpnd:$rd);
 438   dag InOperandList = (ins GPROpnd:$rs, GPROpnd:$rt);
 439   string AsmString = !strconcat(instr_asm, "\t$rd, $rs, $rt");
 440   list<dag> Pattern = [];
 441 }
 442
 443 class MUH_DESC    : MUL_R6_DESC_BASE<"muh", GPR32Opnd>;
 444 class MUHU_DESC   : MUL_R6_DESC_BASE<"muhu", GPR32Opnd>;
 445 class MUL_R6_DESC : MUL_R6_DESC_BASE<"mul", GPR32Opnd>;
 446 class MULU_DESC   : MUL_R6_DESC_BASE<"mulu", GPR32Opnd>;
 447
 448 class COP1_4R_DESC_BASE<string instr_asm, RegisterOperand FGROpnd> {
 449   dag OutOperandList = (outs FGROpnd:$fd);
 450   dag InOperandList = (ins FGROpnd:$fd_in, FGROpnd:$fs, FGROpnd:$ft);
 451   string AsmString = !strconcat(instr_asm, "\t$fd, $fs, $ft");
 452   list<dag> Pattern = [];
 453   string Constraints = "$fd_in = $fd";
 454 }
 455
 456 class SEL_D_DESC : COP1_4R_DESC_BASE<"sel.d", FGR64Opnd>;
 457 class SEL_S_DESC : COP1_4R_DESC_BASE<"sel.s", FGR32Opnd>;
 458
 459 class SELEQNE_Z_DESC_BASE<string instr_asm, RegisterOperand GPROpnd> {
 460   dag OutOperandList = (outs GPROpnd:$rd);
 461   dag InOperandList = (ins GPROpnd:$rs, GPROpnd:$rt);
 462   string AsmString = !strconcat(instr_asm, "\t$rd, $rs, $rt");
 463   list<dag> Pattern = [];
 464 }
 465
 466 class SELEQZ_DESC : SELEQNE_Z_DESC_BASE<"seleqz", GPR32Opnd>;
 467 class SELNEZ_DESC : SELEQNE_Z_DESC_BASE<"selnez", GPR32Opnd>;
 468
 469 class MADDF_S_DESC  : COP1_4R_DESC_BASE<"maddf.s", FGR32Opnd>;
 470 class MADDF_D_DESC  : COP1_4R_DESC_BASE<"maddf.d", FGR64Opnd>;
 471 class MSUBF_S_DESC  : COP1_4R_DESC_BASE<"msubf.s", FGR32Opnd>;
 472 class MSUBF_D_DESC  : COP1_4R_DESC_BASE<"msubf.d", FGR64Opnd>;
 473
 474 class MAX_MIN_DESC_BASE<string instr_asm, RegisterOperand FGROpnd> {
 475   dag OutOperandList = (outs FGROpnd:$fd);
 476   dag InOperandList = (ins FGROpnd:$fs, FGROpnd:$ft);
 477   string AsmString = !strconcat(instr_asm, "\t$fd, $fs, $ft");
 478   list<dag> Pattern = [];
 479 }
 480
 481 class MAX_S_DESC : MAX_MIN_DESC_BASE<"max.s", FGR32Opnd>;
 482 class MAX_D_DESC : MAX_MIN_DESC_BASE<"max.d", FGR64Opnd>;
 483 class MIN_S_DESC : MAX_MIN_DESC_BASE<"min.s", FGR32Opnd>;
 484 class MIN_D_DESC : MAX_MIN_DESC_BASE<"min.d", FGR64Opnd>;
 485
 486 class MAXA_S_DESC : MAX_MIN_DESC_BASE<"maxa.s", FGR32Opnd>;
 487 class MAXA_D_DESC : MAX_MIN_DESC_BASE<"maxa.d", FGR64Opnd>;
 488 class MINA_S_DESC : MAX_MIN_DESC_BASE<"mina.s", FGR32Opnd>;
 489 class MINA_D_DESC : MAX_MIN_DESC_BASE<"mina.d", FGR64Opnd>;
 490
 491 class SELEQNEZ_DESC_BASE<string instr_asm, RegisterOperand FGROpnd> {
 492   dag OutOperandList = (outs FGROpnd:$fd);
 493   dag InOperandList = (ins FGROpnd:$fs, FGROpnd:$ft);
 494   string AsmString = !strconcat(instr_asm, "\t$fd, $fs, $ft");
 495   list<dag> Pattern = [];
 496 }
 497
 498 class SELEQZ_S_DESC : SELEQNEZ_DESC_BASE<"seleqz.s", FGR32Opnd>;
 499 class SELEQZ_D_DESC : SELEQNEZ_DESC_BASE<"seleqz.d", FGR64Opnd>;
 500 class SELNEZ_S_DESC : SELEQNEZ_DESC_BASE<"selnez.s", FGR32Opnd>;
 501 class SELNEZ_D_DESC : SELEQNEZ_DESC_BASE<"selnez.d", FGR64Opnd>;
 502
 503 class CLASS_RINT_DESC_BASE<string instr_asm, RegisterOperand FGROpnd> {
 504   dag OutOperandList = (outs FGROpnd:$fd);
 505   dag InOperandList = (ins FGROpnd:$fs);
 506   string AsmString = !strconcat(instr_asm, "\t$fd, $fs");
 507   list<dag> Pattern = [];
 508 }
 509
 510 class RINT_S_DESC : CLASS_RINT_DESC_BASE<"rint.s", FGR32Opnd>;
 511 class RINT_D_DESC : CLASS_RINT_DESC_BASE<"rint.d", FGR64Opnd>;
 512 class CLASS_S_DESC : CLASS_RINT_DESC_BASE<"class.s", FGR32Opnd>;
 513 class CLASS_D_DESC : CLASS_RINT_DESC_BASE<"class.d", FGR64Opnd>;
 514
 515 //===----------------------------------------------------------------------===//
 516 //
 517 // Instruction Definitions
 518 //
 519 //===----------------------------------------------------------------------===//
 520
 521 def ADDIUPC : ADDIUPC_ENC, ADDIUPC_DESC, ISA_MIPS32R6;
 522 def ALIGN : ALIGN_ENC, ALIGN_DESC, ISA_MIPS32R6;
 523 def ALUIPC : ALUIPC_ENC, ALUIPC_DESC, ISA_MIPS32R6;
 524 def AUI : AUI_ENC, AUI_DESC, ISA_MIPS32R6;
 525 def AUIPC : AUIPC_ENC, AUIPC_DESC, ISA_MIPS32R6;
 526 def BALC : BALC_ENC, BALC_DESC, ISA_MIPS32R6;
 527 def BC1EQZ : BC1EQZ_ENC, BC1EQZ_DESC, ISA_MIPS32R6;
 528 def BC1NEZ : BC1NEZ_ENC, BC1NEZ_DESC, ISA_MIPS32R6;
 529 def BC2EQZ : BC2EQZ_ENC, BC2EQZ_DESC, ISA_MIPS32R6;
 530 def BC2NEZ : BC2NEZ_ENC, BC2NEZ_DESC, ISA_MIPS32R6;
 531 def BC : BC_ENC, BC_DESC, ISA_MIPS32R6;
 532 def BEQC : BEQC_ENC, BEQC_DESC, ISA_MIPS32R6;
 533 def BEQZALC : BEQZALC_ENC, BEQZALC_DESC, ISA_MIPS32R6;
 534 def BEQZC : BEQZC_ENC, BEQZC_DESC, ISA_MIPS32R6;
 535 def BGEC;  // Also aliased to blec with operands swapped
 536 def BGEUC; // Also aliased to bleuc with operands swapped
 537 def BGEZALC : BGEZALC_ENC, BGEZALC_DESC, ISA_MIPS32R6;
 538 def BGEZC : BGEZC_ENC, BGEZC_DESC, ISA_MIPS32R6;
 539 def BGTZALC : BGTZALC_ENC, BGTZALC_DESC, ISA_MIPS32R6;
 540 def BGTZC : BGTZC_ENC, BGTZC_DESC, ISA_MIPS32R6;
 541 def BITSWAP : BITSWAP_ENC, BITSWAP_DESC, ISA_MIPS32R6;
 542 def BLEZALC : BLEZALC_ENC, BLEZALC_DESC, ISA_MIPS32R6;
 543 def BLEZC : BLEZC_ENC, BLEZC_DESC, ISA_MIPS32R6;
 544 def BLTC; // Also aliased to bgtc with operands swapped
 545 def BLTUC; // Also aliased to bgtuc with operands swapped
 546 def BLTZALC : BLTZALC_ENC, BLTZALC_DESC, ISA_MIPS32R6;
 547 def BLTZC : BLTZC_ENC, BLTZC_DESC, ISA_MIPS32R6;
 548 def BNEC : BNEC_ENC, BNEC_DESC, ISA_MIPS32R6;
 549 def BNEZALC : BNEZALC_ENC, BNEZALC_DESC, ISA_MIPS32R6;
 550 def BNEZC : BNEZC_ENC, BNEZC_DESC, ISA_MIPS32R6;
 551 def BNVC : BNVC_ENC, BNVC_DESC, ISA_MIPS32R6;
 552 def BOVC : BOVC_ENC, BOVC_DESC, ISA_MIPS32R6;
 553 def CLASS_D : CLASS_D_ENC, CLASS_D_DESC, ISA_MIPS32R6;
 554 def CLASS_S : CLASS_S_ENC, CLASS_S_DESC, ISA_MIPS32R6;
 555 defm S : CMP_CC_M<FIELD_CMP_FORMAT_S, "s", FGR32Opnd>;
 556 defm D : CMP_CC_M<FIELD_CMP_FORMAT_D, "d", FGR64Opnd>;
 557 def DIV : DIV_ENC, DIV_DESC, ISA_MIPS32R6;
 558 def DIVU : DIVU_ENC, DIVU_DESC, ISA_MIPS32R6;
 559 def JIALC : JIALC_ENC, JIALC_DESC, ISA_MIPS32R6;
 560 def JIC : JIC_ENC, JIC_DESC, ISA_MIPS32R6;
 561 def JR_HB_R6 : JR_HB_R6_ENC, JR_HB_R6_DESC, ISA_MIPS32R6;
 562 // def LSA; // See MSA
 563 def LWPC : LWPC_ENC, LWPC_DESC, ISA_MIPS32R6;
 564 def LWUPC : LWUPC_ENC, LWUPC_DESC, ISA_MIPS32R6;
 565 def MADDF_S : MADDF_S_ENC, MADDF_S_DESC, ISA_MIPS32R6;
 566 def MADDF_D : MADDF_D_ENC, MADDF_D_DESC, ISA_MIPS32R6;
 567 def MAXA_D : MAXA_D_ENC, MAXA_D_DESC, ISA_MIPS32R6;
 568 def MAXA_S : MAXA_S_ENC, MAXA_S_DESC, ISA_MIPS32R6;
 569 def MAX_D : MAX_D_ENC, MAX_D_DESC, ISA_MIPS32R6;
 570 def MAX_S : MAX_S_ENC, MAX_S_DESC, ISA_MIPS32R6;
 571 def MINA_D : MINA_D_ENC, MINA_D_DESC, ISA_MIPS32R6;
 572 def MINA_S : MINA_S_ENC, MINA_S_DESC, ISA_MIPS32R6;
 573 def MIN_D : MIN_D_ENC, MIN_D_DESC, ISA_MIPS32R6;
 574 def MIN_S : MIN_S_ENC, MIN_S_DESC, ISA_MIPS32R6;
 575 def MOD : MOD_ENC, MOD_DESC, ISA_MIPS32R6;
 576 def MODU : MODU_ENC, MODU_DESC, ISA_MIPS32R6;
 577 def MSUBF_S : MSUBF_S_ENC, MSUBF_S_DESC, ISA_MIPS32R6;
 578 def MSUBF_D : MSUBF_D_ENC, MSUBF_D_DESC, ISA_MIPS32R6;
 579 def MUH    : MUH_ENC, MUH_DESC, ISA_MIPS32R6;
 580 def MUHU   : MUHU_ENC, MUHU_DESC, ISA_MIPS32R6;
 581 def MUL_R6 : MUL_R6_ENC, MUL_R6_DESC, ISA_MIPS32R6;
 582 def MULU   : MULU_ENC, MULU_DESC, ISA_MIPS32R6;
 583 def NAL; // BAL with rd=0
 584 def RINT_D : RINT_D_ENC, RINT_D_DESC, ISA_MIPS32R6;
 585 def RINT_S : RINT_S_ENC, RINT_S_DESC, ISA_MIPS32R6;
 586 def SELEQZ : SELEQZ_ENC, SELEQZ_DESC, ISA_MIPS32R6;
 587 def SELEQZ_D : SELEQZ_D_ENC, SELEQZ_D_DESC, ISA_MIPS32R6;
 588 def SELEQZ_S : SELEQZ_S_ENC, SELEQZ_S_DESC, ISA_MIPS32R6;
 589 def SELNEZ : SELNEZ_ENC, SELNEZ_DESC, ISA_MIPS32R6;
 590 def SELNEZ_D : SELNEZ_D_ENC, SELNEZ_D_DESC, ISA_MIPS32R6;
 591 def SELNEZ_S : SELNEZ_S_ENC, SELNEZ_S_DESC, ISA_MIPS32R6;
 592 def SEL_D : SEL_D_ENC, SEL_D_DESC, ISA_MIPS32R6;
 593 def SEL_S : SEL_S_ENC, SEL_S_DESC, ISA_MIPS32R6;