cmake/config-ix.cmake

   1
   2 # include checks
   3 include(CheckIncludeFile)
   4 check_include_file(alloca.h HAVE_ALLOCA_H)
   5 check_include_file(argz.h HAVE_ARGZ_H)
   6 check_include_file(assert.h HAVE_ASSERT_H)
   7 check_include_file(dirent.h HAVE_DIRENT_H)
   8 check_include_file(dl.h HAVE_DL_H)
   9 check_include_file(dld.h HAVE_DLD_H)
  10 check_include_file(dlfcn.h HAVE_DLFCN_H)
  11 check_include_file(errno.h HAVE_ERRNO_H)
  12 check_include_file(execinfo.h HAVE_EXECINFO_H)
  13 check_include_file(fcntl.h HAVE_FCNTL_H)
  14 check_include_file(inttypes.h HAVE_INTTYPES_H)
  15 check_include_file(limits.h HAVE_LIMITS_H)
  16 check_include_file(link.h HAVE_LINK_H)
  17 check_include_file(malloc.h HAVE_MALLOC_H)
  18 check_include_file(malloc/malloc.h HAVE_MALLOC_MALLOC_H)
  19 check_include_file(memory.h HAVE_MEMORY_H)
  20 check_include_file(ndir.h HAVE_NDIR_H)
  21 check_include_file(pthread.h HAVE_PTHREAD_H)
  22 check_include_file(setjmp.h HAVE_SETJMP_H)
  23 check_include_file(signal.h HAVE_SIGNAL_H)
  24 check_include_file(stdint.h HAVE_STDINT_H)
  25 check_include_file(stdio.h HAVE_STDIO_H)
  26 check_include_file(stdlib.h HAVE_STDLIB_H)
  27 check_include_file(string.h HAVE_STRING_H)
  28 check_include_file(sys/dir.h HAVE_SYS_DIR_H)
  29 check_include_file(sys/dl.h HAVE_SYS_DL_H)
  30 check_include_file(sys/ioctl.h HAVE_SYS_IOCTL_H)
  31 check_include_file(sys/mman.h HAVE_SYS_MMAN_H)
  32 check_include_file(sys/ndir.h HAVE_SYS_NDIR_H)
  33 check_include_file(sys/param.h HAVE_SYS_PARAM_H)
  34 check_include_file(sys/resource.h HAVE_SYS_RESOURCE_H)
  35 check_include_file(sys/stat.h HAVE_SYS_STAT_H)
  36 check_include_file(sys/time.h HAVE_SYS_TIME_H)
  37 check_include_file(sys/types.h HAVE_SYS_TYPES_H)
  38 check_include_file(sys/wait.h HAVE_SYS_WAIT_H)
  39 check_include_file(termios.h HAVE_TERMIOS_H)
  40 check_include_file(unistd.h HAVE_UNISTD_H)
  41 check_include_file(utime.h HAVE_UTIME_H)
  42 check_include_file(windows.h HAVE_WINDOWS_H)
  43
  44 # library checks
  45 include(CheckLibraryExists)
  46 check_library_exists(pthread pthread_create "" HAVE_LIBPTHREAD)
  47 check_library_exists(dl dlopen "" HAVE_LIBDL)
  48
  49 # function checks
  50 include(CheckSymbolExists)
  51 include(CheckFunctionExists)
  52 check_symbol_exists(alloca alloca.h HAVE_ALLOCA)
  53 check_symbol_exists(getpagesize unistd.h HAVE_GETPAGESIZE)
  54 check_symbol_exists(getrusage sys/resource.h HAVE_GETRUSAGE)
  55 check_symbol_exists(setrlimit sys/resource.h HAVE_SETRLIMIT)
  56 check_function_exists(isatty HAVE_ISATTY)
  57 check_symbol_exists(isinf cmath HAVE_ISINF_IN_CMATH)
  58 check_symbol_exists(isinf math.h HAVE_ISINF_IN_MATH_H)
  59 check_symbol_exists(isnan cmath HAVE_ISNAN_IN_CMATH)
  60 check_symbol_exists(isnan math.h HAVE_ISNAN_IN_MATH_H)
  61 check_symbol_exists(ceilf math.h HAVE_CEILF)
  62 check_symbol_exists(floorf math.h HAVE_FLOORF)
  63 check_symbol_exists(mallinfo malloc.h HAVE_MALLINFO)
  64 check_symbol_exists(malloc_zone_statistics malloc/malloc.h
  65                     HAVE_MALLOC_ZONE_STATISTICS)
  66 check_symbol_exists(pthread_mutex_lock pthread.h HAVE_PTHREAD_MUTEX_LOCK)
  67 check_symbol_exists(strtoll stdlib.h HAVE_STRTOLL)
  68
  69 check_symbol_exists(__GLIBC__ stdio.h LLVM_USING_GLIBC)
  70 if( LLVM_USING_GLIBC )
  71   add_llvm_definitions( -D_GNU_SOURCE )
  72 endif()
  73
  74 include(CheckCXXCompilerFlag)
  75 check_cxx_compiler_flag("-fPIC" SUPPORTS_FPIC_FLAG)
  76
  77 include(GetTargetTriple)
  78 get_target_triple(LLVM_HOSTTRIPLE)
  79 message(STATUS "LLVM_HOSTTRIPLE: ${LLVM_HOSTTRIPLE}")
  80
  81 # Determine the native architecture.
  82 # FIXME: this will have to change for cross-compiling.
  83 string(REGEX MATCH "^[^-]*" LLVM_NATIVE_ARCH ${LLVM_HOSTTRIPLE})
  84 if (LLVM_NATIVE_ARCH MATCHES "i[2-6]86")
  85   set(LLVM_NATIVE_ARCH X86)
  86 elseif (LLVM_NATIVE_ARCH STREQUAL amd64)
  87   set(LLVM_NATIVE_ARCH X86)
  88 elseif (LLVM_NATIVE_ARCH STREQUAL x86_64)
  89   set(LLVM_NATIVE_ARCH X86)
  90 elseif (LLVM_NATIVE_ARCH MATCHES "sparc")
  91   set(LLVM_NATIVE_ARCH Sparc)
  92 elseif (LLVM_NATIVE_ARCH MATCHES "powerpc")
  93   set(LLVM_NATIVE_ARCH PowerPC)
  94 elseif (LLVM_NATIVE_ARCH MATCHES "alpha")
  95   set(LLVM_NATIVE_ARCH Alpha)
  96 elseif (LLVM_NATIVE_ARCH MATCHES "ia64")
  97   set(LLVM_NATIVE_ARCH IA64)
  98 elseif (LLVM_NATIVE_ARCH MATCHES "arm")
  99   set(LLVM_NATIVE_ARCH ARM)
 100 elseif (LLVM_NATIVE_ARCH MATCHES "mips")
 101   set(LLVM_NATIVE_ARCH Mips)
 102 elseif (LLVM_NATIVE_ARCH MATCHES "pic16")
 103   set(LLVM_NATIVE_ARCH "PIC16")
 104 elseif (LLVM_NATIVE_ARCH MATCHES "xcore")
 105   set(LLVM_NATIVE_ARCH XCore)
 106 elseif (LLVM_NATIVE_ARCH MATCHES "msp430")
 107   set(LLVM_NATIVE_ARCH MSP430)
 108 else ()
 109   message(STATUS
 110     "Unknown architecture ${LLVM_NATIVE_ARCH}; lli will not JIT code")
 111   set(LLVM_NATIVE_ARCH)
 112 endif ()
 113
 114 if (LLVM_NATIVE_ARCH)
 115   list(FIND LLVM_TARGETS_TO_BUILD ${LLVM_NATIVE_ARCH} NATIVE_ARCH_IDX)
 116   if (NATIVE_ARCH_IDX EQUAL -1)
 117     message(STATUS
 118       "Native target ${LLVM_NATIVE_ARCH} is not selected; lli will not JIT code")
 119     set(LLVM_NATIVE_ARCH)
 120   else ()
 121     message(STATUS "Native target architecture is ${LLVM_NATIVE_ARCH}")
 122   endif ()
 123 endif()
 124
 125 if( MINGW )
 126   set(HAVE_LIBIMAGEHLP 1)
 127   set(HAVE_LIBPSAPI 1)
 128   # TODO: Check existence of libraries.
 129   #   include(CheckLibraryExists)
 130   #   CHECK_LIBRARY_EXISTS(imagehlp ??? . HAVE_LIBIMAGEHLP)
 131 endif( MINGW )
 132
 133 if( MSVC )
 134   set(error_t int)
 135   set(mode_t "unsigned short")
 136   set(LTDL_SHLIBPATH_VAR "PATH")
 137   set(LTDL_SYSSEARCHPATH "")
 138   set(LTDL_DLOPEN_DEPLIBS 1)
 139   set(SHLIBEXT ".lib")
 140   set(LTDL_OBJDIR "_libs")
 141   set(HAVE_STRTOLL 1)
 142   set(strtoll "_strtoi64")
 143   set(strtoull "_strtoui64")
 144   set(stricmp "_stricmp")
 145   set(strdup "_strdup")
 146 else( MSVC )
 147   set(LTDL_SHLIBPATH_VAR "LD_LIBRARY_PATH")
 148   set(LTDL_SYSSEARCHPATH "") # TODO
 149   set(LTDL_DLOPEN_DEPLIBS 0)  # TODO
 150 endif( MSVC )
 151
 152 # FIXME: Signal handler return type, currently hardcoded to 'void'
 153 set(RETSIGTYPE void)
 154
 155 if( LLVM_ENABLE_THREADS )
 156   if( HAVE_PTHREAD_H OR WIN32 )
 157     set(ENABLE_THREADS 1)
 158   endif()
 159 endif()
 160
 161 if( ENABLE_THREADS )
 162   message(STATUS "Threads enabled.")
 163 else( ENABLE_THREADS )
 164   message(STATUS "Threads disabled.")
 165 endif()
 166
 167 configure_file(
 168   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/config.h.cmake
 169   ${LLVM_BINARY_DIR}/include/llvm/Config/config.h
 170   )
 171
 172 configure_file(
 173   ${LLVM_MAIN_INCLUDE_DIR}/llvm/ADT/iterator.cmake
 174   ${LLVM_BINARY_DIR}/include/llvm/ADT/iterator.h
 175   )
 176
 177 configure_file(
 178   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Support/DataTypes.h.cmake
 179   ${LLVM_BINARY_DIR}/include/llvm/Support/DataTypes.h
 180   )
 181