cmake/config-ix.cmake

   1 if( WIN32 AND NOT CYGWIN )
   2   # We consider Cygwin as another Unix
   3   set(PURE_WINDOWS 1)
   4 endif()
   5
   6 include(CheckIncludeFile)
   7 include(CheckIncludeFileCXX)
   8 include(CheckLibraryExists)
   9 include(CheckSymbolExists)
  10 include(CheckFunctionExists)
  11 include(CheckCXXSourceCompiles)
  12 include(TestBigEndian)
  13
  14 if( UNIX AND NOT BEOS )
  15   # Used by check_symbol_exists:
  16   set(CMAKE_REQUIRED_LIBRARIES m)
  17 endif()
  18
  19 # Helper macros and functions
  20 macro(add_cxx_include result files)
  21   set(${result} "")
  22   foreach (file_name ${files})
  23      set(${result} "${${result}}#include<${file_name}>\n")
  24   endforeach()
  25 endmacro(add_cxx_include files result)
  26
  27 function(check_type_exists type files variable)
  28   add_cxx_include(includes "${files}")
  29   CHECK_CXX_SOURCE_COMPILES("
  30     ${includes} ${type} typeVar;
  31     int main() {
  32         return 0;
  33     }
  34     " ${variable})
  35 endfunction()
  36
  37 # include checks
  38 check_include_file_cxx(cxxabi.h HAVE_CXXABI_H)
  39 check_include_file(dirent.h HAVE_DIRENT_H)
  40 check_include_file(dlfcn.h HAVE_DLFCN_H)
  41 check_include_file(errno.h HAVE_ERRNO_H)
  42 check_include_file(execinfo.h HAVE_EXECINFO_H)
  43 check_include_file(fcntl.h HAVE_FCNTL_H)
  44 check_include_file(inttypes.h HAVE_INTTYPES_H)
  45 check_include_file(limits.h HAVE_LIMITS_H)
  46 check_include_file(malloc.h HAVE_MALLOC_H)
  47 check_include_file(malloc/malloc.h HAVE_MALLOC_MALLOC_H)
  48 check_include_file(ndir.h HAVE_NDIR_H)
  49 if( NOT PURE_WINDOWS )
  50   check_include_file(pthread.h HAVE_PTHREAD_H)
  51 endif()
  52 check_include_file(sanitizer/msan_interface.h HAVE_SANITIZER_MSAN_INTERFACE_H)
  53 check_include_file(signal.h HAVE_SIGNAL_H)
  54 check_include_file(stdint.h HAVE_STDINT_H)
  55 check_include_file(sys/dir.h HAVE_SYS_DIR_H)
  56 check_include_file(sys/ioctl.h HAVE_SYS_IOCTL_H)
  57 check_include_file(sys/mman.h HAVE_SYS_MMAN_H)
  58 check_include_file(sys/ndir.h HAVE_SYS_NDIR_H)
  59 check_include_file(sys/param.h HAVE_SYS_PARAM_H)
  60 check_include_file(sys/resource.h HAVE_SYS_RESOURCE_H)
  61 check_include_file(sys/stat.h HAVE_SYS_STAT_H)
  62 check_include_file(sys/time.h HAVE_SYS_TIME_H)
  63 check_include_file(sys/uio.h HAVE_SYS_UIO_H)
  64 check_include_file(sys/wait.h HAVE_SYS_WAIT_H)
  65 check_include_file(termios.h HAVE_TERMIOS_H)
  66 check_include_file(unistd.h HAVE_UNISTD_H)
  67 check_include_file(utime.h HAVE_UTIME_H)
  68 check_include_file(valgrind/valgrind.h HAVE_VALGRIND_VALGRIND_H)
  69 check_include_file(zlib.h HAVE_ZLIB_H)
  70 check_include_file(fenv.h HAVE_FENV_H)
  71 check_symbol_exists(FE_ALL_EXCEPT "fenv.h" HAVE_DECL_FE_ALL_EXCEPT)
  72 check_symbol_exists(FE_INEXACT "fenv.h" HAVE_DECL_FE_INEXACT)
  73
  74 check_include_file(mach/mach.h HAVE_MACH_MACH_H)
  75 check_include_file(mach-o/dyld.h HAVE_MACH_O_DYLD_H)
  76
  77 check_include_file(curses.h HAVE_CURSES_H)
  78 check_include_file(ncurses.h HAVE_NCURSES_H)
  79 check_include_file(ncursesw.h HAVE_NCURSESW_H)
  80 check_include_file(ncurses/curses.h HAVE_NCURSES_CURSES_H)
  81 check_include_file(ncursesw/curses.h HAVE_NCURSESW_CURSES_H)
  82
  83 # library checks
  84 if( NOT PURE_WINDOWS )
  85   check_library_exists(pthread pthread_create "" HAVE_LIBPTHREAD)
  86   if (HAVE_LIBPTHREAD)
  87     check_library_exists(pthread pthread_getspecific "" HAVE_PTHREAD_GETSPECIFIC)
  88     check_library_exists(pthread pthread_rwlock_init "" HAVE_PTHREAD_RWLOCK_INIT)
  89     check_library_exists(pthread pthread_mutex_lock "" HAVE_PTHREAD_MUTEX_LOCK)
  90   else()
  91     # this could be Android
  92     check_library_exists(c pthread_create "" PTHREAD_IN_LIBC)
  93     if (PTHREAD_IN_LIBC)
  94       check_library_exists(c pthread_getspecific "" HAVE_PTHREAD_GETSPECIFIC)
  95       check_library_exists(c pthread_rwlock_init "" HAVE_PTHREAD_RWLOCK_INIT)
  96       check_library_exists(c pthread_mutex_lock "" HAVE_PTHREAD_MUTEX_LOCK)
  97     endif()
  98   endif()
  99   check_library_exists(dl dlopen "" HAVE_LIBDL)
 100   check_library_exists(rt clock_gettime "" HAVE_LIBRT)
 101   if (LLVM_ENABLE_ZLIB)
 102     check_library_exists(z compress2 "" HAVE_LIBZ)
 103   else()
 104     set(HAVE_LIBZ 0)
 105   endif()
 106   if(LLVM_ENABLE_CURSES)
 107     check_library_exists(curses has_colors "" HAVE_CURSES)
 108     if(NOT HAVE_CURSES)
 109       check_library_exists(ncurses has_colors "" HAVE_NCURSES)
 110       set(HAVE_CURSES ${HAVE_NCURSES})
 111       if(NOT HAVE_CURSES)
 112         check_library_exists(ncursesw has_colors "" HAVE_NCURSESW)
 113         set(HAVE_CURSES ${HAVE_NCURSESW})
 114       endif()
 115     endif()
 116   else()
 117     set(HAVE_CURSES 0)
 118   endif()
 119 endif()
 120
 121 # function checks
 122 check_symbol_exists(arc4random "stdlib.h" HAVE_ARC4RANDOM)
 123 check_symbol_exists(backtrace "execinfo.h" HAVE_BACKTRACE)
 124 check_symbol_exists(getpagesize unistd.h HAVE_GETPAGESIZE)
 125 check_symbol_exists(getrusage sys/resource.h HAVE_GETRUSAGE)
 126 check_symbol_exists(setrlimit sys/resource.h HAVE_SETRLIMIT)
 127 check_symbol_exists(isatty unistd.h HAVE_ISATTY)
 128 check_symbol_exists(isinf cmath HAVE_ISINF_IN_CMATH)
 129 check_symbol_exists(isinf math.h HAVE_ISINF_IN_MATH_H)
 130 check_symbol_exists(finite ieeefp.h HAVE_FINITE_IN_IEEEFP_H)
 131 check_symbol_exists(isnan cmath HAVE_ISNAN_IN_CMATH)
 132 check_symbol_exists(isnan math.h HAVE_ISNAN_IN_MATH_H)
 133 check_symbol_exists(ceilf math.h HAVE_CEILF)
 134 check_symbol_exists(floorf math.h HAVE_FLOORF)
 135 check_symbol_exists(fmodf math.h HAVE_FMODF)
 136 check_symbol_exists(log math.h HAVE_LOG)
 137 check_symbol_exists(log2 math.h HAVE_LOG2)
 138 check_symbol_exists(log10 math.h HAVE_LOG10)
 139 check_symbol_exists(exp math.h HAVE_EXP)
 140 check_symbol_exists(exp2 math.h HAVE_EXP2)
 141 check_symbol_exists(exp10 math.h HAVE_EXP10)
 142 check_symbol_exists(futimens sys/stat.h HAVE_FUTIMENS)
 143 check_symbol_exists(futimes sys/time.h HAVE_FUTIMES)
 144 if( HAVE_SETJMP_H )
 145   check_symbol_exists(longjmp setjmp.h HAVE_LONGJMP)
 146   check_symbol_exists(setjmp setjmp.h HAVE_SETJMP)
 147   check_symbol_exists(siglongjmp setjmp.h HAVE_SIGLONGJMP)
 148   check_symbol_exists(sigsetjmp setjmp.h HAVE_SIGSETJMP)
 149 endif()
 150 if( HAVE_SYS_UIO_H )
 151   check_symbol_exists(writev sys/uio.h HAVE_WRITEV)
 152 endif()
 153 check_symbol_exists(nearbyintf math.h HAVE_NEARBYINTF)
 154 check_symbol_exists(mallinfo malloc.h HAVE_MALLINFO)
 155 check_symbol_exists(malloc_zone_statistics malloc/malloc.h
 156                     HAVE_MALLOC_ZONE_STATISTICS)
 157 check_symbol_exists(mkdtemp "stdlib.h;unistd.h" HAVE_MKDTEMP)
 158 check_symbol_exists(mkstemp "stdlib.h;unistd.h" HAVE_MKSTEMP)
 159 check_symbol_exists(mktemp "stdlib.h;unistd.h" HAVE_MKTEMP)
 160 check_symbol_exists(closedir "sys/types.h;dirent.h" HAVE_CLOSEDIR)
 161 check_symbol_exists(opendir "sys/types.h;dirent.h" HAVE_OPENDIR)
 162 check_symbol_exists(readdir "sys/types.h;dirent.h" HAVE_READDIR)
 163 check_symbol_exists(getcwd unistd.h HAVE_GETCWD)
 164 check_symbol_exists(gettimeofday sys/time.h HAVE_GETTIMEOFDAY)
 165 check_symbol_exists(getrlimit "sys/types.h;sys/time.h;sys/resource.h" HAVE_GETRLIMIT)
 166 check_symbol_exists(posix_spawn spawn.h HAVE_POSIX_SPAWN)
 167 check_symbol_exists(pread unistd.h HAVE_PREAD)
 168 check_symbol_exists(sbrk unistd.h HAVE_SBRK)
 169 check_symbol_exists(srand48 stdlib.h HAVE_RAND48_SRAND48)
 170 if( HAVE_RAND48_SRAND48 )
 171   check_symbol_exists(lrand48 stdlib.h HAVE_RAND48_LRAND48)
 172   if( HAVE_RAND48_LRAND48 )
 173     check_symbol_exists(drand48 stdlib.h HAVE_RAND48_DRAND48)
 174     if( HAVE_RAND48_DRAND48 )
 175       set(HAVE_RAND48 1 CACHE INTERNAL "are srand48/lrand48/drand48 available?")
 176     endif()
 177   endif()
 178 endif()
 179 check_symbol_exists(strtoll stdlib.h HAVE_STRTOLL)
 180 check_symbol_exists(strtoq stdlib.h HAVE_STRTOQ)
 181 check_symbol_exists(strerror string.h HAVE_STRERROR)
 182 check_symbol_exists(strerror_r string.h HAVE_STRERROR_R)
 183 check_symbol_exists(strerror_s string.h HAVE_DECL_STRERROR_S)
 184 check_symbol_exists(setenv stdlib.h HAVE_SETENV)
 185 if( PURE_WINDOWS )
 186   check_symbol_exists(_chsize_s io.h HAVE__CHSIZE_S)
 187
 188   check_function_exists(_alloca HAVE__ALLOCA)
 189   check_function_exists(__alloca HAVE___ALLOCA)
 190   check_function_exists(__chkstk HAVE___CHKSTK)
 191   check_function_exists(___chkstk HAVE____CHKSTK)
 192
 193   check_function_exists(__ashldi3 HAVE___ASHLDI3)
 194   check_function_exists(__ashrdi3 HAVE___ASHRDI3)
 195   check_function_exists(__divdi3 HAVE___DIVDI3)
 196   check_function_exists(__fixdfdi HAVE___FIXDFDI)
 197   check_function_exists(__fixsfdi HAVE___FIXSFDI)
 198   check_function_exists(__floatdidf HAVE___FLOATDIDF)
 199   check_function_exists(__lshrdi3 HAVE___LSHRDI3)
 200   check_function_exists(__moddi3 HAVE___MODDI3)
 201   check_function_exists(__udivdi3 HAVE___UDIVDI3)
 202   check_function_exists(__umoddi3 HAVE___UMODDI3)
 203
 204   check_function_exists(__main HAVE___MAIN)
 205   check_function_exists(__cmpdi2 HAVE___CMPDI2)
 206 endif()
 207 if( HAVE_DLFCN_H )
 208   if( HAVE_LIBDL )
 209     list(APPEND CMAKE_REQUIRED_LIBRARIES dl)
 210   endif()
 211   check_symbol_exists(dlerror dlfcn.h HAVE_DLERROR)
 212   check_symbol_exists(dlopen dlfcn.h HAVE_DLOPEN)
 213   if( HAVE_LIBDL )
 214     list(REMOVE_ITEM CMAKE_REQUIRED_LIBRARIES dl)
 215   endif()
 216 endif()
 217
 218 check_symbol_exists(__GLIBC__ stdio.h LLVM_USING_GLIBC)
 219 if( LLVM_USING_GLIBC )
 220   add_llvm_definitions( -D_GNU_SOURCE )
 221 endif()
 222
 223 set(headers "sys/types.h")
 224
 225 if (HAVE_INTTYPES_H)
 226   set(headers ${headers} "inttypes.h")
 227 endif()
 228
 229 if (HAVE_STDINT_H)
 230   set(headers ${headers} "stdint.h")
 231 endif()
 232
 233 check_type_exists(int64_t "${headers}" HAVE_INT64_T)
 234 check_type_exists(uint64_t "${headers}" HAVE_UINT64_T)
 235 check_type_exists(u_int64_t "${headers}" HAVE_U_INT64_T)
 236
 237 # available programs checks
 238 function(llvm_find_program name)
 239   string(TOUPPER ${name} NAME)
 240   string(REGEX REPLACE "\\." "_" NAME ${NAME})
 241
 242   find_program(LLVM_PATH_${NAME} NAMES ${ARGV})
 243   mark_as_advanced(LLVM_PATH_${NAME})
 244   if(LLVM_PATH_${NAME})
 245     set(HAVE_${NAME} 1 CACHE INTERNAL "Is ${name} available ?")
 246     mark_as_advanced(HAVE_${NAME})
 247   else(LLVM_PATH_${NAME})
 248     set(HAVE_${NAME} "" CACHE INTERNAL "Is ${name} available ?")
 249   endif(LLVM_PATH_${NAME})
 250 endfunction()
 251
 252 llvm_find_program(gv)
 253 llvm_find_program(circo)
 254 llvm_find_program(twopi)
 255 llvm_find_program(neato)
 256 llvm_find_program(fdp)
 257 llvm_find_program(dot)
 258 llvm_find_program(dotty)
 259 llvm_find_program(xdot xdot.py)
 260 llvm_find_program(Graphviz)
 261
 262 if( LLVM_ENABLE_FFI )
 263   find_path(FFI_INCLUDE_PATH ffi.h PATHS ${FFI_INCLUDE_DIR})
 264   if( FFI_INCLUDE_PATH )
 265     set(FFI_HEADER ffi.h CACHE INTERNAL "")
 266     set(HAVE_FFI_H 1 CACHE INTERNAL "")
 267   else()
 268     find_path(FFI_INCLUDE_PATH ffi/ffi.h PATHS ${FFI_INCLUDE_DIR})
 269     if( FFI_INCLUDE_PATH )
 270       set(FFI_HEADER ffi/ffi.h CACHE INTERNAL "")
 271       set(HAVE_FFI_FFI_H 1 CACHE INTERNAL "")
 272     endif()
 273   endif()
 274
 275   if( NOT FFI_HEADER )
 276     message(FATAL_ERROR "libffi includes are not found.")
 277   endif()
 278
 279   find_library(FFI_LIBRARY_PATH ffi PATHS ${FFI_LIBRARY_DIR})
 280   if( NOT FFI_LIBRARY_PATH )
 281     message(FATAL_ERROR "libffi is not found.")
 282   endif()
 283
 284   list(APPEND CMAKE_REQUIRED_LIBRARIES ${FFI_LIBRARY_PATH})
 285   list(APPEND CMAKE_REQUIRED_INCLUDES ${FFI_INCLUDE_PATH})
 286   check_symbol_exists(ffi_call ${FFI_HEADER} HAVE_FFI_CALL)
 287   list(REMOVE_ITEM CMAKE_REQUIRED_INCLUDES ${FFI_INCLUDE_PATH})
 288   list(REMOVE_ITEM CMAKE_REQUIRED_LIBRARIES ${FFI_LIBRARY_PATH})
 289 else()
 290   unset(HAVE_FFI_FFI_H CACHE)
 291   unset(HAVE_FFI_H CACHE)
 292   unset(HAVE_FFI_CALL CACHE)
 293 endif( LLVM_ENABLE_FFI )
 294
 295 # Define LLVM_HAS_ATOMICS if gcc or MSVC atomic builtins are supported.
 296 include(CheckAtomic)
 297
 298 if( LLVM_ENABLE_PIC )
 299   set(ENABLE_PIC 1)
 300 else()
 301   set(ENABLE_PIC 0)
 302 endif()
 303
 304 find_package(LibXml2)
 305 if (LIBXML2_FOUND)
 306   set(CLANG_HAVE_LIBXML 1)
 307 endif ()
 308
 309 include(CheckCXXCompilerFlag)
 310
 311 check_cxx_compiler_flag("-Wno-variadic-macros" SUPPORTS_NO_VARIADIC_MACROS_FLAG)
 312
 313 set(USE_NO_MAYBE_UNINITIALIZED 0)
 314 set(USE_NO_UNINITIALIZED 0)
 315
 316 # Disable gcc's potentially uninitialized use analysis as it presents lots of
 317 # false positives.
 318 if (CMAKE_COMPILER_IS_GNUCXX)
 319   check_cxx_compiler_flag("-Wmaybe-uninitialized" HAS_MAYBE_UNINITIALIZED)
 320   if (HAS_MAYBE_UNINITIALIZED)
 321     set(USE_NO_MAYBE_UNINITIALIZED 1)
 322   else()
 323     # Only recent versions of gcc make the distinction between -Wuninitialized
 324     # and -Wmaybe-uninitialized. If -Wmaybe-uninitialized isn't supported, just
 325     # turn off all uninitialized use warnings.
 326     check_cxx_compiler_flag("-Wuninitialized" HAS_UNINITIALIZED)
 327     set(USE_NO_UNINITIALIZED ${HAS_UNINITIALIZED})
 328   endif()
 329 endif()
 330
 331 # By default, we target the host, but this can be overridden at CMake
 332 # invocation time.
 333 include(GetHostTriple)
 334 get_host_triple(LLVM_INFERRED_HOST_TRIPLE)
 335
 336 set(LLVM_HOST_TRIPLE "${LLVM_INFERRED_HOST_TRIPLE}" CACHE STRING
 337     "Host on which LLVM binaries will run")
 338
 339 # Determine the native architecture.
 340 string(TOLOWER "${LLVM_TARGET_ARCH}" LLVM_NATIVE_ARCH)
 341 if( LLVM_NATIVE_ARCH STREQUAL "host" )
 342   string(REGEX MATCH "^[^-]*" LLVM_NATIVE_ARCH ${LLVM_HOST_TRIPLE})
 343 endif ()
 344
 345 if (LLVM_NATIVE_ARCH MATCHES "i[2-6]86")
 346   set(LLVM_NATIVE_ARCH X86)
 347 elseif (LLVM_NATIVE_ARCH STREQUAL "x86")
 348   set(LLVM_NATIVE_ARCH X86)
 349 elseif (LLVM_NATIVE_ARCH STREQUAL "amd64")
 350   set(LLVM_NATIVE_ARCH X86)
 351 elseif (LLVM_NATIVE_ARCH STREQUAL "x86_64")
 352   set(LLVM_NATIVE_ARCH X86)
 353 elseif (LLVM_NATIVE_ARCH MATCHES "sparc")
 354   set(LLVM_NATIVE_ARCH Sparc)
 355 elseif (LLVM_NATIVE_ARCH MATCHES "powerpc")
 356   set(LLVM_NATIVE_ARCH PowerPC)
 357 elseif (LLVM_NATIVE_ARCH MATCHES "aarch64")
 358   set(LLVM_NATIVE_ARCH AArch64)
 359 elseif (LLVM_NATIVE_ARCH MATCHES "arm")
 360   set(LLVM_NATIVE_ARCH ARM)
 361 elseif (LLVM_NATIVE_ARCH MATCHES "mips")
 362   set(LLVM_NATIVE_ARCH Mips)
 363 elseif (LLVM_NATIVE_ARCH MATCHES "xcore")
 364   set(LLVM_NATIVE_ARCH XCore)
 365 elseif (LLVM_NATIVE_ARCH MATCHES "msp430")
 366   set(LLVM_NATIVE_ARCH MSP430)
 367 elseif (LLVM_NATIVE_ARCH MATCHES "hexagon")
 368   set(LLVM_NATIVE_ARCH Hexagon)
 369 elseif (LLVM_NATIVE_ARCH MATCHES "s390x")
 370   set(LLVM_NATIVE_ARCH SystemZ)
 371 else ()
 372   message(FATAL_ERROR "Unknown architecture ${LLVM_NATIVE_ARCH}")
 373 endif ()
 374
 375 # If build targets includes "host", then replace with native architecture.
 376 list(FIND LLVM_TARGETS_TO_BUILD "host" idx)
 377 if( NOT idx LESS 0 )
 378   list(REMOVE_AT LLVM_TARGETS_TO_BUILD ${idx})
 379   list(APPEND LLVM_TARGETS_TO_BUILD ${LLVM_NATIVE_ARCH})
 380   list(REMOVE_DUPLICATES LLVM_TARGETS_TO_BUILD)
 381 endif()
 382
 383 list(FIND LLVM_TARGETS_TO_BUILD ${LLVM_NATIVE_ARCH} NATIVE_ARCH_IDX)
 384 if (NATIVE_ARCH_IDX EQUAL -1)
 385   message(STATUS
 386     "Native target ${LLVM_NATIVE_ARCH} is not selected; lli will not JIT code")
 387 else ()
 388   message(STATUS "Native target architecture is ${LLVM_NATIVE_ARCH}")
 389   set(LLVM_NATIVE_TARGET LLVMInitialize${LLVM_NATIVE_ARCH}Target)
 390   set(LLVM_NATIVE_TARGETINFO LLVMInitialize${LLVM_NATIVE_ARCH}TargetInfo)
 391   set(LLVM_NATIVE_TARGETMC LLVMInitialize${LLVM_NATIVE_ARCH}TargetMC)
 392   set(LLVM_NATIVE_ASMPRINTER LLVMInitialize${LLVM_NATIVE_ARCH}AsmPrinter)
 393
 394   # We don't have an ASM parser for all architectures yet.
 395   if (EXISTS ${CMAKE_SOURCE_DIR}/lib/Target/${LLVM_NATIVE_ARCH}/AsmParser/CMakeLists.txt)
 396     set(LLVM_NATIVE_ASMPARSER LLVMInitialize${LLVM_NATIVE_ARCH}AsmParser)
 397   endif ()
 398
 399   # We don't have an disassembler for all architectures yet.
 400   if (EXISTS ${CMAKE_SOURCE_DIR}/lib/Target/${LLVM_NATIVE_ARCH}/Disassembler/CMakeLists.txt)
 401     set(LLVM_NATIVE_DISASSEMBLER LLVMInitialize${LLVM_NATIVE_ARCH}Disassembler)
 402   endif ()
 403 endif ()
 404
 405 if( MINGW )
 406   set(HAVE_LIBIMAGEHLP 1)
 407   set(HAVE_LIBPSAPI 1)
 408   # TODO: Check existence of libraries.
 409   #   include(CheckLibraryExists)
 410   #   CHECK_LIBRARY_EXISTS(imagehlp ??? . HAVE_LIBIMAGEHLP)
 411 endif( MINGW )
 412
 413 if (NOT HAVE_STRTOLL)
 414   # Use _strtoi64 if strtoll is not available.
 415   check_symbol_exists(_strtoi64 stdlib.h have_strtoi64)
 416   if (have_strtoi64)
 417     set(HAVE_STRTOLL 1)
 418     set(strtoll "_strtoi64")
 419     set(strtoull "_strtoui64")
 420   endif ()
 421 endif ()
 422
 423 if( MSVC )
 424   set(SHLIBEXT ".lib")
 425   set(stricmp "_stricmp")
 426   set(strdup "_strdup")
 427 endif( MSVC )
 428
 429 if( PURE_WINDOWS )
 430   CHECK_CXX_SOURCE_COMPILES("
 431     #include <windows.h>
 432     #include <imagehlp.h>
 433     extern \"C\" void foo(PENUMLOADED_MODULES_CALLBACK);
 434     extern \"C\" void foo(BOOL(CALLBACK*)(PCSTR,ULONG_PTR,ULONG,PVOID));
 435     int main(){return 0;}"
 436     HAVE_ELMCB_PCSTR)
 437   if( HAVE_ELMCB_PCSTR )
 438     set(WIN32_ELMCB_PCSTR "PCSTR")
 439   else()
 440     set(WIN32_ELMCB_PCSTR "PSTR")
 441   endif()
 442 endif( PURE_WINDOWS )
 443
 444 # FIXME: Signal handler return type, currently hardcoded to 'void'
 445 set(RETSIGTYPE void)
 446
 447 if( LLVM_ENABLE_THREADS )
 448   # Check if threading primitives aren't supported on this platform
 449   if( NOT HAVE_PTHREAD_H AND NOT WIN32 )
 450     set(LLVM_ENABLE_THREADS 0)
 451   endif()
 452 endif()
 453
 454 if( LLVM_ENABLE_THREADS )
 455   message(STATUS "Threads enabled.")
 456 else( LLVM_ENABLE_THREADS )
 457   message(STATUS "Threads disabled.")
 458 endif()
 459
 460 if (LLVM_ENABLE_ZLIB )
 461   # Check if zlib is available in the system.
 462   if ( NOT HAVE_ZLIB_H OR NOT HAVE_LIBZ )
 463     set(LLVM_ENABLE_ZLIB 0)
 464   endif()
 465 endif()
 466
 467 set(LLVM_PREFIX ${CMAKE_INSTALL_PREFIX})