cmake/modules/AddLLVM.cmake

   1 include(LLVMParseArguments)
   2 include(LLVMProcessSources)
   3 include(LLVM-Config)
   4
   5 function(llvm_update_compile_flags name)
   6   get_property(sources TARGET ${name} PROPERTY SOURCES)
   7   if("${sources}" MATCHES "\\.c(;|$)")
   8     set(update_src_props ON)
   9   endif()
  10
  11   if(LLVM_REQUIRES_EH)
  12     set(LLVM_REQUIRES_RTTI ON)
  13   else()
  14     if(LLVM_COMPILER_IS_GCC_COMPATIBLE)
  15       list(APPEND LLVM_COMPILE_FLAGS "-fno-exceptions")
  16     elseif(MSVC)
  17       list(APPEND LLVM_COMPILE_DEFINITIONS _HAS_EXCEPTIONS=0)
  18       list(APPEND LLVM_COMPILE_FLAGS "/EHs-c-")
  19     endif()
  20   endif()
  21
  22   if(NOT LLVM_REQUIRES_RTTI)
  23     list(APPEND LLVM_COMPILE_DEFINITIONS GTEST_HAS_RTTI=0)
  24     if (LLVM_COMPILER_IS_GCC_COMPATIBLE)
  25       list(APPEND LLVM_COMPILE_FLAGS "-fno-rtti")
  26     elseif (MSVC)
  27       list(APPEND LLVM_COMPILE_FLAGS "/GR-")
  28     endif ()
  29   endif()
  30
  31   # Assume that;
  32   #   - LLVM_COMPILE_FLAGS is list.
  33   #   - PROPERTY COMPILE_FLAGS is string.
  34   string(REPLACE ";" " " target_compile_flags "${LLVM_COMPILE_FLAGS}")
  35
  36   if(update_src_props)
  37     foreach(fn ${sources})
  38       get_filename_component(suf ${fn} EXT)
  39       if("${suf}" STREQUAL ".cpp")
  40         set_property(SOURCE ${fn} APPEND_STRING PROPERTY
  41           COMPILE_FLAGS "${target_compile_flags}")
  42       endif()
  43     endforeach()
  44   else()
  45     # Update target props, since all sources are C++.
  46     set_property(TARGET ${name} APPEND_STRING PROPERTY
  47       COMPILE_FLAGS "${target_compile_flags}")
  48   endif()
  49
  50   set_property(TARGET ${name} APPEND PROPERTY COMPILE_DEFINITIONS ${LLVM_COMPILE_DEFINITIONS})
  51 endfunction()
  52
  53 function(add_llvm_symbol_exports target_name export_file)
  54   if(${CMAKE_SYSTEM_NAME} MATCHES "Darwin")
  55     set(native_export_file "${target_name}.exports")
  56     add_custom_command(OUTPUT ${native_export_file}
  57       COMMAND sed -e "s/^/_/" < ${export_file} > ${native_export_file}
  58       DEPENDS ${export_file}
  59       VERBATIM
  60       COMMENT "Creating export file for ${target_name}")
  61     set_property(TARGET ${target_name} APPEND_STRING PROPERTY
  62                  LINK_FLAGS " -Wl,-exported_symbols_list,${CMAKE_CURRENT_BINARY_DIR}/${native_export_file}")
  63   elseif(LLVM_HAVE_LINK_VERSION_SCRIPT)
  64     # Gold and BFD ld require a version script rather than a plain list.
  65     set(native_export_file "${target_name}.exports")
  66     # FIXME: Don't write the "local:" line on OpenBSD.
  67     add_custom_command(OUTPUT ${native_export_file}
  68       COMMAND echo "{" > ${native_export_file}
  69       COMMAND grep -q "[[:alnum:]]" ${export_file} && echo "  global:" >> ${native_export_file} || :
  70       COMMAND sed -e "s/$/;/" -e "s/^/    /" < ${export_file} >> ${native_export_file}
  71       COMMAND echo "  local: *;" >> ${native_export_file}
  72       COMMAND echo "};" >> ${native_export_file}
  73       DEPENDS ${export_file}
  74       VERBATIM
  75       COMMENT "Creating export file for ${target_name}")
  76     set_property(TARGET ${target_name} APPEND_STRING PROPERTY
  77                  LINK_FLAGS "  -Wl,--version-script,${CMAKE_CURRENT_BINARY_DIR}/${native_export_file}")
  78   else()
  79     set(native_export_file "${target_name}.def")
  80
  81     set(CAT "type")
  82     if(CYGWIN)
  83       set(CAT "cat")
  84     endif()
  85
  86     # Using ${export_file} in add_custom_command directly confuses cmd.exe.
  87     file(TO_NATIVE_PATH ${export_file} export_file_backslashes)
  88
  89     add_custom_command(OUTPUT ${native_export_file}
  90       COMMAND ${CMAKE_COMMAND} -E echo "EXPORTS" > ${native_export_file}
  91       COMMAND ${CAT} ${export_file_backslashes} >> ${native_export_file}
  92       DEPENDS ${export_file}
  93       VERBATIM
  94       COMMENT "Creating export file for ${target_name}")
  95     if(CYGWIN OR MINGW)
  96       set_property(TARGET ${target_name} APPEND_STRING PROPERTY
  97                    LINK_FLAGS " ${CMAKE_CURRENT_BINARY_DIR}/${native_export_file}")
  98     else()
  99       set_property(TARGET ${target_name} APPEND_STRING PROPERTY
 100                    LINK_FLAGS " /DEF:${CMAKE_CURRENT_BINARY_DIR}/${native_export_file}")
 101     endif()
 102   endif()
 103
 104   add_custom_target(${target_name}_exports DEPENDS ${native_export_file})
 105   set_target_properties(${target_name}_exports PROPERTIES FOLDER "Misc")
 106
 107   get_property(srcs TARGET ${target_name} PROPERTY SOURCES)
 108   foreach(src ${srcs})
 109     get_filename_component(extension ${src} EXT)
 110     if(extension STREQUAL ".cpp")
 111       set(first_source_file ${src})
 112       break()
 113     endif()
 114   endforeach()
 115
 116   # Force re-linking when the exports file changes. Actually, it
 117   # forces recompilation of the source file. The LINK_DEPENDS target
 118   # property only works for makefile-based generators.
 119   # FIXME: This is not safe because this will create the same target
 120   # ${native_export_file} in several different file:
 121   # - One where we emitted ${target_name}_exports
 122   # - One where we emitted the build command for the following object.
 123   # set_property(SOURCE ${first_source_file} APPEND PROPERTY
 124   #   OBJECT_DEPENDS ${CMAKE_CURRENT_BINARY_DIR}/${native_export_file})
 125
 126   set_property(DIRECTORY APPEND
 127     PROPERTY ADDITIONAL_MAKE_CLEAN_FILES ${native_export_file})
 128
 129   add_dependencies(${target_name} ${target_name}_exports)
 130 endfunction(add_llvm_symbol_exports)
 131
 132 function(add_dead_strip target_name)
 133   if(NOT LLVM_NO_DEAD_STRIP)
 134     if(${CMAKE_SYSTEM_NAME} MATCHES "Darwin")
 135       set_property(TARGET ${target_name} APPEND_STRING PROPERTY
 136                    LINK_FLAGS " -Wl,-dead_strip")
 137     elseif(NOT WIN32)
 138       # Object files are compiled with -ffunction-data-sections.
 139       set_property(TARGET ${target_name} APPEND_STRING PROPERTY
 140                    LINK_FLAGS " -Wl,--gc-sections")
 141     endif()
 142   endif()
 143 endfunction(add_dead_strip)
 144
 145 # Set each output directory according to ${CMAKE_CONFIGURATION_TYPES}.
 146 # Note: Don't set variables CMAKE_*_OUTPUT_DIRECTORY any more,
 147 # or a certain builder, for eaxample, msbuild.exe, would be confused.
 148 function(set_output_directory target bindir libdir)
 149   if(NOT "${CMAKE_CFG_INTDIR}" STREQUAL ".")
 150     foreach(build_mode ${CMAKE_CONFIGURATION_TYPES})
 151       string(TOUPPER "${build_mode}" CONFIG_SUFFIX)
 152       string(REPLACE ${CMAKE_CFG_INTDIR} ${build_mode} bi ${bindir})
 153       string(REPLACE ${CMAKE_CFG_INTDIR} ${build_mode} li ${libdir})
 154       set_target_properties(${target} PROPERTIES "RUNTIME_OUTPUT_DIRECTORY_${CONFIG_SUFFIX}" ${bi})
 155       set_target_properties(${target} PROPERTIES "ARCHIVE_OUTPUT_DIRECTORY_${CONFIG_SUFFIX}" ${li})
 156       set_target_properties(${target} PROPERTIES "LIBRARY_OUTPUT_DIRECTORY_${CONFIG_SUFFIX}" ${li})
 157     endforeach()
 158   else()
 159     set_target_properties(${target} PROPERTIES RUNTIME_OUTPUT_DIRECTORY ${bindir})
 160     set_target_properties(${target} PROPERTIES ARCHIVE_OUTPUT_DIRECTORY ${libdir})
 161     set_target_properties(${target} PROPERTIES LIBRARY_OUTPUT_DIRECTORY ${libdir})
 162   endif()
 163 endfunction()
 164
 165 # llvm_add_library(name sources...
 166 #   SHARED;STATIC
 167 #     STATIC by default w/o BUILD_SHARED_LIBS.
 168 #     SHARED by default w/  BUILD_SHARED_LIBS.
 169 #   MODULE
 170 #     Target ${name} might not be created on unsupported platforms.
 171 #     Check with "if(TARGET ${name})".
 172 #   OUTPUT_NAME name
 173 #     Corresponds to OUTPUT_NAME in target properties.
 174 #   DEPENDS targets...
 175 #     Same semantics as add_dependencies().
 176 #   LINK_COMPONENTS components...
 177 #     Same as the variable LLVM_LINK_COMPONENTS.
 178 #   LINK_LIBS lib_targets...
 179 #     Same semantics as target_link_libraries().
 180 #   ADDITIONAL_HEADERS
 181 #     May specify header files for IDE generators.
 182 #   )
 183 function(llvm_add_library name)
 184   cmake_parse_arguments(ARG
 185     "MODULE;SHARED;STATIC"
 186     "OUTPUT_NAME"
 187     "ADDITIONAL_HEADERS;DEPENDS;LINK_COMPONENTS;LINK_LIBS;OBJLIBS"
 188     ${ARGN})
 189   list(APPEND LLVM_COMMON_DEPENDS ${ARG_DEPENDS})
 190   if(ARG_ADDITIONAL_HEADERS)
 191     # Pass through ADDITIONAL_HEADERS.
 192     set(ARG_ADDITIONAL_HEADERS ADDITIONAL_HEADERS ${ARG_ADDITIONAL_HEADERS})
 193   endif()
 194   if(ARG_OBJLIBS)
 195     set(ALL_FILES ${ARG_OBJLIBS})
 196   else()
 197     llvm_process_sources(ALL_FILES ${ARG_UNPARSED_ARGUMENTS} ${ARG_ADDITIONAL_HEADERS})
 198   endif()
 199
 200   if(ARG_MODULE)
 201     if(ARG_SHARED OR ARG_STATIC)
 202       message(WARNING "MODULE with SHARED|STATIC doesn't make sense.")
 203     endif()
 204     if(NOT LLVM_ON_UNIX OR CYGWIN)
 205       message(STATUS "${name} ignored -- Loadable modules not supported on this platform.")
 206       return()
 207     endif()
 208   else()
 209     if(BUILD_SHARED_LIBS AND NOT ARG_STATIC)
 210       set(ARG_SHARED TRUE)
 211     endif()
 212     if(NOT ARG_SHARED)
 213       set(ARG_STATIC TRUE)
 214     endif()
 215   endif()
 216
 217   # Generate objlib
 218   if(ARG_SHARED AND ARG_STATIC)
 219     # Generate an obj library for both targets.
 220     set(obj_name "obj.${name}")
 221     add_library(${obj_name} OBJECT EXCLUDE_FROM_ALL
 222       ${ALL_FILES}
 223       )
 224     llvm_update_compile_flags(${obj_name})
 225     set(ALL_FILES "$<TARGET_OBJECTS:${obj_name}>")
 226
 227     set_target_properties(${obj_name} PROPERTIES FOLDER "Object Libraries")
 228   endif()
 229
 230   if(ARG_SHARED AND ARG_STATIC)
 231     # static
 232     set(name_static "${name}_static")
 233     if(ARG_OUTPUT_NAME)
 234       set(output_name OUTPUT_NAME "${ARG_OUTPUT_NAME}_static")
 235     endif()
 236     # DEPENDS has been appended to LLVM_COMMON_LIBS.
 237     llvm_add_library(${name_static} STATIC
 238       ${output_name}
 239       OBJLIBS ${ALL_FILES} # objlib
 240       LINK_LIBS ${ARG_LINK_LIBS}
 241       LINK_COMPONENTS ${ARG_LINK_COMPONENTS}
 242       )
 243     # FIXME: Add name_static to anywhere in TARGET ${name}'s PROPERTY.
 244     set(ARG_STATIC)
 245   endif()
 246
 247   if(ARG_MODULE)
 248     add_library(${name} MODULE ${ALL_FILES})
 249   elseif(ARG_SHARED)
 250     add_library(${name} SHARED ${ALL_FILES})
 251   else()
 252     add_library(${name} STATIC ${ALL_FILES})
 253   endif()
 254   set_output_directory(${name} ${LLVM_RUNTIME_OUTPUT_INTDIR} ${LLVM_LIBRARY_OUTPUT_INTDIR})
 255   llvm_update_compile_flags(${name})
 256   add_dead_strip( ${name} )
 257   if(ARG_OUTPUT_NAME)
 258     set_target_properties(${name}
 259       PROPERTIES
 260       OUTPUT_NAME ${ARG_OUTPUT_NAME}
 261       )
 262   endif()
 263
 264   if(ARG_MODULE)
 265     set_target_properties(${name} PROPERTIES
 266       PREFIX ""
 267       SUFFIX ${LLVM_PLUGIN_EXT}
 268       )
 269   endif()
 270
 271   if(ARG_SHARED)
 272     if (MSVC)
 273       set_target_properties(${name}
 274         PROPERTIES
 275         IMPORT_SUFFIX ".imp")
 276     endif ()
 277   endif()
 278
 279   if(ARG_MODULE OR ARG_SHARED)
 280     if (LLVM_EXPORTED_SYMBOL_FILE)
 281       add_llvm_symbol_exports( ${name} ${LLVM_EXPORTED_SYMBOL_FILE} )
 282     endif()
 283   endif()
 284
 285   target_link_libraries(${name} ${ARG_LINK_LIBS})
 286
 287   llvm_config(${name} ${ARG_LINK_COMPONENTS} ${LLVM_LINK_COMPONENTS})
 288
 289   if(LLVM_COMMON_DEPENDS)
 290     add_dependencies(${name} ${LLVM_COMMON_DEPENDS})
 291   endif()
 292 endfunction()
 293
 294 macro(add_llvm_library name)
 295   if( BUILD_SHARED_LIBS )
 296     llvm_add_library(${name} SHARED ${ARGN})
 297   else()
 298     llvm_add_library(${name} ${ARGN})
 299   endif()
 300   set_property( GLOBAL APPEND PROPERTY LLVM_LIBS ${name} )
 301
 302   if( EXCLUDE_FROM_ALL )
 303     set_target_properties( ${name} PROPERTIES EXCLUDE_FROM_ALL ON)
 304   else()
 305     if (NOT LLVM_INSTALL_TOOLCHAIN_ONLY OR ${name} STREQUAL "LTO")
 306       install(TARGETS ${name}
 307         EXPORT LLVMExports
 308         LIBRARY DESTINATION lib${LLVM_LIBDIR_SUFFIX}
 309         ARCHIVE DESTINATION lib${LLVM_LIBDIR_SUFFIX})
 310     endif()
 311     set_property(GLOBAL APPEND PROPERTY LLVM_EXPORTS ${name})
 312   endif()
 313   set_target_properties(${name} PROPERTIES FOLDER "Libraries")
 314
 315   # Add the explicit dependency information for this library.
 316   #
 317   # It would be nice to verify that we have the dependencies for this library
 318   # name, but using get_property(... SET) doesn't suffice to determine if a
 319   # property has been set to an empty value.
 320   get_property(lib_deps GLOBAL PROPERTY LLVMBUILD_LIB_DEPS_${name})
 321   target_link_libraries(${name} ${lib_deps})
 322 endmacro(add_llvm_library name)
 323
 324 macro(add_llvm_loadable_module name)
 325   llvm_add_library(${name} MODULE ${ARGN})
 326   if(NOT TARGET ${name})
 327     # Add empty "phony" target
 328     add_custom_target(${name})
 329   else()
 330     if( EXCLUDE_FROM_ALL )
 331       set_target_properties( ${name} PROPERTIES EXCLUDE_FROM_ALL ON)
 332     else()
 333       if (NOT LLVM_INSTALL_TOOLCHAIN_ONLY)
 334         install(TARGETS ${name}
 335           EXPORT LLVMExports
 336           LIBRARY DESTINATION lib${LLVM_LIBDIR_SUFFIX}
 337           ARCHIVE DESTINATION lib${LLVM_LIBDIR_SUFFIX})
 338       endif()
 339       set_property(GLOBAL APPEND PROPERTY LLVM_EXPORTS ${name})
 340     endif()
 341   endif()
 342
 343   set_target_properties(${name} PROPERTIES FOLDER "Loadable modules")
 344 endmacro(add_llvm_loadable_module name)
 345
 346
 347 macro(add_llvm_executable name)
 348   llvm_process_sources( ALL_FILES ${ARGN} )
 349   if( EXCLUDE_FROM_ALL )
 350     add_executable(${name} EXCLUDE_FROM_ALL ${ALL_FILES})
 351   else()
 352     add_executable(${name} ${ALL_FILES})
 353   endif()
 354   llvm_update_compile_flags(${name})
 355   add_dead_strip( ${name} )
 356
 357   if (LLVM_EXPORTED_SYMBOL_FILE)
 358     add_llvm_symbol_exports( ${name} ${LLVM_EXPORTED_SYMBOL_FILE} )
 359   endif(LLVM_EXPORTED_SYMBOL_FILE)
 360
 361   set(EXCLUDE_FROM_ALL OFF)
 362   set_output_directory(${name} ${LLVM_RUNTIME_OUTPUT_INTDIR} ${LLVM_LIBRARY_OUTPUT_INTDIR})
 363   llvm_config( ${name} ${LLVM_LINK_COMPONENTS} )
 364   if( LLVM_COMMON_DEPENDS )
 365     add_dependencies( ${name} ${LLVM_COMMON_DEPENDS} )
 366   endif( LLVM_COMMON_DEPENDS )
 367 endmacro(add_llvm_executable name)
 368
 369
 370 set (LLVM_TOOLCHAIN_TOOLS
 371   llvm-ar
 372   llvm-objdump
 373   )
 374
 375 macro(add_llvm_tool name)
 376   if( NOT LLVM_BUILD_TOOLS )
 377     set(EXCLUDE_FROM_ALL ON)
 378   endif()
 379   add_llvm_executable(${name} ${ARGN})
 380
 381   list(FIND LLVM_TOOLCHAIN_TOOLS ${name} LLVM_IS_${name}_TOOLCHAIN_TOOL)
 382   if (LLVM_IS_${name}_TOOLCHAIN_TOOL GREATER -1 OR NOT LLVM_INSTALL_TOOLCHAIN_ONLY)
 383     if( LLVM_BUILD_TOOLS )
 384       install(TARGETS ${name}
 385               EXPORT LLVMExports
 386               RUNTIME DESTINATION bin)
 387     endif()
 388   endif()
 389   if( LLVM_BUILD_TOOLS )
 390     set_property(GLOBAL APPEND PROPERTY LLVM_EXPORTS ${name})
 391   endif()
 392   set_target_properties(${name} PROPERTIES FOLDER "Tools")
 393 endmacro(add_llvm_tool name)
 394
 395
 396 macro(add_llvm_example name)
 397   if( NOT LLVM_BUILD_EXAMPLES )
 398     set(EXCLUDE_FROM_ALL ON)
 399   endif()
 400   add_llvm_executable(${name} ${ARGN})
 401   if( LLVM_BUILD_EXAMPLES )
 402     install(TARGETS ${name} RUNTIME DESTINATION examples)
 403   endif()
 404   set_target_properties(${name} PROPERTIES FOLDER "Examples")
 405 endmacro(add_llvm_example name)
 406
 407
 408 macro(add_llvm_utility name)
 409   add_llvm_executable(${name} ${ARGN})
 410   set_target_properties(${name} PROPERTIES FOLDER "Utils")
 411 endmacro(add_llvm_utility name)
 412
 413
 414 macro(add_llvm_target target_name)
 415   include_directories(BEFORE
 416     ${CMAKE_CURRENT_BINARY_DIR}
 417     ${CMAKE_CURRENT_SOURCE_DIR})
 418   add_llvm_library(LLVM${target_name} ${ARGN} ${TABLEGEN_OUTPUT})
 419   set( CURRENT_LLVM_TARGET LLVM${target_name} )
 420 endmacro(add_llvm_target)
 421
 422 # Add external project that may want to be built as part of llvm such as Clang,
 423 # lld, and Polly. This adds two options. One for the source directory of the
 424 # project, which defaults to ${CMAKE_CURRENT_SOURCE_DIR}/${name}. Another to
 425 # enable or disable building it with everything else.
 426 # Additional parameter can be specified as the name of directory.
 427 macro(add_llvm_external_project name)
 428   set(add_llvm_external_dir "${ARGN}")
 429   if("${add_llvm_external_dir}" STREQUAL "")
 430     set(add_llvm_external_dir ${name})
 431   endif()
 432   list(APPEND LLVM_IMPLICIT_PROJECT_IGNORE "${CMAKE_CURRENT_SOURCE_DIR}/${add_llvm_external_dir}")
 433   string(REPLACE "-" "_" nameUNDERSCORE ${name})
 434   string(TOUPPER ${nameUNDERSCORE} nameUPPER)
 435   set(LLVM_EXTERNAL_${nameUPPER}_SOURCE_DIR "${CMAKE_CURRENT_SOURCE_DIR}/${add_llvm_external_dir}"
 436       CACHE PATH "Path to ${name} source directory")
 437   if (NOT ${LLVM_EXTERNAL_${nameUPPER}_SOURCE_DIR} STREQUAL ""
 438       AND EXISTS ${LLVM_EXTERNAL_${nameUPPER}_SOURCE_DIR}/CMakeLists.txt)
 439     option(LLVM_EXTERNAL_${nameUPPER}_BUILD
 440            "Whether to build ${name} as part of LLVM" ON)
 441     if (LLVM_EXTERNAL_${nameUPPER}_BUILD)
 442       add_subdirectory(${LLVM_EXTERNAL_${nameUPPER}_SOURCE_DIR} ${add_llvm_external_dir})
 443     endif()
 444   endif()
 445 endmacro(add_llvm_external_project)
 446
 447 macro(add_llvm_tool_subdirectory name)
 448   list(APPEND LLVM_IMPLICIT_PROJECT_IGNORE "${CMAKE_CURRENT_SOURCE_DIR}/${name}")
 449   add_subdirectory(${name})
 450 endmacro(add_llvm_tool_subdirectory)
 451
 452 macro(ignore_llvm_tool_subdirectory name)
 453   list(APPEND LLVM_IMPLICIT_PROJECT_IGNORE "${CMAKE_CURRENT_SOURCE_DIR}/${name}")
 454 endmacro(ignore_llvm_tool_subdirectory)
 455
 456 function(add_llvm_implicit_external_projects)
 457   set(list_of_implicit_subdirs "")
 458   file(GLOB sub-dirs "${CMAKE_CURRENT_SOURCE_DIR}/*")
 459   foreach(dir ${sub-dirs})
 460     if(IS_DIRECTORY "${dir}")
 461       list(FIND LLVM_IMPLICIT_PROJECT_IGNORE "${dir}" tool_subdir_ignore)
 462       if( tool_subdir_ignore EQUAL -1
 463           AND EXISTS "${dir}/CMakeLists.txt")
 464         get_filename_component(fn "${dir}" NAME)
 465         list(APPEND list_of_implicit_subdirs "${fn}")
 466       endif()
 467     endif()
 468   endforeach()
 469
 470   foreach(external_proj ${list_of_implicit_subdirs})
 471     add_llvm_external_project("${external_proj}")
 472   endforeach()
 473 endfunction(add_llvm_implicit_external_projects)
 474
 475 # Generic support for adding a unittest.
 476 function(add_unittest test_suite test_name)
 477   if( NOT LLVM_BUILD_TESTS )
 478     set(EXCLUDE_FROM_ALL ON)
 479   endif()
 480
 481   # Visual Studio 2012 only supports up to 8 template parameters in
 482   # std::tr1::tuple by default, but gtest requires 10
 483   if (MSVC AND MSVC_VERSION EQUAL 1700)
 484     list(APPEND LLVM_COMPILE_DEFINITIONS _VARIADIC_MAX=10)
 485   endif ()
 486
 487   include_directories(${LLVM_MAIN_SRC_DIR}/utils/unittest/googletest/include)
 488   if (NOT LLVM_ENABLE_THREADS)
 489     list(APPEND LLVM_COMPILE_DEFINITIONS GTEST_HAS_PTHREAD=0)
 490   endif ()
 491
 492   if (SUPPORTS_NO_VARIADIC_MACROS_FLAG)
 493     list(APPEND LLVM_COMPILE_FLAGS "-Wno-variadic-macros")
 494   endif ()
 495
 496   set(LLVM_REQUIRES_RTTI OFF)
 497
 498   add_llvm_executable(${test_name} ${ARGN})
 499   set(outdir ${CMAKE_CURRENT_BINARY_DIR}/${CMAKE_CFG_INTDIR})
 500   set_output_directory(${test_name} ${outdir} ${outdir})
 501   target_link_libraries(${test_name}
 502     gtest
 503     gtest_main
 504     LLVMSupport # gtest needs it for raw_ostream.
 505     )
 506
 507   add_dependencies(${test_suite} ${test_name})
 508   get_target_property(test_suite_folder ${test_suite} FOLDER)
 509   if (NOT ${test_suite_folder} STREQUAL "NOTFOUND")
 510     set_property(TARGET ${test_name} PROPERTY FOLDER "${test_suite_folder}")
 511   endif ()
 512 endfunction()
 513
 514 # This function provides an automatic way to 'configure'-like generate a file
 515 # based on a set of common and custom variables, specifically targeting the
 516 # variables needed for the 'lit.site.cfg' files. This function bundles the
 517 # common variables that any Lit instance is likely to need, and custom
 518 # variables can be passed in.
 519 function(configure_lit_site_cfg input output)
 520   foreach(c ${LLVM_TARGETS_TO_BUILD})
 521     set(TARGETS_BUILT "${TARGETS_BUILT} ${c}")
 522   endforeach(c)
 523   set(TARGETS_TO_BUILD ${TARGETS_BUILT})
 524
 525   set(SHLIBEXT "${LTDL_SHLIB_EXT}")
 526
 527   if(BUILD_SHARED_LIBS)
 528     set(LLVM_SHARED_LIBS_ENABLED "1")
 529   else()
 530     set(LLVM_SHARED_LIBS_ENABLED "0")
 531   endif(BUILD_SHARED_LIBS)
 532
 533   if(${CMAKE_SYSTEM_NAME} MATCHES "Darwin")
 534     set(SHLIBPATH_VAR "DYLD_LIBRARY_PATH")
 535   else() # Default for all other unix like systems.
 536     # CMake hardcodes the library locaction using rpath.
 537     # Therefore LD_LIBRARY_PATH is not required to run binaries in the
 538     # build dir. We pass it anyways.
 539     set(SHLIBPATH_VAR "LD_LIBRARY_PATH")
 540   endif()
 541
 542   # Configuration-time: See Unit/lit.site.cfg.in
 543   if (CMAKE_CFG_INTDIR STREQUAL ".")
 544     set(LLVM_BUILD_MODE ".")
 545   else ()
 546     set(LLVM_BUILD_MODE "%(build_mode)s")
 547   endif ()
 548
 549   # They below might not be the build tree but provided binary tree.
 550   set(LLVM_SOURCE_DIR ${LLVM_MAIN_SRC_DIR})
 551   set(LLVM_BINARY_DIR ${LLVM_BINARY_DIR})
 552   string(REPLACE ${CMAKE_CFG_INTDIR} ${LLVM_BUILD_MODE} LLVM_TOOLS_DIR ${LLVM_TOOLS_BINARY_DIR})
 553   string(REPLACE ${CMAKE_CFG_INTDIR} ${LLVM_BUILD_MODE} LLVM_LIBS_DIR  ${LLVM_LIBRARY_DIR})
 554
 555   # SHLIBDIR points the build tree.
 556   string(REPLACE ${CMAKE_CFG_INTDIR} ${LLVM_BUILD_MODE} SHLIBDIR ${LLVM_LIBRARY_OUTPUT_INTDIR})
 557
 558   set(PYTHON_EXECUTABLE ${PYTHON_EXECUTABLE})
 559   set(ENABLE_SHARED ${LLVM_SHARED_LIBS_ENABLED})
 560   set(SHLIBPATH_VAR ${SHLIBPATH_VAR})
 561
 562   if(LLVM_ENABLE_ASSERTIONS AND NOT MSVC_IDE)
 563     set(ENABLE_ASSERTIONS "1")
 564   else()
 565     set(ENABLE_ASSERTIONS "0")
 566   endif()
 567
 568   set(HOST_OS ${CMAKE_SYSTEM_NAME})
 569   set(HOST_ARCH ${CMAKE_SYSTEM_PROCESSOR})
 570
 571   if (CLANG_ENABLE_ARCMT)
 572     set(ENABLE_CLANG_ARCMT "1")
 573   else()
 574     set(ENABLE_CLANG_ARCMT "0")
 575   endif()
 576   if (CLANG_ENABLE_REWRITER)
 577     set(ENABLE_CLANG_REWRITER "1")
 578   else()
 579     set(ENABLE_CLANG_REWRITER "0")
 580   endif()
 581   if (CLANG_ENABLE_STATIC_ANALYZER)
 582     set(ENABLE_CLANG_STATIC_ANALYZER "1")
 583   else()
 584     set(ENABLE_CLANG_STATIC_ANALYZER "0")
 585   endif()
 586
 587   configure_file(${input} ${output} @ONLY)
 588 endfunction()
 589
 590 # A raw function to create a lit target. This is used to implement the testuite
 591 # management functions.
 592 function(add_lit_target target comment)
 593   parse_arguments(ARG "PARAMS;DEPENDS;ARGS" "" ${ARGN})
 594   set(LIT_ARGS "${ARG_ARGS} ${LLVM_LIT_ARGS}")
 595   separate_arguments(LIT_ARGS)
 596   if (NOT CMAKE_CFG_INTDIR STREQUAL ".")
 597     list(APPEND LIT_ARGS --param build_mode=${CMAKE_CFG_INTDIR})
 598   endif ()
 599   set(LIT_COMMAND
 600     ${PYTHON_EXECUTABLE}
 601     ${LLVM_MAIN_SRC_DIR}/utils/lit/lit.py
 602     ${LIT_ARGS}
 603     )
 604   foreach(param ${ARG_PARAMS})
 605     list(APPEND LIT_COMMAND --param ${param})
 606   endforeach()
 607   if( ARG_DEPENDS )
 608     add_custom_target(${target}
 609       COMMAND ${LIT_COMMAND} ${ARG_DEFAULT_ARGS}
 610       COMMENT "${comment}"
 611       )
 612     add_dependencies(${target} ${ARG_DEPENDS})
 613   else()
 614     add_custom_target(${target}
 615       COMMAND ${CMAKE_COMMAND} -E echo "${target} does nothing, no tools built.")
 616     message(STATUS "${target} does nothing.")
 617   endif()
 618
 619   # Tests should be excluded from "Build Solution".
 620   set_target_properties(${target} PROPERTIES EXCLUDE_FROM_DEFAULT_BUILD ON)
 621 endfunction()
 622
 623 # A function to add a set of lit test suites to be driven through 'check-*' targets.
 624 function(add_lit_testsuite target comment)
 625   parse_arguments(ARG "PARAMS;DEPENDS;ARGS" "" ${ARGN})
 626
 627   # EXCLUDE_FROM_ALL excludes the test ${target} out of check-all.
 628   if(NOT EXCLUDE_FROM_ALL)
 629     # Register the testsuites, params and depends for the global check rule.
 630     set_property(GLOBAL APPEND PROPERTY LLVM_LIT_TESTSUITES ${ARG_DEFAULT_ARGS})
 631     set_property(GLOBAL APPEND PROPERTY LLVM_LIT_PARAMS ${ARG_PARAMS})
 632     set_property(GLOBAL APPEND PROPERTY LLVM_LIT_DEPENDS ${ARG_DEPENDS})
 633     set_property(GLOBAL APPEND PROPERTY LLVM_LIT_EXTRA_ARGS ${ARG_ARGS})
 634   endif()
 635
 636   # Produce a specific suffixed check rule.
 637   add_lit_target(${target} ${comment}
 638     ${ARG_DEFAULT_ARGS}
 639     PARAMS ${ARG_PARAMS}
 640     DEPENDS ${ARG_DEPENDS}
 641     ARGS ${ARG_ARGS}
 642     )
 643 endfunction()