cmake/config-ix.cmake

   1 include(CheckIncludeFile)
   2 include(CheckLibraryExists)
   3 include(CheckSymbolExists)
   4 include(CheckFunctionExists)
   5 include(CheckCXXSourceCompiles)
   6 include(TestBigEndian)
   7
   8 if( UNIX AND NOT BEOS )
   9   # Used by check_symbol_exists:
  10   set(CMAKE_REQUIRED_LIBRARIES m)
  11 endif()
  12
  13 # Helper macros and functions
  14 macro(add_cxx_include result files)
  15   set(${result} "")
  16   foreach (file_name ${files})
  17      set(${result} "${${result}}#include<${file_name}>\n")
  18   endforeach()
  19 endmacro(add_cxx_include files result)
  20
  21 function(check_type_exists type files variable)
  22   add_cxx_include(includes "${files}")
  23   CHECK_CXX_SOURCE_COMPILES("
  24     ${includes} ${type} typeVar;
  25     int main() {
  26         return 0;
  27     }
  28     " ${variable})
  29 endfunction()
  30
  31 # include checks
  32 check_include_file(argz.h HAVE_ARGZ_H)
  33 check_include_file(assert.h HAVE_ASSERT_H)
  34 check_include_file(ctype.h HAVE_CTYPE_H)
  35 check_include_file(dirent.h HAVE_DIRENT_H)
  36 check_include_file(dl.h HAVE_DL_H)
  37 check_include_file(dld.h HAVE_DLD_H)
  38 check_include_file(dlfcn.h HAVE_DLFCN_H)
  39 check_include_file(errno.h HAVE_ERRNO_H)
  40 check_include_file(execinfo.h HAVE_EXECINFO_H)
  41 check_include_file(fcntl.h HAVE_FCNTL_H)
  42 check_include_file(inttypes.h HAVE_INTTYPES_H)
  43 check_include_file(limits.h HAVE_LIMITS_H)
  44 check_include_file(link.h HAVE_LINK_H)
  45 check_include_file(malloc.h HAVE_MALLOC_H)
  46 check_include_file(malloc/malloc.h HAVE_MALLOC_MALLOC_H)
  47 check_include_file(memory.h HAVE_MEMORY_H)
  48 check_include_file(ndir.h HAVE_NDIR_H)
  49 if( NOT LLVM_ON_WIN32 )
  50   check_include_file(pthread.h HAVE_PTHREAD_H)
  51 endif()
  52 check_include_file(setjmp.h HAVE_SETJMP_H)
  53 check_include_file(signal.h HAVE_SIGNAL_H)
  54 check_include_file(stdint.h HAVE_STDINT_H)
  55 check_include_file(stdio.h HAVE_STDIO_H)
  56 check_include_file(stdlib.h HAVE_STDLIB_H)
  57 check_include_file(string.h HAVE_STRING_H)
  58 check_include_file(strings.h HAVE_STRINGS_H)
  59 check_include_file(sys/dir.h HAVE_SYS_DIR_H)
  60 check_include_file(sys/dl.h HAVE_SYS_DL_H)
  61 check_include_file(sys/ioctl.h HAVE_SYS_IOCTL_H)
  62 check_include_file(sys/mman.h HAVE_SYS_MMAN_H)
  63 check_include_file(sys/ndir.h HAVE_SYS_NDIR_H)
  64 check_include_file(sys/param.h HAVE_SYS_PARAM_H)
  65 check_include_file(sys/resource.h HAVE_SYS_RESOURCE_H)
  66 check_include_file(sys/stat.h HAVE_SYS_STAT_H)
  67 check_include_file(sys/time.h HAVE_SYS_TIME_H)
  68 check_include_file(sys/types.h HAVE_SYS_TYPES_H)
  69 check_include_file(sys/wait.h HAVE_SYS_WAIT_H)
  70 check_include_file(termios.h HAVE_TERMIOS_H)
  71 check_include_file(unistd.h HAVE_UNISTD_H)
  72 check_include_file(utime.h HAVE_UTIME_H)
  73 check_include_file(valgrind/valgrind.h HAVE_VALGRIND_VALGRIND_H)
  74 check_include_file(windows.h HAVE_WINDOWS_H)
  75 check_include_file(fenv.h HAVE_FENV_H)
  76 check_include_file(mach/mach.h HAVE_MACH_MACH_H)
  77 check_include_file(mach-o/dyld.h HAVE_MACH_O_DYLD_H)
  78
  79 # library checks
  80 if( NOT LLVM_ON_WIN32 )
  81   check_library_exists(pthread pthread_create "" HAVE_LIBPTHREAD)
  82   check_library_exists(pthread pthread_getspecific "" HAVE_PTHREAD_GETSPECIFIC)
  83   check_library_exists(pthread pthread_rwlock_init "" HAVE_PTHREAD_RWLOCK_INIT)
  84   check_library_exists(dl dlopen "" HAVE_LIBDL)
  85 endif()
  86
  87 # function checks
  88 check_symbol_exists(getpagesize unistd.h HAVE_GETPAGESIZE)
  89 check_symbol_exists(getrusage sys/resource.h HAVE_GETRUSAGE)
  90 check_symbol_exists(setrlimit sys/resource.h HAVE_SETRLIMIT)
  91 check_function_exists(isatty HAVE_ISATTY)
  92 check_symbol_exists(index strings.h HAVE_INDEX)
  93 check_symbol_exists(isinf cmath HAVE_ISINF_IN_CMATH)
  94 check_symbol_exists(isinf math.h HAVE_ISINF_IN_MATH_H)
  95 check_symbol_exists(finite ieeefp.h HAVE_FINITE_IN_IEEEFP_H)
  96 check_symbol_exists(isnan cmath HAVE_ISNAN_IN_CMATH)
  97 check_symbol_exists(isnan math.h HAVE_ISNAN_IN_MATH_H)
  98 check_symbol_exists(ceilf math.h HAVE_CEILF)
  99 check_symbol_exists(floorf math.h HAVE_FLOORF)
 100 check_symbol_exists(fmodf math.h HAVE_FMODF)
 101 if( HAVE_SETJMP_H )
 102   check_symbol_exists(longjmp setjmp.h HAVE_LONGJMP)
 103   check_symbol_exists(setjmp setjmp.h HAVE_SETJMP)
 104   check_symbol_exists(siglongjmp setjmp.h HAVE_SIGLONGJMP)
 105   check_symbol_exists(sigsetjmp setjmp.h HAVE_SIGSETJMP)
 106 endif()
 107 check_symbol_exists(nearbyintf math.h HAVE_NEARBYINTF)
 108 check_symbol_exists(mallinfo malloc.h HAVE_MALLINFO)
 109 check_symbol_exists(malloc_zone_statistics malloc/malloc.h
 110                     HAVE_MALLOC_ZONE_STATISTICS)
 111 check_symbol_exists(mkdtemp "stdlib.h;unistd.h" HAVE_MKDTEMP)
 112 check_symbol_exists(mkstemp "stdlib.h;unistd.h" HAVE_MKSTEMP)
 113 check_symbol_exists(mktemp "stdlib.h;unistd.h" HAVE_MKTEMP)
 114 check_symbol_exists(closedir "sys/types.h;dirent.h" HAVE_CLOSEDIR)
 115 check_symbol_exists(opendir "sys/types.h;dirent.h" HAVE_OPENDIR)
 116 check_symbol_exists(readdir "sys/types.h;dirent.h" HAVE_READDIR)
 117 check_symbol_exists(getcwd unistd.h HAVE_GETCWD)
 118 check_symbol_exists(gettimeofday sys/time.h HAVE_GETTIMEOFDAY)
 119 check_symbol_exists(getrlimit "sys/types.h;sys/time.h;sys/resource.h" HAVE_GETRLIMIT)
 120 check_symbol_exists(rindex strings.h HAVE_RINDEX)
 121 check_symbol_exists(strchr string.h HAVE_STRCHR)
 122 check_symbol_exists(strcmp string.h HAVE_STRCMP)
 123 check_symbol_exists(strdup string.h HAVE_STRDUP)
 124 check_symbol_exists(strrchr string.h HAVE_STRRCHR)
 125 if( NOT LLVM_ON_WIN32 )
 126   check_symbol_exists(pthread_mutex_lock pthread.h HAVE_PTHREAD_MUTEX_LOCK)
 127 endif()
 128 check_symbol_exists(sbrk unistd.h HAVE_SBRK)
 129 check_symbol_exists(srand48 stdlib.h HAVE_RAND48_SRAND48)
 130 if( HAVE_RAND48_SRAND48 )
 131   check_symbol_exists(lrand48 stdlib.h HAVE_RAND48_LRAND48)
 132   if( HAVE_RAND48_LRAND48 )
 133     check_symbol_exists(drand48 stdlib.h HAVE_RAND48_DRAND48)
 134     if( HAVE_RAND48_DRAND48 )
 135       set(HAVE_RAND48 1 CACHE INTERNAL "are srand48/lrand48/drand48 available?")
 136     endif()
 137   endif()
 138 endif()
 139 check_symbol_exists(strtoll stdlib.h HAVE_STRTOLL)
 140 check_symbol_exists(strtoq stdlib.h HAVE_STRTOQ)
 141 check_symbol_exists(strerror string.h HAVE_STRERROR)
 142 check_symbol_exists(strerror_r string.h HAVE_STRERROR_R)
 143 check_symbol_exists(strerror_s string.h HAVE_STRERROR_S)
 144 check_symbol_exists(memcpy string.h HAVE_MEMCPY)
 145 check_symbol_exists(memmove string.h HAVE_MEMMOVE)
 146 check_symbol_exists(setenv stdlib.h HAVE_SETENV)
 147 if ( LLVM_ON_WIN32 )
 148   check_symbol_exists(_chsize_s io.h HAVE__CHSIZE_S)
 149 endif()
 150 if( HAVE_ARGZ_H )
 151   check_symbol_exists(argz_append argz.h HAVE_ARGZ_APPEND)
 152   check_symbol_exists(argz_create_sep argz.h HAVE_ARGZ_CREATE_SEP)
 153   check_symbol_exists(argz_insert argz.h HAVE_ARGZ_INSERT)
 154   check_symbol_exists(argz_next argz.h HAVE_ARGZ_NEXT)
 155   check_symbol_exists(argz_stringify argz.h HAVE_ARGZ_STRINGIFY)
 156 endif()
 157 if( HAVE_DLFCN_H )
 158   if( HAVE_LIBDL )
 159     list(APPEND CMAKE_REQUIRED_LIBRARIES dl)
 160   endif()
 161   check_symbol_exists(dlerror dlfcn.h HAVE_DLERROR)
 162   check_symbol_exists(dlopen dlfcn.h HAVE_DLOPEN)
 163   if( HAVE_LIBDL )
 164     list(REMOVE_ITEM CMAKE_REQUIRED_LIBRARIES dl)
 165   endif()
 166 endif()
 167
 168 check_symbol_exists(__GLIBC__ stdio.h LLVM_USING_GLIBC)
 169 if( LLVM_USING_GLIBC )
 170   add_llvm_definitions( -D_GNU_SOURCE )
 171 endif()
 172
 173 # Type checks
 174 check_type_exists(std::bidirectional_iterator<int,int> "iterator;iostream" HAVE_BI_ITERATOR)
 175 check_type_exists(std::iterator<int,int,int> iterator HAVE_STD_ITERATOR)
 176 check_type_exists(std::forward_iterator<int,int> iterator HAVE_FWD_ITERATOR)
 177
 178 set(headers "")
 179 if (HAVE_SYS_TYPES_H)
 180   set(headers ${headers} "sys/types.h")
 181 endif()
 182
 183 if (HAVE_INTTYPES_H)
 184   set(headers ${headers} "inttypes.h")
 185 endif()
 186
 187 if (HAVE_STDINT_H)
 188   set(headers ${headers} "stdint.h")
 189 endif()
 190
 191 check_type_exists(int64_t "${headers}" HAVE_INT64_T)
 192 check_type_exists(uint64_t "${headers}" HAVE_UINT64_T)
 193 check_type_exists(u_int64_t "${headers}" HAVE_U_INT64_T)
 194 check_type_exists(error_t errno.h HAVE_ERROR_T)
 195
 196 # available programs checks
 197 function(llvm_find_program name)
 198   string(TOUPPER ${name} NAME)
 199   find_program(LLVM_PATH_${NAME} ${name})
 200   mark_as_advanced(LLVM_PATH_${NAME})
 201   if(LLVM_PATH_${NAME})
 202     set(HAVE_${NAME} 1 CACHE INTERNAL "Is ${name} available ?")
 203     mark_as_advanced(HAVE_${NAME})
 204   else(LLVM_PATH_${NAME})
 205     set(HAVE_${NAME} "" CACHE INTERNAL "Is ${name} available ?")
 206   endif(LLVM_PATH_${NAME})
 207 endfunction()
 208
 209 llvm_find_program(gv)
 210 llvm_find_program(circo)
 211 llvm_find_program(twopi)
 212 llvm_find_program(neato)
 213 llvm_find_program(fdp)
 214 llvm_find_program(dot)
 215 llvm_find_program(dotty)
 216
 217 if( LLVM_ENABLE_FFI )
 218   find_path(FFI_INCLUDE_PATH ffi.h PATHS ${FFI_INCLUDE_DIR})
 219   if( FFI_INCLUDE_PATH )
 220     set(FFI_HEADER ffi.h CACHE INTERNAL "")
 221     set(HAVE_FFI_H 1 CACHE INTERNAL "")
 222   else()
 223     find_path(FFI_INCLUDE_PATH ffi/ffi.h PATHS ${FFI_INCLUDE_DIR})
 224     if( FFI_INCLUDE_PATH )
 225       set(FFI_HEADER ffi/ffi.h CACHE INTERNAL "")
 226       set(HAVE_FFI_FFI_H 1 CACHE INTERNAL "")
 227     endif()
 228   endif()
 229
 230   if( NOT FFI_HEADER )
 231     message(FATAL_ERROR "libffi includes are not found.")
 232   endif()
 233
 234   find_library(FFI_LIBRARY_PATH ffi PATHS ${FFI_LIBRARY_DIR})
 235   if( NOT FFI_LIBRARY_PATH )
 236     message(FATAL_ERROR "libffi is not found.")
 237   endif()
 238
 239   list(APPEND CMAKE_REQUIRED_LIBRARIES ${FFI_LIBRARY_PATH})
 240   list(APPEND CMAKE_REQUIRED_INCLUDES ${FFI_INCLUDE_PATH})
 241   check_symbol_exists(ffi_call ${FFI_HEADER} HAVE_FFI_CALL)
 242   list(REMOVE_ITEM CMAKE_REQUIRED_INCLUDES ${FFI_INCLUDE_PATH})
 243   list(REMOVE_ITEM CMAKE_REQUIRED_LIBRARIES ${FFI_LIBRARY_PATH})
 244 endif( LLVM_ENABLE_FFI )
 245
 246 # Define LLVM_MULTITHREADED if gcc atomic builtins exists.
 247 include(CheckAtomic)
 248
 249 if( LLVM_ENABLE_PIC )
 250   set(ENABLE_PIC 1)
 251 else()
 252   set(ENABLE_PIC 0)
 253 endif()
 254
 255 include(CheckCXXCompilerFlag)
 256
 257 check_cxx_compiler_flag("-Wno-variadic-macros" SUPPORTS_NO_VARIADIC_MACROS_FLAG)
 258
 259 include(GetTargetTriple)
 260 get_target_triple(LLVM_HOSTTRIPLE)
 261
 262 # FIXME: We don't distinguish the target and the host. :(
 263 set(TARGET_TRIPLE "${LLVM_HOSTTRIPLE}")
 264
 265 # Determine the native architecture.
 266 string(TOLOWER "${LLVM_TARGET_ARCH}" LLVM_NATIVE_ARCH)
 267 if( LLVM_NATIVE_ARCH STREQUAL "host" )
 268   string(REGEX MATCH "^[^-]*" LLVM_NATIVE_ARCH ${LLVM_HOSTTRIPLE})
 269 endif ()
 270
 271 if (LLVM_NATIVE_ARCH MATCHES "i[2-6]86")
 272   set(LLVM_NATIVE_ARCH X86)
 273 elseif (LLVM_NATIVE_ARCH STREQUAL "x86")
 274   set(LLVM_NATIVE_ARCH X86)
 275 elseif (LLVM_NATIVE_ARCH STREQUAL "amd64")
 276   set(LLVM_NATIVE_ARCH X86)
 277 elseif (LLVM_NATIVE_ARCH STREQUAL "x86_64")
 278   set(LLVM_NATIVE_ARCH X86)
 279 elseif (LLVM_NATIVE_ARCH MATCHES "sparc")
 280   set(LLVM_NATIVE_ARCH Sparc)
 281 elseif (LLVM_NATIVE_ARCH MATCHES "powerpc")
 282   set(LLVM_NATIVE_ARCH PowerPC)
 283 elseif (LLVM_NATIVE_ARCH MATCHES "alpha")
 284   set(LLVM_NATIVE_ARCH Alpha)
 285 elseif (LLVM_NATIVE_ARCH MATCHES "arm")
 286   set(LLVM_NATIVE_ARCH ARM)
 287 elseif (LLVM_NATIVE_ARCH MATCHES "mips")
 288   set(LLVM_NATIVE_ARCH Mips)
 289 elseif (LLVM_NATIVE_ARCH MATCHES "xcore")
 290   set(LLVM_NATIVE_ARCH XCore)
 291 elseif (LLVM_NATIVE_ARCH MATCHES "msp430")
 292   set(LLVM_NATIVE_ARCH MSP430)
 293 else ()
 294   message(STATUS
 295     "Unknown architecture ${LLVM_NATIVE_ARCH}; lli will not JIT code")
 296   set(LLVM_NATIVE_ARCH)
 297 endif ()
 298
 299 if (LLVM_NATIVE_ARCH)
 300   list(FIND LLVM_TARGETS_TO_BUILD ${LLVM_NATIVE_ARCH} NATIVE_ARCH_IDX)
 301   if (NATIVE_ARCH_IDX EQUAL -1)
 302     message(STATUS
 303       "Native target ${LLVM_NATIVE_ARCH} is not selected; lli will not JIT code")
 304     set(LLVM_NATIVE_ARCH)
 305   else ()
 306     message(STATUS "Native target architecture is ${LLVM_NATIVE_ARCH}")
 307     set(LLVM_NATIVE_TARGET LLVMInitialize${LLVM_NATIVE_ARCH}Target)
 308     set(LLVM_NATIVE_TARGETINFO LLVMInitialize${LLVM_NATIVE_ARCH}TargetInfo)
 309     set(LLVM_NATIVE_ASMPRINTER LLVMInitialize${LLVM_NATIVE_ARCH}AsmPrinter)
 310   endif ()
 311 endif()
 312
 313 if( MINGW )
 314   set(HAVE_LIBIMAGEHLP 1)
 315   set(HAVE_LIBPSAPI 1)
 316   # TODO: Check existence of libraries.
 317   #   include(CheckLibraryExists)
 318   #   CHECK_LIBRARY_EXISTS(imagehlp ??? . HAVE_LIBIMAGEHLP)
 319 endif( MINGW )
 320
 321 if( MSVC )
 322   set(error_t int)
 323   set(mode_t "unsigned short")
 324   set(LTDL_SHLIBPATH_VAR "PATH")
 325   set(LTDL_SYSSEARCHPATH "")
 326   set(LTDL_DLOPEN_DEPLIBS 1)
 327   set(SHLIBEXT ".lib")
 328   set(LTDL_OBJDIR "_libs")
 329   set(HAVE_STRTOLL 1)
 330   set(strtoll "_strtoi64")
 331   set(strtoull "_strtoui64")
 332   set(stricmp "_stricmp")
 333   set(strdup "_strdup")
 334 else( MSVC )
 335   set(LTDL_SHLIBPATH_VAR "LD_LIBRARY_PATH")
 336   set(LTDL_SYSSEARCHPATH "") # TODO
 337   set(LTDL_DLOPEN_DEPLIBS 0)  # TODO
 338 endif( MSVC )
 339
 340 # FIXME: Signal handler return type, currently hardcoded to 'void'
 341 set(RETSIGTYPE void)
 342
 343 if( LLVM_ENABLE_THREADS )
 344   if( HAVE_PTHREAD_H OR WIN32 )
 345     set(ENABLE_THREADS 1)
 346   endif()
 347 endif()
 348
 349 if( ENABLE_THREADS )
 350   message(STATUS "Threads enabled.")
 351 else( ENABLE_THREADS )
 352   message(STATUS "Threads disabled.")
 353 endif()
 354
 355 set(LLVM_PREFIX ${CMAKE_INSTALL_PREFIX})
 356
 357 configure_file(
 358   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/config.h.cmake
 359   ${LLVM_BINARY_DIR}/include/llvm/Config/config.h
 360   )
 361
 362 configure_file(
 363   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Config/llvm-config.h.cmake
 364   ${LLVM_BINARY_DIR}/include/llvm/Config/llvm-config.h
 365   )
 366
 367 configure_file(
 368   ${LLVM_MAIN_INCLUDE_DIR}/llvm/Support/DataTypes.h.cmake
 369   ${LLVM_BINARY_DIR}/include/llvm/Support/DataTypes.h
 370   )
 371