autoconf/configure.ac

   1 dnl === configure.ac --------------------------------------------------------===
   2 dnl                     The LLVM Compiler Infrastructure
   3 dnl
   4 dnl This file is distributed under the University of Illinois Open Source
   5 dnl License. See LICENSE.TXT for details.
   6 dnl
   7 dnl===-----------------------------------------------------------------------===
   8 dnl This is the LLVM configuration script. It is processed by the autoconf
   9 dnl program to produce a script named configure. This script contains the
  10 dnl configuration checks that LLVM needs in order to support multiple platforms.
  11 dnl This file is composed of 10 sections per the recommended organization of
  12 dnl autoconf input defined in the autoconf documentation. As this file evolves,
  13 dnl please keep the various types of checks within their sections. The sections
  14 dnl are as follows:
  15 dnl
  16 dnl SECTION 1: Initialization & Setup
  17 dnl SECTION 2: Architecture, target, and host checks
  18 dnl SECTION 3: Command line arguments for the configure script.
  19 dnl SECTION 4: Check for programs we need and that they are the right version
  20 dnl SECTION 5: Check for libraries
  21 dnl SECTION 6: Check for header files
  22 dnl SECTION 7: Check for types and structures
  23 dnl SECTION 8: Check for specific functions needed
  24 dnl SECTION 9: Additional checks, variables, etc.
  25 dnl SECTION 10: Specify the output files and generate it
  26 dnl
  27 dnl===-----------------------------------------------------------------------===
  28 dnl===
  29 dnl=== SECTION 1: Initialization & Setup
  30 dnl===
  31 dnl===-----------------------------------------------------------------------===
  32 dnl Initialize autoconf and define the package name, version number and
  33 dnl address for reporting bugs.
  34 AC_INIT([LLVM],[3.5svn],[http://llvm.org/bugs/])
  35 LLVM_DEFINE_SUBST([LLVM_VERSION_MAJOR], [3], [Major version of the LLVM API])
  36 LLVM_DEFINE_SUBST([LLVM_VERSION_MINOR], [5], [Minor version of the LLVM API])
  37
  38 dnl Provide a copyright substitution and ensure the copyright notice is included
  39 dnl in the output of --version option of the generated configure script.
  40 AC_SUBST(LLVM_COPYRIGHT,["Copyright (c) 2003-2014 University of Illinois at Urbana-Champaign."])
  41 AC_COPYRIGHT([Copyright (c) 2003-2014 University of Illinois at Urbana-Champaign.])
  42
  43 dnl Indicate that we require autoconf 2.60 or later.
  44 AC_PREREQ(2.60)
  45
  46 dnl Verify that the source directory is valid. This makes sure that we are
  47 dnl configuring LLVM and not some other package (it validates --srcdir argument)
  48 AC_CONFIG_SRCDIR([lib/IR/Module.cpp])
  49
  50 dnl Place all of the extra autoconf files into the config subdirectory. Tell
  51 dnl various tools where the m4 autoconf macros are.
  52 AC_CONFIG_AUX_DIR([autoconf])
  53
  54 dnl Quit if the source directory has already been configured.
  55 dnl NOTE: This relies upon undocumented autoconf behavior.
  56 if test ${srcdir} != "." ; then
  57   if test -f ${srcdir}/include/llvm/Config/config.h ; then
  58     AC_MSG_ERROR([Already configured in ${srcdir}])
  59   fi
  60 fi
  61
  62 dnl Default to empty (i.e. assigning the null string to) CFLAGS and CXXFLAGS,
  63 dnl instead of the autoconf default (for example, '-g -O2' for CC=gcc).
  64 : ${CFLAGS=}
  65 : ${CXXFLAGS=}
  66
  67 dnl We need to check for the compiler up here to avoid anything else
  68 dnl starting with a different one.
  69 AC_PROG_CC(clang gcc)
  70 AC_PROG_CXX(clang++ g++)
  71 AC_PROG_CPP
  72
  73 dnl If CXX is Clang, check that it can find and parse C++ standard library
  74 dnl headers.
  75 if test "$CXX" = "clang++" ; then
  76   AC_MSG_CHECKING([whether clang works])
  77   AC_LANG_PUSH([C++])
  78   dnl Note that space between 'include' and '(' is required.  There's a broken
  79   dnl regex in aclocal that otherwise will think that we call m4's include
  80   dnl builtin.
  81   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <limits>
  82 #if __has_include (<cxxabi.h>)
  83 #include <cxxabi.h>
  84 #endif
  85 #if __has_include (<unwind.h>)
  86 #include <unwind.h>
  87 #endif
  88 ]])],
  89 [
  90   AC_MSG_RESULT([yes])
  91 ],
  92 [
  93   AC_MSG_RESULT([no])
  94   AC_MSG_ERROR([Selected compiler could not find or parse C++ standard library headers.  Rerun with CC=c-compiler CXX=c++-compiler ./configure ...])
  95 ])
  96   AC_LANG_POP([C++])
  97 fi
  98
  99 dnl Set up variables that track whether the host compiler is GCC or Clang where
 100 dnl we can effectively sanity check them. We don't try to sanity check all the
 101 dnl other possible compilers.
 102 AC_MSG_CHECKING([whether GCC or Clang is our host compiler])
 103 AC_LANG_PUSH([C++])
 104 llvm_cv_cxx_compiler=unknown
 105 AC_COMPILE_IFELSE([AC_LANG_SOURCE([[#if ! __clang__
 106                                     #error
 107                                     #endif
 108                                     ]])],
 109                   llvm_cv_cxx_compiler=clang,
 110                   [AC_COMPILE_IFELSE([AC_LANG_SOURCE([[#if ! __GNUC__
 111                                                        #error
 112                                                        #endif
 113                                                        ]])],
 114                                      llvm_cv_cxx_compiler=gcc, [])])
 115 AC_LANG_POP([C++])
 116 AC_MSG_RESULT([${llvm_cv_cxx_compiler}])
 117
 118 dnl Configure all of the projects present in our source tree. While we could
 119 dnl just AC_CONFIG_SUBDIRS on the set of directories in projects that have a
 120 dnl configure script, that usage of the AC_CONFIG_SUBDIRS macro is deprecated.
 121 dnl Instead we match on the known projects.
 122
 123 dnl
 124 dnl One tricky part of doing this is that some projects depend upon other
 125 dnl projects.  For example, several projects rely upon the LLVM test suite.
 126 dnl We want to configure those projects first so that their object trees are
 127 dnl created before running the configure scripts of projects that depend upon
 128 dnl them.
 129 dnl
 130
 131 dnl Several projects use the LLVM test suite, so configure it next.
 132 if test -d ${srcdir}/projects/test-suite ; then
 133   AC_CONFIG_SUBDIRS([projects/test-suite])
 134 fi
 135
 136 dnl llvm-test is the old name of the test-suite, kept here for backwards
 137 dnl compatibility
 138 if test -d ${srcdir}/projects/llvm-test ; then
 139   AC_CONFIG_SUBDIRS([projects/llvm-test])
 140 fi
 141
 142 dnl Some projects use poolalloc; configure that next
 143 if test -d ${srcdir}/projects/poolalloc ; then
 144   AC_CONFIG_SUBDIRS([projects/poolalloc])
 145 fi
 146
 147 if test -d ${srcdir}/projects/llvm-poolalloc ; then
 148   AC_CONFIG_SUBDIRS([projects/llvm-poolalloc])
 149 fi
 150
 151 dnl Check for all other projects
 152 for i in `ls ${srcdir}/projects`
 153 do
 154   if test -d ${srcdir}/projects/${i} ; then
 155     case ${i} in
 156       sample)       AC_CONFIG_SUBDIRS([projects/sample])    ;;
 157       safecode)     AC_CONFIG_SUBDIRS([projects/safecode]) ;;
 158       compiler-rt)       ;;
 159       test-suite)     ;;
 160       llvm-test)      ;;
 161       poolalloc)      ;;
 162       llvm-poolalloc) ;;
 163       *)
 164         AC_MSG_WARN([Unknown project (${i}) won't be configured automatically])
 165         ;;
 166     esac
 167   fi
 168 done
 169
 170 dnl Disable the build of polly, even if it is checked out into tools/polly.
 171 AC_ARG_ENABLE(polly,
 172               AS_HELP_STRING([--enable-polly],
 173                              [Use polly if available (default is YES)]),,
 174                              enableval=default)
 175 case "$enableval" in
 176   yes) AC_SUBST(ENABLE_POLLY,[1]) ;;
 177   no)  AC_SUBST(ENABLE_POLLY,[0]) ;;
 178   default) AC_SUBST(ENABLE_POLLY,[1]) ;;
 179   *) AC_MSG_ERROR([Invalid setting for --enable-polly. Use "yes" or "no"]) ;;
 180 esac
 181
 182
 183 dnl Check if polly is checked out into tools/polly and configure it if
 184 dnl available.
 185 if (test -d ${srcdir}/tools/polly) && (test $ENABLE_POLLY -eq 1) ; then
 186   AC_SUBST(LLVM_HAS_POLLY,1)
 187   AC_CONFIG_SUBDIRS([tools/polly])
 188 fi
 189
 190 dnl===-----------------------------------------------------------------------===
 191 dnl===
 192 dnl=== SECTION 2: Architecture, target, and host checks
 193 dnl===
 194 dnl===-----------------------------------------------------------------------===
 195
 196 dnl Check the target for which we're compiling and the host that will do the
 197 dnl compilations. This will tell us which LLVM compiler will be used for
 198 dnl compiling SSA into object code. This needs to be done early because
 199 dnl following tests depend on it.
 200 AC_CANONICAL_TARGET
 201
 202 dnl Determine the platform type and cache its value. This helps us configure
 203 dnl the System library to the correct build platform.
 204 AC_CACHE_CHECK([type of operating system we're going to host on],
 205                [llvm_cv_os_type],
 206 [case $host in
 207   *-*-aix*)
 208     llvm_cv_link_all_option="-Wl,--whole-archive"
 209     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 210     llvm_cv_os_type="AIX"
 211     llvm_cv_platform_type="Unix" ;;
 212   *-*-irix*)
 213     llvm_cv_link_all_option="-Wl,--whole-archive"
 214     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 215     llvm_cv_os_type="IRIX"
 216     llvm_cv_platform_type="Unix" ;;
 217   *-*-cygwin*)
 218     llvm_cv_link_all_option="-Wl,--whole-archive"
 219     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 220     llvm_cv_os_type="Cygwin"
 221     llvm_cv_platform_type="Unix" ;;
 222   *-*-darwin*)
 223     llvm_cv_link_all_option="-Wl,-all_load"
 224     llvm_cv_no_link_all_option="-Wl,-noall_load"
 225     llvm_cv_os_type="Darwin"
 226     llvm_cv_platform_type="Unix" ;;
 227   *-*-minix*)
 228     llvm_cv_link_all_option="-Wl,-all_load"
 229     llvm_cv_no_link_all_option="-Wl,-noall_load"
 230     llvm_cv_os_type="Minix"
 231     llvm_cv_platform_type="Unix" ;;
 232   *-*-freebsd*)
 233     llvm_cv_link_all_option="-Wl,--whole-archive"
 234     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 235     llvm_cv_os_type="FreeBSD"
 236     llvm_cv_platform_type="Unix" ;;
 237   *-*-kfreebsd-gnu)
 238     llvm_cv_link_all_option="-Wl,--whole-archive"
 239     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 240     llvm_cv_os_type="GNU/kFreeBSD"
 241     llvm_cv_platform_type="Unix" ;;
 242   *-*-openbsd*)
 243     llvm_cv_link_all_option="-Wl,--whole-archive"
 244     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 245     llvm_cv_os_type="OpenBSD"
 246     llvm_cv_platform_type="Unix" ;;
 247   *-*-netbsd*)
 248     llvm_cv_link_all_option="-Wl,--whole-archive"
 249     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 250     llvm_cv_os_type="NetBSD"
 251     llvm_cv_platform_type="Unix" ;;
 252   *-*-dragonfly*)
 253     llvm_cv_link_all_option="-Wl,--whole-archive"
 254     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 255     llvm_cv_os_type="DragonFly"
 256     llvm_cv_platform_type="Unix" ;;
 257   *-*-hpux*)
 258     llvm_cv_link_all_option="-Wl,--whole-archive"
 259     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 260     llvm_cv_os_type="HP-UX"
 261     llvm_cv_platform_type="Unix" ;;
 262   *-*-interix*)
 263     llvm_cv_link_all_option="-Wl,--whole-archive"
 264     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 265     llvm_cv_os_type="Interix"
 266     llvm_cv_platform_type="Unix" ;;
 267   *-*-linux*)
 268     llvm_cv_link_all_option="-Wl,--whole-archive"
 269     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 270     llvm_cv_os_type="Linux"
 271     llvm_cv_platform_type="Unix" ;;
 272   *-*-gnu*)
 273     llvm_cv_link_all_option="-Wl,--whole-archive"
 274     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 275     llvm_cv_os_type="GNU"
 276     llvm_cv_platform_type="Unix" ;;
 277   *-*-solaris*)
 278     llvm_cv_link_all_option="-Wl,-z,allextract"
 279     llvm_cv_no_link_all_option="-Wl,-z,defaultextract"
 280     llvm_cv_os_type="SunOS"
 281     llvm_cv_platform_type="Unix" ;;
 282   *-*-auroraux*)
 283     llvm_cv_link_all_option="-Wl,-z,allextract"
 284     llvm_cv_link_all_option="-Wl,-z,defaultextract"
 285     llvm_cv_os_type="AuroraUX"
 286     llvm_cv_platform_type="Unix" ;;
 287   *-*-win32*)
 288     llvm_cv_link_all_option="-Wl,--whole-archive"
 289     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 290     llvm_cv_os_type="Win32"
 291     llvm_cv_platform_type="Win32" ;;
 292   *-*-mingw*)
 293     llvm_cv_link_all_option="-Wl,--whole-archive"
 294     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 295     llvm_cv_os_type="MingW"
 296     llvm_cv_platform_type="Win32" ;;
 297   *-*-haiku*)
 298     llvm_cv_link_all_option="-Wl,--whole-archive"
 299     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 300     llvm_cv_os_type="Haiku"
 301     llvm_cv_platform_type="Unix" ;;
 302   *-unknown-eabi*)
 303     llvm_cv_link_all_option="-Wl,--whole-archive"
 304     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 305     llvm_cv_os_type="Freestanding"
 306     llvm_cv_platform_type="Unix" ;;
 307   *-unknown-elf*)
 308     llvm_cv_link_all_option="-Wl,--whole-archive"
 309     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 310     llvm_cv_os_type="Freestanding"
 311     llvm_cv_platform_type="Unix" ;;
 312   *)
 313     llvm_cv_link_all_option=""
 314     llvm_cv_no_link_all_option=""
 315     llvm_cv_os_type="Unknown"
 316     llvm_cv_platform_type="Unknown" ;;
 317 esac])
 318
 319 AC_CACHE_CHECK([type of operating system we're going to target],
 320                [llvm_cv_target_os_type],
 321 [case $target in
 322   *-*-aix*)
 323     llvm_cv_target_os_type="AIX" ;;
 324   *-*-irix*)
 325     llvm_cv_target_os_type="IRIX" ;;
 326   *-*-cygwin*)
 327     llvm_cv_target_os_type="Cygwin" ;;
 328   *-*-darwin*)
 329     llvm_cv_target_os_type="Darwin" ;;
 330   *-*-minix*)
 331     llvm_cv_target_os_type="Minix" ;;
 332   *-*-freebsd*)
 333     llvm_cv_target_os_type="FreeBSD" ;;
 334   *-*-kfreebsd-gnu)
 335     llvm_cv_target_os_type="GNU/kFreeBSD" ;;
 336   *-*-openbsd*)
 337     llvm_cv_target_os_type="OpenBSD" ;;
 338   *-*-netbsd*)
 339     llvm_cv_target_os_type="NetBSD" ;;
 340   *-*-dragonfly*)
 341     llvm_cv_target_os_type="DragonFly" ;;
 342   *-*-hpux*)
 343     llvm_cv_target_os_type="HP-UX" ;;
 344   *-*-interix*)
 345     llvm_cv_target_os_type="Interix" ;;
 346   *-*-linux*)
 347     llvm_cv_target_os_type="Linux" ;;
 348   *-*-gnu*)
 349     llvm_cv_target_os_type="GNU" ;;
 350   *-*-solaris*)
 351     llvm_cv_target_os_type="SunOS" ;;
 352   *-*-auroraux*)
 353     llvm_cv_target_os_type="AuroraUX" ;;
 354   *-*-win32*)
 355     llvm_cv_target_os_type="Win32" ;;
 356   *-*-mingw*)
 357     llvm_cv_target_os_type="MingW" ;;
 358   *-*-haiku*)
 359     llvm_cv_target_os_type="Haiku" ;;
 360   *-*-rtems*)
 361     llvm_cv_target_os_type="RTEMS" ;;
 362   *-*-nacl*)
 363     llvm_cv_target_os_type="NativeClient" ;;
 364   *-unknown-eabi*)
 365     llvm_cv_target_os_type="Freestanding" ;;
 366   *)
 367     llvm_cv_target_os_type="Unknown" ;;
 368 esac])
 369
 370 dnl Make sure we aren't attempting to configure for an unknown system
 371 if test "$llvm_cv_os_type" = "Unknown" ; then
 372   AC_MSG_ERROR([Operating system is unknown, configure can't continue])
 373 fi
 374
 375 dnl Set the "OS" Makefile variable based on the platform type so the
 376 dnl makefile can configure itself to specific build hosts
 377 AC_SUBST(OS,$llvm_cv_os_type)
 378 AC_SUBST(HOST_OS,$llvm_cv_os_type)
 379 AC_SUBST(TARGET_OS,$llvm_cv_target_os_type)
 380
 381 dnl Set the LINKALL and NOLINKALL Makefile variables based on the platform
 382 AC_SUBST(LINKALL,$llvm_cv_link_all_option)
 383 AC_SUBST(NOLINKALL,$llvm_cv_no_link_all_option)
 384
 385 dnl Set the "LLVM_ON_*" variables based on llvm_cv_platform_type
 386 dnl This is used by lib/Support to determine the basic kind of implementation
 387 dnl to use.
 388 case $llvm_cv_platform_type in
 389   Unix)
 390     AC_DEFINE([LLVM_ON_UNIX],[1],[Define if this is Unixish platform])
 391     AC_SUBST(LLVM_ON_UNIX,[1])
 392     AC_SUBST(LLVM_ON_WIN32,[0])
 393     ;;
 394   Win32)
 395     AC_DEFINE([LLVM_ON_WIN32],[1],[Define if this is Win32ish platform])
 396     AC_SUBST(LLVM_ON_UNIX,[0])
 397     AC_SUBST(LLVM_ON_WIN32,[1])
 398     ;;
 399 esac
 400
 401 dnl Determine what our target architecture is and configure accordingly.
 402 dnl This will allow Makefiles to make a distinction between the hardware and
 403 dnl the OS.
 404 AC_CACHE_CHECK([target architecture],[llvm_cv_target_arch],
 405 [case $target in
 406   i?86-*)                 llvm_cv_target_arch="x86" ;;
 407   amd64-* | x86_64-*)     llvm_cv_target_arch="x86_64" ;;
 408   sparc*-*)               llvm_cv_target_arch="Sparc" ;;
 409   powerpc*-*)             llvm_cv_target_arch="PowerPC" ;;
 410   arm*-*)                 llvm_cv_target_arch="ARM" ;;
 411   aarch64*-*)             llvm_cv_target_arch="AArch64" ;;
 412   mips-* | mips64-*)      llvm_cv_target_arch="Mips" ;;
 413   mipsel-* | mips64el-*)  llvm_cv_target_arch="Mips" ;;
 414   xcore-*)                llvm_cv_target_arch="XCore" ;;
 415   msp430-*)               llvm_cv_target_arch="MSP430" ;;
 416   hexagon-*)              llvm_cv_target_arch="Hexagon" ;;
 417   nvptx-*)                llvm_cv_target_arch="NVPTX" ;;
 418   s390x-*)                llvm_cv_target_arch="SystemZ" ;;
 419   *)                      llvm_cv_target_arch="Unknown" ;;
 420 esac])
 421
 422 if test "$llvm_cv_target_arch" = "Unknown" ; then
 423   AC_MSG_WARN([Configuring LLVM for an unknown target archicture])
 424 fi
 425
 426 dnl Determine the LLVM native architecture for the target
 427 case "$llvm_cv_target_arch" in
 428     x86)     LLVM_NATIVE_ARCH="X86" ;;
 429     x86_64)  LLVM_NATIVE_ARCH="X86" ;;
 430     *)       LLVM_NATIVE_ARCH="$llvm_cv_target_arch" ;;
 431 esac
 432
 433 dnl Define a substitution, ARCH, for the target architecture
 434 AC_SUBST(ARCH,$llvm_cv_target_arch)
 435 AC_SUBST(LLVM_NATIVE_ARCH,$LLVM_NATIVE_ARCH)
 436
 437 dnl Determine what our host architecture.
 438 dnl This will allow MCJIT regress tests runs only for supported
 439 dnl platforms.
 440 case $host in
 441   i?86-*)                 host_arch="x86" ;;
 442   amd64-* | x86_64-*)     host_arch="x86_64" ;;
 443   sparc*-*)               host_arch="Sparc" ;;
 444   powerpc*-*)             host_arch="PowerPC" ;;
 445   arm*-*)                 host_arch="ARM" ;;
 446   aarch64*-*)             host_arch="AArch64" ;;
 447   mips-* | mips64-*)      host_arch="Mips" ;;
 448   mipsel-* | mips64el-*)  host_arch="Mips" ;;
 449   xcore-*)                host_arch="XCore" ;;
 450   msp430-*)               host_arch="MSP430" ;;
 451   hexagon-*)              host_arch="Hexagon" ;;
 452   s390x-*)                host_arch="SystemZ" ;;
 453   *)                      host_arch="Unknown" ;;
 454 esac
 455
 456 if test "$host_arch" = "Unknown" ; then
 457   AC_MSG_WARN([Configuring LLVM for an unknown host archicture])
 458 fi
 459
 460 AC_SUBST(HOST_ARCH,$host_arch)
 461
 462 dnl Check for build platform executable suffix if we're cross-compiling
 463 if test "$cross_compiling" = yes; then
 464   AC_SUBST(LLVM_CROSS_COMPILING, [1])
 465   AC_BUILD_EXEEXT
 466   ac_build_prefix=${build_alias}-
 467   AC_CHECK_PROG(BUILD_CXX, ${ac_build_prefix}g++, ${ac_build_prefix}g++)
 468   if test -z "$BUILD_CXX"; then
 469      AC_CHECK_PROG(BUILD_CXX, g++, g++)
 470      if test -z "$BUILD_CXX"; then
 471        AC_CHECK_PROG(BUILD_CXX, c++, c++, , , /usr/ucb/c++)
 472      fi
 473   fi
 474 else
 475   AC_SUBST(LLVM_CROSS_COMPILING, [0])
 476 fi
 477
 478 dnl Check to see if there's a .svn or .git directory indicating that this
 479 dnl build is being done from a checkout. This sets up several defaults for
 480 dnl the command line switches. When we build with a checkout directory,
 481 dnl we get a debug with assertions turned on. Without, we assume a source
 482 dnl release and we get an optimized build without assertions.
 483 dnl See --enable-optimized and --enable-assertions below
 484 if test -d ".svn" -o -d "${srcdir}/.svn" -o -d ".git" -o -d "${srcdir}/.git"; then
 485   cvsbuild="yes"
 486   optimize="no"
 487   AC_SUBST(CVSBUILD,[[CVSBUILD=1]])
 488 else
 489   cvsbuild="no"
 490   optimize="yes"
 491 fi
 492
 493 dnl===-----------------------------------------------------------------------===
 494 dnl===
 495 dnl=== SECTION 3: Command line arguments for the configure script.
 496 dnl===
 497 dnl===-----------------------------------------------------------------------===
 498
 499 dnl --enable-libcpp : check whether or not to use libc++ on the command line
 500 AC_ARG_ENABLE(libcpp,
 501               AS_HELP_STRING([--enable-libcpp],
 502                              [Use libc++ if available (default is NO)]),,
 503                              enableval=default)
 504 case "$enableval" in
 505   yes) AC_SUBST(ENABLE_LIBCPP,[1]) ;;
 506   no)  AC_SUBST(ENABLE_LIBCPP,[0]) ;;
 507   default) AC_SUBST(ENABLE_LIBCPP,[0]);;
 508   *) AC_MSG_ERROR([Invalid setting for --enable-libcpp. Use "yes" or "no"]) ;;
 509 esac
 510
 511 dnl Check both GCC and Clang for sufficiently modern versions. These checks can
 512 dnl be bypassed by passing a flag if necessary on a platform. We have to do
 513 dnl these checks here so that we have the configuration of the standard C++
 514 dnl library finished.
 515 AC_ARG_ENABLE(compiler-version-checks,
 516               AS_HELP_STRING([--enable-compiler-version-checks],
 517                              [Check the version of the host compiler (default is YES)]),,
 518                              enableval=default)
 519 case "$enableval" in
 520   no)
 521     ;;
 522   yes|default)
 523     AC_LANG_PUSH([C++])
 524     case "$llvm_cv_cxx_compiler" in
 525     clang)
 526       AC_MSG_CHECKING([whether Clang is new enough])
 527       AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 528 #if __clang_major__ < 3 || (__clang_major__ == 3 && __clang_minor__ < 1)
 529 #error This version of Clang is too old to build LLVM
 530 #endif
 531 ]])],
 532           [AC_MSG_RESULT([yes])],
 533           [AC_MSG_RESULT([no])
 534            AC_MSG_ERROR([
 535 The selected Clang compiler is not new enough to build LLVM. Please upgrade to
 536 Clang 3.1. You may pass --disable-compiler-version-checks to configure to
 537 bypass these sanity checks.])])
 538
 539       dnl Note that libstdc++4.6 is known broken for C++11 builds. The errors
 540       dnl are sometimes deeply confusing though. Here we test for an obvious
 541       dnl incomplete feature in 4.6's standard library that was completed in
 542       dnl 4.7's. We also have to disable this test if 'ENABLE_LIBCPP' is set
 543       dnl because the enable flags don't actually fix CXXFLAGS, they rely on
 544       dnl that happening in the Makefile.
 545       if test "$ENABLE_LIBCPP" -eq 0 ; then
 546         AC_MSG_CHECKING([whether Clang will select a modern C++ standard library])
 547         llvm_cv_old_cxxflags="$CXXFLAGS"
 548         CXXFLAGS="$CXXFLAGS -std=c++0x"
 549         AC_LINK_IFELSE([AC_LANG_SOURCE([[
 550 #include <atomic>
 551 std::atomic<float> x(0.0f);
 552 int main() { return (float)x; }
 553 ]])],
 554             [AC_MSG_RESULT([yes])],
 555             [AC_MSG_RESULT([no])
 556              AC_MSG_ERROR([
 557 We detected a missing feature in the standard C++ library that was known to be
 558 missing in libstdc++4.6 and implemented in libstdc++4.7. There are numerous
 559 C++11 problems with 4.6's library, and we don't support GCCs or libstdc++ older
 560 than 4.7. You will need to update your system and ensure Clang uses the newer
 561 standard library.
 562
 563 If this error is incorrect or you need to force things to work, you may pass
 564 '--disable-compiler-version-checks' to configure to bypass this test.])])
 565         CXXFLAGS="$llvm_cv_old_cxxflags"
 566       fi
 567       ;;
 568     gcc)
 569       AC_MSG_CHECKING([whether GCC is new enough])
 570       AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 571 #if __GNUC__ < 4 || (__GNUC__ == 4 && __GNUC_MINOR__ < 7)
 572 #error This version of GCC is too old to build LLVM
 573 #endif
 574 ]])],
 575           [AC_MSG_RESULT([yes])],
 576           [AC_MSG_RESULT([no])
 577            AC_MSG_ERROR([
 578 The selected GCC C++ compiler is not new enough to build LLVM. Please upgrade
 579 to GCC 4.7. You may pass --disable-compiler-version-checks to configure to
 580 bypass these sanity checks.])])
 581       ;;
 582     unknown)
 583       ;;
 584     esac
 585     AC_LANG_POP([C++])
 586     ;;
 587   *)
 588     AC_MSG_ERROR([Invalid setting for --enable-compiler-version-checks. Use "yes" or "no"])
 589     ;;
 590 esac
 591
 592 dnl --enable-cxx11 : check whether or not to use -std=c++11 on the command line
 593 AC_ARG_ENABLE(cxx11,
 594               AS_HELP_STRING([--enable-cxx11],
 595                              [Use c++11 if available (default is NO)]),,
 596                              enableval=default)
 597 case "$enableval" in
 598   yes) AC_SUBST(ENABLE_CXX11,[1]) ;;
 599   no)  AC_SUBST(ENABLE_CXX11,[0]) ;;
 600   default) AC_SUBST(ENABLE_CXX11,[0]);;
 601   *) AC_MSG_ERROR([Invalid setting for --enable-cxx11. Use "yes" or "no"]) ;;
 602 esac
 603
 604 dnl --enable-fission : check whether or not to use -gsplit-dwarf on the command
 605 dnl line
 606 AC_ARG_ENABLE(split-dwarf,
 607               AS_HELP_STRING([--enable-split-dwarf],
 608                              [Use split-dwarf if available (default is NO)]),,
 609                              enableval=default)
 610 case "$enableval" in
 611   yes) AC_SUBST(ENABLE_SPLIT_DWARF,[1]) ;;
 612   no)  AC_SUBST(ENABLE_SPLIT_DWARF,[0]) ;;
 613   default) AC_SUBST(ENABLE_SPLIT_DWARF,[0]);;
 614   *) AC_MSG_ERROR([Invalid setting for --enable-split-dwarf. Use "yes" or "no"]) ;;
 615 esac
 616
 617 dnl --enable-clang-arcmt: check whether to enable clang arcmt
 618 clang_arcmt="yes"
 619 AC_ARG_ENABLE(clang-arcmt,
 620               AS_HELP_STRING([--enable-clang-arcmt],
 621                              [Enable building of clang ARCMT (default is YES)]),
 622                              clang_arcmt="$enableval",
 623                              enableval="yes")
 624 case "$enableval" in
 625   yes) AC_SUBST(ENABLE_CLANG_ARCMT,[1]) ;;
 626   no)  AC_SUBST(ENABLE_CLANG_ARCMT,[0]) ;;
 627   default) AC_SUBST(ENABLE_CLANG_ARCMT,[1]);;
 628   *) AC_MSG_ERROR([Invalid setting for --enable-clang-arcmt. Use "yes" or "no"]) ;;
 629 esac
 630
 631 dnl --enable-clang-static-analyzer: check whether to enable static-analyzer
 632 clang_static_analyzer="yes"
 633 AC_ARG_ENABLE(clang-static-analyzer,
 634               AS_HELP_STRING([--enable-clang-static-analyzer],
 635                              [Enable building of clang Static Analyzer (default is YES)]),
 636                              clang_static_analyzer="$enableval",
 637                              enableval="yes")
 638 case "$enableval" in
 639   yes) AC_SUBST(ENABLE_CLANG_STATIC_ANALYZER,[1]) ;;
 640   no)
 641     if test ${clang_arcmt} != "no" ; then
 642       AC_MSG_ERROR([Cannot enable clang ARC Migration Tool while disabling static analyzer.])
 643     fi
 644     AC_SUBST(ENABLE_CLANG_STATIC_ANALYZER,[0])
 645     ;;
 646   default) AC_SUBST(ENABLE_CLANG_STATIC_ANALYZER,[1]);;
 647   *) AC_MSG_ERROR([Invalid setting for --enable-clang-static-analyzer. Use "yes" or "no"]) ;;
 648 esac
 649
 650 dnl --enable-clang-rewriter: check whether to enable clang rewriter
 651 AC_ARG_ENABLE(clang-rewriter,
 652               AS_HELP_STRING([--enable-clang-rewriter],
 653                              [Enable building of clang rewriter (default is YES)]),,
 654                              enableval="yes")
 655 case "$enableval" in
 656   yes) AC_SUBST(ENABLE_CLANG_REWRITER,[1]) ;;
 657   no)
 658     if test ${clang_arcmt} != "no" ; then
 659       AC_MSG_ERROR([Cannot enable clang ARC Migration Tool while disabling rewriter.])
 660     fi
 661     if test ${clang_static_analyzer} != "no" ; then
 662       AC_MSG_ERROR([Cannot enable clang static analyzer while disabling rewriter.])
 663     fi
 664     AC_SUBST(ENABLE_CLANG_REWRITER,[0])
 665     ;;
 666   default) AC_SUBST(ENABLE_CLANG_REWRITER,[1]);;
 667   *) AC_MSG_ERROR([Invalid setting for --enable-clang-rewriter. Use "yes" or "no"]) ;;
 668 esac
 669
 670 dnl --enable-optimized : check whether they want to do an optimized build:
 671 AC_ARG_ENABLE(optimized, AS_HELP_STRING(
 672  --enable-optimized,[Compile with optimizations enabled (default is NO)]),,enableval=$optimize)
 673 if test ${enableval} = "no" ; then
 674   AC_SUBST(ENABLE_OPTIMIZED,[[]])
 675 else
 676   AC_SUBST(ENABLE_OPTIMIZED,[[ENABLE_OPTIMIZED=1]])
 677 fi
 678
 679 dnl --enable-profiling : check whether they want to do a profile build:
 680 AC_ARG_ENABLE(profiling, AS_HELP_STRING(
 681  --enable-profiling,[Compile with profiling enabled (default is NO)]),,enableval="no")
 682 if test ${enableval} = "no" ; then
 683   AC_SUBST(ENABLE_PROFILING,[[]])
 684 else
 685   AC_SUBST(ENABLE_PROFILING,[[ENABLE_PROFILING=1]])
 686 fi
 687
 688 dnl --enable-assertions : check whether they want to turn on assertions or not:
 689 AC_ARG_ENABLE(assertions,AS_HELP_STRING(
 690   --enable-assertions,[Compile with assertion checks enabled (default is YES)]),, enableval="yes")
 691 if test ${enableval} = "yes" ; then
 692   AC_SUBST(DISABLE_ASSERTIONS,[[]])
 693 else
 694   AC_SUBST(DISABLE_ASSERTIONS,[[DISABLE_ASSERTIONS=1]])
 695 fi
 696
 697 dnl --enable-werror : check whether we want Werror on by default
 698 AC_ARG_ENABLE(werror,AS_HELP_STRING(
 699   --enable-werror,[Compile with -Werror enabled (default is NO)]),, enableval="no")
 700 case "$enableval" in
 701   yes) AC_SUBST(ENABLE_WERROR,[1]) ;;
 702   no)  AC_SUBST(ENABLE_WERROR,[0]) ;;
 703   default) AC_SUBST(ENABLE_WERROR,[0]);;
 704   *) AC_MSG_ERROR([Invalid setting for --enable-werror. Use "yes" or "no"]) ;;
 705 esac
 706
 707 dnl --enable-expensive-checks : check whether they want to turn on expensive debug checks:
 708 AC_ARG_ENABLE(expensive-checks,AS_HELP_STRING(
 709   --enable-expensive-checks,[Compile with expensive debug checks enabled (default is NO)]),, enableval="no")
 710 if test ${enableval} = "yes" ; then
 711   AC_SUBST(ENABLE_EXPENSIVE_CHECKS,[[ENABLE_EXPENSIVE_CHECKS=1]])
 712   AC_SUBST(EXPENSIVE_CHECKS,[[yes]])
 713 else
 714   AC_SUBST(ENABLE_EXPENSIVE_CHECKS,[[]])
 715   AC_SUBST(EXPENSIVE_CHECKS,[[no]])
 716 fi
 717
 718 dnl --enable-debug-runtime : should runtime libraries have debug symbols?
 719 AC_ARG_ENABLE(debug-runtime,
 720    AS_HELP_STRING(--enable-debug-runtime,[Build runtime libs with debug symbols (default is NO)]),,enableval=no)
 721 if test ${enableval} = "no" ; then
 722   AC_SUBST(DEBUG_RUNTIME,[[]])
 723 else
 724   AC_SUBST(DEBUG_RUNTIME,[[DEBUG_RUNTIME=1]])
 725 fi
 726
 727 dnl --enable-debug-symbols : should even optimized compiler libraries
 728 dnl have debug symbols?
 729 AC_ARG_ENABLE(debug-symbols,
 730    AS_HELP_STRING(--enable-debug-symbols,[Build compiler with debug symbols (default is NO if optimization is on and YES if it's off)]),,enableval=no)
 731 if test ${enableval} = "no" ; then
 732   AC_SUBST(DEBUG_SYMBOLS,[[]])
 733 else
 734   AC_SUBST(DEBUG_SYMBOLS,[[DEBUG_SYMBOLS=1]])
 735 fi
 736
 737 dnl --enable-keep-symbols : do not strip installed executables
 738 AC_ARG_ENABLE(keep-symbols,
 739    AS_HELP_STRING(--enable-keep-symbols,[Do not strip installed executables)]),,enableval=no)
 740 if test ${enableval} = "no" ; then
 741   AC_SUBST(KEEP_SYMBOLS,[[]])
 742 else
 743   AC_SUBST(KEEP_SYMBOLS,[[KEEP_SYMBOLS=1]])
 744 fi
 745
 746 dnl --enable-jit: check whether they want to enable the jit
 747 AC_ARG_ENABLE(jit,
 748   AS_HELP_STRING(--enable-jit,
 749                  [Enable Just In Time Compiling (default is YES)]),,
 750   enableval=default)
 751 if test ${enableval} = "no"
 752 then
 753   AC_SUBST(JIT,[[]])
 754 else
 755   case "$llvm_cv_target_arch" in
 756     x86)         AC_SUBST(TARGET_HAS_JIT,1) ;;
 757     Sparc)       AC_SUBST(TARGET_HAS_JIT,0) ;;
 758     PowerPC)     AC_SUBST(TARGET_HAS_JIT,1) ;;
 759     x86_64)      AC_SUBST(TARGET_HAS_JIT,1) ;;
 760     ARM)         AC_SUBST(TARGET_HAS_JIT,1) ;;
 761     AArch64)     AC_SUBST(TARGET_HAS_JIT,0) ;;
 762     Mips)        AC_SUBST(TARGET_HAS_JIT,1) ;;
 763     XCore)       AC_SUBST(TARGET_HAS_JIT,0) ;;
 764     MSP430)      AC_SUBST(TARGET_HAS_JIT,0) ;;
 765     Hexagon)     AC_SUBST(TARGET_HAS_JIT,0) ;;
 766     NVPTX)       AC_SUBST(TARGET_HAS_JIT,0) ;;
 767     SystemZ)     AC_SUBST(TARGET_HAS_JIT,1) ;;
 768     *)           AC_SUBST(TARGET_HAS_JIT,0) ;;
 769   esac
 770 fi
 771
 772 TARGETS_WITH_JIT="AArch64 ARM Mips PowerPC SystemZ X86"
 773 AC_SUBST(TARGETS_WITH_JIT,$TARGETS_WITH_JIT)
 774
 775 dnl Allow enablement of building and installing docs
 776 AC_ARG_ENABLE(docs,
 777               AS_HELP_STRING([--enable-docs],
 778                              [Build documents (default is YES)]),,
 779                              enableval=default)
 780 case "$enableval" in
 781   yes) AC_SUBST(ENABLE_DOCS,[1]) ;;
 782   no)  AC_SUBST(ENABLE_DOCS,[0]) ;;
 783   default) AC_SUBST(ENABLE_DOCS,[1]) ;;
 784   *) AC_MSG_ERROR([Invalid setting for --enable-docs. Use "yes" or "no"]) ;;
 785 esac
 786
 787 dnl Allow enablement of doxygen generated documentation
 788 AC_ARG_ENABLE(doxygen,
 789               AS_HELP_STRING([--enable-doxygen],
 790                              [Build doxygen documentation (default is NO)]),,
 791                              enableval=default)
 792 case "$enableval" in
 793   yes) AC_SUBST(ENABLE_DOXYGEN,[1]) ;;
 794   no)  AC_SUBST(ENABLE_DOXYGEN,[0]) ;;
 795   default) AC_SUBST(ENABLE_DOXYGEN,[0]) ;;
 796   *) AC_MSG_ERROR([Invalid setting for --enable-doxygen. Use "yes" or "no"]) ;;
 797 esac
 798
 799 dnl Allow disablement of threads
 800 AC_ARG_ENABLE(threads,
 801               AS_HELP_STRING([--enable-threads],
 802                              [Use threads if available (default is YES)]),,
 803                              enableval=default)
 804 case "$enableval" in
 805   yes) AC_SUBST(LLVM_ENABLE_THREADS,[1]) ;;
 806   no)  AC_SUBST(LLVM_ENABLE_THREADS,[0]) ;;
 807   default) AC_SUBST(LLVM_ENABLE_THREADS,[1]) ;;
 808   *) AC_MSG_ERROR([Invalid setting for --enable-threads. Use "yes" or "no"]) ;;
 809 esac
 810 AC_DEFINE_UNQUOTED([LLVM_ENABLE_THREADS],$LLVM_ENABLE_THREADS,
 811                    [Define if threads enabled])
 812
 813 dnl Allow disablement of pthread.h
 814 AC_ARG_ENABLE(pthreads,
 815               AS_HELP_STRING([--enable-pthreads],
 816                              [Use pthreads if available (default is YES)]),,
 817                              enableval=default)
 818 case "$enableval" in
 819   yes) AC_SUBST(ENABLE_PTHREADS,[1]) ;;
 820   no)  AC_SUBST(ENABLE_PTHREADS,[0]) ;;
 821   default) AC_SUBST(ENABLE_PTHREADS,[1]) ;;
 822   *) AC_MSG_ERROR([Invalid setting for --enable-pthreads. Use "yes" or "no"]) ;;
 823 esac
 824
 825 dnl Allow disablement of zlib
 826 AC_ARG_ENABLE(zlib,
 827               AS_HELP_STRING([--enable-zlib],
 828                              [Use zlib for compression/decompression if
 829                               available (default is YES)]),,
 830                               enableval=default)
 831 case "$enableval" in
 832   yes) AC_SUBST(LLVM_ENABLE_ZLIB,[1]) ;;
 833   no)  AC_SUBST(LLVM_ENABLE_ZLIB,[0]) ;;
 834   default) AC_SUBST(LLVM_ENABLE_ZLIB,[1]) ;;
 835   *) AC_MSG_ERROR([Invalid setting for --enable-zlib. Use "yes" or "no"]) ;;
 836 esac
 837 AC_DEFINE_UNQUOTED([LLVM_ENABLE_ZLIB],$LLVM_ENABLE_ZLIB,
 838                    [Define if zlib is enabled])
 839
 840 dnl Allow building without position independent code
 841 AC_ARG_ENABLE(pic,
 842   AS_HELP_STRING([--enable-pic],
 843                  [Build LLVM with Position Independent Code (default is YES)]),,
 844                  enableval=default)
 845 case "$enableval" in
 846   yes) AC_SUBST(ENABLE_PIC,[1]) ;;
 847   no)  AC_SUBST(ENABLE_PIC,[0]) ;;
 848   default) AC_SUBST(ENABLE_PIC,[1]) ;;
 849   *) AC_MSG_ERROR([Invalid setting for --enable-pic. Use "yes" or "no"]) ;;
 850 esac
 851 AC_DEFINE_UNQUOTED([ENABLE_PIC],$ENABLE_PIC,
 852                    [Define if position independent code is enabled])
 853
 854 dnl Allow building a shared library and linking tools against it.
 855 AC_ARG_ENABLE(shared,
 856   AS_HELP_STRING([--enable-shared],
 857                  [Build a shared library and link tools against it (default is NO)]),,
 858                  enableval=default)
 859 case "$enableval" in
 860   yes) AC_SUBST(ENABLE_SHARED,[1]) ;;
 861   no)  AC_SUBST(ENABLE_SHARED,[0]) ;;
 862   default) AC_SUBST(ENABLE_SHARED,[0]) ;;
 863   *) AC_MSG_ERROR([Invalid setting for --enable-shared. Use "yes" or "no"]) ;;
 864 esac
 865
 866 dnl Allow libstdc++ is embedded in LLVM.dll.
 867 AC_ARG_ENABLE(embed-stdcxx,
 868   AS_HELP_STRING([--enable-embed-stdcxx],
 869                  [Build a shared library with embedded libstdc++ for Win32 DLL (default is NO)]),,
 870                  enableval=default)
 871 case "$enableval" in
 872   yes) AC_SUBST(ENABLE_EMBED_STDCXX,[1]) ;;
 873   no)  AC_SUBST(ENABLE_EMBED_STDCXX,[0]) ;;
 874   default) AC_SUBST(ENABLE_EMBED_STDCXX,[0]) ;;
 875   *) AC_MSG_ERROR([Invalid setting for --enable-embed-stdcxx. Use "yes" or "no"]) ;;
 876 esac
 877
 878 dnl Enable embedding timestamp information into build.
 879 AC_ARG_ENABLE(timestamps,
 880   AS_HELP_STRING([--enable-timestamps],
 881                  [Enable embedding timestamp information in build (default is YES)]),,
 882                  enableval=default)
 883 case "$enableval" in
 884   yes) AC_SUBST(ENABLE_TIMESTAMPS,[1]) ;;
 885   no)  AC_SUBST(ENABLE_TIMESTAMPS,[0]) ;;
 886   default) AC_SUBST(ENABLE_TIMESTAMPS,[1]) ;;
 887   *) AC_MSG_ERROR([Invalid setting for --enable-timestamps. Use "yes" or "no"]) ;;
 888 esac
 889 AC_DEFINE_UNQUOTED([ENABLE_TIMESTAMPS],$ENABLE_TIMESTAMPS,
 890                    [Define if timestamp information (e.g., __DATE__) is allowed])
 891
 892 dnl Enable support for showing backtraces.
 893 AC_ARG_ENABLE(backtraces, AS_HELP_STRING(
 894   [--enable-backtraces],
 895   [Enable embedding backtraces on crash (default is YES)]),
 896   [case "$enableval" in
 897     yes) llvm_cv_enable_backtraces="yes" ;;
 898     no)  llvm_cv_enable_backtraces="no"  ;;
 899     *) AC_MSG_ERROR([Invalid setting for --enable-backtraces. Use "yes" or "no"]) ;;
 900   esac],
 901   llvm_cv_enable_backtraces="yes")
 902 if test "$llvm_cv_enable_backtraces" = "yes" ; then
 903   AC_DEFINE([ENABLE_BACKTRACES],[1],
 904             [Define if you want backtraces on crash])
 905 fi
 906
 907 dnl Enable installing platform specific signal handling overrides, for improved
 908 dnl CrashRecovery support or interaction with crash reporting software. This
 909 dnl support may be inappropriate for some clients embedding LLVM as a library.
 910 AC_ARG_ENABLE(crash-overrides, AS_HELP_STRING(
 911   [--enable-crash-overrides],
 912   [Enable crash handling overrides (default is YES)]),
 913   [case "$enableval" in
 914     yes) llvm_cv_enable_crash_overrides="yes" ;;
 915     no)  llvm_cv_enable_crash_overrides="no"  ;;
 916     *) AC_MSG_ERROR([Invalid setting for --enable-crash-overrides. Use "yes" or "no"]) ;;
 917   esac],
 918   llvm_cv_enable_crash_overrides="yes")
 919 if test "$llvm_cv_enable_crash_overrides" = "yes" ; then
 920   AC_DEFINE([ENABLE_CRASH_OVERRIDES],[1],
 921             [Define to enable crash handling overrides])
 922 fi
 923
 924 dnl List all possible targets
 925 ALL_TARGETS="X86 Sparc PowerPC AArch64 ARM Mips XCore MSP430 CppBackend NVPTX Hexagon SystemZ R600"
 926 AC_SUBST(ALL_TARGETS,$ALL_TARGETS)
 927
 928 dnl Allow specific targets to be specified for building (or not)
 929 TARGETS_TO_BUILD=""
 930 AC_ARG_ENABLE([targets],AS_HELP_STRING([--enable-targets],
 931     [Build specific host targets: all or target1,target2,... Valid targets are:
 932      host, x86, x86_64, sparc, powerpc, arm, aarch64, mips, hexagon,
 933      xcore, msp430, nvptx, systemz, r600, and cpp (default=all)]),,
 934     enableval=all)
 935 if test "$enableval" = host-only ; then
 936   enableval=host
 937 fi
 938 case "$enableval" in
 939   all) TARGETS_TO_BUILD="$ALL_TARGETS" ;;
 940   *)for a_target in `echo $enableval|sed -e 's/,/ /g' ` ; do
 941       case "$a_target" in
 942         x86)      TARGETS_TO_BUILD="X86 $TARGETS_TO_BUILD" ;;
 943         x86_64)   TARGETS_TO_BUILD="X86 $TARGETS_TO_BUILD" ;;
 944         sparc)    TARGETS_TO_BUILD="Sparc $TARGETS_TO_BUILD" ;;
 945         powerpc)  TARGETS_TO_BUILD="PowerPC $TARGETS_TO_BUILD" ;;
 946         aarch64)  TARGETS_TO_BUILD="AArch64 $TARGETS_TO_BUILD" ;;
 947         arm)      TARGETS_TO_BUILD="ARM $TARGETS_TO_BUILD" ;;
 948         mips)     TARGETS_TO_BUILD="Mips $TARGETS_TO_BUILD" ;;
 949         mipsel)   TARGETS_TO_BUILD="Mips $TARGETS_TO_BUILD" ;;
 950         mips64)   TARGETS_TO_BUILD="Mips $TARGETS_TO_BUILD" ;;
 951         mips64el) TARGETS_TO_BUILD="Mips $TARGETS_TO_BUILD" ;;
 952         xcore)    TARGETS_TO_BUILD="XCore $TARGETS_TO_BUILD" ;;
 953         msp430)   TARGETS_TO_BUILD="MSP430 $TARGETS_TO_BUILD" ;;
 954         cpp)      TARGETS_TO_BUILD="CppBackend $TARGETS_TO_BUILD" ;;
 955         hexagon)  TARGETS_TO_BUILD="Hexagon $TARGETS_TO_BUILD" ;;
 956         nvptx)    TARGETS_TO_BUILD="NVPTX $TARGETS_TO_BUILD" ;;
 957         systemz)  TARGETS_TO_BUILD="SystemZ $TARGETS_TO_BUILD" ;;
 958         r600)     TARGETS_TO_BUILD="R600 $TARGETS_TO_BUILD" ;;
 959         host) case "$llvm_cv_target_arch" in
 960             x86)         TARGETS_TO_BUILD="X86 $TARGETS_TO_BUILD" ;;
 961             x86_64)      TARGETS_TO_BUILD="X86 $TARGETS_TO_BUILD" ;;
 962             Sparc)       TARGETS_TO_BUILD="Sparc $TARGETS_TO_BUILD" ;;
 963             PowerPC)     TARGETS_TO_BUILD="PowerPC $TARGETS_TO_BUILD" ;;
 964             AArch64)     TARGETS_TO_BUILD="AArch64 $TARGETS_TO_BUILD" ;;
 965             ARM)         TARGETS_TO_BUILD="ARM $TARGETS_TO_BUILD" ;;
 966             Mips)        TARGETS_TO_BUILD="Mips $TARGETS_TO_BUILD" ;;
 967             XCore)       TARGETS_TO_BUILD="XCore $TARGETS_TO_BUILD" ;;
 968             MSP430)      TARGETS_TO_BUILD="MSP430 $TARGETS_TO_BUILD" ;;
 969             Hexagon)     TARGETS_TO_BUILD="Hexagon $TARGETS_TO_BUILD" ;;
 970             NVPTX)       TARGETS_TO_BUILD="NVPTX $TARGETS_TO_BUILD" ;;
 971             SystemZ)     TARGETS_TO_BUILD="SystemZ $TARGETS_TO_BUILD" ;;
 972             *)       AC_MSG_ERROR([Can not set target to build]) ;;
 973           esac ;;
 974         *) AC_MSG_ERROR([Unrecognized target $a_target]) ;;
 975       esac
 976   done
 977   ;;
 978 esac
 979
 980 AC_ARG_ENABLE([experimental-targets],AS_HELP_STRING([--enable-experimental-targets],
 981     [Build experimental host targets: disable or target1,target2,...
 982      (default=disable)]),,
 983     enableval=disable)
 984
 985 if test ${enableval} != "disable"
 986 then
 987   TARGETS_TO_BUILD="$enableval $TARGETS_TO_BUILD"
 988 fi
 989
 990 AC_SUBST(TARGETS_TO_BUILD,$TARGETS_TO_BUILD)
 991
 992 dnl Determine whether we are building LLVM support for the native architecture.
 993 dnl If so, define LLVM_NATIVE_ARCH to that LLVM target.
 994 for a_target in $TARGETS_TO_BUILD; do
 995   if test "$a_target" = "$LLVM_NATIVE_ARCH"; then
 996     AC_DEFINE_UNQUOTED(LLVM_NATIVE_ARCH, $LLVM_NATIVE_ARCH,
 997       [LLVM architecture name for the native architecture, if available])
 998     LLVM_NATIVE_TARGET="LLVMInitialize${LLVM_NATIVE_ARCH}Target"
 999     LLVM_NATIVE_TARGETINFO="LLVMInitialize${LLVM_NATIVE_ARCH}TargetInfo"
