include/llvm/Target/TargetSelectionDAG.td

   1 //===- TargetSelectionDAG.td - Common code for DAG isels ---*- tablegen -*-===//
   2 //
   3 //                     The LLVM Compiler Infrastructure
   4 //
   5 // This file is distributed under the University of Illinois Open Source
   6 // License. See LICENSE.TXT for details.
   7 //
   8 //===----------------------------------------------------------------------===//
   9 //
  10 // This file defines the target-independent interfaces used by SelectionDAG
  11 // instruction selection generators.
  12 //
  13 //===----------------------------------------------------------------------===//
  14
  15 //===----------------------------------------------------------------------===//
  16 // Selection DAG Type Constraint definitions.
  17 //
  18 // Note that the semantics of these constraints are hard coded into tblgen.  To
  19 // modify or add constraints, you have to hack tblgen.
  20 //
  21
  22 class SDTypeConstraint<int opnum> {
  23   int OperandNum = opnum;
  24 }
  25
  26 // SDTCisVT - The specified operand has exactly this VT.
  27 class SDTCisVT<int OpNum, ValueType vt> : SDTypeConstraint<OpNum> {
  28   ValueType VT = vt;
  29 }
  30
  31 class SDTCisPtrTy<int OpNum> : SDTypeConstraint<OpNum>;
  32
  33 // SDTCisInt - The specified operand has integer type.
  34 class SDTCisInt<int OpNum> : SDTypeConstraint<OpNum>;
  35
  36 // SDTCisFP - The specified operand has floating-point type.
  37 class SDTCisFP<int OpNum> : SDTypeConstraint<OpNum>;
  38
  39 // SDTCisVec - The specified operand has a vector type.
  40 class SDTCisVec<int OpNum> : SDTypeConstraint<OpNum>;
  41
  42 // SDTCisSameAs - The two specified operands have identical types.
  43 class SDTCisSameAs<int OpNum, int OtherOp> : SDTypeConstraint<OpNum> {
  44   int OtherOperandNum = OtherOp;
  45 }
  46
  47 // SDTCisVTSmallerThanOp - The specified operand is a VT SDNode, and its type is
  48 // smaller than the 'Other' operand.
  49 class SDTCisVTSmallerThanOp<int OpNum, int OtherOp> : SDTypeConstraint<OpNum> {
  50   int OtherOperandNum = OtherOp;
  51 }
  52
  53 class SDTCisOpSmallerThanOp<int SmallOp, int BigOp> : SDTypeConstraint<SmallOp>{
  54   int BigOperandNum = BigOp;
  55 }
  56
  57 /// SDTCisEltOfVec - This indicates that ThisOp is a scalar type of the same
  58 /// type as the element type of OtherOp, which is a vector type.
  59 class SDTCisEltOfVec<int ThisOp, int OtherOp>
  60   : SDTypeConstraint<ThisOp> {
  61   int OtherOpNum = OtherOp;
  62 }
  63
  64 /// SDTCisSubVecOfVec - This indicates that ThisOp is a vector type
  65 /// with length less that of OtherOp, which is a vector type.
  66 class SDTCisSubVecOfVec<int ThisOp, int OtherOp>
  67   : SDTypeConstraint<ThisOp> {
  68   int OtherOpNum = OtherOp;
  69 }
  70
  71 // SDTCVecEltisVT - The specified operand is vector type with element type
  72 // of VT.
  73 class SDTCVecEltisVT<int OpNum, ValueType vt> : SDTypeConstraint<OpNum> {
  74   ValueType VT = vt;
  75 }
  76
  77 // SDTCisSameNumEltsAs - The two specified operands have identical number
  78 // of elements.
  79 class SDTCisSameNumEltsAs<int OpNum, int OtherOp> : SDTypeConstraint<OpNum> {
  80   int OtherOperandNum = OtherOp;
  81 }
  82
  83 //===----------------------------------------------------------------------===//
  84 // Selection DAG Type Profile definitions.
  85 //
  86 // These use the constraints defined above to describe the type requirements of
  87 // the various nodes.  These are not hard coded into tblgen, allowing targets to
  88 // add their own if needed.
  89 //
  90
  91 // SDTypeProfile - This profile describes the type requirements of a Selection
  92 // DAG node.
  93 class SDTypeProfile<int numresults, int numoperands,
  94                     list<SDTypeConstraint> constraints> {
  95   int NumResults = numresults;
  96   int NumOperands = numoperands;
  97   list<SDTypeConstraint> Constraints = constraints;
  98 }
  99
 100 // Builtin profiles.
 101 def SDTIntLeaf: SDTypeProfile<1, 0, [SDTCisInt<0>]>;         // for 'imm'.
 102 def SDTFPLeaf : SDTypeProfile<1, 0, [SDTCisFP<0>]>;          // for 'fpimm'.
 103 def SDTPtrLeaf: SDTypeProfile<1, 0, [SDTCisPtrTy<0>]>;       // for '&g'.
 104 def SDTOther  : SDTypeProfile<1, 0, [SDTCisVT<0, OtherVT>]>; // for 'vt'.
 105 def SDTUNDEF  : SDTypeProfile<1, 0, []>;                     // for 'undef'.
 106 def SDTUnaryOp  : SDTypeProfile<1, 1, []>;                   // for bitconvert.
 107
 108 def SDTIntBinOp : SDTypeProfile<1, 2, [     // add, and, or, xor, udiv, etc.
 109   SDTCisSameAs<0, 1>, SDTCisSameAs<0, 2>, SDTCisInt<0>
 110 ]>;
 111 def SDTIntShiftOp : SDTypeProfile<1, 2, [   // shl, sra, srl
 112   SDTCisSameAs<0, 1>, SDTCisInt<0>, SDTCisInt<2>
 113 ]>;
 114 def SDTIntBinHiLoOp : SDTypeProfile<2, 2, [ // mulhi, mullo, sdivrem, udivrem
 115   SDTCisSameAs<0, 1>, SDTCisSameAs<0, 2>, SDTCisSameAs<0, 3>,SDTCisInt<0>
 116 ]>;
 117
 118 def SDTFPBinOp : SDTypeProfile<1, 2, [      // fadd, fmul, etc.
 119   SDTCisSameAs<0, 1>, SDTCisSameAs<0, 2>, SDTCisFP<0>
 120 ]>;
 121 def SDTFPSignOp : SDTypeProfile<1, 2, [     // fcopysign.
 122   SDTCisSameAs<0, 1>, SDTCisFP<0>, SDTCisFP<2>
 123 ]>;
 124 def SDTFPTernaryOp : SDTypeProfile<1, 3, [  // fmadd, fnmsub, etc.
 125   SDTCisSameAs<0, 1>, SDTCisSameAs<0, 2>, SDTCisSameAs<0, 3>, SDTCisFP<0>
 126 ]>;
 127 def SDTIntUnaryOp : SDTypeProfile<1, 1, [   // ctlz
 128   SDTCisSameAs<0, 1>, SDTCisInt<0>
 129 ]>;
 130 def SDTIntExtendOp : SDTypeProfile<1, 1, [  // sext, zext, anyext
 131   SDTCisInt<0>, SDTCisInt<1>, SDTCisOpSmallerThanOp<1, 0>
 132 ]>;
 133 def SDTIntTruncOp  : SDTypeProfile<1, 1, [  // trunc
 134   SDTCisInt<0>, SDTCisInt<1>, SDTCisOpSmallerThanOp<0, 1>
 135 ]>;
 136 def SDTFPUnaryOp  : SDTypeProfile<1, 1, [   // fneg, fsqrt, etc
 137   SDTCisSameAs<0, 1>, SDTCisFP<0>
 138 ]>;
 139 def SDTFPRoundOp  : SDTypeProfile<1, 1, [   // fround
 140   SDTCisFP<0>, SDTCisFP<1>, SDTCisOpSmallerThanOp<0, 1>
 141 ]>;
 142 def SDTFPExtendOp  : SDTypeProfile<1, 1, [  // fextend
 143   SDTCisFP<0>, SDTCisFP<1>, SDTCisOpSmallerThanOp<1, 0>
 144 ]>;
 145 def SDTIntToFPOp : SDTypeProfile<1, 1, [    // [su]int_to_fp
 146   SDTCisFP<0>, SDTCisInt<1>
 147 ]>;
 148 def SDTFPToIntOp : SDTypeProfile<1, 1, [    // fp_to_[su]int
 149   SDTCisInt<0>, SDTCisFP<1>
 150 ]>;
 151 def SDTExtInreg : SDTypeProfile<1, 2, [     // sext_inreg
 152   SDTCisSameAs<0, 1>, SDTCisInt<0>, SDTCisVT<2, OtherVT>,
 153   SDTCisVTSmallerThanOp<2, 1>
 154 ]>;
 155
 156 def SDTSetCC : SDTypeProfile<1, 3, [        // setcc
 157   SDTCisInt<0>, SDTCisSameAs<1, 2>, SDTCisVT<3, OtherVT>
 158 ]>;
 159
 160 def SDTSelect : SDTypeProfile<1, 3, [       // select
 161   SDTCisInt<1>, SDTCisSameAs<0, 2>, SDTCisSameAs<2, 3>
 162 ]>;
 163
 164 def SDTVSelect : SDTypeProfile<1, 3, [       // vselect
 165   SDTCisInt<1>, SDTCisSameAs<0, 2>, SDTCisSameAs<2, 3>
 166 ]>;
 167
 168 def SDTSelectCC : SDTypeProfile<1, 5, [     // select_cc
 169   SDTCisSameAs<1, 2>, SDTCisSameAs<3, 4>, SDTCisSameAs<0, 3>,
 170   SDTCisVT<5, OtherVT>
 171 ]>;
 172
 173 def SDTBr : SDTypeProfile<0, 1, [           // br
 174   SDTCisVT<0, OtherVT>
 175 ]>;
 176
 177 def SDTBrCC : SDTypeProfile<0, 4, [       // brcc
 178   SDTCisVT<0, OtherVT>, SDTCisSameAs<1, 2>, SDTCisVT<3, OtherVT>
 179 ]>;
 180
 181 def SDTBrcond : SDTypeProfile<0, 2, [       // brcond
 182   SDTCisInt<0>, SDTCisVT<1, OtherVT>
 183 ]>;
 184
 185 def SDTBrind : SDTypeProfile<0, 1, [        // brind
 186   SDTCisPtrTy<0>
 187 ]>;
 188
 189 def SDTNone : SDTypeProfile<0, 0, []>;      // ret, trap
 190
 191 def SDTLoad : SDTypeProfile<1, 1, [         // load
 192   SDTCisPtrTy<1>
 193 ]>;
 194
 195 def SDTStore : SDTypeProfile<0, 2, [        // store
 196   SDTCisPtrTy<1>
 197 ]>;
 198
 199 def SDTIStore : SDTypeProfile<1, 3, [       // indexed store
 200   SDTCisSameAs<0, 2>, SDTCisPtrTy<0>, SDTCisPtrTy<3>
 201 ]>;
 202
 203 def SDTMaskedStore: SDTypeProfile<0, 3, [       // masked store
 204   SDTCisPtrTy<0>, SDTCisVec<1>, SDTCisVec<2>
 205 ]>;
 206
 207 def SDTMaskedLoad: SDTypeProfile<1, 3, [       // masked load
 208   SDTCisVec<0>, SDTCisPtrTy<1>, SDTCisVec<2>, SDTCisSameAs<0, 3>
 209 ]>;
 210
 211 def SDTMaskedGather: SDTypeProfile<2, 3, [       // masked gather
 212   SDTCisVec<0>, SDTCisVec<1>, SDTCisSameAs<0, 2>, SDTCisSameAs<1, 3>,
 213   SDTCisPtrTy<4>, SDTCVecEltisVT<1, i1>, SDTCisSameNumEltsAs<0, 1>
 214 ]>;
 215
 216 def SDTMaskedScatter: SDTypeProfile<1, 3, [       // masked scatter
 217   SDTCisVec<0>, SDTCisVec<1>, SDTCisSameAs<0, 2>, SDTCisSameNumEltsAs<0, 1>,
 218   SDTCVecEltisVT<0, i1>, SDTCisPtrTy<3>
 219 ]>;
 220
 221 def SDTVecShuffle : SDTypeProfile<1, 2, [
 222   SDTCisSameAs<0, 1>, SDTCisSameAs<1, 2>
 223 ]>;
 224 def SDTVecExtract : SDTypeProfile<1, 2, [   // vector extract
 225   SDTCisEltOfVec<0, 1>, SDTCisPtrTy<2>
 226 ]>;
 227 def SDTVecInsert : SDTypeProfile<1, 3, [    // vector insert
 228   SDTCisEltOfVec<2, 1>, SDTCisSameAs<0, 1>, SDTCisPtrTy<3>
 229 ]>;
 230
 231 def SDTSubVecExtract : SDTypeProfile<1, 2, [// subvector extract
 232   SDTCisSubVecOfVec<0,1>, SDTCisInt<2>
 233 ]>;
 234 def SDTSubVecInsert : SDTypeProfile<1, 3, [ // subvector insert
 235   SDTCisSubVecOfVec<2, 1>, SDTCisSameAs<0,1>, SDTCisInt<3>
 236 ]>;
 237
 238 def SDTPrefetch : SDTypeProfile<0, 4, [     // prefetch
 239   SDTCisPtrTy<0>, SDTCisSameAs<1, 2>, SDTCisSameAs<1, 3>, SDTCisInt<1>
 240 ]>;
 241
 242 def SDTMemBarrier : SDTypeProfile<0, 5, [   // memory barrier
 243   SDTCisSameAs<0,1>,  SDTCisSameAs<0,2>,  SDTCisSameAs<0,3>, SDTCisSameAs<0,4>,
 244   SDTCisInt<0>
 245 ]>;
 246 def SDTAtomicFence : SDTypeProfile<0, 2, [
 247   SDTCisSameAs<0,1>, SDTCisPtrTy<0>
 248 ]>;
 249 def SDTAtomic3 : SDTypeProfile<1, 3, [
 250   SDTCisSameAs<0,2>,  SDTCisSameAs<0,3>, SDTCisInt<0>, SDTCisPtrTy<1>
 251 ]>;
 252 def SDTAtomic2 : SDTypeProfile<1, 2, [
 253   SDTCisSameAs<0,2>, SDTCisInt<0>, SDTCisPtrTy<1>
 254 ]>;
 255 def SDTAtomicStore : SDTypeProfile<0, 2, [
 256   SDTCisPtrTy<0>, SDTCisInt<1>
 257 ]>;
 258 def SDTAtomicLoad : SDTypeProfile<1, 1, [
 259   SDTCisInt<0>, SDTCisPtrTy<1>
 260 ]>;
 261
 262 def SDTConvertOp : SDTypeProfile<1, 5, [ //cvtss, su, us, uu, ff, fs, fu, sf, su
 263   SDTCisVT<2, OtherVT>, SDTCisVT<3, OtherVT>, SDTCisPtrTy<4>, SDTCisPtrTy<5>
 264 ]>;
 265
 266 class SDCallSeqStart<list<SDTypeConstraint> constraints> :
 267         SDTypeProfile<0, 1, constraints>;
 268 class SDCallSeqEnd<list<SDTypeConstraint> constraints> :
 269         SDTypeProfile<0, 2, constraints>;
 270
 271 //===----------------------------------------------------------------------===//
 272 // Selection DAG Node Properties.
 273 //
 274 // Note: These are hard coded into tblgen.
 275 //
 276 class SDNodeProperty;
 277 def SDNPCommutative : SDNodeProperty;   // X op Y == Y op X
 278 def SDNPAssociative : SDNodeProperty;   // (X op Y) op Z == X op (Y op Z)
 279 def SDNPHasChain    : SDNodeProperty;   // R/W chain operand and result
 280 def SDNPOutGlue     : SDNodeProperty;   // Write a flag result
 281 def SDNPInGlue      : SDNodeProperty;   // Read a flag operand
 282 def SDNPOptInGlue   : SDNodeProperty;   // Optionally read a flag operand
 283 def SDNPMayStore    : SDNodeProperty;   // May write to memory, sets 'mayStore'.
 284 def SDNPMayLoad     : SDNodeProperty;   // May read memory, sets 'mayLoad'.
 285 def SDNPSideEffect  : SDNodeProperty;   // Sets 'HasUnmodelledSideEffects'.
 286 def SDNPMemOperand  : SDNodeProperty;   // Touches memory, has assoc MemOperand
 287 def SDNPVariadic    : SDNodeProperty;   // Node has variable arguments.
 288 def SDNPWantRoot    : SDNodeProperty;   // ComplexPattern gets the root of match
 289 def SDNPWantParent  : SDNodeProperty;   // ComplexPattern gets the parent
 290
 291 //===----------------------------------------------------------------------===//
 292 // Selection DAG Pattern Operations
 293 class SDPatternOperator;
 294
 295 //===----------------------------------------------------------------------===//
 296 // Selection DAG Node definitions.
 297 //
 298 class SDNode<string opcode, SDTypeProfile typeprof,
 299              list<SDNodeProperty> props = [], string sdclass = "SDNode">
 300              : SDPatternOperator {
 301   string Opcode  = opcode;
 302   string SDClass = sdclass;
 303   list<SDNodeProperty> Properties = props;
 304   SDTypeProfile TypeProfile = typeprof;
 305 }
 306
 307 // Special TableGen-recognized dag nodes
 308 def set;
 309 def implicit;
 310 def node;
 311 def srcvalue;
 312
 313 def imm        : SDNode<"ISD::Constant"  , SDTIntLeaf , [], "ConstantSDNode">;
 314 def timm       : SDNode<"ISD::TargetConstant",SDTIntLeaf, [], "ConstantSDNode">;
 315 def fpimm      : SDNode<"ISD::ConstantFP", SDTFPLeaf  , [], "ConstantFPSDNode">;
 316 def vt         : SDNode<"ISD::VALUETYPE" , SDTOther   , [], "VTSDNode">;
 317 def bb         : SDNode<"ISD::BasicBlock", SDTOther   , [], "BasicBlockSDNode">;
 318 def cond       : SDNode<"ISD::CONDCODE"  , SDTOther   , [], "CondCodeSDNode">;
 319 def undef      : SDNode<"ISD::UNDEF"     , SDTUNDEF   , []>;
 320 def globaladdr : SDNode<"ISD::GlobalAddress",         SDTPtrLeaf, [],
 321                         "GlobalAddressSDNode">;
 322 def tglobaladdr : SDNode<"ISD::TargetGlobalAddress",  SDTPtrLeaf, [],
 323                          "GlobalAddressSDNode">;
 324 def globaltlsaddr : SDNode<"ISD::GlobalTLSAddress",         SDTPtrLeaf, [],
 325                           "GlobalAddressSDNode">;
 326 def tglobaltlsaddr : SDNode<"ISD::TargetGlobalTLSAddress",  SDTPtrLeaf, [],
 327                            "GlobalAddressSDNode">;
 328 def constpool   : SDNode<"ISD::ConstantPool",         SDTPtrLeaf, [],
 329                          "ConstantPoolSDNode">;
 330 def tconstpool  : SDNode<"ISD::TargetConstantPool",   SDTPtrLeaf, [],
 331                          "ConstantPoolSDNode">;
 332 def jumptable   : SDNode<"ISD::JumpTable",            SDTPtrLeaf, [],
 333                          "JumpTableSDNode">;
 334 def tjumptable  : SDNode<"ISD::TargetJumpTable",      SDTPtrLeaf, [],
 335                          "JumpTableSDNode">;
 336 def frameindex  : SDNode<"ISD::FrameIndex",           SDTPtrLeaf, [],
 337                          "FrameIndexSDNode">;
 338 def tframeindex : SDNode<"ISD::TargetFrameIndex",     SDTPtrLeaf, [],
 339                          "FrameIndexSDNode">;
 340 def externalsym : SDNode<"ISD::ExternalSymbol",       SDTPtrLeaf, [],
 341                          "ExternalSymbolSDNode">;
 342 def texternalsym: SDNode<"ISD::TargetExternalSymbol", SDTPtrLeaf, [],
 343                          "ExternalSymbolSDNode">;
 344 def blockaddress : SDNode<"ISD::BlockAddress",        SDTPtrLeaf, [],
 345                          "BlockAddressSDNode">;
 346 def tblockaddress: SDNode<"ISD::TargetBlockAddress",  SDTPtrLeaf, [],
 347                          "BlockAddressSDNode">;
 348
 349 def add        : SDNode<"ISD::ADD"       , SDTIntBinOp   ,
 350                         [SDNPCommutative, SDNPAssociative]>;
 351 def sub        : SDNode<"ISD::SUB"       , SDTIntBinOp>;
 352 def mul        : SDNode<"ISD::MUL"       , SDTIntBinOp,
 353                         [SDNPCommutative, SDNPAssociative]>;
 354 def mulhs      : SDNode<"ISD::MULHS"     , SDTIntBinOp, [SDNPCommutative]>;
 355 def mulhu      : SDNode<"ISD::MULHU"     , SDTIntBinOp, [SDNPCommutative]>;
 356 def smullohi   : SDNode<"ISD::SMUL_LOHI" , SDTIntBinHiLoOp, [SDNPCommutative]>;
 357 def umullohi   : SDNode<"ISD::UMUL_LOHI" , SDTIntBinHiLoOp, [SDNPCommutative]>;
 358 def sdiv       : SDNode<"ISD::SDIV"      , SDTIntBinOp>;
 359 def udiv       : SDNode<"ISD::UDIV"      , SDTIntBinOp>;
 360 def srem       : SDNode<"ISD::SREM"      , SDTIntBinOp>;
 361 def urem       : SDNode<"ISD::UREM"      , SDTIntBinOp>;
 362 def sdivrem    : SDNode<"ISD::SDIVREM"   , SDTIntBinHiLoOp>;
 363 def udivrem    : SDNode<"ISD::UDIVREM"   , SDTIntBinHiLoOp>;
 364 def srl        : SDNode<"ISD::SRL"       , SDTIntShiftOp>;
 365 def sra        : SDNode<"ISD::SRA"       , SDTIntShiftOp>;
 366 def shl        : SDNode<"ISD::SHL"       , SDTIntShiftOp>;
 367 def rotl       : SDNode<"ISD::ROTL"      , SDTIntShiftOp>;
 368 def rotr       : SDNode<"ISD::ROTR"      , SDTIntShiftOp>;
 369 def and        : SDNode<"ISD::AND"       , SDTIntBinOp,
 370                         [SDNPCommutative, SDNPAssociative]>;
 371 def or         : SDNode<"ISD::OR"        , SDTIntBinOp,
 372                         [SDNPCommutative, SDNPAssociative]>;
 373 def xor        : SDNode<"ISD::XOR"       , SDTIntBinOp,
 374                         [SDNPCommutative, SDNPAssociative]>;
 375 def addc       : SDNode<"ISD::ADDC"      , SDTIntBinOp,
 376                         [SDNPCommutative, SDNPOutGlue]>;
 377 def adde       : SDNode<"ISD::ADDE"      , SDTIntBinOp,
 378                         [SDNPCommutative, SDNPOutGlue, SDNPInGlue]>;
 379 def subc       : SDNode<"ISD::SUBC"      , SDTIntBinOp,
 380                         [SDNPOutGlue]>;
 381 def sube       : SDNode<"ISD::SUBE"      , SDTIntBinOp,
 382                         [SDNPOutGlue, SDNPInGlue]>;
 383 def smin       : SDNode<"ISD::SMIN"      , SDTIntBinOp>;
 384 def smax       : SDNode<"ISD::SMAX"      , SDTIntBinOp>;
 385 def umin       : SDNode<"ISD::UMIN"      , SDTIntBinOp>;
 386 def umax       : SDNode<"ISD::UMAX"      , SDTIntBinOp>;
 387
 388 def sext_inreg : SDNode<"ISD::SIGN_EXTEND_INREG", SDTExtInreg>;
 389 def bswap      : SDNode<"ISD::BSWAP"      , SDTIntUnaryOp>;
 390 def ctlz       : SDNode<"ISD::CTLZ"       , SDTIntUnaryOp>;
 391 def cttz       : SDNode<"ISD::CTTZ"       , SDTIntUnaryOp>;
 392 def ctpop      : SDNode<"ISD::CTPOP"      , SDTIntUnaryOp>;
 393 def ctlz_zero_undef : SDNode<"ISD::CTLZ_ZERO_UNDEF", SDTIntUnaryOp>;
 394 def cttz_zero_undef : SDNode<"ISD::CTTZ_ZERO_UNDEF", SDTIntUnaryOp>;
 395 def sext       : SDNode<"ISD::SIGN_EXTEND", SDTIntExtendOp>;
 396 def zext       : SDNode<"ISD::ZERO_EXTEND", SDTIntExtendOp>;
 397 def anyext     : SDNode<"ISD::ANY_EXTEND" , SDTIntExtendOp>;
 398 def trunc      : SDNode<"ISD::TRUNCATE"   , SDTIntTruncOp>;
 399 def bitconvert : SDNode<"ISD::BITCAST"    , SDTUnaryOp>;
 400 def addrspacecast : SDNode<"ISD::ADDRSPACECAST", SDTUnaryOp>;
 401 def extractelt : SDNode<"ISD::EXTRACT_VECTOR_ELT", SDTVecExtract>;
 402 def insertelt  : SDNode<"ISD::INSERT_VECTOR_ELT", SDTVecInsert>;
 403
 404 def fadd       : SDNode<"ISD::FADD"       , SDTFPBinOp, [SDNPCommutative]>;
 405 def fsub       : SDNode<"ISD::FSUB"       , SDTFPBinOp>;
 406 def fmul       : SDNode<"ISD::FMUL"       , SDTFPBinOp, [SDNPCommutative]>;
 407 def fdiv       : SDNode<"ISD::FDIV"       , SDTFPBinOp>;
 408 def frem       : SDNode<"ISD::FREM"       , SDTFPBinOp>;
 409 def fma        : SDNode<"ISD::FMA"        , SDTFPTernaryOp>;
 410 def fmad       : SDNode<"ISD::FMAD"       , SDTFPTernaryOp>;
 411 def fabs       : SDNode<"ISD::FABS"       , SDTFPUnaryOp>;
 412 def fminnum    : SDNode<"ISD::FMINNUM"    , SDTFPBinOp>;
 413 def fmaxnum    : SDNode<"ISD::FMAXNUM"    , SDTFPBinOp>;
 414 def fgetsign   : SDNode<"ISD::FGETSIGN"   , SDTFPToIntOp>;
 415 def fneg       : SDNode<"ISD::FNEG"       , SDTFPUnaryOp>;
 416 def fsqrt      : SDNode<"ISD::FSQRT"      , SDTFPUnaryOp>;
 417 def fsin       : SDNode<"ISD::FSIN"       , SDTFPUnaryOp>;
 418 def fcos       : SDNode<"ISD::FCOS"       , SDTFPUnaryOp>;
 419 def fexp2      : SDNode<"ISD::FEXP2"      , SDTFPUnaryOp>;
 420 def fpow       : SDNode<"ISD::FPOW"       , SDTFPBinOp>;
 421 def flog2      : SDNode<"ISD::FLOG2"      , SDTFPUnaryOp>;
 422 def frint      : SDNode<"ISD::FRINT"      , SDTFPUnaryOp>;
 423 def ftrunc     : SDNode<"ISD::FTRUNC"     , SDTFPUnaryOp>;
 424 def fceil      : SDNode<"ISD::FCEIL"      , SDTFPUnaryOp>;
 425 def ffloor     : SDNode<"ISD::FFLOOR"     , SDTFPUnaryOp>;
 426 def fnearbyint : SDNode<"ISD::FNEARBYINT" , SDTFPUnaryOp>;
 427 def frnd       : SDNode<"ISD::FROUND"     , SDTFPUnaryOp>;
 428
 429 def fround     : SDNode<"ISD::FP_ROUND"   , SDTFPRoundOp>;
 430 def fextend    : SDNode<"ISD::FP_EXTEND"  , SDTFPExtendOp>;
 431 def fcopysign  : SDNode<"ISD::FCOPYSIGN"  , SDTFPSignOp>;
 432
 433 def sint_to_fp : SDNode<"ISD::SINT_TO_FP" , SDTIntToFPOp>;
 434 def uint_to_fp : SDNode<"ISD::UINT_TO_FP" , SDTIntToFPOp>;
 435 def fp_to_sint : SDNode<"ISD::FP_TO_SINT" , SDTFPToIntOp>;
 436 def fp_to_uint : SDNode<"ISD::FP_TO_UINT" , SDTFPToIntOp>;
 437 def f16_to_fp  : SDNode<"ISD::FP16_TO_FP" , SDTIntToFPOp>;
 438 def fp_to_f16  : SDNode<"ISD::FP_TO_FP16" , SDTFPToIntOp>;
 439
 440 def setcc      : SDNode<"ISD::SETCC"      , SDTSetCC>;
 441 def select     : SDNode<"ISD::SELECT"     , SDTSelect>;
 442 def vselect    : SDNode<"ISD::VSELECT"    , SDTVSelect>;
 443 def selectcc   : SDNode<"ISD::SELECT_CC"  , SDTSelectCC>;
 444
 445 def brcc       : SDNode<"ISD::BR_CC"      , SDTBrCC,   [SDNPHasChain]>;
 446 def brcond     : SDNode<"ISD::BRCOND"     , SDTBrcond, [SDNPHasChain]>;
 447 def brind      : SDNode<"ISD::BRIND"      , SDTBrind,  [SDNPHasChain]>;
 448 def br         : SDNode<"ISD::BR"         , SDTBr,     [SDNPHasChain]>;
 449 def trap       : SDNode<"ISD::TRAP"       , SDTNone,
 450                         [SDNPHasChain, SDNPSideEffect]>;
 451 def debugtrap  : SDNode<"ISD::DEBUGTRAP"  , SDTNone,
 452                         [SDNPHasChain, SDNPSideEffect]>;
 453
 454 def prefetch   : SDNode<"ISD::PREFETCH"   , SDTPrefetch,
 455                         [SDNPHasChain, SDNPMayLoad, SDNPMayStore,
 456                          SDNPMemOperand]>;
 457
 458 def readcyclecounter : SDNode<"ISD::READCYCLECOUNTER", SDTIntLeaf,
 459                      [SDNPHasChain, SDNPSideEffect]>;
 460
 461 def atomic_fence : SDNode<"ISD::ATOMIC_FENCE" , SDTAtomicFence,
 462                           [SDNPHasChain, SDNPSideEffect]>;
 463
 464 def atomic_cmp_swap : SDNode<"ISD::ATOMIC_CMP_SWAP" , SDTAtomic3,
 465                     [SDNPHasChain, SDNPMayStore, SDNPMayLoad, SDNPMemOperand]>;
 466 def atomic_load_add : SDNode<"ISD::ATOMIC_LOAD_ADD" , SDTAtomic2,
 467                     [SDNPHasChain, SDNPMayStore, SDNPMayLoad, SDNPMemOperand]>;
 468 def atomic_swap     : SDNode<"ISD::ATOMIC_SWAP", SDTAtomic2,
 469                     [SDNPHasChain, SDNPMayStore, SDNPMayLoad, SDNPMemOperand]>;
 470 def atomic_load_sub : SDNode<"ISD::ATOMIC_LOAD_SUB" , SDTAtomic2,
 471                     [SDNPHasChain, SDNPMayStore, SDNPMayLoad, SDNPMemOperand]>;
 472 def atomic_load_and : SDNode<"ISD::ATOMIC_LOAD_AND" , SDTAtomic2,
 473                     [SDNPHasChain, SDNPMayStore, SDNPMayLoad, SDNPMemOperand]>;
 474 def atomic_load_or  : SDNode<"ISD::ATOMIC_LOAD_OR" , SDTAtomic2,
 475                     [SDNPHasChain, SDNPMayStore, SDNPMayLoad, SDNPMemOperand]>;
 476 def atomic_load_xor : SDNode<"ISD::ATOMIC_LOAD_XOR" , SDTAtomic2,
 477                     [SDNPHasChain, SDNPMayStore, SDNPMayLoad, SDNPMemOperand]>;
 478 def atomic_load_nand: SDNode<"ISD::ATOMIC_LOAD_NAND", SDTAtomic2,
 479                     [SDNPHasChain, SDNPMayStore, SDNPMayLoad, SDNPMemOperand]>;
 480 def atomic_load_min : SDNode<"ISD::ATOMIC_LOAD_MIN", SDTAtomic2,
 481                     [SDNPHasChain, SDNPMayStore, SDNPMayLoad, SDNPMemOperand]>;
 482 def atomic_load_max : SDNode<"ISD::ATOMIC_LOAD_MAX", SDTAtomic2,
 483                     [SDNPHasChain, SDNPMayStore, SDNPMayLoad, SDNPMemOperand]>;
 484 def atomic_load_umin : SDNode<"ISD::ATOMIC_LOAD_UMIN", SDTAtomic2,
 485                     [SDNPHasChain, SDNPMayStore, SDNPMayLoad, SDNPMemOperand]>;
 486 def atomic_load_umax : SDNode<"ISD::ATOMIC_LOAD_UMAX", SDTAtomic2,
 487                     [SDNPHasChain, SDNPMayStore, SDNPMayLoad, SDNPMemOperand]>;
 488 def atomic_load      : SDNode<"ISD::ATOMIC_LOAD", SDTAtomicLoad,
 489                     [SDNPHasChain, SDNPMayLoad, SDNPMemOperand]>;
 490 def atomic_store     : SDNode<"ISD::ATOMIC_STORE", SDTAtomicStore,
 491                     [SDNPHasChain, SDNPMayStore, SDNPMemOperand]>;
 492
 493 def masked_store : SDNode<"ISD::MSTORE",  SDTMaskedStore,
 494                        [SDNPHasChain, SDNPMayStore, SDNPMemOperand]>;
 495 def masked_load  : SDNode<"ISD::MLOAD",  SDTMaskedLoad,
 496                        [SDNPHasChain, SDNPMayLoad, SDNPMemOperand]>;
 497 def masked_scatter : SDNode<"ISD::MSCATTER",  SDTMaskedScatter,
 498                        [SDNPHasChain, SDNPMayStore, SDNPMemOperand]>;
 499 def masked_gather  : SDNode<"ISD::MGATHER",  SDTMaskedGather,
 500                        [SDNPHasChain, SDNPMayLoad, SDNPMemOperand]>;
 501
 502 // Do not use ld, st directly. Use load, extload, sextload, zextload, store,
 503 // and truncst (see below).
 504 def ld         : SDNode<"ISD::LOAD"       , SDTLoad,
 505                         [SDNPHasChain, SDNPMayLoad, SDNPMemOperand]>;
 506 def st         : SDNode<"ISD::STORE"      , SDTStore,
 507                         [SDNPHasChain, SDNPMayStore, SDNPMemOperand]>;
 508 def ist        : SDNode<"ISD::STORE"      , SDTIStore,
 509                         [SDNPHasChain, SDNPMayStore, SDNPMemOperand]>;
 510
 511 def vector_shuffle : SDNode<"ISD::VECTOR_SHUFFLE", SDTVecShuffle, []>;
 512 def build_vector : SDNode<"ISD::BUILD_VECTOR", SDTypeProfile<1, -1, []>, []>;
 513 def scalar_to_vector : SDNode<"ISD::SCALAR_TO_VECTOR", SDTypeProfile<1, 1, []>,
 514                               []>;
 515 def vector_extract : SDNode<"ISD::EXTRACT_VECTOR_ELT",
 516     SDTypeProfile<1, 2, [SDTCisPtrTy<2>]>, []>;
 517 def vector_insert : SDNode<"ISD::INSERT_VECTOR_ELT",
 518     SDTypeProfile<1, 3, [SDTCisSameAs<0, 1>, SDTCisPtrTy<3>]>, []>;
 519 def concat_vectors : SDNode<"ISD::CONCAT_VECTORS",
 520     SDTypeProfile<1, 2, [SDTCisSubVecOfVec<1, 0>, SDTCisSameAs<1, 2>]>,[]>;
 521
 522 // This operator does not do subvector type checking.  The ARM
 523 // backend, at least, needs it.
 524 def vector_extract_subvec : SDNode<"ISD::EXTRACT_SUBVECTOR",
 525     SDTypeProfile<1, 2, [SDTCisInt<2>, SDTCisVec<1>, SDTCisVec<0>]>,
 526     []>;
 527
 528 // This operator does subvector type checking.
 529 def extract_subvector : SDNode<"ISD::EXTRACT_SUBVECTOR", SDTSubVecExtract, []>;
 530 def insert_subvector : SDNode<"ISD::INSERT_SUBVECTOR", SDTSubVecInsert, []>;
 531
 532 // Nodes for intrinsics, you should use the intrinsic itself and let tblgen use
 533 // these internally.  Don't reference these directly.
 534 def intrinsic_void : SDNode<"ISD::INTRINSIC_VOID",
 535                             SDTypeProfile<0, -1, [SDTCisPtrTy<0>]>,
 536                             [SDNPHasChain]>;
 537 def intrinsic_w_chain : SDNode<"ISD::INTRINSIC_W_CHAIN",
 538                                SDTypeProfile<1, -1, [SDTCisPtrTy<1>]>,
 539                                [SDNPHasChain]>;
 540 def intrinsic_wo_chain : SDNode<"ISD::INTRINSIC_WO_CHAIN",
 541                                 SDTypeProfile<1, -1, [SDTCisPtrTy<1>]>, []>;
 542
 543 // Do not use cvt directly. Use cvt forms below
 544 def cvt : SDNode<"ISD::CONVERT_RNDSAT", SDTConvertOp>;
 545
 546 def SDT_assertext : SDTypeProfile<1, 1,
 547   [SDTCisInt<0>, SDTCisInt<1>, SDTCisSameAs<1, 0>]>;
 548 def assertsext : SDNode<"ISD::AssertSext", SDT_assertext>;
 549 def assertzext : SDNode<"ISD::AssertZext", SDT_assertext>;
 550
 551
 552 //===----------------------------------------------------------------------===//
 553 // Selection DAG Condition Codes
 554
 555 class CondCode; // ISD::CondCode enums
 556 def SETOEQ : CondCode; def SETOGT : CondCode;
 557 def SETOGE : CondCode; def SETOLT : CondCode; def SETOLE : CondCode;
 558 def SETONE : CondCode; def SETO   : CondCode; def SETUO  : CondCode;
 559 def SETUEQ : CondCode; def SETUGT : CondCode; def SETUGE : CondCode;
 560 def SETULT : CondCode; def SETULE : CondCode; def SETUNE : CondCode;
 561
 562 def SETEQ : CondCode; def SETGT : CondCode; def SETGE : CondCode;
 563 def SETLT : CondCode; def SETLE : CondCode; def SETNE : CondCode;
 564
 565
 566 //===----------------------------------------------------------------------===//
 567 // Selection DAG Node Transformation Functions.
 568 //
 569 // This mechanism allows targets to manipulate nodes in the output DAG once a
 570 // match has been formed.  This is typically used to manipulate immediate
 571 // values.
 572 //
 573 class SDNodeXForm<SDNode opc, code xformFunction> {
 574   SDNode Opcode = opc;
 575   code XFormFunction = xformFunction;
 576 }
 577
 578 def NOOP_SDNodeXForm : SDNodeXForm<imm, [{}]>;
 579
 580 //===----------------------------------------------------------------------===//
 581 // PatPred Subclasses.
 582 //
 583 // These allow specifying different sorts of predicates that control whether a
 584 // node is matched.
 585 //
 586 class PatPred;
 587
 588 class CodePatPred<code predicate> : PatPred {
 589   code PredicateCode = predicate;
 590 }
 591
 592
 593 //===----------------------------------------------------------------------===//
 594 // Selection DAG Pattern Fragments.
 595 //
 596 // Pattern fragments are reusable chunks of dags that match specific things.
 597 // They can take arguments and have C++ predicates that control whether they
 598 // match.  They are intended to make the patterns for common instructions more
 599 // compact and readable.
 600 //
 601
 602 /// PatFrag - Represents a pattern fragment.  This can match something on the
 603 /// DAG, from a single node to multiple nested other fragments.
 604 ///
 605 class PatFrag<dag ops, dag frag, code pred = [{}],
 606               SDNodeXForm xform = NOOP_SDNodeXForm> : SDPatternOperator {
 607   dag Operands = ops;
 608   dag Fragment = frag;
 609   code PredicateCode = pred;
 610   code ImmediateCode = [{}];
 611   SDNodeXForm OperandTransform = xform;
 612 }
 613
 614 // OutPatFrag is a pattern fragment that is used as part of an output pattern
 615 // (not an input pattern). These do not have predicates or transforms, but are
 616 // used to avoid repeated subexpressions in output patterns.
 617 class OutPatFrag<dag ops, dag frag>
 618  : PatFrag<ops, frag, [{}], NOOP_SDNodeXForm>;
 619
 620 // PatLeaf's are pattern fragments that have no operands.  This is just a helper
 621 // to define immediates and other common things concisely.
 622 class PatLeaf<dag frag, code pred = [{}], SDNodeXForm xform = NOOP_SDNodeXForm>
 623  : PatFrag<(ops), frag, pred, xform>;
 624
 625
 626 // ImmLeaf is a pattern fragment with a constraint on the immediate.  The
 627 // constraint is a function that is run on the immediate (always with the value
 628 // sign extended out to an int64_t) as Imm.  For example:
 629 //
 630 //  def immSExt8 : ImmLeaf<i16, [{ return (char)Imm == Imm; }]>;
 631 //
 632 // this is a more convenient form to match 'imm' nodes in than PatLeaf and also
 633 // is preferred over using PatLeaf because it allows the code generator to
 634 // reason more about the constraint.
 635 //
 636 // If FastIsel should ignore all instructions that have an operand of this type,
 637 // the FastIselShouldIgnore flag can be set.  This is an optimization to reduce
 638 // the code size of the generated fast instruction selector.
 639 class ImmLeaf<ValueType vt, code pred, SDNodeXForm xform = NOOP_SDNodeXForm>
 640   : PatFrag<(ops), (vt imm), [{}], xform> {
 641   let ImmediateCode = pred;
 642   bit FastIselShouldIgnore = 0;
 643 }
 644
 645
 646 // Leaf fragments.
 647
 648 def vtInt      : PatLeaf<(vt),  [{ return N->getVT().isInteger(); }]>;
 649 def vtFP       : PatLeaf<(vt),  [{ return N->getVT().isFloatingPoint(); }]>;
 650
 651 def immAllOnesV: PatLeaf<(build_vector), [{
 652   return ISD::isBuildVectorAllOnes(N);
 653 }]>;
 654 def immAllZerosV: PatLeaf<(build_vector), [{
 655   return ISD::isBuildVectorAllZeros(N);
 656 }]>;
 657
 658
 659
 660 // Other helper fragments.
 661 def not  : PatFrag<(ops node:$in), (xor node:$in, -1)>;
 662 def vnot : PatFrag<(ops node:$in), (xor node:$in, immAllOnesV)>;
 663 def ineg : PatFrag<(ops node:$in), (sub 0, node:$in)>;
 664
 665 // null_frag - The null pattern operator is used in multiclass instantiations
 666 // which accept an SDPatternOperator for use in matching patterns for internal
 667 // definitions. When expanding a pattern, if the null fragment is referenced
 668 // in the expansion, the pattern is discarded and it is as-if '[]' had been
 669 // specified. This allows multiclasses to have the isel patterns be optional.
 670 def null_frag : SDPatternOperator;
 671
 672 // load fragments.
 673 def unindexedload : PatFrag<(ops node:$ptr), (ld node:$ptr), [{
 674   return cast<LoadSDNode>(N)->getAddressingMode() == ISD::UNINDEXED;
 675 }]>;
 676 def load : PatFrag<(ops node:$ptr), (unindexedload node:$ptr), [{
 677   return cast<LoadSDNode>(N)->getExtensionType() == ISD::NON_EXTLOAD;
 678 }]>;
 679
 680 // extending load fragments.
 681 def extload   : PatFrag<(ops node:$ptr), (unindexedload node:$ptr), [{
 682   return cast<LoadSDNode>(N)->getExtensionType() == ISD::EXTLOAD;
 683 }]>;
 684 def sextload  : PatFrag<(ops node:$ptr), (unindexedload node:$ptr), [{
 685   return cast<LoadSDNode>(N)->getExtensionType() == ISD::SEXTLOAD;
 686 }]>;
 687 def zextload  : PatFrag<(ops node:$ptr), (unindexedload node:$ptr), [{
 688   return cast<LoadSDNode>(N)->getExtensionType() == ISD::ZEXTLOAD;
 689 }]>;
 690
 691 def extloadi1  : PatFrag<(ops node:$ptr), (extload node:$ptr), [{
 692   return cast<LoadSDNode>(N)->getMemoryVT() == MVT::i1;
 693 }]>;
 694 def extloadi8  : PatFrag<(ops node:$ptr), (extload node:$ptr), [{
 695   return cast<LoadSDNode>(N)->getMemoryVT() == MVT::i8;
 696 }]>;
 697 def extloadi16 : PatFrag<(ops node:$ptr), (extload node:$ptr), [{
 698   return cast<LoadSDNode>(N)->getMemoryVT() == MVT::i16;
 699 }]>;
 700 def extloadi32 : PatFrag<(ops node:$ptr), (extload node:$ptr), [{
 701   return cast<LoadSDNode>(N)->getMemoryVT() == MVT::i32;
 702 }]>;
 703 def extloadf32 : PatFrag<(ops node:$ptr), (extload node:$ptr), [{
 704   return cast<LoadSDNode>(N)->getMemoryVT() == MVT::f32;
 705 }]>;
 706 def extloadf64 : PatFrag<(ops node:$ptr), (extload node:$ptr), [{
 707   return cast<LoadSDNode>(N)->getMemoryVT() == MVT::f64;
 708 }]>;
 709
 710 def sextloadi1  : PatFrag<(ops node:$ptr), (sextload node:$ptr), [{
 711   return cast<LoadSDNode>(N)->getMemoryVT() == MVT::i1;
 712 }]>;
 713 def sextloadi8  : PatFrag<(ops node:$ptr), (sextload node:$ptr), [{
 714   return cast<LoadSDNode>(N)->getMemoryVT() == MVT::i8;
 715 }]>;
 716 def sextloadi16 : PatFrag<(ops node:$ptr), (sextload node:$ptr), [{
 717   return cast<LoadSDNode>(N)->getMemoryVT() == MVT::i16;
 718 }]>;
 719 def sextloadi32 : PatFrag<(ops node:$ptr), (sextload node:$ptr), [{
 720   return cast<LoadSDNode>(N)->getMemoryVT() == MVT::i32;
 721 }]>;
 722
 723 def zextloadi1  : PatFrag<(ops node:$ptr), (zextload node:$ptr), [{
 724   return cast<LoadSDNode>(N)->getMemoryVT() == MVT::i1;
 725 }]>;
 726 def zextloadi8  : PatFrag<(ops node:$ptr), (zextload node:$ptr), [{
 727   return cast<LoadSDNode>(N)->getMemoryVT() == MVT::i8;
 728 }]>;
 729 def zextloadi16 : PatFrag<(ops node:$ptr), (zextload node:$ptr), [{
 730   return cast<LoadSDNode>(N)->getMemoryVT() == MVT::i16;
 731 }]>;
 732 def zextloadi32 : PatFrag<(ops node:$ptr), (zextload node:$ptr), [{
 733   return cast<LoadSDNode>(N)->getMemoryVT() == MVT::i32;
 734 }]>;
 735
 736 def extloadvi1  : PatFrag<(ops node:$ptr), (extload node:$ptr), [{
 737   return cast<LoadSDNode>(N)->getMemoryVT().getScalarType() == MVT::i1;
 738 }]>;
 739 def extloadvi8  : PatFrag<(ops node:$ptr), (extload node:$ptr), [{
 740   return cast<LoadSDNode>(N)->getMemoryVT().getScalarType() == MVT::i8;
 741 }]>;
 742 def extloadvi16 : PatFrag<(ops node:$ptr), (extload node:$ptr), [{
 743   return cast<LoadSDNode>(N)->getMemoryVT().getScalarType() == MVT::i16;
 744 }]>;
 745 def extloadvi32 : PatFrag<(ops node:$ptr), (extload node:$ptr), [{
 746   return cast<LoadSDNode>(N)->getMemoryVT().getScalarType() == MVT::i32;
 747 }]>;
 748 def extloadvf32 : PatFrag<(ops node:$ptr), (extload node:$ptr), [{
 749   return cast<LoadSDNode>(N)->getMemoryVT().getScalarType() == MVT::f32;
 750 }]>;
 751 def extloadvf64 : PatFrag<(ops node:$ptr), (extload node:$ptr), [{
 752   return cast<LoadSDNode>(N)->getMemoryVT().getScalarType() == MVT::f64;
 753 }]>;
 754
 755 def sextloadvi1  : PatFrag<(ops node:$ptr), (sextload node:$ptr), [{
 756   return cast<LoadSDNode>(N)->getMemoryVT().getScalarType() == MVT::i1;
 757 }]>;
 758 def sextloadvi8  : PatFrag<(ops node:$ptr), (sextload node:$ptr), [{
 759   return cast<LoadSDNode>(N)->getMemoryVT().getScalarType() == MVT::i8;
 760 }]>;
 761 def sextloadvi16 : PatFrag<(ops node:$ptr), (sextload node:$ptr), [{
 762   return cast<LoadSDNode>(N)->getMemoryVT().getScalarType() == MVT::i16;
 763 }]>;
 764 def sextloadvi32 : PatFrag<(ops node:$ptr), (sextload node:$ptr), [{
 765   return cast<LoadSDNode>(N)->getMemoryVT().getScalarType() == MVT::i32;
 766 }]>;
 767
 768 def zextloadvi1  : PatFrag<(ops node:$ptr), (zextload node:$ptr), [{
 769   return cast<LoadSDNode>(N)->getMemoryVT().getScalarType() == MVT::i1;
 770 }]>;
 771 def zextloadvi8  : PatFrag<(ops node:$ptr), (zextload node:$ptr), [{
 772   return cast<LoadSDNode>(N)->getMemoryVT().getScalarType() == MVT::i8;
 773 }]>;
 774 def zextloadvi16 : PatFrag<(ops node:$ptr), (zextload node:$ptr), [{
 775   return cast<LoadSDNode>(N)->getMemoryVT().getScalarType() == MVT::i16;
 776 }]>;
 777 def zextloadvi32 : PatFrag<(ops node:$ptr), (zextload node:$ptr), [{
 778   return cast<LoadSDNode>(N)->getMemoryVT().getScalarType() == MVT::i32;
 779 }]>;
 780
 781 // store fragments.
 782 def unindexedstore : PatFrag<(ops node:$val, node:$ptr),
 783                              (st node:$val, node:$ptr), [{
 784   return cast<StoreSDNode>(N)->getAddressingMode() == ISD::UNINDEXED;
 785 }]>;
 786 def store : PatFrag<(ops node:$val, node:$ptr),
 787                     (unindexedstore node:$val, node:$ptr), [{
 788   return !cast<StoreSDNode>(N)->isTruncatingStore();
 789 }]>;
 790
 791 // truncstore fragments.
 792 def truncstore : PatFrag<(ops node:$val, node:$ptr),
 793                          (unindexedstore node:$val, node:$ptr), [{
 794   return cast<StoreSDNode>(N)->isTruncatingStore();
 795 }]>;
 796 def truncstorei8 : PatFrag<(ops node:$val, node:$ptr),
 797                            (truncstore node:$val, node:$ptr), [{
 798   return cast<StoreSDNode>(N)->getMemoryVT() == MVT::i8;
 799 }]>;
 800 def truncstorei16 : PatFrag<(ops node:$val, node:$ptr),
 801                             (truncstore node:$val, node:$ptr), [{
 802   return cast<StoreSDNode>(N)->getMemoryVT() == MVT::i16;
 803 }]>;
 804 def truncstorei32 : PatFrag<(ops node:$val, node:$ptr),
 805                             (truncstore node:$val, node:$ptr), [{
 806   return cast<StoreSDNode>(N)->getMemoryVT() == MVT::i32;
 807 }]>;
 808 def truncstoref32 : PatFrag<(ops node:$val, node:$ptr),
 809                             (truncstore node:$val, node:$ptr), [{
 810   return cast<StoreSDNode>(N)->getMemoryVT() == MVT::f32;
 811 }]>;
 812 def truncstoref64 : PatFrag<(ops node:$val, node:$ptr),
 813                             (truncstore node:$val, node:$ptr), [{
 814   return cast<StoreSDNode>(N)->getMemoryVT() == MVT::f64;
 815 }]>;
 816
 817 // indexed store fragments.
 818 def istore : PatFrag<(ops node:$val, node:$base, node:$offset),
 819                      (ist node:$val, node:$base, node:$offset), [{
 820   return !cast<StoreSDNode>(N)->isTruncatingStore();
 821 }]>;
 822
 823 def pre_store : PatFrag<(ops node:$val, node:$base, node:$offset),
 824                         (istore node:$val, node:$base, node:$offset), [{
 825   ISD::MemIndexedMode AM = cast<StoreSDNode>(N)->getAddressingMode();
 826   return AM == ISD::PRE_INC || AM == ISD::PRE_DEC;
 827 }]>;
 828
 829 def itruncstore : PatFrag<(ops node:$val, node:$base, node:$offset),
 830                           (ist node:$val, node:$base, node:$offset), [{
 831   return cast<StoreSDNode>(N)->isTruncatingStore();
 832 }]>;
 833 def pre_truncst : PatFrag<(ops node:$val, node:$base, node:$offset),
 834                           (itruncstore node:$val, node:$base, node:$offset), [{
 835   ISD::MemIndexedMode AM = cast<StoreSDNode>(N)->getAddressingMode();
 836   return AM == ISD::PRE_INC || AM == ISD::PRE_DEC;
 837 }]>;
 838 def pre_truncsti1 : PatFrag<(ops node:$val, node:$base, node:$offset),
 839                             (pre_truncst node:$val, node:$base, node:$offset), [{
 840   return cast<StoreSDNode>(N)->getMemoryVT() == MVT::i1;
 841 }]>;
 842 def pre_truncsti8 : PatFrag<(ops node:$val, node:$base, node:$offset),
 843                             (pre_truncst node:$val, node:$base, node:$offset), [{
 844   return cast<StoreSDNode>(N)->getMemoryVT() == MVT::i8;
 845 }]>;
 846 def pre_truncsti16 : PatFrag<(ops node:$val, node:$base, node:$offset),
 847                              (pre_truncst node:$val, node:$base, node:$offset), [{
 848   return cast<StoreSDNode>(N)->getMemoryVT() == MVT::i16;
 849 }]>;
 850 def pre_truncsti32 : PatFrag<(ops node:$val, node:$base, node:$offset),
 851                              (pre_truncst node:$val, node:$base, node:$offset), [{
 852   return cast<StoreSDNode>(N)->getMemoryVT() == MVT::i32;
 853 }]>;
 854 def pre_truncstf32 : PatFrag<(ops node:$val, node:$base, node:$offset),
 855                              (pre_truncst node:$val, node:$base, node:$offset), [{
 856   return cast<StoreSDNode>(N)->getMemoryVT() == MVT::f32;
 857 }]>;
 858
 859 def post_store : PatFrag<(ops node:$val, node:$ptr, node:$offset),
 860                          (istore node:$val, node:$ptr, node:$offset), [{
 861   ISD::MemIndexedMode AM = cast<StoreSDNode>(N)->getAddressingMode();
 862   return AM == ISD::POST_INC || AM == ISD::POST_DEC;
 863 }]>;
 864
 865 def post_truncst : PatFrag<(ops node:$val, node:$base, node:$offset),
 866                            (itruncstore node:$val, node:$base, node:$offset), [{
 867   ISD::MemIndexedMode AM = cast<StoreSDNode>(N)->getAddressingMode();
 868   return AM == ISD::POST_INC || AM == ISD::POST_DEC;
 869 }]>;
 870 def post_truncsti1 : PatFrag<(ops node:$val, node:$base, node:$offset),
 871                              (post_truncst node:$val, node:$base, node:$offset), [{
 872   return cast<StoreSDNode>(N)->getMemoryVT() == MVT::i1;
 873 }]>;
 874 def post_truncsti8 : PatFrag<(ops node:$val, node:$base, node:$offset),
 875                              (post_truncst node:$val, node:$base, node:$offset), [{
 876   return cast<StoreSDNode>(N)->getMemoryVT() == MVT::i8;
 877 }]>;
 878 def post_truncsti16 : PatFrag<(ops node:$val, node:$base, node:$offset),
 879                               (post_truncst node:$val, node:$base, node:$offset), [{
 880   return cast<StoreSDNode>(N)->getMemoryVT() == MVT::i16;
 881 }]>;
 882 def post_truncsti32 : PatFrag<(ops node:$val, node:$base, node:$offset),
 883                               (post_truncst node:$val, node:$base, node:$offset), [{
 884   return cast<StoreSDNode>(N)->getMemoryVT() == MVT::i32;
 885 }]>;
 886 def post_truncstf32 : PatFrag<(ops node:$val, node:$base, node:$offset),
 887                               (post_truncst node:$val, node:$base, node:$offset), [{
 888   return cast<StoreSDNode>(N)->getMemoryVT() == MVT::f32;
 889 }]>;
 890
 891 // setcc convenience fragments.
 892 def setoeq : PatFrag<(ops node:$lhs, node:$rhs),
 893                      (setcc node:$lhs, node:$rhs, SETOEQ)>;
 894 def setogt : PatFrag<(ops node:$lhs, node:$rhs),
 895                      (setcc node:$lhs, node:$rhs, SETOGT)>;
 896 def setoge : PatFrag<(ops node:$lhs, node:$rhs),
 897                      (setcc node:$lhs, node:$rhs, SETOGE)>;
 898 def setolt : PatFrag<(ops node:$lhs, node:$rhs),
 899                      (setcc node:$lhs, node:$rhs, SETOLT)>;
 900 def setole : PatFrag<(ops node:$lhs, node:$rhs),
 901                      (setcc node:$lhs, node:$rhs, SETOLE)>;
 902 def setone : PatFrag<(ops node:$lhs, node:$rhs),
 903                      (setcc node:$lhs, node:$rhs, SETONE)>;
 904 def seto   : PatFrag<(ops node:$lhs, node:$rhs),
 905                      (setcc node:$lhs, node:$rhs, SETO)>;
 906 def setuo  : PatFrag<(ops node:$lhs, node:$rhs),
 907                      (setcc node:$lhs, node:$rhs, SETUO)>;
 908 def setueq : PatFrag<(ops node:$lhs, node:$rhs),
 909                      (setcc node:$lhs, node:$rhs, SETUEQ)>;
 910 def setugt : PatFrag<(ops node:$lhs, node:$rhs),
 911                      (setcc node:$lhs, node:$rhs, SETUGT)>;
 912 def setuge : PatFrag<(ops node:$lhs, node:$rhs),
 913                      (setcc node:$lhs, node:$rhs, SETUGE)>;
 914 def setult : PatFrag<(ops node:$lhs, node:$rhs),
 915                      (setcc node:$lhs, node:$rhs, SETULT)>;
 916 def setule : PatFrag<(ops node:$lhs, node:$rhs),
 917                      (setcc node:$lhs, node:$rhs, SETULE)>;
 918 def setune : PatFrag<(ops node:$lhs, node:$rhs),
 919                      (setcc node:$lhs, node:$rhs, SETUNE)>;
 920 def seteq  : PatFrag<(ops node:$lhs, node:$rhs),
 921                      (setcc node:$lhs, node:$rhs, SETEQ)>;
 922 def setgt  : PatFrag<(ops node:$lhs, node:$rhs),
 923                      (setcc node:$lhs, node:$rhs, SETGT)>;
 924 def setge  : PatFrag<(ops node:$lhs, node:$rhs),
 925                      (setcc node:$lhs, node:$rhs, SETGE)>;
 926 def setlt  : PatFrag<(ops node:$lhs, node:$rhs),
 927                      (setcc node:$lhs, node:$rhs, SETLT)>;
 928 def setle  : PatFrag<(ops node:$lhs, node:$rhs),
 929                      (setcc node:$lhs, node:$rhs, SETLE)>;
 930 def setne  : PatFrag<(ops node:$lhs, node:$rhs),
 931                      (setcc node:$lhs, node:$rhs, SETNE)>;
 932
 933 def atomic_cmp_swap_8 :
 934   PatFrag<(ops node:$ptr, node:$cmp, node:$swap),
 935           (atomic_cmp_swap node:$ptr, node:$cmp, node:$swap), [{
 936   return cast<AtomicSDNode>(N)->getMemoryVT() == MVT::i8;
 937 }]>;
 938 def atomic_cmp_swap_16 :
 939   PatFrag<(ops node:$ptr, node:$cmp, node:$swap),
 940           (atomic_cmp_swap node:$ptr, node:$cmp, node:$swap), [{
 941   return cast<AtomicSDNode>(N)->getMemoryVT() == MVT::i16;
 942 }]>;
 943 def atomic_cmp_swap_32 :
 944   PatFrag<(ops node:$ptr, node:$cmp, node:$swap),
 945           (atomic_cmp_swap node:$ptr, node:$cmp, node:$swap), [{
 946   return cast<AtomicSDNode>(N)->getMemoryVT() == MVT::i32;
 947 }]>;
 948 def atomic_cmp_swap_64 :
 949   PatFrag<(ops node:$ptr, node:$cmp, node:$swap),
 950           (atomic_cmp_swap node:$ptr, node:$cmp, node:$swap), [{
 951   return cast<AtomicSDNode>(N)->getMemoryVT() == MVT::i64;
 952 }]>;
 953
 954 multiclass binary_atomic_op<SDNode atomic_op> {
 955   def _8 : PatFrag<(ops node:$ptr, node:$val),
 956                    (atomic_op node:$ptr, node:$val), [{
 957     return cast<AtomicSDNode>(N)->getMemoryVT() == MVT::i8;
 958   }]>;
 959   def _16 : PatFrag<(ops node:$ptr, node:$val),
 960                    (atomic_op node:$ptr, node:$val), [{
 961     return cast<AtomicSDNode>(N)->getMemoryVT() == MVT::i16;
 962   }]>;
 963   def _32 : PatFrag<(ops node:$ptr, node:$val),
 964                    (atomic_op node:$ptr, node:$val), [{
 965     return cast<AtomicSDNode>(N)->getMemoryVT() == MVT::i32;
 966   }]>;
 967   def _64 : PatFrag<(ops node:$ptr, node:$val),
 968                    (atomic_op node:$ptr, node:$val), [{
 969     return cast<AtomicSDNode>(N)->getMemoryVT() == MVT::i64;
 970   }]>;
 971 }
 972
 973 defm atomic_load_add  : binary_atomic_op<atomic_load_add>;
 974 defm atomic_swap      : binary_atomic_op<atomic_swap>;
 975 defm atomic_load_sub  : binary_atomic_op<atomic_load_sub>;
 976 defm atomic_load_and  : binary_atomic_op<atomic_load_and>;
 977 defm atomic_load_or   : binary_atomic_op<atomic_load_or>;
 978 defm atomic_load_xor  : binary_atomic_op<atomic_load_xor>;
 979 defm atomic_load_nand : binary_atomic_op<atomic_load_nand>;
 980 defm atomic_load_min  : binary_atomic_op<atomic_load_min>;
 981 defm atomic_load_max  : binary_atomic_op<atomic_load_max>;
 982 defm atomic_load_umin : binary_atomic_op<atomic_load_umin>;
 983 defm atomic_load_umax : binary_atomic_op<atomic_load_umax>;
 984 defm atomic_store     : binary_atomic_op<atomic_store>;
 985
 986 def atomic_load_8 :
 987   PatFrag<(ops node:$ptr),
 988           (atomic_load node:$ptr), [{
 989   return cast<AtomicSDNode>(N)->getMemoryVT() == MVT::i8;
 990 }]>;
 991 def atomic_load_16 :
 992   PatFrag<(ops node:$ptr),
 993           (atomic_load node:$ptr), [{
 994   return cast<AtomicSDNode>(N)->getMemoryVT() == MVT::i16;
 995 }]>;
 996 def atomic_load_32 :
 997   PatFrag<(ops node:$ptr),
 998           (atomic_load node:$ptr), [{
 999   return cast<AtomicSDNode>(N)->getMemoryVT() == MVT::i32;
1000 }]>;
1001 def atomic_load_64 :
1002   PatFrag<(ops node:$ptr),
1003           (atomic_load node:$ptr), [{
1004   return cast<AtomicSDNode>(N)->getMemoryVT() == MVT::i64;
1005 }]>;
1006
1007 //===----------------------------------------------------------------------===//
1008 // Selection DAG CONVERT_RNDSAT patterns
1009
1010 def cvtff : PatFrag<(ops node:$val, node:$dty, node:$sty, node:$rd, node:$sat),
1011     (cvt node:$val, node:$dty, node:$sty, node:$rd, node:$sat), [{
1012        return cast<CvtRndSatSDNode>(N)->getCvtCode() == ISD::CVT_FF;
1013     }]>;
1014
1015 def cvtss : PatFrag<(ops node:$val, node:$dty, node:$sty, node:$rd, node:$sat),
1016     (cvt node:$val, node:$dty, node:$sty, node:$rd, node:$sat), [{
1017        return cast<CvtRndSatSDNode>(N)->getCvtCode() == ISD::CVT_SS;
1018     }]>;
1019
1020 def cvtsu : PatFrag<(ops node:$val, node:$dty, node:$sty, node:$rd, node:$sat),
1021     (cvt node:$val, node:$dty, node:$sty, node:$rd, node:$sat), [{
1022        return cast<CvtRndSatSDNode>(N)->getCvtCode() == ISD::CVT_SU;
1023     }]>;
1024
1025 def cvtus : PatFrag<(ops node:$val, node:$dty, node:$sty, node:$rd, node:$sat),
1026     (cvt node:$val, node:$dty, node:$sty, node:$rd, node:$sat), [{
1027        return cast<CvtRndSatSDNode>(N)->getCvtCode() == ISD::CVT_US;
1028     }]>;
1029
1030 def cvtuu : PatFrag<(ops node:$val, node:$dty, node:$sty, node:$rd, node:$sat),
1031     (cvt node:$val, node:$dty, node:$sty, node:$rd, node:$sat), [{
1032        return cast<CvtRndSatSDNode>(N)->getCvtCode() == ISD::CVT_UU;
1033     }]>;
1034
1035 def cvtsf : PatFrag<(ops node:$val, node:$dty, node:$sty, node:$rd, node:$sat),
1036     (cvt node:$val, node:$dty, node:$sty, node:$rd, node:$sat), [{
1037        return cast<CvtRndSatSDNode>(N)->getCvtCode() == ISD::CVT_SF;
1038     }]>;
1039
1040 def cvtuf : PatFrag<(ops node:$val, node:$dty, node:$sty, node:$rd, node:$sat),
1041     (cvt node:$val, node:$dty, node:$sty, node:$rd, node:$sat), [{
1042        return cast<CvtRndSatSDNode>(N)->getCvtCode() == ISD::CVT_UF;
1043     }]>;
1044
1045 def cvtfs : PatFrag<(ops node:$val, node:$dty, node:$sty, node:$rd, node:$sat),
1046     (cvt node:$val, node:$dty, node:$sty, node:$rd, node:$sat), [{
1047        return cast<CvtRndSatSDNode>(N)->getCvtCode() == ISD::CVT_FS;
1048     }]>;
1049
1050 def cvtfu : PatFrag<(ops node:$val, node:$dty, node:$sty, node:$rd, node:$sat),
1051     (cvt node:$val, node:$dty, node:$sty, node:$rd, node:$sat), [{
1052        return cast<CvtRndSatSDNode>(N)->getCvtCode() == ISD::CVT_FU;
1053     }]>;
1054
1055 //===----------------------------------------------------------------------===//
1056 // Selection DAG Pattern Support.
1057 //
1058 // Patterns are what are actually matched against by the target-flavored
1059 // instruction selection DAG.  Instructions defined by the target implicitly
1060 // define patterns in most cases, but patterns can also be explicitly added when
1061 // an operation is defined by a sequence of instructions (e.g. loading a large
1062 // immediate value on RISC targets that do not support immediates as large as
1063 // their GPRs).
1064 //
1065
1066 class Pattern<dag patternToMatch, list<dag> resultInstrs> {
1067   dag             PatternToMatch  = patternToMatch;
1068   list<dag>       ResultInstrs    = resultInstrs;
1069   list<Predicate> Predicates      = [];  // See class Instruction in Target.td.
1070   int             AddedComplexity = 0;   // See class Instruction in Target.td.
1071 }
1072
1073 // Pat - A simple (but common) form of a pattern, which produces a simple result
1074 // not needing a full list.
1075 class Pat<dag pattern, dag result> : Pattern<pattern, [result]>;
1076
1077 //===----------------------------------------------------------------------===//
1078 // Complex pattern definitions.
1079 //
1080
1081 // Complex patterns, e.g. X86 addressing mode, requires pattern matching code
1082 // in C++. NumOperands is the number of operands returned by the select function;
1083 // SelectFunc is the name of the function used to pattern match the max. pattern;
1084 // RootNodes are the list of possible root nodes of the sub-dags to match.
1085 // e.g. X86 addressing mode - def addr : ComplexPattern<4, "SelectAddr", [add]>;
1086 //
1087 class ComplexPattern<ValueType ty, int numops, string fn,
1088                      list<SDNode> roots = [], list<SDNodeProperty> props = []> {
1089   ValueType Ty = ty;
1090   int NumOperands = numops;
1091   string SelectFunc = fn;
1092   list<SDNode> RootNodes = roots;
1093   list<SDNodeProperty> Properties = props;
1094 }