cmake/modules/HandleLLVMOptions.cmake

   1 # This CMake module is responsible for interpreting the user defined LLVM_
   2 # options and executing the appropriate CMake commands to realize the users'
   3 # selections.
   4
   5 # This is commonly needed so make sure it's defined before we include anything
   6 # else.
   7 string(TOUPPER "${CMAKE_BUILD_TYPE}" uppercase_CMAKE_BUILD_TYPE)
   8
   9 include(HandleLLVMStdlib)
  10 include(AddLLVMDefinitions)
  11 include(CheckCCompilerFlag)
  12 include(CheckCXXCompilerFlag)
  13
  14 if(NOT LLVM_FORCE_USE_OLD_TOOLCHAIN)
  15   if(CMAKE_CXX_COMPILER_ID STREQUAL "GNU")
  16     if(CMAKE_CXX_COMPILER_VERSION VERSION_LESS 4.7)
  17       message(FATAL_ERROR "Host GCC version must be at least 4.7!")
  18     endif()
  19   elseif(CMAKE_CXX_COMPILER_ID STREQUAL "Clang")
  20     if(CMAKE_CXX_COMPILER_VERSION VERSION_LESS 3.1)
  21       message(FATAL_ERROR "Host Clang version must be at least 3.1!")
  22     endif()
  23
  24     # Also test that we aren't using too old of a version of libstdc++ with the
  25     # Clang compiler. This is tricky as there is no real way to check the
  26     # version of libstdc++ directly. Instead we test for a known bug in
  27     # libstdc++4.6 that is fixed in libstdc++4.7.
  28     if(NOT LLVM_ENABLE_LIBCXX)
  29       set(OLD_CMAKE_REQUIRED_FLAGS ${CMAKE_REQUIRED_FLAGS})
  30       set(OLD_CMAKE_REQUIRED_LIBRARIES ${CMAKE_REQUIRED_LIBRARIES})
  31       set(CMAKE_REQUIRED_FLAGS "-std=c++0x")
  32       check_cxx_source_compiles("
  33 #include <atomic>
  34 std::atomic<float> x(0.0f);
  35 int main() { return (float)x; }"
  36         LLVM_NO_OLD_LIBSTDCXX)
  37       if(NOT LLVM_NO_OLD_LIBSTDCXX)
  38         message(FATAL_ERROR "Host Clang must be able to find libstdc++4.7 or newer!")
  39       endif()
  40       set(CMAKE_REQUIRED_FLAGS ${OLD_CMAKE_REQUIRED_FLAGS})
  41       set(CMAKE_REQUIRED_LIBRARIES ${OLD_CMAKE_REQUIRED_LIBRARIES})
  42     endif()
  43   elseif(CMAKE_CXX_COMPILER_ID MATCHES "MSVC")
  44     if(CMAKE_CXX_COMPILER_VERSION VERSION_LESS 17.0)
  45       message(FATAL_ERROR "Host Visual Studio must be at least 2012 (MSVC 17.0)")
  46     endif()
  47   endif()
  48 endif()
  49
  50 if( LLVM_ENABLE_ASSERTIONS )
  51   # MSVC doesn't like _DEBUG on release builds. See PR 4379.
  52   if( NOT MSVC )
  53     add_definitions( -D_DEBUG )
  54   endif()
  55   # On non-Debug builds cmake automatically defines NDEBUG, so we
  56   # explicitly undefine it:
  57   if( NOT uppercase_CMAKE_BUILD_TYPE STREQUAL "DEBUG" )
  58     add_definitions( -UNDEBUG )
  59     # Also remove /D NDEBUG to avoid MSVC warnings about conflicting defines.
  60     foreach (flags_var_to_scrub
  61         CMAKE_CXX_FLAGS_RELEASE
  62         CMAKE_CXX_FLAGS_RELWITHDEBINFO
  63         CMAKE_CXX_FLAGS_MINSIZEREL
  64         CMAKE_C_FLAGS_RELEASE
  65         CMAKE_C_FLAGS_RELWITHDEBINFO
  66         CMAKE_C_FLAGS_MINSIZEREL)
  67       string (REGEX REPLACE "(^| )[/-]D *NDEBUG($| )" " "
  68         "${flags_var_to_scrub}" "${${flags_var_to_scrub}}")
  69     endforeach()
  70   endif()
  71 endif()
  72
  73 if(WIN32)
  74   set(LLVM_HAVE_LINK_VERSION_SCRIPT 0)
  75   if(CYGWIN)
  76     set(LLVM_ON_WIN32 0)
  77     set(LLVM_ON_UNIX 1)
  78   else(CYGWIN)
  79     set(LLVM_ON_WIN32 1)
  80     set(LLVM_ON_UNIX 0)
  81   endif(CYGWIN)
  82 else(WIN32)
  83   if(UNIX)
  84     set(LLVM_ON_WIN32 0)
  85     set(LLVM_ON_UNIX 1)
  86     if(APPLE)
  87       set(LLVM_HAVE_LINK_VERSION_SCRIPT 0)
  88     else(APPLE)
  89       set(LLVM_HAVE_LINK_VERSION_SCRIPT 1)
  90     endif(APPLE)
  91   else(UNIX)
  92     MESSAGE(SEND_ERROR "Unable to determine platform")
  93   endif(UNIX)
  94 endif(WIN32)
  95
  96 set(EXEEXT ${CMAKE_EXECUTABLE_SUFFIX})
  97 set(LTDL_SHLIB_EXT ${CMAKE_SHARED_LIBRARY_SUFFIX})
  98
  99 # We use *.dylib rather than *.so on darwin.
 100 set(LLVM_PLUGIN_EXT ${CMAKE_SHARED_LIBRARY_SUFFIX})
 101
 102 if(APPLE)
 103   # Darwin-specific linker flags for loadable modules.
 104   set(CMAKE_MODULE_LINKER_FLAGS "${CMAKE_MODULE_LINKER_FLAGS} -Wl,-flat_namespace -Wl,-undefined -Wl,suppress")
 105 endif()
 106
 107 # Pass -Wl,-z,defs. This makes sure all symbols are defined. Otherwise a DSO
 108 # build might work on ELF but fail on MachO/COFF.
 109 if(NOT (${CMAKE_SYSTEM_NAME} MATCHES "Darwin" OR WIN32))
 110   set(CMAKE_SHARED_LINKER_FLAGS "${CMAKE_SHARED_LINKER_FLAGS} -Wl,-z,defs")
 111 endif()
 112
 113
 114 function(append value)
 115   foreach(variable ${ARGN})
 116     set(${variable} "${${variable}} ${value}" PARENT_SCOPE)
 117   endforeach(variable)
 118 endfunction()
 119
 120 function(append_if condition value)
 121   if (${condition})
 122     foreach(variable ${ARGN})
 123       set(${variable} "${${variable}} ${value}" PARENT_SCOPE)
 124     endforeach(variable)
 125   endif()
 126 endfunction()
 127
 128 macro(add_flag_if_supported flag name)
 129   check_c_compiler_flag("-Werror ${flag}" "C_SUPPORTS_${name}")
 130   append_if("C_SUPPORTS_${name}" "${flag}" CMAKE_C_FLAGS)
 131   check_cxx_compiler_flag("-Werror ${flag}" "CXX_SUPPORTS_${name}")
 132   append_if("CXX_SUPPORTS_${name}" "${flag}" CMAKE_CXX_FLAGS)
 133 endmacro()
 134
 135 function(add_flag_or_print_warning flag name)
 136   check_c_compiler_flag("-Werror ${flag}" "C_SUPPORTS_${name}")
 137   check_cxx_compiler_flag("-Werror ${flag}" "CXX_SUPPORTS_${name}")
 138   if (C_SUPPORTS_${name} AND CXX_SUPPORTS_${name})
 139     message(STATUS "Building with ${flag}")
 140     set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} ${flag}" PARENT_SCOPE)
 141     set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} ${flag}" PARENT_SCOPE)
 142   else()
 143     message(WARNING "${flag} is not supported.")
 144   endif()
 145 endfunction()
 146
 147 if( LLVM_ENABLE_PIC )
 148   if( XCODE )
 149     # Xcode has -mdynamic-no-pic on by default, which overrides -fPIC. I don't
 150     # know how to disable this, so just force ENABLE_PIC off for now.
 151     message(WARNING "-fPIC not supported with Xcode.")
 152   elseif( WIN32 OR CYGWIN)
 153     # On Windows all code is PIC. MinGW warns if -fPIC is used.
 154   else()
 155     add_flag_or_print_warning("-fPIC" FPIC)
 156
 157     if( WIN32 OR CYGWIN)
 158       # MinGW warns if -fvisibility-inlines-hidden is used.
 159     else()
 160       check_cxx_compiler_flag("-fvisibility-inlines-hidden" SUPPORTS_FVISIBILITY_INLINES_HIDDEN_FLAG)
 161       append_if(SUPPORTS_FVISIBILITY_INLINES_HIDDEN_FLAG "-fvisibility-inlines-hidden" CMAKE_CXX_FLAGS)
 162     endif()
 163   endif()
 164 endif()
 165
 166 if( CMAKE_SIZEOF_VOID_P EQUAL 8 AND NOT WIN32 )
 167   # TODO: support other platforms and toolchains.
 168   if( LLVM_BUILD_32_BITS )
 169     message(STATUS "Building 32 bits executables and libraries.")
 170     add_llvm_definitions( -m32 )
 171     set(CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} -m32")
 172     set(CMAKE_SHARED_LINKER_FLAGS "${CMAKE_SHARED_LINKER_FLAGS} -m32")
 173     set(CMAKE_MODULE_LINKER_FLAGS "${CMAKE_MODULE_LINKER_FLAGS} -m32")
 174   endif( LLVM_BUILD_32_BITS )
 175 endif( CMAKE_SIZEOF_VOID_P EQUAL 8 AND NOT WIN32 )
 176
 177 if (LLVM_BUILD_STATIC)
 178   set(CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} -static")
 179 endif()
 180
 181 if( XCODE )
 182   # For Xcode enable several build settings that correspond to
 183   # many warnings that are on by default in Clang but are
 184   # not enabled for historical reasons.  For versions of Xcode
 185   # that do not support these options they will simply
 186   # be ignored.
 187   set(CMAKE_XCODE_ATTRIBUTE_GCC_WARN_ABOUT_RETURN_TYPE "YES")
 188   set(CMAKE_XCODE_ATTRIBUTE_GCC_WARN_ABOUT_MISSING_NEWLINE "YES")
 189   set(CMAKE_XCODE_ATTRIBUTE_GCC_WARN_UNUSED_VALUE "YES")
 190   set(CMAKE_XCODE_ATTRIBUTE_GCC_WARN_UNUSED_VARIABLE "YES")
 191   set(CMAKE_XCODE_ATTRIBUTE_GCC_WARN_SIGN_COMPARE "YES")
 192   set(CMAKE_XCODE_ATTRIBUTE_GCC_WARN_UNUSED_FUNCTION "YES")
 193   set(CMAKE_XCODE_ATTRIBUTE_GCC_WARN_INITIALIZER_NOT_FULLY_BRACKETED "YES")
 194   set(CMAKE_XCODE_ATTRIBUTE_GCC_WARN_HIDDEN_VIRTUAL_FUNCTIONS "YES")
 195   set(CMAKE_XCODE_ATTRIBUTE_GCC_WARN_UNINITIALIZED_AUTOS "YES")
 196   set(CMAKE_XCODE_ATTRIBUTE_CLANG_WARN_BOOL_CONVERSION "YES")
 197   set(CMAKE_XCODE_ATTRIBUTE_CLANG_WARN_EMPTY_BODY "YES")
 198   set(CMAKE_XCODE_ATTRIBUTE_CLANG_WARN_ENUM_CONVERSION "YES")
 199   set(CMAKE_XCODE_ATTRIBUTE_CLANG_WARN_INT_CONVERSION "YES")
 200   set(CMAKE_XCODE_ATTRIBUTE_CLANG_WARN_CONSTANT_CONVERSION "YES")
 201   set(CMAKE_XCODE_ATTRIBUTE_GCC_WARN_NON_VIRTUAL_DESTRUCTOR "YES")
 202 endif()
 203
 204 # On Win32 using MS tools, provide an option to set the number of parallel jobs
 205 # to use.
 206 if( MSVC_IDE )
 207   set(LLVM_COMPILER_JOBS "0" CACHE STRING
 208     "Number of parallel compiler jobs. 0 means use all processors. Default is 0.")
 209   if( NOT LLVM_COMPILER_JOBS STREQUAL "1" )
 210     if( LLVM_COMPILER_JOBS STREQUAL "0" )
 211       add_llvm_definitions( /MP )
 212     else()
 213       message(STATUS "Number of parallel compiler jobs set to " ${LLVM_COMPILER_JOBS})
 214       add_llvm_definitions( /MP${LLVM_COMPILER_JOBS} )
 215     endif()
 216   else()
 217     message(STATUS "Parallel compilation disabled")
 218   endif()
 219 endif()
 220
 221 if( MSVC )
 222   include(ChooseMSVCCRT)
 223
 224   if( NOT (${CMAKE_VERSION} VERSION_LESS 2.8.11) )
 225     # set stack reserved size to ~10MB
 226     # CMake previously automatically set this value for MSVC builds, but the
 227     # behavior was changed in CMake 2.8.11 (Issue 12437) to use the MSVC default
 228     # value (1 MB) which is not enough for us in tasks such as parsing recursive
 229     # C++ templates in Clang.
 230     set(CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} /STACK:10000000")
 231   endif()
 232
 233   if( MSVC11 )
 234     add_llvm_definitions(-D_VARIADIC_MAX=10)
 235   endif()
 236
 237   # Add definitions that make MSVC much less annoying.
 238   add_llvm_definitions(
 239     # For some reason MS wants to deprecate a bunch of standard functions...
 240     -D_CRT_SECURE_NO_DEPRECATE
 241     -D_CRT_SECURE_NO_WARNINGS
 242     -D_CRT_NONSTDC_NO_DEPRECATE
 243     -D_CRT_NONSTDC_NO_WARNINGS
 244     -D_SCL_SECURE_NO_DEPRECATE
 245     -D_SCL_SECURE_NO_WARNINGS
 246
 247     # Disabled warnings.
 248     -wd4146 # Suppress 'unary minus operator applied to unsigned type, result still unsigned'
 249     -wd4180 # Suppress 'qualifier applied to function type has no meaning; ignored'
 250     -wd4244 # Suppress ''argument' : conversion from 'type1' to 'type2', possible loss of data'
 251     -wd4258 # Suppress ''var' : definition from the for loop is ignored; the definition from the enclosing scope is used'
 252     -wd4267 # Suppress ''var' : conversion from 'size_t' to 'type', possible loss of data'
 253     -wd4291 # Suppress ''declaration' : no matching operator delete found; memory will not be freed if initialization throws an exception'
 254     -wd4345 # Suppress 'behavior change: an object of POD type constructed with an initializer of the form () will be default-initialized'
 255     -wd4351 # Suppress 'new behavior: elements of array 'array' will be default initialized'
 256     -wd4355 # Suppress ''this' : used in base member initializer list'
 257     -wd4456 # Suppress 'declaration of 'var' hides local variable'
 258     -wd4457 # Suppress 'declaration of 'var' hides function parameter'
 259     -wd4458 # Suppress 'declaration of 'var' hides class member'
 260     -wd4459 # Suppress 'declaration of 'var' hides global declaration'
 261     -wd4503 # Suppress ''identifier' : decorated name length exceeded, name was truncated'
 262     -wd4624 # Suppress ''derived class' : destructor could not be generated because a base class destructor is inaccessible'
 263     -wd4722 # Suppress 'function' : destructor never returns, potential memory leak
 264     -wd4800 # Suppress ''type' : forcing value to bool 'true' or 'false' (performance warning)'
 265
 266     # Promoted warnings.
 267     -w14062 # Promote 'enumerator in switch of enum is not handled' to level 1 warning.
 268
 269     # Promoted warnings to errors.
 270     -we4238 # Promote 'nonstandard extension used : class rvalue used as lvalue' to error.
 271     )
 272
 273   # Enable warnings
 274   if (LLVM_ENABLE_WARNINGS)
 275     add_llvm_definitions( /W4 )
 276     if (LLVM_ENABLE_PEDANTIC)
 277       # No MSVC equivalent available
 278     endif (LLVM_ENABLE_PEDANTIC)
 279   endif (LLVM_ENABLE_WARNINGS)
 280   if (LLVM_ENABLE_WERROR)
 281     add_llvm_definitions( /WX )
 282   endif (LLVM_ENABLE_WERROR)
 283 elseif( LLVM_COMPILER_IS_GCC_COMPATIBLE )
 284   if (LLVM_ENABLE_WARNINGS)
 285     append("-Wall -W -Wno-unused-parameter -Wwrite-strings" CMAKE_C_FLAGS CMAKE_CXX_FLAGS)
 286     append("-Wcast-qual" CMAKE_CXX_FLAGS)
 287
 288     # Turn off missing field initializer warnings for gcc to avoid noise from
 289     # false positives with empty {}. Turn them on otherwise (they're off by
 290     # default for clang).
 291     check_cxx_compiler_flag("-Wmissing-field-initializers" CXX_SUPPORTS_MISSING_FIELD_INITIALIZERS_FLAG)
 292     if (CXX_SUPPORTS_MISSING_FIELD_INITIALIZERS_FLAG)
 293       if (CMAKE_COMPILER_IS_GNUCXX)
 294         append("-Wno-missing-field-initializers" CMAKE_C_FLAGS CMAKE_CXX_FLAGS)
 295       else()
 296         append("-Wmissing-field-initializers" CMAKE_C_FLAGS CMAKE_CXX_FLAGS)
 297       endif()
 298     endif()
 299
 300     append_if(LLVM_ENABLE_PEDANTIC "-pedantic -Wno-long-long" CMAKE_C_FLAGS CMAKE_CXX_FLAGS)
 301     add_flag_if_supported("-Wcovered-switch-default" COVERED_SWITCH_DEFAULT_FLAG)
 302     append_if(USE_NO_UNINITIALIZED "-Wno-uninitialized" CMAKE_CXX_FLAGS)
 303     append_if(USE_NO_MAYBE_UNINITIALIZED "-Wno-maybe-uninitialized" CMAKE_CXX_FLAGS)
 304
 305     # Check if -Wnon-virtual-dtor warns even though the class is marked final.
 306     # If it does, don't add it. So it won't be added on clang 3.4 and older.
 307     # This also catches cases when -Wnon-virtual-dtor isn't supported by
 308     # the compiler at all.
 309     set(OLD_CMAKE_REQUIRED_FLAGS ${CMAKE_REQUIRED_FLAGS})
 310     set(CMAKE_REQUIRED_FLAGS "${CMAKE_REQUIRED_FLAGS} -std=c++11 -Werror=non-virtual-dtor")
 311     CHECK_CXX_SOURCE_COMPILES("class base {public: virtual void anchor();protected: ~base();};
 312                                class derived final : public base { public: ~derived();};
 313                                int main() { return 0; }"
 314                               CXX_WONT_WARN_ON_FINAL_NONVIRTUALDTOR)
 315     set(CMAKE_REQUIRED_FLAGS ${OLD_CMAKE_REQUIRED_FLAGS})
 316     append_if(CXX_WONT_WARN_ON_FINAL_NONVIRTUALDTOR
 317               "-Wnon-virtual-dtor" CMAKE_CXX_FLAGS)
 318
 319     # Check if -Wcomment is OK with an // comment ending with '\' if the next
 320     # line is also a // comment.
 321     set(OLD_CMAKE_REQUIRED_FLAGS ${CMAKE_REQUIRED_FLAGS})
 322     set(CMAKE_REQUIRED_FLAGS "${CMAKE_REQUIRED_FLAGS} -Werror -Wcomment")
 323     CHECK_C_SOURCE_COMPILES("// \\\\\\n//\\nint main() {return 0;}"
 324                             C_WCOMMENT_ALLOWS_LINE_WRAP)
 325     set(CMAKE_REQUIRED_FLAGS ${OLD_CMAKE_REQUIRED_FLAGS})
 326     if (NOT C_WCOMMENT_ALLOWS_LINE_WRAP)
 327       append("-Wno-comment" CMAKE_C_FLAGS CMAKE_CXX_FLAGS)
 328     endif()
 329   endif (LLVM_ENABLE_WARNINGS)
 330   append_if(LLVM_ENABLE_WERROR "-Werror" CMAKE_C_FLAGS CMAKE_CXX_FLAGS)
 331   if (NOT LLVM_ENABLE_TIMESTAMPS)
 332     add_flag_if_supported("-Werror=date-time" WERROR_DATE_TIME)
 333   endif ()
 334   if (LLVM_ENABLE_CXX1Y)
 335     check_cxx_compiler_flag("-std=c++1y" CXX_SUPPORTS_CXX1Y)
 336     append_if(CXX_SUPPORTS_CXX1Y "-std=c++1y" CMAKE_CXX_FLAGS)
 337   else()
 338     check_cxx_compiler_flag("-std=c++11" CXX_SUPPORTS_CXX11)
 339     if (CXX_SUPPORTS_CXX11)
 340       if (CYGWIN OR MINGW)
 341         # MinGW and Cygwin are a bit stricter and lack things like
 342         # 'strdup', 'stricmp', etc in c++11 mode.
 343         append("-std=gnu++11" CMAKE_CXX_FLAGS)
 344       else()
 345         append("-std=c++11" CMAKE_CXX_FLAGS)
 346       endif()
 347     else()
 348       message(FATAL_ERROR "LLVM requires C++11 support but the '-std=c++11' flag isn't supported.")
 349     endif()
 350   endif()
 351   if (LLVM_ENABLE_MODULES)
 352     set(OLD_CMAKE_REQUIRED_FLAGS ${CMAKE_REQUIRED_FLAGS})
 353     set(CMAKE_REQUIRED_FLAGS "${CMAKE_REQUIRED_FLAGS} -fmodules -fcxx-modules")
 354     # Check that we can build code with modules enabled, and that repeatedly
 355     # including <cassert> still manages to respect NDEBUG properly.
 356     CHECK_CXX_SOURCE_COMPILES("#undef NDEBUG
 357                                #include <cassert>
 358                                #define NDEBUG
 359                                #include <cassert>
 360                                int main() { assert(this code is not compiled); }"
 361                                CXX_SUPPORTS_MODULES)
 362     set(CMAKE_REQUIRED_FLAGS ${OLD_CMAKE_REQUIRED_FLAGS})
 363     if (CXX_SUPPORTS_MODULES)
 364       append_if(CXX_SUPPORTS_MODULES "-fmodules" CMAKE_C_FLAGS)
 365       append_if(CXX_SUPPORTS_MODULES "-fmodules -fcxx-modules" CMAKE_CXX_FLAGS)
 366     else()
 367       message(FATAL_ERROR "LLVM_ENABLE_MODULES is not supported by this compiler")
 368     endif()
 369   endif(LLVM_ENABLE_MODULES)
 370 endif( MSVC )
 371
 372 macro(append_common_sanitizer_flags)
 373   # Append -fno-omit-frame-pointer and turn on debug info to get better
 374   # stack traces.
 375   add_flag_if_supported("-fno-omit-frame-pointer" FNO_OMIT_FRAME_POINTER)
 376   if (NOT uppercase_CMAKE_BUILD_TYPE STREQUAL "DEBUG" AND
 377       NOT uppercase_CMAKE_BUILD_TYPE STREQUAL "RELWITHDEBINFO")
 378     add_flag_if_supported("-gline-tables-only" GLINE_TABLES_ONLY)
 379   endif()
 380   # Use -O1 even in debug mode, otherwise sanitizers slowdown is too large.
 381   if (uppercase_CMAKE_BUILD_TYPE STREQUAL "DEBUG")
 382     add_flag_if_supported("-O1" O1)
 383   endif()
 384 endmacro()
 385
 386 # Turn on sanitizers if necessary.
 387 if(LLVM_USE_SANITIZER)
 388   if (LLVM_ON_UNIX)
 389     if (LLVM_USE_SANITIZER STREQUAL "Address")
 390       append_common_sanitizer_flags()
 391       append("-fsanitize=address" CMAKE_C_FLAGS CMAKE_CXX_FLAGS)
 392     elseif (LLVM_USE_SANITIZER MATCHES "Memory(WithOrigins)?")
 393       append_common_sanitizer_flags()
 394       append("-fsanitize=memory" CMAKE_C_FLAGS CMAKE_CXX_FLAGS)
 395       if(LLVM_USE_SANITIZER STREQUAL "MemoryWithOrigins")
 396         append("-fsanitize-memory-track-origins" CMAKE_C_FLAGS CMAKE_CXX_FLAGS)
 397       endif()
 398     elseif (LLVM_USE_SANITIZER STREQUAL "Undefined")
 399       append_common_sanitizer_flags()
 400       append("-fsanitize=undefined -fno-sanitize=vptr,function -fno-sanitize-recover"
 401               CMAKE_C_FLAGS CMAKE_CXX_FLAGS)
 402     elseif (LLVM_USE_SANITIZER STREQUAL "Thread")
 403       append_common_sanitizer_flags()
 404       append("-fsanitize=thread" CMAKE_C_FLAGS CMAKE_CXX_FLAGS)
 405     else()
 406       message(WARNING "Unsupported value of LLVM_USE_SANITIZER: ${LLVM_USE_SANITIZER}")
 407     endif()
 408   else()
 409     message(WARNING "LLVM_USE_SANITIZER is not supported on this platform.")
 410   endif()
 411 endif()
 412
 413 # Turn on -gsplit-dwarf if requested
 414 if(LLVM_USE_SPLIT_DWARF)
 415   add_definitions("-gsplit-dwarf")
 416 endif()
 417
 418 add_llvm_definitions( -D__STDC_CONSTANT_MACROS )
 419 add_llvm_definitions( -D__STDC_FORMAT_MACROS )
 420 add_llvm_definitions( -D__STDC_LIMIT_MACROS )
 421
 422 # clang doesn't print colored diagnostics when invoked from Ninja
 423 if (UNIX AND
 424     CMAKE_CXX_COMPILER_ID STREQUAL "Clang" AND
 425     CMAKE_GENERATOR STREQUAL "Ninja")
 426   append("-fcolor-diagnostics" CMAKE_C_FLAGS CMAKE_CXX_FLAGS)
 427 endif()
 428
 429 # Add flags for add_dead_strip().
 430 # FIXME: With MSVS, consider compiling with /Gy and linking with /OPT:REF?
 431 # But MinSizeRel seems to add that automatically, so maybe disable these
 432 # flags instead if LLVM_NO_DEAD_STRIP is set.
 433 if(NOT CYGWIN AND NOT WIN32)
 434   if(NOT ${CMAKE_SYSTEM_NAME} MATCHES "Darwin")
 435     check_c_compiler_flag("-Werror -fno-function-sections" C_SUPPORTS_FNO_FUNCTION_SECTIONS)
 436     if (C_SUPPORTS_FNO_FUNCTION_SECTIONS)
 437       # Don't add -ffunction-section if it can be disabled with -fno-function-sections.
 438       # Doing so will break sanitizers.
 439       add_flag_if_supported("-ffunction-sections" FFUNCTION_SECTIONS)
 440     endif()
 441     add_flag_if_supported("-fdata-sections" FDATA_SECTIONS)
 442   endif()
 443 endif()
 444
 445 if(CYGWIN OR MINGW)
 446   # Prune --out-implib from executables. It doesn't make sense even
 447   # with --export-all-symbols.
 448   string(REGEX REPLACE "-Wl,--out-implib,[^ ]+ " " "
 449     CMAKE_C_LINK_EXECUTABLE "${CMAKE_C_LINK_EXECUTABLE}")
 450   string(REGEX REPLACE "-Wl,--out-implib,[^ ]+ " " "
 451     CMAKE_CXX_LINK_EXECUTABLE "${CMAKE_CXX_LINK_EXECUTABLE}")
 452 endif()
 453
 454 if(MSVC)
 455   # Remove flags here, for exceptions and RTTI.
 456   # Each target property or source property should be responsible to control
 457   # them.
 458   # CL.EXE complains to override flags like "/GR /GR-".
 459   string(REGEX REPLACE "(^| ) */EH[-cs]+ *( |$)" "\\1 \\2" CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS}")
 460   string(REGEX REPLACE "(^| ) */GR-? *( |$)" "\\1 \\2" CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS}")
 461 endif()
 462
 463 # Provide public options to globally control RTTI and EH
 464 option(LLVM_ENABLE_EH "Enable Exception handling" OFF)
 465 option(LLVM_ENABLE_RTTI "Enable run time type information" OFF)
 466 if(LLVM_ENABLE_EH AND NOT LLVM_ENABLE_RTTI)
 467   message(FATAL_ERROR "Exception handling requires RTTI. You must set LLVM_ENABLE_RTTI to ON")
 468 endif()
 469
 470 # Plugin support
 471 # FIXME: Make this configurable.
 472 if(WIN32 OR CYGWIN)
 473   if(BUILD_SHARED_LIBS)
 474     set(LLVM_ENABLE_PLUGINS ON)
 475   else()
 476     set(LLVM_ENABLE_PLUGINS OFF)
 477   endif()
 478 else()
 479   set(LLVM_ENABLE_PLUGINS ON)
 480 endif()