1000     LLVM_NATIVE_TARGETMC="LLVMInitialize${LLVM_NATIVE_ARCH}TargetMC"
1001     LLVM_NATIVE_ASMPRINTER="LLVMInitialize${LLVM_NATIVE_ARCH}AsmPrinter"
1002     if test -f ${srcdir}/lib/Target/${LLVM_NATIVE_ARCH}/AsmParser/Makefile ; then
1003       LLVM_NATIVE_ASMPARSER="LLVMInitialize${LLVM_NATIVE_ARCH}AsmParser"
1004     fi
1005     if test -f ${srcdir}/lib/Target/${LLVM_NATIVE_ARCH}/Disassembler/Makefile ; then
1006       LLVM_NATIVE_DISASSEMBLER="LLVMInitialize${LLVM_NATIVE_ARCH}Disassembler"
1007     fi
1008     AC_DEFINE_UNQUOTED(LLVM_NATIVE_TARGET, $LLVM_NATIVE_TARGET,
1009       [LLVM name for the native Target init function, if available])
1010     AC_DEFINE_UNQUOTED(LLVM_NATIVE_TARGETINFO, $LLVM_NATIVE_TARGETINFO,
1011       [LLVM name for the native TargetInfo init function, if available])
1012     AC_DEFINE_UNQUOTED(LLVM_NATIVE_TARGETMC, $LLVM_NATIVE_TARGETMC,
1013       [LLVM name for the native target MC init function, if available])
1014     AC_DEFINE_UNQUOTED(LLVM_NATIVE_ASMPRINTER, $LLVM_NATIVE_ASMPRINTER,
1015       [LLVM name for the native AsmPrinter init function, if available])
1016     if test -f ${srcdir}/lib/Target/${LLVM_NATIVE_ARCH}/AsmParser/Makefile ; then
1017       AC_DEFINE_UNQUOTED(LLVM_NATIVE_ASMPARSER, $LLVM_NATIVE_ASMPARSER,
1018        [LLVM name for the native AsmParser init function, if available])
1019     fi
1020     if test -f ${srcdir}/lib/Target/${LLVM_NATIVE_ARCH}/Disassembler/Makefile ; then
1021       AC_DEFINE_UNQUOTED(LLVM_NATIVE_DISASSEMBLER, $LLVM_NATIVE_DISASSEMBLER,
1022        [LLVM name for the native Disassembler init function, if available])
1023     fi
1024   fi
1025 done
1026
1027 dnl Build the LLVM_TARGET and LLVM_... macros for Targets.def and the individual
1028 dnl target feature def files.
1029 LLVM_ENUM_TARGETS=""
1030 LLVM_ENUM_ASM_PRINTERS=""
1031 LLVM_ENUM_ASM_PARSERS=""
1032 LLVM_ENUM_DISASSEMBLERS=""
1033 for target_to_build in $TARGETS_TO_BUILD; do
1034   LLVM_ENUM_TARGETS="LLVM_TARGET($target_to_build) $LLVM_ENUM_TARGETS"
1035   if test -f ${srcdir}/lib/Target/${target_to_build}/*AsmPrinter.cpp ; then
1036     LLVM_ENUM_ASM_PRINTERS="LLVM_ASM_PRINTER($target_to_build) $LLVM_ENUM_ASM_PRINTERS";
1037   fi
1038   if test -f ${srcdir}/lib/Target/${target_to_build}/AsmParser/Makefile ; then
1039     LLVM_ENUM_ASM_PARSERS="LLVM_ASM_PARSER($target_to_build) $LLVM_ENUM_ASM_PARSERS";
1040   fi
1041   if test -f ${srcdir}/lib/Target/${target_to_build}/Disassembler/Makefile ; then
1042     LLVM_ENUM_DISASSEMBLERS="LLVM_DISASSEMBLER($target_to_build) $LLVM_ENUM_DISASSEMBLERS";
1043   fi
1044 done
1045 AC_SUBST(LLVM_ENUM_TARGETS)
1046 AC_SUBST(LLVM_ENUM_ASM_PRINTERS)
1047 AC_SUBST(LLVM_ENUM_ASM_PARSERS)
1048 AC_SUBST(LLVM_ENUM_DISASSEMBLERS)
1049
1050 dnl Override the option to use for optimized builds.
1051 AC_ARG_WITH(optimize-option,
1052   AS_HELP_STRING([--with-optimize-option],
1053                  [Select the compiler options to use for optimized builds]),,
1054                  withval=default)
1055 AC_MSG_CHECKING([optimization flags])
1056 case "$withval" in
1057   default)
1058     case "$llvm_cv_os_type" in
1059     FreeBSD) optimize_option=-O2 ;;
1060     MingW) optimize_option=-O2 ;;
1061     *)     optimize_option=-O3 ;;
1062     esac ;;
1063   *) optimize_option="$withval" ;;
1064 esac
1065 AC_SUBST(OPTIMIZE_OPTION,$optimize_option)
1066 AC_MSG_RESULT([$optimize_option])
1067
1068 dnl Specify extra build options
1069 AC_ARG_WITH(extra-options,
1070   AS_HELP_STRING([--with-extra-options],
1071                  [Specify additional options to compile LLVM with]),,
1072                  withval=default)
1073 case "$withval" in
1074   default) EXTRA_OPTIONS= ;;
1075   *) EXTRA_OPTIONS=$withval ;;
1076 esac
1077 AC_SUBST(EXTRA_OPTIONS,$EXTRA_OPTIONS)
1078
1079 dnl Specify extra linker build options
1080 AC_ARG_WITH(extra-ld-options,
1081   AS_HELP_STRING([--with-extra-ld-options],
1082                  [Specify additional options to link LLVM with]),,
1083                  withval=default)
1084 case "$withval" in
1085   default) EXTRA_LD_OPTIONS= ;;
1086   *) EXTRA_LD_OPTIONS=$withval ;;
1087 esac
1088 AC_SUBST(EXTRA_LD_OPTIONS,$EXTRA_LD_OPTIONS)
1089
1090 dnl Allow specific bindings to be specified for building (or not)
1091 AC_ARG_ENABLE([bindings],AS_HELP_STRING([--enable-bindings],
1092     [Build specific language bindings: all,auto,none,{binding-name} (default=auto)]),,
1093     enableval=default)
1094 BINDINGS_TO_BUILD=""
1095 case "$enableval" in
1096   yes | default | auto) BINDINGS_TO_BUILD="auto" ;;
1097   all ) BINDINGS_TO_BUILD="ocaml" ;;
1098   none | no) BINDINGS_TO_BUILD="" ;;
1099   *)for a_binding in `echo $enableval|sed -e 's/,/ /g' ` ; do
1100       case "$a_binding" in
1101         ocaml) BINDINGS_TO_BUILD="ocaml $BINDINGS_TO_BUILD" ;;
1102         *) AC_MSG_ERROR([Unrecognized binding $a_binding]) ;;
1103       esac
1104   done
1105   ;;
1106 esac
1107
1108 dnl Allow the ocaml libdir to be overridden. This could go in a configure
1109 dnl script for bindings/ocaml/configure, except that its auto value depends on
1110 dnl OCAMLC, which is found here to support tests.
1111 AC_ARG_WITH([ocaml-libdir],
1112   [AS_HELP_STRING([--with-ocaml-libdir],
1113     [Specify install location for ocaml bindings (default is stdlib)])],
1114   [],
1115   [withval=auto])
1116 case "$withval" in
1117   auto) with_ocaml_libdir="$withval" ;;
1118   /* | [[A-Za-z]]:[[\\/]]*) with_ocaml_libdir="$withval" ;;
1119   *) AC_MSG_ERROR([Invalid path for --with-ocaml-libdir. Provide full path]) ;;
1120 esac
1121
1122 AC_ARG_WITH(clang-srcdir,
1123   AS_HELP_STRING([--with-clang-srcdir],
1124     [Directory to the out-of-tree Clang source]),,
1125     withval="-")
1126 case "$withval" in
1127   -) clang_src_root="" ;;
1128   /* | [[A-Za-z]]:[[\\/]]*) clang_src_root="$withval" ;;
1129   *) clang_src_root="$ac_pwd/$withval" ;;
1130 esac
1131 AC_SUBST(CLANG_SRC_ROOT,[$clang_src_root])
1132
1133 AC_ARG_WITH(clang-resource-dir,
1134   AS_HELP_STRING([--with-clang-resource-dir],
1135     [Relative directory from the Clang binary for resource files]),,
1136     withval="")
1137 AC_DEFINE_UNQUOTED(CLANG_RESOURCE_DIR,"$withval",
1138                    [Relative directory for resource files])
1139
1140 AC_ARG_WITH(c-include-dirs,
1141   AS_HELP_STRING([--with-c-include-dirs],
1142     [Colon separated list of directories clang will search for headers]),,
1143     withval="")
1144 AC_DEFINE_UNQUOTED(C_INCLUDE_DIRS,"$withval",
1145                    [Directories clang will search for headers])
1146
1147 # Clang normally uses the system c++ headers and libraries. With this option,
1148 # clang will use the ones provided by a gcc installation instead. This option should
1149 # be passed the same value that was used with --prefix when configuring gcc.
1150 AC_ARG_WITH(gcc-toolchain,
1151   AS_HELP_STRING([--with-gcc-toolchain],
1152     [Directory where gcc is installed.]),,
1153     withval="")
1154 AC_DEFINE_UNQUOTED(GCC_INSTALL_PREFIX,"$withval",
1155                    [Directory where gcc is installed.])
1156
1157 AC_ARG_WITH(default-sysroot,
1158   AS_HELP_STRING([--with-default-sysroot],
1159     [Add --sysroot=<path> to all compiler invocations.]),,
1160     withval="")
1161 AC_DEFINE_UNQUOTED(DEFAULT_SYSROOT,"$withval",
1162                    [Default <path> to all compiler invocations for --sysroot=<path>.])
1163
1164 dnl Allow linking of LLVM with GPLv3 binutils code.
1165 AC_ARG_WITH(binutils-include,
1166   AS_HELP_STRING([--with-binutils-include],
1167     [Specify path to binutils/include/ containing plugin-api.h file for gold plugin.]),,
1168   withval=default)
1169 case "$withval" in
1170   default) WITH_BINUTILS_INCDIR=default ;;
1171   /* | [[A-Za-z]]:[[\\/]]*)      WITH_BINUTILS_INCDIR=$withval ;;
1172   *) AC_MSG_ERROR([Invalid path for --with-binutils-include. Provide full path]) ;;
1173 esac
1174 if test "x$WITH_BINUTILS_INCDIR" != xdefault ; then
1175   AC_SUBST(BINUTILS_INCDIR,$WITH_BINUTILS_INCDIR)
1176   if test ! -f "$WITH_BINUTILS_INCDIR/plugin-api.h"; then
1177      echo "$WITH_BINUTILS_INCDIR/plugin-api.h"
1178      AC_MSG_ERROR([Invalid path to directory containing plugin-api.h.]);
1179   fi
1180 fi
1181
1182 dnl Specify the URL where bug reports should be submitted.
1183 AC_ARG_WITH(bug-report-url,
1184   AS_HELP_STRING([--with-bug-report-url],
1185     [Specify the URL where bug reports should be submitted (default=http://llvm.org/bugs/)]),,
1186     withval="http://llvm.org/bugs/")
1187 AC_DEFINE_UNQUOTED(BUG_REPORT_URL,"$withval",
1188                    [Bug report URL.])
1189
1190 dnl --enable-terminfo: check whether the user wants to control use of terminfo:
1191 AC_ARG_ENABLE(terminfo,AS_HELP_STRING(
1192   [--enable-terminfo],
1193   [Query the terminfo database if available (default is YES)]),
1194   [case "$enableval" in
1195     yes) llvm_cv_enable_terminfo="yes" ;;
1196     no)  llvm_cv_enable_terminfo="no"  ;;
1197     *) AC_MSG_ERROR([Invalid setting for --enable-terminfo. Use "yes" or "no"]) ;;
1198   esac],
1199   llvm_cv_enable_terminfo="yes")
1200 case "$llvm_cv_enable_terminfo" in
1201   yes) AC_SUBST(ENABLE_TERMINFO,[1]) ;;
1202   no)  AC_SUBST(ENABLE_TERMINFO,[0]) ;;
1203 esac
1204
1205 dnl --enable-libedit: check whether the user wants to turn off libedit.
1206 AC_ARG_ENABLE(libedit,AS_HELP_STRING(
1207   [--enable-libedit],
1208   [Use libedit if available (default is YES)]),
1209   [case "$enableval" in
1210     yes) llvm_cv_enable_libedit="yes" ;;
1211     no)  llvm_cv_enable_libedit="no"  ;;
1212     *) AC_MSG_ERROR([Invalid setting for --enable-libedit. Use "yes" or "no"]) ;;
1213   esac],
1214   llvm_cv_enable_libedit="yes")
1215
1216 dnl --enable-libffi : check whether the user wants to turn off libffi:
1217 AC_ARG_ENABLE(libffi,AS_HELP_STRING(
1218   --enable-libffi,[Check for the presence of libffi (default is NO)]),
1219   [case "$enableval" in
1220     yes) llvm_cv_enable_libffi="yes" ;;
1221     no)  llvm_cv_enable_libffi="no"  ;;
1222     *) AC_MSG_ERROR([Invalid setting for --enable-libffi. Use "yes" or "no"]) ;;
1223   esac],
1224   llvm_cv_enable_libffi=no)
1225
1226 AC_ARG_WITH(internal-prefix,
1227   AS_HELP_STRING([--with-internal-prefix],
1228     [Installation directory for internal files]),,
1229     withval="")
1230 AC_SUBST(INTERNAL_PREFIX,[$withval])
1231
1232 dnl===-----------------------------------------------------------------------===
1233 dnl===
1234 dnl=== SECTION 4: Check for programs we need and that they are the right version
1235 dnl===
1236 dnl===-----------------------------------------------------------------------===
1237
1238 AC_PROG_NM
1239 AC_SUBST(NM)
1240
1241 dnl Check for the tools that the makefiles require
1242 AC_CHECK_GNU_MAKE
1243 AC_PROG_LN_S
1244 AC_PATH_PROG(CMP, [cmp], [cmp])
1245 AC_PATH_PROG(CP, [cp], [cp])
1246 AC_PATH_PROG(DATE, [date], [date])
1247 AC_PATH_PROG(FIND, [find], [find])
1248 AC_PATH_PROG(GREP, [grep], [grep])
1249 AC_PATH_PROG(MKDIR,[mkdir],[mkdir])
1250 AC_PATH_PROG(MV,   [mv],   [mv])
1251 AC_PROG_RANLIB
1252 AC_CHECK_TOOL(AR, ar, false)
1253 AC_PATH_PROG(RM,   [rm],   [rm])
1254 AC_PATH_PROG(SED,  [sed],  [sed])
1255 AC_PATH_PROG(TAR,  [tar],  [gtar])
1256 AC_PATH_PROG(BINPWD,[pwd],  [pwd])
1257
1258 dnl Looking for misc. graph plotting software
1259 AC_PATH_PROG(GRAPHVIZ, [Graphviz], [echo Graphviz])
1260 if test "$GRAPHVIZ" != "echo Graphviz" ; then
1261   AC_DEFINE([HAVE_GRAPHVIZ],[1],[Define if the Graphviz program is available])
1262   dnl If we're targeting for mingw we should emit windows paths, not msys
1263   if test "$llvm_cv_os_type" = "MingW" ; then
1264     GRAPHVIZ=`echo $GRAPHVIZ | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
1265   fi
1266   AC_DEFINE_UNQUOTED([LLVM_PATH_GRAPHVIZ],"$GRAPHVIZ${EXEEXT}",
1267    [Define to path to Graphviz program if found or 'echo Graphviz' otherwise])
1268 fi
1269 AC_PATH_PROG(DOT, [dot], [echo dot])
1270 if test "$DOT" != "echo dot" ; then
1271   AC_DEFINE([HAVE_DOT],[1],[Define if the dot program is available])
1272   dnl If we're targeting for mingw we should emit windows paths, not msys
1273   if test "$llvm_cv_os_type" = "MingW" ; then
1274     DOT=`echo $DOT | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
1275   fi
1276   AC_DEFINE_UNQUOTED([LLVM_PATH_DOT],"$DOT${EXEEXT}",
1277    [Define to path to dot program if found or 'echo dot' otherwise])
1278 fi
1279 AC_PATH_PROG(FDP, [fdp], [echo fdp])
1280 if test "$FDP" != "echo fdp" ; then
1281   AC_DEFINE([HAVE_FDP],[1],[Define if the neat program is available])
1282   dnl If we're targeting for mingw we should emit windows paths, not msys
1283   if test "$llvm_cv_os_type" = "MingW" ; then
1284     FDP=`echo $FDP | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
1285   fi
1286   AC_DEFINE_UNQUOTED([LLVM_PATH_FDP],"$FDP${EXEEXT}",
1287    [Define to path to fdp program if found or 'echo fdp' otherwise])
1288 fi
1289 AC_PATH_PROG(NEATO, [neato], [echo neato])
1290 if test "$NEATO" != "echo neato" ; then
1291   AC_DEFINE([HAVE_NEATO],[1],[Define if the neat program is available])
1292   dnl If we're targeting for mingw we should emit windows paths, not msys
1293   if test "$llvm_cv_os_type" = "MingW" ; then
1294     NEATO=`echo $NEATO | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
1295   fi
1296   AC_DEFINE_UNQUOTED([LLVM_PATH_NEATO],"$NEATO${EXEEXT}",
1297    [Define to path to neato program if found or 'echo neato' otherwise])
1298 fi
1299 AC_PATH_PROG(TWOPI, [twopi], [echo twopi])
1300 if test "$TWOPI" != "echo twopi" ; then
1301   AC_DEFINE([HAVE_TWOPI],[1],[Define if the neat program is available])
1302   dnl If we're targeting for mingw we should emit windows paths, not msys
1303   if test "$llvm_cv_os_type" = "MingW" ; then
1304     TWOPI=`echo $TWOPI | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
1305   fi
1306   AC_DEFINE_UNQUOTED([LLVM_PATH_TWOPI],"$TWOPI${EXEEXT}",
1307    [Define to path to twopi program if found or 'echo twopi' otherwise])
1308 fi
1309 AC_PATH_PROG(CIRCO, [circo], [echo circo])
1310 if test "$CIRCO" != "echo circo" ; then
1311   AC_DEFINE([HAVE_CIRCO],[1],[Define if the neat program is available])
1312   dnl If we're targeting for mingw we should emit windows paths, not msys
1313   if test "$llvm_cv_os_type" = "MingW" ; then
1314     CIRCO=`echo $CIRCO | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
1315   fi
1316   AC_DEFINE_UNQUOTED([LLVM_PATH_CIRCO],"$CIRCO${EXEEXT}",
1317    [Define to path to circo program if found or 'echo circo' otherwise])
1318 fi
1319 AC_PATH_PROGS(GV, [gv gsview32], [echo gv])
1320 if test "$GV" != "echo gv" ; then
1321   AC_DEFINE([HAVE_GV],[1],[Define if the gv program is available])
1322   dnl If we're targeting for mingw we should emit windows paths, not msys
1323   if test "$llvm_cv_os_type" = "MingW" ; then
1324     GV=`echo $GV | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
1325   fi
1326   AC_DEFINE_UNQUOTED([LLVM_PATH_GV],"$GV${EXEEXT}",
1327    [Define to path to gv program if found or 'echo gv' otherwise])
1328 fi
1329 AC_PATH_PROG(DOTTY, [dotty], [echo dotty])
1330 if test "$DOTTY" != "echo dotty" ; then
1331   AC_DEFINE([HAVE_DOTTY],[1],[Define if the dotty program is available])
1332   dnl If we're targeting for mingw we should emit windows paths, not msys
1333   if test "$llvm_cv_os_type" = "MingW" ; then
1334     DOTTY=`echo $DOTTY | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
1335   fi
1336   AC_DEFINE_UNQUOTED([LLVM_PATH_DOTTY],"$DOTTY${EXEEXT}",
1337    [Define to path to dotty program if found or 'echo dotty' otherwise])
1338 fi
1339 AC_PATH_PROGS(XDOT, [xdot xdot.py], [echo xdot])
1340 if test "$XDOT" != "echo xdot" ; then
1341   AC_DEFINE([HAVE_XDOT],[1],[Define if the xdot program is available])
1342   dnl If we're targeting for mingw we should emit windows paths, not msys
1343   if test "$llvm_cv_os_type" = "MingW" ; then
1344     XDOT=`echo $XDOT | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
1345   fi
1346   AC_DEFINE_UNQUOTED([LLVM_PATH_XDOT],"$XDOT${EXEEXT}",
1347    [Define to path to xdot program if found or 'echo xdot' otherwise])
1348 fi
1349
1350 dnl Find the install program
1351 AC_PROG_INSTALL
1352 dnl Prepend src dir to install path dir if it's a relative path
1353 dnl This is a hack for installs that take place in something other
1354 dnl than the top level.
1355 case "$INSTALL" in
1356  [[\\/$]]* | ?:[[\\/]]* ) ;;
1357  *)  INSTALL="\\\$(TOPSRCDIR)/$INSTALL" ;;
1358 esac
1359
1360 dnl Checks for documentation and testing tools that we can do without. If these
1361 dnl are not found then they are set to "true" which always succeeds but does
1362 dnl nothing. This just lets the build output show that we could have done
1363 dnl something if the tool was available.
1364 AC_PATH_PROG(BZIP2, [bzip2])
1365 AC_PATH_PROG(CAT, [cat])
1366 AC_PATH_PROG(DOXYGEN, [doxygen])
1367 AC_PATH_PROG(GROFF, [groff])
1368 AC_PATH_PROG(GZIPBIN, [gzip])
1369 AC_PATH_PROG(PDFROFF, [pdfroff])
1370 AC_PATH_PROG(ZIP, [zip])
1371 AC_PATH_PROGS(OCAMLC, [ocamlc])
1372 AC_PATH_PROGS(OCAMLOPT, [ocamlopt])
1373 AC_PATH_PROGS(OCAMLDEP, [ocamldep])
1374 AC_PATH_PROGS(OCAMLDOC, [ocamldoc])
1375 AC_PATH_PROGS(GAS, [gas as])
1376
1377 dnl Get the version of the linker in use.
1378 AC_LINK_GET_VERSION
1379
1380 dnl Determine whether the linker supports the -R option.
1381 AC_LINK_USE_R
1382
1383 dnl Determine whether the compiler supports the -rdynamic option.
1384 AC_LINK_EXPORT_DYNAMIC
1385
1386 dnl Determine whether the linker supports the --version-script option.
1387 AC_LINK_VERSION_SCRIPT
1388
1389 dnl Check for libtool and the library that has dlopen function (which must come
1390 dnl before the AC_PROG_LIBTOOL check in order to enable dlopening libraries with
1391 dnl libtool).
1392 AC_LIBTOOL_DLOPEN
1393 AC_LIB_LTDL
1394
1395 AC_MSG_CHECKING([tool compatibility])
1396
1397 dnl Ensure that compilation tools are GCC or a GNU compatible compiler such as
1398 dnl ICC; we use GCC specific options in the makefiles so the compiler needs
1399 dnl to support those options.
1400 dnl "icc" emits gcc signatures
1401 dnl "icc -no-gcc" emits no gcc signature BUT is still compatible
1402 ICC=no
1403 IXX=no
1404 case $CC in
1405   icc*|icpc*)
1406     ICC=yes
1407     IXX=yes
1408     ;;
1409    *)
1410     ;;
1411 esac
1412
1413 if test "$GCC" != "yes" && test "$ICC" != "yes"
1414 then
1415   AC_MSG_ERROR([gcc|icc required but not found])
1416 fi
1417
1418 dnl Ensure that compilation tools are compatible with GCC extensions
1419 if test "$GXX" != "yes" && test "$IXX" != "yes"
1420 then
1421   AC_MSG_ERROR([g++|clang++|icc required but not found])
1422 fi
1423
1424 dnl Verify that GCC is version 3.0 or higher
1425 if test "$GCC" = "yes"
1426 then
1427   AC_COMPILE_IFELSE(
1428 [
1429   AC_LANG_SOURCE([[
1430     #if !defined(__GNUC__) || __GNUC__ < 3
1431     #error Unsupported GCC version
1432     #endif
1433   ]])
1434 ],
1435 [], [AC_MSG_ERROR([gcc 3.x required, but you have a lower version])])
1436 fi
1437
1438 dnl Check for GNU Make.  We use its extensions, so don't build without it
1439 if test -z "$llvm_cv_gnu_make_command"
1440 then
1441   AC_MSG_ERROR([GNU Make required but not found])
1442 fi
1443
1444 dnl Tool compatibility is okay if we make it here.
1445 AC_MSG_RESULT([ok])
1446
1447 dnl Check optional compiler flags.
1448 AC_MSG_CHECKING([optional compiler flags])
1449 CXX_FLAG_CHECK(NO_VARIADIC_MACROS, [-Wno-variadic-macros])
1450 CXX_FLAG_CHECK(NO_MISSING_FIELD_INITIALIZERS, [-Wno-missing-field-initializers])
1451 CXX_FLAG_CHECK(COVERED_SWITCH_DEFAULT, [-Wcovered-switch-default])
1452
1453 dnl GCC's potential uninitialized use analysis is weak and presents lots of
1454 dnl false positives, so disable it.
1455 NO_UNINITIALIZED=
1456 NO_MAYBE_UNINITIALIZED=
1457 if test "$GXX" = "yes"
1458 then
1459   CXX_FLAG_CHECK(NO_MAYBE_UNINITIALIZED, [-Wno-maybe-uninitialized])
1460   dnl gcc 4.7 introduced -Wmaybe-uninitialized to distinguish cases which are
1461   dnl known to be uninitialized from cases which might be uninitialized.  We
1462   dnl still want to catch the first kind of errors.
1463   if test -z "$NO_MAYBE_UNINITIALIZED"
1464   then
1465     CXX_FLAG_CHECK(NO_UNINITIALIZED, [-Wno-uninitialized])
1466   fi
1467 fi
1468 AC_MSG_RESULT([$NO_VARIADIC_MACROS $NO_MISSING_FIELD_INITIALIZERS $COVERED_SWITCH_DEFAULT $NO_UNINITIALIZED $NO_MAYBE_UNINITIALIZED])
1469
1470 AC_ARG_WITH([python],
1471             [AS_HELP_STRING([--with-python], [path to python])],
1472             [PYTHON="$withval"])
1473
1474 if test -n "$PYTHON" && test -x "$PYTHON" ; then
1475   AC_MSG_CHECKING([for python])
1476   AC_MSG_RESULT([user defined: $with_python])
1477 else
1478   if test -n "$PYTHON" ; then
1479     AC_MSG_WARN([specified python ($PYTHON) is not usable, searching path])
1480   fi
1481
1482   AC_PATH_PROG([PYTHON], [python python2 python26],
1483                [AC_MSG_RESULT([not found])
1484                 AC_MSG_ERROR([could not find python 2.5 or higher])])
1485 fi
1486
1487 AC_MSG_CHECKING([for python >= 2.5])
1488 ac_python_version=`$PYTHON -V 2>&1 | cut -d' ' -f2`
1489 ac_python_version_major=`echo $ac_python_version | cut -d'.' -f1`
1490 ac_python_version_minor=`echo $ac_python_version | cut -d'.' -f2`
1491 ac_python_version_patch=`echo $ac_python_version | cut -d'.' -f3`
1492 if test "$ac_python_version_major" -gt "2" || \
1493    (test "$ac_python_version_major" -eq "2" && \
1494     test "$ac_python_version_minor" -ge "5") ; then
1495   AC_MSG_RESULT([$PYTHON ($ac_python_version)])
1496 else
1497   AC_MSG_RESULT([not found])
1498   AC_MSG_FAILURE([found python $ac_python_version ($PYTHON); required >= 2.5])
1499 fi
1500
1501 dnl===-----------------------------------------------------------------------===
1502 dnl===
1503 dnl=== SECTION 5: Check for libraries
1504 dnl===
1505 dnl===-----------------------------------------------------------------------===
1506
1507 AC_CHECK_LIB(m,sin)
1508 if test "$llvm_cv_os_type" = "MingW" ; then
1509   AC_CHECK_LIB(imagehlp, main)
1510   AC_CHECK_LIB(psapi, main)
1511   AC_CHECK_LIB(shell32, main)
1512 fi
1513
1514 dnl dlopen() is required for plugin support.
1515 AC_SEARCH_LIBS(dlopen,dl,LLVM_DEFINE_SUBST([HAVE_DLOPEN],[1],
1516                [Define if dlopen() is available on this platform.]),
1517                AC_MSG_WARN([dlopen() not found - disabling plugin support]))
1518
1519 dnl Search for the clock_gettime() function. Note that we rely on the POSIX
1520 dnl macros to detect whether clock_gettime is available, this just finds the
1521 dnl right libraries to link with.
1522 AC_SEARCH_LIBS(clock_gettime,rt)
1523
1524 dnl The curses library is optional; used for querying terminal info
1525 if test "$llvm_cv_enable_terminfo" = "yes" ; then
1526   dnl We need the has_color functionality in curses for it to be useful.
1527   AC_SEARCH_LIBS(setupterm,tinfo terminfo curses ncurses ncursesw,
1528                  LLVM_DEFINE_SUBST([HAVE_TERMINFO],[1],
1529                                    [Define if the setupterm() function is supported this platform.]))
1530 fi
1531
1532 dnl The libedit library is optional; used by lib/LineEditor
1533 if test "$llvm_cv_enable_libedit" = "yes" ; then
1534   AC_SEARCH_LIBS(el_init,edit,
1535                  AC_DEFINE([HAVE_LIBEDIT],[1],
1536                            [Define if libedit is available on this platform.]))
1537 fi
1538
1539 dnl libffi is optional; used to call external functions from the interpreter
1540 if test "$llvm_cv_enable_libffi" = "yes" ; then
1541   AC_SEARCH_LIBS(ffi_call,ffi,AC_DEFINE([HAVE_FFI_CALL],[1],
1542                  [Define if libffi is available on this platform.]),
1543                  AC_MSG_ERROR([libffi not found - configure without --enable-libffi to compile without it]))
1544 fi
1545
1546 dnl mallinfo is optional; the code can compile (minus features) without it
1547 AC_SEARCH_LIBS(mallinfo,malloc,AC_DEFINE([HAVE_MALLINFO],[1],
1548                [Define if mallinfo() is available on this platform.]))
1549
1550 dnl pthread locking functions are optional - but llvm will not be thread-safe
1551 dnl without locks.
1552 if test "$LLVM_ENABLE_THREADS" -eq 1 && test "$ENABLE_PTHREADS" -eq 1 ; then
1553   AC_CHECK_LIB(pthread, pthread_mutex_init)
1554   AC_SEARCH_LIBS(pthread_mutex_lock,pthread,
1555                  AC_DEFINE([HAVE_PTHREAD_MUTEX_LOCK],[1],
1556                            [Have pthread_mutex_lock]))
1557   AC_SEARCH_LIBS(pthread_rwlock_init,pthread,
1558                  AC_DEFINE([HAVE_PTHREAD_RWLOCK_INIT],[1],
1559                  [Have pthread_rwlock_init]))
1560   AC_SEARCH_LIBS(pthread_getspecific,pthread,
1561                  AC_DEFINE([HAVE_PTHREAD_GETSPECIFIC],[1],
1562                  [Have pthread_getspecific]))
1563 fi
1564
1565 dnl zlib is optional; used for compression/uncompression
1566 if test "$LLVM_ENABLE_ZLIB" -eq 1 ; then
1567   AC_CHECK_LIB(z, compress2)
1568 fi
1569
1570 dnl Allow extra x86-disassembler library
1571 AC_ARG_WITH(udis86,
1572   AS_HELP_STRING([--with-udis86=<path>],
1573     [Use udis86 external x86 disassembler library]),
1574     [
1575       AC_SUBST(USE_UDIS86, [1])
1576       case "$withval" in
1577         /usr/lib|yes) ;;
1578         *) LDFLAGS="$LDFLAGS -L${withval}" ;;
1579       esac
1580       AC_CHECK_LIB(udis86, ud_init, [], [
1581         echo "Error! You need to have libudis86 around."
1582         exit -1
1583       ])
1584     ],
1585     AC_SUBST(USE_UDIS86, [0]))
1586 AC_DEFINE_UNQUOTED([USE_UDIS86],$USE_UDIS86,
1587                    [Define if use udis86 library])
1588
1589 dnl Allow OProfile support for JIT output.
1590 AC_ARG_WITH(oprofile,
1591   AS_HELP_STRING([--with-oprofile=<prefix>],
1592     [Tell OProfile >= 0.9.4 how to symbolize JIT output]),
1593     [
1594       AC_SUBST(USE_OPROFILE, [1])
1595       case "$withval" in
1596         /usr|yes) llvm_cv_oppath=/usr/lib/oprofile ;;
1597         no) llvm_cv_oppath=
1598             AC_SUBST(USE_OPROFILE, [0]) ;;
1599         *) llvm_cv_oppath="${withval}/lib/oprofile"
1600            CPPFLAGS="-I${withval}/include";;
1601       esac
1602       case $llvm_cv_os_type in
1603         Linux)
1604           if test -n "$llvm_cv_oppath" ; then
1605             LIBS="$LIBS -lopagent -L${llvm_cv_oppath} -Wl,-rpath,${llvm_cv_oppath}"
1606             dnl Work around http://bugs.debian.org/cgi-bin/bugreport.cgi?bug=537744:
1607             dnl libbfd is not included properly in libopagent in some Debian
1608             dnl versions.  If libbfd isn't found at all, we assume opagent works
1609             dnl anyway.
1610             AC_SEARCH_LIBS(bfd_init, bfd, [], [])
1611             AC_SEARCH_LIBS(op_open_agent, opagent, [], [
1612               echo "Error! You need to have libopagent around."
1613               exit -1
1614             ])
1615             AC_CHECK_HEADER([opagent.h], [], [
1616               echo "Error! You need to have opagent.h around."
1617               exit -1
1618               ])
1619           fi ;;
1620         *)
1621           AC_MSG_ERROR([OProfile support is available on Linux only.]) ;;
1622       esac
1623     ],
1624     [
1625       AC_SUBST(USE_OPROFILE, [0])
1626     ])
1627 AC_DEFINE_UNQUOTED([LLVM_USE_OPROFILE],$USE_OPROFILE,
1628                    [Define if we have the oprofile JIT-support library])
1629
1630 dnl Enable support for Intel JIT Events API.
1631 AC_ARG_WITH(intel-jitevents,
1632   AS_HELP_STRING([--with-intel-jitevents  Notify Intel JIT profiling API of generated code]),
1633     [
1634        case "$withval" in
1635           yes) AC_SUBST(USE_INTEL_JITEVENTS,[1]);;
1636           no)  AC_SUBST(USE_INTEL_JITEVENTS,[0]);;
1637           *) AC_MSG_ERROR([Invalid setting for --with-intel-jitevents. Use "yes" or "no"]);;
1638        esac
1639
1640       case $llvm_cv_os_type in
1641         Linux|Win32|Cygwin|MingW) ;;
1642         *) AC_MSG_ERROR([Intel JIT API support is available on Linux and Windows only.]);;
1643       esac
1644
1645       case "$llvm_cv_target_arch" in
1646         x86|x86_64) ;;
1647         *) AC_MSG_ERROR([Target architecture $llvm_cv_target_arch does not support Intel JIT Events API.]);;
1648       esac
1649     ],
1650     [
1651       AC_SUBST(USE_INTEL_JITEVENTS, [0])
1652     ])
1653 AC_DEFINE_UNQUOTED([LLVM_USE_INTEL_JITEVENTS],$USE_INTEL_JITEVENTS,
1654                    [Define if we have the Intel JIT API runtime support library])
1655
1656 dnl Check for libxml2
1657 dnl Right now we're just checking for the existence, we could also check for a
1658 dnl particular version via --version on xml2-config
1659 AC_CHECK_PROGS(XML2CONFIG, xml2-config)
1660
1661 AC_MSG_CHECKING(for libxml2 includes)
1662 if test "x$XML2CONFIG" = "x"; then
1663  AC_MSG_RESULT(xml2-config not found)
1664 else
1665  LIBXML2_INC=`$XML2CONFIG --cflags`
1666  AC_MSG_RESULT($LIBXML2_INC)
1667  AC_CHECK_LIB(xml2, xmlReadFile,[AC_DEFINE([CLANG_HAVE_LIBXML],1,[Define if we have libxml2])
1668                                 LIBXML2_LIBS="-lxml2"])
1669 fi
1670 AC_SUBST(LIBXML2_LIBS)
1671 AC_SUBST(LIBXML2_INC)
1672
1673 dnl===-----------------------------------------------------------------------===
1674 dnl===
1675 dnl=== SECTION 6: Check for header files
1676 dnl===
1677 dnl===-----------------------------------------------------------------------===
1678
1679 dnl First, use autoconf provided macros for specific headers that we need
1680 dnl We don't check for ancient stuff or things that are guaranteed to be there
1681 dnl by the C++ standard. We always use the <cfoo> versions of <foo.h> C headers.
1682 dnl Generally we're looking for POSIX headers.
1683 AC_HEADER_DIRENT
1684 AC_HEADER_MMAP_ANONYMOUS
1685 AC_HEADER_STAT
1686 AC_HEADER_SYS_WAIT
1687 AC_HEADER_TIME
1688
1689 AC_LANG_PUSH([C++])
1690 AC_CHECK_HEADERS([cxxabi.h])
1691 AC_LANG_POP([C++])
1692 AC_CHECK_HEADERS([dlfcn.h execinfo.h fcntl.h inttypes.h link.h])
1693 AC_CHECK_HEADERS([malloc.h setjmp.h signal.h stdint.h termios.h unistd.h])
1694 AC_CHECK_HEADERS([utime.h])
1695 AC_CHECK_HEADERS([sys/mman.h sys/param.h sys/resource.h sys/time.h sys/uio.h])
1696 AC_CHECK_HEADERS([sys/ioctl.h malloc/malloc.h mach/mach.h])
1697 AC_CHECK_HEADERS([valgrind/valgrind.h])
1698 AC_CHECK_HEADERS([fenv.h])
1699 AC_CHECK_DECLS([FE_ALL_EXCEPT, FE_INEXACT], [], [], [[#include <fenv.h>]])
1700 if test "$LLVM_ENABLE_THREADS" -eq 1 && test "$ENABLE_PTHREADS" -eq 1 ; then
1701   AC_CHECK_HEADERS(pthread.h,
1702                    AC_SUBST(HAVE_PTHREAD, 1),
1703                    AC_SUBST(HAVE_PTHREAD, 0))
1704 else
1705   AC_SUBST(HAVE_PTHREAD, 0)
1706 fi
1707 if test "$LLVM_ENABLE_ZLIB" -eq 1 ; then
1708   AC_CHECK_HEADERS(zlib.h,
1709                    AC_SUBST(HAVE_LIBZ, 1),
1710                    AC_SUBST(HAVE_LIBZ, 0))
1711 else
1712   AC_SUBST(HAVE_LIBZ, 0)
1713 fi
1714
1715 dnl Try to find ffi.h.
1716 if test "$llvm_cv_enable_libffi" = "yes" ; then
1717   AC_CHECK_HEADERS([ffi.h ffi/ffi.h])
1718 fi
1719
1720 dnl Try to find Darwin specific crash reporting libraries.
1721 AC_CHECK_HEADERS([CrashReporterClient.h])
1722
1723 dnl Try to find Darwin specific crash reporting global.
1724 AC_MSG_CHECKING([__crashreporter_info__])
1725 AC_LINK_IFELSE(
1726 [
1727   AC_LANG_SOURCE([[
1728     extern const char *__crashreporter_info__;
1729     int main() {
1730       __crashreporter_info__ = "test";
1731       return 0;
1732     }
1733   ]])
1734 ],
1735 [
1736   AC_MSG_RESULT([yes])
1737   AC_DEFINE([HAVE_CRASHREPORTER_INFO], [1], [can use __crashreporter_info__])
1738 ],
1739 [
1740   AC_MSG_RESULT([no])
1741   AC_DEFINE([HAVE_CRASHREPORTER_INFO], [0], [can use __crashreporter_info__])
1742 ])
1743
1744 dnl===-----------------------------------------------------------------------===
1745 dnl===
1746 dnl=== SECTION 7: Check for types and structures
1747 dnl===
1748 dnl===-----------------------------------------------------------------------===
1749
1750 AC_HUGE_VAL_CHECK
1751 AC_TYPE_PID_T
1752 AC_TYPE_SIZE_T
1753 AC_DEFINE_UNQUOTED([RETSIGTYPE],[void],[Define as the return type of signal handlers (`int' or `void').])
1754 AC_STRUCT_TM
1755 AC_CHECK_TYPES([int64_t],,AC_MSG_ERROR([Type int64_t required but not found]))
1756 AC_CHECK_TYPES([uint64_t],,
1757          AC_CHECK_TYPES([u_int64_t],,
1758          AC_MSG_ERROR([Type uint64_t or u_int64_t required but not found])))
1759
1760 dnl===-----------------------------------------------------------------------===
1761 dnl===
1762 dnl=== SECTION 8: Check for specific functions needed
1763 dnl===
1764 dnl===-----------------------------------------------------------------------===
1765
1766 AC_CHECK_FUNCS([backtrace ceilf floorf roundf rintf nearbyintf getcwd ])
1767 AC_CHECK_FUNCS([powf fmodf strtof round ])
1768 AC_CHECK_FUNCS([log log2 log10 exp exp2])
1769 AC_CHECK_FUNCS([getpagesize getrusage getrlimit setrlimit gettimeofday ])
1770 AC_CHECK_FUNCS([isatty mkdtemp mkstemp ])
1771 AC_CHECK_FUNCS([mktemp posix_spawn pread realpath sbrk setrlimit ])
1772 AC_CHECK_FUNCS([strerror strerror_r setenv ])
1773 AC_CHECK_FUNCS([strtoll strtoq sysconf malloc_zone_statistics ])
1774 AC_CHECK_FUNCS([setjmp longjmp sigsetjmp siglongjmp writev])
1775 AC_CHECK_FUNCS([futimes futimens])
1776 AC_C_PRINTF_A
1777 AC_FUNC_RAND48
1778
1779 dnl Check for arc4random accessible via AC_INCLUDES_DEFAULT.
1780 AC_CHECK_DECLS([arc4random])
1781
1782 dnl Check the declaration "Secure API" on Windows environments.
1783 AC_CHECK_DECLS([strerror_s])
1784
1785 dnl Check symbols in libgcc.a for JIT on Mingw.
1786 if test "$llvm_cv_os_type" = "MingW" ; then
1787   AC_CHECK_LIB(gcc,_alloca,AC_DEFINE([HAVE__ALLOCA],[1],[Have host's _alloca]))
1788   AC_CHECK_LIB(gcc,__alloca,AC_DEFINE([HAVE___ALLOCA],[1],[Have host's __alloca]))
1789   AC_CHECK_LIB(gcc,__chkstk,AC_DEFINE([HAVE___CHKSTK],[1],[Have host's __chkstk]))
1790   AC_CHECK_LIB(gcc,___chkstk,AC_DEFINE([HAVE____CHKSTK],[1],[Have host's ___chkstk]))
1791
1792   AC_CHECK_LIB(gcc,__ashldi3,AC_DEFINE([HAVE___ASHLDI3],[1],[Have host's __ashldi3]))
1793   AC_CHECK_LIB(gcc,__ashrdi3,AC_DEFINE([HAVE___ASHRDI3],[1],[Have host's __ashrdi3]))
1794   AC_CHECK_LIB(gcc,__divdi3,AC_DEFINE([HAVE___DIVDI3],[1],[Have host's __divdi3]))
1795   AC_CHECK_LIB(gcc,__fixdfdi,AC_DEFINE([HAVE___FIXDFDI],[1],[Have host's __fixdfdi]))
1796   AC_CHECK_LIB(gcc,__fixsfdi,AC_DEFINE([HAVE___FIXSFDI],[1],[Have host's __fixsfdi]))
1797   AC_CHECK_LIB(gcc,__floatdidf,AC_DEFINE([HAVE___FLOATDIDF],[1],[Have host's __floatdidf]))
1798   AC_CHECK_LIB(gcc,__lshrdi3,AC_DEFINE([HAVE___LSHRDI3],[1],[Have host's __lshrdi3]))
1799   AC_CHECK_LIB(gcc,__moddi3,AC_DEFINE([HAVE___MODDI3],[1],[Have host's __moddi3]))
1800   AC_CHECK_LIB(gcc,__udivdi3,AC_DEFINE([HAVE___UDIVDI3],[1],[Have host's __udivdi3]))
1801   AC_CHECK_LIB(gcc,__umoddi3,AC_DEFINE([HAVE___UMODDI3],[1],[Have host's __umoddi3]))
1802
1803   AC_CHECK_LIB(gcc,__main,AC_DEFINE([HAVE___MAIN],[1],[Have host's __main]))
1804   AC_CHECK_LIB(gcc,__cmpdi2,AC_DEFINE([HAVE___CMPDI2],[1],[Have host's __cmpdi2]))
1805 fi
1806
1807 dnl Check Win32 API EnumerateLoadedModules.
1808 if test "$llvm_cv_os_type" = "MingW" ; then
1809   AC_MSG_CHECKING([whether EnumerateLoadedModules() accepts new decl])
1810   AC_COMPILE_IFELSE(
1811 [
1812   AC_LANG_SOURCE([[
1813     #include <windows.h>
1814     #include <imagehlp.h>
1815     extern void foo(PENUMLOADED_MODULES_CALLBACK);
1816     extern void foo(BOOL(CALLBACK*)(PCSTR,ULONG_PTR,ULONG,PVOID));
1817   ]])
1818 ],
1819 [
1820   AC_MSG_RESULT([yes])
1821   llvm_cv_win32_elmcb_pcstr="PCSTR"
1822 ],
1823 [
1824   AC_MSG_RESULT([no])
1825   llvm_cv_win32_elmcb_pcstr="PSTR"
1826 ])
1827   AC_DEFINE_UNQUOTED([WIN32_ELMCB_PCSTR],$llvm_cv_win32_elmcb_pcstr,[Type of 1st arg on ELM Callback])
1828 fi
1829
1830 dnl Check for variations in the Standard C++ library and STL. These macros are
1831 dnl provided by LLVM in the autoconf/m4 directory.
1832 AC_FUNC_ISNAN
1833 AC_FUNC_ISINF
1834
1835 dnl Check for mmap support.We also need to know if /dev/zero is required to
1836 dnl be opened for allocating RWX memory.
1837 dnl Make sure we aren't attempting to configure for an unknown system
1838 if test "$llvm_cv_platform_type" = "Unix" ; then
1839   AC_FUNC_MMAP
1840   AC_FUNC_MMAP_FILE
1841   AC_NEED_DEV_ZERO_FOR_MMAP
1842
1843   if test "$ac_cv_func_mmap_fixed_mapped" = "no"
1844   then
1845     AC_MSG_WARN([mmap() of a fixed address required but not supported])
1846   fi
1847   if test "$ac_cv_func_mmap_file" = "no"
1848   then
1849     AC_MSG_WARN([mmap() of files required but not found])
1850   fi
1851 fi
1852
1853 dnl atomic builtins are required for threading support.
1854 AC_MSG_CHECKING(for GCC atomic builtins)
1855 dnl Since we'll be using these atomic builtins in C++ files we should test
1856 dnl the C++ compiler.
1857 AC_LANG_PUSH([C++])
1858 AC_LINK_IFELSE(
1859 [
1860   AC_LANG_SOURCE([[
1861     int main() {
1862       volatile unsigned long val = 1;
1863       __sync_synchronize();
1864       __sync_val_compare_and_swap(&val, 1, 0);
1865       __sync_add_and_fetch(&val, 1);
1866       __sync_sub_and_fetch(&val, 1);
1867       return 0;
1868     }
1869   ]])
1870 ],
1871 [
1872   AC_MSG_RESULT([yes])
1873   AC_DEFINE([LLVM_HAS_ATOMICS], [1], [Has gcc/MSVC atomic intrinsics])
1874 ],
1875 [
1876   AC_MSG_RESULT([no])
1877   AC_DEFINE([LLVM_HAS_ATOMICS], [0], [Has gcc/MSVC atomic intrinsics])
1878   AC_MSG_WARN([LLVM will be built thread-unsafe because atomic builtins are missing])
1879 ])
1880 AC_LANG_POP([C++])
1881
1882 dnl===-----------------------------------------------------------------------===
1883 dnl===
1884 dnl=== SECTION 9: Additional checks, variables, etc.
1885 dnl===
1886 dnl===-----------------------------------------------------------------------===
1887
1888 dnl Handle 32-bit linux systems running a 64-bit kernel.
1889 dnl This has to come after section 4 because it invokes the compiler.
1890 if test "$llvm_cv_os_type" = "Linux" -a "$llvm_cv_target_arch" = "x86_64" ; then
1891   AC_IS_LINUX_MIXED
1892   if test "$llvm_cv_linux_mixed" = "yes"; then
1893     llvm_cv_target_arch="x86"
1894     ARCH="x86"
1895   fi
1896 fi
1897
1898 dnl Check whether __dso_handle is present
1899 AC_CHECK_FUNCS([__dso_handle])
1900
1901 dnl Propagate the shared library extension that the libltdl checks did to
1902 dnl the Makefiles so we can use it there too
1903 AC_SUBST(SHLIBEXT,$libltdl_cv_shlibext)
1904
1905 dnl Propagate the run-time library path variable that the libltdl
1906 dnl checks found to the Makefiles so we can use it there too
1907 AC_SUBST(SHLIBPATH_VAR,$libltdl_cv_shlibpath_var)
1908
1909 dnl Translate the various configuration directories and other basic
1910 dnl information into substitutions that will end up in Makefile.config.in
1911 dnl that these configured values can be used by the makefiles
1912 if test "${prefix}" = "NONE" ; then
1913   prefix="/usr/local"
1914 fi
1915 eval LLVM_PREFIX="${prefix}";
1916 eval LLVM_BINDIR="${prefix}/bin";
1917 eval LLVM_DATADIR="${prefix}/share/llvm";
1918 eval LLVM_DOCSDIR="${prefix}/share/doc/llvm";
1919 eval LLVM_ETCDIR="${prefix}/etc/llvm";
1920 eval LLVM_INCLUDEDIR="${prefix}/include";
1921 eval LLVM_INFODIR="${prefix}/info";
1922 eval LLVM_MANDIR="${prefix}/man";
1923 LLVM_CONFIGTIME=`date`
1924 AC_SUBST(LLVM_PREFIX)
1925 AC_SUBST(LLVM_BINDIR)
1926 AC_SUBST(LLVM_DATADIR)
1927 AC_SUBST(LLVM_DOCSDIR)
1928 AC_SUBST(LLVM_ETCDIR)
1929 AC_SUBST(LLVM_INCLUDEDIR)
1930 AC_SUBST(LLVM_INFODIR)
1931 AC_SUBST(LLVM_MANDIR)
1932 AC_SUBST(LLVM_CONFIGTIME)
1933
1934 dnl Disable embedding timestamps in the build directory, with ENABLE_TIMESTAMPS.
1935 if test "${ENABLE_TIMESTAMPS}" = "0"; then
1936   LLVM_CONFIGTIME="(timestamp not enabled)"
1937 fi
1938
1939 dnl Place the various directories into the config.h file as #defines so that we
1940 dnl can know about the installation paths within LLVM.
1941 AC_DEFINE_UNQUOTED(LLVM_PREFIX,"$LLVM_PREFIX",
1942                    [Installation prefix directory])
1943 AC_DEFINE_UNQUOTED(LLVM_BINDIR, "$LLVM_BINDIR",
1944                    [Installation directory for binary executables])
1945 AC_DEFINE_UNQUOTED(LLVM_DATADIR, "$LLVM_DATADIR",
1946                    [Installation directory for data files])
1947 AC_DEFINE_UNQUOTED(LLVM_DOCSDIR, "$LLVM_DOCSDIR",
1948                    [Installation directory for documentation])
1949 AC_DEFINE_UNQUOTED(LLVM_ETCDIR, "$LLVM_ETCDIR",
1950                    [Installation directory for config files])
1951 AC_DEFINE_UNQUOTED(LLVM_INCLUDEDIR, "$LLVM_INCLUDEDIR",
1952                    [Installation directory for include files])
1953 AC_DEFINE_UNQUOTED(LLVM_INFODIR, "$LLVM_INFODIR",
1954                    [Installation directory for .info files])
1955 AC_DEFINE_UNQUOTED(LLVM_MANDIR, "$LLVM_MANDIR",
1956                    [Installation directory for man pages])
1957 AC_DEFINE_UNQUOTED(LLVM_CONFIGTIME, "$LLVM_CONFIGTIME",
1958                    [Time at which LLVM was configured])
1959 AC_DEFINE_UNQUOTED(LLVM_HOST_TRIPLE, "$host",
1960                    [Host triple LLVM will be executed on])
1961 AC_DEFINE_UNQUOTED(LLVM_DEFAULT_TARGET_TRIPLE, "$target",
1962                    [Target triple LLVM will generate code for by default])
1963
1964 dnl Determine which bindings to build.
1965 if test "$BINDINGS_TO_BUILD" = auto ; then
1966   BINDINGS_TO_BUILD=""
1967   if test "x$OCAMLC" != x -a "x$OCAMLDEP" != x ; then
1968     BINDINGS_TO_BUILD="ocaml $BINDINGS_TO_BUILD"
1969   fi
1970 fi
1971 AC_SUBST(BINDINGS_TO_BUILD,$BINDINGS_TO_BUILD)
1972
1973 dnl This isn't really configurey, but it avoids having to repeat the list in
1974 dnl other files.
1975 AC_SUBST(ALL_BINDINGS,ocaml)
1976
1977 dnl Do any work necessary to ensure that bindings have what they need.
1978 binding_prereqs_failed=0
1979 for a_binding in $BINDINGS_TO_BUILD ; do
1980   case "$a_binding" in
1981   ocaml)
1982     if test "x$OCAMLC" = x ; then
1983       AC_MSG_WARN([--enable-bindings=ocaml specified, but ocamlc not found. Try configure OCAMLC=/path/to/ocamlc])
1984       binding_prereqs_failed=1
1985     fi
1986     if test "x$OCAMLDEP" = x ; then
1987       AC_MSG_WARN([--enable-bindings=ocaml specified, but ocamldep not found. Try configure OCAMLDEP=/path/to/ocamldep])
1988       binding_prereqs_failed=1
1989     fi
1990     if test "x$OCAMLOPT" = x ; then
1991       AC_MSG_WARN([--enable-bindings=ocaml specified, but ocamlopt not found. Try configure OCAMLOPT=/path/to/ocamlopt])
1992       dnl ocamlopt is optional!
1993     fi
1994     if test "x$with_ocaml_libdir" != xauto ; then
1995       AC_SUBST(OCAML_LIBDIR,$with_ocaml_libdir)
1996     else
1997       ocaml_stdlib="`"$OCAMLC" -where`"
1998       if test "$LLVM_PREFIX" '<' "$ocaml_stdlib" -a "$ocaml_stdlib" '<' "$LLVM_PREFIX~"
1999       then
2000         # ocaml stdlib is beneath our prefix; use stdlib
2001         AC_SUBST(OCAML_LIBDIR,$ocaml_stdlib)
2002       else
2003         # ocaml stdlib is outside our prefix; use libdir/ocaml
2004         AC_SUBST(OCAML_LIBDIR,${prefix}/lib/ocaml)
2005       fi
2006     fi
2007     ;;
2008   esac
2009 done
2010 if test "$binding_prereqs_failed" = 1 ; then
2011   AC_MSG_ERROR([Prequisites for bindings not satisfied. Fix them or use configure --disable-bindings.])
2012 fi
2013
2014 dnl Determine whether the compiler supports -fvisibility-inlines-hidden.
2015 AC_CXX_USE_VISIBILITY_INLINES_HIDDEN
2016
2017 dnl Determine linker rpath flag
2018 if test "$llvm_cv_link_use_r" = "yes" ; then
2019   RPATH="-Wl,-R"
2020 else
2021   RPATH="-Wl,-rpath"
2022 fi
2023 AC_SUBST(RPATH)
2024
2025 dnl Determine linker rdynamic flag
2026 if test "$llvm_cv_link_use_export_dynamic" = "yes" ; then
2027   RDYNAMIC="-rdynamic"
2028 else
2029   RDYNAMIC=""
2030 fi
2031 AC_SUBST(RDYNAMIC)
2032
2033 dnl===-----------------------------------------------------------------------===
2034 dnl===
2035 dnl=== SECTION 10: Specify the output files and generate it
2036 dnl===
2037 dnl===-----------------------------------------------------------------------===
2038
2039 dnl Configure header files
2040 dnl WARNING: dnl If you add or remove any of the following config headers, then
2041 dnl you MUST also update Makefile so that the variable FilesToConfig
2042 dnl contains the same list of files as AC_CONFIG_HEADERS below. This ensures the
2043 dnl files can be updated automatically when their *.in sources change.
2044 AC_CONFIG_HEADERS([include/llvm/Config/config.h include/llvm/Config/llvm-config.h])
2045 AH_TOP([#ifndef CONFIG_H
2046 #define CONFIG_H])
2047 AH_BOTTOM([#endif])
2048
2049 AC_CONFIG_FILES([include/llvm/Config/Targets.def])
2050 AC_CONFIG_FILES([include/llvm/Config/AsmPrinters.def])
2051 AC_CONFIG_FILES([include/llvm/Config/AsmParsers.def])
2052 AC_CONFIG_FILES([include/llvm/Config/Disassemblers.def])
2053 AC_CONFIG_HEADERS([include/llvm/Support/DataTypes.h])
2054
2055 dnl Configure the makefile's configuration data
2056 AC_CONFIG_FILES([Makefile.config])
2057
2058 dnl Configure the RPM spec file for LLVM
2059 AC_CONFIG_FILES([llvm.spec])
2060
2061 dnl Configure doxygen's configuration file
2062 AC_CONFIG_FILES([docs/doxygen.cfg])
2063
2064 dnl Configure clang, if present
2065 if test "${clang_src_root}" = ""; then
2066   clang_src_root="$srcdir/tools/clang"
2067 fi
2068 if test -f ${clang_src_root}/README.txt; then
2069   dnl Use variables to stay under 80 columns.
2070   configh="include/clang/Config/config.h"
2071   doxy="docs/doxygen.cfg"
2072   AC_CONFIG_HEADERS([tools/clang/${configh}:${clang_src_root}/${configh}.in])
2073   AC_CONFIG_FILES([tools/clang/${doxy}:${clang_src_root}/${doxy}.in])
2074 fi
2075
2076 dnl OCaml findlib META file
2077 AC_CONFIG_FILES([bindings/ocaml/llvm/META.llvm])
2078
2079 dnl Add --program-prefix value to Makefile.rules. Already an ARG variable.
2080 test "x$program_prefix" = "xNONE" && program_prefix=""
2081 AC_SUBST([program_prefix])
2082
2083
2084 dnl Do special configuration of Makefiles
2085 AC_CONFIG_COMMANDS([setup],,[llvm_src="${srcdir}"])
2086 AC_CONFIG_MAKEFILE(Makefile)
2087 AC_CONFIG_MAKEFILE(Makefile.common)
2088 AC_CONFIG_MAKEFILE(examples/Makefile)
2089 AC_CONFIG_MAKEFILE(lib/Makefile)
2090 AC_CONFIG_MAKEFILE(test/Makefile)
2091 AC_CONFIG_MAKEFILE(test/Makefile.tests)
2092 AC_CONFIG_MAKEFILE(unittests/Makefile)
2093 AC_CONFIG_MAKEFILE(tools/Makefile)
2094 AC_CONFIG_MAKEFILE(utils/Makefile)
2095 AC_CONFIG_MAKEFILE(projects/Makefile)
2096 AC_CONFIG_MAKEFILE(bindings/Makefile)
2097 AC_CONFIG_MAKEFILE(bindings/ocaml/Makefile.ocaml)
2098
2099 dnl Finally, crank out the output
2100 AC_OUTPUT