include/llvm/IR/Intrinsics.td

   1 //===- Intrinsics.td - Defines all LLVM intrinsics ---------*- tablegen -*-===//
   2 //
   3 //                     The LLVM Compiler Infrastructure
   4 //
   5 // This file is distributed under the University of Illinois Open Source
   6 // License. See LICENSE.TXT for details.
   7 //
   8 //===----------------------------------------------------------------------===//
   9 //
  10 // This file defines properties of all LLVM intrinsics.
  11 //
  12 //===----------------------------------------------------------------------===//
  13
  14 include "llvm/CodeGen/ValueTypes.td"
  15
  16 //===----------------------------------------------------------------------===//
  17 //  Properties we keep track of for intrinsics.
  18 //===----------------------------------------------------------------------===//
  19
  20 class IntrinsicProperty;
  21
  22 // Intr*Mem - Memory properties.  An intrinsic is allowed to have at most one of
  23 // these properties set.  They are listed from the most aggressive (best to use
  24 // if correct) to the least aggressive.  If no property is set, the worst case
  25 // is assumed (it may read and write any memory it can get access to and it may
  26 // have other side effects).
  27
  28 // IntrNoMem - The intrinsic does not access memory or have any other side
  29 // effects.  It may be CSE'd deleted if dead, etc.
  30 def IntrNoMem : IntrinsicProperty;
  31
  32 // IntrReadArgMem - This intrinsic reads only from memory that one of its
  33 // pointer-typed arguments points to, but may read an unspecified amount.
  34 def IntrReadArgMem : IntrinsicProperty;
  35
  36 // IntrReadMem - This intrinsic reads from unspecified memory, so it cannot be
  37 // moved across stores.  However, it can be reordered otherwise and can be
  38 // deleted if dead.
  39 def IntrReadMem : IntrinsicProperty;
  40
  41 // IntrReadWriteArgMem - This intrinsic reads and writes only from memory that
  42 // one of its arguments points to, but may access an unspecified amount.  The
  43 // reads and writes may be volatile, but except for this it has no other side
  44 // effects.
  45 def IntrReadWriteArgMem : IntrinsicProperty;
  46
  47 // Commutative - This intrinsic is commutative: X op Y == Y op X.
  48 def Commutative : IntrinsicProperty;
  49
  50 // Throws - This intrinsic can throw.
  51 def Throws : IntrinsicProperty;
  52
  53 // NoCapture - The specified argument pointer is not captured by the intrinsic.
  54 class NoCapture<int argNo> : IntrinsicProperty {
  55   int ArgNo = argNo;
  56 }
  57
  58 def IntrNoReturn : IntrinsicProperty;
  59
  60 //===----------------------------------------------------------------------===//
  61 // Types used by intrinsics.
  62 //===----------------------------------------------------------------------===//
  63
  64 class LLVMType<ValueType vt> {
  65   ValueType VT = vt;
  66 }
  67
  68 class LLVMQualPointerType<LLVMType elty, int addrspace>
  69   : LLVMType<iPTR>{
  70   LLVMType ElTy = elty;
  71   int AddrSpace = addrspace;
  72 }
  73
  74 class LLVMPointerType<LLVMType elty>
  75   : LLVMQualPointerType<elty, 0>;
  76
  77 class LLVMAnyPointerType<LLVMType elty>
  78   : LLVMType<iPTRAny>{
  79   LLVMType ElTy = elty;
  80 }
  81
  82 // Match the type of another intrinsic parameter.  Number is an index into the
  83 // list of overloaded types for the intrinsic, excluding all the fixed types.
  84 // The Number value must refer to a previously listed type.  For example:
  85 //   Intrinsic<[llvm_i32_ty], [llvm_i32_ty, llvm_anyfloat_ty, LLVMMatchType<0>]>
  86 // has two overloaded types, the 2nd and 3rd arguments.  LLVMMatchType<0>
  87 // refers to the first overloaded type, which is the 2nd argument.
  88 class LLVMMatchType<int num>
  89   : LLVMType<OtherVT>{
  90   int Number = num;
  91 }
  92
  93 // Match the type of another intrinsic parameter that is expected to be
  94 // an integral vector type, but change the element size to be twice as wide
  95 // or half as wide as the other type.  This is only useful when the intrinsic
  96 // is overloaded, so the matched type should be declared as iAny.
  97 class LLVMExtendedElementVectorType<int num> : LLVMMatchType<num>;
  98 class LLVMTruncatedElementVectorType<int num> : LLVMMatchType<num>;
  99
 100 def llvm_void_ty       : LLVMType<isVoid>;
 101 def llvm_anyint_ty     : LLVMType<iAny>;
 102 def llvm_anyfloat_ty   : LLVMType<fAny>;
 103 def llvm_anyvector_ty  : LLVMType<vAny>;
 104 def llvm_i1_ty         : LLVMType<i1>;
 105 def llvm_i8_ty         : LLVMType<i8>;
 106 def llvm_i16_ty        : LLVMType<i16>;
 107 def llvm_i32_ty        : LLVMType<i32>;
 108 def llvm_i64_ty        : LLVMType<i64>;
 109 def llvm_half_ty       : LLVMType<f16>;
 110 def llvm_float_ty      : LLVMType<f32>;
 111 def llvm_double_ty     : LLVMType<f64>;
 112 def llvm_f80_ty        : LLVMType<f80>;
 113 def llvm_f128_ty       : LLVMType<f128>;
 114 def llvm_ppcf128_ty    : LLVMType<ppcf128>;
 115 def llvm_ptr_ty        : LLVMPointerType<llvm_i8_ty>;             // i8*
 116 def llvm_ptrptr_ty     : LLVMPointerType<llvm_ptr_ty>;            // i8**
 117 def llvm_anyptr_ty     : LLVMAnyPointerType<llvm_i8_ty>;          // (space)i8*
 118 def llvm_empty_ty      : LLVMType<OtherVT>;                       // { }
 119 def llvm_descriptor_ty : LLVMPointerType<llvm_empty_ty>;          // { }*
 120 def llvm_metadata_ty   : LLVMType<MetadataVT>;                    // !{...}
 121
 122 def llvm_x86mmx_ty     : LLVMType<x86mmx>;
 123 def llvm_ptrx86mmx_ty  : LLVMPointerType<llvm_x86mmx_ty>;         // <1 x i64>*
 124
 125 def llvm_v2i1_ty       : LLVMType<v2i1>;     //  2 x i1
 126 def llvm_v4i1_ty       : LLVMType<v4i1>;     //  4 x i1
 127 def llvm_v8i1_ty       : LLVMType<v8i1>;     //  8 x i1
 128 def llvm_v16i1_ty      : LLVMType<v16i1>;    // 16 x i1
 129 def llvm_v32i1_ty      : LLVMType<v32i1>;    // 32 x i1
 130 def llvm_v64i1_ty      : LLVMType<v64i1>;    // 64 x i1
 131 def llvm_v2i8_ty       : LLVMType<v2i8>;     //  2 x i8
 132 def llvm_v4i8_ty       : LLVMType<v4i8>;     //  4 x i8
 133 def llvm_v8i8_ty       : LLVMType<v8i8>;     //  8 x i8
 134 def llvm_v16i8_ty      : LLVMType<v16i8>;    // 16 x i8
 135 def llvm_v32i8_ty      : LLVMType<v32i8>;    // 32 x i8
 136 def llvm_v64i8_ty      : LLVMType<v64i8>;    // 64 x i8
 137
 138 def llvm_v1i16_ty      : LLVMType<v1i16>;    //  1 x i16
 139 def llvm_v2i16_ty      : LLVMType<v2i16>;    //  2 x i16
 140 def llvm_v4i16_ty      : LLVMType<v4i16>;    //  4 x i16
 141 def llvm_v8i16_ty      : LLVMType<v8i16>;    //  8 x i16
 142 def llvm_v16i16_ty     : LLVMType<v16i16>;   // 16 x i16
 143 def llvm_v32i16_ty     : LLVMType<v32i16>;   // 32 x i16
 144
 145 def llvm_v1i32_ty      : LLVMType<v1i32>;    //  1 x i32
 146 def llvm_v2i32_ty      : LLVMType<v2i32>;    //  2 x i32
 147 def llvm_v4i32_ty      : LLVMType<v4i32>;    //  4 x i32
 148 def llvm_v8i32_ty      : LLVMType<v8i32>;    //  8 x i32
 149 def llvm_v16i32_ty     : LLVMType<v16i32>;   // 16 x i32
 150 def llvm_v1i64_ty      : LLVMType<v1i64>;    //  1 x i64
 151 def llvm_v2i64_ty      : LLVMType<v2i64>;    //  2 x i64
 152 def llvm_v4i64_ty      : LLVMType<v4i64>;    //  4 x i64
 153 def llvm_v8i64_ty      : LLVMType<v8i64>;    //  8 x i64
 154 def llvm_v16i64_ty     : LLVMType<v16i64>;   // 16 x i64
 155
 156 def llvm_v2f32_ty      : LLVMType<v2f32>;    //  2 x float
 157 def llvm_v4f32_ty      : LLVMType<v4f32>;    //  4 x float
 158 def llvm_v8f32_ty      : LLVMType<v8f32>;    //  8 x float
 159 def llvm_v16f32_ty     : LLVMType<v16f32>;   // 16 x float
 160 def llvm_v2f64_ty      : LLVMType<v2f64>;    //  2 x double
 161 def llvm_v4f64_ty      : LLVMType<v4f64>;    //  4 x double
 162 def llvm_v8f64_ty      : LLVMType<v8f64>;    //  8 x double
 163
 164 def llvm_vararg_ty     : LLVMType<isVoid>;   // this means vararg here
 165
 166
 167 //===----------------------------------------------------------------------===//
 168 // Intrinsic Definitions.
 169 //===----------------------------------------------------------------------===//
 170
 171 // Intrinsic class - This is used to define one LLVM intrinsic.  The name of the
 172 // intrinsic definition should start with "int_", then match the LLVM intrinsic
 173 // name with the "llvm." prefix removed, and all "."s turned into "_"s.  For
 174 // example, llvm.bswap.i16 -> int_bswap_i16.
 175 //
 176 //  * RetTypes is a list containing the return types expected for the
 177 //    intrinsic.
 178 //  * ParamTypes is a list containing the parameter types expected for the
 179 //    intrinsic.
 180 //  * Properties can be set to describe the behavior of the intrinsic.
 181 //
 182 class SDPatternOperator;
 183 class Intrinsic<list<LLVMType> ret_types,
 184                 list<LLVMType> param_types = [],
 185                 list<IntrinsicProperty> properties = [],
 186                 string name = ""> : SDPatternOperator {
 187   string LLVMName = name;
 188   string TargetPrefix = "";   // Set to a prefix for target-specific intrinsics.
 189   list<LLVMType> RetTypes = ret_types;
 190   list<LLVMType> ParamTypes = param_types;
 191   list<IntrinsicProperty> Properties = properties;
 192
 193   bit isTarget = 0;
 194 }
 195
 196 /// GCCBuiltin - If this intrinsic exactly corresponds to a GCC builtin, this
 197 /// specifies the name of the builtin.  This provides automatic CBE and CFE
 198 /// support.
 199 class GCCBuiltin<string name> {
 200   string GCCBuiltinName = name;
 201 }
 202
 203
 204 //===--------------- Variable Argument Handling Intrinsics ----------------===//
 205 //
 206
 207 def int_vastart : Intrinsic<[], [llvm_ptr_ty], [], "llvm.va_start">;
 208 def int_vacopy  : Intrinsic<[], [llvm_ptr_ty, llvm_ptr_ty], [],
 209                             "llvm.va_copy">;
 210 def int_vaend   : Intrinsic<[], [llvm_ptr_ty], [], "llvm.va_end">;
 211
 212 //===------------------- Garbage Collection Intrinsics --------------------===//
 213 //
 214 def int_gcroot  : Intrinsic<[],
 215                             [llvm_ptrptr_ty, llvm_ptr_ty]>;
 216 def int_gcread  : Intrinsic<[llvm_ptr_ty],
 217                             [llvm_ptr_ty, llvm_ptrptr_ty],
 218                             [IntrReadArgMem]>;
 219 def int_gcwrite : Intrinsic<[],
 220                             [llvm_ptr_ty, llvm_ptr_ty, llvm_ptrptr_ty],
 221                             [IntrReadWriteArgMem, NoCapture<1>, NoCapture<2>]>;
 222
 223 //===--------------------- Code Generator Intrinsics ----------------------===//
 224 //
 225 def int_returnaddress : Intrinsic<[llvm_ptr_ty], [llvm_i32_ty], [IntrNoMem]>;
 226 def int_frameaddress  : Intrinsic<[llvm_ptr_ty], [llvm_i32_ty], [IntrNoMem]>;
 227
 228 // Note: we treat stacksave/stackrestore as writemem because we don't otherwise
 229 // model their dependencies on allocas.
 230 def int_stacksave     : Intrinsic<[llvm_ptr_ty]>,
 231                         GCCBuiltin<"__builtin_stack_save">;
 232 def int_stackrestore  : Intrinsic<[], [llvm_ptr_ty]>,
 233                         GCCBuiltin<"__builtin_stack_restore">;
 234
 235 // IntrReadWriteArgMem is more pessimistic than strictly necessary for prefetch,
 236 // however it does conveniently prevent the prefetch from being reordered
 237 // with respect to nearby accesses to the same memory.
 238 def int_prefetch      : Intrinsic<[],
 239                                   [llvm_ptr_ty, llvm_i32_ty, llvm_i32_ty,
 240                                    llvm_i32_ty],
 241                                   [IntrReadWriteArgMem, NoCapture<0>]>;
 242 def int_pcmarker      : Intrinsic<[], [llvm_i32_ty]>;
 243
 244 def int_readcyclecounter : Intrinsic<[llvm_i64_ty]>;
 245
 246 // Stack Protector Intrinsic - The stackprotector intrinsic writes the stack
 247 // guard to the correct place on the stack frame.
 248 def int_stackprotector : Intrinsic<[], [llvm_ptr_ty, llvm_ptrptr_ty], []>;
 249
 250 //===------------------- Standard C Library Intrinsics --------------------===//
 251 //
 252
 253 def int_memcpy  : Intrinsic<[],
 254                              [llvm_anyptr_ty, llvm_anyptr_ty, llvm_anyint_ty,
 255                               llvm_i32_ty, llvm_i1_ty],
 256                             [IntrReadWriteArgMem, NoCapture<0>, NoCapture<1>]>;
 257 def int_memmove : Intrinsic<[],
 258                             [llvm_anyptr_ty, llvm_anyptr_ty, llvm_anyint_ty,
 259                              llvm_i32_ty, llvm_i1_ty],
 260                             [IntrReadWriteArgMem, NoCapture<0>, NoCapture<1>]>;
 261 def int_memset  : Intrinsic<[],
 262                             [llvm_anyptr_ty, llvm_i8_ty, llvm_anyint_ty,
 263                              llvm_i32_ty, llvm_i1_ty],
 264                             [IntrReadWriteArgMem, NoCapture<0>]>;
 265
 266 // These functions do not actually read memory, but they are sensitive to the
 267 // rounding mode.  This needs to be modelled separately; in the meantime
 268 // declaring them as reading memory is conservatively correct.
 269 let Properties = [IntrReadMem] in {
 270   def int_sqrt : Intrinsic<[llvm_anyfloat_ty], [LLVMMatchType<0>]>;
 271   def int_powi : Intrinsic<[llvm_anyfloat_ty], [LLVMMatchType<0>, llvm_i32_ty]>;
 272   def int_sin  : Intrinsic<[llvm_anyfloat_ty], [LLVMMatchType<0>]>;
 273   def int_cos  : Intrinsic<[llvm_anyfloat_ty], [LLVMMatchType<0>]>;
 274   def int_pow  : Intrinsic<[llvm_anyfloat_ty],
 275                            [LLVMMatchType<0>, LLVMMatchType<0>]>;
 276   def int_log  : Intrinsic<[llvm_anyfloat_ty], [LLVMMatchType<0>]>;
 277   def int_log10: Intrinsic<[llvm_anyfloat_ty], [LLVMMatchType<0>]>;
 278   def int_log2 : Intrinsic<[llvm_anyfloat_ty], [LLVMMatchType<0>]>;
 279   def int_exp  : Intrinsic<[llvm_anyfloat_ty], [LLVMMatchType<0>]>;
 280   def int_exp2 : Intrinsic<[llvm_anyfloat_ty], [LLVMMatchType<0>]>;
 281   def int_fabs : Intrinsic<[llvm_anyfloat_ty], [LLVMMatchType<0>]>;
 282   def int_floor : Intrinsic<[llvm_anyfloat_ty], [LLVMMatchType<0>]>;
 283   def int_ceil  : Intrinsic<[llvm_anyfloat_ty], [LLVMMatchType<0>]>;
 284   def int_trunc : Intrinsic<[llvm_anyfloat_ty], [LLVMMatchType<0>]>;
 285   def int_rint  : Intrinsic<[llvm_anyfloat_ty], [LLVMMatchType<0>]>;
 286   def int_nearbyint : Intrinsic<[llvm_anyfloat_ty], [LLVMMatchType<0>]>;
 287 }
 288
 289 let Properties = [IntrNoMem] in {
 290   def int_fma  : Intrinsic<[llvm_anyfloat_ty],
 291                          [LLVMMatchType<0>, LLVMMatchType<0>,
 292                           LLVMMatchType<0>]>;
 293
 294   def int_fmuladd : Intrinsic<[llvm_anyfloat_ty],
 295                               [LLVMMatchType<0>, LLVMMatchType<0>,
 296                                LLVMMatchType<0>]>;
 297 }
 298
 299 // NOTE: these are internal interfaces.
 300 def int_setjmp     : Intrinsic<[llvm_i32_ty],  [llvm_ptr_ty]>;
 301 def int_longjmp    : Intrinsic<[], [llvm_ptr_ty, llvm_i32_ty], [IntrNoReturn]>;
 302 def int_sigsetjmp  : Intrinsic<[llvm_i32_ty] , [llvm_ptr_ty, llvm_i32_ty]>;
 303 def int_siglongjmp : Intrinsic<[], [llvm_ptr_ty, llvm_i32_ty], [IntrNoReturn]>;
 304
 305 // Internal interface for object size checking
 306 def int_objectsize : Intrinsic<[llvm_anyint_ty], [llvm_ptr_ty, llvm_i1_ty],
 307                                [IntrNoMem]>,
 308                                GCCBuiltin<"__builtin_object_size">;
 309
 310 //===------------------------- Expect Intrinsics --------------------------===//
 311 //
 312 def int_expect : Intrinsic<[llvm_anyint_ty], [LLVMMatchType<0>,
 313                                               LLVMMatchType<0>], [IntrNoMem]>;
 314
 315 //===-------------------- Bit Manipulation Intrinsics ---------------------===//
 316 //
 317
 318 // None of these intrinsics accesses memory at all.
 319 let Properties = [IntrNoMem] in {
 320   def int_bswap: Intrinsic<[llvm_anyint_ty], [LLVMMatchType<0>]>;
 321   def int_ctpop: Intrinsic<[llvm_anyint_ty], [LLVMMatchType<0>]>;
 322   def int_ctlz : Intrinsic<[llvm_anyint_ty], [LLVMMatchType<0>, llvm_i1_ty]>;
 323   def int_cttz : Intrinsic<[llvm_anyint_ty], [LLVMMatchType<0>, llvm_i1_ty]>;
 324 }
 325
 326 //===------------------------ Debugger Intrinsics -------------------------===//
 327 //
 328
 329 // None of these intrinsics accesses memory at all...but that doesn't mean the
 330 // optimizers can change them aggressively.  Special handling needed in a few
 331 // places.
 332 let Properties = [IntrNoMem] in {
 333   def int_dbg_declare      : Intrinsic<[],
 334                                        [llvm_metadata_ty, llvm_metadata_ty]>;
 335   def int_dbg_value        : Intrinsic<[],
 336                                        [llvm_metadata_ty, llvm_i64_ty,
 337                                         llvm_metadata_ty]>;
 338 }
 339
 340 //===------------------ Exception Handling Intrinsics----------------------===//
 341 //
 342
 343 // The result of eh.typeid.for depends on the enclosing function, but inside a
 344 // given function it is 'const' and may be CSE'd etc.
 345 def int_eh_typeid_for : Intrinsic<[llvm_i32_ty], [llvm_ptr_ty], [IntrNoMem]>;
 346
 347 def int_eh_return_i32 : Intrinsic<[], [llvm_i32_ty, llvm_ptr_ty]>;
 348 def int_eh_return_i64 : Intrinsic<[], [llvm_i64_ty, llvm_ptr_ty]>;
 349
 350 // __builtin_unwind_init is an undocumented GCC intrinsic that causes all
 351 // callee-saved registers to be saved and restored (regardless of whether they
 352 // are used) in the calling function. It is used by libgcc_eh.
 353 def int_eh_unwind_init: Intrinsic<[]>,
 354                         GCCBuiltin<"__builtin_unwind_init">;
 355
 356 def int_eh_dwarf_cfa  : Intrinsic<[llvm_ptr_ty], [llvm_i32_ty]>;
 357
 358 let Properties = [IntrNoMem] in {
 359   def int_eh_sjlj_lsda             : Intrinsic<[llvm_ptr_ty]>;
 360   def int_eh_sjlj_callsite         : Intrinsic<[], [llvm_i32_ty]>;
 361 }
 362 def int_eh_sjlj_functioncontext : Intrinsic<[], [llvm_ptr_ty]>;
 363 def int_eh_sjlj_setjmp          : Intrinsic<[llvm_i32_ty], [llvm_ptr_ty]>;
 364 def int_eh_sjlj_longjmp         : Intrinsic<[], [llvm_ptr_ty], [IntrNoReturn]>;
 365
 366 //===---------------- Generic Variable Attribute Intrinsics----------------===//
 367 //
 368 def int_var_annotation : Intrinsic<[],
 369                                    [llvm_ptr_ty, llvm_ptr_ty,
 370                                     llvm_ptr_ty, llvm_i32_ty],
 371                                    [], "llvm.var.annotation">;
 372 def int_ptr_annotation : Intrinsic<[LLVMAnyPointerType<llvm_anyint_ty>],
 373                                    [LLVMMatchType<0>, llvm_ptr_ty, llvm_ptr_ty,
 374                                     llvm_i32_ty],
 375                                    [], "llvm.ptr.annotation">;
 376 def int_annotation : Intrinsic<[llvm_anyint_ty],
 377                                [LLVMMatchType<0>, llvm_ptr_ty,
 378                                 llvm_ptr_ty, llvm_i32_ty],
 379                                [], "llvm.annotation">;
 380
 381 //===------------------------ Trampoline Intrinsics -----------------------===//
 382 //
 383 def int_init_trampoline : Intrinsic<[],
 384                                     [llvm_ptr_ty, llvm_ptr_ty, llvm_ptr_ty],
 385                                     [IntrReadWriteArgMem, NoCapture<0>]>,
 386                                    GCCBuiltin<"__builtin_init_trampoline">;
 387
 388 def int_adjust_trampoline : Intrinsic<[llvm_ptr_ty], [llvm_ptr_ty],
 389                                       [IntrReadArgMem]>,
 390                                      GCCBuiltin<"__builtin_adjust_trampoline">;
 391
 392 //===------------------------ Overflow Intrinsics -------------------------===//
 393 //
 394
 395 // Expose the carry flag from add operations on two integrals.
 396 def int_sadd_with_overflow : Intrinsic<[llvm_anyint_ty, llvm_i1_ty],
 397                                        [LLVMMatchType<0>, LLVMMatchType<0>],
 398                                        [IntrNoMem]>;
 399 def int_uadd_with_overflow : Intrinsic<[llvm_anyint_ty, llvm_i1_ty],
 400                                        [LLVMMatchType<0>, LLVMMatchType<0>],
 401                                        [IntrNoMem]>;
 402
 403 def int_ssub_with_overflow : Intrinsic<[llvm_anyint_ty, llvm_i1_ty],
 404                                        [LLVMMatchType<0>, LLVMMatchType<0>],
 405                                        [IntrNoMem]>;
 406 def int_usub_with_overflow : Intrinsic<[llvm_anyint_ty, llvm_i1_ty],
 407                                        [LLVMMatchType<0>, LLVMMatchType<0>],
 408                                        [IntrNoMem]>;
 409
 410 def int_smul_with_overflow : Intrinsic<[llvm_anyint_ty, llvm_i1_ty],
 411                                        [LLVMMatchType<0>, LLVMMatchType<0>],
 412                                        [IntrNoMem]>;
 413 def int_umul_with_overflow : Intrinsic<[llvm_anyint_ty, llvm_i1_ty],
 414                                        [LLVMMatchType<0>, LLVMMatchType<0>],
 415                                        [IntrNoMem]>;
 416
 417 //===------------------------- Memory Use Markers -------------------------===//
 418 //
 419 def int_lifetime_start  : Intrinsic<[],
 420                                     [llvm_i64_ty, llvm_ptr_ty],
 421                                     [IntrReadWriteArgMem, NoCapture<1>]>;
 422 def int_lifetime_end    : Intrinsic<[],
 423                                     [llvm_i64_ty, llvm_ptr_ty],
 424                                     [IntrReadWriteArgMem, NoCapture<1>]>;
 425 def int_invariant_start : Intrinsic<[llvm_descriptor_ty],
 426                                     [llvm_i64_ty, llvm_ptr_ty],
 427                                     [IntrReadWriteArgMem, NoCapture<1>]>;
 428 def int_invariant_end   : Intrinsic<[],
 429                                     [llvm_descriptor_ty, llvm_i64_ty,
 430                                      llvm_ptr_ty],
 431                                     [IntrReadWriteArgMem, NoCapture<2>]>;
 432
 433 //===-------------------------- Other Intrinsics --------------------------===//
 434 //
 435 def int_flt_rounds : Intrinsic<[llvm_i32_ty]>,
 436                      GCCBuiltin<"__builtin_flt_rounds">;
 437 def int_trap : Intrinsic<[], [], [IntrNoReturn]>,
 438                GCCBuiltin<"__builtin_trap">;
 439 def int_debugtrap : Intrinsic<[]>,
 440                     GCCBuiltin<"__builtin_debugtrap">;
 441
 442 // NOP: calls/invokes to this intrinsic are removed by codegen
 443 def int_donothing : Intrinsic<[], [], [IntrNoMem]>;
 444
 445 // Intrisics to support half precision floating point format
 446 let Properties = [IntrNoMem] in {
 447 def int_convert_to_fp16   : Intrinsic<[llvm_i16_ty], [llvm_float_ty]>,
 448                             GCCBuiltin<"__gnu_f2h_ieee">;
 449 def int_convert_from_fp16 : Intrinsic<[llvm_float_ty], [llvm_i16_ty]>,
 450                             GCCBuiltin<"__gnu_h2f_ieee">;
 451 }
 452
 453 // These convert intrinsics are to support various conversions between
 454 // various types with rounding and saturation. NOTE: avoid using these
 455 // intrinsics as they might be removed sometime in the future and
 456 // most targets don't support them.
 457 def int_convertff  : Intrinsic<[llvm_anyfloat_ty],
 458                                [llvm_anyfloat_ty, llvm_i32_ty, llvm_i32_ty]>;
 459 def int_convertfsi : Intrinsic<[llvm_anyfloat_ty],
 460                                [llvm_anyint_ty, llvm_i32_ty, llvm_i32_ty]>;
 461 def int_convertfui : Intrinsic<[llvm_anyfloat_ty],
 462                                [llvm_anyint_ty, llvm_i32_ty, llvm_i32_ty]>;
 463 def int_convertsif : Intrinsic<[llvm_anyint_ty],
 464                                [llvm_anyfloat_ty, llvm_i32_ty, llvm_i32_ty]>;
 465 def int_convertuif : Intrinsic<[llvm_anyint_ty],
 466                                [llvm_anyfloat_ty, llvm_i32_ty, llvm_i32_ty]>;
 467 def int_convertss  : Intrinsic<[llvm_anyint_ty],
 468                                [llvm_anyint_ty, llvm_i32_ty, llvm_i32_ty]>;
 469 def int_convertsu  : Intrinsic<[llvm_anyint_ty],
 470                                [llvm_anyint_ty, llvm_i32_ty, llvm_i32_ty]>;
 471 def int_convertus  : Intrinsic<[llvm_anyint_ty],
 472                                [llvm_anyint_ty, llvm_i32_ty, llvm_i32_ty]>;
 473 def int_convertuu  : Intrinsic<[llvm_anyint_ty],
 474                                [llvm_anyint_ty, llvm_i32_ty, llvm_i32_ty]>;
 475
 476 //===----------------------------------------------------------------------===//
 477 // Target-specific intrinsics
 478 //===----------------------------------------------------------------------===//
 479
 480 include "llvm/IR/IntrinsicsPowerPC.td"
 481 include "llvm/IR/IntrinsicsX86.td"
 482 include "llvm/IR/IntrinsicsARM.td"
 483 include "llvm/IR/IntrinsicsXCore.td"
 484 include "llvm/IR/IntrinsicsHexagon.td"
 485 include "llvm/IR/IntrinsicsNVVM.td"
 486 include "llvm/IR/IntrinsicsMips.td"
 487 include "llvm/IR/IntrinsicsR600.td"