08874bfbd68c46fd372b6362751f4374b5ebb5cc
[oota-llvm.git] / docs / LangRef.rst
1 ==============================
2 LLVM Language Reference Manual
3 ==============================
4
5 .. contents::
6    :local:
7    :depth: 3
8
9 Abstract
10 ========
11
12 This document is a reference manual for the LLVM assembly language. LLVM
13 is a Static Single Assignment (SSA) based representation that provides
14 type safety, low-level operations, flexibility, and the capability of
15 representing 'all' high-level languages cleanly. It is the common code
16 representation used throughout all phases of the LLVM compilation
17 strategy.
18
19 Introduction
20 ============
21
22 The LLVM code representation is designed to be used in three different
23 forms: as an in-memory compiler IR, as an on-disk bitcode representation
24 (suitable for fast loading by a Just-In-Time compiler), and as a human
25 readable assembly language representation. This allows LLVM to provide a
26 powerful intermediate representation for efficient compiler
27 transformations and analysis, while providing a natural means to debug
28 and visualize the transformations. The three different forms of LLVM are
29 all equivalent. This document describes the human readable
30 representation and notation.
31
32 The LLVM representation aims to be light-weight and low-level while
33 being expressive, typed, and extensible at the same time. It aims to be
34 a "universal IR" of sorts, by being at a low enough level that
35 high-level ideas may be cleanly mapped to it (similar to how
36 microprocessors are "universal IR's", allowing many source languages to
37 be mapped to them). By providing type information, LLVM can be used as
38 the target of optimizations: for example, through pointer analysis, it
39 can be proven that a C automatic variable is never accessed outside of
40 the current function, allowing it to be promoted to a simple SSA value
41 instead of a memory location.
42
43 .. _wellformed:
44
45 Well-Formedness
46 ---------------
47
48 It is important to note that this document describes 'well formed' LLVM
49 assembly language. There is a difference between what the parser accepts
50 and what is considered 'well formed'. For example, the following
51 instruction is syntactically okay, but not well formed:
52
53 .. code-block:: llvm
54
55     %x = add i32 1, %x
56
57 because the definition of ``%x`` does not dominate all of its uses. The
58 LLVM infrastructure provides a verification pass that may be used to
59 verify that an LLVM module is well formed. This pass is automatically
60 run by the parser after parsing input assembly and by the optimizer
61 before it outputs bitcode. The violations pointed out by the verifier
62 pass indicate bugs in transformation passes or input to the parser.
63
64 .. _identifiers:
65
66 Identifiers
67 ===========
68
69 LLVM identifiers come in two basic types: global and local. Global
70 identifiers (functions, global variables) begin with the ``'@'``
71 character. Local identifiers (register names, types) begin with the
72 ``'%'`` character. Additionally, there are three different formats for
73 identifiers, for different purposes:
74
75 #. Named values are represented as a string of characters with their
76    prefix. For example, ``%foo``, ``@DivisionByZero``,
77    ``%a.really.long.identifier``. The actual regular expression used is
78    '``[%@][a-zA-Z$._][a-zA-Z$._0-9]*``'. Identifiers which require other
79    characters in their names can be surrounded with quotes. Special
80    characters may be escaped using ``"\xx"`` where ``xx`` is the ASCII
81    code for the character in hexadecimal. In this way, any character can
82    be used in a name value, even quotes themselves.
83 #. Unnamed values are represented as an unsigned numeric value with
84    their prefix. For example, ``%12``, ``@2``, ``%44``.
85 #. Constants, which are described in the section  Constants_ below.
86
87 LLVM requires that values start with a prefix for two reasons: Compilers
88 don't need to worry about name clashes with reserved words, and the set
89 of reserved words may be expanded in the future without penalty.
90 Additionally, unnamed identifiers allow a compiler to quickly come up
91 with a temporary variable without having to avoid symbol table
92 conflicts.
93
94 Reserved words in LLVM are very similar to reserved words in other
95 languages. There are keywords for different opcodes ('``add``',
96 '``bitcast``', '``ret``', etc...), for primitive type names ('``void``',
97 '``i32``', etc...), and others. These reserved words cannot conflict
98 with variable names, because none of them start with a prefix character
99 (``'%'`` or ``'@'``).
100
101 Here is an example of LLVM code to multiply the integer variable
102 '``%X``' by 8:
103
104 The easy way:
105
106 .. code-block:: llvm
107
108     %result = mul i32 %X, 8
109
110 After strength reduction:
111
112 .. code-block:: llvm
113
114     %result = shl i32 %X, 3
115
116 And the hard way:
117
118 .. code-block:: llvm
119
120     %0 = add i32 %X, %X           ; yields {i32}:%0
121     %1 = add i32 %0, %0           ; yields {i32}:%1
122     %result = add i32 %1, %1
123
124 This last way of multiplying ``%X`` by 8 illustrates several important
125 lexical features of LLVM:
126
127 #. Comments are delimited with a '``;``' and go until the end of line.
128 #. Unnamed temporaries are created when the result of a computation is
129    not assigned to a named value.
130 #. Unnamed temporaries are numbered sequentially (using a per-function
131    incrementing counter, starting with 0).
132
133 It also shows a convention that we follow in this document. When
134 demonstrating instructions, we will follow an instruction with a comment
135 that defines the type and name of value produced.
136
137 High Level Structure
138 ====================
139
140 Module Structure
141 ----------------
142
143 LLVM programs are composed of ``Module``'s, each of which is a
144 translation unit of the input programs. Each module consists of
145 functions, global variables, and symbol table entries. Modules may be
146 combined together with the LLVM linker, which merges function (and
147 global variable) definitions, resolves forward declarations, and merges
148 symbol table entries. Here is an example of the "hello world" module:
149
150 .. code-block:: llvm
151
152     ; Declare the string constant as a global constant.
153     @.str = private unnamed_addr constant [13 x i8] c"hello world\0A\00"
154
155     ; External declaration of the puts function
156     declare i32 @puts(i8* nocapture) nounwind
157
158     ; Definition of main function
159     define i32 @main() {   ; i32()*
160       ; Convert [13 x i8]* to i8  *...
161       %cast210 = getelementptr [13 x i8]* @.str, i64 0, i64 0
162
163       ; Call puts function to write out the string to stdout.
164       call i32 @puts(i8* %cast210)
165       ret i32 0
166     }
167
168     ; Named metadata
169     !1 = metadata !{i32 42}
170     !foo = !{!1, null}
171
172 This example is made up of a :ref:`global variable <globalvars>` named
173 "``.str``", an external declaration of the "``puts``" function, a
174 :ref:`function definition <functionstructure>` for "``main``" and
175 :ref:`named metadata <namedmetadatastructure>` "``foo``".
176
177 In general, a module is made up of a list of global values (where both
178 functions and global variables are global values). Global values are
179 represented by a pointer to a memory location (in this case, a pointer
180 to an array of char, and a pointer to a function), and have one of the
181 following :ref:`linkage types <linkage>`.
182
183 .. _linkage:
184
185 Linkage Types
186 -------------
187
188 All Global Variables and Functions have one of the following types of
189 linkage:
190
191 ``private``
192     Global values with "``private``" linkage are only directly
193     accessible by objects in the current module. In particular, linking
194     code into a module with an private global value may cause the
195     private to be renamed as necessary to avoid collisions. Because the
196     symbol is private to the module, all references can be updated. This
197     doesn't show up in any symbol table in the object file.
198 ``linker_private``
199     Similar to ``private``, but the symbol is passed through the
200     assembler and evaluated by the linker. Unlike normal strong symbols,
201     they are removed by the linker from the final linked image
202     (executable or dynamic library).
203 ``linker_private_weak``
204     Similar to "``linker_private``", but the symbol is weak. Note that
205     ``linker_private_weak`` symbols are subject to coalescing by the
206     linker. The symbols are removed by the linker from the final linked
207     image (executable or dynamic library).
208 ``internal``
209     Similar to private, but the value shows as a local symbol
210     (``STB_LOCAL`` in the case of ELF) in the object file. This
211     corresponds to the notion of the '``static``' keyword in C.
212 ``available_externally``
213     Globals with "``available_externally``" linkage are never emitted
214     into the object file corresponding to the LLVM module. They exist to
215     allow inlining and other optimizations to take place given knowledge
216     of the definition of the global, which is known to be somewhere
217     outside the module. Globals with ``available_externally`` linkage
218     are allowed to be discarded at will, and are otherwise the same as
219     ``linkonce_odr``. This linkage type is only allowed on definitions,
220     not declarations.
221 ``linkonce``
222     Globals with "``linkonce``" linkage are merged with other globals of
223     the same name when linkage occurs. This can be used to implement
224     some forms of inline functions, templates, or other code which must
225     be generated in each translation unit that uses it, but where the
226     body may be overridden with a more definitive definition later.
227     Unreferenced ``linkonce`` globals are allowed to be discarded. Note
228     that ``linkonce`` linkage does not actually allow the optimizer to
229     inline the body of this function into callers because it doesn't
230     know if this definition of the function is the definitive definition
231     within the program or whether it will be overridden by a stronger
232     definition. To enable inlining and other optimizations, use
233     "``linkonce_odr``" linkage.
234 ``weak``
235     "``weak``" linkage has the same merging semantics as ``linkonce``
236     linkage, except that unreferenced globals with ``weak`` linkage may
237     not be discarded. This is used for globals that are declared "weak"
238     in C source code.
239 ``common``
240     "``common``" linkage is most similar to "``weak``" linkage, but they
241     are used for tentative definitions in C, such as "``int X;``" at
242     global scope. Symbols with "``common``" linkage are merged in the
243     same way as ``weak symbols``, and they may not be deleted if
244     unreferenced. ``common`` symbols may not have an explicit section,
245     must have a zero initializer, and may not be marked
246     ':ref:`constant <globalvars>`'. Functions and aliases may not have
247     common linkage.
248
249 .. _linkage_appending:
250
251 ``appending``
252     "``appending``" linkage may only be applied to global variables of
253     pointer to array type. When two global variables with appending
254     linkage are linked together, the two global arrays are appended
255     together. This is the LLVM, typesafe, equivalent of having the
256     system linker append together "sections" with identical names when
257     .o files are linked.
258 ``extern_weak``
259     The semantics of this linkage follow the ELF object file model: the
260     symbol is weak until linked, if not linked, the symbol becomes null
261     instead of being an undefined reference.
262 ``linkonce_odr``, ``weak_odr``
263     Some languages allow differing globals to be merged, such as two
264     functions with different semantics. Other languages, such as
265     ``C++``, ensure that only equivalent globals are ever merged (the
266     "one definition rule" --- "ODR").  Such languages can use the
267     ``linkonce_odr`` and ``weak_odr`` linkage types to indicate that the
268     global will only be merged with equivalent globals. These linkage
269     types are otherwise the same as their non-``odr`` versions.
270 ``linkonce_odr_auto_hide``
271     Similar to "``linkonce_odr``", but nothing in the translation unit
272     takes the address of this definition. For instance, functions that
273     had an inline definition, but the compiler decided not to inline it.
274     ``linkonce_odr_auto_hide`` may have only ``default`` visibility. The
275     symbols are removed by the linker from the final linked image
276     (executable or dynamic library).
277 ``external``
278     If none of the above identifiers are used, the global is externally
279     visible, meaning that it participates in linkage and can be used to
280     resolve external symbol references.
281
282 The next two types of linkage are targeted for Microsoft Windows
283 platform only. They are designed to support importing (exporting)
284 symbols from (to) DLLs (Dynamic Link Libraries).
285
286 ``dllimport``
287     "``dllimport``" linkage causes the compiler to reference a function
288     or variable via a global pointer to a pointer that is set up by the
289     DLL exporting the symbol. On Microsoft Windows targets, the pointer
290     name is formed by combining ``__imp_`` and the function or variable
291     name.
292 ``dllexport``
293     "``dllexport``" linkage causes the compiler to provide a global
294     pointer to a pointer in a DLL, so that it can be referenced with the
295     ``dllimport`` attribute. On Microsoft Windows targets, the pointer
296     name is formed by combining ``__imp_`` and the function or variable
297     name.
298
299 For example, since the "``.LC0``" variable is defined to be internal, if
300 another module defined a "``.LC0``" variable and was linked with this
301 one, one of the two would be renamed, preventing a collision. Since
302 "``main``" and "``puts``" are external (i.e., lacking any linkage
303 declarations), they are accessible outside of the current module.
304
305 It is illegal for a function *declaration* to have any linkage type
306 other than ``external``, ``dllimport`` or ``extern_weak``.
307
308 Aliases can have only ``external``, ``internal``, ``weak`` or
309 ``weak_odr`` linkages.
310
311 .. _callingconv:
312
313 Calling Conventions
314 -------------------
315
316 LLVM :ref:`functions <functionstructure>`, :ref:`calls <i_call>` and
317 :ref:`invokes <i_invoke>` can all have an optional calling convention
318 specified for the call. The calling convention of any pair of dynamic
319 caller/callee must match, or the behavior of the program is undefined.
320 The following calling conventions are supported by LLVM, and more may be
321 added in the future:
322
323 "``ccc``" - The C calling convention
324     This calling convention (the default if no other calling convention
325     is specified) matches the target C calling conventions. This calling
326     convention supports varargs function calls and tolerates some
327     mismatch in the declared prototype and implemented declaration of
328     the function (as does normal C).
329 "``fastcc``" - The fast calling convention
330     This calling convention attempts to make calls as fast as possible
331     (e.g. by passing things in registers). This calling convention
332     allows the target to use whatever tricks it wants to produce fast
333     code for the target, without having to conform to an externally
334     specified ABI (Application Binary Interface). `Tail calls can only
335     be optimized when this, the GHC or the HiPE convention is
336     used. <CodeGenerator.html#id80>`_ This calling convention does not
337     support varargs and requires the prototype of all callees to exactly
338     match the prototype of the function definition.
339 "``coldcc``" - The cold calling convention
340     This calling convention attempts to make code in the caller as
341     efficient as possible under the assumption that the call is not
342     commonly executed. As such, these calls often preserve all registers
343     so that the call does not break any live ranges in the caller side.
344     This calling convention does not support varargs and requires the
345     prototype of all callees to exactly match the prototype of the
346     function definition.
347 "``cc 10``" - GHC convention
348     This calling convention has been implemented specifically for use by
349     the `Glasgow Haskell Compiler (GHC) <http://www.haskell.org/ghc>`_.
350     It passes everything in registers, going to extremes to achieve this
351     by disabling callee save registers. This calling convention should
352     not be used lightly but only for specific situations such as an
353     alternative to the *register pinning* performance technique often
354     used when implementing functional programming languages. At the
355     moment only X86 supports this convention and it has the following
356     limitations:
357
358     -  On *X86-32* only supports up to 4 bit type parameters. No
359        floating point types are supported.
360     -  On *X86-64* only supports up to 10 bit type parameters and 6
361        floating point parameters.
362
363     This calling convention supports `tail call
364     optimization <CodeGenerator.html#id80>`_ but requires both the
365     caller and callee are using it.
366 "``cc 11``" - The HiPE calling convention
367     This calling convention has been implemented specifically for use by
368     the `High-Performance Erlang
369     (HiPE) <http://www.it.uu.se/research/group/hipe/>`_ compiler, *the*
370     native code compiler of the `Ericsson's Open Source Erlang/OTP
371     system <http://www.erlang.org/download.shtml>`_. It uses more
372     registers for argument passing than the ordinary C calling
373     convention and defines no callee-saved registers. The calling
374     convention properly supports `tail call
375     optimization <CodeGenerator.html#id80>`_ but requires that both the
376     caller and the callee use it. It uses a *register pinning*
377     mechanism, similar to GHC's convention, for keeping frequently
378     accessed runtime components pinned to specific hardware registers.
379     At the moment only X86 supports this convention (both 32 and 64
380     bit).
381 "``cc <n>``" - Numbered convention
382     Any calling convention may be specified by number, allowing
383     target-specific calling conventions to be used. Target specific
384     calling conventions start at 64.
385
386 More calling conventions can be added/defined on an as-needed basis, to
387 support Pascal conventions or any other well-known target-independent
388 convention.
389
390 .. _visibilitystyles:
391
392 Visibility Styles
393 -----------------
394
395 All Global Variables and Functions have one of the following visibility
396 styles:
397
398 "``default``" - Default style
399     On targets that use the ELF object file format, default visibility
400     means that the declaration is visible to other modules and, in
401     shared libraries, means that the declared entity may be overridden.
402     On Darwin, default visibility means that the declaration is visible
403     to other modules. Default visibility corresponds to "external
404     linkage" in the language.
405 "``hidden``" - Hidden style
406     Two declarations of an object with hidden visibility refer to the
407     same object if they are in the same shared object. Usually, hidden
408     visibility indicates that the symbol will not be placed into the
409     dynamic symbol table, so no other module (executable or shared
410     library) can reference it directly.
411 "``protected``" - Protected style
412     On ELF, protected visibility indicates that the symbol will be
413     placed in the dynamic symbol table, but that references within the
414     defining module will bind to the local symbol. That is, the symbol
415     cannot be overridden by another module.
416
417 .. _namedtypes:
418
419 Named Types
420 -----------
421
422 LLVM IR allows you to specify name aliases for certain types. This can
423 make it easier to read the IR and make the IR more condensed
424 (particularly when recursive types are involved). An example of a name
425 specification is:
426
427 .. code-block:: llvm
428
429     %mytype = type { %mytype*, i32 }
430
431 You may give a name to any :ref:`type <typesystem>` except
432 ":ref:`void <t_void>`". Type name aliases may be used anywhere a type is
433 expected with the syntax "%mytype".
434
435 Note that type names are aliases for the structural type that they
436 indicate, and that you can therefore specify multiple names for the same
437 type. This often leads to confusing behavior when dumping out a .ll
438 file. Since LLVM IR uses structural typing, the name is not part of the
439 type. When printing out LLVM IR, the printer will pick *one name* to
440 render all types of a particular shape. This means that if you have code
441 where two different source types end up having the same LLVM type, that
442 the dumper will sometimes print the "wrong" or unexpected type. This is
443 an important design point and isn't going to change.
444
445 .. _globalvars:
446
447 Global Variables
448 ----------------
449
450 Global variables define regions of memory allocated at compilation time
451 instead of run-time. Global variables may optionally be initialized, may
452 have an explicit section to be placed in, and may have an optional
453 explicit alignment specified.
454
455 A variable may be defined as ``thread_local``, which means that it will
456 not be shared by threads (each thread will have a separated copy of the
457 variable). Not all targets support thread-local variables. Optionally, a
458 TLS model may be specified:
459
460 ``localdynamic``
461     For variables that are only used within the current shared library.
462 ``initialexec``
463     For variables in modules that will not be loaded dynamically.
464 ``localexec``
465     For variables defined in the executable and only used within it.
466
467 The models correspond to the ELF TLS models; see `ELF Handling For
468 Thread-Local Storage <http://people.redhat.com/drepper/tls.pdf>`_ for
469 more information on under which circumstances the different models may
470 be used. The target may choose a different TLS model if the specified
471 model is not supported, or if a better choice of model can be made.
472
473 A variable may be defined as a global ``constant``, which indicates that
474 the contents of the variable will **never** be modified (enabling better
475 optimization, allowing the global data to be placed in the read-only
476 section of an executable, etc). Note that variables that need runtime
477 initialization cannot be marked ``constant`` as there is a store to the
478 variable.
479
480 LLVM explicitly allows *declarations* of global variables to be marked
481 constant, even if the final definition of the global is not. This
482 capability can be used to enable slightly better optimization of the
483 program, but requires the language definition to guarantee that
484 optimizations based on the 'constantness' are valid for the translation
485 units that do not include the definition.
486
487 As SSA values, global variables define pointer values that are in scope
488 (i.e. they dominate) all basic blocks in the program. Global variables
489 always define a pointer to their "content" type because they describe a
490 region of memory, and all memory objects in LLVM are accessed through
491 pointers.
492
493 Global variables can be marked with ``unnamed_addr`` which indicates
494 that the address is not significant, only the content. Constants marked
495 like this can be merged with other constants if they have the same
496 initializer. Note that a constant with significant address *can* be
497 merged with a ``unnamed_addr`` constant, the result being a constant
498 whose address is significant.
499
500 A global variable may be declared to reside in a target-specific
501 numbered address space. For targets that support them, address spaces
502 may affect how optimizations are performed and/or what target
503 instructions are used to access the variable. The default address space
504 is zero. The address space qualifier must precede any other attributes.
505
506 LLVM allows an explicit section to be specified for globals. If the
507 target supports it, it will emit globals to the section specified.
508
509 By default, global initializers are optimized by assuming that global
510 variables defined within the module are not modified from their
511 initial values before the start of the global initializer.  This is
512 true even for variables potentially accessible from outside the
513 module, including those with external linkage or appearing in
514 ``@llvm.used``. This assumption may be suppressed by marking the
515 variable with ``externally_initialized``.
516
517 An explicit alignment may be specified for a global, which must be a
518 power of 2. If not present, or if the alignment is set to zero, the
519 alignment of the global is set by the target to whatever it feels
520 convenient. If an explicit alignment is specified, the global is forced
521 to have exactly that alignment. Targets and optimizers are not allowed
522 to over-align the global if the global has an assigned section. In this
523 case, the extra alignment could be observable: for example, code could
524 assume that the globals are densely packed in their section and try to
525 iterate over them as an array, alignment padding would break this
526 iteration.
527
528 For example, the following defines a global in a numbered address space
529 with an initializer, section, and alignment:
530
531 .. code-block:: llvm
532
533     @G = addrspace(5) constant float 1.0, section "foo", align 4
534
535 The following example defines a thread-local global with the
536 ``initialexec`` TLS model:
537
538 .. code-block:: llvm
539
540     @G = thread_local(initialexec) global i32 0, align 4
541
542 .. _functionstructure:
543
544 Functions
545 ---------
546
547 LLVM function definitions consist of the "``define``" keyword, an
548 optional :ref:`linkage type <linkage>`, an optional :ref:`visibility
549 style <visibility>`, an optional :ref:`calling convention <callingconv>`,
550 an optional ``unnamed_addr`` attribute, a return type, an optional
551 :ref:`parameter attribute <paramattrs>` for the return type, a function
552 name, a (possibly empty) argument list (each with optional :ref:`parameter
553 attributes <paramattrs>`), optional :ref:`function attributes <fnattrs>`,
554 an optional section, an optional alignment, an optional :ref:`garbage
555 collector name <gc>`, an optional :ref:`prefix <prefixdata>`, an opening
556 curly brace, a list of basic blocks, and a closing curly brace.
557
558 LLVM function declarations consist of the "``declare``" keyword, an
559 optional :ref:`linkage type <linkage>`, an optional :ref:`visibility
560 style <visibility>`, an optional :ref:`calling convention <callingconv>`,
561 an optional ``unnamed_addr`` attribute, a return type, an optional
562 :ref:`parameter attribute <paramattrs>` for the return type, a function
563 name, a possibly empty list of arguments, an optional alignment, an optional
564 :ref:`garbage collector name <gc>` and an optional :ref:`prefix <prefixdata>`.
565
566 A function definition contains a list of basic blocks, forming the CFG
567 (Control Flow Graph) for the function. Each basic block may optionally
568 start with a label (giving the basic block a symbol table entry),
569 contains a list of instructions, and ends with a
570 :ref:`terminator <terminators>` instruction (such as a branch or function
571 return). If explicit label is not provided, a block is assigned an
572 implicit numbered label, using a next value from the same counter as used
573 for unnamed temporaries (:ref:`see above<identifiers>`). For example, if a
574 function entry block does not have explicit label, it will be assigned
575 label "%0", then first unnamed temporary in that block will be "%1", etc.
576
577 The first basic block in a function is special in two ways: it is
578 immediately executed on entrance to the function, and it is not allowed
579 to have predecessor basic blocks (i.e. there can not be any branches to
580 the entry block of a function). Because the block can have no
581 predecessors, it also cannot have any :ref:`PHI nodes <i_phi>`.
582
583 LLVM allows an explicit section to be specified for functions. If the
584 target supports it, it will emit functions to the section specified.
585
586 An explicit alignment may be specified for a function. If not present,
587 or if the alignment is set to zero, the alignment of the function is set
588 by the target to whatever it feels convenient. If an explicit alignment
589 is specified, the function is forced to have at least that much
590 alignment. All alignments must be a power of 2.
591
592 If the ``unnamed_addr`` attribute is given, the address is know to not
593 be significant and two identical functions can be merged.
594
595 Syntax::
596
597     define [linkage] [visibility]
598            [cconv] [ret attrs]
599            <ResultType> @<FunctionName> ([argument list])
600            [fn Attrs] [section "name"] [align N]
601            [gc] [prefix Constant] { ... }
602
603 .. _langref_aliases:
604
605 Aliases
606 -------
607
608 Aliases act as "second name" for the aliasee value (which can be either
609 function, global variable, another alias or bitcast of global value).
610 Aliases may have an optional :ref:`linkage type <linkage>`, and an optional
611 :ref:`visibility style <visibility>`.
612
613 Syntax::
614
615     @<Name> = alias [Linkage] [Visibility] <AliaseeTy> @<Aliasee>
616
617 .. _namedmetadatastructure:
618
619 Named Metadata
620 --------------
621
622 Named metadata is a collection of metadata. :ref:`Metadata
623 nodes <metadata>` (but not metadata strings) are the only valid
624 operands for a named metadata.
625
626 Syntax::
627
628     ; Some unnamed metadata nodes, which are referenced by the named metadata.
629     !0 = metadata !{metadata !"zero"}
630     !1 = metadata !{metadata !"one"}
631     !2 = metadata !{metadata !"two"}
632     ; A named metadata.
633     !name = !{!0, !1, !2}
634
635 .. _paramattrs:
636
637 Parameter Attributes
638 --------------------
639
640 The return type and each parameter of a function type may have a set of
641 *parameter attributes* associated with them. Parameter attributes are
642 used to communicate additional information about the result or
643 parameters of a function. Parameter attributes are considered to be part
644 of the function, not of the function type, so functions with different
645 parameter attributes can have the same function type.
646
647 Parameter attributes are simple keywords that follow the type specified.
648 If multiple parameter attributes are needed, they are space separated.
649 For example:
650
651 .. code-block:: llvm
652
653     declare i32 @printf(i8* noalias nocapture, ...)
654     declare i32 @atoi(i8 zeroext)
655     declare signext i8 @returns_signed_char()
656
657 Note that any attributes for the function result (``nounwind``,
658 ``readonly``) come immediately after the argument list.
659
660 Currently, only the following parameter attributes are defined:
661
662 ``zeroext``
663     This indicates to the code generator that the parameter or return
664     value should be zero-extended to the extent required by the target's
665     ABI (which is usually 32-bits, but is 8-bits for a i1 on x86-64) by
666     the caller (for a parameter) or the callee (for a return value).
667 ``signext``
668     This indicates to the code generator that the parameter or return
669     value should be sign-extended to the extent required by the target's
670     ABI (which is usually 32-bits) by the caller (for a parameter) or
671     the callee (for a return value).
672 ``inreg``
673     This indicates that this parameter or return value should be treated
674     in a special target-dependent fashion during while emitting code for
675     a function call or return (usually, by putting it in a register as
676     opposed to memory, though some targets use it to distinguish between
677     two different kinds of registers). Use of this attribute is
678     target-specific.
679 ``byval``
680     This indicates that the pointer parameter should really be passed by
681     value to the function. The attribute implies that a hidden copy of
682     the pointee is made between the caller and the callee, so the callee
683     is unable to modify the value in the caller. This attribute is only
684     valid on LLVM pointer arguments. It is generally used to pass
685     structs and arrays by value, but is also valid on pointers to
686     scalars. The copy is considered to belong to the caller not the
687     callee (for example, ``readonly`` functions should not write to
688     ``byval`` parameters). This is not a valid attribute for return
689     values.
690
691     The byval attribute also supports specifying an alignment with the
692     align attribute. It indicates the alignment of the stack slot to
693     form and the known alignment of the pointer specified to the call
694     site. If the alignment is not specified, then the code generator
695     makes a target-specific assumption.
696
697 ``sret``
698     This indicates that the pointer parameter specifies the address of a
699     structure that is the return value of the function in the source
700     program. This pointer must be guaranteed by the caller to be valid:
701     loads and stores to the structure may be assumed by the callee
702     not to trap and to be properly aligned. This may only be applied to
703     the first parameter. This is not a valid attribute for return
704     values.
705 ``noalias``
706     This indicates that pointer values :ref:`based <pointeraliasing>` on
707     the argument or return value do not alias pointer values which are
708     not *based* on it, ignoring certain "irrelevant" dependencies. For a
709     call to the parent function, dependencies between memory references
710     from before or after the call and from those during the call are
711     "irrelevant" to the ``noalias`` keyword for the arguments and return
712     value used in that call. The caller shares the responsibility with
713     the callee for ensuring that these requirements are met. For further
714     details, please see the discussion of the NoAlias response in `alias
715     analysis <AliasAnalysis.html#MustMayNo>`_.
716
717     Note that this definition of ``noalias`` is intentionally similar
718     to the definition of ``restrict`` in C99 for function arguments,
719     though it is slightly weaker.
720
721     For function return values, C99's ``restrict`` is not meaningful,
722     while LLVM's ``noalias`` is.
723 ``nocapture``
724     This indicates that the callee does not make any copies of the
725     pointer that outlive the callee itself. This is not a valid
726     attribute for return values.
727
728 .. _nest:
729
730 ``nest``
731     This indicates that the pointer parameter can be excised using the
732     :ref:`trampoline intrinsics <int_trampoline>`. This is not a valid
733     attribute for return values and can only be applied to one parameter.
734
735 ``returned``
736     This indicates that the function always returns the argument as its return
737     value. This is an optimization hint to the code generator when generating
738     the caller, allowing tail call optimization and omission of register saves
739     and restores in some cases; it is not checked or enforced when generating
740     the callee. The parameter and the function return type must be valid
741     operands for the :ref:`bitcast instruction <i_bitcast>`. This is not a
742     valid attribute for return values and can only be applied to one parameter.
743
744 .. _gc:
745
746 Garbage Collector Names
747 -----------------------
748
749 Each function may specify a garbage collector name, which is simply a
750 string:
751
752 .. code-block:: llvm
753
754     define void @f() gc "name" { ... }
755
756 The compiler declares the supported values of *name*. Specifying a
757 collector which will cause the compiler to alter its output in order to
758 support the named garbage collection algorithm.
759
760 .. _prefixdata:
761
762 Prefix Data
763 -----------
764
765 Prefix data is data associated with a function which the code generator
766 will emit immediately before the function body.  The purpose of this feature
767 is to allow frontends to associate language-specific runtime metadata with
768 specific functions and make it available through the function pointer while
769 still allowing the function pointer to be called.  To access the data for a
770 given function, a program may bitcast the function pointer to a pointer to
771 the constant's type.  This implies that the IR symbol points to the start
772 of the prefix data.
773
774 To maintain the semantics of ordinary function calls, the prefix data must
775 have a particular format.  Specifically, it must begin with a sequence of
776 bytes which decode to a sequence of machine instructions, valid for the
777 module's target, which transfer control to the point immediately succeeding
778 the prefix data, without performing any other visible action.  This allows
779 the inliner and other passes to reason about the semantics of the function
780 definition without needing to reason about the prefix data.  Obviously this
781 makes the format of the prefix data highly target dependent.
782
783 A trivial example of valid prefix data for the x86 architecture is ``i8 144``,
784 which encodes the ``nop`` instruction:
785
786 .. code-block:: llvm
787
788     define void @f() prefix i8 144 { ... }
789
790 Generally prefix data can be formed by encoding a relative branch instruction
791 which skips the metadata, as in this example of valid prefix data for the
792 x86_64 architecture, where the first two bytes encode ``jmp .+10``:
793
794 .. code-block:: llvm
795
796     %0 = type <{ i8, i8, i8* }>
797
798     define void @f() prefix %0 <{ i8 235, i8 8, i8* @md}> { ... }
799
800 A function may have prefix data but no body.  This has similar semantics
801 to the ``available_externally`` linkage in that the data may be used by the
802 optimizers but will not be emitted in the object file.
803
804 .. _attrgrp:
805
806 Attribute Groups
807 ----------------
808
809 Attribute groups are groups of attributes that are referenced by objects within
810 the IR. They are important for keeping ``.ll`` files readable, because a lot of
811 functions will use the same set of attributes. In the degenerative case of a
812 ``.ll`` file that corresponds to a single ``.c`` file, the single attribute
813 group will capture the important command line flags used to build that file.
814
815 An attribute group is a module-level object. To use an attribute group, an
816 object references the attribute group's ID (e.g. ``#37``). An object may refer
817 to more than one attribute group. In that situation, the attributes from the
818 different groups are merged.
819
820 Here is an example of attribute groups for a function that should always be
821 inlined, has a stack alignment of 4, and which shouldn't use SSE instructions:
822
823 .. code-block:: llvm
824
825    ; Target-independent attributes:
826    attributes #0 = { alwaysinline alignstack=4 }
827
828    ; Target-dependent attributes:
829    attributes #1 = { "no-sse" }
830
831    ; Function @f has attributes: alwaysinline, alignstack=4, and "no-sse".
832    define void @f() #0 #1 { ... }
833
834 .. _fnattrs:
835
836 Function Attributes
837 -------------------
838
839 Function attributes are set to communicate additional information about
840 a function. Function attributes are considered to be part of the
841 function, not of the function type, so functions with different function
842 attributes can have the same function type.
843
844 Function attributes are simple keywords that follow the type specified.
845 If multiple attributes are needed, they are space separated. For
846 example:
847
848 .. code-block:: llvm
849
850     define void @f() noinline { ... }
851     define void @f() alwaysinline { ... }
852     define void @f() alwaysinline optsize { ... }
853     define void @f() optsize { ... }
854
855 ``alignstack(<n>)``
856     This attribute indicates that, when emitting the prologue and
857     epilogue, the backend should forcibly align the stack pointer.
858     Specify the desired alignment, which must be a power of two, in
859     parentheses.
860 ``alwaysinline``
861     This attribute indicates that the inliner should attempt to inline
862     this function into callers whenever possible, ignoring any active
863     inlining size threshold for this caller.
864 ``builtin``
865     This indicates that the callee function at a call site should be
866     recognized as a built-in function, even though the function's declaration
867     uses the ``nobuiltin`` attribute. This is only valid at call sites for
868     direct calls to functions which are declared with the ``nobuiltin``
869     attribute.
870 ``cold``
871     This attribute indicates that this function is rarely called. When
872     computing edge weights, basic blocks post-dominated by a cold
873     function call are also considered to be cold; and, thus, given low
874     weight.
875 ``inlinehint``
876     This attribute indicates that the source code contained a hint that
877     inlining this function is desirable (such as the "inline" keyword in
878     C/C++). It is just a hint; it imposes no requirements on the
879     inliner.
880 ``minsize``
881     This attribute suggests that optimization passes and code generator
882     passes make choices that keep the code size of this function as small
883     as possible and perform optimizations that may sacrifice runtime 
884     performance in order to minimize the size of the generated code.
885 ``naked``
886     This attribute disables prologue / epilogue emission for the
887     function. This can have very system-specific consequences.
888 ``nobuiltin``
889     This indicates that the callee function at a call site is not recognized as
890     a built-in function. LLVM will retain the original call and not replace it
891     with equivalent code based on the semantics of the built-in function, unless
892     the call site uses the ``builtin`` attribute. This is valid at call sites
893     and on function declarations and definitions.
894 ``noduplicate``
895     This attribute indicates that calls to the function cannot be
896     duplicated. A call to a ``noduplicate`` function may be moved
897     within its parent function, but may not be duplicated within
898     its parent function.
899
900     A function containing a ``noduplicate`` call may still
901     be an inlining candidate, provided that the call is not
902     duplicated by inlining. That implies that the function has
903     internal linkage and only has one call site, so the original
904     call is dead after inlining.
905 ``noimplicitfloat``
906     This attributes disables implicit floating point instructions.
907 ``noinline``
908     This attribute indicates that the inliner should never inline this
909     function in any situation. This attribute may not be used together
910     with the ``alwaysinline`` attribute.
911 ``nonlazybind``
912     This attribute suppresses lazy symbol binding for the function. This
913     may make calls to the function faster, at the cost of extra program
914     startup time if the function is not called during program startup.
915 ``noredzone``
916     This attribute indicates that the code generator should not use a
917     red zone, even if the target-specific ABI normally permits it.
918 ``noreturn``
919     This function attribute indicates that the function never returns
920     normally. This produces undefined behavior at runtime if the
921     function ever does dynamically return.
922 ``nounwind``
923     This function attribute indicates that the function never returns
924     with an unwind or exceptional control flow. If the function does
925     unwind, its runtime behavior is undefined.
926 ``optnone``
927     This function attribute indicates that the function is not optimized
928     by any optimization or code generator passes with the 
929     exception of interprocedural optimization passes.
930     This attribute cannot be used together with the ``alwaysinline``
931     attribute; this attribute is also incompatible
932     with the ``minsize`` attribute and the ``optsize`` attribute.
933     
934     The inliner should never inline this function in any situation.
935     Only functions with the ``alwaysinline`` attribute are valid
936     candidates for inlining inside the body of this function.
937 ``optsize``
938     This attribute suggests that optimization passes and code generator
939     passes make choices that keep the code size of this function low,
940     and otherwise do optimizations specifically to reduce code size as
941     long as they do not significantly impact runtime performance.
942 ``readnone``
943     On a function, this attribute indicates that the function computes its
944     result (or decides to unwind an exception) based strictly on its arguments,
945     without dereferencing any pointer arguments or otherwise accessing
946     any mutable state (e.g. memory, control registers, etc) visible to
947     caller functions. It does not write through any pointer arguments
948     (including ``byval`` arguments) and never changes any state visible
949     to callers. This means that it cannot unwind exceptions by calling
950     the ``C++`` exception throwing methods.
951     
952     On an argument, this attribute indicates that the function does not
953     dereference that pointer argument, even though it may read or write the
954     memory that the pointer points to if accessed through other pointers.
955 ``readonly``
956     On a function, this attribute indicates that the function does not write
957     through any pointer arguments (including ``byval`` arguments) or otherwise
958     modify any state (e.g. memory, control registers, etc) visible to
959     caller functions. It may dereference pointer arguments and read
960     state that may be set in the caller. A readonly function always
961     returns the same value (or unwinds an exception identically) when
962     called with the same set of arguments and global state. It cannot
963     unwind an exception by calling the ``C++`` exception throwing
964     methods.
965     
966     On an argument, this attribute indicates that the function does not write
967     through this pointer argument, even though it may write to the memory that
968     the pointer points to.
969 ``returns_twice``
970     This attribute indicates that this function can return twice. The C
971     ``setjmp`` is an example of such a function. The compiler disables
972     some optimizations (like tail calls) in the caller of these
973     functions.
974 ``sanitize_address``
975     This attribute indicates that AddressSanitizer checks
976     (dynamic address safety analysis) are enabled for this function.
977 ``sanitize_memory``
978     This attribute indicates that MemorySanitizer checks (dynamic detection
979     of accesses to uninitialized memory) are enabled for this function.
980 ``sanitize_thread``
981     This attribute indicates that ThreadSanitizer checks
982     (dynamic thread safety analysis) are enabled for this function.
983 ``ssp``
984     This attribute indicates that the function should emit a stack
985     smashing protector. It is in the form of a "canary" --- a random value
986     placed on the stack before the local variables that's checked upon
987     return from the function to see if it has been overwritten. A
988     heuristic is used to determine if a function needs stack protectors
989     or not. The heuristic used will enable protectors for functions with:
990
991     - Character arrays larger than ``ssp-buffer-size`` (default 8).
992     - Aggregates containing character arrays larger than ``ssp-buffer-size``.
993     - Calls to alloca() with variable sizes or constant sizes greater than
994       ``ssp-buffer-size``.
995
996     If a function that has an ``ssp`` attribute is inlined into a
997     function that doesn't have an ``ssp`` attribute, then the resulting
998     function will have an ``ssp`` attribute.
999 ``sspreq``
1000     This attribute indicates that the function should *always* emit a
1001     stack smashing protector. This overrides the ``ssp`` function
1002     attribute.
1003
1004     If a function that has an ``sspreq`` attribute is inlined into a
1005     function that doesn't have an ``sspreq`` attribute or which has an
1006     ``ssp`` or ``sspstrong`` attribute, then the resulting function will have
1007     an ``sspreq`` attribute.
1008 ``sspstrong``
1009     This attribute indicates that the function should emit a stack smashing
1010     protector. This attribute causes a strong heuristic to be used when
1011     determining if a function needs stack protectors.  The strong heuristic
1012     will enable protectors for functions with:
1013
1014     - Arrays of any size and type
1015     - Aggregates containing an array of any size and type.
1016     - Calls to alloca().
1017     - Local variables that have had their address taken.
1018
1019     This overrides the ``ssp`` function attribute.
1020
1021     If a function that has an ``sspstrong`` attribute is inlined into a
1022     function that doesn't have an ``sspstrong`` attribute, then the
1023     resulting function will have an ``sspstrong`` attribute.
1024 ``uwtable``
1025     This attribute indicates that the ABI being targeted requires that
1026     an unwind table entry be produce for this function even if we can
1027     show that no exceptions passes by it. This is normally the case for
1028     the ELF x86-64 abi, but it can be disabled for some compilation
1029     units.
1030
1031 .. _moduleasm:
1032
1033 Module-Level Inline Assembly
1034 ----------------------------
1035
1036 Modules may contain "module-level inline asm" blocks, which corresponds
1037 to the GCC "file scope inline asm" blocks. These blocks are internally
1038 concatenated by LLVM and treated as a single unit, but may be separated
1039 in the ``.ll`` file if desired. The syntax is very simple:
1040
1041 .. code-block:: llvm
1042
1043     module asm "inline asm code goes here"
1044     module asm "more can go here"
1045
1046 The strings can contain any character by escaping non-printable
1047 characters. The escape sequence used is simply "\\xx" where "xx" is the
1048 two digit hex code for the number.
1049
1050 The inline asm code is simply printed to the machine code .s file when
1051 assembly code is generated.
1052
1053 .. _langref_datalayout:
1054
1055 Data Layout
1056 -----------
1057
1058 A module may specify a target specific data layout string that specifies
1059 how data is to be laid out in memory. The syntax for the data layout is
1060 simply:
1061
1062 .. code-block:: llvm
1063
1064     target datalayout = "layout specification"
1065
1066 The *layout specification* consists of a list of specifications
1067 separated by the minus sign character ('-'). Each specification starts
1068 with a letter and may include other information after the letter to
1069 define some aspect of the data layout. The specifications accepted are
1070 as follows:
1071
1072 ``E``
1073     Specifies that the target lays out data in big-endian form. That is,
1074     the bits with the most significance have the lowest address
1075     location.
1076 ``e``
1077     Specifies that the target lays out data in little-endian form. That
1078     is, the bits with the least significance have the lowest address
1079     location.
1080 ``S<size>``
1081     Specifies the natural alignment of the stack in bits. Alignment
1082     promotion of stack variables is limited to the natural stack
1083     alignment to avoid dynamic stack realignment. The stack alignment
1084     must be a multiple of 8-bits. If omitted, the natural stack
1085     alignment defaults to "unspecified", which does not prevent any
1086     alignment promotions.
1087 ``p[n]:<size>:<abi>:<pref>``
1088     This specifies the *size* of a pointer and its ``<abi>`` and
1089     ``<pref>``\erred alignments for address space ``n``. All sizes are in
1090     bits. Specifying the ``<pref>`` alignment is optional. If omitted, the
1091     preceding ``:`` should be omitted too. The address space, ``n`` is
1092     optional, and if not specified, denotes the default address space 0.
1093     The value of ``n`` must be in the range [1,2^23).
1094 ``i<size>:<abi>:<pref>``
1095     This specifies the alignment for an integer type of a given bit
1096     ``<size>``. The value of ``<size>`` must be in the range [1,2^23).
1097 ``v<size>:<abi>:<pref>``
1098     This specifies the alignment for a vector type of a given bit
1099     ``<size>``.
1100 ``f<size>:<abi>:<pref>``
1101     This specifies the alignment for a floating point type of a given bit
1102     ``<size>``. Only values of ``<size>`` that are supported by the target
1103     will work. 32 (float) and 64 (double) are supported on all targets; 80
1104     or 128 (different flavors of long double) are also supported on some
1105     targets.
1106 ``a<size>:<abi>:<pref>``
1107     This specifies the alignment for an aggregate type of a given bit
1108     ``<size>``.
1109 ``s<size>:<abi>:<pref>``
1110     This specifies the alignment for a stack object of a given bit
1111     ``<size>``.
1112 ``n<size1>:<size2>:<size3>...``
1113     This specifies a set of native integer widths for the target CPU in
1114     bits. For example, it might contain ``n32`` for 32-bit PowerPC,
1115     ``n32:64`` for PowerPC 64, or ``n8:16:32:64`` for X86-64. Elements of
1116     this set are considered to support most general arithmetic operations
1117     efficiently.
1118
1119 When constructing the data layout for a given target, LLVM starts with a
1120 default set of specifications which are then (possibly) overridden by
1121 the specifications in the ``datalayout`` keyword. The default
1122 specifications are given in this list:
1123
1124 -  ``E`` - big endian
1125 -  ``p:64:64:64`` - 64-bit pointers with 64-bit alignment.
1126 -  ``p[n]:64:64:64`` - Other address spaces are assumed to be the
1127    same as the default address space.
1128 -  ``S0`` - natural stack alignment is unspecified
1129 -  ``i1:8:8`` - i1 is 8-bit (byte) aligned
1130 -  ``i8:8:8`` - i8 is 8-bit (byte) aligned
1131 -  ``i16:16:16`` - i16 is 16-bit aligned
1132 -  ``i32:32:32`` - i32 is 32-bit aligned
1133 -  ``i64:32:64`` - i64 has ABI alignment of 32-bits but preferred
1134    alignment of 64-bits
1135 -  ``f16:16:16`` - half is 16-bit aligned
1136 -  ``f32:32:32`` - float is 32-bit aligned
1137 -  ``f64:64:64`` - double is 64-bit aligned
1138 -  ``f128:128:128`` - quad is 128-bit aligned
1139 -  ``v64:64:64`` - 64-bit vector is 64-bit aligned
1140 -  ``v128:128:128`` - 128-bit vector is 128-bit aligned
1141 -  ``a0:0:64`` - aggregates are 64-bit aligned
1142
1143 When LLVM is determining the alignment for a given type, it uses the
1144 following rules:
1145
1146 #. If the type sought is an exact match for one of the specifications,
1147    that specification is used.
1148 #. If no match is found, and the type sought is an integer type, then
1149    the smallest integer type that is larger than the bitwidth of the
1150    sought type is used. If none of the specifications are larger than
1151    the bitwidth then the largest integer type is used. For example,
1152    given the default specifications above, the i7 type will use the
1153    alignment of i8 (next largest) while both i65 and i256 will use the
1154    alignment of i64 (largest specified).
1155 #. If no match is found, and the type sought is a vector type, then the
1156    largest vector type that is smaller than the sought vector type will
1157    be used as a fall back. This happens because <128 x double> can be
1158    implemented in terms of 64 <2 x double>, for example.
1159
1160 The function of the data layout string may not be what you expect.
1161 Notably, this is not a specification from the frontend of what alignment
1162 the code generator should use.
1163
1164 Instead, if specified, the target data layout is required to match what
1165 the ultimate *code generator* expects. This string is used by the
1166 mid-level optimizers to improve code, and this only works if it matches
1167 what the ultimate code generator uses. If you would like to generate IR
1168 that does not embed this target-specific detail into the IR, then you
1169 don't have to specify the string. This will disable some optimizations
1170 that require precise layout information, but this also prevents those
1171 optimizations from introducing target specificity into the IR.
1172
1173 .. _pointeraliasing:
1174
1175 Pointer Aliasing Rules
1176 ----------------------
1177
1178 Any memory access must be done through a pointer value associated with
1179 an address range of the memory access, otherwise the behavior is
1180 undefined. Pointer values are associated with address ranges according
1181 to the following rules:
1182
1183 -  A pointer value is associated with the addresses associated with any
1184    value it is *based* on.
1185 -  An address of a global variable is associated with the address range
1186    of the variable's storage.
1187 -  The result value of an allocation instruction is associated with the
1188    address range of the allocated storage.
1189 -  A null pointer in the default address-space is associated with no
1190    address.
1191 -  An integer constant other than zero or a pointer value returned from
1192    a function not defined within LLVM may be associated with address
1193    ranges allocated through mechanisms other than those provided by
1194    LLVM. Such ranges shall not overlap with any ranges of addresses
1195    allocated by mechanisms provided by LLVM.
1196
1197 A pointer value is *based* on another pointer value according to the
1198 following rules:
1199
1200 -  A pointer value formed from a ``getelementptr`` operation is *based*
1201    on the first operand of the ``getelementptr``.
1202 -  The result value of a ``bitcast`` is *based* on the operand of the
1203    ``bitcast``.
1204 -  A pointer value formed by an ``inttoptr`` is *based* on all pointer
1205    values that contribute (directly or indirectly) to the computation of
1206    the pointer's value.
1207 -  The "*based* on" relationship is transitive.
1208
1209 Note that this definition of *"based"* is intentionally similar to the
1210 definition of *"based"* in C99, though it is slightly weaker.
1211
1212 LLVM IR does not associate types with memory. The result type of a
1213 ``load`` merely indicates the size and alignment of the memory from
1214 which to load, as well as the interpretation of the value. The first
1215 operand type of a ``store`` similarly only indicates the size and
1216 alignment of the store.
1217
1218 Consequently, type-based alias analysis, aka TBAA, aka
1219 ``-fstrict-aliasing``, is not applicable to general unadorned LLVM IR.
1220 :ref:`Metadata <metadata>` may be used to encode additional information
1221 which specialized optimization passes may use to implement type-based
1222 alias analysis.
1223
1224 .. _volatile:
1225
1226 Volatile Memory Accesses
1227 ------------------------
1228
1229 Certain memory accesses, such as :ref:`load <i_load>`'s,
1230 :ref:`store <i_store>`'s, and :ref:`llvm.memcpy <int_memcpy>`'s may be
1231 marked ``volatile``. The optimizers must not change the number of
1232 volatile operations or change their order of execution relative to other
1233 volatile operations. The optimizers *may* change the order of volatile
1234 operations relative to non-volatile operations. This is not Java's
1235 "volatile" and has no cross-thread synchronization behavior.
1236
1237 IR-level volatile loads and stores cannot safely be optimized into
1238 llvm.memcpy or llvm.memmove intrinsics even when those intrinsics are
1239 flagged volatile. Likewise, the backend should never split or merge
1240 target-legal volatile load/store instructions.
1241
1242 .. admonition:: Rationale
1243
1244  Platforms may rely on volatile loads and stores of natively supported
1245  data width to be executed as single instruction. For example, in C
1246  this holds for an l-value of volatile primitive type with native
1247  hardware support, but not necessarily for aggregate types. The
1248  frontend upholds these expectations, which are intentionally
1249  unspecified in the IR. The rules above ensure that IR transformation
1250  do not violate the frontend's contract with the language.
1251
1252 .. _memmodel:
1253
1254 Memory Model for Concurrent Operations
1255 --------------------------------------
1256
1257 The LLVM IR does not define any way to start parallel threads of
1258 execution or to register signal handlers. Nonetheless, there are
1259 platform-specific ways to create them, and we define LLVM IR's behavior
1260 in their presence. This model is inspired by the C++0x memory model.
1261
1262 For a more informal introduction to this model, see the :doc:`Atomics`.
1263
1264 We define a *happens-before* partial order as the least partial order
1265 that
1266
1267 -  Is a superset of single-thread program order, and
1268 -  When a *synchronizes-with* ``b``, includes an edge from ``a`` to
1269    ``b``. *Synchronizes-with* pairs are introduced by platform-specific
1270    techniques, like pthread locks, thread creation, thread joining,
1271    etc., and by atomic instructions. (See also :ref:`Atomic Memory Ordering
1272    Constraints <ordering>`).
1273
1274 Note that program order does not introduce *happens-before* edges
1275 between a thread and signals executing inside that thread.
1276
1277 Every (defined) read operation (load instructions, memcpy, atomic
1278 loads/read-modify-writes, etc.) R reads a series of bytes written by
1279 (defined) write operations (store instructions, atomic
1280 stores/read-modify-writes, memcpy, etc.). For the purposes of this
1281 section, initialized globals are considered to have a write of the
1282 initializer which is atomic and happens before any other read or write
1283 of the memory in question. For each byte of a read R, R\ :sub:`byte`
1284 may see any write to the same byte, except:
1285
1286 -  If write\ :sub:`1`  happens before write\ :sub:`2`, and
1287    write\ :sub:`2` happens before R\ :sub:`byte`, then
1288    R\ :sub:`byte` does not see write\ :sub:`1`.
1289 -  If R\ :sub:`byte` happens before write\ :sub:`3`, then
1290    R\ :sub:`byte` does not see write\ :sub:`3`.
1291
1292 Given that definition, R\ :sub:`byte` is defined as follows:
1293
1294 -  If R is volatile, the result is target-dependent. (Volatile is
1295    supposed to give guarantees which can support ``sig_atomic_t`` in
1296    C/C++, and may be used for accesses to addresses which do not behave
1297    like normal memory. It does not generally provide cross-thread
1298    synchronization.)
1299 -  Otherwise, if there is no write to the same byte that happens before
1300    R\ :sub:`byte`, R\ :sub:`byte` returns ``undef`` for that byte.
1301 -  Otherwise, if R\ :sub:`byte` may see exactly one write,
1302    R\ :sub:`byte` returns the value written by that write.
1303 -  Otherwise, if R is atomic, and all the writes R\ :sub:`byte` may
1304    see are atomic, it chooses one of the values written. See the :ref:`Atomic
1305    Memory Ordering Constraints <ordering>` section for additional
1306    constraints on how the choice is made.
1307 -  Otherwise R\ :sub:`byte` returns ``undef``.
1308
1309 R returns the value composed of the series of bytes it read. This
1310 implies that some bytes within the value may be ``undef`` **without**
1311 the entire value being ``undef``. Note that this only defines the
1312 semantics of the operation; it doesn't mean that targets will emit more
1313 than one instruction to read the series of bytes.
1314
1315 Note that in cases where none of the atomic intrinsics are used, this
1316 model places only one restriction on IR transformations on top of what
1317 is required for single-threaded execution: introducing a store to a byte
1318 which might not otherwise be stored is not allowed in general.
1319 (Specifically, in the case where another thread might write to and read
1320 from an address, introducing a store can change a load that may see
1321 exactly one write into a load that may see multiple writes.)
1322
1323 .. _ordering:
1324
1325 Atomic Memory Ordering Constraints
1326 ----------------------------------
1327
1328 Atomic instructions (:ref:`cmpxchg <i_cmpxchg>`,
1329 :ref:`atomicrmw <i_atomicrmw>`, :ref:`fence <i_fence>`,
1330 :ref:`atomic load <i_load>`, and :ref:`atomic store <i_store>`) take
1331 an ordering parameter that determines which other atomic instructions on
1332 the same address they *synchronize with*. These semantics are borrowed
1333 from Java and C++0x, but are somewhat more colloquial. If these
1334 descriptions aren't precise enough, check those specs (see spec
1335 references in the :doc:`atomics guide <Atomics>`).
1336 :ref:`fence <i_fence>` instructions treat these orderings somewhat
1337 differently since they don't take an address. See that instruction's
1338 documentation for details.
1339
1340 For a simpler introduction to the ordering constraints, see the
1341 :doc:`Atomics`.
1342
1343 ``unordered``
1344     The set of values that can be read is governed by the happens-before
1345     partial order. A value cannot be read unless some operation wrote
1346     it. This is intended to provide a guarantee strong enough to model
1347     Java's non-volatile shared variables. This ordering cannot be
1348     specified for read-modify-write operations; it is not strong enough
1349     to make them atomic in any interesting way.
1350 ``monotonic``
1351     In addition to the guarantees of ``unordered``, there is a single
1352     total order for modifications by ``monotonic`` operations on each
1353     address. All modification orders must be compatible with the
1354     happens-before order. There is no guarantee that the modification
1355     orders can be combined to a global total order for the whole program
1356     (and this often will not be possible). The read in an atomic
1357     read-modify-write operation (:ref:`cmpxchg <i_cmpxchg>` and
1358     :ref:`atomicrmw <i_atomicrmw>`) reads the value in the modification
1359     order immediately before the value it writes. If one atomic read
1360     happens before another atomic read of the same address, the later
1361     read must see the same value or a later value in the address's
1362     modification order. This disallows reordering of ``monotonic`` (or
1363     stronger) operations on the same address. If an address is written
1364     ``monotonic``-ally by one thread, and other threads ``monotonic``-ally
1365     read that address repeatedly, the other threads must eventually see
1366     the write. This corresponds to the C++0x/C1x
1367     ``memory_order_relaxed``.
1368 ``acquire``
1369     In addition to the guarantees of ``monotonic``, a
1370     *synchronizes-with* edge may be formed with a ``release`` operation.
1371     This is intended to model C++'s ``memory_order_acquire``.
1372 ``release``
1373     In addition to the guarantees of ``monotonic``, if this operation
1374     writes a value which is subsequently read by an ``acquire``
1375     operation, it *synchronizes-with* that operation. (This isn't a
1376     complete description; see the C++0x definition of a release
1377     sequence.) This corresponds to the C++0x/C1x
1378     ``memory_order_release``.
1379 ``acq_rel`` (acquire+release)
1380     Acts as both an ``acquire`` and ``release`` operation on its
1381     address. This corresponds to the C++0x/C1x ``memory_order_acq_rel``.
1382 ``seq_cst`` (sequentially consistent)
1383     In addition to the guarantees of ``acq_rel`` (``acquire`` for an
1384     operation which only reads, ``release`` for an operation which only
1385     writes), there is a global total order on all
1386     sequentially-consistent operations on all addresses, which is
1387     consistent with the *happens-before* partial order and with the
1388     modification orders of all the affected addresses. Each
1389     sequentially-consistent read sees the last preceding write to the
1390     same address in this global order. This corresponds to the C++0x/C1x
1391     ``memory_order_seq_cst`` and Java volatile.
1392
1393 .. _singlethread:
1394
1395 If an atomic operation is marked ``singlethread``, it only *synchronizes
1396 with* or participates in modification and seq\_cst total orderings with
1397 other operations running in the same thread (for example, in signal
1398 handlers).
1399
1400 .. _fastmath:
1401
1402 Fast-Math Flags
1403 ---------------
1404
1405 LLVM IR floating-point binary ops (:ref:`fadd <i_fadd>`,
1406 :ref:`fsub <i_fsub>`, :ref:`fmul <i_fmul>`, :ref:`fdiv <i_fdiv>`,
1407 :ref:`frem <i_frem>`) have the following flags that can set to enable
1408 otherwise unsafe floating point operations
1409
1410 ``nnan``
1411    No NaNs - Allow optimizations to assume the arguments and result are not
1412    NaN. Such optimizations are required to retain defined behavior over
1413    NaNs, but the value of the result is undefined.
1414
1415 ``ninf``
1416    No Infs - Allow optimizations to assume the arguments and result are not
1417    +/-Inf. Such optimizations are required to retain defined behavior over
1418    +/-Inf, but the value of the result is undefined.
1419
1420 ``nsz``
1421    No Signed Zeros - Allow optimizations to treat the sign of a zero
1422    argument or result as insignificant.
1423
1424 ``arcp``
1425    Allow Reciprocal - Allow optimizations to use the reciprocal of an
1426    argument rather than perform division.
1427
1428 ``fast``
1429    Fast - Allow algebraically equivalent transformations that may
1430    dramatically change results in floating point (e.g. reassociate). This
1431    flag implies all the others.
1432
1433 .. _typesystem:
1434
1435 Type System
1436 ===========
1437
1438 The LLVM type system is one of the most important features of the
1439 intermediate representation. Being typed enables a number of
1440 optimizations to be performed on the intermediate representation
1441 directly, without having to do extra analyses on the side before the
1442 transformation. A strong type system makes it easier to read the
1443 generated code and enables novel analyses and transformations that are
1444 not feasible to perform on normal three address code representations.
1445
1446 .. _typeclassifications:
1447
1448 Type Classifications
1449 --------------------
1450
1451 The types fall into a few useful classifications:
1452
1453
1454 .. list-table::
1455    :header-rows: 1
1456
1457    * - Classification
1458      - Types
1459
1460    * - :ref:`integer <t_integer>`
1461      - ``i1``, ``i2``, ``i3``, ... ``i8``, ... ``i16``, ... ``i32``, ...
1462        ``i64``, ...
1463
1464    * - :ref:`floating point <t_floating>`
1465      - ``half``, ``float``, ``double``, ``x86_fp80``, ``fp128``,
1466        ``ppc_fp128``
1467
1468
1469    * - first class
1470
1471        .. _t_firstclass:
1472
1473      - :ref:`integer <t_integer>`, :ref:`floating point <t_floating>`,
1474        :ref:`pointer <t_pointer>`, :ref:`vector <t_vector>`,
1475        :ref:`structure <t_struct>`, :ref:`array <t_array>`,
1476        :ref:`label <t_label>`, :ref:`metadata <t_metadata>`.
1477
1478    * - :ref:`primitive <t_primitive>`
1479      - :ref:`label <t_label>`,
1480        :ref:`void <t_void>`,
1481        :ref:`integer <t_integer>`,
1482        :ref:`floating point <t_floating>`,
1483        :ref:`x86mmx <t_x86mmx>`,
1484        :ref:`metadata <t_metadata>`.
1485
1486    * - :ref:`derived <t_derived>`
1487      - :ref:`array <t_array>`,
1488        :ref:`function <t_function>`,
1489        :ref:`pointer <t_pointer>`,
1490        :ref:`structure <t_struct>`,
1491        :ref:`vector <t_vector>`,
1492        :ref:`opaque <t_opaque>`.
1493
1494 The :ref:`first class <t_firstclass>` types are perhaps the most important.
1495 Values of these types are the only ones which can be produced by
1496 instructions.
1497
1498 .. _t_primitive:
1499
1500 Primitive Types
1501 ---------------
1502
1503 The primitive types are the fundamental building blocks of the LLVM
1504 system.
1505
1506 .. _t_integer:
1507
1508 Integer Type
1509 ^^^^^^^^^^^^
1510
1511 Overview:
1512 """""""""
1513
1514 The integer type is a very simple type that simply specifies an
1515 arbitrary bit width for the integer type desired. Any bit width from 1
1516 bit to 2\ :sup:`23`\ -1 (about 8 million) can be specified.
1517
1518 Syntax:
1519 """""""
1520
1521 ::
1522
1523       iN
1524
1525 The number of bits the integer will occupy is specified by the ``N``
1526 value.
1527
1528 Examples:
1529 """""""""
1530
1531 +----------------+------------------------------------------------+
1532 | ``i1``         | a single-bit integer.                          |
1533 +----------------+------------------------------------------------+
1534 | ``i32``        | a 32-bit integer.                              |
1535 +----------------+------------------------------------------------+
1536 | ``i1942652``   | a really big integer of over 1 million bits.   |
1537 +----------------+------------------------------------------------+
1538
1539 .. _t_floating:
1540
1541 Floating Point Types
1542 ^^^^^^^^^^^^^^^^^^^^
1543
1544 .. list-table::
1545    :header-rows: 1
1546
1547    * - Type
1548      - Description
1549
1550    * - ``half``
1551      - 16-bit floating point value
1552
1553    * - ``float``
1554      - 32-bit floating point value
1555
1556    * - ``double``
1557      - 64-bit floating point value
1558
1559    * - ``fp128``
1560      - 128-bit floating point value (112-bit mantissa)
1561
1562    * - ``x86_fp80``
1563      -  80-bit floating point value (X87)
1564
1565    * - ``ppc_fp128``
1566      - 128-bit floating point value (two 64-bits)
1567
1568 .. _t_x86mmx:
1569
1570 X86mmx Type
1571 ^^^^^^^^^^^
1572
1573 Overview:
1574 """""""""
1575
1576 The x86mmx type represents a value held in an MMX register on an x86
1577 machine. The operations allowed on it are quite limited: parameters and
1578 return values, load and store, and bitcast. User-specified MMX
1579 instructions are represented as intrinsic or asm calls with arguments
1580 and/or results of this type. There are no arrays, vectors or constants
1581 of this type.
1582
1583 Syntax:
1584 """""""
1585
1586 ::
1587
1588       x86mmx
1589
1590 .. _t_void:
1591
1592 Void Type
1593 ^^^^^^^^^
1594
1595 Overview:
1596 """""""""
1597
1598 The void type does not represent any value and has no size.
1599
1600 Syntax:
1601 """""""
1602
1603 ::
1604
1605       void
1606
1607 .. _t_label:
1608
1609 Label Type
1610 ^^^^^^^^^^
1611
1612 Overview:
1613 """""""""
1614
1615 The label type represents code labels.
1616
1617 Syntax:
1618 """""""
1619
1620 ::
1621
1622       label
1623
1624 .. _t_metadata:
1625
1626 Metadata Type
1627 ^^^^^^^^^^^^^
1628
1629 Overview:
1630 """""""""
1631
1632 The metadata type represents embedded metadata. No derived types may be
1633 created from metadata except for :ref:`function <t_function>` arguments.
1634
1635 Syntax:
1636 """""""
1637
1638 ::
1639
1640       metadata
1641
1642 .. _t_derived:
1643
1644 Derived Types
1645 -------------
1646
1647 The real power in LLVM comes from the derived types in the system. This
1648 is what allows a programmer to represent arrays, functions, pointers,
1649 and other useful types. Each of these types contain one or more element
1650 types which may be a primitive type, or another derived type. For
1651 example, it is possible to have a two dimensional array, using an array
1652 as the element type of another array.
1653
1654 .. _t_aggregate:
1655
1656 Aggregate Types
1657 ^^^^^^^^^^^^^^^
1658
1659 Aggregate Types are a subset of derived types that can contain multiple
1660 member types. :ref:`Arrays <t_array>` and :ref:`structs <t_struct>` are
1661 aggregate types. :ref:`Vectors <t_vector>` are not considered to be
1662 aggregate types.
1663
1664 .. _t_array:
1665
1666 Array Type
1667 ^^^^^^^^^^
1668
1669 Overview:
1670 """""""""
1671
1672 The array type is a very simple derived type that arranges elements
1673 sequentially in memory. The array type requires a size (number of
1674 elements) and an underlying data type.
1675
1676 Syntax:
1677 """""""
1678
1679 ::
1680
1681       [<# elements> x <elementtype>]
1682
1683 The number of elements is a constant integer value; ``elementtype`` may
1684 be any type with a size.
1685
1686 Examples:
1687 """""""""
1688
1689 +------------------+--------------------------------------+
1690 | ``[40 x i32]``   | Array of 40 32-bit integer values.   |
1691 +------------------+--------------------------------------+
1692 | ``[41 x i32]``   | Array of 41 32-bit integer values.   |
1693 +------------------+--------------------------------------+
1694 | ``[4 x i8]``     | Array of 4 8-bit integer values.     |
1695 +------------------+--------------------------------------+
1696
1697 Here are some examples of multidimensional arrays:
1698
1699 +-----------------------------+----------------------------------------------------------+
1700 | ``[3 x [4 x i32]]``         | 3x4 array of 32-bit integer values.                      |
1701 +-----------------------------+----------------------------------------------------------+
1702 | ``[12 x [10 x float]]``     | 12x10 array of single precision floating point values.   |
1703 +-----------------------------+----------------------------------------------------------+
1704 | ``[2 x [3 x [4 x i16]]]``   | 2x3x4 array of 16-bit integer values.                    |
1705 +-----------------------------+----------------------------------------------------------+
1706
1707 There is no restriction on indexing beyond the end of the array implied
1708 by a static type (though there are restrictions on indexing beyond the
1709 bounds of an allocated object in some cases). This means that
1710 single-dimension 'variable sized array' addressing can be implemented in
1711 LLVM with a zero length array type. An implementation of 'pascal style
1712 arrays' in LLVM could use the type "``{ i32, [0 x float]}``", for
1713 example.
1714
1715 .. _t_function:
1716
1717 Function Type
1718 ^^^^^^^^^^^^^
1719
1720 Overview:
1721 """""""""
1722
1723 The function type can be thought of as a function signature. It consists
1724 of a return type and a list of formal parameter types. The return type
1725 of a function type is a first class type or a void type.
1726
1727 Syntax:
1728 """""""
1729
1730 ::
1731
1732       <returntype> (<parameter list>)
1733
1734 ...where '``<parameter list>``' is a comma-separated list of type
1735 specifiers. Optionally, the parameter list may include a type ``...``,
1736 which indicates that the function takes a variable number of arguments.
1737 Variable argument functions can access their arguments with the
1738 :ref:`variable argument handling intrinsic <int_varargs>` functions.
1739 '``<returntype>``' is any type except :ref:`label <t_label>`.
1740
1741 Examples:
1742 """""""""
1743
1744 +---------------------------------+---------------------------------------------------------------------------------------------------------------------------------------------------------------------+
1745 | ``i32 (i32)``                   | function taking an ``i32``, returning an ``i32``                                                                                                                    |
1746 +---------------------------------+---------------------------------------------------------------------------------------------------------------------------------------------------------------------+
1747 | ``float (i16, i32 *) *``        | :ref:`Pointer <t_pointer>` to a function that takes an ``i16`` and a :ref:`pointer <t_pointer>` to ``i32``, returning ``float``.                                    |
1748 +---------------------------------+---------------------------------------------------------------------------------------------------------------------------------------------------------------------+
1749 | ``i32 (i8*, ...)``              | A vararg function that takes at least one :ref:`pointer <t_pointer>` to ``i8`` (char in C), which returns an integer. This is the signature for ``printf`` in LLVM. |
1750 +---------------------------------+---------------------------------------------------------------------------------------------------------------------------------------------------------------------+
1751 | ``{i32, i32} (i32)``            | A function taking an ``i32``, returning a :ref:`structure <t_struct>` containing two ``i32`` values                                                                 |
1752 +---------------------------------+---------------------------------------------------------------------------------------------------------------------------------------------------------------------+
1753
1754 .. _t_struct:
1755
1756 Structure Type
1757 ^^^^^^^^^^^^^^
1758
1759 Overview:
1760 """""""""
1761
1762 The structure type is used to represent a collection of data members
1763 together in memory. The elements of a structure may be any type that has
1764 a size.
1765
1766 Structures in memory are accessed using '``load``' and '``store``' by
1767 getting a pointer to a field with the '``getelementptr``' instruction.
1768 Structures in registers are accessed using the '``extractvalue``' and
1769 '``insertvalue``' instructions.
1770
1771 Structures may optionally be "packed" structures, which indicate that
1772 the alignment of the struct is one byte, and that there is no padding
1773 between the elements. In non-packed structs, padding between field types
1774 is inserted as defined by the DataLayout string in the module, which is
1775 required to match what the underlying code generator expects.
1776
1777 Structures can either be "literal" or "identified". A literal structure
1778 is defined inline with other types (e.g. ``{i32, i32}*``) whereas
1779 identified types are always defined at the top level with a name.
1780 Literal types are uniqued by their contents and can never be recursive
1781 or opaque since there is no way to write one. Identified types can be
1782 recursive, can be opaqued, and are never uniqued.
1783
1784 Syntax:
1785 """""""
1786
1787 ::
1788
1789       %T1 = type { <type list> }     ; Identified normal struct type
1790       %T2 = type <{ <type list> }>   ; Identified packed struct type
1791
1792 Examples:
1793 """""""""
1794
1795 +------------------------------+---------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------+
1796 | ``{ i32, i32, i32 }``        | A triple of three ``i32`` values                                                                                                                                                      |
1797 +------------------------------+---------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------+
1798 | ``{ float, i32 (i32) * }``   | A pair, where the first element is a ``float`` and the second element is a :ref:`pointer <t_pointer>` to a :ref:`function <t_function>` that takes an ``i32``, returning an ``i32``.  |
1799 +------------------------------+---------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------+
1800 | ``<{ i8, i32 }>``            | A packed struct known to be 5 bytes in size.                                                                                                                                          |
1801 +------------------------------+---------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------+
1802
1803 .. _t_opaque:
1804
1805 Opaque Structure Types
1806 ^^^^^^^^^^^^^^^^^^^^^^
1807
1808 Overview:
1809 """""""""
1810
1811 Opaque structure types are used to represent named structure types that
1812 do not have a body specified. This corresponds (for example) to the C
1813 notion of a forward declared structure.
1814
1815 Syntax:
1816 """""""
1817
1818 ::
1819
1820       %X = type opaque
1821       %52 = type opaque
1822
1823 Examples:
1824 """""""""
1825
1826 +--------------+-------------------+
1827 | ``opaque``   | An opaque type.   |
1828 +--------------+-------------------+
1829
1830 .. _t_pointer:
1831
1832 Pointer Type
1833 ^^^^^^^^^^^^
1834
1835 Overview:
1836 """""""""
1837
1838 The pointer type is used to specify memory locations. Pointers are
1839 commonly used to reference objects in memory.
1840
1841 Pointer types may have an optional address space attribute defining the
1842 numbered address space where the pointed-to object resides. The default
1843 address space is number zero. The semantics of non-zero address spaces
1844 are target-specific.
1845
1846 Note that LLVM does not permit pointers to void (``void*``) nor does it
1847 permit pointers to labels (``label*``). Use ``i8*`` instead.
1848
1849 Syntax:
1850 """""""
1851
1852 ::
1853
1854       <type> *
1855
1856 Examples:
1857 """""""""
1858
1859 +-------------------------+--------------------------------------------------------------------------------------------------------------+
1860 | ``[4 x i32]*``          | A :ref:`pointer <t_pointer>` to :ref:`array <t_array>` of four ``i32`` values.                               |
1861 +-------------------------+--------------------------------------------------------------------------------------------------------------+
1862 | ``i32 (i32*) *``        | A :ref:`pointer <t_pointer>` to a :ref:`function <t_function>` that takes an ``i32*``, returning an ``i32``. |
1863 +-------------------------+--------------------------------------------------------------------------------------------------------------+
1864 | ``i32 addrspace(5)*``   | A :ref:`pointer <t_pointer>` to an ``i32`` value that resides in address space #5.                           |
1865 +-------------------------+--------------------------------------------------------------------------------------------------------------+
1866
1867 .. _t_vector:
1868
1869 Vector Type
1870 ^^^^^^^^^^^
1871
1872 Overview:
1873 """""""""
1874
1875 A vector type is a simple derived type that represents a vector of
1876 elements. Vector types are used when multiple primitive data are
1877 operated in parallel using a single instruction (SIMD). A vector type
1878 requires a size (number of elements) and an underlying primitive data
1879 type. Vector types are considered :ref:`first class <t_firstclass>`.
1880
1881 Syntax:
1882 """""""
1883
1884 ::
1885
1886       < <# elements> x <elementtype> >
1887
1888 The number of elements is a constant integer value larger than 0;
1889 elementtype may be any integer or floating point type, or a pointer to
1890 these types. Vectors of size zero are not allowed.
1891
1892 Examples:
1893 """""""""
1894
1895 +-------------------+--------------------------------------------------+
1896 | ``<4 x i32>``     | Vector of 4 32-bit integer values.               |
1897 +-------------------+--------------------------------------------------+
1898 | ``<8 x float>``   | Vector of 8 32-bit floating-point values.        |
1899 +-------------------+--------------------------------------------------+
1900 | ``<2 x i64>``     | Vector of 2 64-bit integer values.               |
1901 +-------------------+--------------------------------------------------+
1902 | ``<4 x i64*>``    | Vector of 4 pointers to 64-bit integer values.   |
1903 +-------------------+--------------------------------------------------+
1904
1905 Constants
1906 =========
1907
1908 LLVM has several different basic types of constants. This section
1909 describes them all and their syntax.
1910
1911 Simple Constants
1912 ----------------
1913
1914 **Boolean constants**
1915     The two strings '``true``' and '``false``' are both valid constants
1916     of the ``i1`` type.
1917 **Integer constants**
1918     Standard integers (such as '4') are constants of the
1919     :ref:`integer <t_integer>` type. Negative numbers may be used with
1920     integer types.
1921 **Floating point constants**
1922     Floating point constants use standard decimal notation (e.g.
1923     123.421), exponential notation (e.g. 1.23421e+2), or a more precise
1924     hexadecimal notation (see below). The assembler requires the exact
1925     decimal value of a floating-point constant. For example, the
1926     assembler accepts 1.25 but rejects 1.3 because 1.3 is a repeating
1927     decimal in binary. Floating point constants must have a :ref:`floating
1928     point <t_floating>` type.
1929 **Null pointer constants**
1930     The identifier '``null``' is recognized as a null pointer constant
1931     and must be of :ref:`pointer type <t_pointer>`.
1932
1933 The one non-intuitive notation for constants is the hexadecimal form of
1934 floating point constants. For example, the form
1935 '``double    0x432ff973cafa8000``' is equivalent to (but harder to read
1936 than) '``double 4.5e+15``'. The only time hexadecimal floating point
1937 constants are required (and the only time that they are generated by the
1938 disassembler) is when a floating point constant must be emitted but it
1939 cannot be represented as a decimal floating point number in a reasonable
1940 number of digits. For example, NaN's, infinities, and other special
1941 values are represented in their IEEE hexadecimal format so that assembly
1942 and disassembly do not cause any bits to change in the constants.
1943
1944 When using the hexadecimal form, constants of types half, float, and
1945 double are represented using the 16-digit form shown above (which
1946 matches the IEEE754 representation for double); half and float values
1947 must, however, be exactly representable as IEEE 754 half and single
1948 precision, respectively. Hexadecimal format is always used for long
1949 double, and there are three forms of long double. The 80-bit format used
1950 by x86 is represented as ``0xK`` followed by 20 hexadecimal digits. The
1951 128-bit format used by PowerPC (two adjacent doubles) is represented by
1952 ``0xM`` followed by 32 hexadecimal digits. The IEEE 128-bit format is
1953 represented by ``0xL`` followed by 32 hexadecimal digits. Long doubles
1954 will only work if they match the long double format on your target.
1955 The IEEE 16-bit format (half precision) is represented by ``0xH``
1956 followed by 4 hexadecimal digits. All hexadecimal formats are big-endian
1957 (sign bit at the left).
1958
1959 There are no constants of type x86mmx.
1960
1961 .. _complexconstants:
1962
1963 Complex Constants
1964 -----------------
1965
1966 Complex constants are a (potentially recursive) combination of simple
1967 constants and smaller complex constants.
1968
1969 **Structure constants**
1970     Structure constants are represented with notation similar to
1971     structure type definitions (a comma separated list of elements,
1972     surrounded by braces (``{}``)). For example:
1973     "``{ i32 4, float 17.0, i32* @G }``", where "``@G``" is declared as
1974     "``@G = external global i32``". Structure constants must have
1975     :ref:`structure type <t_struct>`, and the number and types of elements
1976     must match those specified by the type.
1977 **Array constants**
1978     Array constants are represented with notation similar to array type
1979     definitions (a comma separated list of elements, surrounded by
1980     square brackets (``[]``)). For example:
1981     "``[ i32 42, i32 11, i32 74 ]``". Array constants must have
1982     :ref:`array type <t_array>`, and the number and types of elements must
1983     match those specified by the type.
1984 **Vector constants**
1985     Vector constants are represented with notation similar to vector
1986     type definitions (a comma separated list of elements, surrounded by
1987     less-than/greater-than's (``<>``)). For example:
1988     "``< i32 42, i32 11, i32 74, i32 100 >``". Vector constants
1989     must have :ref:`vector type <t_vector>`, and the number and types of
1990     elements must match those specified by the type.
1991 **Zero initialization**
1992     The string '``zeroinitializer``' can be used to zero initialize a
1993     value to zero of *any* type, including scalar and
1994     :ref:`aggregate <t_aggregate>` types. This is often used to avoid
1995     having to print large zero initializers (e.g. for large arrays) and
1996     is always exactly equivalent to using explicit zero initializers.
1997 **Metadata node**
1998     A metadata node is a structure-like constant with :ref:`metadata
1999     type <t_metadata>`. For example:
2000     "``metadata !{ i32 0, metadata !"test" }``". Unlike other
2001     constants that are meant to be interpreted as part of the
2002     instruction stream, metadata is a place to attach additional
2003     information such as debug info.
2004
2005 Global Variable and Function Addresses
2006 --------------------------------------
2007
2008 The addresses of :ref:`global variables <globalvars>` and
2009 :ref:`functions <functionstructure>` are always implicitly valid
2010 (link-time) constants. These constants are explicitly referenced when
2011 the :ref:`identifier for the global <identifiers>` is used and always have
2012 :ref:`pointer <t_pointer>` type. For example, the following is a legal LLVM
2013 file:
2014
2015 .. code-block:: llvm
2016
2017     @X = global i32 17
2018     @Y = global i32 42
2019     @Z = global [2 x i32*] [ i32* @X, i32* @Y ]
2020
2021 .. _undefvalues:
2022
2023 Undefined Values
2024 ----------------
2025
2026 The string '``undef``' can be used anywhere a constant is expected, and
2027 indicates that the user of the value may receive an unspecified
2028 bit-pattern. Undefined values may be of any type (other than '``label``'
2029 or '``void``') and be used anywhere a constant is permitted.
2030
2031 Undefined values are useful because they indicate to the compiler that
2032 the program is well defined no matter what value is used. This gives the
2033 compiler more freedom to optimize. Here are some examples of
2034 (potentially surprising) transformations that are valid (in pseudo IR):
2035
2036 .. code-block:: llvm
2037
2038       %A = add %X, undef
2039       %B = sub %X, undef
2040       %C = xor %X, undef
2041     Safe:
2042       %A = undef
2043       %B = undef
2044       %C = undef
2045
2046 This is safe because all of the output bits are affected by the undef
2047 bits. Any output bit can have a zero or one depending on the input bits.
2048
2049 .. code-block:: llvm
2050
2051       %A = or %X, undef
2052       %B = and %X, undef
2053     Safe:
2054       %A = -1
2055       %B = 0
2056     Unsafe:
2057       %A = undef
2058       %B = undef
2059
2060 These logical operations have bits that are not always affected by the
2061 input. For example, if ``%X`` has a zero bit, then the output of the
2062 '``and``' operation will always be a zero for that bit, no matter what
2063 the corresponding bit from the '``undef``' is. As such, it is unsafe to
2064 optimize or assume that the result of the '``and``' is '``undef``'.
2065 However, it is safe to assume that all bits of the '``undef``' could be
2066 0, and optimize the '``and``' to 0. Likewise, it is safe to assume that
2067 all the bits of the '``undef``' operand to the '``or``' could be set,
2068 allowing the '``or``' to be folded to -1.
2069
2070 .. code-block:: llvm
2071
2072       %A = select undef, %X, %Y
2073       %B = select undef, 42, %Y
2074       %C = select %X, %Y, undef
2075     Safe:
2076       %A = %X     (or %Y)
2077       %B = 42     (or %Y)
2078       %C = %Y
2079     Unsafe:
2080       %A = undef
2081       %B = undef
2082       %C = undef
2083
2084 This set of examples shows that undefined '``select``' (and conditional
2085 branch) conditions can go *either way*, but they have to come from one
2086 of the two operands. In the ``%A`` example, if ``%X`` and ``%Y`` were
2087 both known to have a clear low bit, then ``%A`` would have to have a
2088 cleared low bit. However, in the ``%C`` example, the optimizer is
2089 allowed to assume that the '``undef``' operand could be the same as
2090 ``%Y``, allowing the whole '``select``' to be eliminated.
2091
2092 .. code-block:: llvm
2093
2094       %A = xor undef, undef
2095
2096       %B = undef
2097       %C = xor %B, %B
2098
2099       %D = undef
2100       %E = icmp lt %D, 4
2101       %F = icmp gte %D, 4
2102
2103     Safe:
2104       %A = undef
2105       %B = undef
2106       %C = undef
2107       %D = undef
2108       %E = undef
2109       %F = undef
2110
2111 This example points out that two '``undef``' operands are not
2112 necessarily the same. This can be surprising to people (and also matches
2113 C semantics) where they assume that "``X^X``" is always zero, even if
2114 ``X`` is undefined. This isn't true for a number of reasons, but the
2115 short answer is that an '``undef``' "variable" can arbitrarily change
2116 its value over its "live range". This is true because the variable
2117 doesn't actually *have a live range*. Instead, the value is logically
2118 read from arbitrary registers that happen to be around when needed, so
2119 the value is not necessarily consistent over time. In fact, ``%A`` and
2120 ``%C`` need to have the same semantics or the core LLVM "replace all
2121 uses with" concept would not hold.
2122
2123 .. code-block:: llvm
2124
2125       %A = fdiv undef, %X
2126       %B = fdiv %X, undef
2127     Safe:
2128       %A = undef
2129     b: unreachable
2130
2131 These examples show the crucial difference between an *undefined value*
2132 and *undefined behavior*. An undefined value (like '``undef``') is
2133 allowed to have an arbitrary bit-pattern. This means that the ``%A``
2134 operation can be constant folded to '``undef``', because the '``undef``'
2135 could be an SNaN, and ``fdiv`` is not (currently) defined on SNaN's.
2136 However, in the second example, we can make a more aggressive
2137 assumption: because the ``undef`` is allowed to be an arbitrary value,
2138 we are allowed to assume that it could be zero. Since a divide by zero
2139 has *undefined behavior*, we are allowed to assume that the operation
2140 does not execute at all. This allows us to delete the divide and all
2141 code after it. Because the undefined operation "can't happen", the
2142 optimizer can assume that it occurs in dead code.
2143
2144 .. code-block:: llvm
2145
2146     a:  store undef -> %X
2147     b:  store %X -> undef
2148     Safe:
2149     a: <deleted>
2150     b: unreachable
2151
2152 These examples reiterate the ``fdiv`` example: a store *of* an undefined
2153 value can be assumed to not have any effect; we can assume that the
2154 value is overwritten with bits that happen to match what was already
2155 there. However, a store *to* an undefined location could clobber
2156 arbitrary memory, therefore, it has undefined behavior.
2157
2158 .. _poisonvalues:
2159
2160 Poison Values
2161 -------------
2162
2163 Poison values are similar to :ref:`undef values <undefvalues>`, however
2164 they also represent the fact that an instruction or constant expression
2165 which cannot evoke side effects has nevertheless detected a condition
2166 which results in undefined behavior.
2167
2168 There is currently no way of representing a poison value in the IR; they
2169 only exist when produced by operations such as :ref:`add <i_add>` with
2170 the ``nsw`` flag.
2171
2172 Poison value behavior is defined in terms of value *dependence*:
2173
2174 -  Values other than :ref:`phi <i_phi>` nodes depend on their operands.
2175 -  :ref:`Phi <i_phi>` nodes depend on the operand corresponding to
2176    their dynamic predecessor basic block.
2177 -  Function arguments depend on the corresponding actual argument values
2178    in the dynamic callers of their functions.
2179 -  :ref:`Call <i_call>` instructions depend on the :ref:`ret <i_ret>`
2180    instructions that dynamically transfer control back to them.
2181 -  :ref:`Invoke <i_invoke>` instructions depend on the
2182    :ref:`ret <i_ret>`, :ref:`resume <i_resume>`, or exception-throwing
2183    call instructions that dynamically transfer control back to them.
2184 -  Non-volatile loads and stores depend on the most recent stores to all
2185    of the referenced memory addresses, following the order in the IR
2186    (including loads and stores implied by intrinsics such as
2187    :ref:`@llvm.memcpy <int_memcpy>`.)
2188 -  An instruction with externally visible side effects depends on the
2189    most recent preceding instruction with externally visible side
2190    effects, following the order in the IR. (This includes :ref:`volatile
2191    operations <volatile>`.)
2192 -  An instruction *control-depends* on a :ref:`terminator
2193    instruction <terminators>` if the terminator instruction has
2194    multiple successors and the instruction is always executed when
2195    control transfers to one of the successors, and may not be executed
2196    when control is transferred to another.
2197 -  Additionally, an instruction also *control-depends* on a terminator
2198    instruction if the set of instructions it otherwise depends on would
2199    be different if the terminator had transferred control to a different
2200    successor.
2201 -  Dependence is transitive.
2202
2203 Poison Values have the same behavior as :ref:`undef values <undefvalues>`,
2204 with the additional affect that any instruction which has a *dependence*
2205 on a poison value has undefined behavior.
2206
2207 Here are some examples:
2208
2209 .. code-block:: llvm
2210
2211     entry:
2212       %poison = sub nuw i32 0, 1           ; Results in a poison value.
2213       %still_poison = and i32 %poison, 0   ; 0, but also poison.
2214       %poison_yet_again = getelementptr i32* @h, i32 %still_poison
2215       store i32 0, i32* %poison_yet_again  ; memory at @h[0] is poisoned
2216
2217       store i32 %poison, i32* @g           ; Poison value stored to memory.
2218       %poison2 = load i32* @g              ; Poison value loaded back from memory.
2219
2220       store volatile i32 %poison, i32* @g  ; External observation; undefined behavior.
2221
2222       %narrowaddr = bitcast i32* @g to i16*
2223       %wideaddr = bitcast i32* @g to i64*
2224       %poison3 = load i16* %narrowaddr     ; Returns a poison value.
2225       %poison4 = load i64* %wideaddr       ; Returns a poison value.
2226
2227       %cmp = icmp slt i32 %poison, 0       ; Returns a poison value.
2228       br i1 %cmp, label %true, label %end  ; Branch to either destination.
2229
2230     true:
2231       store volatile i32 0, i32* @g        ; This is control-dependent on %cmp, so
2232                                            ; it has undefined behavior.
2233       br label %end
2234
2235     end:
2236       %p = phi i32 [ 0, %entry ], [ 1, %true ]
2237                                            ; Both edges into this PHI are
2238                                            ; control-dependent on %cmp, so this
2239                                            ; always results in a poison value.
2240
2241       store volatile i32 0, i32* @g        ; This would depend on the store in %true
2242                                            ; if %cmp is true, or the store in %entry
2243                                            ; otherwise, so this is undefined behavior.
2244
2245       br i1 %cmp, label %second_true, label %second_end
2246                                            ; The same branch again, but this time the
2247                                            ; true block doesn't have side effects.
2248
2249     second_true:
2250       ; No side effects!
2251       ret void
2252
2253     second_end:
2254       store volatile i32 0, i32* @g        ; This time, the instruction always depends
2255                                            ; on the store in %end. Also, it is
2256                                            ; control-equivalent to %end, so this is
2257                                            ; well-defined (ignoring earlier undefined
2258                                            ; behavior in this example).
2259
2260 .. _blockaddress:
2261
2262 Addresses of Basic Blocks
2263 -------------------------
2264
2265 ``blockaddress(@function, %block)``
2266
2267 The '``blockaddress``' constant computes the address of the specified
2268 basic block in the specified function, and always has an ``i8*`` type.
2269 Taking the address of the entry block is illegal.
2270
2271 This value only has defined behavior when used as an operand to the
2272 ':ref:`indirectbr <i_indirectbr>`' instruction, or for comparisons
2273 against null. Pointer equality tests between labels addresses results in
2274 undefined behavior --- though, again, comparison against null is ok, and
2275 no label is equal to the null pointer. This may be passed around as an
2276 opaque pointer sized value as long as the bits are not inspected. This
2277 allows ``ptrtoint`` and arithmetic to be performed on these values so
2278 long as the original value is reconstituted before the ``indirectbr``
2279 instruction.
2280
2281 Finally, some targets may provide defined semantics when using the value
2282 as the operand to an inline assembly, but that is target specific.
2283
2284 .. _constantexprs:
2285
2286 Constant Expressions
2287 --------------------
2288
2289 Constant expressions are used to allow expressions involving other
2290 constants to be used as constants. Constant expressions may be of any
2291 :ref:`first class <t_firstclass>` type and may involve any LLVM operation
2292 that does not have side effects (e.g. load and call are not supported).
2293 The following is the syntax for constant expressions:
2294
2295 ``trunc (CST to TYPE)``
2296     Truncate a constant to another type. The bit size of CST must be
2297     larger than the bit size of TYPE. Both types must be integers.
2298 ``zext (CST to TYPE)``
2299     Zero extend a constant to another type. The bit size of CST must be
2300     smaller than the bit size of TYPE. Both types must be integers.
2301 ``sext (CST to TYPE)``
2302     Sign extend a constant to another type. The bit size of CST must be
2303     smaller than the bit size of TYPE. Both types must be integers.
2304 ``fptrunc (CST to TYPE)``
2305     Truncate a floating point constant to another floating point type.
2306     The size of CST must be larger than the size of TYPE. Both types
2307     must be floating point.
2308 ``fpext (CST to TYPE)``
2309     Floating point extend a constant to another type. The size of CST
2310     must be smaller or equal to the size of TYPE. Both types must be
2311     floating point.
2312 ``fptoui (CST to TYPE)``
2313     Convert a floating point constant to the corresponding unsigned
2314     integer constant. TYPE must be a scalar or vector integer type. CST
2315     must be of scalar or vector floating point type. Both CST and TYPE
2316     must be scalars, or vectors of the same number of elements. If the
2317     value won't fit in the integer type, the results are undefined.
2318 ``fptosi (CST to TYPE)``
2319     Convert a floating point constant to the corresponding signed
2320     integer constant. TYPE must be a scalar or vector integer type. CST
2321     must be of scalar or vector floating point type. Both CST and TYPE
2322     must be scalars, or vectors of the same number of elements. If the
2323     value won't fit in the integer type, the results are undefined.
2324 ``uitofp (CST to TYPE)``
2325     Convert an unsigned integer constant to the corresponding floating
2326     point constant. TYPE must be a scalar or vector floating point type.
2327     CST must be of scalar or vector integer type. Both CST and TYPE must
2328     be scalars, or vectors of the same number of elements. If the value
2329     won't fit in the floating point type, the results are undefined.
2330 ``sitofp (CST to TYPE)``
2331     Convert a signed integer constant to the corresponding floating
2332     point constant. TYPE must be a scalar or vector floating point type.
2333     CST must be of scalar or vector integer type. Both CST and TYPE must
2334     be scalars, or vectors of the same number of elements. If the value
2335     won't fit in the floating point type, the results are undefined.
2336 ``ptrtoint (CST to TYPE)``
2337     Convert a pointer typed constant to the corresponding integer
2338     constant. ``TYPE`` must be an integer type. ``CST`` must be of
2339     pointer type. The ``CST`` value is zero extended, truncated, or
2340     unchanged to make it fit in ``TYPE``.
2341 ``inttoptr (CST to TYPE)``
2342     Convert an integer constant to a pointer constant. TYPE must be a
2343     pointer type. CST must be of integer type. The CST value is zero
2344     extended, truncated, or unchanged to make it fit in a pointer size.
2345     This one is *really* dangerous!
2346 ``bitcast (CST to TYPE)``
2347     Convert a constant, CST, to another TYPE. The constraints of the
2348     operands are the same as those for the :ref:`bitcast
2349     instruction <i_bitcast>`.
2350 ``getelementptr (CSTPTR, IDX0, IDX1, ...)``, ``getelementptr inbounds (CSTPTR, IDX0, IDX1, ...)``
2351     Perform the :ref:`getelementptr operation <i_getelementptr>` on
2352     constants. As with the :ref:`getelementptr <i_getelementptr>`
2353     instruction, the index list may have zero or more indexes, which are
2354     required to make sense for the type of "CSTPTR".
2355 ``select (COND, VAL1, VAL2)``
2356     Perform the :ref:`select operation <i_select>` on constants.
2357 ``icmp COND (VAL1, VAL2)``
2358     Performs the :ref:`icmp operation <i_icmp>` on constants.
2359 ``fcmp COND (VAL1, VAL2)``
2360     Performs the :ref:`fcmp operation <i_fcmp>` on constants.
2361 ``extractelement (VAL, IDX)``
2362     Perform the :ref:`extractelement operation <i_extractelement>` on
2363     constants.
2364 ``insertelement (VAL, ELT, IDX)``
2365     Perform the :ref:`insertelement operation <i_insertelement>` on
2366     constants.
2367 ``shufflevector (VEC1, VEC2, IDXMASK)``
2368     Perform the :ref:`shufflevector operation <i_shufflevector>` on
2369     constants.
2370 ``extractvalue (VAL, IDX0, IDX1, ...)``
2371     Perform the :ref:`extractvalue operation <i_extractvalue>` on
2372     constants. The index list is interpreted in a similar manner as
2373     indices in a ':ref:`getelementptr <i_getelementptr>`' operation. At
2374     least one index value must be specified.
2375 ``insertvalue (VAL, ELT, IDX0, IDX1, ...)``
2376     Perform the :ref:`insertvalue operation <i_insertvalue>` on constants.
2377     The index list is interpreted in a similar manner as indices in a
2378     ':ref:`getelementptr <i_getelementptr>`' operation. At least one index
2379     value must be specified.
2380 ``OPCODE (LHS, RHS)``
2381     Perform the specified operation of the LHS and RHS constants. OPCODE
2382     may be any of the :ref:`binary <binaryops>` or :ref:`bitwise
2383     binary <bitwiseops>` operations. The constraints on operands are
2384     the same as those for the corresponding instruction (e.g. no bitwise
2385     operations on floating point values are allowed).
2386
2387 Other Values
2388 ============
2389
2390 .. _inlineasmexprs:
2391
2392 Inline Assembler Expressions
2393 ----------------------------
2394
2395 LLVM supports inline assembler expressions (as opposed to :ref:`Module-Level
2396 Inline Assembly <moduleasm>`) through the use of a special value. This
2397 value represents the inline assembler as a string (containing the
2398 instructions to emit), a list of operand constraints (stored as a
2399 string), a flag that indicates whether or not the inline asm expression
2400 has side effects, and a flag indicating whether the function containing
2401 the asm needs to align its stack conservatively. An example inline
2402 assembler expression is:
2403
2404 .. code-block:: llvm
2405
2406     i32 (i32) asm "bswap $0", "=r,r"
2407
2408 Inline assembler expressions may **only** be used as the callee operand
2409 of a :ref:`call <i_call>` or an :ref:`invoke <i_invoke>` instruction.
2410 Thus, typically we have:
2411
2412 .. code-block:: llvm
2413
2414     %X = call i32 asm "bswap $0", "=r,r"(i32 %Y)
2415
2416 Inline asms with side effects not visible in the constraint list must be
2417 marked as having side effects. This is done through the use of the
2418 '``sideeffect``' keyword, like so:
2419
2420 .. code-block:: llvm
2421
2422     call void asm sideeffect "eieio", ""()
2423
2424 In some cases inline asms will contain code that will not work unless
2425 the stack is aligned in some way, such as calls or SSE instructions on
2426 x86, yet will not contain code that does that alignment within the asm.
2427 The compiler should make conservative assumptions about what the asm
2428 might contain and should generate its usual stack alignment code in the
2429 prologue if the '``alignstack``' keyword is present:
2430
2431 .. code-block:: llvm
2432
2433     call void asm alignstack "eieio", ""()
2434
2435 Inline asms also support using non-standard assembly dialects. The
2436 assumed dialect is ATT. When the '``inteldialect``' keyword is present,
2437 the inline asm is using the Intel dialect. Currently, ATT and Intel are
2438 the only supported dialects. An example is:
2439
2440 .. code-block:: llvm
2441
2442     call void asm inteldialect "eieio", ""()
2443
2444 If multiple keywords appear the '``sideeffect``' keyword must come
2445 first, the '``alignstack``' keyword second and the '``inteldialect``'
2446 keyword last.
2447
2448 Inline Asm Metadata
2449 ^^^^^^^^^^^^^^^^^^^
2450
2451 The call instructions that wrap inline asm nodes may have a
2452 "``!srcloc``" MDNode attached to it that contains a list of constant
2453 integers. If present, the code generator will use the integer as the
2454 location cookie value when report errors through the ``LLVMContext``
2455 error reporting mechanisms. This allows a front-end to correlate backend
2456 errors that occur with inline asm back to the source code that produced
2457 it. For example:
2458
2459 .. code-block:: llvm
2460
2461     call void asm sideeffect "something bad", ""(), !srcloc !42
2462     ...
2463     !42 = !{ i32 1234567 }
2464
2465 It is up to the front-end to make sense of the magic numbers it places
2466 in the IR. If the MDNode contains multiple constants, the code generator
2467 will use the one that corresponds to the line of the asm that the error
2468 occurs on.
2469
2470 .. _metadata:
2471
2472 Metadata Nodes and Metadata Strings
2473 -----------------------------------
2474
2475 LLVM IR allows metadata to be attached to instructions in the program
2476 that can convey extra information about the code to the optimizers and
2477 code generator. One example application of metadata is source-level
2478 debug information. There are two metadata primitives: strings and nodes.
2479 All metadata has the ``metadata`` type and is identified in syntax by a
2480 preceding exclamation point ('``!``').
2481
2482 A metadata string is a string surrounded by double quotes. It can
2483 contain any character by escaping non-printable characters with
2484 "``\xx``" where "``xx``" is the two digit hex code. For example:
2485 "``!"test\00"``".
2486
2487 Metadata nodes are represented with notation similar to structure
2488 constants (a comma separated list of elements, surrounded by braces and
2489 preceded by an exclamation point). Metadata nodes can have any values as
2490 their operand. For example:
2491
2492 .. code-block:: llvm
2493
2494     !{ metadata !"test\00", i32 10}
2495
2496 A :ref:`named metadata <namedmetadatastructure>` is a collection of
2497 metadata nodes, which can be looked up in the module symbol table. For
2498 example:
2499
2500 .. code-block:: llvm
2501
2502     !foo =  metadata !{!4, !3}
2503
2504 Metadata can be used as function arguments. Here ``llvm.dbg.value``
2505 function is using two metadata arguments:
2506
2507 .. code-block:: llvm
2508
2509     call void @llvm.dbg.value(metadata !24, i64 0, metadata !25)
2510
2511 Metadata can be attached with an instruction. Here metadata ``!21`` is
2512 attached to the ``add`` instruction using the ``!dbg`` identifier:
2513
2514 .. code-block:: llvm
2515
2516     %indvar.next = add i64 %indvar, 1, !dbg !21
2517
2518 More information about specific metadata nodes recognized by the
2519 optimizers and code generator is found below.
2520
2521 '``tbaa``' Metadata
2522 ^^^^^^^^^^^^^^^^^^^
2523
2524 In LLVM IR, memory does not have types, so LLVM's own type system is not
2525 suitable for doing TBAA. Instead, metadata is added to the IR to
2526 describe a type system of a higher level language. This can be used to
2527 implement typical C/C++ TBAA, but it can also be used to implement
2528 custom alias analysis behavior for other languages.
2529
2530 The current metadata format is very simple. TBAA metadata nodes have up
2531 to three fields, e.g.:
2532
2533 .. code-block:: llvm
2534
2535     !0 = metadata !{ metadata !"an example type tree" }
2536     !1 = metadata !{ metadata !"int", metadata !0 }
2537     !2 = metadata !{ metadata !"float", metadata !0 }
2538     !3 = metadata !{ metadata !"const float", metadata !2, i64 1 }
2539
2540 The first field is an identity field. It can be any value, usually a
2541 metadata string, which uniquely identifies the type. The most important
2542 name in the tree is the name of the root node. Two trees with different
2543 root node names are entirely disjoint, even if they have leaves with
2544 common names.
2545
2546 The second field identifies the type's parent node in the tree, or is
2547 null or omitted for a root node. A type is considered to alias all of
2548 its descendants and all of its ancestors in the tree. Also, a type is
2549 considered to alias all types in other trees, so that bitcode produced
2550 from multiple front-ends is handled conservatively.
2551
2552 If the third field is present, it's an integer which if equal to 1
2553 indicates that the type is "constant" (meaning
2554 ``pointsToConstantMemory`` should return true; see `other useful
2555 AliasAnalysis methods <AliasAnalysis.html#OtherItfs>`_).
2556
2557 '``tbaa.struct``' Metadata
2558 ^^^^^^^^^^^^^^^^^^^^^^^^^^
2559
2560 The :ref:`llvm.memcpy <int_memcpy>` is often used to implement
2561 aggregate assignment operations in C and similar languages, however it
2562 is defined to copy a contiguous region of memory, which is more than
2563 strictly necessary for aggregate types which contain holes due to
2564 padding. Also, it doesn't contain any TBAA information about the fields
2565 of the aggregate.
2566
2567 ``!tbaa.struct`` metadata can describe which memory subregions in a
2568 memcpy are padding and what the TBAA tags of the struct are.
2569
2570 The current metadata format is very simple. ``!tbaa.struct`` metadata
2571 nodes are a list of operands which are in conceptual groups of three.
2572 For each group of three, the first operand gives the byte offset of a
2573 field in bytes, the second gives its size in bytes, and the third gives
2574 its tbaa tag. e.g.:
2575
2576 .. code-block:: llvm
2577
2578     !4 = metadata !{ i64 0, i64 4, metadata !1, i64 8, i64 4, metadata !2 }
2579
2580 This describes a struct with two fields. The first is at offset 0 bytes
2581 with size 4 bytes, and has tbaa tag !1. The second is at offset 8 bytes
2582 and has size 4 bytes and has tbaa tag !2.
2583
2584 Note that the fields need not be contiguous. In this example, there is a
2585 4 byte gap between the two fields. This gap represents padding which
2586 does not carry useful data and need not be preserved.
2587
2588 '``fpmath``' Metadata
2589 ^^^^^^^^^^^^^^^^^^^^^
2590
2591 ``fpmath`` metadata may be attached to any instruction of floating point
2592 type. It can be used to express the maximum acceptable error in the
2593 result of that instruction, in ULPs, thus potentially allowing the
2594 compiler to use a more efficient but less accurate method of computing
2595 it. ULP is defined as follows:
2596
2597     If ``x`` is a real number that lies between two finite consecutive
2598     floating-point numbers ``a`` and ``b``, without being equal to one
2599     of them, then ``ulp(x) = |b - a|``, otherwise ``ulp(x)`` is the
2600     distance between the two non-equal finite floating-point numbers
2601     nearest ``x``. Moreover, ``ulp(NaN)`` is ``NaN``.
2602
2603 The metadata node shall consist of a single positive floating point
2604 number representing the maximum relative error, for example:
2605
2606 .. code-block:: llvm
2607
2608     !0 = metadata !{ float 2.5 } ; maximum acceptable inaccuracy is 2.5 ULPs
2609
2610 '``range``' Metadata
2611 ^^^^^^^^^^^^^^^^^^^^
2612
2613 ``range`` metadata may be attached only to loads of integer types. It
2614 expresses the possible ranges the loaded value is in. The ranges are
2615 represented with a flattened list of integers. The loaded value is known
2616 to be in the union of the ranges defined by each consecutive pair. Each
2617 pair has the following properties:
2618
2619 -  The type must match the type loaded by the instruction.
2620 -  The pair ``a,b`` represents the range ``[a,b)``.
2621 -  Both ``a`` and ``b`` are constants.
2622 -  The range is allowed to wrap.
2623 -  The range should not represent the full or empty set. That is,
2624    ``a!=b``.
2625
2626 In addition, the pairs must be in signed order of the lower bound and
2627 they must be non-contiguous.
2628
2629 Examples:
2630
2631 .. code-block:: llvm
2632
2633       %a = load i8* %x, align 1, !range !0 ; Can only be 0 or 1
2634       %b = load i8* %y, align 1, !range !1 ; Can only be 255 (-1), 0 or 1
2635       %c = load i8* %z, align 1, !range !2 ; Can only be 0, 1, 3, 4 or 5
2636       %d = load i8* %z, align 1, !range !3 ; Can only be -2, -1, 3, 4 or 5
2637     ...
2638     !0 = metadata !{ i8 0, i8 2 }
2639     !1 = metadata !{ i8 255, i8 2 }
2640     !2 = metadata !{ i8 0, i8 2, i8 3, i8 6 }
2641     !3 = metadata !{ i8 -2, i8 0, i8 3, i8 6 }
2642
2643 '``llvm.loop``'
2644 ^^^^^^^^^^^^^^^
2645
2646 It is sometimes useful to attach information to loop constructs. Currently,
2647 loop metadata is implemented as metadata attached to the branch instruction
2648 in the loop latch block. This type of metadata refer to a metadata node that is
2649 guaranteed to be separate for each loop. The loop identifier metadata is
2650 specified with the name ``llvm.loop``.
2651
2652 The loop identifier metadata is implemented using a metadata that refers to
2653 itself to avoid merging it with any other identifier metadata, e.g.,
2654 during module linkage or function inlining. That is, each loop should refer
2655 to their own identification metadata even if they reside in separate functions.
2656 The following example contains loop identifier metadata for two separate loop
2657 constructs:
2658
2659 .. code-block:: llvm
2660
2661     !0 = metadata !{ metadata !0 }
2662     !1 = metadata !{ metadata !1 }
2663
2664 The loop identifier metadata can be used to specify additional per-loop
2665 metadata. Any operands after the first operand can be treated as user-defined
2666 metadata. For example the ``llvm.vectorizer.unroll`` metadata is understood
2667 by the loop vectorizer to indicate how many times to unroll the loop:
2668
2669 .. code-block:: llvm
2670
2671       br i1 %exitcond, label %._crit_edge, label %.lr.ph, !llvm.loop !0
2672     ...
2673     !0 = metadata !{ metadata !0, metadata !1 }
2674     !1 = metadata !{ metadata !"llvm.vectorizer.unroll", i32 2 }
2675
2676 '``llvm.mem``'
2677 ^^^^^^^^^^^^^^^
2678
2679 Metadata types used to annotate memory accesses with information helpful
2680 for optimizations are prefixed with ``llvm.mem``.
2681
2682 '``llvm.mem.parallel_loop_access``' Metadata
2683 ^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^
2684
2685 For a loop to be parallel, in addition to using
2686 the ``llvm.loop`` metadata to mark the loop latch branch instruction,
2687 also all of the memory accessing instructions in the loop body need to be
2688 marked with the ``llvm.mem.parallel_loop_access`` metadata. If there
2689 is at least one memory accessing instruction not marked with the metadata,
2690 the loop must be considered a sequential loop. This causes parallel loops to be
2691 converted to sequential loops due to optimization passes that are unaware of
2692 the parallel semantics and that insert new memory instructions to the loop
2693 body.
2694
2695 Example of a loop that is considered parallel due to its correct use of
2696 both ``llvm.loop`` and ``llvm.mem.parallel_loop_access``
2697 metadata types that refer to the same loop identifier metadata.
2698
2699 .. code-block:: llvm
2700
2701    for.body:
2702      ...
2703      %0 = load i32* %arrayidx, align 4, !llvm.mem.parallel_loop_access !0
2704      ...
2705      store i32 %0, i32* %arrayidx4, align 4, !llvm.mem.parallel_loop_access !0
2706      ...
2707      br i1 %exitcond, label %for.end, label %for.body, !llvm.loop !0
2708
2709    for.end:
2710    ...
2711    !0 = metadata !{ metadata !0 }
2712
2713 It is also possible to have nested parallel loops. In that case the
2714 memory accesses refer to a list of loop identifier metadata nodes instead of
2715 the loop identifier metadata node directly:
2716
2717 .. code-block:: llvm
2718
2719    outer.for.body:
2720    ...
2721
2722    inner.for.body:
2723      ...
2724      %0 = load i32* %arrayidx, align 4, !llvm.mem.parallel_loop_access !0
2725      ...
2726      store i32 %0, i32* %arrayidx4, align 4, !llvm.mem.parallel_loop_access !0
2727      ...
2728      br i1 %exitcond, label %inner.for.end, label %inner.for.body, !llvm.loop !1
2729
2730    inner.for.end:
2731      ...
2732      %0 = load i32* %arrayidx, align 4, !llvm.mem.parallel_loop_access !0
2733      ...
2734      store i32 %0, i32* %arrayidx4, align 4, !llvm.mem.parallel_loop_access !0
2735      ...
2736      br i1 %exitcond, label %outer.for.end, label %outer.for.body, !llvm.loop !2
2737
2738    outer.for.end:                                          ; preds = %for.body
2739    ...
2740    !0 = metadata !{ metadata !1, metadata !2 } ; a list of loop identifiers
2741    !1 = metadata !{ metadata !1 } ; an identifier for the inner loop
2742    !2 = metadata !{ metadata !2 } ; an identifier for the outer loop
2743
2744 '``llvm.vectorizer``'
2745 ^^^^^^^^^^^^^^^^^^^^^
2746
2747 Metadata prefixed with ``llvm.vectorizer`` is used to control per-loop
2748 vectorization parameters such as vectorization factor and unroll factor.
2749
2750 ``llvm.vectorizer`` metadata should be used in conjunction with ``llvm.loop``
2751 loop identification metadata.
2752
2753 '``llvm.vectorizer.unroll``' Metadata
2754 ^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^
2755
2756 This metadata instructs the loop vectorizer to unroll the specified
2757 loop exactly ``N`` times.
2758
2759 The first operand is the string ``llvm.vectorizer.unroll`` and the second
2760 operand is an integer specifying the unroll factor. For example:
2761
2762 .. code-block:: llvm
2763
2764    !0 = metadata !{ metadata !"llvm.vectorizer.unroll", i32 4 }
2765
2766 Note that setting ``llvm.vectorizer.unroll`` to 1 disables unrolling of the
2767 loop.
2768
2769 If ``llvm.vectorizer.unroll`` is set to 0 then the amount of unrolling will be
2770 determined automatically.
2771
2772 '``llvm.vectorizer.width``' Metadata
2773 ^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^
2774
2775 This metadata sets the target width of the vectorizer to ``N``. Without
2776 this metadata, the vectorizer will choose a width automatically.
2777 Regardless of this metadata, the vectorizer will only vectorize loops if
2778 it believes it is valid to do so.
2779
2780 The first operand is the string ``llvm.vectorizer.width`` and the second
2781 operand is an integer specifying the width. For example:
2782
2783 .. code-block:: llvm
2784
2785    !0 = metadata !{ metadata !"llvm.vectorizer.width", i32 4 }
2786
2787 Note that setting ``llvm.vectorizer.width`` to 1 disables vectorization of the
2788 loop.
2789
2790 If ``llvm.vectorizer.width`` is set to 0 then the width will be determined
2791 automatically.
2792
2793 Module Flags Metadata
2794 =====================
2795
2796 Information about the module as a whole is difficult to convey to LLVM's
2797 subsystems. The LLVM IR isn't sufficient to transmit this information.
2798 The ``llvm.module.flags`` named metadata exists in order to facilitate
2799 this. These flags are in the form of key / value pairs --- much like a
2800 dictionary --- making it easy for any subsystem who cares about a flag to
2801 look it up.
2802
2803 The ``llvm.module.flags`` metadata contains a list of metadata triplets.
2804 Each triplet has the following form:
2805
2806 -  The first element is a *behavior* flag, which specifies the behavior
2807    when two (or more) modules are merged together, and it encounters two
2808    (or more) metadata with the same ID. The supported behaviors are
2809    described below.
2810 -  The second element is a metadata string that is a unique ID for the
2811    metadata. Each module may only have one flag entry for each unique ID (not
2812    including entries with the **Require** behavior).
2813 -  The third element is the value of the flag.
2814
2815 When two (or more) modules are merged together, the resulting
2816 ``llvm.module.flags`` metadata is the union of the modules' flags. That is, for
2817 each unique metadata ID string, there will be exactly one entry in the merged
2818 modules ``llvm.module.flags`` metadata table, and the value for that entry will
2819 be determined by the merge behavior flag, as described below. The only exception
2820 is that entries with the *Require* behavior are always preserved.
2821
2822 The following behaviors are supported:
2823
2824 .. list-table::
2825    :header-rows: 1
2826    :widths: 10 90
2827
2828    * - Value
2829      - Behavior
2830
2831    * - 1
2832      - **Error**
2833            Emits an error if two values disagree, otherwise the resulting value
2834            is that of the operands.
2835
2836    * - 2
2837      - **Warning**
2838            Emits a warning if two values disagree. The result value will be the
2839            operand for the flag from the first module being linked.
2840
2841    * - 3
2842      - **Require**
2843            Adds a requirement that another module flag be present and have a
2844            specified value after linking is performed. The value must be a
2845            metadata pair, where the first element of the pair is the ID of the
2846            module flag to be restricted, and the second element of the pair is
2847            the value the module flag should be restricted to. This behavior can
2848            be used to restrict the allowable results (via triggering of an
2849            error) of linking IDs with the **Override** behavior.
2850
2851    * - 4
2852      - **Override**
2853            Uses the specified value, regardless of the behavior or value of the
2854            other module. If both modules specify **Override**, but the values
2855            differ, an error will be emitted.
2856
2857    * - 5
2858      - **Append**
2859            Appends the two values, which are required to be metadata nodes.
2860
2861    * - 6
2862      - **AppendUnique**
2863            Appends the two values, which are required to be metadata
2864            nodes. However, duplicate entries in the second list are dropped
2865            during the append operation.
2866
2867 It is an error for a particular unique flag ID to have multiple behaviors,
2868 except in the case of **Require** (which adds restrictions on another metadata
2869 value) or **Override**.
2870
2871 An example of module flags:
2872
2873 .. code-block:: llvm
2874
2875     !0 = metadata !{ i32 1, metadata !"foo", i32 1 }
2876     !1 = metadata !{ i32 4, metadata !"bar", i32 37 }
2877     !2 = metadata !{ i32 2, metadata !"qux", i32 42 }
2878     !3 = metadata !{ i32 3, metadata !"qux",
2879       metadata !{
2880         metadata !"foo", i32 1
2881       }
2882     }
2883     !llvm.module.flags = !{ !0, !1, !2, !3 }
2884
2885 -  Metadata ``!0`` has the ID ``!"foo"`` and the value '1'. The behavior
2886    if two or more ``!"foo"`` flags are seen is to emit an error if their
2887    values are not equal.
2888
2889 -  Metadata ``!1`` has the ID ``!"bar"`` and the value '37'. The
2890    behavior if two or more ``!"bar"`` flags are seen is to use the value
2891    '37'.
2892
2893 -  Metadata ``!2`` has the ID ``!"qux"`` and the value '42'. The
2894    behavior if two or more ``!"qux"`` flags are seen is to emit a
2895    warning if their values are not equal.
2896
2897 -  Metadata ``!3`` has the ID ``!"qux"`` and the value:
2898
2899    ::
2900
2901        metadata !{ metadata !"foo", i32 1 }
2902
2903    The behavior is to emit an error if the ``llvm.module.flags`` does not
2904    contain a flag with the ID ``!"foo"`` that has the value '1' after linking is
2905    performed.
2906
2907 Objective-C Garbage Collection Module Flags Metadata
2908 ----------------------------------------------------
2909
2910 On the Mach-O platform, Objective-C stores metadata about garbage
2911 collection in a special section called "image info". The metadata
2912 consists of a version number and a bitmask specifying what types of
2913 garbage collection are supported (if any) by the file. If two or more
2914 modules are linked together their garbage collection metadata needs to
2915 be merged rather than appended together.
2916
2917 The Objective-C garbage collection module flags metadata consists of the
2918 following key-value pairs:
2919
2920 .. list-table::
2921    :header-rows: 1
2922    :widths: 30 70
2923
2924    * - Key
2925      - Value
2926
2927    * - ``Objective-C Version``
2928      - **[Required]** --- The Objective-C ABI version. Valid values are 1 and 2.
2929
2930    * - ``Objective-C Image Info Version``
2931      - **[Required]** --- The version of the image info section. Currently
2932        always 0.
2933
2934    * - ``Objective-C Image Info Section``
2935      - **[Required]** --- The section to place the metadata. Valid values are
2936        ``"__OBJC, __image_info, regular"`` for Objective-C ABI version 1, and
2937        ``"__DATA,__objc_imageinfo, regular, no_dead_strip"`` for
2938        Objective-C ABI version 2.
2939
2940    * - ``Objective-C Garbage Collection``
2941      - **[Required]** --- Specifies whether garbage collection is supported or
2942        not. Valid values are 0, for no garbage collection, and 2, for garbage
2943        collection supported.
2944
2945    * - ``Objective-C GC Only``
2946      - **[Optional]** --- Specifies that only garbage collection is supported.
2947        If present, its value must be 6. This flag requires that the
2948        ``Objective-C Garbage Collection`` flag have the value 2.
2949
2950 Some important flag interactions:
2951
2952 -  If a module with ``Objective-C Garbage Collection`` set to 0 is
2953    merged with a module with ``Objective-C Garbage Collection`` set to
2954    2, then the resulting module has the
2955    ``Objective-C Garbage Collection`` flag set to 0.
2956 -  A module with ``Objective-C Garbage Collection`` set to 0 cannot be
2957    merged with a module with ``Objective-C GC Only`` set to 6.
2958
2959 Automatic Linker Flags Module Flags Metadata
2960 --------------------------------------------
2961
2962 Some targets support embedding flags to the linker inside individual object
2963 files. Typically this is used in conjunction with language extensions which
2964 allow source files to explicitly declare the libraries they depend on, and have
2965 these automatically be transmitted to the linker via object files.
2966
2967 These flags are encoded in the IR using metadata in the module flags section,
2968 using the ``Linker Options`` key. The merge behavior for this flag is required
2969 to be ``AppendUnique``, and the value for the key is expected to be a metadata
2970 node which should be a list of other metadata nodes, each of which should be a
2971 list of metadata strings defining linker options.
2972
2973 For example, the following metadata section specifies two separate sets of
2974 linker options, presumably to link against ``libz`` and the ``Cocoa``
2975 framework::
2976
2977     !0 = metadata !{ i32 6, metadata !"Linker Options",
2978        metadata !{
2979           metadata !{ metadata !"-lz" },
2980           metadata !{ metadata !"-framework", metadata !"Cocoa" } } }
2981     !llvm.module.flags = !{ !0 }
2982
2983 The metadata encoding as lists of lists of options, as opposed to a collapsed
2984 list of options, is chosen so that the IR encoding can use multiple option
2985 strings to specify e.g., a single library, while still having that specifier be
2986 preserved as an atomic element that can be recognized by a target specific
2987 assembly writer or object file emitter.
2988
2989 Each individual option is required to be either a valid option for the target's
2990 linker, or an option that is reserved by the target specific assembly writer or
2991 object file emitter. No other aspect of these options is defined by the IR.
2992
2993 .. _intrinsicglobalvariables:
2994
2995 Intrinsic Global Variables
2996 ==========================
2997
2998 LLVM has a number of "magic" global variables that contain data that
2999 affect code generation or other IR semantics. These are documented here.
3000 All globals of this sort should have a section specified as
3001 "``llvm.metadata``". This section and all globals that start with
3002 "``llvm.``" are reserved for use by LLVM.
3003
3004 .. _gv_llvmused:
3005
3006 The '``llvm.used``' Global Variable
3007 -----------------------------------
3008
3009 The ``@llvm.used`` global is an array which has
3010 :ref:`appending linkage <linkage_appending>`. This array contains a list of
3011 pointers to named global variables, functions and aliases which may optionally
3012 have a pointer cast formed of bitcast or getelementptr. For example, a legal
3013 use of it is:
3014
3015 .. code-block:: llvm
3016
3017     @X = global i8 4
3018     @Y = global i32 123
3019
3020     @llvm.used = appending global [2 x i8*] [
3021        i8* @X,
3022        i8* bitcast (i32* @Y to i8*)
3023     ], section "llvm.metadata"
3024
3025 If a symbol appears in the ``@llvm.used`` list, then the compiler, assembler,
3026 and linker are required to treat the symbol as if there is a reference to the
3027 symbol that it cannot see (which is why they have to be named). For example, if
3028 a variable has internal linkage and no references other than that from the
3029 ``@llvm.used`` list, it cannot be deleted. This is commonly used to represent
3030 references from inline asms and other things the compiler cannot "see", and
3031 corresponds to "``attribute((used))``" in GNU C.
3032
3033 On some targets, the code generator must emit a directive to the
3034 assembler or object file to prevent the assembler and linker from
3035 molesting the symbol.
3036
3037 .. _gv_llvmcompilerused:
3038
3039 The '``llvm.compiler.used``' Global Variable
3040 --------------------------------------------
3041
3042 The ``@llvm.compiler.used`` directive is the same as the ``@llvm.used``
3043 directive, except that it only prevents the compiler from touching the
3044 symbol. On targets that support it, this allows an intelligent linker to
3045 optimize references to the symbol without being impeded as it would be
3046 by ``@llvm.used``.
3047
3048 This is a rare construct that should only be used in rare circumstances,
3049 and should not be exposed to source languages.
3050
3051 .. _gv_llvmglobalctors:
3052
3053 The '``llvm.global_ctors``' Global Variable
3054 -------------------------------------------
3055
3056 .. code-block:: llvm
3057
3058     %0 = type { i32, void ()* }
3059     @llvm.global_ctors = appending global [1 x %0] [%0 { i32 65535, void ()* @ctor }]
3060
3061 The ``@llvm.global_ctors`` array contains a list of constructor
3062 functions and associated priorities. The functions referenced by this
3063 array will be called in ascending order of priority (i.e. lowest first)
3064 when the module is loaded. The order of functions with the same priority
3065 is not defined.
3066
3067 .. _llvmglobaldtors:
3068
3069 The '``llvm.global_dtors``' Global Variable
3070 -------------------------------------------
3071
3072 .. code-block:: llvm
3073
3074     %0 = type { i32, void ()* }
3075     @llvm.global_dtors = appending global [1 x %0] [%0 { i32 65535, void ()* @dtor }]
3076
3077 The ``@llvm.global_dtors`` array contains a list of destructor functions
3078 and associated priorities. The functions referenced by this array will
3079 be called in descending order of priority (i.e. highest first) when the
3080 module is loaded. The order of functions with the same priority is not
3081 defined.
3082
3083 Instruction Reference
3084 =====================
3085
3086 The LLVM instruction set consists of several different classifications
3087 of instructions: :ref:`terminator instructions <terminators>`, :ref:`binary
3088 instructions <binaryops>`, :ref:`bitwise binary
3089 instructions <bitwiseops>`, :ref:`memory instructions <memoryops>`, and
3090 :ref:`other instructions <otherops>`.
3091
3092 .. _terminators:
3093
3094 Terminator Instructions
3095 -----------------------
3096
3097 As mentioned :ref:`previously <functionstructure>`, every basic block in a
3098 program ends with a "Terminator" instruction, which indicates which
3099 block should be executed after the current block is finished. These
3100 terminator instructions typically yield a '``void``' value: they produce
3101 control flow, not values (the one exception being the
3102 ':ref:`invoke <i_invoke>`' instruction).
3103
3104 The terminator instructions are: ':ref:`ret <i_ret>`',
3105 ':ref:`br <i_br>`', ':ref:`switch <i_switch>`',
3106 ':ref:`indirectbr <i_indirectbr>`', ':ref:`invoke <i_invoke>`',
3107 ':ref:`resume <i_resume>`', and ':ref:`unreachable <i_unreachable>`'.
3108
3109 .. _i_ret:
3110
3111 '``ret``' Instruction
3112 ^^^^^^^^^^^^^^^^^^^^^
3113
3114 Syntax:
3115 """""""
3116
3117 ::
3118
3119       ret <type> <value>       ; Return a value from a non-void function
3120       ret void                 ; Return from void function
3121
3122 Overview:
3123 """""""""
3124
3125 The '``ret``' instruction is used to return control flow (and optionally
3126 a value) from a function back to the caller.
3127
3128 There are two forms of the '``ret``' instruction: one that returns a
3129 value and then causes control flow, and one that just causes control
3130 flow to occur.
3131
3132 Arguments:
3133 """"""""""
3134
3135 The '``ret``' instruction optionally accepts a single argument, the
3136 return value. The type of the return value must be a ':ref:`first
3137 class <t_firstclass>`' type.
3138
3139 A function is not :ref:`well formed <wellformed>` if it it has a non-void
3140 return type and contains a '``ret``' instruction with no return value or
3141 a return value with a type that does not match its type, or if it has a
3142 void return type and contains a '``ret``' instruction with a return
3143 value.
3144
3145 Semantics:
3146 """"""""""
3147
3148 When the '``ret``' instruction is executed, control flow returns back to
3149 the calling function's context. If the caller is a
3150 ":ref:`call <i_call>`" instruction, execution continues at the
3151 instruction after the call. If the caller was an
3152 ":ref:`invoke <i_invoke>`" instruction, execution continues at the
3153 beginning of the "normal" destination block. If the instruction returns
3154 a value, that value shall set the call or invoke instruction's return
3155 value.
3156
3157 Example:
3158 """"""""
3159
3160 .. code-block:: llvm
3161
3162       ret i32 5                       ; Return an integer value of 5
3163       ret void                        ; Return from a void function
3164       ret { i32, i8 } { i32 4, i8 2 } ; Return a struct of values 4 and 2
3165
3166 .. _i_br:
3167
3168 '``br``' Instruction
3169 ^^^^^^^^^^^^^^^^^^^^
3170
3171 Syntax:
3172 """""""
3173
3174 ::
3175
3176       br i1 <cond>, label <iftrue>, label <iffalse>
3177       br label <dest>          ; Unconditional branch
3178
3179 Overview:
3180 """""""""
3181
3182 The '``br``' instruction is used to cause control flow to transfer to a
3183 different basic block in the current function. There are two forms of
3184 this instruction, corresponding to a conditional branch and an
3185 unconditional branch.
3186
3187 Arguments:
3188 """"""""""
3189
3190 The conditional branch form of the '``br``' instruction takes a single
3191 '``i1``' value and two '``label``' values. The unconditional form of the
3192 '``br``' instruction takes a single '``label``' value as a target.
3193
3194 Semantics:
3195 """"""""""
3196
3197 Upon execution of a conditional '``br``' instruction, the '``i1``'
3198 argument is evaluated. If the value is ``true``, control flows to the
3199 '``iftrue``' ``label`` argument. If "cond" is ``false``, control flows
3200 to the '``iffalse``' ``label`` argument.
3201
3202 Example:
3203 """"""""
3204
3205 .. code-block:: llvm
3206
3207     Test:
3208       %cond = icmp eq i32 %a, %b
3209       br i1 %cond, label %IfEqual, label %IfUnequal
3210     IfEqual:
3211       ret i32 1
3212     IfUnequal:
3213       ret i32 0
3214
3215 .. _i_switch:
3216
3217 '``switch``' Instruction
3218 ^^^^^^^^^^^^^^^^^^^^^^^^
3219
3220 Syntax:
3221 """""""
3222
3223 ::
3224
3225       switch <intty> <value>, label <defaultdest> [ <intty> <val>, label <dest> ... ]
3226
3227 Overview:
3228 """""""""
3229
3230 The '``switch``' instruction is used to transfer control flow to one of
3231 several different places. It is a generalization of the '``br``'
3232 instruction, allowing a branch to occur to one of many possible
3233 destinations.
3234
3235 Arguments:
3236 """"""""""
3237
3238 The '``switch``' instruction uses three parameters: an integer
3239 comparison value '``value``', a default '``label``' destination, and an
3240 array of pairs of comparison value constants and '``label``'s. The table
3241 is not allowed to contain duplicate constant entries.
3242
3243 Semantics:
3244 """"""""""
3245
3246 The ``switch`` instruction specifies a table of values and destinations.
3247 When the '``switch``' instruction is executed, this table is searched
3248 for the given value. If the value is found, control flow is transferred
3249 to the corresponding destination; otherwise, control flow is transferred
3250 to the default destination.
3251
3252 Implementation:
3253 """""""""""""""
3254
3255 Depending on properties of the target machine and the particular
3256 ``switch`` instruction, this instruction may be code generated in
3257 different ways. For example, it could be generated as a series of
3258 chained conditional branches or with a lookup table.
3259
3260 Example:
3261 """"""""
3262
3263 .. code-block:: llvm
3264
3265      ; Emulate a conditional br instruction
3266      %Val = zext i1 %value to i32
3267      switch i32 %Val, label %truedest [ i32 0, label %falsedest ]
3268
3269      ; Emulate an unconditional br instruction
3270      switch i32 0, label %dest [ ]
3271
3272      ; Implement a jump table:
3273      switch i32 %val, label %otherwise [ i32 0, label %onzero
3274                                          i32 1, label %onone
3275                                          i32 2, label %ontwo ]
3276
3277 .. _i_indirectbr:
3278
3279 '``indirectbr``' Instruction
3280 ^^^^^^^^^^^^^^^^^^^^^^^^^^^^
3281
3282 Syntax:
3283 """""""
3284
3285 ::
3286
3287       indirectbr <somety>* <address>, [ label <dest1>, label <dest2>, ... ]
3288
3289 Overview:
3290 """""""""
3291
3292 The '``indirectbr``' instruction implements an indirect branch to a
3293 label within the current function, whose address is specified by
3294 "``address``". Address must be derived from a
3295 :ref:`blockaddress <blockaddress>` constant.
3296
3297 Arguments:
3298 """"""""""
3299
3300 The '``address``' argument is the address of the label to jump to. The
3301 rest of the arguments indicate the full set of possible destinations
3302 that the address may point to. Blocks are allowed to occur multiple
3303 times in the destination list, though this isn't particularly useful.
3304
3305 This destination list is required so that dataflow analysis has an
3306 accurate understanding of the CFG.
3307
3308 Semantics:
3309 """"""""""
3310
3311 Control transfers to the block specified in the address argument. All
3312 possible destination blocks must be listed in the label list, otherwise
3313 this instruction has undefined behavior. This implies that jumps to
3314 labels defined in other functions have undefined behavior as well.
3315
3316 Implementation:
3317 """""""""""""""
3318
3319 This is typically implemented with a jump through a register.
3320
3321 Example:
3322 """"""""
3323
3324 .. code-block:: llvm
3325
3326      indirectbr i8* %Addr, [ label %bb1, label %bb2, label %bb3 ]
3327
3328 .. _i_invoke:
3329
3330 '``invoke``' Instruction
3331 ^^^^^^^^^^^^^^^^^^^^^^^^
3332
3333 Syntax:
3334 """""""
3335
3336 ::
3337
3338       <result> = invoke [cconv] [ret attrs] <ptr to function ty> <function ptr val>(<function args>) [fn attrs]
3339                     to label <normal label> unwind label <exception label>
3340
3341 Overview:
3342 """""""""
3343
3344 The '``invoke``' instruction causes control to transfer to a specified
3345 function, with the possibility of control flow transfer to either the
3346 '``normal``' label or the '``exception``' label. If the callee function
3347 returns with the "``ret``" instruction, control flow will return to the
3348 "normal" label. If the callee (or any indirect callees) returns via the
3349 ":ref:`resume <i_resume>`" instruction or other exception handling
3350 mechanism, control is interrupted and continued at the dynamically
3351 nearest "exception" label.
3352
3353 The '``exception``' label is a `landing
3354 pad <ExceptionHandling.html#overview>`_ for the exception. As such,
3355 '``exception``' label is required to have the
3356 ":ref:`landingpad <i_landingpad>`" instruction, which contains the
3357 information about the behavior of the program after unwinding happens,
3358 as its first non-PHI instruction. The restrictions on the
3359 "``landingpad``" instruction's tightly couples it to the "``invoke``"
3360 instruction, so that the important information contained within the
3361 "``landingpad``" instruction can't be lost through normal code motion.
3362
3363 Arguments:
3364 """"""""""
3365
3366 This instruction requires several arguments:
3367
3368 #. The optional "cconv" marker indicates which :ref:`calling
3369    convention <callingconv>` the call should use. If none is
3370    specified, the call defaults to using C calling conventions.
3371 #. The optional :ref:`Parameter Attributes <paramattrs>` list for return
3372    values. Only '``zeroext``', '``signext``', and '``inreg``' attributes
3373    are valid here.
3374 #. '``ptr to function ty``': shall be the signature of the pointer to
3375    function value being invoked. In most cases, this is a direct
3376    function invocation, but indirect ``invoke``'s are just as possible,
3377    branching off an arbitrary pointer to function value.
3378 #. '``function ptr val``': An LLVM value containing a pointer to a
3379    function to be invoked.
3380 #. '``function args``': argument list whose types match the function
3381    signature argument types and parameter attributes. All arguments must
3382    be of :ref:`first class <t_firstclass>` type. If the function signature
3383    indicates the function accepts a variable number of arguments, the
3384    extra arguments can be specified.
3385 #. '``normal label``': the label reached when the called function
3386    executes a '``ret``' instruction.
3387 #. '``exception label``': the label reached when a callee returns via
3388    the :ref:`resume <i_resume>` instruction or other exception handling
3389    mechanism.
3390 #. The optional :ref:`function attributes <fnattrs>` list. Only
3391    '``noreturn``', '``nounwind``', '``readonly``' and '``readnone``'
3392    attributes are valid here.
3393
3394 Semantics:
3395 """"""""""
3396
3397 This instruction is designed to operate as a standard '``call``'
3398 instruction in most regards. The primary difference is that it
3399 establishes an association with a label, which is used by the runtime
3400 library to unwind the stack.
3401
3402 This instruction is used in languages with destructors to ensure that
3403 proper cleanup is performed in the case of either a ``longjmp`` or a
3404 thrown exception. Additionally, this is important for implementation of
3405 '``catch``' clauses in high-level languages that support them.
3406
3407 For the purposes of the SSA form, the definition of the value returned
3408 by the '``invoke``' instruction is deemed to occur on the edge from the
3409 current block to the "normal" label. If the callee unwinds then no
3410 return value is available.
3411
3412 Example:
3413 """"""""
3414
3415 .. code-block:: llvm
3416
3417       %retval = invoke i32 @Test(i32 15) to label %Continue
3418                   unwind label %TestCleanup              ; {i32}:retval set
3419       %retval = invoke coldcc i32 %Testfnptr(i32 15) to label %Continue
3420                   unwind label %TestCleanup              ; {i32}:retval set
3421
3422 .. _i_resume:
3423
3424 '``resume``' Instruction
3425 ^^^^^^^^^^^^^^^^^^^^^^^^
3426
3427 Syntax:
3428 """""""
3429
3430 ::
3431
3432       resume <type> <value>
3433
3434 Overview:
3435 """""""""
3436
3437 The '``resume``' instruction is a terminator instruction that has no
3438 successors.
3439
3440 Arguments:
3441 """"""""""
3442
3443 The '``resume``' instruction requires one argument, which must have the
3444 same type as the result of any '``landingpad``' instruction in the same
3445 function.
3446
3447 Semantics:
3448 """"""""""
3449
3450 The '``resume``' instruction resumes propagation of an existing
3451 (in-flight) exception whose unwinding was interrupted with a
3452 :ref:`landingpad <i_landingpad>` instruction.
3453
3454 Example:
3455 """"""""
3456
3457 .. code-block:: llvm
3458
3459       resume { i8*, i32 } %exn
3460
3461 .. _i_unreachable:
3462
3463 '``unreachable``' Instruction
3464 ^^^^^^^^^^^^^^^^^^^^^^^^^^^^^
3465
3466 Syntax:
3467 """""""
3468
3469 ::
3470
3471       unreachable
3472
3473 Overview:
3474 """""""""
3475
3476 The '``unreachable``' instruction has no defined semantics. This
3477 instruction is used to inform the optimizer that a particular portion of
3478 the code is not reachable. This can be used to indicate that the code
3479 after a no-return function cannot be reached, and other facts.
3480
3481 Semantics:
3482 """"""""""
3483
3484 The '``unreachable``' instruction has no defined semantics.
3485
3486 .. _binaryops:
3487
3488 Binary Operations
3489 -----------------
3490
3491 Binary operators are used to do most of the computation in a program.
3492 They require two operands of the same type, execute an operation on
3493 them, and produce a single value. The operands might represent multiple
3494 data, as is the case with the :ref:`vector <t_vector>` data type. The
3495 result value has the same type as its operands.
3496
3497 There are several different binary operators:
3498
3499 .. _i_add:
3500
3501 '``add``' Instruction
3502 ^^^^^^^^^^^^^^^^^^^^^
3503
3504 Syntax:
3505 """""""
3506
3507 ::
3508
3509       <result> = add <ty> <op1>, <op2>          ; yields {ty}:result
3510       <result> = add nuw <ty> <op1>, <op2>      ; yields {ty}:result
3511       <result> = add nsw <ty> <op1>, <op2>      ; yields {ty}:result
3512       <result> = add nuw nsw <ty> <op1>, <op2>  ; yields {ty}:result
3513
3514 Overview:
3515 """""""""
3516
3517 The '``add``' instruction returns the sum of its two operands.
3518
3519 Arguments:
3520 """"""""""
3521
3522 The two arguments to the '``add``' instruction must be
3523 :ref:`integer <t_integer>` or :ref:`vector <t_vector>` of integer values. Both
3524 arguments must have identical types.
3525
3526 Semantics:
3527 """"""""""
3528
3529 The value produced is the integer sum of the two operands.
3530
3531 If the sum has unsigned overflow, the result returned is the
3532 mathematical result modulo 2\ :sup:`n`\ , where n is the bit width of
3533 the result.
3534
3535 Because LLVM integers use a two's complement representation, this
3536 instruction is appropriate for both signed and unsigned integers.
3537
3538 ``nuw`` and ``nsw`` stand for "No Unsigned Wrap" and "No Signed Wrap",
3539 respectively. If the ``nuw`` and/or ``nsw`` keywords are present, the
3540 result value of the ``add`` is a :ref:`poison value <poisonvalues>` if
3541 unsigned and/or signed overflow, respectively, occurs.
3542
3543 Example:
3544 """"""""
3545
3546 .. code-block:: llvm
3547
3548       <result> = add i32 4, %var          ; yields {i32}:result = 4 + %var
3549
3550 .. _i_fadd:
3551
3552 '``fadd``' Instruction
3553 ^^^^^^^^^^^^^^^^^^^^^^
3554
3555 Syntax:
3556 """""""
3557
3558 ::
3559
3560       <result> = fadd [fast-math flags]* <ty> <op1>, <op2>   ; yields {ty}:result
3561
3562 Overview:
3563 """""""""
3564
3565 The '``fadd``' instruction returns the sum of its two operands.
3566
3567 Arguments:
3568 """"""""""
3569
3570 The two arguments to the '``fadd``' instruction must be :ref:`floating
3571 point <t_floating>` or :ref:`vector <t_vector>` of floating point values.
3572 Both arguments must have identical types.
3573
3574 Semantics:
3575 """"""""""
3576
3577 The value produced is the floating point sum of the two operands. This
3578 instruction can also take any number of :ref:`fast-math flags <fastmath>`,
3579 which are optimization hints to enable otherwise unsafe floating point
3580 optimizations:
3581
3582 Example:
3583 """"""""
3584
3585 .. code-block:: llvm
3586
3587       <result> = fadd float 4.0, %var          ; yields {float}:result = 4.0 + %var
3588
3589 '``sub``' Instruction
3590 ^^^^^^^^^^^^^^^^^^^^^
3591
3592 Syntax:
3593 """""""
3594
3595 ::
3596
3597       <result> = sub <ty> <op1>, <op2>          ; yields {ty}:result
3598       <result> = sub nuw <ty> <op1>, <op2>      ; yields {ty}:result
3599       <result> = sub nsw <ty> <op1>, <op2>      ; yields {ty}:result
3600       <result> = sub nuw nsw <ty> <op1>, <op2>  ; yields {ty}:result
3601
3602 Overview:
3603 """""""""
3604
3605 The '``sub``' instruction returns the difference of its two operands.
3606
3607 Note that the '``sub``' instruction is used to represent the '``neg``'
3608 instruction present in most other intermediate representations.
3609
3610 Arguments:
3611 """"""""""
3612
3613 The two arguments to the '``sub``' instruction must be
3614 :ref:`integer <t_integer>` or :ref:`vector <t_vector>` of integer values. Both
3615 arguments must have identical types.
3616
3617 Semantics:
3618 """"""""""
3619
3620 The value produced is the integer difference of the two operands.
3621
3622 If the difference has unsigned overflow, the result returned is the
3623 mathematical result modulo 2\ :sup:`n`\ , where n is the bit width of
3624 the result.
3625
3626 Because LLVM integers use a two's complement representation, this
3627 instruction is appropriate for both signed and unsigned integers.
3628
3629 ``nuw`` and ``nsw`` stand for "No Unsigned Wrap" and "No Signed Wrap",
3630 respectively. If the ``nuw`` and/or ``nsw`` keywords are present, the
3631 result value of the ``sub`` is a :ref:`poison value <poisonvalues>` if
3632 unsigned and/or signed overflow, respectively, occurs.
3633
3634 Example:
3635 """"""""
3636
3637 .. code-block:: llvm
3638
3639       <result> = sub i32 4, %var          ; yields {i32}:result = 4 - %var
3640       <result> = sub i32 0, %val          ; yields {i32}:result = -%var
3641
3642 .. _i_fsub:
3643
3644 '``fsub``' Instruction
3645 ^^^^^^^^^^^^^^^^^^^^^^
3646
3647 Syntax:
3648 """""""
3649
3650 ::
3651
3652       <result> = fsub [fast-math flags]* <ty> <op1>, <op2>   ; yields {ty}:result
3653
3654 Overview:
3655 """""""""
3656
3657 The '``fsub``' instruction returns the difference of its two operands.
3658
3659 Note that the '``fsub``' instruction is used to represent the '``fneg``'
3660 instruction present in most other intermediate representations.
3661
3662 Arguments:
3663 """"""""""
3664
3665 The two arguments to the '``fsub``' instruction must be :ref:`floating
3666 point <t_floating>` or :ref:`vector <t_vector>` of floating point values.
3667 Both arguments must have identical types.
3668
3669 Semantics:
3670 """"""""""
3671
3672 The value produced is the floating point difference of the two operands.
3673 This instruction can also take any number of :ref:`fast-math
3674 flags <fastmath>`, which are optimization hints to enable otherwise
3675 unsafe floating point optimizations:
3676
3677 Example:
3678 """"""""
3679
3680 .. code-block:: llvm
3681
3682       <result> = fsub float 4.0, %var           ; yields {float}:result = 4.0 - %var
3683       <result> = fsub float -0.0, %val          ; yields {float}:result = -%var
3684
3685 '``mul``' Instruction
3686 ^^^^^^^^^^^^^^^^^^^^^
3687
3688 Syntax:
3689 """""""
3690
3691 ::
3692
3693       <result> = mul <ty> <op1>, <op2>          ; yields {ty}:result
3694       <result> = mul nuw <ty> <op1>, <op2>      ; yields {ty}:result
3695       <result> = mul nsw <ty> <op1>, <op2>      ; yields {ty}:result
3696       <result> = mul nuw nsw <ty> <op1>, <op2>  ; yields {ty}:result
3697
3698 Overview:
3699 """""""""
3700
3701 The '``mul``' instruction returns the product of its two operands.
3702
3703 Arguments:
3704 """"""""""
3705
3706 The two arguments to the '``mul``' instruction must be
3707 :ref:`integer <t_integer>` or :ref:`vector <t_vector>` of integer values. Both
3708 arguments must have identical types.
3709
3710 Semantics:
3711 """"""""""
3712
3713 The value produced is the integer product of the two operands.
3714
3715 If the result of the multiplication has unsigned overflow, the result
3716 returned is the mathematical result modulo 2\ :sup:`n`\ , where n is the
3717 bit width of the result.
3718
3719 Because LLVM integers use a two's complement representation, and the
3720 result is the same width as the operands, this instruction returns the
3721 correct result for both signed and unsigned integers. If a full product
3722 (e.g. ``i32`` * ``i32`` -> ``i64``) is needed, the operands should be
3723 sign-extended or zero-extended as appropriate to the width of the full
3724 product.
3725
3726 ``nuw`` and ``nsw`` stand for "No Unsigned Wrap" and "No Signed Wrap",
3727 respectively. If the ``nuw`` and/or ``nsw`` keywords are present, the
3728 result value of the ``mul`` is a :ref:`poison value <poisonvalues>` if
3729 unsigned and/or signed overflow, respectively, occurs.
3730
3731 Example:
3732 """"""""
3733
3734 .. code-block:: llvm
3735
3736       <result> = mul i32 4, %var          ; yields {i32}:result = 4 * %var
3737
3738 .. _i_fmul:
3739
3740 '``fmul``' Instruction
3741 ^^^^^^^^^^^^^^^^^^^^^^
3742
3743 Syntax:
3744 """""""
3745
3746 ::
3747
3748       <result> = fmul [fast-math flags]* <ty> <op1>, <op2>   ; yields {ty}:result
3749
3750 Overview:
3751 """""""""
3752
3753 The '``fmul``' instruction returns the product of its two operands.
3754
3755 Arguments:
3756 """"""""""
3757
3758 The two arguments to the '``fmul``' instruction must be :ref:`floating
3759 point <t_floating>` or :ref:`vector <t_vector>` of floating point values.
3760 Both arguments must have identical types.
3761
3762 Semantics:
3763 """"""""""
3764
3765 The value produced is the floating point product of the two operands.
3766 This instruction can also take any number of :ref:`fast-math
3767 flags <fastmath>`, which are optimization hints to enable otherwise
3768 unsafe floating point optimizations:
3769
3770 Example:
3771 """"""""
3772
3773 .. code-block:: llvm
3774
3775       <result> = fmul float 4.0, %var          ; yields {float}:result = 4.0 * %var
3776
3777 '``udiv``' Instruction
3778 ^^^^^^^^^^^^^^^^^^^^^^
3779
3780 Syntax:
3781 """""""
3782
3783 ::
3784
3785       <result> = udiv <ty> <op1>, <op2>         ; yields {ty}:result
3786       <result> = udiv exact <ty> <op1>, <op2>   ; yields {ty}:result
3787
3788 Overview:
3789 """""""""
3790
3791 The '``udiv``' instruction returns the quotient of its two operands.
3792
3793 Arguments:
3794 """"""""""
3795
3796 The two arguments to the '``udiv``' instruction must be
3797 :ref:`integer <t_integer>` or :ref:`vector <t_vector>` of integer values. Both
3798 arguments must have identical types.
3799
3800 Semantics:
3801 """"""""""
3802
3803 The value produced is the unsigned integer quotient of the two operands.
3804
3805 Note that unsigned integer division and signed integer division are
3806 distinct operations; for signed integer division, use '``sdiv``'.
3807
3808 Division by zero leads to undefined behavior.
3809
3810 If the ``exact`` keyword is present, the result value of the ``udiv`` is
3811 a :ref:`poison value <poisonvalues>` if %op1 is not a multiple of %op2 (as
3812 such, "((a udiv exact b) mul b) == a").
3813
3814 Example:
3815 """"""""
3816
3817 .. code-block:: llvm
3818
3819       <result> = udiv i32 4, %var          ; yields {i32}:result = 4 / %var
3820
3821 '``sdiv``' Instruction
3822 ^^^^^^^^^^^^^^^^^^^^^^
3823
3824 Syntax:
3825 """""""
3826
3827 ::
3828
3829       <result> = sdiv <ty> <op1>, <op2>         ; yields {ty}:result
3830       <result> = sdiv exact <ty> <op1>, <op2>   ; yields {ty}:result
3831
3832 Overview:
3833 """""""""
3834
3835 The '``sdiv``' instruction returns the quotient of its two operands.
3836
3837 Arguments:
3838 """"""""""
3839
3840 The two arguments to the '``sdiv``' instruction must be
3841 :ref:`integer <t_integer>` or :ref:`vector <t_vector>` of integer values. Both
3842 arguments must have identical types.
3843
3844 Semantics:
3845 """"""""""
3846
3847 The value produced is the signed integer quotient of the two operands
3848 rounded towards zero.
3849
3850 Note that signed integer division and unsigned integer division are
3851 distinct operations; for unsigned integer division, use '``udiv``'.
3852
3853 Division by zero leads to undefined behavior. Overflow also leads to
3854 undefined behavior; this is a rare case, but can occur, for example, by
3855 doing a 32-bit division of -2147483648 by -1.
3856
3857 If the ``exact`` keyword is present, the result value of the ``sdiv`` is
3858 a :ref:`poison value <poisonvalues>` if the result would be rounded.
3859
3860 Example:
3861 """"""""
3862
3863 .. code-block:: llvm
3864
3865       <result> = sdiv i32 4, %var          ; yields {i32}:result = 4 / %var
3866
3867 .. _i_fdiv:
3868
3869 '``fdiv``' Instruction
3870 ^^^^^^^^^^^^^^^^^^^^^^
3871
3872 Syntax:
3873 """""""
3874
3875 ::
3876
3877       <result> = fdiv [fast-math flags]* <ty> <op1>, <op2>   ; yields {ty}:result
3878
3879 Overview:
3880 """""""""
3881
3882 The '``fdiv``' instruction returns the quotient of its two operands.
3883
3884 Arguments:
3885 """"""""""
3886
3887 The two arguments to the '``fdiv``' instruction must be :ref:`floating
3888 point <t_floating>` or :ref:`vector <t_vector>` of floating point values.
3889 Both arguments must have identical types.
3890
3891 Semantics:
3892 """"""""""
3893
3894 The value produced is the floating point quotient of the two operands.
3895 This instruction can also take any number of :ref:`fast-math
3896 flags <fastmath>`, which are optimization hints to enable otherwise
3897 unsafe floating point optimizations:
3898
3899 Example:
3900 """"""""
3901
3902 .. code-block:: llvm
3903
3904       <result> = fdiv float 4.0, %var          ; yields {float}:result = 4.0 / %var
3905
3906 '``urem``' Instruction
3907 ^^^^^^^^^^^^^^^^^^^^^^
3908
3909 Syntax:
3910 """""""
3911
3912 ::
3913
3914       <result> = urem <ty> <op1>, <op2>   ; yields {ty}:result
3915
3916 Overview:
3917 """""""""
3918
3919 The '``urem``' instruction returns the remainder from the unsigned
3920 division of its two arguments.
3921
3922 Arguments:
3923 """"""""""
3924
3925 The two arguments to the '``urem``' instruction must be
3926 :ref:`integer <t_integer>` or :ref:`vector <t_vector>` of integer values. Both
3927 arguments must have identical types.
3928
3929 Semantics:
3930 """"""""""
3931
3932 This instruction returns the unsigned integer *remainder* of a division.
3933 This instruction always performs an unsigned division to get the
3934 remainder.
3935
3936 Note that unsigned integer remainder and signed integer remainder are
3937 distinct operations; for signed integer remainder, use '``srem``'.
3938
3939 Taking the remainder of a division by zero leads to undefined behavior.
3940
3941 Example:
3942 """"""""
3943
3944 .. code-block:: llvm
3945
3946       <result> = urem i32 4, %var          ; yields {i32}:result = 4 % %var
3947
3948 '``srem``' Instruction
3949 ^^^^^^^^^^^^^^^^^^^^^^
3950
3951 Syntax:
3952 """""""
3953
3954 ::
3955
3956       <result> = srem <ty> <op1>, <op2>   ; yields {ty}:result
3957
3958 Overview:
3959 """""""""
3960
3961 The '``srem``' instruction returns the remainder from the signed
3962 division of its two operands. This instruction can also take
3963 :ref:`vector <t_vector>` versions of the values in which case the elements
3964 must be integers.
3965
3966 Arguments:
3967 """"""""""
3968
3969 The two arguments to the '``srem``' instruction must be
3970 :ref:`integer <t_integer>` or :ref:`vector <t_vector>` of integer values. Both
3971 arguments must have identical types.
3972
3973 Semantics:
3974 """"""""""
3975
3976 This instruction returns the *remainder* of a division (where the result
3977 is either zero or has the same sign as the dividend, ``op1``), not the
3978 *modulo* operator (where the result is either zero or has the same sign
3979 as the divisor, ``op2``) of a value. For more information about the
3980 difference, see `The Math
3981 Forum <http://mathforum.org/dr.math/problems/anne.4.28.99.html>`_. For a
3982 table of how this is implemented in various languages, please see
3983 `Wikipedia: modulo
3984 operation <http://en.wikipedia.org/wiki/Modulo_operation>`_.
3985
3986 Note that signed integer remainder and unsigned integer remainder are
3987 distinct operations; for unsigned integer remainder, use '``urem``'.
3988
3989 Taking the remainder of a division by zero leads to undefined behavior.
3990 Overflow also leads to undefined behavior; this is a rare case, but can
3991 occur, for example, by taking the remainder of a 32-bit division of
3992 -2147483648 by -1. (The remainder doesn't actually overflow, but this
3993 rule lets srem be implemented using instructions that return both the
3994 result of the division and the remainder.)
3995
3996 Example:
3997 """"""""
3998
3999 .. code-block:: llvm
4000
4001       <result> = srem i32 4, %var          ; yields {i32}:result = 4 % %var
4002
4003 .. _i_frem:
4004
4005 '``frem``' Instruction
4006 ^^^^^^^^^^^^^^^^^^^^^^
4007
4008 Syntax:
4009 """""""
4010
4011 ::
4012
4013       <result> = frem [fast-math flags]* <ty> <op1>, <op2>   ; yields {ty}:result
4014
4015 Overview:
4016 """""""""
4017
4018 The '``frem``' instruction returns the remainder from the division of
4019 its two operands.
4020
4021 Arguments:
4022 """"""""""
4023
4024 The two arguments to the '``frem``' instruction must be :ref:`floating
4025 point <t_floating>` or :ref:`vector <t_vector>` of floating point values.
4026 Both arguments must have identical types.
4027
4028 Semantics:
4029 """"""""""
4030
4031 This instruction returns the *remainder* of a division. The remainder
4032 has the same sign as the dividend. This instruction can also take any
4033 number of :ref:`fast-math flags <fastmath>`, which are optimization hints
4034 to enable otherwise unsafe floating point optimizations:
4035
4036 Example:
4037 """"""""
4038
4039 .. code-block:: llvm
4040
4041       <result> = frem float 4.0, %var          ; yields {float}:result = 4.0 % %var
4042
4043 .. _bitwiseops:
4044
4045 Bitwise Binary Operations
4046 -------------------------
4047
4048 Bitwise binary operators are used to do various forms of bit-twiddling
4049 in a program. They are generally very efficient instructions and can
4050 commonly be strength reduced from other instructions. They require two
4051 operands of the same type, execute an operation on them, and produce a
4052 single value. The resulting value is the same type as its operands.
4053
4054 '``shl``' Instruction
4055 ^^^^^^^^^^^^^^^^^^^^^
4056
4057 Syntax:
4058 """""""
4059
4060 ::
4061
4062       <result> = shl <ty> <op1>, <op2>           ; yields {ty}:result
4063       <result> = shl nuw <ty> <op1>, <op2>       ; yields {ty}:result
4064       <result> = shl nsw <ty> <op1>, <op2>       ; yields {ty}:result
4065       <result> = shl nuw nsw <ty> <op1>, <op2>   ; yields {ty}:result
4066
4067 Overview:
4068 """""""""
4069
4070 The '``shl``' instruction returns the first operand shifted to the left
4071 a specified number of bits.
4072
4073 Arguments:
4074 """"""""""
4075
4076 Both arguments to the '``shl``' instruction must be the same
4077 :ref:`integer <t_integer>` or :ref:`vector <t_vector>` of integer type.
4078 '``op2``' is treated as an unsigned value.
4079
4080 Semantics:
4081 """"""""""
4082
4083 The value produced is ``op1`` \* 2\ :sup:`op2` mod 2\ :sup:`n`,
4084 where ``n`` is the width of the result. If ``op2`` is (statically or
4085 dynamically) negative or equal to or larger than the number of bits in
4086 ``op1``, the result is undefined. If the arguments are vectors, each
4087 vector element of ``op1`` is shifted by the corresponding shift amount
4088 in ``op2``.
4089
4090 If the ``nuw`` keyword is present, then the shift produces a :ref:`poison
4091 value <poisonvalues>` if it shifts out any non-zero bits. If the
4092 ``nsw`` keyword is present, then the shift produces a :ref:`poison
4093 value <poisonvalues>` if it shifts out any bits that disagree with the
4094 resultant sign bit. As such, NUW/NSW have the same semantics as they
4095 would if the shift were expressed as a mul instruction with the same
4096 nsw/nuw bits in (mul %op1, (shl 1, %op2)).
4097
4098 Example:
4099 """"""""
4100
4101 .. code-block:: llvm
4102
4103       <result> = shl i32 4, %var   ; yields {i32}: 4 << %var
4104       <result> = shl i32 4, 2      ; yields {i32}: 16
4105       <result> = shl i32 1, 10     ; yields {i32}: 1024
4106       <result> = shl i32 1, 32     ; undefined
4107       <result> = shl <2 x i32> < i32 1, i32 1>, < i32 1, i32 2>   ; yields: result=<2 x i32> < i32 2, i32 4>
4108
4109 '``lshr``' Instruction
4110 ^^^^^^^^^^^^^^^^^^^^^^
4111
4112 Syntax:
4113 """""""
4114
4115 ::
4116
4117       <result> = lshr <ty> <op1>, <op2>         ; yields {ty}:result
4118       <result> = lshr exact <ty> <op1>, <op2>   ; yields {ty}:result
4119
4120 Overview:
4121 """""""""
4122
4123 The '``lshr``' instruction (logical shift right) returns the first
4124 operand shifted to the right a specified number of bits with zero fill.
4125
4126 Arguments:
4127 """"""""""
4128
4129 Both arguments to the '``lshr``' instruction must be the same
4130 :ref:`integer <t_integer>` or :ref:`vector <t_vector>` of integer type.
4131 '``op2``' is treated as an unsigned value.
4132
4133 Semantics:
4134 """"""""""
4135
4136 This instruction always performs a logical shift right operation. The
4137 most significant bits of the result will be filled with zero bits after
4138 the shift. If ``op2`` is (statically or dynamically) equal to or larger
4139 than the number of bits in ``op1``, the result is undefined. If the
4140 arguments are vectors, each vector element of ``op1`` is shifted by the
4141 corresponding shift amount in ``op2``.
4142
4143 If the ``exact`` keyword is present, the result value of the ``lshr`` is
4144 a :ref:`poison value <poisonvalues>` if any of the bits shifted out are
4145 non-zero.
4146
4147 Example:
4148 """"""""
4149
4150 .. code-block:: llvm
4151
4152       <result> = lshr i32 4, 1   ; yields {i32}:result = 2
4153       <result> = lshr i32 4, 2   ; yields {i32}:result = 1
4154       <result> = lshr i8  4, 3   ; yields {i8}:result = 0
4155       <result> = lshr i8 -2, 1   ; yields {i8}:result = 0x7F
4156       <result> = lshr i32 1, 32  ; undefined
4157       <result> = lshr <2 x i32> < i32 -2, i32 4>, < i32 1, i32 2>   ; yields: result=<2 x i32> < i32 0x7FFFFFFF, i32 1>
4158
4159 '``ashr``' Instruction
4160 ^^^^^^^^^^^^^^^^^^^^^^
4161
4162 Syntax:
4163 """""""
4164
4165 ::
4166
4167       <result> = ashr <ty> <op1>, <op2>         ; yields {ty}:result
4168       <result> = ashr exact <ty> <op1>, <op2>   ; yields {ty}:result
4169
4170 Overview:
4171 """""""""
4172
4173 The '``ashr``' instruction (arithmetic shift right) returns the first
4174 operand shifted to the right a specified number of bits with sign
4175 extension.
4176
4177 Arguments:
4178 """"""""""
4179
4180 Both arguments to the '``ashr``' instruction must be the same
4181 :ref:`integer <t_integer>` or :ref:`vector <t_vector>` of integer type.
4182 '``op2``' is treated as an unsigned value.
4183
4184 Semantics:
4185 """"""""""
4186
4187 This instruction always performs an arithmetic shift right operation,
4188 The most significant bits of the result will be filled with the sign bit
4189 of ``op1``. If ``op2`` is (statically or dynamically) equal to or larger
4190 than the number of bits in ``op1``, the result is undefined. If the
4191 arguments are vectors, each vector element of ``op1`` is shifted by the
4192 corresponding shift amount in ``op2``.
4193
4194 If the ``exact`` keyword is present, the result value of the ``ashr`` is
4195 a :ref:`poison value <poisonvalues>` if any of the bits shifted out are
4196 non-zero.
4197
4198 Example:
4199 """"""""
4200
4201 .. code-block:: llvm
4202
4203       <result> = ashr i32 4, 1   ; yields {i32}:result = 2
4204       <result> = ashr i32 4, 2   ; yields {i32}:result = 1
4205       <result> = ashr i8  4, 3   ; yields {i8}:result = 0
4206       <result> = ashr i8 -2, 1   ; yields {i8}:result = -1
4207       <result> = ashr i32 1, 32  ; undefined
4208       <result> = ashr <2 x i32> < i32 -2, i32 4>, < i32 1, i32 3>   ; yields: result=<2 x i32> < i32 -1, i32 0>
4209
4210 '``and``' Instruction
4211 ^^^^^^^^^^^^^^^^^^^^^
4212
4213 Syntax:
4214 """""""
4215
4216 ::
4217
4218       <result> = and <ty> <op1>, <op2>   ; yields {ty}:result
4219
4220 Overview:
4221 """""""""
4222
4223 The '``and``' instruction returns the bitwise logical and of its two
4224 operands.
4225
4226 Arguments:
4227 """"""""""
4228
4229 The two arguments to the '``and``' instruction must be
4230 :ref:`integer <t_integer>` or :ref:`vector <t_vector>` of integer values. Both
4231 arguments must have identical types.
4232
4233 Semantics:
4234 """"""""""
4235
4236 The truth table used for the '``and``' instruction is:
4237
4238 +-----+-----+-----+
4239 | In0 | In1 | Out |
4240 +-----+-----+-----+
4241 |   0 |   0 |   0 |
4242 +-----+-----+-----+
4243 |   0 |   1 |   0 |
4244 +-----+-----+-----+
4245 |   1 |   0 |   0 |
4246 +-----+-----+-----+
4247 |   1 |   1 |   1 |
4248 +-----+-----+-----+
4249
4250 Example:
4251 """"""""
4252
4253 .. code-block:: llvm
4254
4255       <result> = and i32 4, %var         ; yields {i32}:result = 4 & %var
4256       <result> = and i32 15, 40          ; yields {i32}:result = 8
4257       <result> = and i32 4, 8            ; yields {i32}:result = 0
4258
4259 '``or``' Instruction
4260 ^^^^^^^^^^^^^^^^^^^^
4261
4262 Syntax:
4263 """""""
4264
4265 ::
4266
4267       <result> = or <ty> <op1>, <op2>   ; yields {ty}:result
4268
4269 Overview:
4270 """""""""
4271
4272 The '``or``' instruction returns the bitwise logical inclusive or of its
4273 two operands.
4274
4275 Arguments:
4276 """"""""""
4277
4278 The two arguments to the '``or``' instruction must be
4279 :ref:`integer <t_integer>` or :ref:`vector <t_vector>` of integer values. Both
4280 arguments must have identical types.
4281
4282 Semantics:
4283 """"""""""
4284
4285 The truth table used for the '``or``' instruction is:
4286
4287 +-----+-----+-----+
4288 | In0 | In1 | Out |
4289 +-----+-----+-----+
4290 |   0 |   0 |   0 |
4291 +-----+-----+-----+
4292 |   0 |   1 |   1 |
4293 +-----+-----+-----+
4294 |   1 |   0 |   1 |
4295 +-----+-----+-----+
4296 |   1 |   1 |   1 |
4297 +-----+-----+-----+
4298
4299 Example:
4300 """"""""
4301
4302 ::
4303
4304       <result> = or i32 4, %var         ; yields {i32}:result = 4 | %var
4305       <result> = or i32 15, 40          ; yields {i32}:result = 47
4306       <result> = or i32 4, 8            ; yields {i32}:result = 12
4307
4308 '``xor``' Instruction
4309 ^^^^^^^^^^^^^^^^^^^^^
4310
4311 Syntax:
4312 """""""
4313
4314 ::
4315
4316       <result> = xor <ty> <op1>, <op2>   ; yields {ty}:result
4317
4318 Overview:
4319 """""""""
4320
4321 The '``xor``' instruction returns the bitwise logical exclusive or of
4322 its two operands. The ``xor`` is used to implement the "one's
4323 complement" operation, which is the "~" operator in C.
4324
4325 Arguments:
4326 """"""""""
4327
4328 The two arguments to the '``xor``' instruction must be
4329 :ref:`integer <t_integer>` or :ref:`vector <t_vector>` of integer values. Both
4330 arguments must have identical types.
4331
4332 Semantics:
4333 """"""""""
4334
4335 The truth table used for the '``xor``' instruction is:
4336
4337 +-----+-----+-----+
4338 | In0 | In1 | Out |
4339 +-----+-----+-----+
4340 |   0 |   0 |   0 |
4341 +-----+-----+-----+
4342 |   0 |   1 |   1 |
4343 +-----+-----+-----+
4344 |   1 |   0 |   1 |
4345 +-----+-----+-----+
4346 |   1 |   1 |   0 |
4347 +-----+-----+-----+
4348
4349 Example:
4350 """"""""
4351
4352 .. code-block:: llvm
4353
4354       <result> = xor i32 4, %var         ; yields {i32}:result = 4 ^ %var
4355       <result> = xor i32 15, 40          ; yields {i32}:result = 39
4356       <result> = xor i32 4, 8            ; yields {i32}:result = 12
4357       <result> = xor i32 %V, -1          ; yields {i32}:result = ~%V
4358
4359 Vector Operations
4360 -----------------
4361
4362 LLVM supports several instructions to represent vector operations in a
4363 target-independent manner. These instructions cover the element-access
4364 and vector-specific operations needed to process vectors effectively.
4365 While LLVM does directly support these vector operations, many
4366 sophisticated algorithms will want to use target-specific intrinsics to
4367 take full advantage of a specific target.
4368
4369 .. _i_extractelement:
4370
4371 '``extractelement``' Instruction
4372 ^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^
4373
4374 Syntax:
4375 """""""
4376
4377 ::
4378
4379       <result> = extractelement <n x <ty>> <val>, i32 <idx>    ; yields <ty>
4380
4381 Overview:
4382 """""""""
4383
4384 The '``extractelement``' instruction extracts a single scalar element
4385 from a vector at a specified index.
4386
4387 Arguments:
4388 """"""""""
4389
4390 The first operand of an '``extractelement``' instruction is a value of
4391 :ref:`vector <t_vector>` type. The second operand is an index indicating
4392 the position from which to extract the element. The index may be a
4393 variable.
4394
4395 Semantics:
4396 """"""""""
4397
4398 The result is a scalar of the same type as the element type of ``val``.
4399 Its value is the value at position ``idx`` of ``val``. If ``idx``
4400 exceeds the length of ``val``, the results are undefined.
4401
4402 Example:
4403 """"""""
4404
4405 .. code-block:: llvm
4406
4407       <result> = extractelement <4 x i32> %vec, i32 0    ; yields i32
4408
4409 .. _i_insertelement:
4410
4411 '``insertelement``' Instruction
4412 ^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^
4413
4414 Syntax:
4415 """""""
4416
4417 ::
4418
4419       <result> = insertelement <n x <ty>> <val>, <ty> <elt>, i32 <idx>    ; yields <n x <ty>>
4420