cmake/modules/AddLLVM.cmake

   1 include(LLVMProcessSources)
   2 include(LLVM-Config)
   3 include(DetermineGCCCompatible)
   4
   5 function(llvm_update_compile_flags name)
   6   get_property(sources TARGET ${name} PROPERTY SOURCES)
   7   if("${sources}" MATCHES "\\.c(;|$)")
   8     set(update_src_props ON)
   9   endif()
  10
  11   # LLVM_REQUIRES_EH is an internal flag that individual
  12   # targets can use to force EH
  13   if((LLVM_REQUIRES_EH OR LLVM_ENABLE_EH) AND NOT CLANG_CL)
  14     if(NOT (LLVM_REQUIRES_RTTI OR LLVM_ENABLE_RTTI))
  15       message(AUTHOR_WARNING "Exception handling requires RTTI. Enabling RTTI for ${name}")
  16       set(LLVM_REQUIRES_RTTI ON)
  17     endif()
  18   else()
  19     if(LLVM_COMPILER_IS_GCC_COMPATIBLE)
  20       list(APPEND LLVM_COMPILE_FLAGS "-fno-exceptions")
  21     elseif(MSVC)
  22       list(APPEND LLVM_COMPILE_DEFINITIONS _HAS_EXCEPTIONS=0)
  23       list(APPEND LLVM_COMPILE_FLAGS "/EHs-c-")
  24     endif()
  25   endif()
  26
  27   # LLVM_REQUIRES_RTTI is an internal flag that individual
  28   # targets can use to force RTTI
  29   set(LLVM_CONFIG_HAS_RTTI YES CACHE INTERNAL "")
  30   if(NOT (LLVM_REQUIRES_RTTI OR LLVM_ENABLE_RTTI))
  31     set(LLVM_CONFIG_HAS_RTTI NO CACHE INTERNAL "")
  32     list(APPEND LLVM_COMPILE_DEFINITIONS GTEST_HAS_RTTI=0)
  33     if (LLVM_COMPILER_IS_GCC_COMPATIBLE)
  34       list(APPEND LLVM_COMPILE_FLAGS "-fno-rtti")
  35     elseif (MSVC)
  36       list(APPEND LLVM_COMPILE_FLAGS "/GR-")
  37     endif ()
  38   endif()
  39
  40   # Assume that;
  41   #   - LLVM_COMPILE_FLAGS is list.
  42   #   - PROPERTY COMPILE_FLAGS is string.
  43   string(REPLACE ";" " " target_compile_flags " ${LLVM_COMPILE_FLAGS}")
  44
  45   if(update_src_props)
  46     foreach(fn ${sources})
  47       get_filename_component(suf ${fn} EXT)
  48       if("${suf}" STREQUAL ".cpp")
  49         set_property(SOURCE ${fn} APPEND_STRING PROPERTY
  50           COMPILE_FLAGS "${target_compile_flags}")
  51       endif()
  52     endforeach()
  53   else()
  54     # Update target props, since all sources are C++.
  55     set_property(TARGET ${name} APPEND_STRING PROPERTY
  56       COMPILE_FLAGS "${target_compile_flags}")
  57   endif()
  58
  59   set_property(TARGET ${name} APPEND PROPERTY COMPILE_DEFINITIONS ${LLVM_COMPILE_DEFINITIONS})
  60 endfunction()
  61
  62 function(add_llvm_symbol_exports target_name export_file)
  63   if(${CMAKE_SYSTEM_NAME} MATCHES "Darwin")
  64     set(native_export_file "${target_name}.exports")
  65     add_custom_command(OUTPUT ${native_export_file}
  66       COMMAND sed -e "s/^/_/" < ${export_file} > ${native_export_file}
  67       DEPENDS ${export_file}
  68       VERBATIM
  69       COMMENT "Creating export file for ${target_name}")
  70     set_property(TARGET ${target_name} APPEND_STRING PROPERTY
  71                  LINK_FLAGS " -Wl,-exported_symbols_list,${CMAKE_CURRENT_BINARY_DIR}/${native_export_file}")
  72   elseif(LLVM_HAVE_LINK_VERSION_SCRIPT)
  73     # Gold and BFD ld require a version script rather than a plain list.
  74     set(native_export_file "${target_name}.exports")
  75     # FIXME: Don't write the "local:" line on OpenBSD.
  76     add_custom_command(OUTPUT ${native_export_file}
  77       COMMAND echo "{" > ${native_export_file}
  78       COMMAND grep -q "[[:alnum:]]" ${export_file} && echo "  global:" >> ${native_export_file} || :
  79       COMMAND sed -e "s/$/;/" -e "s/^/    /" < ${export_file} >> ${native_export_file}
  80       COMMAND echo "  local: *;" >> ${native_export_file}
  81       COMMAND echo "};" >> ${native_export_file}
  82       DEPENDS ${export_file}
  83       VERBATIM
  84       COMMENT "Creating export file for ${target_name}")
  85     if (${CMAKE_SYSTEM_NAME} MATCHES "SunOS")
  86       set_property(TARGET ${target_name} APPEND_STRING PROPERTY
  87                    LINK_FLAGS "  -Wl,-M,${CMAKE_CURRENT_BINARY_DIR}/${native_export_file}")
  88     else()
  89       set_property(TARGET ${target_name} APPEND_STRING PROPERTY
  90                    LINK_FLAGS "  -Wl,--version-script,${CMAKE_CURRENT_BINARY_DIR}/${native_export_file}")
  91     endif()
  92   else()
  93     set(native_export_file "${target_name}.def")
  94
  95     add_custom_command(OUTPUT ${native_export_file}
  96       COMMAND ${PYTHON_EXECUTABLE} -c "import sys;print(''.join(['EXPORTS\\n']+sys.stdin.readlines(),))"
  97         < ${export_file} > ${native_export_file}
  98       DEPENDS ${export_file}
  99       VERBATIM
 100       COMMENT "Creating export file for ${target_name}")
 101     set(export_file_linker_flag "${CMAKE_CURRENT_BINARY_DIR}/${native_export_file}")
 102     if(MSVC)
 103       set(export_file_linker_flag "/DEF:\"${export_file_linker_flag}\"")
 104     endif()
 105     set_property(TARGET ${target_name} APPEND_STRING PROPERTY
 106                  LINK_FLAGS " ${export_file_linker_flag}")
 107   endif()
 108
 109   add_custom_target(${target_name}_exports DEPENDS ${native_export_file})
 110   set_target_properties(${target_name}_exports PROPERTIES FOLDER "Misc")
 111
 112   get_property(srcs TARGET ${target_name} PROPERTY SOURCES)
 113   foreach(src ${srcs})
 114     get_filename_component(extension ${src} EXT)
 115     if(extension STREQUAL ".cpp")
 116       set(first_source_file ${src})
 117       break()
 118     endif()
 119   endforeach()
 120
 121   # Force re-linking when the exports file changes. Actually, it
 122   # forces recompilation of the source file. The LINK_DEPENDS target
 123   # property only works for makefile-based generators.
 124   # FIXME: This is not safe because this will create the same target
 125   # ${native_export_file} in several different file:
 126   # - One where we emitted ${target_name}_exports
 127   # - One where we emitted the build command for the following object.
 128   # set_property(SOURCE ${first_source_file} APPEND PROPERTY
 129   #   OBJECT_DEPENDS ${CMAKE_CURRENT_BINARY_DIR}/${native_export_file})
 130
 131   set_property(DIRECTORY APPEND
 132     PROPERTY ADDITIONAL_MAKE_CLEAN_FILES ${native_export_file})
 133
 134   add_dependencies(${target_name} ${target_name}_exports)
 135
 136   # Add dependency to *_exports later -- CMake issue 14747
 137   list(APPEND LLVM_COMMON_DEPENDS ${target_name}_exports)
 138   set(LLVM_COMMON_DEPENDS ${LLVM_COMMON_DEPENDS} PARENT_SCOPE)
 139 endfunction(add_llvm_symbol_exports)
 140
 141 if(NOT WIN32 AND NOT APPLE)
 142   execute_process(
 143     COMMAND ${CMAKE_C_COMPILER} -Wl,--version
 144     OUTPUT_VARIABLE stdout
 145     ERROR_QUIET
 146     )
 147   if("${stdout}" MATCHES "GNU gold")
 148     set(LLVM_LINKER_IS_GOLD ON)
 149   endif()
 150 endif()
 151
 152 function(add_link_opts target_name)
 153   # Don't use linker optimizations in debug builds since it slows down the
 154   # linker in a context where the optimizations are not important.
 155   if (NOT uppercase_CMAKE_BUILD_TYPE STREQUAL "DEBUG")
 156
 157     # Pass -O3 to the linker. This enabled different optimizations on different
 158     # linkers.
 159     if(NOT (${CMAKE_SYSTEM_NAME} MATCHES "Darwin|SunOS" OR WIN32))
 160       set_property(TARGET ${target_name} APPEND_STRING PROPERTY
 161                    LINK_FLAGS " -Wl,-O3")
 162     endif()
 163
 164     if(LLVM_LINKER_IS_GOLD)
 165       # With gold gc-sections is always safe.
 166       set_property(TARGET ${target_name} APPEND_STRING PROPERTY
 167                    LINK_FLAGS " -Wl,--gc-sections")
 168       # Note that there is a bug with -Wl,--icf=safe so it is not safe
 169       # to enable. See https://sourceware.org/bugzilla/show_bug.cgi?id=17704.
 170     endif()
 171
 172     if(NOT LLVM_NO_DEAD_STRIP)
 173       if(${CMAKE_SYSTEM_NAME} MATCHES "Darwin")
 174         # ld64's implementation of -dead_strip breaks tools that use plugins.
 175         set_property(TARGET ${target_name} APPEND_STRING PROPERTY
 176                      LINK_FLAGS " -Wl,-dead_strip")
 177       elseif(${CMAKE_SYSTEM_NAME} MATCHES "SunOS")
 178         set_property(TARGET ${target_name} APPEND_STRING PROPERTY
 179                      LINK_FLAGS " -Wl,-z -Wl,discard-unused=sections")
 180       elseif(NOT WIN32 AND NOT LLVM_LINKER_IS_GOLD)
 181         # Object files are compiled with -ffunction-data-sections.
 182         # Versions of bfd ld < 2.23.1 have a bug in --gc-sections that breaks
 183         # tools that use plugins. Always pass --gc-sections once we require
 184         # a newer linker.
 185         set_property(TARGET ${target_name} APPEND_STRING PROPERTY
 186                      LINK_FLAGS " -Wl,--gc-sections")
 187       endif()
 188     endif()
 189   endif()
 190 endfunction(add_link_opts)
 191
 192 # Set each output directory according to ${CMAKE_CONFIGURATION_TYPES}.
 193 # Note: Don't set variables CMAKE_*_OUTPUT_DIRECTORY any more,
 194 # or a certain builder, for eaxample, msbuild.exe, would be confused.
 195 function(set_output_directory target)
 196   cmake_parse_arguments(ARG "" "BINARY_DIR;LIBRARY_DIR;" "" ${ARGN})
 197
 198   # module_dir -- corresponding to LIBRARY_OUTPUT_DIRECTORY.
 199   # It affects output of add_library(MODULE).
 200   if(WIN32 OR CYGWIN)
 201     # DLL platform
 202     set(module_dir ${ARG_BINARY_DIR})
 203   else()
 204     set(module_dir ${ARG_LIBRARY_DIR})
 205   endif()
 206   if(NOT "${CMAKE_CFG_INTDIR}" STREQUAL ".")
 207     foreach(build_mode ${CMAKE_CONFIGURATION_TYPES})
 208       string(TOUPPER "${build_mode}" CONFIG_SUFFIX)
 209       if(ARG_BINARY_DIR)
 210         string(REPLACE ${CMAKE_CFG_INTDIR} ${build_mode} bi ${ARG_BINARY_DIR})
 211         set_target_properties(${target} PROPERTIES "RUNTIME_OUTPUT_DIRECTORY_${CONFIG_SUFFIX}" ${bi})
 212       endif()
 213       if(ARG_LIBRARY_DIR)
 214         string(REPLACE ${CMAKE_CFG_INTDIR} ${build_mode} li ${ARG_LIBRARY_DIR})
 215         set_target_properties(${target} PROPERTIES "ARCHIVE_OUTPUT_DIRECTORY_${CONFIG_SUFFIX}" ${li})
 216       endif()
 217       if(module_dir)
 218         string(REPLACE ${CMAKE_CFG_INTDIR} ${build_mode} mi ${module_dir})
 219         set_target_properties(${target} PROPERTIES "LIBRARY_OUTPUT_DIRECTORY_${CONFIG_SUFFIX}" ${mi})
 220       endif()
 221     endforeach()
 222   else()
 223     if(ARG_BINARY_DIR)
 224       set_target_properties(${target} PROPERTIES RUNTIME_OUTPUT_DIRECTORY ${ARG_BINARY_DIR})
 225     endif()
 226     if(ARG_LIBRARY_DIR)
 227       set_target_properties(${target} PROPERTIES ARCHIVE_OUTPUT_DIRECTORY ${ARG_LIBRARY_DIR})
 228     endif()
 229     if(module_dir)
 230       set_target_properties(${target} PROPERTIES LIBRARY_OUTPUT_DIRECTORY ${module_dir})
 231     endif()
 232   endif()
 233 endfunction()
 234
 235 # If on Windows and building with MSVC, add the resource script containing the
 236 # VERSIONINFO data to the project.  This embeds version resource information
 237 # into the output .exe or .dll.
 238 # TODO: Enable for MinGW Windows builds too.
 239 #
 240 function(add_windows_version_resource_file OUT_VAR)
 241   set(sources ${ARGN})
 242   if (MSVC)
 243     set(resource_file ${LLVM_SOURCE_DIR}/resources/windows_version_resource.rc)
 244     if(EXISTS ${resource_file})
 245       set(sources ${sources} ${resource_file})
 246       source_group("Resource Files" ${resource_file})
 247       set(windows_resource_file ${resource_file} PARENT_SCOPE)
 248     endif()
 249   endif(MSVC)
 250
 251   set(${OUT_VAR} ${sources} PARENT_SCOPE)
 252 endfunction(add_windows_version_resource_file)
 253
 254 # set_windows_version_resource_properties(name resource_file...
 255 #   VERSION_MAJOR int
 256 #     Optional major version number (defaults to LLVM_VERSION_MAJOR)
 257 #   VERSION_MINOR int
 258 #     Optional minor version number (defaults to LLVM_VERSION_MINOR)
 259 #   VERSION_PATCHLEVEL int
 260 #     Optional patchlevel version number (defaults to LLVM_VERSION_PATCH)
 261 #   VERSION_STRING
 262 #     Optional version string (defaults to PACKAGE_VERSION)
 263 #   PRODUCT_NAME
 264 #     Optional product name string (defaults to "LLVM")
 265 #   )
 266 function(set_windows_version_resource_properties name resource_file)
 267   cmake_parse_arguments(ARG
 268     ""
 269     "VERSION_MAJOR;VERSION_MINOR;VERSION_PATCHLEVEL;VERSION_STRING;PRODUCT_NAME"
 270     ""
 271     ${ARGN})
 272
 273   if (NOT DEFINED ARG_VERSION_MAJOR)
 274     set(ARG_VERSION_MAJOR ${LLVM_VERSION_MAJOR})
 275   endif()
 276
 277   if (NOT DEFINED ARG_VERSION_MINOR)
 278     set(ARG_VERSION_MINOR ${LLVM_VERSION_MINOR})
 279   endif()
 280
 281   if (NOT DEFINED ARG_VERSION_PATCHLEVEL)
 282     set(ARG_VERSION_PATCHLEVEL ${LLVM_VERSION_PATCH})
 283   endif()
 284
 285   if (NOT DEFINED ARG_VERSION_STRING)
 286     set(ARG_VERSION_STRING ${PACKAGE_VERSION})
 287   endif()
 288
 289   if (NOT DEFINED ARG_PRODUCT_NAME)
 290     set(ARG_PRODUCT_NAME "LLVM")
 291   endif()
 292
 293   set_property(SOURCE ${resource_file}
 294                PROPERTY COMPILE_FLAGS /nologo)
 295   set_property(SOURCE ${resource_file}
 296                PROPERTY COMPILE_DEFINITIONS
 297                "RC_VERSION_FIELD_1=${ARG_VERSION_MAJOR}"
 298                "RC_VERSION_FIELD_2=${ARG_VERSION_MINOR}"
 299                "RC_VERSION_FIELD_3=${ARG_VERSION_PATCHLEVEL}"
 300                "RC_VERSION_FIELD_4=0"
 301                "RC_FILE_VERSION=\"${ARG_VERSION_STRING}\""
 302                "RC_INTERNAL_NAME=\"${name}\""
 303                "RC_PRODUCT_NAME=\"${ARG_PRODUCT_NAME}\""
 304                "RC_PRODUCT_VERSION=\"${ARG_VERSION_STRING}\"")
 305 endfunction(set_windows_version_resource_properties)
 306
 307 # llvm_add_library(name sources...
 308 #   SHARED;STATIC
 309 #     STATIC by default w/o BUILD_SHARED_LIBS.
 310 #     SHARED by default w/  BUILD_SHARED_LIBS.
 311 #   MODULE
 312 #     Target ${name} might not be created on unsupported platforms.
 313 #     Check with "if(TARGET ${name})".
 314 #   DISABLE_LLVM_LINK_LLVM_DYLIB
 315 #     Do not link this library to libLLVM, even if
 316 #     LLVM_LINK_LLVM_DYLIB is enabled.
 317 #   OUTPUT_NAME name
 318 #     Corresponds to OUTPUT_NAME in target properties.
 319 #   DEPENDS targets...
 320 #     Same semantics as add_dependencies().
 321 #   LINK_COMPONENTS components...
 322 #     Same as the variable LLVM_LINK_COMPONENTS.
 323 #   LINK_LIBS lib_targets...
 324 #     Same semantics as target_link_libraries().
 325 #   ADDITIONAL_HEADERS
 326 #     May specify header files for IDE generators.
 327 #   SONAME
 328 #     Should set SONAME link flags and create symlinks
 329 #   )
 330 function(llvm_add_library name)
 331   cmake_parse_arguments(ARG
 332     "MODULE;SHARED;STATIC;DISABLE_LLVM_LINK_LLVM_DYLIB;SONAME"
 333     "OUTPUT_NAME"
 334     "ADDITIONAL_HEADERS;DEPENDS;LINK_COMPONENTS;LINK_LIBS;OBJLIBS"
 335     ${ARGN})
 336   list(APPEND LLVM_COMMON_DEPENDS ${ARG_DEPENDS})
 337   if(ARG_ADDITIONAL_HEADERS)
 338     # Pass through ADDITIONAL_HEADERS.
 339     set(ARG_ADDITIONAL_HEADERS ADDITIONAL_HEADERS ${ARG_ADDITIONAL_HEADERS})
 340   endif()
 341   if(ARG_OBJLIBS)
 342     set(ALL_FILES ${ARG_OBJLIBS})
 343   else()
 344     llvm_process_sources(ALL_FILES ${ARG_UNPARSED_ARGUMENTS} ${ARG_ADDITIONAL_HEADERS})
 345   endif()
 346
 347   if(ARG_MODULE)
 348     if(ARG_SHARED OR ARG_STATIC)
 349       message(WARNING "MODULE with SHARED|STATIC doesn't make sense.")
 350     endif()
 351     if(NOT LLVM_ENABLE_PLUGINS)
 352       message(STATUS "${name} ignored -- Loadable modules not supported on this platform.")
 353       return()
 354     endif()
 355   else()
 356     if(BUILD_SHARED_LIBS AND NOT ARG_STATIC)
 357       set(ARG_SHARED TRUE)
 358     endif()
 359     if(NOT ARG_SHARED)
 360       set(ARG_STATIC TRUE)
 361     endif()
 362   endif()
 363
 364   # Generate objlib
 365   if(ARG_SHARED AND ARG_STATIC)
 366     # Generate an obj library for both targets.
 367     set(obj_name "obj.${name}")
 368     add_library(${obj_name} OBJECT EXCLUDE_FROM_ALL
 369       ${ALL_FILES}
 370       )
 371     llvm_update_compile_flags(${obj_name})
 372     set(ALL_FILES "$<TARGET_OBJECTS:${obj_name}>")
 373
 374     # Do add_dependencies(obj) later due to CMake issue 14747.
 375     list(APPEND objlibs ${obj_name})
 376
 377     set_target_properties(${obj_name} PROPERTIES FOLDER "Object Libraries")
 378   endif()
 379
 380   if(ARG_SHARED AND ARG_STATIC)
 381     # static
 382     set(name_static "${name}_static")
 383     if(ARG_OUTPUT_NAME)
 384       set(output_name OUTPUT_NAME "${ARG_OUTPUT_NAME}")
 385     endif()
 386     # DEPENDS has been appended to LLVM_COMMON_LIBS.
 387     llvm_add_library(${name_static} STATIC
 388       ${output_name}
 389       OBJLIBS ${ALL_FILES} # objlib
 390       LINK_LIBS ${ARG_LINK_LIBS}
 391       LINK_COMPONENTS ${ARG_LINK_COMPONENTS}
 392       )
 393     # FIXME: Add name_static to anywhere in TARGET ${name}'s PROPERTY.
 394     set(ARG_STATIC)
 395   endif()
 396
 397   if(ARG_MODULE)
 398     add_library(${name} MODULE ${ALL_FILES})
 399   elseif(ARG_SHARED)
 400     add_windows_version_resource_file(ALL_FILES ${ALL_FILES})
 401     add_library(${name} SHARED ${ALL_FILES})
 402   else()
 403     add_library(${name} STATIC ${ALL_FILES})
 404   endif()
 405
 406   if(DEFINED windows_resource_file)
 407     set_windows_version_resource_properties(${name} ${windows_resource_file})
 408     set(windows_resource_file ${windows_resource_file} PARENT_SCOPE)
 409   endif()
 410
 411   set_output_directory(${name} BINARY_DIR ${LLVM_RUNTIME_OUTPUT_INTDIR} LIBRARY_DIR ${LLVM_LIBRARY_OUTPUT_INTDIR})
 412   # $<TARGET_OBJECTS> doesn't require compile flags.
 413   if(NOT obj_name)
 414     llvm_update_compile_flags(${name})
 415   endif()
 416   add_link_opts( ${name} )
 417   if(ARG_OUTPUT_NAME)
 418     set_target_properties(${name}
 419       PROPERTIES
 420       OUTPUT_NAME ${ARG_OUTPUT_NAME}
 421       )
 422   endif()
 423
 424   if(ARG_MODULE)
 425     set_target_properties(${name} PROPERTIES
 426       PREFIX ""
 427       SUFFIX ${LLVM_PLUGIN_EXT}
 428       )
 429   endif()
 430
 431   if(ARG_SHARED)
 432     if(WIN32)
 433       set_target_properties(${name} PROPERTIES
 434         PREFIX ""
 435         )
 436     endif()
 437   endif()
 438
 439   if(ARG_MODULE OR ARG_SHARED)
 440     # Do not add -Dname_EXPORTS to the command-line when building files in this
 441     # target. Doing so is actively harmful for the modules build because it
 442     # creates extra module variants, and not useful because we don't use these
 443     # macros.
 444     set_target_properties( ${name} PROPERTIES DEFINE_SYMBOL "" )
 445
 446     if (LLVM_EXPORTED_SYMBOL_FILE)
 447       add_llvm_symbol_exports( ${name} ${LLVM_EXPORTED_SYMBOL_FILE} )
 448     endif()
 449   endif()
 450
 451   # Add the explicit dependency information for this library.
 452   #
 453   # It would be nice to verify that we have the dependencies for this library
 454   # name, but using get_property(... SET) doesn't suffice to determine if a
 455   # property has been set to an empty value.
 456   get_property(lib_deps GLOBAL PROPERTY LLVMBUILD_LIB_DEPS_${name})
 457
 458   if (LLVM_LINK_LLVM_DYLIB AND NOT ARG_STATIC AND NOT ARG_DISABLE_LLVM_LINK_LLVM_DYLIB)
 459     set(llvm_libs LLVM)
 460   else()
 461     llvm_map_components_to_libnames(llvm_libs
 462       ${ARG_LINK_COMPONENTS}
 463       ${LLVM_LINK_COMPONENTS}
 464       )
 465   endif()
 466
 467   if(CMAKE_VERSION VERSION_LESS 2.8.12)
 468     # Link libs w/o keywords, assuming PUBLIC.
 469     target_link_libraries(${name}
 470       ${ARG_LINK_LIBS}
 471       ${lib_deps}
 472       ${llvm_libs}
 473       )
 474   elseif(ARG_STATIC)
 475     target_link_libraries(${name} INTERFACE
 476       ${ARG_LINK_LIBS}
 477       ${lib_deps}
 478       ${llvm_libs}
 479       )
 480   else()
 481     # We can use PRIVATE since SO knows its dependent libs.
 482     target_link_libraries(${name} PRIVATE
 483       ${ARG_LINK_LIBS}
 484       ${lib_deps}
 485       ${llvm_libs}
 486       )
 487   endif()
 488
 489   if(LLVM_COMMON_DEPENDS)
 490     add_dependencies(${name} ${LLVM_COMMON_DEPENDS})
 491     # Add dependencies also to objlibs.
 492     # CMake issue 14747 --  add_dependencies() might be ignored to objlib's user.
 493     foreach(objlib ${objlibs})
 494       add_dependencies(${objlib} ${LLVM_COMMON_DEPENDS})
 495     endforeach()
 496   endif()
 497 endfunction()
 498
 499 macro(add_llvm_library name)
 500   cmake_parse_arguments(ARG
 501     "SHARED;SONAME"
 502     ""
 503     ""
 504     ${ARGN})
 505   if( BUILD_SHARED_LIBS )
 506     llvm_add_library(${name} SHARED ${ARGN})
 507   else()
 508     llvm_add_library(${name} ${ARGN})
 509   endif()
 510   # The gtest libraries should not be installed or exported as a target
 511   if ("${name}" STREQUAL gtest OR "${name}" STREQUAL gtest_main)
 512     set(_is_gtest TRUE)
 513   else()
 514     set(_is_gtest FALSE)
 515     set_property( GLOBAL APPEND PROPERTY LLVM_LIBS ${name} )
 516   endif()
 517
 518   if( EXCLUDE_FROM_ALL )
 519     set_target_properties( ${name} PROPERTIES EXCLUDE_FROM_ALL ON)
 520   elseif(NOT _is_gtest)
 521     if (NOT LLVM_INSTALL_TOOLCHAIN_ONLY OR ${name} STREQUAL "LTO")
 522       if(ARG_SHARED OR BUILD_SHARED_LIBS)
 523         if(WIN32 OR CYGWIN)
 524           set(install_type RUNTIME)
 525         else()
 526           set(install_type LIBRARY)
 527         endif()
 528       else()
 529         set(install_type ARCHIVE)
 530       endif()
 531
 532       install(TARGETS ${name}
 533             EXPORT LLVMExports
 534             ${install_type} DESTINATION lib${LLVM_LIBDIR_SUFFIX}
 535             COMPONENT ${name})
 536
 537       if (NOT CMAKE_CONFIGURATION_TYPES)
 538         add_custom_target(install-${name}
 539                           DEPENDS ${name}
 540                           COMMAND "${CMAKE_COMMAND}"
 541                                   -DCMAKE_INSTALL_COMPONENT=${name}
 542                                   -P "${CMAKE_BINARY_DIR}/cmake_install.cmake")
 543       endif()
 544       if(ARG_SHARED AND UNIX)
 545         if(NOT APPLE AND ARG_SONAME)
 546           set(library_name ${name}-${LLVM_VERSION_MAJOR}.${LLVM_VERSION_MINOR}${LLVM_VERSION_SUFFIX})
 547           set(api_name ${name}-${LLVM_VERSION_MAJOR}.${LLVM_VERSION_MINOR}.${LLVM_VERSION_PATCH}${LLVM_VERSION_SUFFIX})
 548           set_target_properties(${name} PROPERTIES OUTPUT_NAME ${library_name})
 549           llvm_install_library_symlink(${api_name} ${library_name} SHARED
 550             COMPONENT ${name}
 551             ALWAYS_GENERATE)
 552           llvm_install_library_symlink(${name} ${library_name} SHARED
 553             COMPONENT ${name}
 554             ALWAYS_GENERATE)
 555         endif()
 556       endif()
 557     endif()
 558     set_property(GLOBAL APPEND PROPERTY LLVM_EXPORTS ${name})
 559   endif()
 560   set_target_properties(${name} PROPERTIES FOLDER "Libraries")
 561 endmacro(add_llvm_library name)
 562
 563 macro(add_llvm_loadable_module name)
 564   llvm_add_library(${name} MODULE ${ARGN})
 565   if(NOT TARGET ${name})
 566     # Add empty "phony" target
 567     add_custom_target(${name})
 568   else()
 569     if( EXCLUDE_FROM_ALL )
 570       set_target_properties( ${name} PROPERTIES EXCLUDE_FROM_ALL ON)
 571     else()
 572       if (NOT LLVM_INSTALL_TOOLCHAIN_ONLY)
 573         if(WIN32 OR CYGWIN)
 574           # DLL platform
 575           set(dlldir "bin")
 576         else()
 577           set(dlldir "lib${LLVM_LIBDIR_SUFFIX}")
 578         endif()
 579         install(TARGETS ${name}
 580           EXPORT LLVMExports
 581           LIBRARY DESTINATION ${dlldir}
 582           ARCHIVE DESTINATION lib${LLVM_LIBDIR_SUFFIX})
 583       endif()
 584       set_property(GLOBAL APPEND PROPERTY LLVM_EXPORTS ${name})
 585     endif()
 586   endif()
 587
 588   set_target_properties(${name} PROPERTIES FOLDER "Loadable modules")
 589 endmacro(add_llvm_loadable_module name)
 590
 591
 592 macro(add_llvm_executable name)
 593   cmake_parse_arguments(ARG "DISABLE_LLVM_LINK_LLVM_DYLIB" "" "" ${ARGN})
 594   llvm_process_sources( ALL_FILES ${ARG_UNPARSED_ARGUMENTS} )
 595
 596   # Generate objlib
 597   if(LLVM_ENABLE_OBJLIB)
 598     # Generate an obj library for both targets.
 599     set(obj_name "obj.${name}")
 600     add_library(${obj_name} OBJECT EXCLUDE_FROM_ALL
 601       ${ALL_FILES}
 602       )
 603     llvm_update_compile_flags(${obj_name})
 604     set(ALL_FILES "$<TARGET_OBJECTS:${obj_name}>")
 605
 606     set_target_properties(${obj_name} PROPERTIES FOLDER "Object Libraries")
 607   endif()
 608
 609   add_windows_version_resource_file(ALL_FILES ${ALL_FILES})
 610
 611   if(XCODE)
 612     # Note: the dummy.cpp source file provides no definitions. However,
 613     # it forces Xcode to properly link the static library.
 614     list(APPEND ALL_FILES "${LLVM_MAIN_SRC_DIR}/cmake/dummy.cpp")
 615   endif()
 616
 617   if( EXCLUDE_FROM_ALL )
 618     add_executable(${name} EXCLUDE_FROM_ALL ${ALL_FILES})
 619   else()
 620     add_executable(${name} ${ALL_FILES})
 621   endif()
 622
 623   if(DEFINED windows_resource_file)
 624     set_windows_version_resource_properties(${name} ${windows_resource_file})
 625   endif()
 626
 627   # $<TARGET_OBJECTS> doesn't require compile flags.
 628   if(NOT LLVM_ENABLE_OBJLIB)
 629     llvm_update_compile_flags(${name})
 630   endif()
 631   add_link_opts( ${name} )
 632
 633   # Do not add -Dname_EXPORTS to the command-line when building files in this
 634   # target. Doing so is actively harmful for the modules build because it
 635   # creates extra module variants, and not useful because we don't use these
 636   # macros.
 637   set_target_properties( ${name} PROPERTIES DEFINE_SYMBOL "" )
 638
 639   if (LLVM_EXPORTED_SYMBOL_FILE)
 640     add_llvm_symbol_exports( ${name} ${LLVM_EXPORTED_SYMBOL_FILE} )
 641   endif(LLVM_EXPORTED_SYMBOL_FILE)
 642
 643   if (LLVM_LINK_LLVM_DYLIB AND NOT ARG_DISABLE_LLVM_LINK_LLVM_DYLIB)
 644     set(USE_SHARED USE_SHARED)
 645   endif()
 646
 647   set(EXCLUDE_FROM_ALL OFF)
 648   set_output_directory(${name} BINARY_DIR ${LLVM_RUNTIME_OUTPUT_INTDIR} LIBRARY_DIR ${LLVM_LIBRARY_OUTPUT_INTDIR})
 649   llvm_config( ${name} ${USE_SHARED} ${LLVM_LINK_COMPONENTS} )
 650   if( LLVM_COMMON_DEPENDS )
 651     add_dependencies( ${name} ${LLVM_COMMON_DEPENDS} )
 652   endif( LLVM_COMMON_DEPENDS )
 653 endmacro(add_llvm_executable name)
 654
 655 function(export_executable_symbols target)
 656   if (NOT MSVC) # MSVC's linker doesn't support exporting all symbols.
 657     set_target_properties(${target} PROPERTIES ENABLE_EXPORTS 1)
 658   endif()
 659 endfunction()
 660
 661 if(NOT LLVM_TOOLCHAIN_TOOLS)
 662   set (LLVM_TOOLCHAIN_TOOLS
 663     llvm-ar
 664     llvm-ranlib
 665     llvm-lib
 666     llvm-objdump
 667     )
 668 endif()
 669
 670 macro(add_llvm_tool name)
 671   if( NOT LLVM_BUILD_TOOLS )
 672     set(EXCLUDE_FROM_ALL ON)
 673   endif()
 674   add_llvm_executable(${name} ${ARGN})
 675
 676   list(FIND LLVM_TOOLCHAIN_TOOLS ${name} LLVM_IS_${name}_TOOLCHAIN_TOOL)
 677   if (LLVM_IS_${name}_TOOLCHAIN_TOOL GREATER -1 OR NOT LLVM_INSTALL_TOOLCHAIN_ONLY)
 678     if( LLVM_BUILD_TOOLS )
 679       install(TARGETS ${name}
 680               EXPORT LLVMExports
 681               RUNTIME DESTINATION bin
 682               COMPONENT ${name})
 683
 684       if (NOT CMAKE_CONFIGURATION_TYPES)
 685         add_custom_target(install-${name}
 686                           DEPENDS ${name}
 687                           COMMAND "${CMAKE_COMMAND}"
 688                                   -DCMAKE_INSTALL_COMPONENT=${name}
 689                                   -P "${CMAKE_BINARY_DIR}/cmake_install.cmake")
 690       endif()
 691     endif()
 692   endif()
 693   if( LLVM_BUILD_TOOLS )
 694     set_property(GLOBAL APPEND PROPERTY LLVM_EXPORTS ${name})
 695   endif()
 696   set_target_properties(${name} PROPERTIES FOLDER "Tools")
 697 endmacro(add_llvm_tool name)
 698
 699
 700 macro(add_llvm_example name)
 701   if( NOT LLVM_BUILD_EXAMPLES )
 702     set(EXCLUDE_FROM_ALL ON)
 703   endif()
 704   add_llvm_executable(${name} ${ARGN})
 705   if( LLVM_BUILD_EXAMPLES )
 706     install(TARGETS ${name} RUNTIME DESTINATION examples)
 707   endif()
 708   set_target_properties(${name} PROPERTIES FOLDER "Examples")
 709 endmacro(add_llvm_example name)
 710
 711
 712 macro(add_llvm_utility name)
 713   add_llvm_executable(${name} DISABLE_LLVM_LINK_LLVM_DYLIB ${ARGN})
 714   set_target_properties(${name} PROPERTIES FOLDER "Utils")
 715   if( LLVM_INSTALL_UTILS )
 716     install (TARGETS ${name}
 717       RUNTIME DESTINATION bin
 718       COMPONENT ${name})
 719     if (NOT CMAKE_CONFIGURATION_TYPES)
 720       add_custom_target(install-${name}
 721                         DEPENDS ${name}
 722                         COMMAND "${CMAKE_COMMAND}"
 723                                 -DCMAKE_INSTALL_COMPONENT=${name}
 724                                 -P "${CMAKE_BINARY_DIR}/cmake_install.cmake")
 725     endif()
 726   endif()
 727 endmacro(add_llvm_utility name)
 728
 729
 730 macro(add_llvm_target target_name)
 731   include_directories(BEFORE
 732     ${CMAKE_CURRENT_BINARY_DIR}
 733     ${CMAKE_CURRENT_SOURCE_DIR})
 734   add_llvm_library(LLVM${target_name} ${ARGN})
 735   set( CURRENT_LLVM_TARGET LLVM${target_name} )
 736 endmacro(add_llvm_target)
 737
 738 function(canonicalize_tool_name name output)
 739   string(REPLACE "${CMAKE_CURRENT_SOURCE_DIR}/" "" nameStrip ${name})
 740   string(REPLACE "-" "_" nameUNDERSCORE ${nameStrip})
 741   string(TOUPPER ${nameUNDERSCORE} nameUPPER)
 742   set(${output} "${nameUPPER}" PARENT_SCOPE)
 743 endfunction(canonicalize_tool_name)
 744
 745 # Custom add_subdirectory wrapper
 746 # Takes in a project name (i.e. LLVM), the the subdirectory name, and an
 747 # and an optional path if it differs from the name.
 748 macro(add_llvm_subdirectory project type name)
 749   set(add_llvm_external_dir "${ARGN}")
 750   if("${add_llvm_external_dir}" STREQUAL "")
 751     set(add_llvm_external_dir ${name})
 752   endif()
 753   canonicalize_tool_name(${name} nameUPPER)
 754   if(EXISTS ${CMAKE_CURRENT_SOURCE_DIR}/${add_llvm_external_dir}/CMakeLists.txt)
 755     # Treat it as in-tree subproject.
 756     option(${project}_${type}_${nameUPPER}_BUILD
 757            "Whether to build ${name} as part of ${project}" On)
 758     mark_as_advanced(${project}_${type}_${name}_BUILD)
 759     if(${project}_${type}_${nameUPPER}_BUILD)
 760       add_subdirectory(${CMAKE_CURRENT_SOURCE_DIR}/${add_llvm_external_dir} ${add_llvm_external_dir})
 761       # Don't process it in add_llvm_implicit_projects().
 762       set(${project}_${type}_${nameUPPER}_BUILD OFF)
 763     endif()
 764   else()
 765     set(LLVM_EXTERNAL_${nameUPPER}_SOURCE_DIR
 766       "${LLVM_EXTERNAL_${nameUPPER}_SOURCE_DIR}"
 767       CACHE PATH "Path to ${name} source directory")
 768     set(${project}_${type}_${nameUPPER}_BUILD_DEFAULT ON)
 769     if(NOT LLVM_EXTERNAL_${nameUPPER}_SOURCE_DIR OR NOT EXISTS ${LLVM_EXTERNAL_${nameUPPER}_SOURCE_DIR})
 770       set(${project}_${type}_${nameUPPER}_BUILD_DEFAULT OFF)
 771     endif()
 772     if("${LLVM_EXTERNAL_${nameUPPER}_BUILD}" STREQUAL "OFF")
 773       set(${project}_${type}_${nameUPPER}_BUILD_DEFAULT OFF)
 774     endif()
 775     option(${project}_${type}_${nameUPPER}_BUILD
 776       "Whether to build ${name} as part of LLVM"
 777       ${${project}_${type}_${nameUPPER}_BUILD_DEFAULT})
 778     if (${project}_${type}_${nameUPPER}_BUILD)
 779       if(EXISTS ${LLVM_EXTERNAL_${nameUPPER}_SOURCE_DIR})
 780         add_subdirectory(${LLVM_EXTERNAL_${nameUPPER}_SOURCE_DIR} ${add_llvm_external_dir})
 781       elseif(NOT "${LLVM_EXTERNAL_${nameUPPER}_SOURCE_DIR}" STREQUAL "")
 782         message(WARNING "Nonexistent directory for ${name}: ${LLVM_EXTERNAL_${nameUPPER}_SOURCE_DIR}")
 783       endif()
 784       # FIXME: It'd be redundant.
 785       set(${project}_${type}_${nameUPPER}_BUILD Off)
 786     endif()
 787   endif()
 788 endmacro()
 789
 790 # Add external project that may want to be built as part of llvm such as Clang,
 791 # lld, and Polly. This adds two options. One for the source directory of the
 792 # project, which defaults to ${CMAKE_CURRENT_SOURCE_DIR}/${name}. Another to
 793 # enable or disable building it with everything else.
 794 # Additional parameter can be specified as the name of directory.
 795 macro(add_llvm_external_project name)
 796   add_llvm_subdirectory(LLVM TOOL ${name} ${ARGN})
 797 endmacro()
 798
 799 macro(add_llvm_tool_subdirectory name)
 800   add_llvm_external_project(${name})
 801 endmacro(add_llvm_tool_subdirectory)
 802
 803 function(get_project_name_from_src_var var output)
 804   string(REGEX MATCH "LLVM_EXTERNAL_(.*)_SOURCE_DIR"
 805          MACHED_TOOL "${var}")
 806   if(MACHED_TOOL)
 807     set(${output} ${CMAKE_MATCH_1} PARENT_SCOPE)
 808   else()
 809     set(${output} PARENT_SCOPE)
 810   endif()
 811 endfunction()
 812
 813 function(create_subdirectory_options project type)
 814   file(GLOB sub-dirs "${CMAKE_CURRENT_SOURCE_DIR}/*")
 815   foreach(dir ${sub-dirs})
 816     if(IS_DIRECTORY "${dir}" AND EXISTS "${dir}/CMakeLists.txt")
 817       canonicalize_tool_name(${dir} name)
 818       option(${project}_${type}_${name}_BUILD
 819            "Whether to build ${name} as part of ${project}" On)
 820       mark_as_advanced(${project}_${type}_${name}_BUILD)
 821     endif()
 822   endforeach()
 823 endfunction(create_subdirectory_options)
 824
 825 function(create_llvm_tool_options)
 826   create_subdirectory_options(LLVM TOOL)
 827 endfunction(create_llvm_tool_options)
 828
 829 function(add_llvm_implicit_projects)
 830   set(list_of_implicit_subdirs "")
 831   file(GLOB sub-dirs "${CMAKE_CURRENT_SOURCE_DIR}/*")
 832   foreach(dir ${sub-dirs})
 833     if(IS_DIRECTORY "${dir}" AND EXISTS "${dir}/CMakeLists.txt")
 834       canonicalize_tool_name(${dir} name)
 835       if (LLVM_TOOL_${name}_BUILD)
 836         get_filename_component(fn "${dir}" NAME)
 837         list(APPEND list_of_implicit_subdirs "${fn}")
 838       endif()
 839     endif()
 840   endforeach()
 841
 842   foreach(external_proj ${list_of_implicit_subdirs})
 843     add_llvm_external_project("${external_proj}")
 844   endforeach()
 845 endfunction(add_llvm_implicit_projects)
 846
 847 # Generic support for adding a unittest.
 848 function(add_unittest test_suite test_name)
 849   if( NOT LLVM_BUILD_TESTS )
 850     set(EXCLUDE_FROM_ALL ON)
 851   endif()
 852
 853   include_directories(${LLVM_MAIN_SRC_DIR}/utils/unittest/googletest/include)
 854   if (NOT LLVM_ENABLE_THREADS)
 855     list(APPEND LLVM_COMPILE_DEFINITIONS GTEST_HAS_PTHREAD=0)
 856   endif ()
 857
 858   if (SUPPORTS_NO_VARIADIC_MACROS_FLAG)
 859     list(APPEND LLVM_COMPILE_FLAGS "-Wno-variadic-macros")
 860   endif ()
 861
 862   set(LLVM_REQUIRES_RTTI OFF)
 863
 864   add_llvm_executable(${test_name} ${ARGN})
 865   set(outdir ${CMAKE_CURRENT_BINARY_DIR}/${CMAKE_CFG_INTDIR})
 866   set_output_directory(${test_name} BINARY_DIR ${outdir} LIBRARY_DIR ${outdir})
 867   target_link_libraries(${test_name}
 868     gtest
 869     gtest_main
 870     LLVMSupport # gtest needs it for raw_ostream.
 871     )
 872
 873   add_dependencies(${test_suite} ${test_name})
 874   get_target_property(test_suite_folder ${test_suite} FOLDER)
 875   if (NOT ${test_suite_folder} STREQUAL "NOTFOUND")
 876     set_property(TARGET ${test_name} PROPERTY FOLDER "${test_suite_folder}")
 877   endif ()
 878 endfunction()
 879
 880 function(llvm_add_go_executable binary pkgpath)
 881   cmake_parse_arguments(ARG "ALL" "" "DEPENDS;GOFLAGS" ${ARGN})
 882
 883   if(LLVM_BINDINGS MATCHES "go")
 884     # FIXME: This should depend only on the libraries Go needs.
 885     get_property(llvmlibs GLOBAL PROPERTY LLVM_LIBS)
 886     set(binpath ${CMAKE_BINARY_DIR}/bin/${binary}${CMAKE_EXECUTABLE_SUFFIX})
 887     set(cc "${CMAKE_C_COMPILER} ${CMAKE_C_COMPILER_ARG1}")
 888     set(cxx "${CMAKE_CXX_COMPILER} ${CMAKE_CXX_COMPILER_ARG1}")
 889     set(cppflags "")
 890     get_property(include_dirs DIRECTORY PROPERTY INCLUDE_DIRECTORIES)
 891     foreach(d ${include_dirs})
 892       set(cppflags "${cppflags} -I${d}")
 893     endforeach(d)
 894     set(ldflags "${CMAKE_EXE_LINKER_FLAGS}")
 895     if (LLVM_LINK_LLVM_DYLIB)
 896       set(linkmode "dylib")
 897     else()
 898       set(linkmode "component-libs")
 899     endif()
 900     add_custom_command(OUTPUT ${binpath}
 901       COMMAND ${CMAKE_BINARY_DIR}/bin/llvm-go "go=${GO_EXECUTABLE}" "cc=${cc}" "cxx=${cxx}" "cppflags=${cppflags}" "ldflags=${ldflags}" "linkmode=${linkmode}"
 902               ${ARG_GOFLAGS} build -o ${binpath} ${pkgpath}
 903       DEPENDS llvm-config ${CMAKE_BINARY_DIR}/bin/llvm-go${CMAKE_EXECUTABLE_SUFFIX}
 904               ${llvmlibs} ${ARG_DEPENDS}
 905       COMMENT "Building Go executable ${binary}"
 906       VERBATIM)
 907     if (ARG_ALL)
 908       add_custom_target(${binary} ALL DEPENDS ${binpath})
 909     else()
 910       add_custom_target(${binary} DEPENDS ${binpath})
 911     endif()
 912   endif()
 913 endfunction()
 914
 915 # This function provides an automatic way to 'configure'-like generate a file
 916 # based on a set of common and custom variables, specifically targeting the
 917 # variables needed for the 'lit.site.cfg' files. This function bundles the
 918 # common variables that any Lit instance is likely to need, and custom
 919 # variables can be passed in.
 920 function(configure_lit_site_cfg input output)
 921   foreach(c ${LLVM_TARGETS_TO_BUILD})
 922     set(TARGETS_BUILT "${TARGETS_BUILT} ${c}")
 923   endforeach(c)
 924   set(TARGETS_TO_BUILD ${TARGETS_BUILT})
 925
 926   set(SHLIBEXT "${LTDL_SHLIB_EXT}")
 927
 928   # Configuration-time: See Unit/lit.site.cfg.in
 929   if (CMAKE_CFG_INTDIR STREQUAL ".")
 930     set(LLVM_BUILD_MODE ".")
 931   else ()
 932     set(LLVM_BUILD_MODE "%(build_mode)s")
 933   endif ()
 934
 935   # They below might not be the build tree but provided binary tree.
 936   set(LLVM_SOURCE_DIR ${LLVM_MAIN_SRC_DIR})
 937   set(LLVM_BINARY_DIR ${LLVM_BINARY_DIR})
 938   string(REPLACE ${CMAKE_CFG_INTDIR} ${LLVM_BUILD_MODE} LLVM_TOOLS_DIR ${LLVM_TOOLS_BINARY_DIR})
 939   string(REPLACE ${CMAKE_CFG_INTDIR} ${LLVM_BUILD_MODE} LLVM_LIBS_DIR  ${LLVM_LIBRARY_DIR})
 940
 941   # SHLIBDIR points the build tree.
 942   string(REPLACE ${CMAKE_CFG_INTDIR} ${LLVM_BUILD_MODE} SHLIBDIR "${LLVM_SHLIB_OUTPUT_INTDIR}")
 943
 944   set(PYTHON_EXECUTABLE ${PYTHON_EXECUTABLE})
 945   # FIXME: "ENABLE_SHARED" doesn't make sense, since it is used just for
 946   # plugins. We may rename it.
 947   if(LLVM_ENABLE_PLUGINS)
 948     set(ENABLE_SHARED "1")
 949   else()
 950     set(ENABLE_SHARED "0")
 951   endif()
 952
 953   if(LLVM_ENABLE_ASSERTIONS AND NOT MSVC_IDE)
 954     set(ENABLE_ASSERTIONS "1")
 955   else()
 956     set(ENABLE_ASSERTIONS "0")
 957   endif()
 958
 959   set(HOST_OS ${CMAKE_SYSTEM_NAME})
 960   set(HOST_ARCH ${CMAKE_SYSTEM_PROCESSOR})
 961
 962   set(HOST_CC "${CMAKE_C_COMPILER} ${CMAKE_C_COMPILER_ARG1}")
 963   set(HOST_CXX "${CMAKE_CXX_COMPILER} ${CMAKE_CXX_COMPILER_ARG1}")
 964   set(HOST_LDFLAGS "${CMAKE_EXE_LINKER_FLAGS}")
 965
 966   configure_file(${input} ${output} @ONLY)
 967 endfunction()
 968
 969 # A raw function to create a lit target. This is used to implement the testuite
 970 # management functions.
 971 function(add_lit_target target comment)
 972   cmake_parse_arguments(ARG "" "" "PARAMS;DEPENDS;ARGS" ${ARGN})
 973   set(LIT_ARGS "${ARG_ARGS} ${LLVM_LIT_ARGS}")
 974   separate_arguments(LIT_ARGS)
 975   if (NOT CMAKE_CFG_INTDIR STREQUAL ".")
 976     list(APPEND LIT_ARGS --param build_mode=${CMAKE_CFG_INTDIR})
 977   endif ()
 978   if (LLVM_MAIN_SRC_DIR)
 979     set (LIT_COMMAND ${PYTHON_EXECUTABLE} ${LLVM_MAIN_SRC_DIR}/utils/lit/lit.py)
 980   else()
 981     find_program(LIT_COMMAND llvm-lit)
 982   endif ()
 983   list(APPEND LIT_COMMAND ${LIT_ARGS})
 984   foreach(param ${ARG_PARAMS})
 985     list(APPEND LIT_COMMAND --param ${param})
 986   endforeach()
 987   if (ARG_UNPARSED_ARGUMENTS)
 988     add_custom_target(${target}
 989       COMMAND ${LIT_COMMAND} ${ARG_UNPARSED_ARGUMENTS}
 990       COMMENT "${comment}"
 991       ${cmake_3_2_USES_TERMINAL}
 992       )
 993   else()
 994     add_custom_target(${target}
 995       COMMAND ${CMAKE_COMMAND} -E echo "${target} does nothing, no tools built.")
 996     message(STATUS "${target} does nothing.")
 997   endif()
 998   if (ARG_DEPENDS)
 999     add_dependencies(${target} ${ARG_DEPENDS})
