autoconf/configure.ac

   1 dnl === configure.ac --------------------------------------------------------===
   2 dnl                     The LLVM Compiler Infrastructure
   3 dnl
   4 dnl This file was developed by the LLVM research group and is distributed under
   5 dnl the University of Illinois Open Source License. See LICENSE.TXT for details.
   6 dnl
   7 dnl===-----------------------------------------------------------------------===
   8 dnl This is the LLVM configuration script. It is processed by the autoconf
   9 dnl program to produce a script named configure. This script contains the
  10 dnl configuration checks that LLVM needs in order to support multiple platforms.
  11 dnl This file is composed of 10 sections per the recommended organization of
  12 dnl autoconf input defined in the autoconf documentation. As this file evolves,
  13 dnl please keep the various types of checks within their sections. The sections
  14 dnl are as follows:
  15 dnl
  16 dnl SECTION 1: Initialization & Setup
  17 dnl SECTION 2: Architecture, target, and host checks
  18 dnl SECTION 3: Command line arguments for the configure script.
  19 dnl SECTION 4: Check for programs we need and that they are the right version
  20 dnl SECTION 5: Check for libraries
  21 dnl SECTION 6: Check for header files
  22 dnl SECTION 7: Check for types and structures
  23 dnl SECTION 8: Check for specific functions needed
  24 dnl SECTION 9: Additional checks, variables, etc.
  25 dnl SECTION 10: Specify the output files and generate it
  26 dnl
  27 dnl===-----------------------------------------------------------------------===
  28 dnl===
  29 dnl=== SECTION 1: Initialization & Setup
  30 dnl===
  31 dnl===-----------------------------------------------------------------------===
  32 dnl Initialize autoconf and define the package name, version number and
  33 dnl email address for reporting bugs.
  34 AC_INIT([[llvm]],[[1.7cvs]],[llvmbugs@cs.uiuc.edu])
  35
  36 dnl Provide a copyright substitution and ensure the copyright notice is included
  37 dnl in the output of --version option of the generated configure script.
  38 AC_SUBST(LLVM_COPYRIGHT,["Copyright (c) 2003-2005 University of Illinois at Urbana-Champaign."])
  39 AC_COPYRIGHT([Copyright (c) 2003-2005 University of Illinois at Urbana-Champaign.])
  40
  41 dnl Indicate that we require autoconf 2.59 or later. Ths is needed because we
  42 dnl use some autoconf macros only available in 2.59.
  43 AC_PREREQ(2.59)
  44
  45 dnl Verify that the source directory is valid. This makes sure that we are
  46 dnl configuring LLVM and not some other package (it validates --srcdir argument)
  47 AC_CONFIG_SRCDIR([lib/VMCore/Module.cpp])
  48
  49 dnl Place all of the extra autoconf files into the config subdirectory. Tell
  50 dnl various tools where the m4 autoconf macros are.
  51 AC_CONFIG_AUX_DIR([autoconf])
  52
  53 dnl Quit if the source directory has already been configured.
  54 dnl NOTE: This relies upon undocumented autoconf behavior.
  55 if test ${srcdir} != "." ; then
  56   if test -f ${srcdir}/include/llvm/Config/config.h ; then
  57     AC_MSG_ERROR([Already configured in ${srcdir}])
  58   fi
  59 fi
  60
  61 dnl Configure all of the projects present in our source tree. While we could
  62 dnl just AC_CONFIG_SUBDIRS on the set of directories in projects that have a
  63 dnl configure script, that usage of the AC_CONFIG_SUBDIRS macro is deprecated.
  64 dnl Instead we match on the known projects.
  65 for i in `ls ${srcdir}/projects`
  66 do
  67   if test -d ${srcdir}/projects/${i} ; then
  68     case ${i} in
  69       "CVS") ;;
  70       "sample")       AC_CONFIG_SUBDIRS([projects/sample])    ;;
  71       "Stacker")      AC_CONFIG_SUBDIRS([projects/Stacker])   ;;
  72       "llvm-test")    AC_CONFIG_SUBDIRS([projects/llvm-test]) ;;
  73       "llvm-reopt")   AC_CONFIG_SUBDIRS([projects/llvm-reopt]);;
  74       "llvm-gcc")     AC_CONFIG_SUBDIRS([projects/llvm-gcc])  ;;
  75       "llvm-java")    AC_CONFIG_SUBDIRS([projects/llvm-java]) ;;
  76       "llvm-tv")      AC_CONFIG_SUBDIRS([projects/llvm-tv])   ;;
  77       "llvm-poolalloc") AC_CONFIG_SUBDIRS([projects/llvm-poolalloc]) ;;
  78       "llvm-kernel")  AC_CONFIG_SUBDIRS([projects/llvm-kernel]) ;;
  79       *)
  80         AC_MSG_WARN([Unknown project (${i}) won't be configured automatically])
  81         ;;
  82     esac
  83   fi
  84 done
  85
  86 dnl===-----------------------------------------------------------------------===
  87 dnl===
  88 dnl=== SECTION 2: Architecture, target, and host checks
  89 dnl===
  90 dnl===-----------------------------------------------------------------------===
  91
  92 dnl Check the target for which we're compiling and the host that will do the
  93 dnl compilations. This will tell us which LLVM compiler will be used for
  94 dnl compiling SSA into object code. This needs to be done early because
  95 dnl following tests depend on it.
  96 AC_CANONICAL_TARGET
  97
  98 dnl Determine the platform type and cache its value. This helps us configure
  99 dnl the System library to the correct build platform.
 100 AC_CACHE_CHECK([type of operating system we're on],
 101                [llvm_cv_os_type],
 102 [case $build in
 103   *-*-aix*)
 104     llvm_cv_os_type="AIX"
 105     llvm_cv_platform_type="Unix" ;;
 106   *-*-cygwin*)
 107     llvm_cv_os_type="Cygwin"
 108     llvm_cv_platform_type="Unix" ;;
 109   *-*-darwin*)
 110     llvm_cv_os_type="Darwin"
 111     llvm_cv_platform_type="Unix" ;;
 112   *-*-freebsd*)
 113     llvm_cv_os_type="FreeBSD"
 114     llvm_cv_platform_type="Unix" ;;
 115   *-*-hpux*)
 116     llvm_cv_os_type="HP-UX"
 117     llvm_cv_platform_type="Unix" ;;
 118   *-*-interix*)
 119     llvm_cv_os_type="Interix"
 120     llvm_cv_platform_type="Unix" ;;
 121   *-*-linux*)
 122     llvm_cv_os_type="Linux"
 123     llvm_cv_platform_type="Unix" ;;
 124   *-*-solaris*)
 125     llvm_cv_os_type="SunOS"
 126     llvm_cv_platform_type="Unix" ;;
 127   *-*-win32*)
 128     llvm_cv_os_type="Win32"
 129     llvm_cv_platform_type="Win32" ;;
 130   *-*-mingw*)
 131     llvm_cv_os_type="MingW"
 132     llvm_cv_platform_type="Win32" ;;
 133   *)
 134     llvm_cv_os_type="Unknown"
 135     llvm_cv_platform_type="Unknown" ;;
 136 esac])
 137
 138 dnl Make sure we aren't attempting to configure for an unknown system
 139 if test "$llvm_cv_os_type" = "Unknown" ; then
 140   AC_MSG_ERROR([Operating system is unknown, configure can't continue])
 141 fi
 142
 143 dnl Set the "OS" Makefile variable based on the platform type so the
 144 dnl makefile can configure itself to specific build hosts
 145 AC_SUBST(OS,$llvm_cv_os_type)
 146
 147 dnl Set the "LLVM_ON_*" variables based on llvm_cvs_platform_type
 148 dnl This is used by lib/System to determine the basic kind of implementation
 149 dnl to use.
 150 case $llvm_cv_platform_type in
 151   Unix)
 152     AC_DEFINE([LLVM_ON_UNIX],[1],[Define if this is Unixish platform])
 153     AC_SUBST(LLVM_ON_UNIX,[1])
 154     AC_SUBST(LLVM_ON_WIN32,[0])
 155     ;;
 156   Win32)
 157     AC_DEFINE([LLVM_ON_WIN32],[1],[Define if this is Win32ish platform])
 158     AC_SUBST(LLVM_ON_UNIX,[0])
 159     AC_SUBST(LLVM_ON_WIN32,[1])
 160     ;;
 161 esac
 162
 163 dnl Determine what our target architecture is and configure accordingly.
 164 dnl This will allow Makefiles to make a distinction between the hardware and
 165 dnl the OS.
 166 AC_CACHE_CHECK([target architecture],[llvm_cv_target_arch],
 167 [case $target in
 168   i?86-*)                 llvm_cv_target_arch="x86" ;;
 169   amd64-* | x86_64-*)     llvm_cv_target_arch="x86_64" ;;
 170   sparc*-*)               llvm_cv_target_arch="Sparc" ;;
 171   powerpc*-*)             llvm_cv_target_arch="PowerPC" ;;
 172   alpha*-*)               llvm_cv_target_arch="Alpha" ;;
 173   ia64-*)                 llvm_cv_target_arch="IA64" ;;
 174   *)                      llvm_cv_target_arch="Unknown" ;;
 175 esac])
 176
 177 if test "$llvm_cv_target_arch" = "Unknown" ; then
 178   AC_MSG_WARN([Configuring LLVM for an unknown target archicture])
 179 fi
 180
 181 dnl Define a substitution, ARCH, for the target architecture
 182 AC_SUBST(ARCH,$llvm_cv_target_arch)
 183
 184 dnl Check for the endianness of the target
 185 AC_C_BIGENDIAN(AC_SUBST([ENDIAN],[big]),AC_SUBST([ENDIAN],[little]))
 186
 187 dnl Check to see if there's a "CVS" directory indicating that this build is
 188 dnl being done from a CVS checkout. This sets up several defaults for the
 189 dnl command line switches. When we build with a CVS directory, we get a
 190 dnl debug with assertions turned on. Without, we assume a source release and we
 191 dnl get an optimized build without assertions. See --enable-optimized and
 192 dnl --enable-assertions below
 193 if test -d "CVS" ; then
 194   cvsbuild="yes"
 195   optimize="no"
 196   asserts="yes"
 197   AC_SUBST(CVSBUILD,[[CVSBUILD=1]])
 198 else
 199   cvsbuild="no"
 200   optimize="yes"
 201   asserts="no"
 202 fi
 203
 204 dnl===-----------------------------------------------------------------------===
 205 dnl===
 206 dnl=== SECTION 3: Command line arguments for the configure script.
 207 dnl===
 208 dnl===-----------------------------------------------------------------------===
 209
 210 dnl --enable-optimized : check whether they want to do an optimized build:
 211 AC_ARG_ENABLE(optimized, AS_HELP_STRING(
 212  [--enable-optimized,Compile with optimizations enabled (default is NO)]),,enableval=$optimize)
 213 if test ${enableval} = "no" ; then
 214   AC_SUBST(ENABLE_OPTIMIZED,[[]])
 215 else
 216   AC_SUBST(ENABLE_OPTIMIZED,[[ENABLE_OPTIMIZED=1]])
 217 fi
 218
 219 dnl --enable-assertions : check whether they want to turn on assertions or not:
 220 AC_ARG_ENABLE(assertions,AS_HELP_STRING(
 221   [--enable-assertions,Compile with assertion checks enabled (default is NO)]),, enableval=$asserts)
 222 if test ${enableval} = "no" ; then
 223   AC_SUBST(ENABLE_ASSERTIONS,[[]])
 224 else
 225   AC_SUBST(ENABLE_ASSERTIONS,[[ENABLE_ASSERTIONS=1]])
 226 fi
 227
 228 dnl --enable-debug-runtime : should runtime libraries have debug symbols?
 229 AC_ARG_ENABLE(debug-runtime,
 230    AS_HELP_STRING([--enable-debug-runtime,Build runtime libs with debug symbols (default is NO)]),,enableval=no)
 231 if test ${enableval} = "no" ; then
 232   AC_SUBST(DEBUG_RUNTIME,[[]])
 233 else
 234   AC_SUBST(DEBUG_RUNTIME,[[DEBUG_RUNTIME=1]])
 235 fi
 236
 237 dnl --enable-jit: check whether they want to enable the jit
 238 AC_ARG_ENABLE(jit,
 239   AS_HELP_STRING(--enable-jit,
 240                  [Enable Just In Time Compiling (default is YES)]),,
 241   enableval=default)
 242 if test ${enableval} = "no"
 243 then
 244   AC_SUBST(JIT,[[]])
 245 else
 246   case "$llvm_cv_target_arch" in
 247     x86)     AC_SUBST(TARGET_HAS_JIT,1) ;;
 248     Sparc)   AC_SUBST(TARGET_HAS_JIT,1) ;;
 249     PowerPC) AC_SUBST(TARGET_HAS_JIT,1) ;;
 250     x86_64)  AC_SUBST(TARGET_HAS_JIT,0) ;;
 251     Alpha)   AC_SUBST(TARGET_HAS_JIT,1) ;;
 252     IA64)    AC_SUBST(TARGET_HAS_JIT,0) ;;
 253     *)       AC_SUBST(TARGET_HAS_JIT,0) ;;
 254   esac
 255 fi
 256
 257 dnl Allow enablement of doxygen generated documentation
 258 AC_ARG_ENABLE(doxygen,
 259               AS_HELP_STRING([--enable-doxygen],
 260                              [Build doxygen documentation (default is NO)]),,
 261                              enableval=default)
 262 case "$enableval" in
 263   yes) AC_SUBST(ENABLE_DOXYGEN,[1]) ;;
 264   no)  AC_SUBST(ENABLE_DOXYGEN,[0]) ;;
 265   default) AC_SUBST(ENABLE_DOXYGEN,[0]) ;;
 266   *) AC_MSG_ERROR([Invalid setting for --enable-doxygen. Use "yes" or "no"]) ;;
 267 esac
 268
 269 dnl Allow disablement of threads
 270 AC_ARG_ENABLE(threads,
 271               AS_HELP_STRING([--enable-threads],
 272                              [Use threads if available (default is YES)]),,
 273                              enableval=yes)
 274 case "$enableval" in
 275   yes) AC_SUBST(ENABLE_THREADS,[1]) ;;
 276   no)  AC_SUBST(ENABLE_THREADS,[0]) ;;
 277   *) AC_MSG_ERROR([Invalid setting for --enable-threads. Use "yes" or "no"]) ;;
 278 esac
 279 AC_DEFINE_UNQUOTED([ENABLE_THREADS],$ENABLE_THREADS,[Define if threads enabled])
 280
 281 dnl Allow specific targets to be specified for building (or not)
 282 TARGETS_TO_BUILD=""
 283 AC_ARG_ENABLE([targets],AS_HELP_STRING([--enable-target],
 284     [Build specific host targets: all,host-only,{target-name} (default=all)]),,
 285     enableval=all)
 286 case "$enableval" in
 287   all) TARGETS_TO_BUILD="X86 Sparc SparcV9 PowerPC Alpha IA64" ;;
 288   host-only)
 289     case "$llvm_cv_target_arch" in
 290       x86)     TARGETS_TO_BUILD="X86" ;;
 291       x86_64)  TARGETS_TO_BUILD="X86" ;;
 292       Sparc)   TARGETS_TO_BUILD="Sparc SparcV9" ;;
 293       PowerPC) TARGETS_TO_BUILD="PowerPC" ;;
 294       Alpha)   TARGETS_TO_BUILD="Alpha" ;;
 295       IA64)    TARGETS_TO_BUILD="IA64" ;;
 296       *)       AC_MSG_ERROR([Can not set target to build]) ;;
 297     esac
 298     ;;
 299   *)for a_target in `echo $enableval|sed -e 's/,/ /g' ` ; do
 300       case "$a_target" in
 301         x86)     TARGETS_TO_BUILD="X86 $TARGETS_TO_BUILD" ;;
 302         x86_64)  TARGETS_TO_BUILD="X86 $TARGETS_TO_BUILD" ;;
 303         sparc)   TARGETS_TO_BUILD="Sparc SparcV9 $TARGETS_TO_BUILD" ;;
 304         powerpc) TARGETS_TO_BUILD="PowerPC $TARGETS_TO_BUILD" ;;
 305         alpha)   TARGETS_TO_BUILD="Alpha $TARGETS_TO_BUILD" ;;
 306         ia64)    TARGETS_TO_BUILD="IA64 $TARGETS_TO_BUILD" ;;
 307         *) AC_MSG_ERROR([Unrecognized target $a_target]) ;;
 308       esac
 309   done
 310   ;;
 311 esac
 312 TARGETS_TO_BUILD="CBackend $TARGETS_TO_BUILD"
 313 AC_SUBST(TARGETS_TO_BUILD,$TARGETS_TO_BUILD)
 314
 315 dnl Allow a specific llvm-gcc/llvm-g++ pair to be used with this LLVM config.
 316 AC_ARG_WITH(llvmgccdir,
 317   AS_HELP_STRING([--with-llvmgccdir],
 318     [Specify location of llvm-gcc install dir (default searches PATH)]),,
 319     withval=default)
 320 case "$withval" in
 321   default) WITH_LLVMGCCDIR=default ;;
 322   /*)      WITH_LLVMGCCDIR=$withval ;;
 323   *) AC_MSG_ERROR([Invalid path for --with-llvmgccdir. Provide full path]) ;;
 324 esac
 325
 326
 327 dnl===-----------------------------------------------------------------------===
 328 dnl===
 329 dnl=== SECTION 4: Check for programs we need and that they are the right version
 330 dnl===
 331 dnl===-----------------------------------------------------------------------===
 332
 333 dnl Check for compilation tools
 334 AC_PROG_CPP
 335 AC_PROG_CC(gcc)
 336 AC_PROG_CXX(g++)
 337 AC_PROG_FLEX
 338 AC_PROG_BISON
 339
 340 dnl Check for the tools that the makefiles require
 341 AC_CHECK_GNU_MAKE
 342 AC_PROG_LN_S
 343 AC_PATH_PROG(CMP, [cmp], [cmp])
 344 AC_PATH_PROG(CP, [cp], [cp])
 345 AC_PATH_PROG(DATE, [date], [date])
 346 AC_PATH_PROG(FIND, [find], [find])
 347 AC_PATH_PROG(GREP, [grep], [grep])
 348 AC_PATH_PROG(MKDIR,[mkdir],[mkdir])
 349 AC_PATH_PROG(MV,   [mv],   [mv])
 350 AC_PROG_RANLIB
 351 AC_PATH_PROG(RM,   [rm],   [rm])
 352 AC_PATH_PROG(SED,  [sed],  [sed])
 353 AC_PATH_PROG(TAR,  [tar],  [gtar])
 354 AC_PATH_PROG(GRAPHVIZ, [Graphviz], [echo Graphviz])
 355 if test "$GRAPHVIZ" != "echo Graphviz" ; then
 356   AC_DEFINE([HAVE_GRAPHVIZ],[1],[Define if the Graphviz program is available])
 357   AC_DEFINE_UNQUOTED([LLVM_PATH_GRAPHVIZ],"$GRAPHVIZ",
 358    [Define to path to Graphviz program if found or 'echo Graphviz' otherwise])
 359 fi
 360 AC_PATH_PROG(GV, [gv], [echo gv])
 361 if test "$GV" != "echo gv" ; then
 362   AC_DEFINE([HAVE_GV],[1],[Define if the gv program is available])
 363   AC_DEFINE_UNQUOTED([LLVM_PATH_GV],"$GV",
 364    [Define to path to gv program if found or 'echo gv' otherwise])
 365 fi
 366
 367 dnl Look for a sufficiently recent version of Perl.
 368 LLVM_PROG_PERL([5.006])
 369 AC_SUBST(PERL)
 370 if test x"$PERL" = xnone; then
 371    AC_SUBST(HAVE_PERL,0)
 372 else
 373    AC_SUBST(HAVE_PERL,1)
 374 fi
 375
 376 dnl Find the install program
 377 AC_PROG_INSTALL
 378
 379 dnl Checks for documentation and testing tools that we can do without. If these
 380 dnl are not found then they are set to "true" which always succeeds but does
 381 dnl nothing. This just lets the build output show that we could have done
 382 dnl something if the tool was available.
 383 AC_PATH_PROG(BZIP2,[bzip2],[true bzip2])
 384 AC_PATH_PROG(DOT,[dot],[true dot])
 385 AC_PATH_PROG(DOXYGEN,[doxygen],[true doxygen])
 386 AC_PATH_PROG(ETAGS,[etags],[true etags])
 387 AC_PATH_PROG(GROFF,[groff],[true groff])
 388 AC_PATH_PROG(GZIP,[gzip],[true gzip])
 389 AC_PATH_PROG(POD2HTML,[pod2html],[true pod2html])
 390 AC_PATH_PROG(POD2MAN,[pod2man],[true pod2man])
 391 AC_PATH_PROG(RUNTEST,[runtest],[true runtest])
 392 DJ_AC_PATH_TCLSH
 393 AC_PATH_PROG(ZIP,[zip],[true zip])
 394
 395 dnl Determine if the linker supports the -R option.
 396 AC_LINK_USE_R
 397
 398 dnl Check for libtool and the library that has dlopen function (which must come
 399 dnl before the AC_PROG_LIBTOOL check in order to enable dlopening libraries with
 400 dnl libtool).
 401 AC_LIBTOOL_DLOPEN
 402 AC_LIB_LTDL
 403 AC_PROG_LIBTOOL
 404
 405 if test "$lt_cv_dlopen_self" = "yes" ; then
 406   AC_DEFINE([CAN_DLOPEN_SELF],[1],
 407               [Define if dlopen(0) will open the symbols of the program])
 408 fi
 409
 410 dnl Check if we know how to tell etags we are using C++:
 411 etags_version=`$ETAGS --version 2>&1`
 412 case "$etags_version" in
 413         *[Ee]xuberant*) ETAGSFLAGS="--language-force=c++" ;;
 414         *GNU\ Emacs*) ETAGSFLAGS="-l c++" ;;
 415         *) ETAGSFLAGS="" ;;
 416 esac
 417 AC_SUBST(ETAGSFLAGS,$ETAGSFLAGS)
 418
 419 if test "$WITH_LLVMGCCDIR" = "default" ; then
 420   LLVMGCC="llvm-gcc${EXEEXT}"
 421   LLVMGXX="llvm-g++${EXEEXT}"
 422   AC_PATH_PROG(LLVMGCC, $LLVMGCC, [])
 423   AC_PATH_PROG(LLVMGXX, $LLVMGXX, [])
 424 else
 425   LLVMGCC="$WITH_LLVMGCCDIR/bin/llvm-gcc${EXEEXT}"
 426   LLVMGXX="$WITH_LLVMGCCDIR/bin/llvm-g++${EXEEXT}"
 427   AC_SUBST(LLVMGCC,$LLVMGCC)
 428   AC_SUBST(LLVMGXX,$LLVMGXX)
 429 fi
 430
 431 AC_MSG_CHECKING([tool compatibility])
 432
 433 dnl Ensure that compilation tools are GCC or a GNU compatible compiler such as
 434 dnl ICC; we use GCC specific options in the makefiles so the compiler needs
 435 dnl to support those options.
 436 dnl "icc" emits gcc signatures
 437 dnl "icc -no-gcc" emits no gcc signature BUT is still compatible
 438 ICC=no
 439 IXX=no
 440 case $CC in
 441   icc*|icpc*)
 442     ICC=yes
 443     IXX=yes
 444     ;;
 445    *)
 446     ;;
 447 esac
 448
 449 if test "$GCC" != "yes" && test "$ICC" != "yes"
 450 then
 451   AC_MSG_ERROR([gcc|icc required but not found])
 452 fi
 453
 454 dnl Ensure that compilation tools are GCC; we use GCC specific extensions
 455 if test "$GXX" != "yes" && test "$IXX" != "yes"
 456 then
 457   AC_MSG_ERROR([g++|icc required but not found])
 458 fi
 459
 460 dnl Verify that GCC is version 3.0 or higher
 461 if test "$GCC" = "yes"
 462 then
 463   gccmajor=`$CC --version | head -n 1 | sed 's/[[^0-9]]*\([[0-9.]]\).*/\1/'`
 464   if test "$gccmajor" -lt "3"
 465   then
 466     AC_MSG_ERROR([gcc 3.x required, but you have a lower version])
 467   fi
 468 fi
 469
 470 dnl Check for GNU Make.  We use its extensions, so don't build without it
 471 if test -z "$llvm_cv_gnu_make_command"
 472 then
 473   AC_MSG_ERROR([GNU Make required but not found])
 474 fi
 475
 476 dnl Tool compatibility is okay if we make it here.
 477 AC_MSG_RESULT([ok])
 478
 479 dnl===-----------------------------------------------------------------------===
 480 dnl===
 481 dnl=== SECTION 5: Check for libraries
 482 dnl===
 483 dnl===-----------------------------------------------------------------------===
 484
 485 dnl libelf is for sparc only; we can ignore it if we don't have it
 486 AC_CHECK_LIB(elf, elf_begin)
 487 AC_CHECK_LIB(m,sin)
 488
 489 dnl lt_dlopen may be required for plugin support.
 490 AC_SEARCH_LIBS(lt_dlopen,ltdl,AC_DEFINE([HAVE_LT_DLOPEN],[1],
 491               [Define if lt_dlopen() is available on this platform]),
 492               AC_MSG_WARN([lt_dlopen() not found - plugin support might
 493                            not be available]))
 494
 495 dnl dlopen() is required for plugin support.
 496 AC_SEARCH_LIBS(dlopen,dl,AC_DEFINE([HAVE_DLOPEN],[1],
 497                [Define if dlopen() is available on this platform.]),
 498                AC_MSG_WARN([dlopen() not found - disabling plugin support]))
 499
 500 dnl mallinfo is optional; the code can compile (minus features) without it
 501 AC_SEARCH_LIBS(mallinfo,malloc,AC_DEFINE([HAVE_MALLINFO],[1],
 502                [Define if mallinfo() is available on this platform.]))
 503
 504 dnl pthread locking functions are optional - but llvm will not be thread-safe
 505 dnl without locks.
 506 if test "$ENABLE_THREADS" -eq 1 ; then
 507   AC_CHECK_LIB(pthread,pthread_mutex_init)
 508   AC_SEARCH_LIBS(pthread_mutex_lock,pthread,
 509                  AC_DEFINE([HAVE_PTHREAD_MUTEX_LOCK],[1],
 510                            [Have pthread_mutex_lock]))
 511 fi
 512
 513 dnl===-----------------------------------------------------------------------===
 514 dnl===
 515 dnl=== SECTION 6: Check for header files
 516 dnl===
 517 dnl===-----------------------------------------------------------------------===
 518
 519 dnl First, use autoconf provided macros for specific headers that we need
 520 dnl We don't check for ancient stuff or things that are guaranteed to be there
 521 dnl by the C++ standard. We always use the <cfoo> versions of <foo.h> C headers.
 522 dnl Generally we're looking for POSIX headers.
 523 AC_HEADER_DIRENT
 524 AC_HEADER_MMAP_ANONYMOUS
 525 AC_HEADER_STAT
 526 AC_HEADER_STDC
 527 AC_HEADER_SYS_WAIT
 528 AC_HEADER_TIME
 529
 530 AC_CHECK_HEADERS([dlfcn.h execinfo.h fcntl.h inttypes.h limits.h link.h])
 531 AC_CHECK_HEADERS([malloc.h signal.h stdint.h unistd.h utime.h windows.h])
 532 AC_CHECK_HEADERS([sys/mman.h sys/param.h sys/resource.h sys/time.h sys/types.h])
 533 AC_CHECK_HEADERS([malloc/malloc.h])
 534 if test "$ENABLE_THREADS" -eq 1 ; then
 535   AC_CHECK_HEADERS(pthread.h)
 536 fi
 537
 538 dnl===-----------------------------------------------------------------------===
 539 dnl===
 540 dnl=== SECTION 7: Check for types and structures
 541 dnl===
 542 dnl===-----------------------------------------------------------------------===
 543
 544 AC_TYPE_PID_T
 545 AC_TYPE_SIZE_T
 546 AC_TYPE_SIGNAL
 547 AC_STRUCT_TM
 548 AC_CHECK_TYPES([int64_t],,AC_MSG_ERROR([Type int64_t required but not found]))
 549 AC_CHECK_TYPES([uint64_t],,
 550          AC_CHECK_TYPES([u_int64_t],,
 551          AC_MSG_ERROR([Type uint64_t or u_int64_t required but not found])))
 552
 553 dnl===-----------------------------------------------------------------------===
 554 dnl===
 555 dnl=== SECTION 8: Check for specific functions needed
 556 dnl===
 557 dnl===-----------------------------------------------------------------------===
 558
 559 AC_CHECK_FUNCS([backtrace ceilf floorf roundf rintf nearbyintf getcwd ])
 560 AC_CHECK_FUNCS([getpagesize getrusage gettimeofday isatty mkdtemp mkstemp ])
 561 AC_CHECK_FUNCS([mktemp realpath sbrk setrlimit strdup strerror strerror_r ])
 562 AC_CHECK_FUNCS([strtoll strtoq sysconf malloc_zone_statistics ])
 563 AC_C_PRINTF_A
 564 AC_FUNC_ALLOCA
 565 AC_FUNC_RAND48
 566
 567 dnl Check for variations in the Standard C++ library and STL. These macros are
 568 dnl provided by LLVM in the autoconf/m4 directory.
 569 AC_CXX_HAVE_HASH_MAP
 570 AC_CXX_HAVE_HASH_SET
 571 AC_CXX_HAVE_STD_ITERATOR
 572 AC_CXX_HAVE_BI_ITERATOR
 573 AC_CXX_HAVE_FWD_ITERATOR
 574 AC_FUNC_ISNAN
 575 AC_FUNC_ISINF
 576
 577 dnl Check for mmap and mprotect support. We need both to do the JIT and for
 578 dnl bytecode loading, etc. We also need to know if /dev/zero is required to
 579 dnl be opened for allocating RWX memory.
 580 AC_FUNC_MMAP
 581 AC_FUNC_MMAP_FILE
 582 AC_NEED_DEV_ZERO_FOR_MMAP
 583 AC_CHECK_FUNC(mprotect,,
 584               AC_MSG_ERROR([Function mprotect() required but not found]))
 585
 586 if test "$ac_cv_func_mmap_fixed_mapped" = "no"
 587 then
 588   AC_MSG_WARN([mmap() of a fixed address required but not supported])
 589 fi
 590 if test "$ac_cv_func_mmap_file" = "no"
 591 then
 592   AC_MSG_WARN([mmap() of files required but not found])
 593 fi
 594
 595 dnl===-----------------------------------------------------------------------===
 596 dnl===
 597 dnl=== SECTION 9: Additional checks, variables, etc.
 598 dnl===
 599 dnl===-----------------------------------------------------------------------===
 600
 601 dnl See if the llvm-gcc executable can compile to LLVM assembly
 602 AC_CACHE_CHECK([whether llvm-gcc is sane],[llvm_cv_llvmgcc_sanity],
 603 [llvm_cv_llvmgcc_sanity="no"
 604 if test -x "$LLVMGCC" ; then
 605   cp /dev/null conftest.c
 606   "$LLVMGCC" -emit-llvm -S -o - conftest.c | grep implementation > /dev/null 2>&1
 607   if test $? -eq 0 ; then
 608     llvm_cv_llvmgcc_sanity="yes"
 609   fi
 610   rm conftest.c
 611 fi])
 612
 613 dnl Since we have a sane llvm-gcc, identify it and its sub-tools
 614 if test "$llvm_cv_llvmgcc_sanity" = "yes" ; then
 615   llvmcc1path=`"$LLVMGCC" --print-prog-name=cc1`
 616   AC_SUBST(LLVMCC1,$llvmcc1path)
 617   llvmcc1pluspath=`"$LLVMGCC" --print-prog-name=cc1plus`
 618   AC_SUBST(LLVMCC1PLUS,$llvmcc1pluspath)
 619   llvmgccdir=`echo "$llvmcc1path" | sed 's,/libexec/.*,,'`
 620   AC_SUBST(LLVMGCCDIR,$llvmgccdir)
 621   llvmgccversion=[`"$LLVMGCC" -v 2>&1 | grep '^gcc version' | sed 's/^gcc version \([0-9.]*\).*/\1/'`]
 622   llvmgccmajvers=[`echo $llvmgccversion | sed 's/^\([0-9]\).*/\1/'`]
 623   AC_SUBST(LLVMGCC_VERSION,$llvmgccversion)
 624   AC_SUBST(LLVMGCC_MAJVERS,$llvmgccmajvers)
 625 fi
 626
 627 dnl Propagate the shared library extension that the libltdl checks did to
 628 dnl the Makefiles so we can use it there too
 629 AC_SUBST(SHLIBEXT,$libltdl_cv_shlibext)
 630
 631 # Translate the various configuration directories and other basic
 632 # information into substitutions that will end up in Makefile.config.in
 633 # that these configured values can be used by the makefiles
 634 eval LLVM_PREFIX="${prefix}";
 635 eval LLVM_BINDIR="${prefix}/bin";
 636 eval LLVM_LIBDIR="${prefix}/lib";
 637 eval LLVM_DATADIR="${prefix}/share/llvm";
 638 eval LLVM_DOCSDIR="${prefix}/docs/llvm";
 639 eval LLVM_ETCDIR="${prefix}/etc/llvm";
 640 eval LLVM_INCLUDEDIR="${prefix}/include";
 641 eval LLVM_INFODIR="${prefix}/info";
 642 eval LLVM_MANDIR="${prefix}/man";
 643 LLVM_CONFIGTIME=`date`
 644 AC_SUBST(LLVM_PREFIX)
 645 AC_SUBST(LLVM_BINDIR)
 646 AC_SUBST(LLVM_LIBDIR)
 647 AC_SUBST(LLVM_DATADIR)
 648 AC_SUBST(LLVM_DOCSDIR)
 649 AC_SUBST(LLVM_ETCDIR)
 650 AC_SUBST(LLVM_INCLUDEDIR)
 651 AC_SUBST(LLVM_INFODIR)
 652 AC_SUBST(LLVM_MANDIR)
 653 AC_SUBST(LLVM_CONFIGTIME)
 654
 655 # Place the various directores into the config.h file as #defines so that we
 656 # can know about the installation paths within LLVM.
 657 AC_DEFINE_UNQUOTED(LLVM_PREFIX,"$LLVM_PREFIX",
 658                    [Installation prefix directory])
 659 AC_DEFINE_UNQUOTED(LLVM_BINDIR, "$LLVM_BINDIR",
 660                    [Installation directory for binary executables])
 661 AC_DEFINE_UNQUOTED(LLVM_LIBDIR, "$LLVM_LIBDIR",
 662                    [Installation directory for libraries])
 663 AC_DEFINE_UNQUOTED(LLVM_DATADIR, "$LLVM_DATADIR",
 664                    [Installation directory for data files])
 665 AC_DEFINE_UNQUOTED(LLVM_DATADIR, "$LLVM_DOCSDIR",
 666                    [Installation directory for documentation])
 667 AC_DEFINE_UNQUOTED(LLVM_ETCDIR, "$LLVM_ETCDIR",
 668                    [Installation directory for config files])
 669 AC_DEFINE_UNQUOTED(LLVM_INCLUDEDIR, "$LLVM_INCLUDEDIR",
 670                    [Installation directory for include files])
 671 AC_DEFINE_UNQUOTED(LLVM_INFODIR, "$LLVM_INFODIR",
 672                    [Installation directory for .info files])
 673 AC_DEFINE_UNQUOTED(LLVM_MANDIR, "$LLVM_MANDIR",
 674                    [Installation directory for man pages])
 675 AC_DEFINE_UNQUOTED(LLVM_CONFIGTIME, "$LLVM_CONFIGTIME",
 676                    [Time at which LLVM was configured])
 677
 678 dnl===-----------------------------------------------------------------------===
 679 dnl===
 680 dnl=== SECTION 10: Specify the output files and generate it
 681 dnl===
 682 dnl===-----------------------------------------------------------------------===
 683
 684 dnl Configure header files
 685 dnl WARNING: dnl If you add or remove any of the following config headers, then
 686 dnl you MUST also update Makefile.rules so that the variable FilesToConfig
 687 dnl contains the same list of files as AC_CONFIG_HEADERS below. This ensures the
 688 dnl files can be updated automatically when their *.in sources change.
 689 AC_CONFIG_HEADERS([include/llvm/Config/config.h])
 690 AC_CONFIG_HEADERS([include/llvm/Support/DataTypes.h])
 691 AC_CONFIG_HEADERS([include/llvm/ADT/hash_map])
 692 AC_CONFIG_HEADERS([include/llvm/ADT/hash_set])
 693 AC_CONFIG_HEADERS([include/llvm/ADT/iterator])
 694
 695 dnl Configure the makefile's configuration data
 696 AC_CONFIG_FILES([Makefile.config])
 697
 698 dnl Configure doxygen's configuration file
 699 AC_CONFIG_FILES([docs/doxygen.cfg])
 700
 701 dnl Do the first stage of configuration for llvm-config.in.
 702 AC_CONFIG_FILES([utils/llvm-config/llvm-config.in])
 703
 704 dnl Do special configuration of Makefiles
 705 AC_CONFIG_COMMANDS([setup],,[llvm_src="${srcdir}"])
 706 AC_CONFIG_MAKEFILE(Makefile)
 707 AC_CONFIG_MAKEFILE(Makefile.common)
 708 AC_CONFIG_MAKEFILE(examples/Makefile)
 709 AC_CONFIG_MAKEFILE(lib/Makefile)
 710 AC_CONFIG_MAKEFILE(runtime/Makefile)
 711 AC_CONFIG_MAKEFILE(test/Makefile)
 712 AC_CONFIG_MAKEFILE(test/Makefile.tests)
 713 AC_CONFIG_MAKEFILE(tools/Makefile)
 714 AC_CONFIG_MAKEFILE(utils/Makefile)
 715 AC_CONFIG_MAKEFILE(projects/Makefile)
 716
 717 dnl Finally, crank out the output
 718 AC_OUTPUT
 719
 720 dnl Warn loudly if llvm-gcc was not obviously working
 721 if test "$llvm_cv_llvmgcc_sanity" = "no" ; then
 722  AC_MSG_WARN([***** llvm-gcc/llvm-g++ was not found, or does not appear to be ])
 723  AC_MSG_WARN([***** working. Please make sure you have llvmgcc and llvmg++ in])
 724  AC_MSG_WARN([***** your path before configuring LLVM. The runtime libraries])
 725  AC_MSG_WARN([***** (llvm/runtime) will not be built but you should be able to])
 726  AC_MSG_WARN([***** build the llvm tools.])
 727 fi