cmake/modules/AddLLVM.cmake

   1 include(LLVMParseArguments)
   2 include(LLVMProcessSources)
   3 include(LLVM-Config)
   4
   5 function(llvm_update_compile_flags name)
   6   get_property(sources TARGET ${name} PROPERTY SOURCES)
   7   if("${sources}" MATCHES "\\.c(;|$)")
   8     set(update_src_props ON)
   9   endif()
  10
  11   if(LLVM_REQUIRES_EH)
  12     set(LLVM_REQUIRES_RTTI ON)
  13   else()
  14     if(LLVM_COMPILER_IS_GCC_COMPATIBLE)
  15       list(APPEND LLVM_COMPILE_FLAGS "-fno-exceptions")
  16     elseif(MSVC)
  17       list(APPEND LLVM_COMPILE_DEFINITIONS _HAS_EXCEPTIONS=0)
  18       list(APPEND LLVM_COMPILE_FLAGS "/EHs-c-")
  19     endif()
  20   endif()
  21
  22   if(NOT LLVM_REQUIRES_RTTI)
  23     list(APPEND LLVM_COMPILE_DEFINITIONS GTEST_HAS_RTTI=0)
  24     if (LLVM_COMPILER_IS_GCC_COMPATIBLE)
  25       list(APPEND LLVM_COMPILE_FLAGS "-fno-rtti")
  26     elseif (MSVC)
  27       list(APPEND LLVM_COMPILE_FLAGS "/GR-")
  28     endif ()
  29   endif()
  30
  31   # Assume that;
  32   #   - LLVM_COMPILE_FLAGS is list.
  33   #   - PROPERTY COMPILE_FLAGS is string.
  34   string(REPLACE ";" " " target_compile_flags "${LLVM_COMPILE_FLAGS}")
  35
  36   if(update_src_props)
  37     foreach(fn ${sources})
  38       get_filename_component(suf ${fn} EXT)
  39       if("${suf}" STREQUAL ".cpp")
  40         set_property(SOURCE ${fn} APPEND_STRING PROPERTY
  41           COMPILE_FLAGS "${target_compile_flags}")
  42       endif()
  43     endforeach()
  44   else()
  45     # Update target props, since all sources are C++.
  46     set_property(TARGET ${name} APPEND_STRING PROPERTY
  47       COMPILE_FLAGS "${target_compile_flags}")
  48   endif()
  49
  50   set_property(TARGET ${name} APPEND PROPERTY COMPILE_DEFINITIONS ${LLVM_COMPILE_DEFINITIONS})
  51 endfunction()
  52
  53 function(add_llvm_symbol_exports target_name export_file)
  54   if(${CMAKE_SYSTEM_NAME} MATCHES "Darwin")
  55     set(native_export_file "${target_name}.exports")
  56     add_custom_command(OUTPUT ${native_export_file}
  57       COMMAND sed -e "s/^/_/" < ${export_file} > ${native_export_file}
  58       DEPENDS ${export_file}
  59       VERBATIM
  60       COMMENT "Creating export file for ${target_name}")
  61     set_property(TARGET ${target_name} APPEND_STRING PROPERTY
  62                  LINK_FLAGS " -Wl,-exported_symbols_list,${CMAKE_CURRENT_BINARY_DIR}/${native_export_file}")
  63   elseif(LLVM_HAVE_LINK_VERSION_SCRIPT)
  64     # Gold and BFD ld require a version script rather than a plain list.
  65     set(native_export_file "${target_name}.exports")
  66     # FIXME: Don't write the "local:" line on OpenBSD.
  67     add_custom_command(OUTPUT ${native_export_file}
  68       COMMAND echo "{" > ${native_export_file}
  69       COMMAND grep -q "[[:alnum:]]" ${export_file} && echo "  global:" >> ${native_export_file} || :
  70       COMMAND sed -e "s/$/;/" -e "s/^/    /" < ${export_file} >> ${native_export_file}
  71       COMMAND echo "  local: *;" >> ${native_export_file}
  72       COMMAND echo "};" >> ${native_export_file}
  73       DEPENDS ${export_file}
  74       VERBATIM
  75       COMMENT "Creating export file for ${target_name}")
  76     set_property(TARGET ${target_name} APPEND_STRING PROPERTY
  77                  LINK_FLAGS "  -Wl,--version-script,${CMAKE_CURRENT_BINARY_DIR}/${native_export_file}")
  78   else()
  79     set(native_export_file "${target_name}.def")
  80
  81     set(CAT "type")
  82     if(CYGWIN)
  83       set(CAT "cat")
  84     endif()
  85
  86     # Using ${export_file} in add_custom_command directly confuses cmd.exe.
  87     file(TO_NATIVE_PATH ${export_file} export_file_backslashes)
  88
  89     add_custom_command(OUTPUT ${native_export_file}
  90       COMMAND ${CMAKE_COMMAND} -E echo "EXPORTS" > ${native_export_file}
  91       COMMAND ${CAT} ${export_file_backslashes} >> ${native_export_file}
  92       DEPENDS ${export_file}
  93       VERBATIM
  94       COMMENT "Creating export file for ${target_name}")
  95     if(CYGWIN OR MINGW)
  96       set_property(TARGET ${target_name} APPEND_STRING PROPERTY
  97                    LINK_FLAGS " ${CMAKE_CURRENT_BINARY_DIR}/${native_export_file}")
  98     else()
  99       set_property(TARGET ${target_name} APPEND_STRING PROPERTY
 100                    LINK_FLAGS " /DEF:${CMAKE_CURRENT_BINARY_DIR}/${native_export_file}")
 101     endif()
 102   endif()
 103
 104   add_custom_target(${target_name}_exports DEPENDS ${native_export_file})
 105   set_target_properties(${target_name}_exports PROPERTIES FOLDER "Misc")
 106
 107   get_property(srcs TARGET ${target_name} PROPERTY SOURCES)
 108   foreach(src ${srcs})
 109     get_filename_component(extension ${src} EXT)
 110     if(extension STREQUAL ".cpp")
 111       set(first_source_file ${src})
 112       break()
 113     endif()
 114   endforeach()
 115
 116   # Force re-linking when the exports file changes. Actually, it
 117   # forces recompilation of the source file. The LINK_DEPENDS target
 118   # property only works for makefile-based generators.
 119   # FIXME: This is not safe because this will create the same target
 120   # ${native_export_file} in several different file:
 121   # - One where we emitted ${target_name}_exports
 122   # - One where we emitted the build command for the following object.
 123   # set_property(SOURCE ${first_source_file} APPEND PROPERTY
 124   #   OBJECT_DEPENDS ${CMAKE_CURRENT_BINARY_DIR}/${native_export_file})
 125
 126   set_property(DIRECTORY APPEND
 127     PROPERTY ADDITIONAL_MAKE_CLEAN_FILES ${native_export_file})
 128
 129   add_dependencies(${target_name} ${target_name}_exports)
 130
 131   # Add dependency to *_exports later -- CMake issue 14747
 132   list(APPEND LLVM_COMMON_DEPENDS ${target_name}_exports)
 133   set(LLVM_COMMON_DEPENDS ${LLVM_COMMON_DEPENDS} PARENT_SCOPE)
 134 endfunction(add_llvm_symbol_exports)
 135
 136 function(add_dead_strip target_name)
 137   if(NOT LLVM_NO_DEAD_STRIP)
 138     if(${CMAKE_SYSTEM_NAME} MATCHES "Darwin")
 139       set_property(TARGET ${target_name} APPEND_STRING PROPERTY
 140                    LINK_FLAGS " -Wl,-dead_strip")
 141     elseif(NOT WIN32)
 142       # Object files are compiled with -ffunction-data-sections.
 143       set_property(TARGET ${target_name} APPEND_STRING PROPERTY
 144                    LINK_FLAGS " -Wl,--gc-sections")
 145     endif()
 146   endif()
 147 endfunction(add_dead_strip)
 148
 149 # Set each output directory according to ${CMAKE_CONFIGURATION_TYPES}.
 150 # Note: Don't set variables CMAKE_*_OUTPUT_DIRECTORY any more,
 151 # or a certain builder, for eaxample, msbuild.exe, would be confused.
 152 function(set_output_directory target bindir libdir)
 153   if(NOT "${CMAKE_CFG_INTDIR}" STREQUAL ".")
 154     foreach(build_mode ${CMAKE_CONFIGURATION_TYPES})
 155       string(TOUPPER "${build_mode}" CONFIG_SUFFIX)
 156       string(REPLACE ${CMAKE_CFG_INTDIR} ${build_mode} bi ${bindir})
 157       string(REPLACE ${CMAKE_CFG_INTDIR} ${build_mode} li ${libdir})
 158       set_target_properties(${target} PROPERTIES "RUNTIME_OUTPUT_DIRECTORY_${CONFIG_SUFFIX}" ${bi})
 159       set_target_properties(${target} PROPERTIES "ARCHIVE_OUTPUT_DIRECTORY_${CONFIG_SUFFIX}" ${li})
 160       set_target_properties(${target} PROPERTIES "LIBRARY_OUTPUT_DIRECTORY_${CONFIG_SUFFIX}" ${li})
 161     endforeach()
 162   else()
 163     set_target_properties(${target} PROPERTIES RUNTIME_OUTPUT_DIRECTORY ${bindir})
 164     set_target_properties(${target} PROPERTIES ARCHIVE_OUTPUT_DIRECTORY ${libdir})
 165     set_target_properties(${target} PROPERTIES LIBRARY_OUTPUT_DIRECTORY ${libdir})
 166   endif()
 167 endfunction()
 168
 169 # llvm_add_library(name sources...
 170 #   SHARED;STATIC
 171 #     STATIC by default w/o BUILD_SHARED_LIBS.
 172 #     SHARED by default w/  BUILD_SHARED_LIBS.
 173 #   MODULE
 174 #     Target ${name} might not be created on unsupported platforms.
 175 #     Check with "if(TARGET ${name})".
 176 #   OUTPUT_NAME name
 177 #     Corresponds to OUTPUT_NAME in target properties.
 178 #   DEPENDS targets...
 179 #     Same semantics as add_dependencies().
 180 #   LINK_COMPONENTS components...
 181 #     Same as the variable LLVM_LINK_COMPONENTS.
 182 #   LINK_LIBS lib_targets...
 183 #     Same semantics as target_link_libraries().
 184 #   ADDITIONAL_HEADERS
 185 #     May specify header files for IDE generators.
 186 #   )
 187 function(llvm_add_library name)
 188   cmake_parse_arguments(ARG
 189     "MODULE;SHARED;STATIC"
 190     "OUTPUT_NAME"
 191     "ADDITIONAL_HEADERS;DEPENDS;LINK_COMPONENTS;LINK_LIBS;OBJLIBS"
 192     ${ARGN})
 193   list(APPEND LLVM_COMMON_DEPENDS ${ARG_DEPENDS})
 194   if(ARG_ADDITIONAL_HEADERS)
 195     # Pass through ADDITIONAL_HEADERS.
 196     set(ARG_ADDITIONAL_HEADERS ADDITIONAL_HEADERS ${ARG_ADDITIONAL_HEADERS})
 197   endif()
 198   if(ARG_OBJLIBS)
 199     set(ALL_FILES ${ARG_OBJLIBS})
 200   else()
 201     llvm_process_sources(ALL_FILES ${ARG_UNPARSED_ARGUMENTS} ${ARG_ADDITIONAL_HEADERS})
 202   endif()
 203
 204   if(ARG_MODULE)
 205     if(ARG_SHARED OR ARG_STATIC)
 206       message(WARNING "MODULE with SHARED|STATIC doesn't make sense.")
 207     endif()
 208     if(NOT LLVM_ON_UNIX OR CYGWIN)
 209       message(STATUS "${name} ignored -- Loadable modules not supported on this platform.")
 210       return()
 211     endif()
 212   else()
 213     if(BUILD_SHARED_LIBS AND NOT ARG_STATIC)
 214       set(ARG_SHARED TRUE)
 215     endif()
 216     if(NOT ARG_SHARED)
 217       set(ARG_STATIC TRUE)
 218     endif()
 219   endif()
 220
 221   # Generate objlib
 222   if(ARG_SHARED AND ARG_STATIC)
 223     # Generate an obj library for both targets.
 224     set(obj_name "obj.${name}")
 225     add_library(${obj_name} OBJECT EXCLUDE_FROM_ALL
 226       ${ALL_FILES}
 227       )
 228     llvm_update_compile_flags(${obj_name})
 229     set(ALL_FILES "$<TARGET_OBJECTS:${obj_name}>")
 230
 231     # Do add_dependencies(obj) later due to CMake issue 14747.
 232     list(APPEND objlibs ${obj_name})
 233
 234     set_target_properties(${obj_name} PROPERTIES FOLDER "Object Libraries")
 235   endif()
 236
 237   if(ARG_SHARED AND ARG_STATIC)
 238     # static
 239     set(name_static "${name}_static")
 240     if(ARG_OUTPUT_NAME)
 241       set(output_name OUTPUT_NAME "${ARG_OUTPUT_NAME}")
 242     endif()
 243     # DEPENDS has been appended to LLVM_COMMON_LIBS.
 244     llvm_add_library(${name_static} STATIC
 245       ${output_name}
 246       OBJLIBS ${ALL_FILES} # objlib
 247       LINK_LIBS ${ARG_LINK_LIBS}
 248       LINK_COMPONENTS ${ARG_LINK_COMPONENTS}
 249       )
 250     # FIXME: Add name_static to anywhere in TARGET ${name}'s PROPERTY.
 251     set(ARG_STATIC)
 252   endif()
 253
 254   if(ARG_MODULE)
 255     add_library(${name} MODULE ${ALL_FILES})
 256   elseif(ARG_SHARED)
 257     add_library(${name} SHARED ${ALL_FILES})
 258   else()
 259     add_library(${name} STATIC ${ALL_FILES})
 260   endif()
 261   set_output_directory(${name} ${LLVM_RUNTIME_OUTPUT_INTDIR} ${LLVM_LIBRARY_OUTPUT_INTDIR})
 262   llvm_update_compile_flags(${name})
 263   add_dead_strip( ${name} )
 264   if(ARG_OUTPUT_NAME)
 265     set_target_properties(${name}
 266       PROPERTIES
 267       OUTPUT_NAME ${ARG_OUTPUT_NAME}
 268       )
 269   endif()
 270
 271   if(ARG_MODULE)
 272     set_target_properties(${name} PROPERTIES
 273       PREFIX ""
 274       SUFFIX ${LLVM_PLUGIN_EXT}
 275       )
 276   endif()
 277
 278   if(ARG_SHARED)
 279     if (MSVC)
 280       set_target_properties(${name}
 281         PROPERTIES
 282         IMPORT_SUFFIX ".imp")
 283     endif ()
 284   endif()
 285
 286   if(ARG_MODULE OR ARG_SHARED)
 287     if (LLVM_EXPORTED_SYMBOL_FILE)
 288       add_llvm_symbol_exports( ${name} ${LLVM_EXPORTED_SYMBOL_FILE} )
 289     endif()
 290   endif()
 291
 292   # Add the explicit dependency information for this library.
 293   #
 294   # It would be nice to verify that we have the dependencies for this library
 295   # name, but using get_property(... SET) doesn't suffice to determine if a
 296   # property has been set to an empty value.
 297   get_property(lib_deps GLOBAL PROPERTY LLVMBUILD_LIB_DEPS_${name})
 298
 299   llvm_map_components_to_libnames(llvm_libs
 300     ${ARG_LINK_COMPONENTS}
 301     ${LLVM_LINK_COMPONENTS}
 302     )
 303
 304   if(CMAKE_VERSION VERSION_LESS 2.8.12)
 305     # Link libs w/o keywords, assuming PUBLIC.
 306     target_link_libraries(${name}
 307       ${ARG_LINK_LIBS}
 308       ${lib_deps}
 309       ${llvm_libs}
 310       )
 311   elseif(ARG_STATIC)
 312     target_link_libraries(${name} INTERFACE
 313       ${ARG_LINK_LIBS}
 314       ${lib_deps}
 315       ${llvm_libs}
 316       )
 317   elseif(ARG_SHARED AND BUILD_SHARED_LIBS)
 318     # FIXME: It may be PRIVATE since SO knows its dependent libs.
 319     target_link_libraries(${name} PUBLIC
 320       ${ARG_LINK_LIBS}
 321       ${lib_deps}
 322       ${llvm_libs}
 323       )
 324   else()
 325     # MODULE|SHARED
 326     target_link_libraries(${name} PRIVATE
 327       ${ARG_LINK_LIBS}
 328       ${lib_deps}
 329       ${llvm_libs}
 330       )
 331   endif()
 332
 333   if(LLVM_COMMON_DEPENDS)
 334     add_dependencies(${name} ${LLVM_COMMON_DEPENDS})
 335     # Add dependencies also to objlibs.
 336     # CMake issue 14747 --  add_dependencies() might be ignored to objlib's user.
 337     foreach(objlib ${objlibs})
 338       add_dependencies(${objlib} ${LLVM_COMMON_DEPENDS})
 339     endforeach()
 340   endif()
 341 endfunction()
 342
 343 macro(add_llvm_library name)
 344   if( BUILD_SHARED_LIBS )
 345     llvm_add_library(${name} SHARED ${ARGN})
 346   else()
 347     llvm_add_library(${name} ${ARGN})
 348   endif()
 349   set_property( GLOBAL APPEND PROPERTY LLVM_LIBS ${name} )
 350
 351   if( EXCLUDE_FROM_ALL )
 352     set_target_properties( ${name} PROPERTIES EXCLUDE_FROM_ALL ON)
 353   else()
 354     if (NOT LLVM_INSTALL_TOOLCHAIN_ONLY OR ${name} STREQUAL "LTO")
 355       install(TARGETS ${name}
 356         EXPORT LLVMExports
 357         LIBRARY DESTINATION lib${LLVM_LIBDIR_SUFFIX}
 358         ARCHIVE DESTINATION lib${LLVM_LIBDIR_SUFFIX})
 359     endif()
 360     set_property(GLOBAL APPEND PROPERTY LLVM_EXPORTS ${name})
 361   endif()
 362   set_target_properties(${name} PROPERTIES FOLDER "Libraries")
 363 endmacro(add_llvm_library name)
 364
 365 macro(add_llvm_loadable_module name)
 366   llvm_add_library(${name} MODULE ${ARGN})
 367   if(NOT TARGET ${name})
 368     # Add empty "phony" target
 369     add_custom_target(${name})
 370   else()
 371     if( EXCLUDE_FROM_ALL )
 372       set_target_properties( ${name} PROPERTIES EXCLUDE_FROM_ALL ON)
 373     else()
 374       if (NOT LLVM_INSTALL_TOOLCHAIN_ONLY)
 375         install(TARGETS ${name}
 376           EXPORT LLVMExports
 377           LIBRARY DESTINATION lib${LLVM_LIBDIR_SUFFIX}
 378           ARCHIVE DESTINATION lib${LLVM_LIBDIR_SUFFIX})
 379       endif()
 380       set_property(GLOBAL APPEND PROPERTY LLVM_EXPORTS ${name})
 381     endif()
 382   endif()
 383
 384   set_target_properties(${name} PROPERTIES FOLDER "Loadable modules")
 385 endmacro(add_llvm_loadable_module name)
 386
 387
 388 macro(add_llvm_executable name)
 389   llvm_process_sources( ALL_FILES ${ARGN} )
 390   if( EXCLUDE_FROM_ALL )
 391     add_executable(${name} EXCLUDE_FROM_ALL ${ALL_FILES})
 392   else()
 393     add_executable(${name} ${ALL_FILES})
 394   endif()
 395   llvm_update_compile_flags(${name})
 396   add_dead_strip( ${name} )
 397
 398   if (LLVM_EXPORTED_SYMBOL_FILE)
 399     add_llvm_symbol_exports( ${name} ${LLVM_EXPORTED_SYMBOL_FILE} )
 400   endif(LLVM_EXPORTED_SYMBOL_FILE)
 401
 402   set(EXCLUDE_FROM_ALL OFF)
 403   set_output_directory(${name} ${LLVM_RUNTIME_OUTPUT_INTDIR} ${LLVM_LIBRARY_OUTPUT_INTDIR})
 404   llvm_config( ${name} ${LLVM_LINK_COMPONENTS} )
 405   if( LLVM_COMMON_DEPENDS )
 406     add_dependencies( ${name} ${LLVM_COMMON_DEPENDS} )
 407   endif( LLVM_COMMON_DEPENDS )
 408 endmacro(add_llvm_executable name)
 409
 410
 411 set (LLVM_TOOLCHAIN_TOOLS
 412   llvm-ar
 413   llvm-objdump
 414   )
 415
 416 macro(add_llvm_tool name)
 417   if( NOT LLVM_BUILD_TOOLS )
 418     set(EXCLUDE_FROM_ALL ON)
 419   endif()
 420   add_llvm_executable(${name} ${ARGN})
 421
 422   list(FIND LLVM_TOOLCHAIN_TOOLS ${name} LLVM_IS_${name}_TOOLCHAIN_TOOL)
 423   if (LLVM_IS_${name}_TOOLCHAIN_TOOL GREATER -1 OR NOT LLVM_INSTALL_TOOLCHAIN_ONLY)
 424     if( LLVM_BUILD_TOOLS )
 425       install(TARGETS ${name}
 426               EXPORT LLVMExports
 427               RUNTIME DESTINATION bin)
 428     endif()
 429   endif()
 430   if( LLVM_BUILD_TOOLS )
 431     set_property(GLOBAL APPEND PROPERTY LLVM_EXPORTS ${name})
 432   endif()
 433   set_target_properties(${name} PROPERTIES FOLDER "Tools")
 434 endmacro(add_llvm_tool name)
 435
 436
 437 macro(add_llvm_example name)
 438   if( NOT LLVM_BUILD_EXAMPLES )
 439     set(EXCLUDE_FROM_ALL ON)
 440   endif()
 441   add_llvm_executable(${name} ${ARGN})
 442   if( LLVM_BUILD_EXAMPLES )
 443     install(TARGETS ${name} RUNTIME DESTINATION examples)
 444   endif()
 445   set_target_properties(${name} PROPERTIES FOLDER "Examples")
 446 endmacro(add_llvm_example name)
 447
 448
 449 macro(add_llvm_utility name)
 450   add_llvm_executable(${name} ${ARGN})
 451   set_target_properties(${name} PROPERTIES FOLDER "Utils")
 452 endmacro(add_llvm_utility name)
 453
 454
 455 macro(add_llvm_target target_name)
 456   include_directories(BEFORE
 457     ${CMAKE_CURRENT_BINARY_DIR}
 458     ${CMAKE_CURRENT_SOURCE_DIR})
 459   add_llvm_library(LLVM${target_name} ${ARGN} ${TABLEGEN_OUTPUT})
 460   set( CURRENT_LLVM_TARGET LLVM${target_name} )
 461 endmacro(add_llvm_target)
 462
 463 # Add external project that may want to be built as part of llvm such as Clang,
 464 # lld, and Polly. This adds two options. One for the source directory of the
 465 # project, which defaults to ${CMAKE_CURRENT_SOURCE_DIR}/${name}. Another to
 466 # enable or disable building it with everything else.
 467 # Additional parameter can be specified as the name of directory.
 468 macro(add_llvm_external_project name)
 469   set(add_llvm_external_dir "${ARGN}")
 470   if("${add_llvm_external_dir}" STREQUAL "")
 471     set(add_llvm_external_dir ${name})
 472   endif()
 473   list(APPEND LLVM_IMPLICIT_PROJECT_IGNORE "${CMAKE_CURRENT_SOURCE_DIR}/${add_llvm_external_dir}")
 474   string(REPLACE "-" "_" nameUNDERSCORE ${name})
 475   string(TOUPPER ${nameUNDERSCORE} nameUPPER)
 476   set(LLVM_EXTERNAL_${nameUPPER}_SOURCE_DIR "${CMAKE_CURRENT_SOURCE_DIR}/${add_llvm_external_dir}"
 477       CACHE PATH "Path to ${name} source directory")
 478   if (NOT ${LLVM_EXTERNAL_${nameUPPER}_SOURCE_DIR} STREQUAL ""
 479       AND EXISTS ${LLVM_EXTERNAL_${nameUPPER}_SOURCE_DIR}/CMakeLists.txt)
 480     option(LLVM_EXTERNAL_${nameUPPER}_BUILD
 481            "Whether to build ${name} as part of LLVM" ON)
 482     if (LLVM_EXTERNAL_${nameUPPER}_BUILD)
 483       add_subdirectory(${LLVM_EXTERNAL_${nameUPPER}_SOURCE_DIR} ${add_llvm_external_dir})
 484     endif()
 485   endif()
 486 endmacro(add_llvm_external_project)
 487
 488 macro(add_llvm_tool_subdirectory name)
 489   list(APPEND LLVM_IMPLICIT_PROJECT_IGNORE "${CMAKE_CURRENT_SOURCE_DIR}/${name}")
 490   add_subdirectory(${name})
 491 endmacro(add_llvm_tool_subdirectory)
 492
 493 macro(ignore_llvm_tool_subdirectory name)
 494   list(APPEND LLVM_IMPLICIT_PROJECT_IGNORE "${CMAKE_CURRENT_SOURCE_DIR}/${name}")
 495 endmacro(ignore_llvm_tool_subdirectory)
 496
 497 function(add_llvm_implicit_external_projects)
 498   set(list_of_implicit_subdirs "")
 499   file(GLOB sub-dirs "${CMAKE_CURRENT_SOURCE_DIR}/*")
 500   foreach(dir ${sub-dirs})
 501     if(IS_DIRECTORY "${dir}")
 502       list(FIND LLVM_IMPLICIT_PROJECT_IGNORE "${dir}" tool_subdir_ignore)
 503       if( tool_subdir_ignore EQUAL -1
 504           AND EXISTS "${dir}/CMakeLists.txt")
 505         get_filename_component(fn "${dir}" NAME)
 506         list(APPEND list_of_implicit_subdirs "${fn}")
 507       endif()
 508     endif()
 509   endforeach()
 510
 511   foreach(external_proj ${list_of_implicit_subdirs})
 512     add_llvm_external_project("${external_proj}")
 513   endforeach()
 514 endfunction(add_llvm_implicit_external_projects)
 515
 516 # Generic support for adding a unittest.
 517 function(add_unittest test_suite test_name)
 518   if( NOT LLVM_BUILD_TESTS )
 519     set(EXCLUDE_FROM_ALL ON)
 520   endif()
 521
 522   # Visual Studio 2012 only supports up to 8 template parameters in
 523   # std::tr1::tuple by default, but gtest requires 10
 524   if (MSVC AND MSVC_VERSION EQUAL 1700)
 525     list(APPEND LLVM_COMPILE_DEFINITIONS _VARIADIC_MAX=10)
 526   endif ()
 527
 528   include_directories(${LLVM_MAIN_SRC_DIR}/utils/unittest/googletest/include)
 529   if (NOT LLVM_ENABLE_THREADS)
 530     list(APPEND LLVM_COMPILE_DEFINITIONS GTEST_HAS_PTHREAD=0)
 531   endif ()
 532
 533   if (SUPPORTS_NO_VARIADIC_MACROS_FLAG)
 534     list(APPEND LLVM_COMPILE_FLAGS "-Wno-variadic-macros")
 535   endif ()
 536
 537   set(LLVM_REQUIRES_RTTI OFF)
 538
 539   add_llvm_executable(${test_name} ${ARGN})
 540   set(outdir ${CMAKE_CURRENT_BINARY_DIR}/${CMAKE_CFG_INTDIR})
 541   set_output_directory(${test_name} ${outdir} ${outdir})
 542   target_link_libraries(${test_name}
 543     gtest
 544     gtest_main
 545     LLVMSupport # gtest needs it for raw_ostream.
 546     )
 547
 548   add_dependencies(${test_suite} ${test_name})
 549   get_target_property(test_suite_folder ${test_suite} FOLDER)
 550   if (NOT ${test_suite_folder} STREQUAL "NOTFOUND")
 551     set_property(TARGET ${test_name} PROPERTY FOLDER "${test_suite_folder}")
 552   endif ()
 553 endfunction()
 554
 555 # This function provides an automatic way to 'configure'-like generate a file
 556 # based on a set of common and custom variables, specifically targeting the
 557 # variables needed for the 'lit.site.cfg' files. This function bundles the
 558 # common variables that any Lit instance is likely to need, and custom
 559 # variables can be passed in.
 560 function(configure_lit_site_cfg input output)
 561   foreach(c ${LLVM_TARGETS_TO_BUILD})
 562     set(TARGETS_BUILT "${TARGETS_BUILT} ${c}")
 563   endforeach(c)
 564   set(TARGETS_TO_BUILD ${TARGETS_BUILT})
 565
 566   set(SHLIBEXT "${LTDL_SHLIB_EXT}")
 567
 568   if(BUILD_SHARED_LIBS)
 569     set(LLVM_SHARED_LIBS_ENABLED "1")
 570   else()
 571     set(LLVM_SHARED_LIBS_ENABLED "0")
 572   endif(BUILD_SHARED_LIBS)
 573
 574   if(${CMAKE_SYSTEM_NAME} MATCHES "Darwin")
 575     set(SHLIBPATH_VAR "DYLD_LIBRARY_PATH")
 576   else() # Default for all other unix like systems.
 577     # CMake hardcodes the library locaction using rpath.
 578     # Therefore LD_LIBRARY_PATH is not required to run binaries in the
 579     # build dir. We pass it anyways.
 580     set(SHLIBPATH_VAR "LD_LIBRARY_PATH")
 581   endif()
 582
 583   # Configuration-time: See Unit/lit.site.cfg.in
 584   if (CMAKE_CFG_INTDIR STREQUAL ".")
 585     set(LLVM_BUILD_MODE ".")
 586   else ()
 587     set(LLVM_BUILD_MODE "%(build_mode)s")
 588   endif ()
 589
 590   # They below might not be the build tree but provided binary tree.
 591   set(LLVM_SOURCE_DIR ${LLVM_MAIN_SRC_DIR})
 592   set(LLVM_BINARY_DIR ${LLVM_BINARY_DIR})
 593   string(REPLACE ${CMAKE_CFG_INTDIR} ${LLVM_BUILD_MODE} LLVM_TOOLS_DIR ${LLVM_TOOLS_BINARY_DIR})
 594   string(REPLACE ${CMAKE_CFG_INTDIR} ${LLVM_BUILD_MODE} LLVM_LIBS_DIR  ${LLVM_LIBRARY_DIR})
 595
 596   # SHLIBDIR points the build tree.
 597   string(REPLACE ${CMAKE_CFG_INTDIR} ${LLVM_BUILD_MODE} SHLIBDIR ${LLVM_LIBRARY_OUTPUT_INTDIR})
 598
 599   set(PYTHON_EXECUTABLE ${PYTHON_EXECUTABLE})
 600   set(ENABLE_SHARED ${LLVM_SHARED_LIBS_ENABLED})
 601   set(SHLIBPATH_VAR ${SHLIBPATH_VAR})
 602
 603   if(LLVM_ENABLE_ASSERTIONS AND NOT MSVC_IDE)
 604     set(ENABLE_ASSERTIONS "1")
 605   else()
 606     set(ENABLE_ASSERTIONS "0")
 607   endif()
 608
 609   set(HOST_OS ${CMAKE_SYSTEM_NAME})
 610   set(HOST_ARCH ${CMAKE_SYSTEM_PROCESSOR})
 611
 612   if (CLANG_ENABLE_ARCMT)
 613     set(ENABLE_CLANG_ARCMT "1")
 614   else()
 615     set(ENABLE_CLANG_ARCMT "0")
 616   endif()
 617   if (CLANG_ENABLE_REWRITER)
 618     set(ENABLE_CLANG_REWRITER "1")
 619   else()
 620     set(ENABLE_CLANG_REWRITER "0")
 621   endif()
 622   if (CLANG_ENABLE_STATIC_ANALYZER)
 623     set(ENABLE_CLANG_STATIC_ANALYZER "1")
 624   else()
 625     set(ENABLE_CLANG_STATIC_ANALYZER "0")
 626   endif()
 627
 628   configure_file(${input} ${output} @ONLY)
 629 endfunction()
 630
 631 # A raw function to create a lit target. This is used to implement the testuite
 632 # management functions.
 633 function(add_lit_target target comment)
 634   parse_arguments(ARG "PARAMS;DEPENDS;ARGS" "" ${ARGN})
 635   set(LIT_ARGS "${ARG_ARGS} ${LLVM_LIT_ARGS}")
 636   separate_arguments(LIT_ARGS)
 637   if (NOT CMAKE_CFG_INTDIR STREQUAL ".")
 638     list(APPEND LIT_ARGS --param build_mode=${CMAKE_CFG_INTDIR})
 639   endif ()
 640   set(LIT_COMMAND
 641     ${PYTHON_EXECUTABLE}
 642     ${LLVM_MAIN_SRC_DIR}/utils/lit/lit.py
 643     ${LIT_ARGS}
 644     )
 645   foreach(param ${ARG_PARAMS})
 646     list(APPEND LIT_COMMAND --param ${param})
 647   endforeach()
 648   if( ARG_DEPENDS )
 649     add_custom_target(${target}
 650       COMMAND ${LIT_COMMAND} ${ARG_DEFAULT_ARGS}
 651       COMMENT "${comment}"
 652       )
 653     add_dependencies(${target} ${ARG_DEPENDS})
 654   else()
 655     add_custom_target(${target}
 656       COMMAND ${CMAKE_COMMAND} -E echo "${target} does nothing, no tools built.")
 657     message(STATUS "${target} does nothing.")
 658   endif()
 659
 660   # Tests should be excluded from "Build Solution".
 661   set_target_properties(${target} PROPERTIES EXCLUDE_FROM_DEFAULT_BUILD ON)
 662 endfunction()
 663
 664 # A function to add a set of lit test suites to be driven through 'check-*' targets.
 665 function(add_lit_testsuite target comment)
 666   parse_arguments(ARG "PARAMS;DEPENDS;ARGS" "" ${ARGN})
 667
 668   # EXCLUDE_FROM_ALL excludes the test ${target} out of check-all.
 669   if(NOT EXCLUDE_FROM_ALL)
 670     # Register the testsuites, params and depends for the global check rule.
 671     set_property(GLOBAL APPEND PROPERTY LLVM_LIT_TESTSUITES ${ARG_DEFAULT_ARGS})
 672     set_property(GLOBAL APPEND PROPERTY LLVM_LIT_PARAMS ${ARG_PARAMS})
 673     set_property(GLOBAL APPEND PROPERTY LLVM_LIT_DEPENDS ${ARG_DEPENDS})
 674     set_property(GLOBAL APPEND PROPERTY LLVM_LIT_EXTRA_ARGS ${ARG_ARGS})
 675   endif()
 676
 677   # Produce a specific suffixed check rule.
 678   add_lit_target(${target} ${comment}
 679     ${ARG_DEFAULT_ARGS}
 680     PARAMS ${ARG_PARAMS}
 681     DEPENDS ${ARG_DEPENDS}
 682     ARGS ${ARG_ARGS}
 683     )
 684 endfunction()