cmake/config-ix.cmake

   1
   2 # include checks
   3 include(CheckIncludeFile)
   4 check_include_file(argz.h HAVE_ARGZ_H)
   5 check_include_file(assert.h HAVE_ASSERT_H)
   6 check_include_file(dirent.h HAVE_DIRENT_H)
   7 check_include_file(dl.h HAVE_DL_H)
   8 check_include_file(dld.h HAVE_DLD_H)
   9 check_include_file(dlfcn.h HAVE_DLFCN_H)
  10 check_include_file(errno.h HAVE_ERRNO_H)
  11 check_include_file(execinfo.h HAVE_EXECINFO_H)
  12 check_include_file(fcntl.h HAVE_FCNTL_H)
  13 check_include_file(inttypes.h HAVE_INTTYPES_H)
  14 check_include_file(limits.h HAVE_LIMITS_H)
  15 check_include_file(link.h HAVE_LINK_H)
  16 check_include_file(malloc.h HAVE_MALLOC_H)
  17 check_include_file(malloc/malloc.h HAVE_MALLOC_MALLOC_H)
  18 check_include_file(memory.h HAVE_MEMORY_H)
  19 check_include_file(ndir.h HAVE_NDIR_H)
  20 check_include_file(pthread.h HAVE_PTHREAD_H)
  21 check_include_file(setjmp.h HAVE_SETJMP_H)
  22 check_include_file(signal.h HAVE_SIGNAL_H)
  23 check_include_file(stdint.h HAVE_STDINT_H)
  24 check_include_file(stdio.h HAVE_STDIO_H)
  25 check_include_file(stdlib.h HAVE_STDLIB_H)
  26 check_include_file(string.h HAVE_STRING_H)
  27 check_include_file(sys/dir.h HAVE_SYS_DIR_H)
  28 check_include_file(sys/dl.h HAVE_SYS_DL_H)
  29 check_include_file(sys/ioctl.h HAVE_SYS_IOCTL_H)
  30 check_include_file(sys/mman.h HAVE_SYS_MMAN_H)
  31 check_include_file(sys/ndir.h HAVE_SYS_NDIR_H)
  32 check_include_file(sys/param.h HAVE_SYS_PARAM_H)
  33 check_include_file(sys/resource.h HAVE_SYS_RESOURCE_H)
  34 check_include_file(sys/stat.h HAVE_SYS_STAT_H)
  35 check_include_file(sys/time.h HAVE_SYS_TIME_H)
  36 check_include_file(sys/types.h HAVE_SYS_TYPES_H)
  37 check_include_file(termios.h HAVE_TERMIOS_H)
  38 check_include_file(unistd.h HAVE_UNISTD_H)
  39 check_include_file(utime.h HAVE_UTIME_H)
  40 check_include_file(windows.h HAVE_WINDOWS_H)
  41
  42 # library checks
  43 include(CheckLibraryExists)
  44 check_library_exists(pthread pthread_create "" HAVE_LIBPTHREAD)
  45 check_library_exists(dl dlopen "" HAVE_LIBDL)
  46
  47 # function checks
  48 include(CheckSymbolExists)
  49 include(CheckFunctionExists)
  50 check_symbol_exists(getpagesize unistd.h HAVE_GETPAGESIZE)
  51 check_symbol_exists(getrusage sys/resource.h HAVE_GETRUSAGE)
  52 check_symbol_exists(setrlimit sys/resource.h HAVE_SETRLIMIT)
  53 check_function_exists(isatty HAVE_ISATTY)
  54 check_symbol_exists(isinf cmath HAVE_ISINF_IN_CMATH)
  55 check_symbol_exists(isinf math.h HAVE_ISINF_IN_MATH_H)
  56 check_symbol_exists(isnan cmath HAVE_ISNAN_IN_CMATH)
  57 check_symbol_exists(isnan math.h HAVE_ISNAN_IN_MATH_H)
  58 check_symbol_exists(ceilf math.h HAVE_CEILF)
  59 check_symbol_exists(floorf math.h HAVE_FLOORF)
  60 check_symbol_exists(mallinfo malloc.h HAVE_MALLINFO)
  61 check_symbol_exists(malloc_zone_statistics malloc/malloc.h
  62                     HAVE_MALLOC_ZONE_STATISTICS)
  63 check_symbol_exists(pthread_mutex_lock pthread.h HAVE_PTHREAD_MUTEX_LOCK)
  64 check_symbol_exists(strtoll stdlib.h HAVE_STRTOLL)
  65
  66 check_symbol_exists(__GLIBC__ stdio.h LLVM_USING_GLIBC)
  67 if( LLVM_USING_GLIBC )
  68   add_llvm_definitions( -D_GNU_SOURCE )
  69 endif()
  70
  71 include(CheckCXXCompilerFlag)
  72 check_cxx_compiler_flag("-fPIC" SUPPORTS_FPIC_FLAG)
  73
  74 include(GetTargetTriple)
  75 get_target_triple(LLVM_HOSTTRIPLE)
  76 message(STATUS "LLVM_HOSTTRIPLE: ${LLVM_HOSTTRIPLE}")
  77
  78 if( MINGW )
  79   set(HAVE_LIBIMAGEHLP 1)
  80   set(HAVE_LIBPSAPI 1)
  81   # TODO: Check existence of libraries.
  82   #   include(CheckLibraryExists)
  83   #   CHECK_LIBRARY_EXISTS(imagehlp ??? . HAVE_LIBIMAGEHLP)
  84 endif( MINGW )
  85
  86 if( MSVC )
  87   set(error_t int)
  88   set(mode_t "unsigned short")
  89   set(LTDL_SHLIBPATH_VAR "PATH")
  90   set(LTDL_SYSSEARCHPATH "")
  91   set(LTDL_DLOPEN_DEPLIBS 1)
  92   set(SHLIBEXT ".lib")
  93   set(LTDL_OBJDIR "_libs")
  94   set(HAVE_STRTOLL 1)
  95   set(strtoll "_strtoi64")
  96   set(strtoull "_strtoui64")
  97   set(stricmp "_stricmp")
  98   set(strdup "_strdup")
  99 else( MSVC )
 100   set(LTDL_SHLIBPATH_VAR "LD_LIBRARY_PATH")
 101   set(LTDL_SYSSEARCHPATH "") # TODO
 102   set(LTDL_DLOPEN_DEPLIBS 0)  # TODO
 103 endif( MSVC )
 104
 105 # FIXME: Signal handler return type, currently hardcoded to 'void'
 106 set(RETSIGTYPE void)
 107
 108 if( LLVM_ENABLE_THREADS )
 109   if( HAVE_PTHREAD_H OR WIN32 )
 110     set(ENABLE_THREADS 1)
 111   endif()
 112 endif()
 113
 114 if( ENABLE_THREADS )
 115   message(STATUS "Threads enabled.")
 116 else( ENABLE_THREADS )
 117   message(STATUS "Threads disabled.")
 118 endif()
 119
 120 configure_file(
 121   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/config.h.cmake
 122   ${LLVM_BINARY_DIR}/include/llvm/Config/config.h
 123   )
 124
 125 configure_file(
 126   ${LLVM_MAIN_INCLUDE_DIR}/llvm/ADT/iterator.cmake
 127   ${LLVM_BINARY_DIR}/include/llvm/ADT/iterator.h
 128   )
 129
 130 configure_file(
 131   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Support/DataTypes.h.cmake
 132   ${LLVM_BINARY_DIR}/include/llvm/Support/DataTypes.h
 133   )
 134