1000   endif()
1001
1002   # Tests should be excluded from "Build Solution".
1003   set_target_properties(${target} PROPERTIES EXCLUDE_FROM_DEFAULT_BUILD ON)
1004 endfunction()
1005
1006 # A function to add a set of lit test suites to be driven through 'check-*' targets.
1007 function(add_lit_testsuite target comment)
1008   cmake_parse_arguments(ARG "" "" "PARAMS;DEPENDS;ARGS" ${ARGN})
1009
1010   # EXCLUDE_FROM_ALL excludes the test ${target} out of check-all.
1011   if(NOT EXCLUDE_FROM_ALL)
1012     # Register the testsuites, params and depends for the global check rule.
1013     set_property(GLOBAL APPEND PROPERTY LLVM_LIT_TESTSUITES ${ARG_UNPARSED_ARGUMENTS})
1014     set_property(GLOBAL APPEND PROPERTY LLVM_LIT_PARAMS ${ARG_PARAMS})
1015     set_property(GLOBAL APPEND PROPERTY LLVM_LIT_DEPENDS ${ARG_DEPENDS})
1016     set_property(GLOBAL APPEND PROPERTY LLVM_LIT_EXTRA_ARGS ${ARG_ARGS})
1017   endif()
1018
1019   # Produce a specific suffixed check rule.
1020   add_lit_target(${target} ${comment}
1021     ${ARG_UNPARSED_ARGUMENTS}
1022     PARAMS ${ARG_PARAMS}
1023     DEPENDS ${ARG_DEPENDS}
1024     ARGS ${ARG_ARGS}
1025     )
1026 endfunction()
1027
1028 function(add_lit_testsuites project directory)
1029   if (NOT CMAKE_CONFIGURATION_TYPES)
1030     cmake_parse_arguments(ARG "" "" "PARAMS;DEPENDS;ARGS" ${ARGN})
1031     file(GLOB_RECURSE litCfg ${directory}/lit*.cfg)
1032     set(lit_suites)
1033     foreach(f ${litCfg})
1034       get_filename_component(dir ${f} DIRECTORY)
1035       set(lit_suites ${lit_suites} ${dir})
1036     endforeach()
1037     list(REMOVE_DUPLICATES lit_suites)
1038     foreach(dir ${lit_suites})
1039       string(REPLACE ${directory} "" name_slash ${dir})
1040       if (name_slash)
1041         string(REPLACE "/" "-" name_slash ${name_slash})
1042         string(REPLACE "\\" "-" name_dashes ${name_slash})
1043         string(TOLOWER "${project}${name_dashes}" name_var)
1044         add_lit_target("check-${name_var}" "Running lit suite ${dir}"
1045           ${dir}
1046           PARAMS ${ARG_PARAMS}
1047           DEPENDS ${ARG_DEPENDS}
1048           ARGS ${ARG_ARGS}
1049         )
1050       endif()
1051     endforeach()
1052   endif()
1053 endfunction()
1054
1055 function(llvm_install_library_symlink name dest type)
1056   cmake_parse_arguments(ARG "ALWAYS_GENERATE" "COMPONENT" "" ${ARGN})
1057   foreach(path ${CMAKE_MODULE_PATH})
1058     if(EXISTS ${path}/LLVMInstallSymlink.cmake)
1059       set(INSTALL_SYMLINK ${path}/LLVMInstallSymlink.cmake)
1060       break()
1061     endif()
1062   endforeach()
1063
1064   set(component ${ARG_COMPONENT})
1065   if(NOT component)
1066     set(component ${name})
1067   endif()
1068
1069   set(full_name ${CMAKE_${type}_LIBRARY_PREFIX}${name}${CMAKE_${type}_LIBRARY_SUFFIX})
1070   set(full_dest ${CMAKE_${type}_LIBRARY_PREFIX}${dest}${CMAKE_${type}_LIBRARY_SUFFIX})
1071
1072   set(output_dir lib)
1073   if(WIN32 AND "${type}" STREQUAL "SHARED")
1074     set(output_dir bin)
1075   endif()
1076
1077   install(SCRIPT ${INSTALL_SYMLINK}
1078           CODE "install_symlink(${full_name} ${full_dest} ${output_dir})"
1079           COMPONENT ${component})
1080
1081   if (NOT CMAKE_CONFIGURATION_TYPES AND NOT ARG_ALWAYS_GENERATE)
1082     add_custom_target(install-${name}
1083                       DEPENDS ${name} ${dest} install-${dest}
1084                       COMMAND "${CMAKE_COMMAND}"
1085                               -DCMAKE_INSTALL_COMPONENT=${name}
1086                               -P "${CMAKE_BINARY_DIR}/cmake_install.cmake")
1087   endif()
1088 endfunction()
1089
1090 function(llvm_install_symlink name dest)
1091   cmake_parse_arguments(ARG "ALWAYS_GENERATE" "" "" ${ARGN})
1092   foreach(path ${CMAKE_MODULE_PATH})
1093     if(EXISTS ${path}/LLVMInstallSymlink.cmake)
1094       set(INSTALL_SYMLINK ${path}/LLVMInstallSymlink.cmake)
1095       break()
1096     endif()
1097   endforeach()
1098
1099   if(ARG_ALWAYS_GENERATE)
1100     set(component ${dest})
1101   else()
1102     set(component ${name})
1103   endif()
1104
1105   set(full_name ${name}${CMAKE_EXECUTABLE_SUFFIX})
1106   set(full_dest ${dest}${CMAKE_EXECUTABLE_SUFFIX})
1107
1108   install(SCRIPT ${INSTALL_SYMLINK}
1109           CODE "install_symlink(${full_name} ${full_dest} bin)"
1110           COMPONENT ${component})
1111
1112   if (NOT CMAKE_CONFIGURATION_TYPES AND NOT ARG_ALWAYS_GENERATE)
1113     add_custom_target(install-${name}
1114                       DEPENDS ${name} ${dest} install-${dest}
1115                       COMMAND "${CMAKE_COMMAND}"
1116                               -DCMAKE_INSTALL_COMPONENT=${name}
1117                               -P "${CMAKE_BINARY_DIR}/cmake_install.cmake")
1118   endif()
1119 endfunction()
1120
1121 function(add_llvm_tool_symlink name dest)
1122   cmake_parse_arguments(ARG "ALWAYS_GENERATE" "" "" ${ARGN})
1123   if(UNIX)
1124     set(LLVM_LINK_OR_COPY create_symlink)
1125     set(dest_binary "${dest}${CMAKE_EXECUTABLE_SUFFIX}")
1126   else()
1127     set(LLVM_LINK_OR_COPY copy)
1128     set(dest_binary "${LLVM_RUNTIME_OUTPUT_INTDIR}/${dest}${CMAKE_EXECUTABLE_SUFFIX}")
1129   endif()
1130
1131   set(output_path "${LLVM_RUNTIME_OUTPUT_INTDIR}/${name}${CMAKE_EXECUTABLE_SUFFIX}")
1132
1133   if(ARG_ALWAYS_GENERATE)
1134     set_property(DIRECTORY APPEND PROPERTY
1135       ADDITIONAL_MAKE_CLEAN_FILES ${dest_binary})
1136     add_custom_command(TARGET ${dest} POST_BUILD
1137       COMMAND ${CMAKE_COMMAND} -E ${LLVM_LINK_OR_COPY} "${dest_binary}" "${output_path}")
1138   else()
1139     add_custom_command(OUTPUT ${output_path}
1140                      COMMAND ${CMAKE_COMMAND} -E ${LLVM_LINK_OR_COPY} "${dest_binary}" "${output_path}"
1141                      DEPENDS ${dest})
1142     add_custom_target(${name} ALL DEPENDS ${output_path})
1143     set_target_properties(${name} PROPERTIES FOLDER Tools)
1144
1145     # Make sure the parent tool is a toolchain tool, otherwise exclude this tool
1146     list(FIND LLVM_TOOLCHAIN_TOOLS ${dest} LLVM_IS_${dest}_TOOLCHAIN_TOOL)
1147     if (NOT LLVM_IS_${dest}_TOOLCHAIN_TOOL GREATER -1)
1148       set(LLVM_IS_${name}_TOOLCHAIN_TOOL ${LLVM_IS_${dest}_TOOLCHAIN_TOOL})
1149     else()
1150       list(FIND LLVM_TOOLCHAIN_TOOLS ${name} LLVM_IS_${name}_TOOLCHAIN_TOOL)
1151     endif()
1152
1153     # LLVM_IS_${name}_TOOLCHAIN_TOOL will only be greater than -1 if both this
1154     # tool and its parent tool are in LLVM_TOOLCHAIN_TOOLS
1155     if (LLVM_IS_${name}_TOOLCHAIN_TOOL GREATER -1 OR NOT LLVM_INSTALL_TOOLCHAIN_ONLY)
1156       if( LLVM_BUILD_TOOLS )
1157         llvm_install_symlink(${name} ${dest})
1158       endif()
1159     endif()
1160   endif()
1161 endfunction()
1162