cmake/modules/TableGen.cmake

   1 # LLVM_TARGET_DEFINITIONS must contain the name of the .td file to process.
   2 # Extra parameters for `tblgen' may come after `ofn' parameter.
   3 # Adds the name of the generated file to TABLEGEN_OUTPUT.
   4
   5 function(tablegen project ofn)
   6   # Validate calling context.
   7   foreach(v
   8       ${project}_TABLEGEN_EXE
   9       LLVM_MAIN_SRC_DIR
  10       LLVM_MAIN_INCLUDE_DIR
  11       )
  12     if(NOT ${v})
  13       message(FATAL_ERROR "${v} not set")
  14     endif()
  15   endforeach()
  16
  17   file(GLOB local_tds "*.td")
  18   file(GLOB_RECURSE global_tds "${LLVM_MAIN_INCLUDE_DIR}/llvm/*.td")
  19
  20   if (IS_ABSOLUTE ${LLVM_TARGET_DEFINITIONS})
  21     set(LLVM_TARGET_DEFINITIONS_ABSOLUTE ${LLVM_TARGET_DEFINITIONS})
  22   else()
  23     set(LLVM_TARGET_DEFINITIONS_ABSOLUTE
  24       ${CMAKE_CURRENT_SOURCE_DIR}/${LLVM_TARGET_DEFINITIONS})
  25   endif()
  26   add_custom_command(OUTPUT ${CMAKE_CURRENT_BINARY_DIR}/${ofn}.tmp
  27     # Generate tablegen output in a temporary file.
  28     COMMAND ${${project}_TABLEGEN_EXE} ${ARGN} -I ${CMAKE_CURRENT_SOURCE_DIR}
  29     -I ${LLVM_MAIN_SRC_DIR}/lib/Target -I ${LLVM_MAIN_INCLUDE_DIR}
  30     ${LLVM_TARGET_DEFINITIONS_ABSOLUTE}
  31     -o ${CMAKE_CURRENT_BINARY_DIR}/${ofn}.tmp
  32     # The file in LLVM_TARGET_DEFINITIONS may be not in the current
  33     # directory and local_tds may not contain it, so we must
  34     # explicitly list it here:
  35     DEPENDS ${${project}_TABLEGEN_EXE} ${local_tds} ${global_tds}
  36     ${LLVM_TARGET_DEFINITIONS_ABSOLUTE}
  37     COMMENT "Building ${ofn}..."
  38     )
  39   add_custom_command(OUTPUT ${CMAKE_CURRENT_BINARY_DIR}/${ofn}
  40     # Only update the real output file if there are any differences.
  41     # This prevents recompilation of all the files depending on it if there
  42     # aren't any.
  43     COMMAND ${CMAKE_COMMAND} -E copy_if_different
  44         ${CMAKE_CURRENT_BINARY_DIR}/${ofn}.tmp
  45         ${CMAKE_CURRENT_BINARY_DIR}/${ofn}
  46     DEPENDS ${CMAKE_CURRENT_BINARY_DIR}/${ofn}.tmp
  47     COMMENT "Updating ${ofn}..."
  48     )
  49
  50   # `make clean' must remove all those generated files:
  51   set_property(DIRECTORY APPEND
  52     PROPERTY ADDITIONAL_MAKE_CLEAN_FILES ${ofn}.tmp ${ofn})
  53
  54   set(TABLEGEN_OUTPUT ${TABLEGEN_OUTPUT} ${CMAKE_CURRENT_BINARY_DIR}/${ofn} PARENT_SCOPE)
  55   set_source_files_properties(${CMAKE_CURRENT_BINARY_DIR}/${ofn}
  56     PROPERTIES GENERATED 1)
  57 endfunction(tablegen)
  58
  59 macro(add_public_tablegen_target target)
  60   # Creates a target for publicly exporting tablegen dependencies.
  61   if( TABLEGEN_OUTPUT )
  62     add_custom_target(${target}
  63       DEPENDS ${TABLEGEN_OUTPUT})
  64     if (LLVM_COMMON_DEPENDS)
  65       add_dependencies(${target} ${LLVM_COMMON_DEPENDS})
  66     endif ()
  67     set_target_properties(${target} PROPERTIES FOLDER "Tablegenning")
  68     list(APPEND LLVM_COMMON_DEPENDS ${target} intrinsics_gen)
  69   endif( TABLEGEN_OUTPUT )
  70 endmacro()
  71
  72 if(CMAKE_CROSSCOMPILING)
  73   set(CX_NATIVE_TG_DIR "${CMAKE_BINARY_DIR}/native")
  74
  75   add_custom_command(OUTPUT ${CX_NATIVE_TG_DIR}
  76     COMMAND ${CMAKE_COMMAND} -E make_directory ${CX_NATIVE_TG_DIR}
  77     COMMENT "Creating ${CX_NATIVE_TG_DIR}...")
  78
  79   add_custom_command(OUTPUT ${CX_NATIVE_TG_DIR}/CMakeCache.txt
  80     COMMAND ${CMAKE_COMMAND} -UMAKE_TOOLCHAIN_FILE -DCMAKE_BUILD_TYPE=Release
  81                              -DLLVM_BUILD_POLLY=OFF
  82                              -G "${CMAKE_GENERATOR}" ${CMAKE_SOURCE_DIR}
  83     WORKING_DIRECTORY ${CX_NATIVE_TG_DIR}
  84     DEPENDS ${CX_NATIVE_TG_DIR}
  85     COMMENT "Configuring native TableGen...")
  86
  87   add_custom_target(ConfigureNativeTableGen DEPENDS ${CX_NATIVE_TG_DIR}/CMakeCache.txt)
  88
  89   set_directory_properties(PROPERTIES ADDITIONAL_MAKE_CLEAN_FILES ${CX_NATIVE_TG_DIR})
  90 endif()
  91
  92 macro(add_tablegen target project)
  93   set(${target}_OLD_LLVM_LINK_COMPONENTS ${LLVM_LINK_COMPONENTS})
  94   set(LLVM_LINK_COMPONENTS ${LLVM_LINK_COMPONENTS} TableGen)
  95   add_llvm_utility(${target} ${ARGN})
  96   set(LLVM_LINK_COMPONENTS ${${target}_OLD_LLVM_LINK_COMPONENTS})
  97
  98   set(${project}_TABLEGEN "${target}" CACHE
  99       STRING "Native TableGen executable. Saves building one when cross-compiling.")
 100
 101   # Upgrade existing LLVM_TABLEGEN setting.
 102   if(${project} STREQUAL LLVM)
 103     if(${LLVM_TABLEGEN} STREQUAL tblgen)
 104       set(LLVM_TABLEGEN "${target}" CACHE
 105           STRING "Native TableGen executable. Saves building one when cross-compiling."
 106           FORCE)
 107     endif()
 108   endif()
 109
 110   # Effective tblgen executable to be used:
 111   set(${project}_TABLEGEN_EXE ${${project}_TABLEGEN} PARENT_SCOPE)
 112
 113   if(CMAKE_CROSSCOMPILING)
 114     if( ${${project}_TABLEGEN} STREQUAL "${target}" )
 115       set(${project}_TABLEGEN_EXE "${CX_NATIVE_TG_DIR}/bin/${target}")
 116       set(${project}_TABLEGEN_EXE ${${project}_TABLEGEN_EXE} PARENT_SCOPE)
 117
 118       add_custom_command(OUTPUT ${${project}_TABLEGEN_EXE}
 119         COMMAND ${CMAKE_BUILD_TOOL} ${target}
 120         DEPENDS ${CX_NATIVE_TG_DIR}/CMakeCache.txt
 121         WORKING_DIRECTORY ${CX_NATIVE_TG_DIR}
 122         COMMENT "Building native TableGen...")
 123       add_custom_target(${project}NativeTableGen DEPENDS ${${project}_TABLEGEN_EXE})
 124       add_dependencies(${project}NativeTableGen ConfigureNativeTableGen)
 125
 126       add_dependencies(${target} ${project}NativeTableGen)
 127     endif()
 128   endif()
 129
 130   if( MINGW )
 131     if(CMAKE_SIZEOF_VOID_P MATCHES "8")
 132       set_target_properties(${target} PROPERTIES LINK_FLAGS -Wl,--stack,16777216)
 133     endif(CMAKE_SIZEOF_VOID_P MATCHES "8")
 134   endif( MINGW )
 135   if (${project} STREQUAL LLVM AND NOT LLVM_INSTALL_TOOLCHAIN_ONLY)
 136     install(TARGETS ${target}
 137             EXPORT LLVMExports
 138             RUNTIME DESTINATION bin)
 139   endif()
 140   set_property(GLOBAL APPEND PROPERTY LLVM_EXPORTS ${target})
 141 endmacro()