cmake/modules/AddLLVM.cmake

   1 include(LLVMProcessSources)
   2 include(LLVM-Config)
   3
   4 function(llvm_update_compile_flags name)
   5   get_property(sources TARGET ${name} PROPERTY SOURCES)
   6   if("${sources}" MATCHES "\\.c(;|$)")
   7     set(update_src_props ON)
   8   endif()
   9
  10   # LLVM_REQUIRES_EH is an internal flag that individual
  11   # targets can use to force EH
  12   if((LLVM_REQUIRES_EH OR LLVM_ENABLE_EH) AND NOT CLANG_CL)
  13     if(NOT (LLVM_REQUIRES_RTTI OR LLVM_ENABLE_RTTI))
  14       message(AUTHOR_WARNING "Exception handling requires RTTI. Enabling RTTI for ${name}")
  15       set(LLVM_REQUIRES_RTTI ON)
  16     endif()
  17   else()
  18     if(LLVM_COMPILER_IS_GCC_COMPATIBLE)
  19       list(APPEND LLVM_COMPILE_FLAGS "-fno-exceptions")
  20     elseif(MSVC)
  21       list(APPEND LLVM_COMPILE_DEFINITIONS _HAS_EXCEPTIONS=0)
  22       list(APPEND LLVM_COMPILE_FLAGS "/EHs-c-")
  23     endif()
  24     if (CLANG_CL)
  25       # FIXME: Remove this once clang-cl supports SEH
  26       list(APPEND LLVM_COMPILE_DEFINITIONS "GTEST_HAS_SEH=0")
  27     endif()
  28   endif()
  29
  30   # LLVM_REQUIRES_RTTI is an internal flag that individual
  31   # targets can use to force RTTI
  32   if(NOT (LLVM_REQUIRES_RTTI OR LLVM_ENABLE_RTTI))
  33     list(APPEND LLVM_COMPILE_DEFINITIONS GTEST_HAS_RTTI=0)
  34     if (LLVM_COMPILER_IS_GCC_COMPATIBLE)
  35       list(APPEND LLVM_COMPILE_FLAGS "-fno-rtti")
  36     elseif (MSVC)
  37       list(APPEND LLVM_COMPILE_FLAGS "/GR-")
  38     endif ()
  39   endif()
  40
  41   # Assume that;
  42   #   - LLVM_COMPILE_FLAGS is list.
  43   #   - PROPERTY COMPILE_FLAGS is string.
  44   string(REPLACE ";" " " target_compile_flags "${LLVM_COMPILE_FLAGS}")
  45
  46   if(update_src_props)
  47     foreach(fn ${sources})
  48       get_filename_component(suf ${fn} EXT)
  49       if("${suf}" STREQUAL ".cpp")
  50         set_property(SOURCE ${fn} APPEND_STRING PROPERTY
  51           COMPILE_FLAGS "${target_compile_flags}")
  52       endif()
  53     endforeach()
  54   else()
  55     # Update target props, since all sources are C++.
  56     set_property(TARGET ${name} APPEND_STRING PROPERTY
  57       COMPILE_FLAGS "${target_compile_flags}")
  58   endif()
  59
  60   set_property(TARGET ${name} APPEND PROPERTY COMPILE_DEFINITIONS ${LLVM_COMPILE_DEFINITIONS})
  61 endfunction()
  62
  63 function(add_llvm_symbol_exports target_name export_file)
  64   if(${CMAKE_SYSTEM_NAME} MATCHES "Darwin")
  65     set(native_export_file "${target_name}.exports")
  66     add_custom_command(OUTPUT ${native_export_file}
  67       COMMAND sed -e "s/^/_/" < ${export_file} > ${native_export_file}
  68       DEPENDS ${export_file}
  69       VERBATIM
  70       COMMENT "Creating export file for ${target_name}")
  71     set_property(TARGET ${target_name} APPEND_STRING PROPERTY
  72                  LINK_FLAGS " -Wl,-exported_symbols_list,${CMAKE_CURRENT_BINARY_DIR}/${native_export_file}")
  73   elseif(LLVM_HAVE_LINK_VERSION_SCRIPT)
  74     # Gold and BFD ld require a version script rather than a plain list.
  75     set(native_export_file "${target_name}.exports")
  76     # FIXME: Don't write the "local:" line on OpenBSD.
  77     add_custom_command(OUTPUT ${native_export_file}
  78       COMMAND echo "{" > ${native_export_file}
  79       COMMAND grep -q "[[:alnum:]]" ${export_file} && echo "  global:" >> ${native_export_file} || :
  80       COMMAND sed -e "s/$/;/" -e "s/^/    /" < ${export_file} >> ${native_export_file}
  81       COMMAND echo "  local: *;" >> ${native_export_file}
  82       COMMAND echo "};" >> ${native_export_file}
  83       DEPENDS ${export_file}
  84       VERBATIM
  85       COMMENT "Creating export file for ${target_name}")
  86     if (${CMAKE_SYSTEM_NAME} MATCHES "SunOS")
  87       set_property(TARGET ${target_name} APPEND_STRING PROPERTY
  88                    LINK_FLAGS "  -Wl,-M,${CMAKE_CURRENT_BINARY_DIR}/${native_export_file}")
  89     else()
  90       set_property(TARGET ${target_name} APPEND_STRING PROPERTY
  91                    LINK_FLAGS "  -Wl,--version-script,${CMAKE_CURRENT_BINARY_DIR}/${native_export_file}")
  92     endif()
  93   else()
  94     set(native_export_file "${target_name}.def")
  95
  96     set(CAT "cat")
  97     set(export_file_nativeslashes ${export_file})
  98     if(WIN32 AND NOT CYGWIN AND NOT MSYS)
  99       set(CAT "type")
 100       # Convert ${export_file} to native format (backslashes) for "type"
 101       # Does not use file(TO_NATIVE_PATH) as it doesn't create a native
 102       # path but a build-system specific format (see CMake bug
 103       # http://public.kitware.com/Bug/print_bug_page.php?bug_id=5939 )
 104       string(REPLACE / \\ export_file_nativeslashes ${export_file})
 105     endif()
 106
 107     add_custom_command(OUTPUT ${native_export_file}
 108       COMMAND ${CMAKE_COMMAND} -E echo "EXPORTS" > ${native_export_file}
 109       COMMAND ${CAT} ${export_file_nativeslashes} >> ${native_export_file}
 110       DEPENDS ${export_file}
 111       VERBATIM
 112       COMMENT "Creating export file for ${target_name}")
 113     set(export_file_linker_flag "${CMAKE_CURRENT_BINARY_DIR}/${native_export_file}")
 114     if(MSVC)
 115       set(export_file_linker_flag "/DEF:\"${export_file_linker_flag}\"")
 116     endif()
 117     set_property(TARGET ${target_name} APPEND_STRING PROPERTY
 118                  LINK_FLAGS " ${export_file_linker_flag}")
 119   endif()
 120
 121   add_custom_target(${target_name}_exports DEPENDS ${native_export_file})
 122   set_target_properties(${target_name}_exports PROPERTIES FOLDER "Misc")
 123
 124   get_property(srcs TARGET ${target_name} PROPERTY SOURCES)
 125   foreach(src ${srcs})
 126     get_filename_component(extension ${src} EXT)
 127     if(extension STREQUAL ".cpp")
 128       set(first_source_file ${src})
 129       break()
 130     endif()
 131   endforeach()
 132
 133   # Force re-linking when the exports file changes. Actually, it
 134   # forces recompilation of the source file. The LINK_DEPENDS target
 135   # property only works for makefile-based generators.
 136   # FIXME: This is not safe because this will create the same target
 137   # ${native_export_file} in several different file:
 138   # - One where we emitted ${target_name}_exports
 139   # - One where we emitted the build command for the following object.
 140   # set_property(SOURCE ${first_source_file} APPEND PROPERTY
 141   #   OBJECT_DEPENDS ${CMAKE_CURRENT_BINARY_DIR}/${native_export_file})
 142
 143   set_property(DIRECTORY APPEND
 144     PROPERTY ADDITIONAL_MAKE_CLEAN_FILES ${native_export_file})
 145
 146   add_dependencies(${target_name} ${target_name}_exports)
 147
 148   # Add dependency to *_exports later -- CMake issue 14747
 149   list(APPEND LLVM_COMMON_DEPENDS ${target_name}_exports)
 150   set(LLVM_COMMON_DEPENDS ${LLVM_COMMON_DEPENDS} PARENT_SCOPE)
 151 endfunction(add_llvm_symbol_exports)
 152
 153 if(NOT WIN32 AND NOT APPLE)
 154   execute_process(
 155     COMMAND ${CMAKE_C_COMPILER} -Wl,--version
 156     OUTPUT_VARIABLE stdout
 157     ERROR_QUIET
 158     )
 159   if("${stdout}" MATCHES "GNU gold")
 160     set(LLVM_LINKER_IS_GOLD ON)
 161   endif()
 162 endif()
 163
 164 function(add_link_opts target_name)
 165   # Don't use linker optimizations in debug builds since it slows down the
 166   # linker in a context where the optimizations are not important.
 167   if (NOT uppercase_CMAKE_BUILD_TYPE STREQUAL "DEBUG")
 168
 169     # Pass -O3 to the linker. This enabled different optimizations on different
 170     # linkers.
 171     if(NOT (${CMAKE_SYSTEM_NAME} MATCHES "Darwin|SunOS" OR WIN32))
 172       set_property(TARGET ${target_name} APPEND_STRING PROPERTY
 173                    LINK_FLAGS " -Wl,-O3")
 174     endif()
 175
 176     if(LLVM_LINKER_IS_GOLD)
 177       # With gold gc-sections is always safe.
 178       set_property(TARGET ${target_name} APPEND_STRING PROPERTY
 179                    LINK_FLAGS " -Wl,--gc-sections")
 180       # Note that there is a bug with -Wl,--icf=safe so it is not safe
 181       # to enable. See https://sourceware.org/bugzilla/show_bug.cgi?id=17704.
 182     endif()
 183
 184     if(NOT LLVM_NO_DEAD_STRIP)
 185       if(${CMAKE_SYSTEM_NAME} MATCHES "Darwin")
 186         # ld64's implementation of -dead_strip breaks tools that use plugins.
 187         set_property(TARGET ${target_name} APPEND_STRING PROPERTY
 188                      LINK_FLAGS " -Wl,-dead_strip")
 189       elseif(NOT WIN32 AND NOT LLVM_LINKER_IS_GOLD)
 190         # Object files are compiled with -ffunction-data-sections.
 191         # Versions of bfd ld < 2.23.1 have a bug in --gc-sections that breaks
 192         # tools that use plugins. Always pass --gc-sections once we require
 193         # a newer linker.
 194         set_property(TARGET ${target_name} APPEND_STRING PROPERTY
 195                      LINK_FLAGS " -Wl,--gc-sections")
 196       endif()
 197     endif()
 198   endif()
 199 endfunction(add_link_opts)
 200
 201 # Set each output directory according to ${CMAKE_CONFIGURATION_TYPES}.
 202 # Note: Don't set variables CMAKE_*_OUTPUT_DIRECTORY any more,
 203 # or a certain builder, for eaxample, msbuild.exe, would be confused.
 204 function(set_output_directory target bindir libdir)
 205   # Do nothing if *_OUTPUT_INTDIR is empty.
 206   if("${bindir}" STREQUAL "")
 207     return()
 208   endif()
 209
 210   # moddir -- corresponding to LIBRARY_OUTPUT_DIRECTORY.
 211   # It affects output of add_library(MODULE).
 212   if(WIN32 OR CYGWIN)
 213     # DLL platform
 214     set(moddir ${bindir})
 215   else()
 216     set(moddir ${libdir})
 217   endif()
 218   if(NOT "${CMAKE_CFG_INTDIR}" STREQUAL ".")
 219     foreach(build_mode ${CMAKE_CONFIGURATION_TYPES})
 220       string(TOUPPER "${build_mode}" CONFIG_SUFFIX)
 221       string(REPLACE ${CMAKE_CFG_INTDIR} ${build_mode} bi ${bindir})
 222       string(REPLACE ${CMAKE_CFG_INTDIR} ${build_mode} li ${libdir})
 223       string(REPLACE ${CMAKE_CFG_INTDIR} ${build_mode} mi ${moddir})
 224       set_target_properties(${target} PROPERTIES "RUNTIME_OUTPUT_DIRECTORY_${CONFIG_SUFFIX}" ${bi})
 225       set_target_properties(${target} PROPERTIES "ARCHIVE_OUTPUT_DIRECTORY_${CONFIG_SUFFIX}" ${li})
 226       set_target_properties(${target} PROPERTIES "LIBRARY_OUTPUT_DIRECTORY_${CONFIG_SUFFIX}" ${mi})
 227     endforeach()
 228   else()
 229     set_target_properties(${target} PROPERTIES RUNTIME_OUTPUT_DIRECTORY ${bindir})
 230     set_target_properties(${target} PROPERTIES ARCHIVE_OUTPUT_DIRECTORY ${libdir})
 231     set_target_properties(${target} PROPERTIES LIBRARY_OUTPUT_DIRECTORY ${moddir})
 232   endif()
 233 endfunction()
 234
 235 # If on Windows and building with MSVC, add the resource script containing the
 236 # VERSIONINFO data to the project.  This embeds version resource information
 237 # into the output .exe or .dll.
 238 # TODO: Enable for MinGW Windows builds too.
 239 #
 240 function(add_windows_version_resource_file OUT_VAR)
 241   set(sources ${ARGN})
 242   if (MSVC)
 243     set(resource_file ${LLVM_SOURCE_DIR}/resources/windows_version_resource.rc)
 244     if(EXISTS ${resource_file})
 245       set(sources ${sources} ${resource_file})
 246       source_group("Resource Files" ${resource_file})
 247       set(windows_resource_file ${resource_file} PARENT_SCOPE)
 248     endif()
 249   endif(MSVC)
 250
 251   set(${OUT_VAR} ${sources} PARENT_SCOPE)
 252 endfunction(add_windows_version_resource_file)
 253
 254 # set_windows_version_resource_properties(name resource_file...
 255 #   VERSION_MAJOR int
 256 #     Optional major version number (defaults to LLVM_VERSION_MAJOR)
 257 #   VERSION_MINOR int
 258 #     Optional minor version number (defaults to LLVM_VERSION_MINOR)
 259 #   VERSION_PATCHLEVEL int
 260 #     Optional patchlevel version number (defaults to LLVM_VERSION_PATCH)
 261 #   VERSION_STRING
 262 #     Optional version string (defaults to PACKAGE_VERSION)
 263 #   PRODUCT_NAME
 264 #     Optional product name string (defaults to "LLVM")
 265 #   )
 266 function(set_windows_version_resource_properties name resource_file)
 267   cmake_parse_arguments(ARG
 268     ""
 269     "VERSION_MAJOR;VERSION_MINOR;VERSION_PATCHLEVEL;VERSION_STRING;PRODUCT_NAME"
 270     ""
 271     ${ARGN})
 272
 273   if (NOT DEFINED ARG_VERSION_MAJOR)
 274     set(ARG_VERSION_MAJOR ${LLVM_VERSION_MAJOR})
 275   endif()
 276
 277   if (NOT DEFINED ARG_VERSION_MINOR)
 278     set(ARG_VERSION_MINOR ${LLVM_VERSION_MINOR})
 279   endif()
 280
 281   if (NOT DEFINED ARG_VERSION_PATCHLEVEL)
 282     set(ARG_VERSION_PATCHLEVEL ${LLVM_VERSION_PATCH})
 283   endif()
 284
 285   if (NOT DEFINED ARG_VERSION_STRING)
 286     set(ARG_VERSION_STRING ${PACKAGE_VERSION})
 287   endif()
 288
 289   if (NOT DEFINED ARG_PRODUCT_NAME)
 290     set(ARG_PRODUCT_NAME "LLVM")
 291   endif()
 292
 293   set_property(SOURCE ${resource_file}
 294                PROPERTY COMPILE_FLAGS /nologo)
 295   set_property(SOURCE ${resource_file}
 296                PROPERTY COMPILE_DEFINITIONS
 297                "RC_VERSION_FIELD_1=${ARG_VERSION_MAJOR}"
 298                "RC_VERSION_FIELD_2=${ARG_VERSION_MINOR}"
 299                "RC_VERSION_FIELD_3=${ARG_VERSION_PATCHLEVEL}"
 300                "RC_VERSION_FIELD_4=0"
 301                "RC_FILE_VERSION=\"${ARG_VERSION_STRING}\""
 302                "RC_INTERNAL_NAME=\"${name}\""
 303                "RC_PRODUCT_NAME=\"${ARG_PRODUCT_NAME}\""
 304                "RC_PRODUCT_VERSION=\"${ARG_VERSION_STRING}\"")
 305 endfunction(set_windows_version_resource_properties)
 306
 307 # llvm_add_library(name sources...
 308 #   SHARED;STATIC
 309 #     STATIC by default w/o BUILD_SHARED_LIBS.
 310 #     SHARED by default w/  BUILD_SHARED_LIBS.
 311 #   MODULE
 312 #     Target ${name} might not be created on unsupported platforms.
 313 #     Check with "if(TARGET ${name})".
 314 #   OUTPUT_NAME name
 315 #     Corresponds to OUTPUT_NAME in target properties.
 316 #   DEPENDS targets...
 317 #     Same semantics as add_dependencies().
 318 #   LINK_COMPONENTS components...
 319 #     Same as the variable LLVM_LINK_COMPONENTS.
 320 #   LINK_LIBS lib_targets...
 321 #     Same semantics as target_link_libraries().
 322 #   ADDITIONAL_HEADERS
 323 #     May specify header files for IDE generators.
 324 #   )
 325 function(llvm_add_library name)
 326   cmake_parse_arguments(ARG
 327     "MODULE;SHARED;STATIC"
 328     "OUTPUT_NAME"
 329     "ADDITIONAL_HEADERS;DEPENDS;LINK_COMPONENTS;LINK_LIBS;OBJLIBS"
 330     ${ARGN})
 331   list(APPEND LLVM_COMMON_DEPENDS ${ARG_DEPENDS})
 332   if(ARG_ADDITIONAL_HEADERS)
 333     # Pass through ADDITIONAL_HEADERS.
 334     set(ARG_ADDITIONAL_HEADERS ADDITIONAL_HEADERS ${ARG_ADDITIONAL_HEADERS})
 335   endif()
 336   if(ARG_OBJLIBS)
 337     set(ALL_FILES ${ARG_OBJLIBS})
 338   else()
 339     llvm_process_sources(ALL_FILES ${ARG_UNPARSED_ARGUMENTS} ${ARG_ADDITIONAL_HEADERS})
 340   endif()
 341
 342   if(ARG_MODULE)
 343     if(ARG_SHARED OR ARG_STATIC)
 344       message(WARNING "MODULE with SHARED|STATIC doesn't make sense.")
 345     endif()
 346     if(NOT LLVM_ENABLE_PLUGINS)
 347       message(STATUS "${name} ignored -- Loadable modules not supported on this platform.")
 348       return()
 349     endif()
 350   else()
 351     if(BUILD_SHARED_LIBS AND NOT ARG_STATIC)
 352       set(ARG_SHARED TRUE)
 353     endif()
 354     if(NOT ARG_SHARED)
 355       set(ARG_STATIC TRUE)
 356     endif()
 357   endif()
 358
 359   # Generate objlib
 360   if(ARG_SHARED AND ARG_STATIC)
 361     # Generate an obj library for both targets.
 362     set(obj_name "obj.${name}")
 363     add_library(${obj_name} OBJECT EXCLUDE_FROM_ALL
 364       ${ALL_FILES}
 365       )
 366     llvm_update_compile_flags(${obj_name})
 367     set(ALL_FILES "$<TARGET_OBJECTS:${obj_name}>")
 368
 369     # Do add_dependencies(obj) later due to CMake issue 14747.
 370     list(APPEND objlibs ${obj_name})
 371
 372     set_target_properties(${obj_name} PROPERTIES FOLDER "Object Libraries")
 373   endif()
 374
 375   if(ARG_SHARED AND ARG_STATIC)
 376     # static
 377     set(name_static "${name}_static")
 378     if(ARG_OUTPUT_NAME)
 379       set(output_name OUTPUT_NAME "${ARG_OUTPUT_NAME}")
 380     endif()
 381     # DEPENDS has been appended to LLVM_COMMON_LIBS.
 382     llvm_add_library(${name_static} STATIC
 383       ${output_name}
 384       OBJLIBS ${ALL_FILES} # objlib
 385       LINK_LIBS ${ARG_LINK_LIBS}
 386       LINK_COMPONENTS ${ARG_LINK_COMPONENTS}
 387       )
 388     # FIXME: Add name_static to anywhere in TARGET ${name}'s PROPERTY.
 389     set(ARG_STATIC)
 390   endif()
 391
 392   if(ARG_MODULE)
 393     add_library(${name} MODULE ${ALL_FILES})
 394   elseif(ARG_SHARED)
 395     add_windows_version_resource_file(ALL_FILES ${ALL_FILES})
 396     add_library(${name} SHARED ${ALL_FILES})
 397   else()
 398     add_library(${name} STATIC ${ALL_FILES})
 399   endif()
 400
 401   if(DEFINED windows_resource_file)
 402     set_windows_version_resource_properties(${name} ${windows_resource_file})
 403     set(windows_resource_file ${windows_resource_file} PARENT_SCOPE)
 404   endif()
 405
 406   set_output_directory(${name} ${LLVM_RUNTIME_OUTPUT_INTDIR} ${LLVM_LIBRARY_OUTPUT_INTDIR})
 407   llvm_update_compile_flags(${name})
 408   add_link_opts( ${name} )
 409   if(ARG_OUTPUT_NAME)
 410     set_target_properties(${name}
 411       PROPERTIES
 412       OUTPUT_NAME ${ARG_OUTPUT_NAME}
 413       )
 414   endif()
 415
 416   if(ARG_MODULE)
 417     set_target_properties(${name} PROPERTIES
 418       PREFIX ""
 419       SUFFIX ${LLVM_PLUGIN_EXT}
 420       )
 421   endif()
 422
 423   if(ARG_SHARED)
 424     if(WIN32)
 425       set_target_properties(${name} PROPERTIES
 426         PREFIX ""
 427         )
 428     endif()
 429
 430     set_target_properties(${name}
 431       PROPERTIES
 432       SOVERSION ${LLVM_VERSION_MAJOR}.${LLVM_VERSION_MINOR}
 433       VERSION ${LLVM_VERSION_MAJOR}.${LLVM_VERSION_MINOR}.${LLVM_VERSION_PATCH}${LLVM_VERSION_SUFFIX})
 434   endif()
 435
 436   if(ARG_MODULE OR ARG_SHARED)
 437     # Do not add -Dname_EXPORTS to the command-line when building files in this
 438     # target. Doing so is actively harmful for the modules build because it
 439     # creates extra module variants, and not useful because we don't use these
 440     # macros.
 441     set_target_properties( ${name} PROPERTIES DEFINE_SYMBOL "" )
 442
 443     if (LLVM_EXPORTED_SYMBOL_FILE)
 444       add_llvm_symbol_exports( ${name} ${LLVM_EXPORTED_SYMBOL_FILE} )
 445     endif()
 446   endif()
 447
 448   # Add the explicit dependency information for this library.
 449   #
 450   # It would be nice to verify that we have the dependencies for this library
 451   # name, but using get_property(... SET) doesn't suffice to determine if a
 452   # property has been set to an empty value.
 453   get_property(lib_deps GLOBAL PROPERTY LLVMBUILD_LIB_DEPS_${name})
 454
 455   llvm_map_components_to_libnames(llvm_libs
 456     ${ARG_LINK_COMPONENTS}
 457     ${LLVM_LINK_COMPONENTS}
 458     )
 459
 460   if(CMAKE_VERSION VERSION_LESS 2.8.12)
 461     # Link libs w/o keywords, assuming PUBLIC.
 462     target_link_libraries(${name}
 463       ${ARG_LINK_LIBS}
 464       ${lib_deps}
 465       ${llvm_libs}
 466       )
 467   elseif(ARG_STATIC)
 468     target_link_libraries(${name} INTERFACE
 469       ${ARG_LINK_LIBS}
 470       ${lib_deps}
 471       ${llvm_libs}
 472       )
 473   else()
 474     # We can use PRIVATE since SO knows its dependent libs.
 475     target_link_libraries(${name} PRIVATE
 476       ${ARG_LINK_LIBS}
 477       ${lib_deps}
 478       ${llvm_libs}
 479       )
 480   endif()
 481
 482   if(LLVM_COMMON_DEPENDS)
 483     add_dependencies(${name} ${LLVM_COMMON_DEPENDS})
 484     # Add dependencies also to objlibs.
 485     # CMake issue 14747 --  add_dependencies() might be ignored to objlib's user.
 486     foreach(objlib ${objlibs})
 487       add_dependencies(${objlib} ${LLVM_COMMON_DEPENDS})
 488     endforeach()
 489   endif()
 490 endfunction()
 491
 492 macro(add_llvm_library name)
 493   cmake_parse_arguments(ARG
 494     "SHARED"
 495     ""
 496     ""
 497     ${ARGN})
 498   if( BUILD_SHARED_LIBS )
 499     llvm_add_library(${name} SHARED ${ARGN})
 500   else()
 501     llvm_add_library(${name} ${ARGN})
 502   endif()
 503   set_property( GLOBAL APPEND PROPERTY LLVM_LIBS ${name} )
 504
 505   if( EXCLUDE_FROM_ALL )
 506     set_target_properties( ${name} PROPERTIES EXCLUDE_FROM_ALL ON)
 507   else()
 508     if (NOT LLVM_INSTALL_TOOLCHAIN_ONLY OR ${name} STREQUAL "LTO")
 509       if(ARG_SHARED OR BUILD_SHARED_LIBS)
 510         if(WIN32 OR CYGWIN)
 511           set(install_type RUNTIME)
 512         else()
 513           set(install_type LIBRARY)
 514         endif()
 515       else()
 516         set(install_type ARCHIVE)
 517       endif()
 518
 519       install(TARGETS ${name}
 520             EXPORT LLVMExports
 521             ${install_type} DESTINATION lib${LLVM_LIBDIR_SUFFIX}
 522             COMPONENT ${name})
 523
 524       if (NOT CMAKE_CONFIGURATION_TYPES)
 525         add_custom_target(install-${name}
 526                           DEPENDS ${name}
 527                           COMMAND "${CMAKE_COMMAND}"
 528                                   -DCMAKE_INSTALL_COMPONENT=${name}
 529                                   -P "${CMAKE_BINARY_DIR}/cmake_install.cmake")
 530       endif()
 531     endif()
 532     set_property(GLOBAL APPEND PROPERTY LLVM_EXPORTS ${name})
 533   endif()
 534   set_target_properties(${name} PROPERTIES FOLDER "Libraries")
 535 endmacro(add_llvm_library name)
 536
 537 macro(add_llvm_loadable_module name)
 538   llvm_add_library(${name} MODULE ${ARGN})
 539   if(NOT TARGET ${name})
 540     # Add empty "phony" target
 541     add_custom_target(${name})
 542   else()
 543     if( EXCLUDE_FROM_ALL )
 544       set_target_properties( ${name} PROPERTIES EXCLUDE_FROM_ALL ON)
 545     else()
 546       if (NOT LLVM_INSTALL_TOOLCHAIN_ONLY)
 547         if(WIN32 OR CYGWIN)
 548           # DLL platform
 549           set(dlldir "bin")
 550         else()
 551           set(dlldir "lib${LLVM_LIBDIR_SUFFIX}")
 552         endif()
 553         install(TARGETS ${name}
 554           EXPORT LLVMExports
 555           LIBRARY DESTINATION ${dlldir}
 556           ARCHIVE DESTINATION lib${LLVM_LIBDIR_SUFFIX})
 557       endif()
 558       set_property(GLOBAL APPEND PROPERTY LLVM_EXPORTS ${name})
 559     endif()
 560   endif()
 561
 562   set_target_properties(${name} PROPERTIES FOLDER "Loadable modules")
 563 endmacro(add_llvm_loadable_module name)
 564
 565
 566 macro(add_llvm_executable name)
 567   llvm_process_sources( ALL_FILES ${ARGN} )
 568   add_windows_version_resource_file(ALL_FILES ${ALL_FILES})
 569
 570   if( EXCLUDE_FROM_ALL )
 571     add_executable(${name} EXCLUDE_FROM_ALL ${ALL_FILES})
 572   else()
 573     add_executable(${name} ${ALL_FILES})
 574   endif()
 575
 576   if(DEFINED windows_resource_file)
 577     set_windows_version_resource_properties(${name} ${windows_resource_file})
 578   endif()
 579
 580   llvm_update_compile_flags(${name})
 581   add_link_opts( ${name} )
 582
 583   # Do not add -Dname_EXPORTS to the command-line when building files in this
 584   # target. Doing so is actively harmful for the modules build because it
 585   # creates extra module variants, and not useful because we don't use these
 586   # macros.
 587   set_target_properties( ${name} PROPERTIES DEFINE_SYMBOL "" )
 588
 589   if (LLVM_EXPORTED_SYMBOL_FILE)
 590     add_llvm_symbol_exports( ${name} ${LLVM_EXPORTED_SYMBOL_FILE} )
 591   endif(LLVM_EXPORTED_SYMBOL_FILE)
 592
 593   set(EXCLUDE_FROM_ALL OFF)
 594   set_output_directory(${name} ${LLVM_RUNTIME_OUTPUT_INTDIR} ${LLVM_LIBRARY_OUTPUT_INTDIR})
 595   llvm_config( ${name} ${LLVM_LINK_COMPONENTS} )
 596   if( LLVM_COMMON_DEPENDS )
 597     add_dependencies( ${name} ${LLVM_COMMON_DEPENDS} )
 598   endif( LLVM_COMMON_DEPENDS )
 599 endmacro(add_llvm_executable name)
 600
 601 function(export_executable_symbols target)
 602   if (NOT MSVC) # MSVC's linker doesn't support exporting all symbols.
 603     set_target_properties(${target} PROPERTIES ENABLE_EXPORTS 1)
 604   endif()
 605 endfunction()
 606
 607
 608 set (LLVM_TOOLCHAIN_TOOLS
 609   llvm-ar
 610   llvm-objdump
 611   )
 612
 613 macro(add_llvm_tool name)
 614   if( NOT LLVM_BUILD_TOOLS )
 615     set(EXCLUDE_FROM_ALL ON)
 616   endif()
 617   add_llvm_executable(${name} ${ARGN})
 618
 619   list(FIND LLVM_TOOLCHAIN_TOOLS ${name} LLVM_IS_${name}_TOOLCHAIN_TOOL)
 620   if (LLVM_IS_${name}_TOOLCHAIN_TOOL GREATER -1 OR NOT LLVM_INSTALL_TOOLCHAIN_ONLY)
 621     if( LLVM_BUILD_TOOLS )
 622       install(TARGETS ${name}
 623               EXPORT LLVMExports
 624               RUNTIME DESTINATION bin
 625               COMPONENT ${name})
 626
 627       if (NOT CMAKE_CONFIGURATION_TYPES)
 628         add_custom_target(install-${name}
 629                           DEPENDS ${name}
 630                           COMMAND "${CMAKE_COMMAND}"
 631                                   -DCMAKE_INSTALL_COMPONENT=${name}
 632                                   -P "${CMAKE_BINARY_DIR}/cmake_install.cmake")
 633       endif()
 634     endif()
 635   endif()
 636   if( LLVM_BUILD_TOOLS )
 637     set_property(GLOBAL APPEND PROPERTY LLVM_EXPORTS ${name})
 638   endif()
 639   set_target_properties(${name} PROPERTIES FOLDER "Tools")
 640 endmacro(add_llvm_tool name)
 641
 642
 643 macro(add_llvm_example name)
 644   if( NOT LLVM_BUILD_EXAMPLES )
 645     set(EXCLUDE_FROM_ALL ON)
 646   endif()
 647   add_llvm_executable(${name} ${ARGN})
 648   if( LLVM_BUILD_EXAMPLES )
 649     install(TARGETS ${name} RUNTIME DESTINATION examples)
 650   endif()
 651   set_target_properties(${name} PROPERTIES FOLDER "Examples")
 652 endmacro(add_llvm_example name)
 653
 654
 655 macro(add_llvm_utility name)
 656   add_llvm_executable(${name} ${ARGN})
 657   set_target_properties(${name} PROPERTIES FOLDER "Utils")
 658   if( LLVM_INSTALL_UTILS )
 659     install (TARGETS ${name}
 660       RUNTIME DESTINATION bin
 661       COMPONENT ${name})
 662     if (NOT CMAKE_CONFIGURATION_TYPES)
 663       add_custom_target(install-${name}
 664                         DEPENDS ${name}
 665                         COMMAND "${CMAKE_COMMAND}"
 666                                 -DCMAKE_INSTALL_COMPONENT=${name}
 667                                 -P "${CMAKE_BINARY_DIR}/cmake_install.cmake")
 668     endif()
 669   endif()
 670 endmacro(add_llvm_utility name)
 671
 672
 673 macro(add_llvm_target target_name)
 674   include_directories(BEFORE
 675     ${CMAKE_CURRENT_BINARY_DIR}
 676     ${CMAKE_CURRENT_SOURCE_DIR})
 677   add_llvm_library(LLVM${target_name} ${ARGN})
 678   set( CURRENT_LLVM_TARGET LLVM${target_name} )
 679 endmacro(add_llvm_target)
 680
 681 # Add external project that may want to be built as part of llvm such as Clang,
 682 # lld, and Polly. This adds two options. One for the source directory of the
 683 # project, which defaults to ${CMAKE_CURRENT_SOURCE_DIR}/${name}. Another to
 684 # enable or disable building it with everything else.
 685 # Additional parameter can be specified as the name of directory.
 686 macro(add_llvm_external_project name)
 687   set(add_llvm_external_dir "${ARGN}")
 688   if("${add_llvm_external_dir}" STREQUAL "")
 689     set(add_llvm_external_dir ${name})
 690   endif()
 691   list(APPEND LLVM_IMPLICIT_PROJECT_IGNORE "${CMAKE_CURRENT_SOURCE_DIR}/${add_llvm_external_dir}")
 692   string(REPLACE "-" "_" nameUNDERSCORE ${name})
 693   string(TOUPPER ${nameUNDERSCORE} nameUPPER)
 694   set(LLVM_EXTERNAL_${nameUPPER}_SOURCE_DIR "${CMAKE_CURRENT_SOURCE_DIR}/${add_llvm_external_dir}"
 695       CACHE PATH "Path to ${name} source directory")
 696   if (NOT ${LLVM_EXTERNAL_${nameUPPER}_SOURCE_DIR} STREQUAL ""
 697       AND EXISTS ${LLVM_EXTERNAL_${nameUPPER}_SOURCE_DIR}/CMakeLists.txt)
 698     option(LLVM_EXTERNAL_${nameUPPER}_BUILD
 699            "Whether to build ${name} as part of LLVM" ON)
 700     if (LLVM_EXTERNAL_${nameUPPER}_BUILD)
 701       add_subdirectory(${LLVM_EXTERNAL_${nameUPPER}_SOURCE_DIR} ${add_llvm_external_dir})
 702     endif()
 703   endif()
 704 endmacro(add_llvm_external_project)
 705
 706 macro(add_llvm_tool_subdirectory name)
 707   list(APPEND LLVM_IMPLICIT_PROJECT_IGNORE "${CMAKE_CURRENT_SOURCE_DIR}/${name}")
 708   add_subdirectory(${name})
 709 endmacro(add_llvm_tool_subdirectory)
 710
 711 macro(ignore_llvm_tool_subdirectory name)
 712   list(APPEND LLVM_IMPLICIT_PROJECT_IGNORE "${CMAKE_CURRENT_SOURCE_DIR}/${name}")
 713 endmacro(ignore_llvm_tool_subdirectory)
 714
 715 function(add_llvm_implicit_external_projects)
 716   set(list_of_implicit_subdirs "")
 717   file(GLOB sub-dirs "${CMAKE_CURRENT_SOURCE_DIR}/*")
 718   foreach(dir ${sub-dirs})
 719     if(IS_DIRECTORY "${dir}")
 720       list(FIND LLVM_IMPLICIT_PROJECT_IGNORE "${dir}" tool_subdir_ignore)
 721       if( tool_subdir_ignore EQUAL -1
 722           AND EXISTS "${dir}/CMakeLists.txt")
 723         get_filename_component(fn "${dir}" NAME)
 724         list(APPEND list_of_implicit_subdirs "${fn}")
 725       endif()
 726     endif()
 727   endforeach()
 728
 729   foreach(external_proj ${list_of_implicit_subdirs})
 730     add_llvm_external_project("${external_proj}")
 731   endforeach()
 732 endfunction(add_llvm_implicit_external_projects)
 733
 734 # Generic support for adding a unittest.
 735 function(add_unittest test_suite test_name)
 736   if( NOT LLVM_BUILD_TESTS )
 737     set(EXCLUDE_FROM_ALL ON)
 738   endif()
 739
 740   include_directories(${LLVM_MAIN_SRC_DIR}/utils/unittest/googletest/include)
 741   if (NOT LLVM_ENABLE_THREADS)
 742     list(APPEND LLVM_COMPILE_DEFINITIONS GTEST_HAS_PTHREAD=0)
 743   endif ()
 744
 745   if (SUPPORTS_NO_VARIADIC_MACROS_FLAG)
 746     list(APPEND LLVM_COMPILE_FLAGS "-Wno-variadic-macros")
 747   endif ()
 748
 749   set(LLVM_REQUIRES_RTTI OFF)
 750
 751   add_llvm_executable(${test_name} ${ARGN})
 752   set(outdir ${CMAKE_CURRENT_BINARY_DIR}/${CMAKE_CFG_INTDIR})
 753   set_output_directory(${test_name} ${outdir} ${outdir})
 754   target_link_libraries(${test_name}
 755     gtest
 756     gtest_main
 757     LLVMSupport # gtest needs it for raw_ostream.
 758     )
 759
 760   add_dependencies(${test_suite} ${test_name})
 761   get_target_property(test_suite_folder ${test_suite} FOLDER)
 762   if (NOT ${test_suite_folder} STREQUAL "NOTFOUND")
 763     set_property(TARGET ${test_name} PROPERTY FOLDER "${test_suite_folder}")
 764   endif ()
 765 endfunction()
 766
 767 function(llvm_add_go_executable binary pkgpath)
 768   cmake_parse_arguments(ARG "ALL" "" "DEPENDS;GOFLAGS" ${ARGN})
 769
 770   if(LLVM_BINDINGS MATCHES "go")
 771     # FIXME: This should depend only on the libraries Go needs.
 772     get_property(llvmlibs GLOBAL PROPERTY LLVM_LIBS)
 773     set(binpath ${CMAKE_BINARY_DIR}/bin/${binary}${CMAKE_EXECUTABLE_SUFFIX})
 774     set(cc "${CMAKE_C_COMPILER} ${CMAKE_C_COMPILER_ARG1}")
 775     set(cxx "${CMAKE_CXX_COMPILER} ${CMAKE_CXX_COMPILER_ARG1}")
 776     set(cppflags "")
 777     get_property(include_dirs DIRECTORY PROPERTY INCLUDE_DIRECTORIES)
 778     foreach(d ${include_dirs})
 779       set(cppflags "${cppflags} -I${d}")
 780     endforeach(d)
 781     set(ldflags "${CMAKE_EXE_LINKER_FLAGS}")
 782     add_custom_command(OUTPUT ${binpath}
 783       COMMAND ${CMAKE_BINARY_DIR}/bin/llvm-go "cc=${cc}" "cxx=${cxx}" "cppflags=${cppflags}" "ldflags=${ldflags}"
 784               ${ARG_GOFLAGS} build -o ${binpath} ${pkgpath}
 785       DEPENDS llvm-config ${CMAKE_BINARY_DIR}/bin/llvm-go${CMAKE_EXECUTABLE_SUFFIX}
 786               ${llvmlibs} ${ARG_DEPENDS}
 787       COMMENT "Building Go executable ${binary}"
 788       VERBATIM)
 789     if (ARG_ALL)
 790       add_custom_target(${binary} ALL DEPENDS ${binpath})
 791     else()
 792       add_custom_target(${binary} DEPENDS ${binpath})
 793     endif()
 794   endif()
 795 endfunction()
 796
 797 # This function provides an automatic way to 'configure'-like generate a file
 798 # based on a set of common and custom variables, specifically targeting the
 799 # variables needed for the 'lit.site.cfg' files. This function bundles the
 800 # common variables that any Lit instance is likely to need, and custom
 801 # variables can be passed in.
 802 function(configure_lit_site_cfg input output)
 803   foreach(c ${LLVM_TARGETS_TO_BUILD})
 804     set(TARGETS_BUILT "${TARGETS_BUILT} ${c}")
 805   endforeach(c)
 806   set(TARGETS_TO_BUILD ${TARGETS_BUILT})
 807
 808   set(SHLIBEXT "${LTDL_SHLIB_EXT}")
 809
 810   # Configuration-time: See Unit/lit.site.cfg.in
 811   if (CMAKE_CFG_INTDIR STREQUAL ".")
 812     set(LLVM_BUILD_MODE ".")
 813   else ()
 814     set(LLVM_BUILD_MODE "%(build_mode)s")
 815   endif ()
 816
 817   # They below might not be the build tree but provided binary tree.
 818   set(LLVM_SOURCE_DIR ${LLVM_MAIN_SRC_DIR})
 819   set(LLVM_BINARY_DIR ${LLVM_BINARY_DIR})
 820   string(REPLACE ${CMAKE_CFG_INTDIR} ${LLVM_BUILD_MODE} LLVM_TOOLS_DIR ${LLVM_TOOLS_BINARY_DIR})
 821   string(REPLACE ${CMAKE_CFG_INTDIR} ${LLVM_BUILD_MODE} LLVM_LIBS_DIR  ${LLVM_LIBRARY_DIR})
 822
 823   # SHLIBDIR points the build tree.
 824   string(REPLACE ${CMAKE_CFG_INTDIR} ${LLVM_BUILD_MODE} SHLIBDIR "${LLVM_SHLIB_OUTPUT_INTDIR}")
 825
 826   set(PYTHON_EXECUTABLE ${PYTHON_EXECUTABLE})
 827   # FIXME: "ENABLE_SHARED" doesn't make sense, since it is used just for
 828   # plugins. We may rename it.
 829   if(LLVM_ENABLE_PLUGINS)
 830     set(ENABLE_SHARED "1")
 831   else()
 832     set(ENABLE_SHARED "0")
 833   endif()
 834
 835   if(LLVM_ENABLE_ASSERTIONS AND NOT MSVC_IDE)
 836     set(ENABLE_ASSERTIONS "1")
 837   else()
 838     set(ENABLE_ASSERTIONS "0")
 839   endif()
 840
 841   set(HOST_OS ${CMAKE_SYSTEM_NAME})
 842   set(HOST_ARCH ${CMAKE_SYSTEM_PROCESSOR})
 843
 844   set(HOST_CC "${CMAKE_C_COMPILER} ${CMAKE_C_COMPILER_ARG1}")
 845   set(HOST_CXX "${CMAKE_CXX_COMPILER} ${CMAKE_CXX_COMPILER_ARG1}")
 846   set(HOST_LDFLAGS "${CMAKE_EXE_LINKER_FLAGS}")
 847
 848   configure_file(${input} ${output} @ONLY)
 849 endfunction()
 850
 851 # A raw function to create a lit target. This is used to implement the testuite
 852 # management functions.
 853 function(add_lit_target target comment)
 854   cmake_parse_arguments(ARG "" "" "PARAMS;DEPENDS;ARGS" ${ARGN})
 855   set(LIT_ARGS "${ARG_ARGS} ${LLVM_LIT_ARGS}")
 856   separate_arguments(LIT_ARGS)
 857   if (NOT CMAKE_CFG_INTDIR STREQUAL ".")
 858     list(APPEND LIT_ARGS --param build_mode=${CMAKE_CFG_INTDIR})
 859   endif ()
 860   if (LLVM_MAIN_SRC_DIR)
 861     set (LIT_COMMAND ${PYTHON_EXECUTABLE} ${LLVM_MAIN_SRC_DIR}/utils/lit/lit.py)
 862   else()
 863     find_program(LIT_COMMAND llvm-lit)
 864   endif ()
 865   list(APPEND LIT_COMMAND ${LIT_ARGS})
 866   foreach(param ${ARG_PARAMS})
 867     list(APPEND LIT_COMMAND --param ${param})
 868   endforeach()
 869   if (ARG_UNPARSED_ARGUMENTS)
 870     add_custom_target(${target}
 871       COMMAND ${LIT_COMMAND} ${ARG_UNPARSED_ARGUMENTS}
 872       COMMENT "${comment}"
 873       ${cmake_3_2_USES_TERMINAL}
 874       )
 875   else()
 876     add_custom_target(${target}
 877       COMMAND ${CMAKE_COMMAND} -E echo "${target} does nothing, no tools built.")
 878     message(STATUS "${target} does nothing.")
 879   endif()
 880   if (ARG_DEPENDS)
 881     add_dependencies(${target} ${ARG_DEPENDS})
 882   endif()
 883
 884   # Tests should be excluded from "Build Solution".
 885   set_target_properties(${target} PROPERTIES EXCLUDE_FROM_DEFAULT_BUILD ON)
 886 endfunction()
 887
 888 # A function to add a set of lit test suites to be driven through 'check-*' targets.
 889 function(add_lit_testsuite target comment)
 890   cmake_parse_arguments(ARG "" "" "PARAMS;DEPENDS;ARGS" ${ARGN})
 891
 892   # EXCLUDE_FROM_ALL excludes the test ${target} out of check-all.
 893   if(NOT EXCLUDE_FROM_ALL)
 894     # Register the testsuites, params and depends for the global check rule.
 895     set_property(GLOBAL APPEND PROPERTY LLVM_LIT_TESTSUITES ${ARG_UNPARSED_ARGUMENTS})
 896     set_property(GLOBAL APPEND PROPERTY LLVM_LIT_PARAMS ${ARG_PARAMS})
 897     set_property(GLOBAL APPEND PROPERTY LLVM_LIT_DEPENDS ${ARG_DEPENDS})
 898     set_property(GLOBAL APPEND PROPERTY LLVM_LIT_EXTRA_ARGS ${ARG_ARGS})
 899   endif()
 900
 901   # Produce a specific suffixed check rule.
 902   add_lit_target(${target} ${comment}
 903     ${ARG_UNPARSED_ARGUMENTS}
 904     PARAMS ${ARG_PARAMS}
 905     DEPENDS ${ARG_DEPENDS}
 906     ARGS ${ARG_ARGS}
 907     )
 908 endfunction()
 909
 910 function(add_lit_testsuites project directory)
 911   if (NOT CMAKE_CONFIGURATION_TYPES)
 912     cmake_parse_arguments(ARG "" "" "PARAMS;DEPENDS;ARGS" ${ARGN})
 913     file(GLOB_RECURSE litCfg ${directory}/lit*.cfg)
 914     set(lit_suites)
 915     foreach(f ${litCfg})
 916       get_filename_component(dir ${f} DIRECTORY)
 917       set(lit_suites ${lit_suites} ${dir})
 918     endforeach()
 919     list(REMOVE_DUPLICATES lit_suites)
 920     foreach(dir ${lit_suites})
 921       string(REPLACE ${directory} "" name_slash ${dir})
 922       if (name_slash)
 923         string(REPLACE "/" "-" name_slash ${name_slash})
 924         string(REPLACE "\\" "-" name_dashes ${name_slash})
 925         string(TOLOWER "${project}${name_dashes}" name_var)
 926         add_lit_target("check-${name_var}" "Running lit suite ${dir}"
 927           ${dir}
 928           PARAMS ${ARG_PARAMS}
 929           DEPENDS ${ARG_DEPENDS}
 930           ARGS ${ARG_ARGS}
 931         )
 932       endif()
 933     endforeach()
 934   endif()
 935 endfunction()