include/llvm/Intrinsics.td

   1 //===- Intrinsics.td - Defines all LLVM intrinsics ---------*- tablegen -*-===//
   2 //
   3 //                     The LLVM Compiler Infrastructure
   4 //
   5 // This file is distributed under the University of Illinois Open Source
   6 // License. See LICENSE.TXT for details.
   7 //
   8 //===----------------------------------------------------------------------===//
   9 //
  10 // This file defines properties of all LLVM intrinsics.
  11 //
  12 //===----------------------------------------------------------------------===//
  13
  14 include "llvm/CodeGen/ValueTypes.td"
  15
  16 //===----------------------------------------------------------------------===//
  17 //  Properties we keep track of for intrinsics.
  18 //===----------------------------------------------------------------------===//
  19
  20 class IntrinsicProperty;
  21
  22 // Intr*Mem - Memory properties.  An intrinsic is allowed to have at most one of
  23 // these properties set.  They are listed from the most aggressive (best to use
  24 // if correct) to the least aggressive.  If no property is set, the worst case
  25 // is assumed (it may read and write any memory it can get access to and it may
  26 // have other side effects).
  27
  28 // IntrNoMem - The intrinsic does not access memory or have any other side
  29 // effects.  It may be CSE'd deleted if dead, etc.
  30 def IntrNoMem : IntrinsicProperty;
  31
  32 // IntrReadArgMem - This intrinsic reads only from memory that one of its
  33 // pointer-typed arguments points to, but may read an unspecified amount.
  34 def IntrReadArgMem : IntrinsicProperty;
  35
  36 // IntrReadMem - This intrinsic reads from unspecified memory, so it cannot be
  37 // moved across stores.  However, it can be reordered otherwise and can be
  38 // deleted if dead.
  39 def IntrReadMem : IntrinsicProperty;
  40
  41 // IntrReadWriteArgMem - This intrinsic reads and writes only from memory that
  42 // one of its arguments points to, but may access an unspecified amount.  The
  43 // reads and writes may be volatile, but except for this it has no other side
  44 // effects.
  45 def IntrReadWriteArgMem : IntrinsicProperty;
  46
  47 // Commutative - This intrinsic is commutative: X op Y == Y op X.
  48 def Commutative : IntrinsicProperty;
  49
  50 // Throws - This intrinsic can throw.
  51 def Throws : IntrinsicProperty;
  52
  53 // NoCapture - The specified argument pointer is not captured by the intrinsic.
  54 class NoCapture<int argNo> : IntrinsicProperty {
  55   int ArgNo = argNo;
  56 }
  57
  58 def IntrNoReturn : IntrinsicProperty;
  59
  60 //===----------------------------------------------------------------------===//
  61 // Types used by intrinsics.
  62 //===----------------------------------------------------------------------===//
  63
  64 class LLVMType<ValueType vt> {
  65   ValueType VT = vt;
  66 }
  67
  68 class LLVMQualPointerType<LLVMType elty, int addrspace>
  69   : LLVMType<iPTR>{
  70   LLVMType ElTy = elty;
  71   int AddrSpace = addrspace;
  72 }
  73
  74 class LLVMPointerType<LLVMType elty>
  75   : LLVMQualPointerType<elty, 0>;
  76
  77 class LLVMAnyPointerType<LLVMType elty>
  78   : LLVMType<iPTRAny>{
  79   LLVMType ElTy = elty;
  80 }
  81
  82 // Match the type of another intrinsic parameter.  Number is an index into the
  83 // list of overloaded types for the intrinsic, excluding all the fixed types.
  84 // The Number value must refer to a previously listed type.  For example:
  85 //   Intrinsic<[llvm_i32_ty], [llvm_i32_ty, llvm_anyfloat_ty, LLVMMatchType<0>]>
  86 // has two overloaded types, the 2nd and 3rd arguments.  LLVMMatchType<0>
  87 // refers to the first overloaded type, which is the 2nd argument.
  88 class LLVMMatchType<int num>
  89   : LLVMType<OtherVT>{
  90   int Number = num;
  91 }
  92
  93 // Match the type of another intrinsic parameter that is expected to be
  94 // an integral vector type, but change the element size to be twice as wide
  95 // or half as wide as the other type.  This is only useful when the intrinsic
  96 // is overloaded, so the matched type should be declared as iAny.
  97 class LLVMExtendedElementVectorType<int num> : LLVMMatchType<num>;
  98 class LLVMTruncatedElementVectorType<int num> : LLVMMatchType<num>;
  99
 100 def llvm_void_ty       : LLVMType<isVoid>;
 101 def llvm_anyint_ty     : LLVMType<iAny>;
 102 def llvm_anyfloat_ty   : LLVMType<fAny>;
 103 def llvm_anyvector_ty  : LLVMType<vAny>;
 104 def llvm_i1_ty         : LLVMType<i1>;
 105 def llvm_i8_ty         : LLVMType<i8>;
 106 def llvm_i16_ty        : LLVMType<i16>;
 107 def llvm_i32_ty        : LLVMType<i32>;
 108 def llvm_i64_ty        : LLVMType<i64>;
 109 def llvm_float_ty      : LLVMType<f32>;
 110 def llvm_double_ty     : LLVMType<f64>;
 111 def llvm_f80_ty        : LLVMType<f80>;
 112 def llvm_f128_ty       : LLVMType<f128>;
 113 def llvm_ppcf128_ty    : LLVMType<ppcf128>;
 114 def llvm_ptr_ty        : LLVMPointerType<llvm_i8_ty>;             // i8*
 115 def llvm_ptrptr_ty     : LLVMPointerType<llvm_ptr_ty>;            // i8**
 116 def llvm_anyptr_ty     : LLVMAnyPointerType<llvm_i8_ty>;          // (space)i8*
 117 def llvm_empty_ty      : LLVMType<OtherVT>;                       // { }
 118 def llvm_descriptor_ty : LLVMPointerType<llvm_empty_ty>;          // { }*
 119 def llvm_metadata_ty   : LLVMType<MetadataVT>;                    // !{...}
 120
 121 def llvm_x86mmx_ty     : LLVMType<x86mmx>;
 122 def llvm_ptrx86mmx_ty  : LLVMPointerType<llvm_x86mmx_ty>;         // <1 x i64>*
 123
 124 def llvm_v2i1_ty       : LLVMType<v2i1>;     //  2 x i1
 125 def llvm_v4i1_ty       : LLVMType<v4i1>;     //  4 x i1
 126 def llvm_v8i1_ty       : LLVMType<v8i1>;     //  8 x i1
 127 def llvm_v16i1_ty      : LLVMType<v16i1>;    // 16 x i1
 128 def llvm_v2i8_ty       : LLVMType<v2i8>;     //  2 x i8
 129 def llvm_v4i8_ty       : LLVMType<v4i8>;     //  4 x i8
 130 def llvm_v8i8_ty       : LLVMType<v8i8>;     //  8 x i8
 131 def llvm_v16i8_ty      : LLVMType<v16i8>;    // 16 x i8
 132 def llvm_v32i8_ty      : LLVMType<v32i8>;    // 32 x i8
 133 def llvm_v1i16_ty      : LLVMType<v1i16>;    //  1 x i16
 134 def llvm_v2i16_ty      : LLVMType<v2i16>;    //  2 x i16
 135 def llvm_v4i16_ty      : LLVMType<v4i16>;    //  4 x i16
 136 def llvm_v8i16_ty      : LLVMType<v8i16>;    //  8 x i16
 137 def llvm_v16i16_ty     : LLVMType<v16i16>;   // 16 x i16
 138 def llvm_v1i32_ty      : LLVMType<v1i32>;    //  1 x i32
 139 def llvm_v2i32_ty      : LLVMType<v2i32>;    //  2 x i32
 140 def llvm_v4i32_ty      : LLVMType<v4i32>;    //  4 x i32
 141 def llvm_v8i32_ty      : LLVMType<v8i32>;    //  8 x i32
 142 def llvm_v16i32_ty     : LLVMType<v16i32>;   // 16 x i32
 143 def llvm_v1i64_ty      : LLVMType<v1i64>;    //  1 x i64
 144 def llvm_v2i64_ty      : LLVMType<v2i64>;    //  2 x i64
 145 def llvm_v4i64_ty      : LLVMType<v4i64>;    //  4 x i64
 146 def llvm_v8i64_ty      : LLVMType<v8i64>;    //  8 x i64
 147 def llvm_v16i64_ty     : LLVMType<v16i64>;   // 16 x i64
 148
 149 def llvm_v2f32_ty      : LLVMType<v2f32>;    //  2 x float
 150 def llvm_v4f32_ty      : LLVMType<v4f32>;    //  4 x float
 151 def llvm_v8f32_ty      : LLVMType<v8f32>;    //  8 x float
 152 def llvm_v2f64_ty      : LLVMType<v2f64>;    //  2 x double
 153 def llvm_v4f64_ty      : LLVMType<v4f64>;    //  4 x double
 154
 155 def llvm_vararg_ty     : LLVMType<isVoid>;   // this means vararg here
 156
 157
 158 //===----------------------------------------------------------------------===//
 159 // Intrinsic Definitions.
 160 //===----------------------------------------------------------------------===//
 161
 162 // Intrinsic class - This is used to define one LLVM intrinsic.  The name of the
 163 // intrinsic definition should start with "int_", then match the LLVM intrinsic
 164 // name with the "llvm." prefix removed, and all "."s turned into "_"s.  For
 165 // example, llvm.bswap.i16 -> int_bswap_i16.
 166 //
 167 //  * RetTypes is a list containing the return types expected for the
 168 //    intrinsic.
 169 //  * ParamTypes is a list containing the parameter types expected for the
 170 //    intrinsic.
 171 //  * Properties can be set to describe the behavior of the intrinsic.
 172 //
 173 class SDPatternOperator;
 174 class Intrinsic<list<LLVMType> ret_types,
 175                 list<LLVMType> param_types = [],
 176                 list<IntrinsicProperty> properties = [],
 177                 string name = ""> : SDPatternOperator {
 178   string LLVMName = name;
 179   string TargetPrefix = "";   // Set to a prefix for target-specific intrinsics.
 180   list<LLVMType> RetTypes = ret_types;
 181   list<LLVMType> ParamTypes = param_types;
 182   list<IntrinsicProperty> Properties = properties;
 183
 184   bit isTarget = 0;
 185 }
 186
 187 /// GCCBuiltin - If this intrinsic exactly corresponds to a GCC builtin, this
 188 /// specifies the name of the builtin.  This provides automatic CBE and CFE
 189 /// support.
 190 class GCCBuiltin<string name> {
 191   string GCCBuiltinName = name;
 192 }
 193
 194
 195 //===--------------- Variable Argument Handling Intrinsics ----------------===//
 196 //
 197
 198 def int_vastart : Intrinsic<[], [llvm_ptr_ty], [], "llvm.va_start">;
 199 def int_vacopy  : Intrinsic<[], [llvm_ptr_ty, llvm_ptr_ty], [],
 200                             "llvm.va_copy">;
 201 def int_vaend   : Intrinsic<[], [llvm_ptr_ty], [], "llvm.va_end">;
 202
 203 //===------------------- Garbage Collection Intrinsics --------------------===//
 204 //
 205 def int_gcroot  : Intrinsic<[],
 206                             [llvm_ptrptr_ty, llvm_ptr_ty]>;
 207 def int_gcread  : Intrinsic<[llvm_ptr_ty],
 208                             [llvm_ptr_ty, llvm_ptrptr_ty],
 209                             [IntrReadArgMem]>;
 210 def int_gcwrite : Intrinsic<[],
 211                             [llvm_ptr_ty, llvm_ptr_ty, llvm_ptrptr_ty],
 212                             [IntrReadWriteArgMem, NoCapture<1>, NoCapture<2>]>;
 213
 214 //===--------------------- Code Generator Intrinsics ----------------------===//
 215 //
 216 def int_returnaddress : Intrinsic<[llvm_ptr_ty], [llvm_i32_ty], [IntrNoMem]>;
 217 def int_frameaddress  : Intrinsic<[llvm_ptr_ty], [llvm_i32_ty], [IntrNoMem]>;
 218
 219 // Note: we treat stacksave/stackrestore as writemem because we don't otherwise
 220 // model their dependencies on allocas.
 221 def int_stacksave     : Intrinsic<[llvm_ptr_ty]>,
 222                         GCCBuiltin<"__builtin_stack_save">;
 223 def int_stackrestore  : Intrinsic<[], [llvm_ptr_ty]>,
 224                         GCCBuiltin<"__builtin_stack_restore">;
 225
 226 // IntrReadWriteArgMem is more pessimistic than strictly necessary for prefetch,
 227 // however it does conveniently prevent the prefetch from being reordered
 228 // with respect to nearby accesses to the same memory.
 229 def int_prefetch      : Intrinsic<[],
 230                                   [llvm_ptr_ty, llvm_i32_ty, llvm_i32_ty,
 231                                    llvm_i32_ty],
 232                                   [IntrReadWriteArgMem, NoCapture<0>]>;
 233 def int_pcmarker      : Intrinsic<[], [llvm_i32_ty]>;
 234
 235 def int_readcyclecounter : Intrinsic<[llvm_i64_ty]>;
 236
 237 // Stack Protector Intrinsic - The stackprotector intrinsic writes the stack
 238 // guard to the correct place on the stack frame.
 239 def int_stackprotector : Intrinsic<[], [llvm_ptr_ty, llvm_ptrptr_ty], []>;
 240
 241 //===------------------- Standard C Library Intrinsics --------------------===//
 242 //
 243
 244 def int_memcpy  : Intrinsic<[],
 245                              [llvm_anyptr_ty, llvm_anyptr_ty, llvm_anyint_ty,
 246                               llvm_i32_ty, llvm_i1_ty],
 247                             [IntrReadWriteArgMem, NoCapture<0>, NoCapture<1>]>;
 248 def int_memmove : Intrinsic<[],
 249                             [llvm_anyptr_ty, llvm_anyptr_ty, llvm_anyint_ty,
 250                              llvm_i32_ty, llvm_i1_ty],
 251                             [IntrReadWriteArgMem, NoCapture<0>, NoCapture<1>]>;
 252 def int_memset  : Intrinsic<[],
 253                             [llvm_anyptr_ty, llvm_i8_ty, llvm_anyint_ty,
 254                              llvm_i32_ty, llvm_i1_ty],
 255                             [IntrReadWriteArgMem, NoCapture<0>]>;
 256
 257 // These functions do not actually read memory, but they are sensitive to the
 258 // rounding mode.  This needs to be modelled separately; in the meantime
 259 // declaring them as reading memory is conservatively correct.
 260 let Properties = [IntrReadMem] in {
 261   def int_sqrt : Intrinsic<[llvm_anyfloat_ty], [LLVMMatchType<0>]>;
 262   def int_powi : Intrinsic<[llvm_anyfloat_ty], [LLVMMatchType<0>, llvm_i32_ty]>;
 263   def int_sin  : Intrinsic<[llvm_anyfloat_ty], [LLVMMatchType<0>]>;
 264   def int_cos  : Intrinsic<[llvm_anyfloat_ty], [LLVMMatchType<0>]>;
 265   def int_pow  : Intrinsic<[llvm_anyfloat_ty],
 266                            [LLVMMatchType<0>, LLVMMatchType<0>]>;
 267   def int_log  : Intrinsic<[llvm_anyfloat_ty], [LLVMMatchType<0>]>;
 268   def int_log10: Intrinsic<[llvm_anyfloat_ty], [LLVMMatchType<0>]>;
 269   def int_log2 : Intrinsic<[llvm_anyfloat_ty], [LLVMMatchType<0>]>;
 270   def int_exp  : Intrinsic<[llvm_anyfloat_ty], [LLVMMatchType<0>]>;
 271   def int_exp2 : Intrinsic<[llvm_anyfloat_ty], [LLVMMatchType<0>]>;
 272   def int_fabs : Intrinsic<[llvm_anyfloat_ty], [LLVMMatchType<0>]>;
 273   def int_floor : Intrinsic<[llvm_anyfloat_ty], [LLVMMatchType<0>]>;
 274 }
 275
 276 let Properties = [IntrNoMem] in {
 277   def int_fma  : Intrinsic<[llvm_anyfloat_ty],
 278                          [LLVMMatchType<0>, LLVMMatchType<0>,
 279                           LLVMMatchType<0>]>;
 280
 281   def int_fmuladd : Intrinsic<[llvm_anyfloat_ty],
 282                               [LLVMMatchType<0>, LLVMMatchType<0>,
 283                                LLVMMatchType<0>]>;
 284 }
 285
 286 // NOTE: these are internal interfaces.
 287 def int_setjmp     : Intrinsic<[llvm_i32_ty],  [llvm_ptr_ty]>;
 288 def int_longjmp    : Intrinsic<[], [llvm_ptr_ty, llvm_i32_ty]>;
 289 def int_sigsetjmp  : Intrinsic<[llvm_i32_ty] , [llvm_ptr_ty, llvm_i32_ty]>;
 290 def int_siglongjmp : Intrinsic<[], [llvm_ptr_ty, llvm_i32_ty]>;
 291
 292 // Internal interface for object size checking
 293 def int_objectsize : Intrinsic<[llvm_anyint_ty], [llvm_ptr_ty, llvm_i1_ty],
 294                                [IntrNoMem]>,
 295                                GCCBuiltin<"__builtin_object_size">;
 296
 297 //===------------------------- Expect Intrinsics --------------------------===//
 298 //
 299 def int_expect : Intrinsic<[llvm_anyint_ty], [LLVMMatchType<0>,
 300                                               LLVMMatchType<0>], [IntrNoMem]>;
 301
 302 //===-------------------- Bit Manipulation Intrinsics ---------------------===//
 303 //
 304
 305 // None of these intrinsics accesses memory at all.
 306 let Properties = [IntrNoMem] in {
 307   def int_bswap: Intrinsic<[llvm_anyint_ty], [LLVMMatchType<0>]>;
 308   def int_ctpop: Intrinsic<[llvm_anyint_ty], [LLVMMatchType<0>]>;
 309   def int_ctlz : Intrinsic<[llvm_anyint_ty], [LLVMMatchType<0>, llvm_i1_ty]>;
 310   def int_cttz : Intrinsic<[llvm_anyint_ty], [LLVMMatchType<0>, llvm_i1_ty]>;
 311 }
 312
 313 //===------------------------ Debugger Intrinsics -------------------------===//
 314 //
 315
 316 // None of these intrinsics accesses memory at all...but that doesn't mean the
 317 // optimizers can change them aggressively.  Special handling needed in a few
 318 // places.
 319 let Properties = [IntrNoMem] in {
 320   def int_dbg_declare      : Intrinsic<[],
 321                                        [llvm_metadata_ty, llvm_metadata_ty]>;
 322   def int_dbg_value        : Intrinsic<[],
 323                                        [llvm_metadata_ty, llvm_i64_ty,
 324                                         llvm_metadata_ty]>;
 325 }
 326
 327 //===------------------ Exception Handling Intrinsics----------------------===//
 328 //
 329
 330 // The result of eh.typeid.for depends on the enclosing function, but inside a
 331 // given function it is 'const' and may be CSE'd etc.
 332 def int_eh_typeid_for : Intrinsic<[llvm_i32_ty], [llvm_ptr_ty], [IntrNoMem]>;
 333
 334 def int_eh_return_i32 : Intrinsic<[], [llvm_i32_ty, llvm_ptr_ty]>;
 335 def int_eh_return_i64 : Intrinsic<[], [llvm_i64_ty, llvm_ptr_ty]>;
 336
 337 def int_eh_unwind_init: Intrinsic<[]>,
 338                         GCCBuiltin<"__builtin_unwind_init">;
 339
 340 def int_eh_dwarf_cfa  : Intrinsic<[llvm_ptr_ty], [llvm_i32_ty]>;
 341
 342 let Properties = [IntrNoMem] in {
 343   def int_eh_sjlj_lsda             : Intrinsic<[llvm_ptr_ty]>;
 344   def int_eh_sjlj_callsite         : Intrinsic<[], [llvm_i32_ty]>;
 345 }
 346 def int_eh_sjlj_functioncontext : Intrinsic<[], [llvm_ptr_ty]>;
 347 def int_eh_sjlj_setjmp          : Intrinsic<[llvm_i32_ty], [llvm_ptr_ty]>;
 348 def int_eh_sjlj_longjmp         : Intrinsic<[], [llvm_ptr_ty]>;
 349
 350 //===---------------- Generic Variable Attribute Intrinsics----------------===//
 351 //
 352 def int_var_annotation : Intrinsic<[],
 353                                    [llvm_ptr_ty, llvm_ptr_ty,
 354                                     llvm_ptr_ty, llvm_i32_ty],
 355                                    [], "llvm.var.annotation">;
 356 def int_ptr_annotation : Intrinsic<[LLVMAnyPointerType<llvm_anyint_ty>],
 357                                    [LLVMMatchType<0>, llvm_ptr_ty, llvm_ptr_ty,
 358                                     llvm_i32_ty],
 359                                    [], "llvm.ptr.annotation">;
 360 def int_annotation : Intrinsic<[llvm_anyint_ty],
 361                                [LLVMMatchType<0>, llvm_ptr_ty,
 362                                 llvm_ptr_ty, llvm_i32_ty],
 363                                [], "llvm.annotation">;
 364
 365 //===------------------------ Trampoline Intrinsics -----------------------===//
 366 //
 367 def int_init_trampoline : Intrinsic<[],
 368                                     [llvm_ptr_ty, llvm_ptr_ty, llvm_ptr_ty],
 369                                     [IntrReadWriteArgMem, NoCapture<0>]>,
 370                                    GCCBuiltin<"__builtin_init_trampoline">;
 371
 372 def int_adjust_trampoline : Intrinsic<[llvm_ptr_ty], [llvm_ptr_ty],
 373                                       [IntrReadArgMem]>,
 374                                      GCCBuiltin<"__builtin_adjust_trampoline">;
 375
 376 //===------------------------ Overflow Intrinsics -------------------------===//
 377 //
 378
 379 // Expose the carry flag from add operations on two integrals.
 380 def int_sadd_with_overflow : Intrinsic<[llvm_anyint_ty, llvm_i1_ty],
 381                                        [LLVMMatchType<0>, LLVMMatchType<0>],
 382                                        [IntrNoMem]>;
 383 def int_uadd_with_overflow : Intrinsic<[llvm_anyint_ty, llvm_i1_ty],
 384                                        [LLVMMatchType<0>, LLVMMatchType<0>],
 385                                        [IntrNoMem]>;
 386
 387 def int_ssub_with_overflow : Intrinsic<[llvm_anyint_ty, llvm_i1_ty],
 388                                        [LLVMMatchType<0>, LLVMMatchType<0>],
 389                                        [IntrNoMem]>;
 390 def int_usub_with_overflow : Intrinsic<[llvm_anyint_ty, llvm_i1_ty],
 391                                        [LLVMMatchType<0>, LLVMMatchType<0>],
 392                                        [IntrNoMem]>;
 393
 394 def int_smul_with_overflow : Intrinsic<[llvm_anyint_ty, llvm_i1_ty],
 395                                        [LLVMMatchType<0>, LLVMMatchType<0>],
 396                                        [IntrNoMem]>;
 397 def int_umul_with_overflow : Intrinsic<[llvm_anyint_ty, llvm_i1_ty],
 398                                        [LLVMMatchType<0>, LLVMMatchType<0>],
 399                                        [IntrNoMem]>;
 400
 401 //===------------------------- Memory Use Markers -------------------------===//
 402 //
 403 def int_lifetime_start  : Intrinsic<[],
 404                                     [llvm_i64_ty, llvm_ptr_ty],
 405                                     [IntrReadWriteArgMem, NoCapture<1>]>;
 406 def int_lifetime_end    : Intrinsic<[],
 407                                     [llvm_i64_ty, llvm_ptr_ty],
 408                                     [IntrReadWriteArgMem, NoCapture<1>]>;
 409 def int_invariant_start : Intrinsic<[llvm_descriptor_ty],
 410                                     [llvm_i64_ty, llvm_ptr_ty],
 411                                     [IntrReadWriteArgMem, NoCapture<1>]>;
 412 def int_invariant_end   : Intrinsic<[],
 413                                     [llvm_descriptor_ty, llvm_i64_ty,
 414                                      llvm_ptr_ty],
 415                                     [IntrReadWriteArgMem, NoCapture<2>]>;
 416
 417 //===-------------------------- Other Intrinsics --------------------------===//
 418 //
 419 def int_flt_rounds : Intrinsic<[llvm_i32_ty]>,
 420                      GCCBuiltin<"__builtin_flt_rounds">;
 421 def int_trap : Intrinsic<[], [], [IntrNoReturn]>,
 422                GCCBuiltin<"__builtin_trap">;
 423 def int_debugtrap : Intrinsic<[], [], [IntrNoReturn]>,
 424                     GCCBuiltin<"__builtin_debugtrap">;
 425
 426 // NOP: calls/invokes to this intrinsic are removed by codegen
 427 def int_donothing : Intrinsic<[], [], [IntrNoMem]>;
 428
 429 // Intrisics to support half precision floating point format
 430 let Properties = [IntrNoMem] in {
 431 def int_convert_to_fp16   : Intrinsic<[llvm_i16_ty], [llvm_float_ty]>,
 432                             GCCBuiltin<"__gnu_f2h_ieee">;
 433 def int_convert_from_fp16 : Intrinsic<[llvm_float_ty], [llvm_i16_ty]>,
 434                             GCCBuiltin<"__gnu_h2f_ieee">;
 435 }
 436
 437 // These convert intrinsics are to support various conversions between
 438 // various types with rounding and saturation. NOTE: avoid using these
 439 // intrinsics as they might be removed sometime in the future and
 440 // most targets don't support them.
 441 def int_convertff  : Intrinsic<[llvm_anyfloat_ty],
 442                                [llvm_anyfloat_ty, llvm_i32_ty, llvm_i32_ty]>;
 443 def int_convertfsi : Intrinsic<[llvm_anyfloat_ty],
 444                                [llvm_anyint_ty, llvm_i32_ty, llvm_i32_ty]>;
 445 def int_convertfui : Intrinsic<[llvm_anyfloat_ty],
 446                                [llvm_anyint_ty, llvm_i32_ty, llvm_i32_ty]>;
 447 def int_convertsif : Intrinsic<[llvm_anyint_ty],
 448                                [llvm_anyfloat_ty, llvm_i32_ty, llvm_i32_ty]>;
 449 def int_convertuif : Intrinsic<[llvm_anyint_ty],
 450                                [llvm_anyfloat_ty, llvm_i32_ty, llvm_i32_ty]>;
 451 def int_convertss  : Intrinsic<[llvm_anyint_ty],
 452                                [llvm_anyint_ty, llvm_i32_ty, llvm_i32_ty]>;
 453 def int_convertsu  : Intrinsic<[llvm_anyint_ty],
 454                                [llvm_anyint_ty, llvm_i32_ty, llvm_i32_ty]>;
 455 def int_convertus  : Intrinsic<[llvm_anyint_ty],
 456                                [llvm_anyint_ty, llvm_i32_ty, llvm_i32_ty]>;
 457 def int_convertuu  : Intrinsic<[llvm_anyint_ty],
 458                                [llvm_anyint_ty, llvm_i32_ty, llvm_i32_ty]>;
 459
 460 //===----------------------------------------------------------------------===//
 461 // Target-specific intrinsics
 462 //===----------------------------------------------------------------------===//
 463
 464 include "llvm/IntrinsicsPowerPC.td"
 465 include "llvm/IntrinsicsX86.td"
 466 include "llvm/IntrinsicsARM.td"
 467 include "llvm/IntrinsicsCellSPU.td"
 468 include "llvm/IntrinsicsXCore.td"
 469 include "llvm/IntrinsicsHexagon.td"
 470 include "llvm/IntrinsicsNVVM.td"
 471 include "llvm/IntrinsicsMips.td"