include/llvm/Intrinsics.td

   1 //===- Intrinsics.td - Defines all LLVM intrinsics ---------*- tablegen -*-===//
   2 //
   3 //                     The LLVM Compiler Infrastructure
   4 //
   5 // This file is distributed under the University of Illinois Open Source
   6 // License. See LICENSE.TXT for details.
   7 //
   8 //===----------------------------------------------------------------------===//
   9 //
  10 // This file defines properties of all LLVM intrinsics.
  11 //
  12 //===----------------------------------------------------------------------===//
  13
  14 include "llvm/CodeGen/ValueTypes.td"
  15
  16 //===----------------------------------------------------------------------===//
  17 //  Properties we keep track of for intrinsics.
  18 //===----------------------------------------------------------------------===//
  19
  20 class IntrinsicProperty;
  21
  22 // Intr*Mem - Memory properties.  An intrinsic is allowed to have exactly one of
  23 // these properties set.  They are listed from the most aggressive (best to use
  24 // if correct) to the least aggressive.  If no property is set, the worst case
  25 // is assumed (IntrWriteMem).
  26
  27 // IntrNoMem - The intrinsic does not access memory or have any other side
  28 // effects.  It may be CSE'd deleted if dead, etc.
  29 def IntrNoMem : IntrinsicProperty;
  30
  31 // IntrReadArgMem - This intrinsic reads only from memory that one of its
  32 // arguments points to, but may read an unspecified amount.
  33 def IntrReadArgMem : IntrinsicProperty;
  34
  35 // IntrReadMem - This intrinsic reads from unspecified memory, so it cannot be
  36 // moved across stores.  However, it can be reordered otherwise and can be
  37 // deleted if dead.
  38 def IntrReadMem : IntrinsicProperty;
  39
  40 // IntrWriteArgMem - This intrinsic reads and writes only from memory that one
  41 // of its arguments points to, but may access an unspecified amount.  It has no
  42 // other side effects.  This may only be used if the intrinsic doesn't "capture"
  43 // the argument pointer (e.g. storing it someplace).
  44 def IntrWriteArgMem : IntrinsicProperty;
  45
  46 // IntrWriteMem - This intrinsic may read or modify unspecified memory or has
  47 // other side effects.  It cannot be modified by the optimizer.  This is the
  48 // default if the intrinsic has no other Intr*Mem property.
  49 def IntrWriteMem : IntrinsicProperty;
  50
  51 //===----------------------------------------------------------------------===//
  52 // Types used by intrinsics.
  53 //===----------------------------------------------------------------------===//
  54
  55 class LLVMType<ValueType vt> {
  56   ValueType VT = vt;
  57 }
  58
  59 class LLVMPointerType<LLVMType elty>
  60   : LLVMType<iPTR>{
  61   LLVMType ElTy = elty;
  62 }
  63
  64 class LLVMMatchType<int num>
  65   : LLVMType<OtherVT>{
  66   int Number = num;
  67 }
  68
  69 def llvm_void_ty       : LLVMType<isVoid>;
  70 def llvm_anyint_ty     : LLVMType<iAny>;
  71 def llvm_anyfloat_ty   : LLVMType<fAny>;
  72 def llvm_i1_ty         : LLVMType<i1>;
  73 def llvm_i8_ty         : LLVMType<i8>;
  74 def llvm_i16_ty        : LLVMType<i16>;
  75 def llvm_i32_ty        : LLVMType<i32>;
  76 def llvm_i64_ty        : LLVMType<i64>;
  77 def llvm_float_ty      : LLVMType<f32>;
  78 def llvm_double_ty     : LLVMType<f64>;
  79 def llvm_f80_ty        : LLVMType<f80>;
  80 def llvm_f128_ty       : LLVMType<f128>;
  81 def llvm_ppcf128_ty    : LLVMType<ppcf128>;
  82 def llvm_ptr_ty        : LLVMPointerType<llvm_i8_ty>;             // i8*
  83 def llvm_ptrptr_ty     : LLVMPointerType<llvm_ptr_ty>;            // i8**
  84 def llvm_empty_ty      : LLVMType<OtherVT>;                       // { }
  85 def llvm_descriptor_ty : LLVMPointerType<llvm_empty_ty>;          // { }*
  86
  87 def llvm_v16i8_ty      : LLVMType<v16i8>;    // 16 x i8
  88 def llvm_v8i16_ty      : LLVMType<v8i16>;    //  8 x i16
  89 def llvm_v2i64_ty      : LLVMType<v2i64>;    //  2 x i64
  90 def llvm_v2i32_ty      : LLVMType<v2i32>;    //  2 x i32
  91 def llvm_v1i64_ty      : LLVMType<v1i64>;    //  1 x i64
  92 def llvm_v4i32_ty      : LLVMType<v4i32>;    //  4 x i32
  93 def llvm_v4f32_ty      : LLVMType<v4f32>;    //  4 x float
  94 def llvm_v2f64_ty      : LLVMType<v2f64>;    //  2 x double
  95
  96 // MMX Vector Types
  97 def llvm_v8i8_ty       : LLVMType<v8i8>;     //  8 x i8
  98 def llvm_v4i16_ty      : LLVMType<v4i16>;    //  4 x i16
  99
 100 def llvm_vararg_ty     : LLVMType<isVoid>;   // this means vararg here
 101
 102 //===----------------------------------------------------------------------===//
 103 // Intrinsic Definitions.
 104 //===----------------------------------------------------------------------===//
 105
 106 // Intrinsic class - This is used to define one LLVM intrinsic.  The name of the
 107 // intrinsic definition should start with "int_", then match the LLVM intrinsic
 108 // name with the "llvm." prefix removed, and all "."s turned into "_"s.  For
 109 // example, llvm.bswap.i16 -> int_bswap_i16.
 110 //
 111 //  * Types is a list containing the return type and the argument types
 112 //    expected for the intrinsic.
 113 //  * Properties can be set to describe the behavior of the intrinsic.
 114 //
 115 class Intrinsic<list<LLVMType> types,
 116                 list<IntrinsicProperty> properties = [],
 117                 string name = ""> {
 118   string LLVMName = name;
 119   string TargetPrefix = "";   // Set to a prefix for target-specific intrinsics.
 120   list<LLVMType> Types = types;
 121   list<IntrinsicProperty> Properties = properties;
 122 }
 123
 124 /// GCCBuiltin - If this intrinsic exactly corresponds to a GCC builtin, this
 125 /// specifies the name of the builtin.  This provides automatic CBE and CFE
 126 /// support.
 127 class GCCBuiltin<string name> {
 128   string GCCBuiltinName = name;
 129 }
 130
 131
 132 //===--------------- Variable Argument Handling Intrinsics ----------------===//
 133 //
 134
 135 def int_vastart : Intrinsic<[llvm_void_ty, llvm_ptr_ty], [], "llvm.va_start">;
 136 def int_vacopy  : Intrinsic<[llvm_void_ty, llvm_ptr_ty, llvm_ptr_ty], [],
 137                             "llvm.va_copy">;
 138 def int_vaend   : Intrinsic<[llvm_void_ty, llvm_ptr_ty], [], "llvm.va_end">;
 139
 140 //===------------------- Garbage Collection Intrinsics --------------------===//
 141 //
 142 def int_gcroot  : Intrinsic<[llvm_void_ty, llvm_ptrptr_ty, llvm_ptr_ty]>;
 143 def int_gcread  : Intrinsic<[llvm_ptr_ty, llvm_ptr_ty, llvm_ptrptr_ty],
 144                             [IntrReadArgMem]>;
 145 def int_gcwrite : Intrinsic<[llvm_void_ty, llvm_ptr_ty, llvm_ptr_ty,
 146                              llvm_ptrptr_ty], [IntrWriteArgMem]>;
 147
 148 //===--------------------- Code Generator Intrinsics ----------------------===//
 149 //
 150 def int_returnaddress : Intrinsic<[llvm_ptr_ty, llvm_i32_ty], [IntrNoMem]>;
 151 def int_frameaddress  : Intrinsic<[llvm_ptr_ty, llvm_i32_ty], [IntrNoMem]>;
 152
 153 // Note: we treat stacksave/stackrestore as writemem because we don't otherwise
 154 // model their dependencies on allocas.
 155 def int_stacksave     : Intrinsic<[llvm_ptr_ty]>,
 156                         GCCBuiltin<"__builtin_stack_save">;
 157 def int_stackrestore  : Intrinsic<[llvm_void_ty, llvm_ptr_ty]>,
 158                         GCCBuiltin<"__builtin_stack_restore">;
 159 // IntrWriteArgMem is more pessimistic than strictly necessary for prefetch,
 160 // however it does conveniently prevent the prefetch from being reordered
 161 // with respect to nearby accesses to the same memory.
 162 def int_prefetch      : Intrinsic<[llvm_void_ty, llvm_ptr_ty,
 163                                    llvm_i32_ty, llvm_i32_ty],
 164                                   [IntrWriteArgMem]>;
 165 def int_pcmarker      : Intrinsic<[llvm_void_ty, llvm_i32_ty]>;
 166
 167 def int_readcyclecounter : Intrinsic<[llvm_i64_ty]>;
 168
 169 //===------------------- Standard C Library Intrinsics --------------------===//
 170 //
 171
 172 let Properties = [IntrWriteArgMem] in {
 173   def int_memcpy_i32  : Intrinsic<[llvm_void_ty, llvm_ptr_ty, llvm_ptr_ty,
 174                                    llvm_i32_ty, llvm_i32_ty]>;
 175   def int_memcpy_i64  : Intrinsic<[llvm_void_ty, llvm_ptr_ty, llvm_ptr_ty,
 176                                    llvm_i64_ty, llvm_i32_ty]>;
 177   def int_memmove_i32 : Intrinsic<[llvm_void_ty, llvm_ptr_ty, llvm_ptr_ty,
 178                                    llvm_i32_ty, llvm_i32_ty]>;
 179   def int_memmove_i64 : Intrinsic<[llvm_void_ty, llvm_ptr_ty, llvm_ptr_ty,
 180                                    llvm_i64_ty, llvm_i32_ty]>;
 181   def int_memset_i32  : Intrinsic<[llvm_void_ty, llvm_ptr_ty, llvm_i8_ty,
 182                                    llvm_i32_ty, llvm_i32_ty]>;
 183   def int_memset_i64  : Intrinsic<[llvm_void_ty, llvm_ptr_ty, llvm_i8_ty,
 184                                    llvm_i64_ty, llvm_i32_ty]>;
 185 }
 186
 187 let Properties = [IntrNoMem] in {
 188   def int_sqrt : Intrinsic<[llvm_anyfloat_ty, LLVMMatchType<0>]>;
 189   def int_powi : Intrinsic<[llvm_anyfloat_ty, LLVMMatchType<0>, llvm_i32_ty]>;
 190   def int_sin  : Intrinsic<[llvm_anyfloat_ty, LLVMMatchType<0>]>;
 191   def int_cos  : Intrinsic<[llvm_anyfloat_ty, LLVMMatchType<0>]>;
 192   def int_pow  : Intrinsic<[llvm_anyfloat_ty,
 193                             LLVMMatchType<0>, LLVMMatchType<0>]>;
 194 }
 195
 196 // NOTE: these are internal interfaces.
 197 def int_setjmp     : Intrinsic<[llvm_i32_ty , llvm_ptr_ty]>;
 198 def int_longjmp    : Intrinsic<[llvm_void_ty, llvm_ptr_ty, llvm_i32_ty]>;
 199 def int_sigsetjmp  : Intrinsic<[llvm_i32_ty , llvm_ptr_ty, llvm_i32_ty]>;
 200 def int_siglongjmp : Intrinsic<[llvm_void_ty, llvm_ptr_ty, llvm_i32_ty]>;
 201
 202 //===-------------------- Bit Manipulation Intrinsics ---------------------===//
 203 //
 204
 205 // None of these intrinsics accesses memory at all.
 206 let Properties = [IntrNoMem] in {
 207   def int_bswap: Intrinsic<[llvm_anyint_ty, LLVMMatchType<0>]>;
 208   def int_ctpop: Intrinsic<[llvm_anyint_ty, LLVMMatchType<0>]>;
 209   def int_ctlz : Intrinsic<[llvm_anyint_ty, LLVMMatchType<0>]>;
 210   def int_cttz : Intrinsic<[llvm_anyint_ty, LLVMMatchType<0>]>;
 211   def int_part_select :
 212      Intrinsic<[llvm_anyint_ty, LLVMMatchType<0>, llvm_i32_ty, llvm_i32_ty]>;
 213   def int_part_set :
 214      Intrinsic<[llvm_anyint_ty, LLVMMatchType<0>, llvm_anyint_ty, llvm_i32_ty,
 215                 llvm_i32_ty]>;
 216 }
 217
 218 //===------------------------ Debugger Intrinsics -------------------------===//
 219 //
 220
 221 def int_dbg_stoppoint    : Intrinsic<[llvm_void_ty,
 222                                       llvm_i32_ty, llvm_i32_ty,
 223                                       llvm_descriptor_ty]>;
 224 def int_dbg_region_start : Intrinsic<[llvm_void_ty, llvm_descriptor_ty]>;
 225 def int_dbg_region_end   : Intrinsic<[llvm_void_ty, llvm_descriptor_ty]>;
 226 def int_dbg_func_start   : Intrinsic<[llvm_void_ty, llvm_descriptor_ty]>;
 227 def int_dbg_declare      : Intrinsic<[llvm_void_ty, llvm_descriptor_ty,
 228                                                     llvm_descriptor_ty]>;
 229
 230 //===------------------ Exception Handling Intrinsics----------------------===//
 231 //
 232 def int_eh_exception     : Intrinsic<[llvm_ptr_ty]>;
 233 def int_eh_selector_i32  : Intrinsic<[llvm_i32_ty, llvm_ptr_ty, llvm_ptr_ty,
 234                                                    llvm_vararg_ty]>;
 235 def int_eh_selector_i64  : Intrinsic<[llvm_i64_ty, llvm_ptr_ty, llvm_ptr_ty,
 236                                                    llvm_vararg_ty]>;
 237
 238 def int_eh_typeid_for_i32 : Intrinsic<[llvm_i32_ty, llvm_ptr_ty]>;
 239 def int_eh_typeid_for_i64 : Intrinsic<[llvm_i64_ty, llvm_ptr_ty]>;
 240
 241 def int_eh_return     : Intrinsic<[llvm_void_ty, llvm_i32_ty, llvm_ptr_ty]>,
 242                         GCCBuiltin<"__builtin_eh_return">;
 243
 244 def int_eh_unwind_init: Intrinsic<[llvm_void_ty]>,
 245                         GCCBuiltin<"__builtin_unwind_init">;
 246
 247 def int_eh_dwarf_cfa  : Intrinsic<[llvm_ptr_ty, llvm_i32_ty]>;
 248
 249 //===---------------- Generic Variable Attribute Intrinsics----------------===//
 250 //
 251 def int_var_annotation : Intrinsic<[llvm_void_ty, llvm_ptr_ty, llvm_ptr_ty,
 252                                     llvm_ptr_ty, llvm_i32_ty],
 253                                     [], "llvm.var.annotation">;
 254
 255 def int_annotation : Intrinsic<[llvm_anyint_ty, LLVMMatchType<0>, llvm_ptr_ty,
 256                                 llvm_ptr_ty, llvm_i32_ty],
 257                                 [], "llvm.annotation">;
 258
 259 //===------------------------ Trampoline Intrinsics -----------------------===//
 260 //
 261 def int_init_trampoline : Intrinsic<[llvm_ptr_ty, llvm_ptr_ty, llvm_ptr_ty,
 262                                      llvm_ptr_ty], []>,
 263                           GCCBuiltin<"__builtin_init_trampoline">;
 264
 265 //===------------------------- Atomic Intrinsics --------------------------===//
 266 //
 267 def int_memory_barrier : Intrinsic<[llvm_void_ty, llvm_i1_ty, llvm_i1_ty,
 268                                        llvm_i1_ty, llvm_i1_ty, llvm_i1_ty], []>;
 269
 270 //===-------------------------- Other Intrinsics --------------------------===//
 271 //
 272 def int_flt_rounds : Intrinsic<[llvm_i32_ty]>,
 273                      GCCBuiltin<"__builtin_flt_rounds">;
 274 def int_trap : Intrinsic<[llvm_void_ty]>,
 275                GCCBuiltin<"__builtin_trap">;
 276
 277 //===----------------------------------------------------------------------===//
 278 // Target-specific intrinsics
 279 //===----------------------------------------------------------------------===//
 280
 281 include "llvm/IntrinsicsPowerPC.td"
 282 include "llvm/IntrinsicsX86.td"
 283 include "llvm/IntrinsicsARM.td"
 284 include "llvm/IntrinsicsCellSPU.td"