cmake/modules/TableGen.cmake

   1 # LLVM_TARGET_DEFINITIONS must contain the name of the .td file to process.
   2 # Extra parameters for `tblgen' may come after `ofn' parameter.
   3 # Adds the name of the generated file to TABLEGEN_OUTPUT.
   4
   5 function(tablegen project ofn)
   6   # Use the list by include_directories().
   7   get_property(include_dirs DIRECTORY PROPERTY INCLUDE_DIRECTORIES)
   8
   9   # Collect possible dependent *.td(s).
  10   # FIXME: It is far from optimal.
  11   file(GLOB dependent_tds "*.td")
  12   foreach(inc ${include_dirs})
  13     file(GLOB tds "${inc}/*.td")
  14     list(APPEND dependent_tds ${tds})
  15   endforeach()
  16
  17   if (IS_ABSOLUTE ${LLVM_TARGET_DEFINITIONS})
  18     set(LLVM_TARGET_DEFINITIONS_ABSOLUTE ${LLVM_TARGET_DEFINITIONS})
  19   else()
  20     set(LLVM_TARGET_DEFINITIONS_ABSOLUTE
  21       ${CMAKE_CURRENT_SOURCE_DIR}/${LLVM_TARGET_DEFINITIONS})
  22   endif()
  23   foreach(inc ${include_dirs})
  24     list(APPEND TABLEGEN_INCLUDE_DIRECTORIES -I ${inc})
  25   endforeach()
  26   add_custom_command(OUTPUT ${CMAKE_CURRENT_BINARY_DIR}/${ofn}.tmp
  27     # Generate tablegen output in a temporary file.
  28     COMMAND ${${project}_TABLEGEN_EXE} ${ARGN}
  29     -I ${CMAKE_CURRENT_SOURCE_DIR}
  30     ${TABLEGEN_INCLUDE_DIRECTORIES}
  31     ${LLVM_TARGET_DEFINITIONS_ABSOLUTE}
  32     -o ${CMAKE_CURRENT_BINARY_DIR}/${ofn}.tmp
  33     # The file in LLVM_TARGET_DEFINITIONS may be not in the current
  34     # directory and local_tds may not contain it, so we must
  35     # explicitly list it here:
  36     DEPENDS ${${project}_TABLEGEN_EXE} ${dependent_tds}
  37     ${LLVM_TARGET_DEFINITIONS_ABSOLUTE}
  38     COMMENT "Building ${ofn}..."
  39     )
  40   add_custom_command(OUTPUT ${CMAKE_CURRENT_BINARY_DIR}/${ofn}
  41     # Only update the real output file if there are any differences.
  42     # This prevents recompilation of all the files depending on it if there
  43     # aren't any.
  44     COMMAND ${CMAKE_COMMAND} -E copy_if_different
  45         ${CMAKE_CURRENT_BINARY_DIR}/${ofn}.tmp
  46         ${CMAKE_CURRENT_BINARY_DIR}/${ofn}
  47     DEPENDS ${CMAKE_CURRENT_BINARY_DIR}/${ofn}.tmp
  48     COMMENT "Updating ${ofn}..."
  49     )
  50
  51   # `make clean' must remove all those generated files:
  52   set_property(DIRECTORY APPEND
  53     PROPERTY ADDITIONAL_MAKE_CLEAN_FILES ${ofn}.tmp ${ofn})
  54
  55   set(TABLEGEN_OUTPUT ${TABLEGEN_OUTPUT} ${CMAKE_CURRENT_BINARY_DIR}/${ofn} PARENT_SCOPE)
  56   set_source_files_properties(${CMAKE_CURRENT_BINARY_DIR}/${ofn}
  57     PROPERTIES GENERATED 1)
  58 endfunction(tablegen)
  59
  60 macro(add_public_tablegen_target target)
  61   # Creates a target for publicly exporting tablegen dependencies.
  62   if( TABLEGEN_OUTPUT )
  63     add_custom_target(${target}
  64       DEPENDS ${TABLEGEN_OUTPUT})
  65     if (LLVM_COMMON_DEPENDS)
  66       add_dependencies(${target} ${LLVM_COMMON_DEPENDS})
  67     endif ()
  68     set_target_properties(${target} PROPERTIES FOLDER "Tablegenning")
  69     list(APPEND LLVM_COMMON_DEPENDS ${target} intrinsics_gen)
  70   endif( TABLEGEN_OUTPUT )
  71 endmacro()
  72
  73 if(CMAKE_CROSSCOMPILING)
  74   set(CX_NATIVE_TG_DIR "${CMAKE_BINARY_DIR}/native")
  75
  76   add_custom_command(OUTPUT ${CX_NATIVE_TG_DIR}
  77     COMMAND ${CMAKE_COMMAND} -E make_directory ${CX_NATIVE_TG_DIR}
  78     COMMENT "Creating ${CX_NATIVE_TG_DIR}...")
  79
  80   add_custom_command(OUTPUT ${CX_NATIVE_TG_DIR}/CMakeCache.txt
  81     COMMAND ${CMAKE_COMMAND} -UMAKE_TOOLCHAIN_FILE -DCMAKE_BUILD_TYPE=Release
  82                              -DLLVM_BUILD_POLLY=OFF
  83                              -G "${CMAKE_GENERATOR}" ${CMAKE_SOURCE_DIR}
  84     WORKING_DIRECTORY ${CX_NATIVE_TG_DIR}
  85     DEPENDS ${CX_NATIVE_TG_DIR}
  86     COMMENT "Configuring native TableGen...")
  87
  88   add_custom_target(ConfigureNativeTableGen DEPENDS ${CX_NATIVE_TG_DIR}/CMakeCache.txt)
  89
  90   set_directory_properties(PROPERTIES ADDITIONAL_MAKE_CLEAN_FILES ${CX_NATIVE_TG_DIR})
  91 endif()
  92
  93 macro(add_tablegen target project)
  94   set(${target}_OLD_LLVM_LINK_COMPONENTS ${LLVM_LINK_COMPONENTS})
  95   set(LLVM_LINK_COMPONENTS ${LLVM_LINK_COMPONENTS} TableGen)
  96   add_llvm_utility(${target} ${ARGN})
  97   set(LLVM_LINK_COMPONENTS ${${target}_OLD_LLVM_LINK_COMPONENTS})
  98
  99   set(${project}_TABLEGEN "${target}" CACHE
 100       STRING "Native TableGen executable. Saves building one when cross-compiling.")
 101
 102   # Upgrade existing LLVM_TABLEGEN setting.
 103   if(${project} STREQUAL LLVM)
 104     if(${LLVM_TABLEGEN} STREQUAL tblgen)
 105       set(LLVM_TABLEGEN "${target}" CACHE
 106           STRING "Native TableGen executable. Saves building one when cross-compiling."
 107           FORCE)
 108     endif()
 109   endif()
 110
 111   # Effective tblgen executable to be used:
 112   set(${project}_TABLEGEN_EXE ${${project}_TABLEGEN} PARENT_SCOPE)
 113
 114   if(CMAKE_CROSSCOMPILING)
 115     if( ${${project}_TABLEGEN} STREQUAL "${target}" )
 116       set(${project}_TABLEGEN_EXE "${CX_NATIVE_TG_DIR}/bin/${target}")
 117       set(${project}_TABLEGEN_EXE ${${project}_TABLEGEN_EXE} PARENT_SCOPE)
 118
 119       add_custom_command(OUTPUT ${${project}_TABLEGEN_EXE}
 120         COMMAND ${CMAKE_BUILD_TOOL} ${target}
 121         DEPENDS ${CX_NATIVE_TG_DIR}/CMakeCache.txt
 122         WORKING_DIRECTORY ${CX_NATIVE_TG_DIR}
 123         COMMENT "Building native TableGen...")
 124       add_custom_target(${project}NativeTableGen DEPENDS ${${project}_TABLEGEN_EXE})
 125       add_dependencies(${project}NativeTableGen ConfigureNativeTableGen)
 126
 127       add_dependencies(${target} ${project}NativeTableGen)
 128     endif()
 129   endif()
 130
 131   if( MINGW )
 132     target_link_libraries(${target} imagehlp psapi shell32)
 133     if(CMAKE_SIZEOF_VOID_P MATCHES "8")
 134       set_target_properties(${target} PROPERTIES LINK_FLAGS -Wl,--stack,16777216)
 135     endif(CMAKE_SIZEOF_VOID_P MATCHES "8")
 136   endif( MINGW )
 137   if( LLVM_ENABLE_THREADS AND HAVE_LIBPTHREAD AND NOT BEOS )
 138     target_link_libraries(${target} pthread)
 139   endif()
 140
 141   if (${project} STREQUAL LLVM AND NOT LLVM_INSTALL_TOOLCHAIN_ONLY)
 142     install(TARGETS ${target} RUNTIME DESTINATION bin)
 143   endif()
 144 endmacro()