include/llvm/Intrinsics.td

   1 //===- Intrinsics.td - Defines all LLVM intrinsics ---------*- tablegen -*-===//
   2 //
   3 //                     The LLVM Compiler Infrastructure
   4 //
   5 // This file was developed by Chris Lattner and is distributed under the
   6 // University of Illinois Open Source License. See LICENSE.TXT for details.
   7 //
   8 //===----------------------------------------------------------------------===//
   9 //
  10 // This file defines properties of all LLVM intrinsics.
  11 //
  12 //===----------------------------------------------------------------------===//
  13
  14 //===----------------------------------------------------------------------===//
  15 //  Properties we keep track of for intrinsics.
  16 //===----------------------------------------------------------------------===//
  17
  18 class IntrinsicProperty;
  19
  20 // Intr*Mem - Memory properties.  An intrinsic is allowed to have exactly one of
  21 // these properties set.  They are listed from the most aggressive (best to use
  22 // if correct) to the least aggressive.  If no property is set, the worst case
  23 // is assumed (IntrWriteMem).
  24
  25 // InstrNoMem - The intrinsic does not access memory or have any other side
  26 // effects.  It may be CSE'd deleted if dead, etc.
  27 def InstrNoMem : IntrinsicProperty;
  28
  29 // InstrReadArgMem - This intrinsic reads only from memory that one of its
  30 // arguments points to, but may read an unspecified amount.
  31 def InstrReadArgMem : IntrinsicProperty;
  32
  33 // IntrReadMem - This intrinsic reads from unspecified memory, so it cannot be
  34 // moved across stores.  However, it can be reordered otherwise and can be
  35 // deleted if dead.
  36 def IntrReadMem : IntrinsicProperty;
  37
  38 // InstrWriteArgMem - This intrinsic reads and writes only from memory that one
  39 // of its arguments points to, but may access an unspecified amount.  It has no
  40 // other side effects.  This may only be used if the intrinsic doesn't "capture"
  41 // the argument pointer (e.g. storing it someplace).
  42 def InstrWriteArgMem : IntrinsicProperty;
  43
  44 // IntrWriteMem - This intrinsic may read or modify unspecified memory or has
  45 // other side effects.  It cannot be modified by the optimizer.  This is the
  46 // default if the intrinsic has no other Intr*Mem property.
  47 def IntrWriteMem : IntrinsicProperty;
  48
  49 //===----------------------------------------------------------------------===//
  50 // Types used by intrinsics.
  51 //===----------------------------------------------------------------------===//
  52
  53 class LLVMType<string typeval> {
  54   string TypeVal = typeval;
  55 }
  56
  57 def llvm_void_ty       : LLVMType<"Type::VoidTyID">;
  58 def llvm_bool_ty       : LLVMType<"Type::BoolTyID">;
  59 def llvm_sbyte_ty      : LLVMType<"Type::SByteTyID">;
  60 def llvm_short_ty      : LLVMType<"Type::ShortTyID">;
  61 def llvm_int_ty        : LLVMType<"Type::IntTyID">;
  62 def llvm_long_ty       : LLVMType<"Type::LongTyID">;
  63 def llvm_ubyte_ty      : LLVMType<"Type::UByteTyID">;
  64 def llvm_ushort_ty     : LLVMType<"Type::UShortTyID">;
  65 def llvm_uint_ty       : LLVMType<"Type::UIntTyID">;
  66 def llvm_ulong_ty      : LLVMType<"Type::ULongTyID">;
  67 def llvm_float_ty      : LLVMType<"Type::FloatTyID">;
  68 def llvm_double_ty     : LLVMType<"Type::DoubleTyID">;
  69 def llvm_ptr_ty        : LLVMType<"Type::PointerTyID">;     // sbyte*
  70 def llvm_ptrptr_ty     : LLVMType<"Type::PointerTyID">;     // sbyte**
  71 def llvm_anchor_ty     : LLVMType<"Type::PointerTyID">;     // {}*
  72 def llvm_descriptor_ty : LLVMType<"Type::PointerTyID">;     // global*
  73
  74 //===----------------------------------------------------------------------===//
  75 // Intrinsic Definitions.
  76 //===----------------------------------------------------------------------===//
  77
  78 // Intrinsic class - This is used to define one LLVM intrinsic.  The name of the
  79 // intrinsic definition should start with "int_", then match the LLVM intrinsic
  80 // name with the "llvm." prefix removed, and all "."s turned into "_"s.  For
  81 // example, llvm.bswap.i16 -> int_bswap_i16.
  82 //
  83 //  * Types is a list containing the return type and the argument types
  84 //    expected for the intrinsic.
  85 //  * Properties can be set to describe the behavior of the intrinsic.
  86 //
  87 class Intrinsic<list<LLVMType> types,
  88                 list<IntrinsicProperty> properties = [],
  89                 string name = ""> {
  90   string LLVMName = name;
  91   list<LLVMType> Types = types;
  92   list<IntrinsicProperty> Properties = properties;
  93 }
  94
  95
  96 //===--------------- Variable Argument Handling Intrinsics ----------------===//
  97 //
  98
  99 def int_vastart : Intrinsic<[llvm_void_ty, llvm_ptrptr_ty], [], "llvm.va_start">;
 100 def int_vacopy  : Intrinsic<[llvm_void_ty, llvm_ptrptr_ty, llvm_ptrptr_ty], [],
 101                             "llvm.va_copy">;
 102 def int_vaend   : Intrinsic<[llvm_void_ty, llvm_ptrptr_ty], [], "llvm.va_end">;
 103
 104 //===------------------- Garbage Collection Intrinsics --------------------===//
 105 //
 106 def int_gcroot  : Intrinsic<[llvm_void_ty, llvm_ptrptr_ty, llvm_ptr_ty]>;
 107 def int_gcread  : Intrinsic<[llvm_ptr_ty, llvm_ptrptr_ty], [InstrReadArgMem]>;
 108 def int_gcwrite : Intrinsic<[llvm_void_ty, llvm_ptr_ty, llvm_ptrptr_ty],
 109                             [InstrWriteArgMem]>;
 110
 111 //===--------------------- Code Generator Intrinsics ----------------------===//
 112 //
 113 def int_returnaddress : Intrinsic<[llvm_ptr_ty, llvm_uint_ty], [InstrNoMem]>;
 114 def int_frameaddress  : Intrinsic<[llvm_ptr_ty, llvm_uint_ty], [InstrNoMem]>;
 115 def int_stacksave     : Intrinsic<[llvm_ptr_ty], [IntrReadMem]>;
 116 def int_stackrestore  : Intrinsic<[llvm_void_ty, llvm_ptr_ty]>;
 117 def int_prefetch      : Intrinsic<[llvm_void_ty, llvm_ptr_ty,
 118                                    llvm_uint_ty, llvm_uint_ty]>;
 119 def int_pcmarker      : Intrinsic<[llvm_void_ty, llvm_uint_ty]>;
 120
 121 def int_readcyclecounter : Intrinsic<[llvm_ulong_ty]>;
 122
 123 //===------------------- Standard C Library Intrinsics --------------------===//
 124 //
 125
 126 let Properties = [InstrWriteArgMem] in {
 127   def int_memcpy_i32  : Intrinsic<[llvm_void_ty, llvm_ptr_ty, llvm_ptr_ty,
 128                                    llvm_uint_ty, llvm_uint_ty]>;
 129   def int_memcpy_i64  : Intrinsic<[llvm_void_ty, llvm_ptr_ty, llvm_ptr_ty,
 130                                    llvm_ulong_ty, llvm_uint_ty]>;
 131   def int_memmove_i32 : Intrinsic<[llvm_void_ty, llvm_ptr_ty, llvm_ptr_ty,
 132                                    llvm_uint_ty, llvm_uint_ty]>;
 133   def int_memmove_i64 : Intrinsic<[llvm_void_ty, llvm_ptr_ty, llvm_ptr_ty,
 134                                    llvm_ulong_ty, llvm_uint_ty]>;
 135   def int_memset_i32  : Intrinsic<[llvm_void_ty, llvm_ptr_ty, llvm_ubyte_ty,
 136                                    llvm_uint_ty, llvm_uint_ty]>;
 137   def int_memset_i64  : Intrinsic<[llvm_void_ty, llvm_ptr_ty, llvm_ubyte_ty,
 138                                    llvm_ulong_ty, llvm_uint_ty]>;
 139 }
 140
 141 let Properties = [InstrNoMem] in {
 142   def int_isunordered_f32 : Intrinsic<[llvm_bool_ty,
 143                                        llvm_float_ty,  llvm_float_ty]>;
 144   def int_isunordered_f64 : Intrinsic<[llvm_bool_ty,
 145                                        llvm_double_ty, llvm_double_ty]>;
 146   def int_sqrt_f32 : Intrinsic<[llvm_float_ty , llvm_float_ty]>;
 147   def int_sqrt_f64 : Intrinsic<[llvm_double_ty, llvm_double_ty]>;
 148 }
 149
 150 // NOTE: these are internal interfaces.
 151 def int_setjmp     : Intrinsic<[llvm_int_ty , llvm_ptr_ty]>;
 152 def int_longjmp    : Intrinsic<[llvm_void_ty, llvm_ptr_ty, llvm_int_ty]>;
 153 def int_sigsetjmp  : Intrinsic<[llvm_int_ty , llvm_ptr_ty]>;
 154 def int_siglongjmp : Intrinsic<[llvm_void_ty, llvm_ptr_ty, llvm_int_ty]>;
 155
 156 //===-------------------- Bit Manipulation Intrinsics ---------------------===//
 157 //
 158
 159 // None of these intrinsics accesses memory at all.
 160 let Properties = [InstrNoMem] in {
 161   def int_bswap_i16 : Intrinsic<[llvm_ushort_ty, llvm_ushort_ty]>;
 162   def int_bswap_i32 : Intrinsic<[llvm_uint_ty,   llvm_uint_ty]>;
 163   def int_bswap_i64 : Intrinsic<[llvm_ulong_ty,  llvm_ulong_ty]>;
 164
 165   def int_ctpop_i8  : Intrinsic<[llvm_ubyte_ty,  llvm_ubyte_ty]>;
 166   def int_ctpop_i16 : Intrinsic<[llvm_ushort_ty, llvm_ushort_ty]>;
 167   def int_ctpop_i32 : Intrinsic<[llvm_uint_ty,   llvm_uint_ty]>;
 168   def int_ctpop_i64 : Intrinsic<[llvm_ulong_ty,  llvm_ulong_ty]>;
 169
 170   def int_ctlz_i8  : Intrinsic<[llvm_ubyte_ty,  llvm_ubyte_ty]>;
 171   def int_ctlz_i16 : Intrinsic<[llvm_ushort_ty, llvm_ushort_ty]>;
 172   def int_ctlz_i32 : Intrinsic<[llvm_uint_ty,   llvm_uint_ty]>;
 173   def int_ctlz_i64 : Intrinsic<[llvm_ulong_ty,  llvm_ulong_ty]>;
 174
 175   def int_cttz_i8  : Intrinsic<[llvm_ubyte_ty,  llvm_ubyte_ty]>;
 176   def int_cttz_i16 : Intrinsic<[llvm_ushort_ty, llvm_ushort_ty]>;
 177   def int_cttz_i32 : Intrinsic<[llvm_uint_ty,   llvm_uint_ty]>;
 178   def int_cttz_i64 : Intrinsic<[llvm_ulong_ty,  llvm_ulong_ty]>;
 179 }
 180
 181 //===------------------------ Debugger Intrinsics -------------------------===//
 182 //
 183
 184 def int_dbg_stoppoint    : Intrinsic<[llvm_anchor_ty, llvm_anchor_ty,
 185                                       llvm_uint_ty, llvm_uint_ty,
 186                                       llvm_descriptor_ty]>;
 187 def int_dbg_region_start : Intrinsic<[llvm_anchor_ty, llvm_anchor_ty]>;
 188 def int_dbg_region_end   : Intrinsic<[llvm_anchor_ty, llvm_anchor_ty]>;
 189 def int_dbg_func_start   : Intrinsic<[llvm_anchor_ty, llvm_descriptor_ty]>;
 190 //    dbg_declare,      // Declare a local object
 191