autoconf/configure.ac

   1 dnl === configure.ac --------------------------------------------------------===
   2 dnl                     The LLVM Compiler Infrastructure
   3 dnl
   4 dnl This file is distributed under the University of Illinois Open Source
   5 dnl License. See LICENSE.TXT for details.
   6 dnl
   7 dnl===-----------------------------------------------------------------------===
   8 dnl This is the LLVM configuration script. It is processed by the autoconf
   9 dnl program to produce a script named configure. This script contains the
  10 dnl configuration checks that LLVM needs in order to support multiple platforms.
  11 dnl This file is composed of 10 sections per the recommended organization of
  12 dnl autoconf input defined in the autoconf documentation. As this file evolves,
  13 dnl please keep the various types of checks within their sections. The sections
  14 dnl are as follows:
  15 dnl
  16 dnl SECTION 1: Initialization & Setup
  17 dnl SECTION 2: Architecture, target, and host checks
  18 dnl SECTION 3: Command line arguments for the configure script.
  19 dnl SECTION 4: Check for programs we need and that they are the right version
  20 dnl SECTION 5: Check for libraries
  21 dnl SECTION 6: Check for header files
  22 dnl SECTION 7: Check for types and structures
  23 dnl SECTION 8: Check for specific functions needed
  24 dnl SECTION 9: Additional checks, variables, etc.
  25 dnl SECTION 10: Specify the output files and generate it
  26 dnl
  27 dnl===-----------------------------------------------------------------------===
  28 dnl===
  29 dnl=== SECTION 1: Initialization & Setup
  30 dnl===
  31 dnl===-----------------------------------------------------------------------===
  32 dnl Initialize autoconf and define the package name, version number and
  33 dnl address for reporting bugs.
  34 AC_INIT([LLVM],[3.5svn],[http://llvm.org/bugs/])
  35 AC_DEFINE([LLVM_VERSION_MAJOR], [3], [Major version of the LLVM API])
  36 AC_DEFINE([LLVM_VERSION_MINOR], [5], [Minor version of the LLVM API])
  37
  38 dnl Provide a copyright substitution and ensure the copyright notice is included
  39 dnl in the output of --version option of the generated configure script.
  40 AC_SUBST(LLVM_COPYRIGHT,["Copyright (c) 2003-2014 University of Illinois at Urbana-Champaign."])
  41 AC_COPYRIGHT([Copyright (c) 2003-2014 University of Illinois at Urbana-Champaign.])
  42
  43 dnl Indicate that we require autoconf 2.60 or later.
  44 AC_PREREQ(2.60)
  45
  46 dnl Verify that the source directory is valid. This makes sure that we are
  47 dnl configuring LLVM and not some other package (it validates --srcdir argument)
  48 AC_CONFIG_SRCDIR([lib/IR/Module.cpp])
  49
  50 dnl Place all of the extra autoconf files into the config subdirectory. Tell
  51 dnl various tools where the m4 autoconf macros are.
  52 AC_CONFIG_AUX_DIR([autoconf])
  53
  54 dnl Quit if the source directory has already been configured.
  55 dnl NOTE: This relies upon undocumented autoconf behavior.
  56 if test ${srcdir} != "." ; then
  57   if test -f ${srcdir}/include/llvm/Config/config.h ; then
  58     AC_MSG_ERROR([Already configured in ${srcdir}])
  59   fi
  60 fi
  61
  62 dnl Default to empty (i.e. assigning the null string to) CFLAGS and CXXFLAGS,
  63 dnl instead of the autoconf default (for example, '-g -O2' for CC=gcc).
  64 : ${CFLAGS=}
  65 : ${CXXFLAGS=}
  66
  67 dnl We need to check for the compiler up here to avoid anything else
  68 dnl starting with a different one.
  69 AC_PROG_CC(clang llvm-gcc gcc)
  70 AC_PROG_CXX(clang++ llvm-g++ g++)
  71 AC_PROG_CPP
  72
  73 dnl If CXX is Clang, check that it can find and parse C++ standard library
  74 dnl headers.
  75 if test "$CXX" = "clang++" ; then
  76   AC_MSG_CHECKING([whether clang works])
  77   AC_LANG_PUSH([C++])
  78   dnl Note that space between 'include' and '(' is required.  There's a broken
  79   dnl regex in aclocal that otherwise will think that we call m4's include
  80   dnl builtin.
  81   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <limits>
  82 #if __has_include (<cxxabi.h>)
  83 #include <cxxabi.h>
  84 #endif
  85 #if __has_include (<unwind.h>)
  86 #include <unwind.h>
  87 #endif
  88 ]])],
  89 [
  90   AC_MSG_RESULT([yes])
  91 ],
  92 [
  93   AC_MSG_RESULT([no])
  94   AC_MSG_ERROR([Selected compiler could not find or parse C++ standard library headers.  Rerun with CC=c-compiler CXX=c++-compiler ./configure ...])
  95 ])
  96   AC_LANG_POP([C++])
  97 fi
  98
  99 dnl Configure all of the projects present in our source tree. While we could
 100 dnl just AC_CONFIG_SUBDIRS on the set of directories in projects that have a
 101 dnl configure script, that usage of the AC_CONFIG_SUBDIRS macro is deprecated.
 102 dnl Instead we match on the known projects.
 103
 104 dnl
 105 dnl One tricky part of doing this is that some projects depend upon other
 106 dnl projects.  For example, several projects rely upon the LLVM test suite.
 107 dnl We want to configure those projects first so that their object trees are
 108 dnl created before running the configure scripts of projects that depend upon
 109 dnl them.
 110 dnl
 111
 112 dnl Several projects use llvm-gcc, so configure that first
 113 if test -d ${srcdir}/projects/llvm-gcc ; then
 114   AC_CONFIG_SUBDIRS([projects/llvm-gcc])
 115 fi
 116
 117 dnl Several projects use the LLVM test suite, so configure it next.
 118 if test -d ${srcdir}/projects/test-suite ; then
 119   AC_CONFIG_SUBDIRS([projects/test-suite])
 120 fi
 121
 122 dnl llvm-test is the old name of the test-suite, kept here for backwards
 123 dnl compatibility
 124 if test -d ${srcdir}/projects/llvm-test ; then
 125   AC_CONFIG_SUBDIRS([projects/llvm-test])
 126 fi
 127
 128 dnl Some projects use poolalloc; configure that next
 129 if test -d ${srcdir}/projects/poolalloc ; then
 130   AC_CONFIG_SUBDIRS([projects/poolalloc])
 131 fi
 132
 133 if test -d ${srcdir}/projects/llvm-poolalloc ; then
 134   AC_CONFIG_SUBDIRS([projects/llvm-poolalloc])
 135 fi
 136
 137 dnl Check for all other projects
 138 for i in `ls ${srcdir}/projects`
 139 do
 140   if test -d ${srcdir}/projects/${i} ; then
 141     case ${i} in
 142       sample)       AC_CONFIG_SUBDIRS([projects/sample])    ;;
 143       privbracket)  AC_CONFIG_SUBDIRS([projects/privbracket]) ;;
 144       llvm-stacker) AC_CONFIG_SUBDIRS([projects/llvm-stacker]) ;;
 145       llvm-reopt)   AC_CONFIG_SUBDIRS([projects/llvm-reopt]);;
 146       llvm-java)    AC_CONFIG_SUBDIRS([projects/llvm-java]) ;;
 147       llvm-tv)      AC_CONFIG_SUBDIRS([projects/llvm-tv])   ;;
 148       safecode)     AC_CONFIG_SUBDIRS([projects/safecode]) ;;
 149       llvm-kernel)  AC_CONFIG_SUBDIRS([projects/llvm-kernel]) ;;
 150       compiler-rt)       ;;
 151       llvm-gcc)       ;;
 152       test-suite)     ;;
 153       llvm-test)      ;;
 154       poolalloc)      ;;
 155       llvm-poolalloc) ;;
 156       *)
 157         AC_MSG_WARN([Unknown project (${i}) won't be configured automatically])
 158         ;;
 159     esac
 160   fi
 161 done
 162
 163 dnl Disable the build of polly, even if it is checked out into tools/polly.
 164 AC_ARG_ENABLE(polly,
 165               AS_HELP_STRING([--enable-polly],
 166                              [Use polly if available (default is YES)]),,
 167                              enableval=default)
 168 case "$enableval" in
 169   yes) AC_SUBST(ENABLE_POLLY,[1]) ;;
 170   no)  AC_SUBST(ENABLE_POLLY,[0]) ;;
 171   default) AC_SUBST(ENABLE_POLLY,[1]) ;;
 172   *) AC_MSG_ERROR([Invalid setting for --enable-polly. Use "yes" or "no"]) ;;
 173 esac
 174
 175
 176 dnl Check if polly is checked out into tools/polly and configure it if
 177 dnl available.
 178 if (test -d ${srcdir}/tools/polly) && (test $ENABLE_POLLY -eq 1) ; then
 179   AC_SUBST(LLVM_HAS_POLLY,1)
 180   AC_CONFIG_SUBDIRS([tools/polly])
 181 fi
 182
 183 dnl===-----------------------------------------------------------------------===
 184 dnl===
 185 dnl=== SECTION 2: Architecture, target, and host checks
 186 dnl===
 187 dnl===-----------------------------------------------------------------------===
 188
 189 dnl Check the target for which we're compiling and the host that will do the
 190 dnl compilations. This will tell us which LLVM compiler will be used for
 191 dnl compiling SSA into object code. This needs to be done early because
 192 dnl following tests depend on it.
 193 AC_CANONICAL_TARGET
 194
 195 dnl Determine the platform type and cache its value. This helps us configure
 196 dnl the System library to the correct build platform.
 197 AC_CACHE_CHECK([type of operating system we're going to host on],
 198                [llvm_cv_os_type],
 199 [case $host in
 200   *-*-aix*)
 201     llvm_cv_link_all_option="-Wl,--whole-archive"
 202     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 203     llvm_cv_os_type="AIX"
 204     llvm_cv_platform_type="Unix" ;;
 205   *-*-irix*)
 206     llvm_cv_link_all_option="-Wl,--whole-archive"
 207     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 208     llvm_cv_os_type="IRIX"
 209     llvm_cv_platform_type="Unix" ;;
 210   *-*-cygwin*)
 211     llvm_cv_link_all_option="-Wl,--whole-archive"
 212     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 213     llvm_cv_os_type="Cygwin"
 214     llvm_cv_platform_type="Unix" ;;
 215   *-*-darwin*)
 216     llvm_cv_link_all_option="-Wl,-all_load"
 217     llvm_cv_no_link_all_option="-Wl,-noall_load"
 218     llvm_cv_os_type="Darwin"
 219     llvm_cv_platform_type="Unix" ;;
 220   *-*-minix*)
 221     llvm_cv_link_all_option="-Wl,-all_load"
 222     llvm_cv_no_link_all_option="-Wl,-noall_load"
 223     llvm_cv_os_type="Minix"
 224     llvm_cv_platform_type="Unix" ;;
 225   *-*-freebsd*)
 226     llvm_cv_link_all_option="-Wl,--whole-archive"
 227     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 228     llvm_cv_os_type="FreeBSD"
 229     llvm_cv_platform_type="Unix" ;;
 230   *-*-kfreebsd-gnu)
 231     llvm_cv_link_all_option="-Wl,--whole-archive"
 232     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 233     llvm_cv_os_type="GNU/kFreeBSD"
 234     llvm_cv_platform_type="Unix" ;;
 235   *-*-openbsd*)
 236     llvm_cv_link_all_option="-Wl,--whole-archive"
 237     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 238     llvm_cv_os_type="OpenBSD"
 239     llvm_cv_platform_type="Unix" ;;
 240   *-*-netbsd*)
 241     llvm_cv_link_all_option="-Wl,--whole-archive"
 242     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 243     llvm_cv_os_type="NetBSD"
 244     llvm_cv_platform_type="Unix" ;;
 245   *-*-dragonfly*)
 246     llvm_cv_link_all_option="-Wl,--whole-archive"
 247     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 248     llvm_cv_os_type="DragonFly"
 249     llvm_cv_platform_type="Unix" ;;
 250   *-*-hpux*)
 251     llvm_cv_link_all_option="-Wl,--whole-archive"
 252     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 253     llvm_cv_os_type="HP-UX"
 254     llvm_cv_platform_type="Unix" ;;
 255   *-*-interix*)
 256     llvm_cv_link_all_option="-Wl,--whole-archive"
 257     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 258     llvm_cv_os_type="Interix"
 259     llvm_cv_platform_type="Unix" ;;
 260   *-*-linux*)
 261     llvm_cv_link_all_option="-Wl,--whole-archive"
 262     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 263     llvm_cv_os_type="Linux"
 264     llvm_cv_platform_type="Unix" ;;
 265   *-*-gnu*)
 266     llvm_cv_link_all_option="-Wl,--whole-archive"
 267     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 268     llvm_cv_os_type="GNU"
 269     llvm_cv_platform_type="Unix" ;;
 270   *-*-solaris*)
 271     llvm_cv_link_all_option="-Wl,-z,allextract"
 272     llvm_cv_no_link_all_option="-Wl,-z,defaultextract"
 273     llvm_cv_os_type="SunOS"
 274     llvm_cv_platform_type="Unix" ;;
 275   *-*-auroraux*)
 276     llvm_cv_link_all_option="-Wl,-z,allextract"
 277     llvm_cv_link_all_option="-Wl,-z,defaultextract"
 278     llvm_cv_os_type="AuroraUX"
 279     llvm_cv_platform_type="Unix" ;;
 280   *-*-win32*)
 281     llvm_cv_link_all_option="-Wl,--whole-archive"
 282     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 283     llvm_cv_os_type="Win32"
 284     llvm_cv_platform_type="Win32" ;;
 285   *-*-mingw*)
 286     llvm_cv_link_all_option="-Wl,--whole-archive"
 287     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 288     llvm_cv_os_type="MingW"
 289     llvm_cv_platform_type="Win32" ;;
 290   *-*-haiku*)
 291     llvm_cv_link_all_option="-Wl,--whole-archive"
 292     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 293     llvm_cv_os_type="Haiku"
 294     llvm_cv_platform_type="Unix" ;;
 295   *-unknown-eabi*)
 296     llvm_cv_link_all_option="-Wl,--whole-archive"
 297     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 298     llvm_cv_os_type="Freestanding"
 299     llvm_cv_platform_type="Unix" ;;
 300   *-unknown-elf*)
 301     llvm_cv_link_all_option="-Wl,--whole-archive"
 302     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 303     llvm_cv_os_type="Freestanding"
 304     llvm_cv_platform_type="Unix" ;;
 305   *)
 306     llvm_cv_link_all_option=""
 307     llvm_cv_no_link_all_option=""
 308     llvm_cv_os_type="Unknown"
 309     llvm_cv_platform_type="Unknown" ;;
 310 esac])
 311
 312 AC_CACHE_CHECK([type of operating system we're going to target],
 313                [llvm_cv_target_os_type],
 314 [case $target in
 315   *-*-aix*)
 316     llvm_cv_target_os_type="AIX" ;;
 317   *-*-irix*)
 318     llvm_cv_target_os_type="IRIX" ;;
 319   *-*-cygwin*)
 320     llvm_cv_target_os_type="Cygwin" ;;
 321   *-*-darwin*)
 322     llvm_cv_target_os_type="Darwin" ;;
 323   *-*-minix*)
 324     llvm_cv_target_os_type="Minix" ;;
 325   *-*-freebsd*)
 326     llvm_cv_target_os_type="FreeBSD" ;;
 327   *-*-kfreebsd-gnu)
 328     llvm_cv_target_os_type="GNU/kFreeBSD" ;;
 329   *-*-openbsd*)
 330     llvm_cv_target_os_type="OpenBSD" ;;
 331   *-*-netbsd*)
 332     llvm_cv_target_os_type="NetBSD" ;;
 333   *-*-dragonfly*)
 334     llvm_cv_target_os_type="DragonFly" ;;
 335   *-*-hpux*)
 336     llvm_cv_target_os_type="HP-UX" ;;
 337   *-*-interix*)
 338     llvm_cv_target_os_type="Interix" ;;
 339   *-*-linux*)
 340     llvm_cv_target_os_type="Linux" ;;
 341   *-*-gnu*)
 342     llvm_cv_target_os_type="GNU" ;;
 343   *-*-solaris*)
 344     llvm_cv_target_os_type="SunOS" ;;
 345   *-*-auroraux*)
 346     llvm_cv_target_os_type="AuroraUX" ;;
 347   *-*-win32*)
 348     llvm_cv_target_os_type="Win32" ;;
 349   *-*-mingw*)
 350     llvm_cv_target_os_type="MingW" ;;
 351   *-*-haiku*)
 352     llvm_cv_target_os_type="Haiku" ;;
 353   *-*-rtems*)
 354     llvm_cv_target_os_type="RTEMS" ;;
 355   *-*-nacl*)
 356     llvm_cv_target_os_type="NativeClient" ;;
 357   *-unknown-eabi*)
 358     llvm_cv_target_os_type="Freestanding" ;;
 359   *)
 360     llvm_cv_target_os_type="Unknown" ;;
 361 esac])
 362
 363 dnl Make sure we aren't attempting to configure for an unknown system
 364 if test "$llvm_cv_os_type" = "Unknown" ; then
 365   AC_MSG_ERROR([Operating system is unknown, configure can't continue])
 366 fi
 367
 368 dnl Set the "OS" Makefile variable based on the platform type so the
 369 dnl makefile can configure itself to specific build hosts
 370 AC_SUBST(OS,$llvm_cv_os_type)
 371 AC_SUBST(HOST_OS,$llvm_cv_os_type)
 372 AC_SUBST(TARGET_OS,$llvm_cv_target_os_type)
 373
 374 dnl Set the LINKALL and NOLINKALL Makefile variables based on the platform
 375 AC_SUBST(LINKALL,$llvm_cv_link_all_option)
 376 AC_SUBST(NOLINKALL,$llvm_cv_no_link_all_option)
 377
 378 dnl Set the "LLVM_ON_*" variables based on llvm_cv_platform_type
 379 dnl This is used by lib/Support to determine the basic kind of implementation
 380 dnl to use.
 381 case $llvm_cv_platform_type in
 382   Unix)
 383     AC_DEFINE([LLVM_ON_UNIX],[1],[Define if this is Unixish platform])
 384     AC_SUBST(LLVM_ON_UNIX,[1])
 385     AC_SUBST(LLVM_ON_WIN32,[0])
 386     ;;
 387   Win32)
 388     AC_DEFINE([LLVM_ON_WIN32],[1],[Define if this is Win32ish platform])
 389     AC_SUBST(LLVM_ON_UNIX,[0])
 390     AC_SUBST(LLVM_ON_WIN32,[1])
 391     ;;
 392 esac
 393
 394 dnl Determine what our target architecture is and configure accordingly.
 395 dnl This will allow Makefiles to make a distinction between the hardware and
 396 dnl the OS.
 397 AC_CACHE_CHECK([target architecture],[llvm_cv_target_arch],
 398 [case $target in
 399   i?86-*)                 llvm_cv_target_arch="x86" ;;
 400   amd64-* | x86_64-*)     llvm_cv_target_arch="x86_64" ;;
 401   sparc*-*)               llvm_cv_target_arch="Sparc" ;;
 402   powerpc*-*)             llvm_cv_target_arch="PowerPC" ;;
 403   arm*-*)                 llvm_cv_target_arch="ARM" ;;
 404   aarch64*-*)             llvm_cv_target_arch="AArch64" ;;
 405   mips-* | mips64-*)      llvm_cv_target_arch="Mips" ;;
 406   mipsel-* | mips64el-*)  llvm_cv_target_arch="Mips" ;;
 407   xcore-*)                llvm_cv_target_arch="XCore" ;;
 408   msp430-*)               llvm_cv_target_arch="MSP430" ;;
 409   hexagon-*)              llvm_cv_target_arch="Hexagon" ;;
 410   nvptx-*)                llvm_cv_target_arch="NVPTX" ;;
 411   s390x-*)                llvm_cv_target_arch="SystemZ" ;;
 412   *)                      llvm_cv_target_arch="Unknown" ;;
 413 esac])
 414
 415 if test "$llvm_cv_target_arch" = "Unknown" ; then
 416   AC_MSG_WARN([Configuring LLVM for an unknown target archicture])
 417 fi
 418
 419 dnl Determine the LLVM native architecture for the target
 420 case "$llvm_cv_target_arch" in
 421     x86)     LLVM_NATIVE_ARCH="X86" ;;
 422     x86_64)  LLVM_NATIVE_ARCH="X86" ;;
 423     *)       LLVM_NATIVE_ARCH="$llvm_cv_target_arch" ;;
 424 esac
 425
 426 dnl Define a substitution, ARCH, for the target architecture
 427 AC_SUBST(ARCH,$llvm_cv_target_arch)
 428
 429 dnl Determine what our host architecture.
 430 dnl This will allow MCJIT regress tests runs only for supported
 431 dnl platforms.
 432 case $host in
 433   i?86-*)                 host_arch="x86" ;;
 434   amd64-* | x86_64-*)     host_arch="x86_64" ;;
 435   sparc*-*)               host_arch="Sparc" ;;
 436   powerpc*-*)             host_arch="PowerPC" ;;
 437   arm*-*)                 host_arch="ARM" ;;
 438   aarch64*-*)             host_arch="AArch64" ;;
 439   mips-* | mips64-*)      host_arch="Mips" ;;
 440   mipsel-* | mips64el-*)  host_arch="Mips" ;;
 441   xcore-*)                host_arch="XCore" ;;
 442   msp430-*)               host_arch="MSP430" ;;
 443   hexagon-*)              host_arch="Hexagon" ;;
 444   s390x-*)                host_arch="SystemZ" ;;
 445   *)                      host_arch="Unknown" ;;
 446 esac
 447
 448 if test "$host_arch" = "Unknown" ; then
 449   AC_MSG_WARN([Configuring LLVM for an unknown host archicture])
 450 fi
 451
 452 AC_SUBST(HOST_ARCH,$host_arch)
 453
 454 dnl Check for build platform executable suffix if we're cross-compiling
 455 if test "$cross_compiling" = yes; then
 456   AC_SUBST(LLVM_CROSS_COMPILING, [1])
 457   AC_BUILD_EXEEXT
 458   ac_build_prefix=${build_alias}-
 459   AC_CHECK_PROG(BUILD_CXX, ${ac_build_prefix}g++, ${ac_build_prefix}g++)
 460   if test -z "$BUILD_CXX"; then
 461      AC_CHECK_PROG(BUILD_CXX, g++, g++)
 462      if test -z "$BUILD_CXX"; then
 463        AC_CHECK_PROG(BUILD_CXX, c++, c++, , , /usr/ucb/c++)
 464      fi
 465   fi
 466 else
 467   AC_SUBST(LLVM_CROSS_COMPILING, [0])
 468 fi
 469
 470 dnl Check to see if there's a .svn or .git directory indicating that this
 471 dnl build is being done from a checkout. This sets up several defaults for
 472 dnl the command line switches. When we build with a checkout directory,
 473 dnl we get a debug with assertions turned on. Without, we assume a source
 474 dnl release and we get an optimized build without assertions.
 475 dnl See --enable-optimized and --enable-assertions below
 476 if test -d ".svn" -o -d "${srcdir}/.svn" -o -d ".git" -o -d "${srcdir}/.git"; then
 477   cvsbuild="yes"
 478   optimize="no"
 479   AC_SUBST(CVSBUILD,[[CVSBUILD=1]])
 480 else
 481   cvsbuild="no"
 482   optimize="yes"
 483 fi
 484
 485 dnl===-----------------------------------------------------------------------===
 486 dnl===
 487 dnl=== SECTION 3: Command line arguments for the configure script.
 488 dnl===
 489 dnl===-----------------------------------------------------------------------===
 490
 491 dnl --enable-libcpp : check whether or not to use libc++ on the command line
 492 AC_ARG_ENABLE(libcpp,
 493               AS_HELP_STRING([--enable-libcpp],
 494                              [Use libc++ if available (default is NO)]),,
 495                              enableval=default)
 496 case "$enableval" in
 497   yes) AC_SUBST(ENABLE_LIBCPP,[1]) ;;
 498   no)  AC_SUBST(ENABLE_LIBCPP,[0]) ;;
 499   default) AC_SUBST(ENABLE_LIBCPP,[0]);;
 500   *) AC_MSG_ERROR([Invalid setting for --enable-libcpp. Use "yes" or "no"]) ;;
 501 esac
 502
 503 dnl --enable-cxx11 : check whether or not to use -std=c++11 on the command line
 504 AC_ARG_ENABLE(cxx11,
 505               AS_HELP_STRING([--enable-cxx11],
 506                              [Use c++11 if available (default is NO)]),,
 507                              enableval=default)
 508 case "$enableval" in
 509   yes) AC_SUBST(ENABLE_CXX11,[1]) ;;
 510   no)  AC_SUBST(ENABLE_CXX11,[0]) ;;
 511   default) AC_SUBST(ENABLE_CXX11,[0]);;
 512   *) AC_MSG_ERROR([Invalid setting for --enable-cxx11. Use "yes" or "no"]) ;;
 513 esac
 514
 515 dnl --enable-fission : check whether or not to use -gsplit-dwarf on the command
 516 dnl line
 517 AC_ARG_ENABLE(split-dwarf,
 518               AS_HELP_STRING([--enable-split-dwarf],
 519                              [Use split-dwarf if available (default is NO)]),,
 520                              enableval=default)
 521 case "$enableval" in
 522   yes) AC_SUBST(ENABLE_SPLIT_DWARF,[1]) ;;
 523   no)  AC_SUBST(ENABLE_SPLIT_DWARF,[0]) ;;
 524   default) AC_SUBST(ENABLE_SPLIT_DWARF,[0]);;
 525   *) AC_MSG_ERROR([Invalid setting for --enable-split-dwarf. Use "yes" or "no"]) ;;
 526 esac
 527
 528 dnl --enable-clang-arcmt: check whether to enable clang arcmt
 529 clang_arcmt="yes"
 530 AC_ARG_ENABLE(clang-arcmt,
 531               AS_HELP_STRING([--enable-clang-arcmt],
 532                              [Enable building of clang ARCMT (default is YES)]),
 533                              clang_arcmt="$enableval",
 534                              enableval="yes")
 535 case "$enableval" in
 536   yes) AC_SUBST(ENABLE_CLANG_ARCMT,[1]) ;;
 537   no)  AC_SUBST(ENABLE_CLANG_ARCMT,[0]) ;;
 538   default) AC_SUBST(ENABLE_CLANG_ARCMT,[1]);;
 539   *) AC_MSG_ERROR([Invalid setting for --enable-clang-arcmt. Use "yes" or "no"]) ;;
 540 esac
 541
 542 dnl --enable-clang-static-analyzer: check whether to enable static-analyzer
 543 clang_static_analyzer="yes"
 544 AC_ARG_ENABLE(clang-static-analyzer,
 545               AS_HELP_STRING([--enable-clang-static-analyzer],
 546                              [Enable building of clang Static Analyzer (default is YES)]),
 547                              clang_static_analyzer="$enableval",
 548                              enableval="yes")
 549 case "$enableval" in
 550   yes) AC_SUBST(ENABLE_CLANG_STATIC_ANALYZER,[1]) ;;
 551   no)
 552     if test ${clang_arcmt} != "no" ; then
 553       AC_MSG_ERROR([Cannot enable clang ARC Migration Tool while disabling static analyzer.])
 554     fi
 555     AC_SUBST(ENABLE_CLANG_STATIC_ANALYZER,[0])
 556     ;;
 557   default) AC_SUBST(ENABLE_CLANG_STATIC_ANALYZER,[1]);;
 558   *) AC_MSG_ERROR([Invalid setting for --enable-clang-static-analyzer. Use "yes" or "no"]) ;;
 559 esac
 560
 561 dnl --enable-clang-rewriter: check whether to enable clang rewriter
 562 AC_ARG_ENABLE(clang-rewriter,
 563               AS_HELP_STRING([--enable-clang-rewriter],
 564                              [Enable building of clang rewriter (default is YES)]),,
 565                              enableval="yes")
 566 case "$enableval" in
 567   yes) AC_SUBST(ENABLE_CLANG_REWRITER,[1]) ;;
 568   no)
 569     if test ${clang_arcmt} != "no" ; then
 570       AC_MSG_ERROR([Cannot enable clang ARC Migration Tool while disabling rewriter.])
 571     fi
 572     if test ${clang_static_analyzer} != "no" ; then
 573       AC_MSG_ERROR([Cannot enable clang static analyzer while disabling rewriter.])
 574     fi
 575     AC_SUBST(ENABLE_CLANG_REWRITER,[0])
 576     ;;
 577   default) AC_SUBST(ENABLE_CLANG_REWRITER,[1]);;
 578   *) AC_MSG_ERROR([Invalid setting for --enable-clang-rewriter. Use "yes" or "no"]) ;;
 579 esac
 580
 581 dnl --enable-optimized : check whether they want to do an optimized build:
 582 AC_ARG_ENABLE(optimized, AS_HELP_STRING(
 583  --enable-optimized,[Compile with optimizations enabled (default is NO)]),,enableval=$optimize)
 584 if test ${enableval} = "no" ; then
 585   AC_SUBST(ENABLE_OPTIMIZED,[[]])
 586 else
 587   AC_SUBST(ENABLE_OPTIMIZED,[[ENABLE_OPTIMIZED=1]])
 588 fi
 589
 590 dnl --enable-profiling : check whether they want to do a profile build:
 591 AC_ARG_ENABLE(profiling, AS_HELP_STRING(
 592  --enable-profiling,[Compile with profiling enabled (default is NO)]),,enableval="no")
 593 if test ${enableval} = "no" ; then
 594   AC_SUBST(ENABLE_PROFILING,[[]])
 595 else
 596   AC_SUBST(ENABLE_PROFILING,[[ENABLE_PROFILING=1]])
 597 fi
 598
 599 dnl --enable-assertions : check whether they want to turn on assertions or not:
 600 AC_ARG_ENABLE(assertions,AS_HELP_STRING(
 601   --enable-assertions,[Compile with assertion checks enabled (default is YES)]),, enableval="yes")
 602 if test ${enableval} = "yes" ; then
 603   AC_SUBST(DISABLE_ASSERTIONS,[[]])
 604 else
 605   AC_SUBST(DISABLE_ASSERTIONS,[[DISABLE_ASSERTIONS=1]])
 606 fi
 607
 608 dnl --enable-werror : check whether we want Werror on by default
 609 AC_ARG_ENABLE(werror,AS_HELP_STRING(
 610   --enable-werror,[Compile with -Werror enabled (default is NO)]),, enableval="no")
 611 case "$enableval" in
 612   yes) AC_SUBST(ENABLE_WERROR,[1]) ;;
 613   no)  AC_SUBST(ENABLE_WERROR,[0]) ;;
 614   default) AC_SUBST(ENABLE_WERROR,[0]);;
 615   *) AC_MSG_ERROR([Invalid setting for --enable-werror. Use "yes" or "no"]) ;;
 616 esac
 617
 618 dnl --enable-expensive-checks : check whether they want to turn on expensive debug checks:
 619 AC_ARG_ENABLE(expensive-checks,AS_HELP_STRING(
 620   --enable-expensive-checks,[Compile with expensive debug checks enabled (default is NO)]),, enableval="no")
 621 if test ${enableval} = "yes" ; then
 622   AC_SUBST(ENABLE_EXPENSIVE_CHECKS,[[ENABLE_EXPENSIVE_CHECKS=1]])
 623   AC_SUBST(EXPENSIVE_CHECKS,[[yes]])
 624 else
 625   AC_SUBST(ENABLE_EXPENSIVE_CHECKS,[[]])
 626   AC_SUBST(EXPENSIVE_CHECKS,[[no]])
 627 fi
 628
 629 dnl --enable-debug-runtime : should runtime libraries have debug symbols?
 630 AC_ARG_ENABLE(debug-runtime,
 631    AS_HELP_STRING(--enable-debug-runtime,[Build runtime libs with debug symbols (default is NO)]),,enableval=no)
 632 if test ${enableval} = "no" ; then
 633   AC_SUBST(DEBUG_RUNTIME,[[]])
 634 else
 635   AC_SUBST(DEBUG_RUNTIME,[[DEBUG_RUNTIME=1]])
 636 fi
 637
 638 dnl --enable-debug-symbols : should even optimized compiler libraries
 639 dnl have debug symbols?
 640 AC_ARG_ENABLE(debug-symbols,
 641    AS_HELP_STRING(--enable-debug-symbols,[Build compiler with debug symbols (default is NO if optimization is on and YES if it's off)]),,enableval=no)
 642 if test ${enableval} = "no" ; then
 643   AC_SUBST(DEBUG_SYMBOLS,[[]])
 644 else
 645   AC_SUBST(DEBUG_SYMBOLS,[[DEBUG_SYMBOLS=1]])
 646 fi
 647
 648 dnl --enable-keep-symbols : do not strip installed executables
 649 AC_ARG_ENABLE(keep-symbols,
 650    AS_HELP_STRING(--enable-keep-symbols,[Do not strip installed executables)]),,enableval=no)
 651 if test ${enableval} = "no" ; then
 652   AC_SUBST(KEEP_SYMBOLS,[[]])
 653 else
 654   AC_SUBST(KEEP_SYMBOLS,[[KEEP_SYMBOLS=1]])
 655 fi
 656
 657 dnl --enable-jit: check whether they want to enable the jit
 658 AC_ARG_ENABLE(jit,
 659   AS_HELP_STRING(--enable-jit,
 660                  [Enable Just In Time Compiling (default is YES)]),,
 661   enableval=default)
 662 if test ${enableval} = "no"
 663 then
 664   AC_SUBST(JIT,[[]])
 665 else
 666   case "$llvm_cv_target_arch" in
 667     x86)         AC_SUBST(TARGET_HAS_JIT,1) ;;
 668     Sparc)       AC_SUBST(TARGET_HAS_JIT,0) ;;
 669     PowerPC)     AC_SUBST(TARGET_HAS_JIT,1) ;;
 670     x86_64)      AC_SUBST(TARGET_HAS_JIT,1) ;;
 671     ARM)         AC_SUBST(TARGET_HAS_JIT,1) ;;
 672     AArch64)     AC_SUBST(TARGET_HAS_JIT,0) ;;
 673     Mips)        AC_SUBST(TARGET_HAS_JIT,1) ;;
 674     XCore)       AC_SUBST(TARGET_HAS_JIT,0) ;;
 675     MSP430)      AC_SUBST(TARGET_HAS_JIT,0) ;;
 676     Hexagon)     AC_SUBST(TARGET_HAS_JIT,0) ;;
 677     NVPTX)       AC_SUBST(TARGET_HAS_JIT,0) ;;
 678     SystemZ)     AC_SUBST(TARGET_HAS_JIT,1) ;;
 679     *)           AC_SUBST(TARGET_HAS_JIT,0) ;;
 680   esac
 681 fi
 682
 683 dnl Allow enablement of building and installing docs
 684 AC_ARG_ENABLE(docs,
 685               AS_HELP_STRING([--enable-docs],
 686                              [Build documents (default is YES)]),,
 687                              enableval=default)
 688 case "$enableval" in
 689   yes) AC_SUBST(ENABLE_DOCS,[1]) ;;
 690   no)  AC_SUBST(ENABLE_DOCS,[0]) ;;
 691   default) AC_SUBST(ENABLE_DOCS,[1]) ;;
 692   *) AC_MSG_ERROR([Invalid setting for --enable-docs. Use "yes" or "no"]) ;;
 693 esac
 694
 695 dnl Allow enablement of doxygen generated documentation
 696 AC_ARG_ENABLE(doxygen,
 697               AS_HELP_STRING([--enable-doxygen],
 698                              [Build doxygen documentation (default is NO)]),,
 699                              enableval=default)
 700 case "$enableval" in
 701   yes) AC_SUBST(ENABLE_DOXYGEN,[1]) ;;
 702   no)  AC_SUBST(ENABLE_DOXYGEN,[0]) ;;
 703   default) AC_SUBST(ENABLE_DOXYGEN,[0]) ;;
 704   *) AC_MSG_ERROR([Invalid setting for --enable-doxygen. Use "yes" or "no"]) ;;
 705 esac
 706
 707 dnl Allow disablement of threads
 708 AC_ARG_ENABLE(threads,
 709               AS_HELP_STRING([--enable-threads],
 710                              [Use threads if available (default is YES)]),,
 711                              enableval=default)
 712 case "$enableval" in
 713   yes) AC_SUBST(LLVM_ENABLE_THREADS,[1]) ;;
 714   no)  AC_SUBST(LLVM_ENABLE_THREADS,[0]) ;;
 715   default) AC_SUBST(LLVM_ENABLE_THREADS,[1]) ;;
 716   *) AC_MSG_ERROR([Invalid setting for --enable-threads. Use "yes" or "no"]) ;;
 717 esac
 718 AC_DEFINE_UNQUOTED([LLVM_ENABLE_THREADS],$LLVM_ENABLE_THREADS,
 719                    [Define if threads enabled])
 720
 721 dnl Allow disablement of pthread.h
 722 AC_ARG_ENABLE(pthreads,
 723               AS_HELP_STRING([--enable-pthreads],
 724                              [Use pthreads if available (default is YES)]),,
 725                              enableval=default)
 726 case "$enableval" in
 727   yes) AC_SUBST(ENABLE_PTHREADS,[1]) ;;
 728   no)  AC_SUBST(ENABLE_PTHREADS,[0]) ;;
 729   default) AC_SUBST(ENABLE_PTHREADS,[1]) ;;
 730   *) AC_MSG_ERROR([Invalid setting for --enable-pthreads. Use "yes" or "no"]) ;;
 731 esac
 732
 733 dnl Allow disablement of zlib
 734 AC_ARG_ENABLE(zlib,
 735               AS_HELP_STRING([--enable-zlib],
 736                              [Use zlib for compression/decompression if
 737                               available (default is YES)]),,
 738                               enableval=default)
 739 case "$enableval" in
 740   yes) AC_SUBST(LLVM_ENABLE_ZLIB,[1]) ;;
 741   no)  AC_SUBST(LLVM_ENABLE_ZLIB,[0]) ;;
 742   default) AC_SUBST(LLVM_ENABLE_ZLIB,[1]) ;;
 743   *) AC_MSG_ERROR([Invalid setting for --enable-zlib. Use "yes" or "no"]) ;;
 744 esac
 745 AC_DEFINE_UNQUOTED([LLVM_ENABLE_ZLIB],$LLVM_ENABLE_ZLIB,
 746                    [Define if zlib is enabled])
 747
 748 dnl Allow building without position independent code
 749 AC_ARG_ENABLE(pic,
 750   AS_HELP_STRING([--enable-pic],
 751                  [Build LLVM with Position Independent Code (default is YES)]),,
 752                  enableval=default)
 753 case "$enableval" in
 754   yes) AC_SUBST(ENABLE_PIC,[1]) ;;
 755   no)  AC_SUBST(ENABLE_PIC,[0]) ;;
 756   default) AC_SUBST(ENABLE_PIC,[1]) ;;
 757   *) AC_MSG_ERROR([Invalid setting for --enable-pic. Use "yes" or "no"]) ;;
 758 esac
 759 AC_DEFINE_UNQUOTED([ENABLE_PIC],$ENABLE_PIC,
 760                    [Define if position independent code is enabled])
 761
 762 dnl Allow building a shared library and linking tools against it.
 763 AC_ARG_ENABLE(shared,
 764   AS_HELP_STRING([--enable-shared],
 765                  [Build a shared library and link tools against it (default is NO)]),,
 766                  enableval=default)
 767 case "$enableval" in
 768   yes) AC_SUBST(ENABLE_SHARED,[1]) ;;
 769   no)  AC_SUBST(ENABLE_SHARED,[0]) ;;
 770   default) AC_SUBST(ENABLE_SHARED,[0]) ;;
 771   *) AC_MSG_ERROR([Invalid setting for --enable-shared. Use "yes" or "no"]) ;;
 772 esac
 773
 774 dnl Allow libstdc++ is embedded in LLVM.dll.
 775 AC_ARG_ENABLE(embed-stdcxx,
 776   AS_HELP_STRING([--enable-embed-stdcxx],
 777                  [Build a shared library with embedded libstdc++ for Win32 DLL (default is NO)]),,
 778                  enableval=default)
 779 case "$enableval" in
 780   yes) AC_SUBST(ENABLE_EMBED_STDCXX,[1]) ;;
 781   no)  AC_SUBST(ENABLE_EMBED_STDCXX,[0]) ;;
 782   default) AC_SUBST(ENABLE_EMBED_STDCXX,[0]) ;;
 783   *) AC_MSG_ERROR([Invalid setting for --enable-embed-stdcxx. Use "yes" or "no"]) ;;
 784 esac
 785
 786 dnl Enable embedding timestamp information into build.
 787 AC_ARG_ENABLE(timestamps,
 788   AS_HELP_STRING([--enable-timestamps],
 789                  [Enable embedding timestamp information in build (default is YES)]),,
 790                  enableval=default)
 791 case "$enableval" in
 792   yes) AC_SUBST(ENABLE_TIMESTAMPS,[1]) ;;
 793   no)  AC_SUBST(ENABLE_TIMESTAMPS,[0]) ;;
 794   default) AC_SUBST(ENABLE_TIMESTAMPS,[1]) ;;
 795   *) AC_MSG_ERROR([Invalid setting for --enable-timestamps. Use "yes" or "no"]) ;;
 796 esac
 797 AC_DEFINE_UNQUOTED([ENABLE_TIMESTAMPS],$ENABLE_TIMESTAMPS,
 798                    [Define if timestamp information (e.g., __DATE__) is allowed])
 799
 800 dnl Enable support for showing backtraces.
 801 AC_ARG_ENABLE(backtraces, AS_HELP_STRING(
 802   [--enable-backtraces],
 803   [Enable embedding backtraces on crash (default is YES)]),
 804   [case "$enableval" in
 805     yes) llvm_cv_enable_backtraces="yes" ;;
 806     no)  llvm_cv_enable_backtraces="no"  ;;
 807     *) AC_MSG_ERROR([Invalid setting for --enable-backtraces. Use "yes" or "no"]) ;;
 808   esac],
 809   llvm_cv_enable_backtraces="yes")
 810 if test "$llvm_cv_enable_backtraces" = "yes" ; then
 811   AC_DEFINE([ENABLE_BACKTRACES],[1],
 812             [Define if you want backtraces on crash])
 813 fi
 814
 815 dnl Enable installing platform specific signal handling overrides, for improved
 816 dnl CrashRecovery support or interaction with crash reporting software. This
 817 dnl support may be inappropriate for some clients embedding LLVM as a library.
 818 AC_ARG_ENABLE(crash-overrides, AS_HELP_STRING(
 819   [--enable-crash-overrides],
 820   [Enable crash handling overrides (default is YES)]),
 821   [case "$enableval" in
 822     yes) llvm_cv_enable_crash_overrides="yes" ;;
 823     no)  llvm_cv_enable_crash_overrides="no"  ;;
 824     *) AC_MSG_ERROR([Invalid setting for --enable-crash-overrides. Use "yes" or "no"]) ;;
 825   esac],
 826   llvm_cv_enable_crash_overrides="yes")
 827 if test "$llvm_cv_enable_crash_overrides" = "yes" ; then
 828   AC_DEFINE([ENABLE_CRASH_OVERRIDES],[1],
 829             [Define to enable crash handling overrides])
 830 fi
 831
 832 dnl Allow specific targets to be specified for building (or not)
 833 TARGETS_TO_BUILD=""
 834 AC_ARG_ENABLE([targets],AS_HELP_STRING([--enable-targets],
 835     [Build specific host targets: all or target1,target2,... Valid targets are:
 836      host, x86, x86_64, sparc, powerpc, arm, aarch64, mips, hexagon,
 837      xcore, msp430, nvptx, systemz, r600, and cpp (default=all)]),,
 838     enableval=all)
 839 if test "$enableval" = host-only ; then
 840   enableval=host
 841 fi
 842 case "$enableval" in
 843   all) TARGETS_TO_BUILD="X86 Sparc PowerPC AArch64 ARM Mips XCore MSP430 CppBackend NVPTX Hexagon SystemZ R600" ;;
 844   *)for a_target in `echo $enableval|sed -e 's/,/ /g' ` ; do
 845       case "$a_target" in
 846         x86)      TARGETS_TO_BUILD="X86 $TARGETS_TO_BUILD" ;;
 847         x86_64)   TARGETS_TO_BUILD="X86 $TARGETS_TO_BUILD" ;;
 848         sparc)    TARGETS_TO_BUILD="Sparc $TARGETS_TO_BUILD" ;;
 849         powerpc)  TARGETS_TO_BUILD="PowerPC $TARGETS_TO_BUILD" ;;
 850         aarch64)  TARGETS_TO_BUILD="AArch64 $TARGETS_TO_BUILD" ;;
 851         arm)      TARGETS_TO_BUILD="ARM $TARGETS_TO_BUILD" ;;
 852         mips)     TARGETS_TO_BUILD="Mips $TARGETS_TO_BUILD" ;;
 853         mipsel)   TARGETS_TO_BUILD="Mips $TARGETS_TO_BUILD" ;;
 854         mips64)   TARGETS_TO_BUILD="Mips $TARGETS_TO_BUILD" ;;
 855         mips64el) TARGETS_TO_BUILD="Mips $TARGETS_TO_BUILD" ;;
 856         xcore)    TARGETS_TO_BUILD="XCore $TARGETS_TO_BUILD" ;;
 857         msp430)   TARGETS_TO_BUILD="MSP430 $TARGETS_TO_BUILD" ;;
 858         cpp)      TARGETS_TO_BUILD="CppBackend $TARGETS_TO_BUILD" ;;
 859         hexagon)  TARGETS_TO_BUILD="Hexagon $TARGETS_TO_BUILD" ;;
 860         nvptx)    TARGETS_TO_BUILD="NVPTX $TARGETS_TO_BUILD" ;;
 861         systemz)  TARGETS_TO_BUILD="SystemZ $TARGETS_TO_BUILD" ;;
 862         r600)     TARGETS_TO_BUILD="R600 $TARGETS_TO_BUILD" ;;
 863         host) case "$llvm_cv_target_arch" in
 864             x86)         TARGETS_TO_BUILD="X86 $TARGETS_TO_BUILD" ;;
 865             x86_64)      TARGETS_TO_BUILD="X86 $TARGETS_TO_BUILD" ;;
 866             Sparc)       TARGETS_TO_BUILD="Sparc $TARGETS_TO_BUILD" ;;
 867             PowerPC)     TARGETS_TO_BUILD="PowerPC $TARGETS_TO_BUILD" ;;
 868             AArch64)     TARGETS_TO_BUILD="AArch64 $TARGETS_TO_BUILD" ;;
 869             ARM)         TARGETS_TO_BUILD="ARM $TARGETS_TO_BUILD" ;;
 870             Mips)        TARGETS_TO_BUILD="Mips $TARGETS_TO_BUILD" ;;
 871             XCore)       TARGETS_TO_BUILD="XCore $TARGETS_TO_BUILD" ;;
 872             MSP430)      TARGETS_TO_BUILD="MSP430 $TARGETS_TO_BUILD" ;;
 873             Hexagon)     TARGETS_TO_BUILD="Hexagon $TARGETS_TO_BUILD" ;;
 874             NVPTX)       TARGETS_TO_BUILD="NVPTX $TARGETS_TO_BUILD" ;;
 875             SystemZ)     TARGETS_TO_BUILD="SystemZ $TARGETS_TO_BUILD" ;;
 876             *)       AC_MSG_ERROR([Can not set target to build]) ;;
 877           esac ;;
 878         *) AC_MSG_ERROR([Unrecognized target $a_target]) ;;
 879       esac
 880   done
 881   ;;
 882 esac
 883
 884 AC_ARG_ENABLE([experimental-targets],AS_HELP_STRING([--enable-experimental-targets],
 885     [Build experimental host targets: disable or target1,target2,...
 886      (default=disable)]),,
 887     enableval=disable)
 888
 889 if test ${enableval} != "disable"
 890 then
 891   TARGETS_TO_BUILD="$enableval $TARGETS_TO_BUILD"
 892 fi
 893
 894 AC_SUBST(TARGETS_TO_BUILD,$TARGETS_TO_BUILD)
 895
 896 dnl Determine whether we are building LLVM support for the native architecture.
 897 dnl If so, define LLVM_NATIVE_ARCH to that LLVM target.
 898 for a_target in $TARGETS_TO_BUILD; do
 899   if test "$a_target" = "$LLVM_NATIVE_ARCH"; then
 900     AC_DEFINE_UNQUOTED(LLVM_NATIVE_ARCH, $LLVM_NATIVE_ARCH,
 901       [LLVM architecture name for the native architecture, if available])
 902     LLVM_NATIVE_TARGET="LLVMInitialize${LLVM_NATIVE_ARCH}Target"
 903     LLVM_NATIVE_TARGETINFO="LLVMInitialize${LLVM_NATIVE_ARCH}TargetInfo"
 904     LLVM_NATIVE_TARGETMC="LLVMInitialize${LLVM_NATIVE_ARCH}TargetMC"
 905     LLVM_NATIVE_ASMPRINTER="LLVMInitialize${LLVM_NATIVE_ARCH}AsmPrinter"
 906     if test -f ${srcdir}/lib/Target/${LLVM_NATIVE_ARCH}/AsmParser/Makefile ; then
 907       LLVM_NATIVE_ASMPARSER="LLVMInitialize${LLVM_NATIVE_ARCH}AsmParser"
 908     fi
 909     if test -f ${srcdir}/lib/Target/${LLVM_NATIVE_ARCH}/Disassembler/Makefile ; then
 910       LLVM_NATIVE_DISASSEMBLER="LLVMInitialize${LLVM_NATIVE_ARCH}Disassembler"
 911     fi
 912     AC_DEFINE_UNQUOTED(LLVM_NATIVE_TARGET, $LLVM_NATIVE_TARGET,
 913       [LLVM name for the native Target init function, if available])
 914     AC_DEFINE_UNQUOTED(LLVM_NATIVE_TARGETINFO, $LLVM_NATIVE_TARGETINFO,
 915       [LLVM name for the native TargetInfo init function, if available])
 916     AC_DEFINE_UNQUOTED(LLVM_NATIVE_TARGETMC, $LLVM_NATIVE_TARGETMC,
 917       [LLVM name for the native target MC init function, if available])
 918     AC_DEFINE_UNQUOTED(LLVM_NATIVE_ASMPRINTER, $LLVM_NATIVE_ASMPRINTER,
 919       [LLVM name for the native AsmPrinter init function, if available])
 920     if test -f ${srcdir}/lib/Target/${LLVM_NATIVE_ARCH}/AsmParser/Makefile ; then
 921       AC_DEFINE_UNQUOTED(LLVM_NATIVE_ASMPARSER, $LLVM_NATIVE_ASMPARSER,
 922        [LLVM name for the native AsmParser init function, if available])
 923     fi
 924     if test -f ${srcdir}/lib/Target/${LLVM_NATIVE_ARCH}/Disassembler/Makefile ; then
 925       AC_DEFINE_UNQUOTED(LLVM_NATIVE_DISASSEMBLER, $LLVM_NATIVE_DISASSEMBLER,
 926        [LLVM name for the native Disassembler init function, if available])
 927     fi
 928   fi
 929 done
 930
 931 dnl Build the LLVM_TARGET and LLVM_... macros for Targets.def and the individual
 932 dnl target feature def files.
 933 LLVM_ENUM_TARGETS=""
 934 LLVM_ENUM_ASM_PRINTERS=""
 935 LLVM_ENUM_ASM_PARSERS=""
 936 LLVM_ENUM_DISASSEMBLERS=""
 937 for target_to_build in $TARGETS_TO_BUILD; do
 938   LLVM_ENUM_TARGETS="LLVM_TARGET($target_to_build) $LLVM_ENUM_TARGETS"
 939   if test -f ${srcdir}/lib/Target/${target_to_build}/*AsmPrinter.cpp ; then
 940     LLVM_ENUM_ASM_PRINTERS="LLVM_ASM_PRINTER($target_to_build) $LLVM_ENUM_ASM_PRINTERS";
 941   fi
 942   if test -f ${srcdir}/lib/Target/${target_to_build}/AsmParser/Makefile ; then
 943     LLVM_ENUM_ASM_PARSERS="LLVM_ASM_PARSER($target_to_build) $LLVM_ENUM_ASM_PARSERS";
 944   fi
 945   if test -f ${srcdir}/lib/Target/${target_to_build}/Disassembler/Makefile ; then
 946     LLVM_ENUM_DISASSEMBLERS="LLVM_DISASSEMBLER($target_to_build) $LLVM_ENUM_DISASSEMBLERS";
 947   fi
 948 done
 949 AC_SUBST(LLVM_ENUM_TARGETS)
 950 AC_SUBST(LLVM_ENUM_ASM_PRINTERS)
 951 AC_SUBST(LLVM_ENUM_ASM_PARSERS)
 952 AC_SUBST(LLVM_ENUM_DISASSEMBLERS)
 953
 954 dnl Override the option to use for optimized builds.
 955 AC_ARG_WITH(optimize-option,
 956   AS_HELP_STRING([--with-optimize-option],
 957                  [Select the compiler options to use for optimized builds]),,
 958                  withval=default)
 959 AC_MSG_CHECKING([optimization flags])
 960 case "$withval" in
 961   default)
 962     case "$llvm_cv_os_type" in
 963     FreeBSD) optimize_option=-O2 ;;
 964     MingW) optimize_option=-O2 ;;
 965     *)     optimize_option=-O3 ;;
 966     esac ;;
 967   *) optimize_option="$withval" ;;
 968 esac
 969 AC_SUBST(OPTIMIZE_OPTION,$optimize_option)
 970 AC_MSG_RESULT([$optimize_option])
 971
 972 dnl Specify extra build options
 973 AC_ARG_WITH(extra-options,
 974   AS_HELP_STRING([--with-extra-options],
 975                  [Specify additional options to compile LLVM with]),,
 976                  withval=default)
 977 case "$withval" in
 978   default) EXTRA_OPTIONS= ;;
 979   *) EXTRA_OPTIONS=$withval ;;
 980 esac
 981 AC_SUBST(EXTRA_OPTIONS,$EXTRA_OPTIONS)
 982
 983 dnl Specify extra linker build options
 984 AC_ARG_WITH(extra-ld-options,
 985   AS_HELP_STRING([--with-extra-ld-options],
 986                  [Specify additional options to link LLVM with]),,
 987                  withval=default)
 988 case "$withval" in
 989   default) EXTRA_LD_OPTIONS= ;;
 990   *) EXTRA_LD_OPTIONS=$withval ;;
 991 esac
 992 AC_SUBST(EXTRA_LD_OPTIONS,$EXTRA_LD_OPTIONS)
 993
 994 dnl Allow specific bindings to be specified for building (or not)
 995 AC_ARG_ENABLE([bindings],AS_HELP_STRING([--enable-bindings],
 996     [Build specific language bindings: all,auto,none,{binding-name} (default=auto)]),,
 997     enableval=default)
 998 BINDINGS_TO_BUILD=""
 999 case "$enableval" in
1000   yes | default | auto) BINDINGS_TO_BUILD="auto" ;;
1001   all ) BINDINGS_TO_BUILD="ocaml" ;;
1002   none | no) BINDINGS_TO_BUILD="" ;;
1003   *)for a_binding in `echo $enableval|sed -e 's/,/ /g' ` ; do
1004       case "$a_binding" in
1005         ocaml) BINDINGS_TO_BUILD="ocaml $BINDINGS_TO_BUILD" ;;
1006         *) AC_MSG_ERROR([Unrecognized binding $a_binding]) ;;
1007       esac
1008   done
1009   ;;
1010 esac
1011
1012 dnl Allow the ocaml libdir to be overridden. This could go in a configure
1013 dnl script for bindings/ocaml/configure, except that its auto value depends on
1014 dnl OCAMLC, which is found here to support tests.
1015 AC_ARG_WITH([ocaml-libdir],
1016   [AS_HELP_STRING([--with-ocaml-libdir],
1017     [Specify install location for ocaml bindings (default is stdlib)])],
1018   [],
1019   [withval=auto])
1020 case "$withval" in
1021   auto) with_ocaml_libdir="$withval" ;;
1022   /* | [[A-Za-z]]:[[\\/]]*) with_ocaml_libdir="$withval" ;;
1023   *) AC_MSG_ERROR([Invalid path for --with-ocaml-libdir. Provide full path]) ;;
1024 esac
1025
1026 AC_ARG_WITH(clang-srcdir,
1027   AS_HELP_STRING([--with-clang-srcdir],
1028     [Directory to the out-of-tree Clang source]),,
1029     withval="-")
1030 case "$withval" in
1031   -) clang_src_root="" ;;
1032   /* | [[A-Za-z]]:[[\\/]]*) clang_src_root="$withval" ;;
1033   *) clang_src_root="$ac_pwd/$withval" ;;
1034 esac
1035 AC_SUBST(CLANG_SRC_ROOT,[$clang_src_root])
1036
1037 AC_ARG_WITH(clang-resource-dir,
1038   AS_HELP_STRING([--with-clang-resource-dir],
1039     [Relative directory from the Clang binary for resource files]),,
1040     withval="")
1041 AC_DEFINE_UNQUOTED(CLANG_RESOURCE_DIR,"$withval",
1042                    [Relative directory for resource files])
1043
1044 AC_ARG_WITH(c-include-dirs,
1045   AS_HELP_STRING([--with-c-include-dirs],
1046     [Colon separated list of directories clang will search for headers]),,
1047     withval="")
1048 AC_DEFINE_UNQUOTED(C_INCLUDE_DIRS,"$withval",
1049                    [Directories clang will search for headers])
1050
1051 # Clang normally uses the system c++ headers and libraries. With this option,
1052 # clang will use the ones provided by a gcc installation instead. This option should
1053 # be passed the same value that was used with --prefix when configuring gcc.
1054 AC_ARG_WITH(gcc-toolchain,
1055   AS_HELP_STRING([--with-gcc-toolchain],
1056     [Directory where gcc is installed.]),,
1057     withval="")
1058 AC_DEFINE_UNQUOTED(GCC_INSTALL_PREFIX,"$withval",
1059                    [Directory where gcc is installed.])
1060
1061 AC_ARG_WITH(default-sysroot,
1062   AS_HELP_STRING([--with-default-sysroot],
1063     [Add --sysroot=<path> to all compiler invocations.]),,
1064     withval="")
1065 AC_DEFINE_UNQUOTED(DEFAULT_SYSROOT,"$withval",
1066                    [Default <path> to all compiler invocations for --sysroot=<path>.])
1067
1068 dnl Allow linking of LLVM with GPLv3 binutils code.
1069 AC_ARG_WITH(binutils-include,
1070   AS_HELP_STRING([--with-binutils-include],
1071     [Specify path to binutils/include/ containing plugin-api.h file for gold plugin.]),,
1072   withval=default)
1073 case "$withval" in
1074   default) WITH_BINUTILS_INCDIR=default ;;
1075   /* | [[A-Za-z]]:[[\\/]]*)      WITH_BINUTILS_INCDIR=$withval ;;
1076   *) AC_MSG_ERROR([Invalid path for --with-binutils-include. Provide full path]) ;;
1077 esac
1078 if test "x$WITH_BINUTILS_INCDIR" != xdefault ; then
1079   AC_SUBST(BINUTILS_INCDIR,$WITH_BINUTILS_INCDIR)
1080   if test ! -f "$WITH_BINUTILS_INCDIR/plugin-api.h"; then
1081      echo "$WITH_BINUTILS_INCDIR/plugin-api.h"
1082      AC_MSG_ERROR([Invalid path to directory containing plugin-api.h.]);
1083   fi
1084 fi
1085
1086 dnl Specify the URL where bug reports should be submitted.
1087 AC_ARG_WITH(bug-report-url,
1088   AS_HELP_STRING([--with-bug-report-url],
1089     [Specify the URL where bug reports should be submitted (default=http://llvm.org/bugs/)]),,
1090     withval="http://llvm.org/bugs/")
1091 AC_DEFINE_UNQUOTED(BUG_REPORT_URL,"$withval",
1092                    [Bug report URL.])
1093
1094 dnl --enable-terminfo: check whether the user wants to control use of terminfo:
1095 AC_ARG_ENABLE(terminfo,AS_HELP_STRING(
1096   [--enable-terminfo],
1097   [Query the terminfo database if available (default is YES)]),
1098   [case "$enableval" in
1099     yes) llvm_cv_enable_terminfo="yes" ;;
1100     no)  llvm_cv_enable_terminfo="no"  ;;
1101     *) AC_MSG_ERROR([Invalid setting for --enable-terminfo. Use "yes" or "no"]) ;;
1102   esac],
1103   llvm_cv_enable_terminfo="yes")
1104
1105 dnl --enable-libffi : check whether the user wants to turn off libffi:
1106 AC_ARG_ENABLE(libffi,AS_HELP_STRING(
1107   --enable-libffi,[Check for the presence of libffi (default is NO)]),
1108   [case "$enableval" in
1109     yes) llvm_cv_enable_libffi="yes" ;;
1110     no)  llvm_cv_enable_libffi="no"  ;;
1111     *) AC_MSG_ERROR([Invalid setting for --enable-libffi. Use "yes" or "no"]) ;;
1112   esac],
1113   llvm_cv_enable_libffi=no)
1114
1115 AC_ARG_WITH(internal-prefix,
1116   AS_HELP_STRING([--with-internal-prefix],
1117     [Installation directory for internal files]),,
1118     withval="")
1119 AC_SUBST(INTERNAL_PREFIX,[$withval])
1120
1121 dnl===-----------------------------------------------------------------------===
1122 dnl===
1123 dnl=== SECTION 4: Check for programs we need and that they are the right version
1124 dnl===
1125 dnl===-----------------------------------------------------------------------===
1126
1127 AC_PROG_NM
1128 AC_SUBST(NM)
1129
1130 dnl Check for the tools that the makefiles require
1131 AC_CHECK_GNU_MAKE
1132 AC_PROG_LN_S
1133 AC_PATH_PROG(CMP, [cmp], [cmp])
1134 AC_PATH_PROG(CP, [cp], [cp])
1135 AC_PATH_PROG(DATE, [date], [date])
1136 AC_PATH_PROG(FIND, [find], [find])
1137 AC_PATH_PROG(GREP, [grep], [grep])
1138 AC_PATH_PROG(MKDIR,[mkdir],[mkdir])
1139 AC_PATH_PROG(MV,   [mv],   [mv])
1140 AC_PROG_RANLIB
1141 AC_CHECK_TOOL(AR, ar, false)
1142 AC_PATH_PROG(RM,   [rm],   [rm])
1143 AC_PATH_PROG(SED,  [sed],  [sed])
1144 AC_PATH_PROG(TAR,  [tar],  [gtar])
1145 AC_PATH_PROG(BINPWD,[pwd],  [pwd])
1146
1147 dnl Looking for misc. graph plotting software
1148 AC_PATH_PROG(GRAPHVIZ, [Graphviz], [echo Graphviz])
1149 if test "$GRAPHVIZ" != "echo Graphviz" ; then
1150   AC_DEFINE([HAVE_GRAPHVIZ],[1],[Define if the Graphviz program is available])
1151   dnl If we're targeting for mingw we should emit windows paths, not msys
1152   if test "$llvm_cv_os_type" = "MingW" ; then
1153     GRAPHVIZ=`echo $GRAPHVIZ | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
1154   fi
1155   AC_DEFINE_UNQUOTED([LLVM_PATH_GRAPHVIZ],"$GRAPHVIZ${EXEEXT}",
1156    [Define to path to Graphviz program if found or 'echo Graphviz' otherwise])
1157 fi
1158 AC_PATH_PROG(DOT, [dot], [echo dot])
1159 if test "$DOT" != "echo dot" ; then
1160   AC_DEFINE([HAVE_DOT],[1],[Define if the dot program is available])
1161   dnl If we're targeting for mingw we should emit windows paths, not msys
1162   if test "$llvm_cv_os_type" = "MingW" ; then
1163     DOT=`echo $DOT | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
1164   fi
1165   AC_DEFINE_UNQUOTED([LLVM_PATH_DOT],"$DOT${EXEEXT}",
1166    [Define to path to dot program if found or 'echo dot' otherwise])
1167 fi
1168 AC_PATH_PROG(FDP, [fdp], [echo fdp])
1169 if test "$FDP" != "echo fdp" ; then
1170   AC_DEFINE([HAVE_FDP],[1],[Define if the neat program is available])
1171   dnl If we're targeting for mingw we should emit windows paths, not msys
1172   if test "$llvm_cv_os_type" = "MingW" ; then
1173     FDP=`echo $FDP | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
1174   fi
1175   AC_DEFINE_UNQUOTED([LLVM_PATH_FDP],"$FDP${EXEEXT}",
1176    [Define to path to fdp program if found or 'echo fdp' otherwise])
1177 fi
1178 AC_PATH_PROG(NEATO, [neato], [echo neato])
1179 if test "$NEATO" != "echo neato" ; then
1180   AC_DEFINE([HAVE_NEATO],[1],[Define if the neat program is available])
1181   dnl If we're targeting for mingw we should emit windows paths, not msys
1182   if test "$llvm_cv_os_type" = "MingW" ; then
1183     NEATO=`echo $NEATO | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
1184   fi
1185   AC_DEFINE_UNQUOTED([LLVM_PATH_NEATO],"$NEATO${EXEEXT}",
1186    [Define to path to neato program if found or 'echo neato' otherwise])
1187 fi
1188 AC_PATH_PROG(TWOPI, [twopi], [echo twopi])
1189 if test "$TWOPI" != "echo twopi" ; then
1190   AC_DEFINE([HAVE_TWOPI],[1],[Define if the neat program is available])
1191   dnl If we're targeting for mingw we should emit windows paths, not msys
1192   if test "$llvm_cv_os_type" = "MingW" ; then
1193     TWOPI=`echo $TWOPI | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
1194   fi
1195   AC_DEFINE_UNQUOTED([LLVM_PATH_TWOPI],"$TWOPI${EXEEXT}",
1196    [Define to path to twopi program if found or 'echo twopi' otherwise])
1197 fi
1198 AC_PATH_PROG(CIRCO, [circo], [echo circo])
1199 if test "$CIRCO" != "echo circo" ; then
1200   AC_DEFINE([HAVE_CIRCO],[1],[Define if the neat program is available])
1201   dnl If we're targeting for mingw we should emit windows paths, not msys
1202   if test "$llvm_cv_os_type" = "MingW" ; then
1203     CIRCO=`echo $CIRCO | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
1204   fi
1205   AC_DEFINE_UNQUOTED([LLVM_PATH_CIRCO],"$CIRCO${EXEEXT}",
1206    [Define to path to circo program if found or 'echo circo' otherwise])
1207 fi
1208 AC_PATH_PROGS(GV, [gv gsview32], [echo gv])
1209 if test "$GV" != "echo gv" ; then
1210   AC_DEFINE([HAVE_GV],[1],[Define if the gv program is available])
1211   dnl If we're targeting for mingw we should emit windows paths, not msys
1212   if test "$llvm_cv_os_type" = "MingW" ; then
1213     GV=`echo $GV | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
1214   fi
1215   AC_DEFINE_UNQUOTED([LLVM_PATH_GV],"$GV${EXEEXT}",
1216    [Define to path to gv program if found or 'echo gv' otherwise])
1217 fi
1218 AC_PATH_PROG(DOTTY, [dotty], [echo dotty])
1219 if test "$DOTTY" != "echo dotty" ; then
1220   AC_DEFINE([HAVE_DOTTY],[1],[Define if the dotty program is available])
1221   dnl If we're targeting for mingw we should emit windows paths, not msys
1222   if test "$llvm_cv_os_type" = "MingW" ; then
1223     DOTTY=`echo $DOTTY | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
1224   fi
1225   AC_DEFINE_UNQUOTED([LLVM_PATH_DOTTY],"$DOTTY${EXEEXT}",
1226    [Define to path to dotty program if found or 'echo dotty' otherwise])
1227 fi
1228 AC_PATH_PROGS(XDOT, [xdot xdot.py], [echo xdot])
1229 if test "$XDOT" != "echo xdot" ; then
1230   AC_DEFINE([HAVE_XDOT],[1],[Define if the xdot program is available])
1231   dnl If we're targeting for mingw we should emit windows paths, not msys
1232   if test "$llvm_cv_os_type" = "MingW" ; then
1233     XDOT=`echo $XDOT | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
1234   fi
1235   AC_DEFINE_UNQUOTED([LLVM_PATH_XDOT],"$XDOT${EXEEXT}",
1236    [Define to path to xdot program if found or 'echo xdot' otherwise])
1237 fi
1238
1239 dnl Find the install program
1240 AC_PROG_INSTALL
1241 dnl Prepend src dir to install path dir if it's a relative path
1242 dnl This is a hack for installs that take place in something other
1243 dnl than the top level.
1244 case "$INSTALL" in
1245  [[\\/$]]* | ?:[[\\/]]* ) ;;
1246  *)  INSTALL="\\\$(TOPSRCDIR)/$INSTALL" ;;
1247 esac
1248
1249 dnl Checks for documentation and testing tools that we can do without. If these
1250 dnl are not found then they are set to "true" which always succeeds but does
1251 dnl nothing. This just lets the build output show that we could have done
1252 dnl something if the tool was available.
1253 AC_PATH_PROG(BZIP2, [bzip2])
1254 AC_PATH_PROG(CAT, [cat])
1255 AC_PATH_PROG(DOXYGEN, [doxygen])
1256 AC_PATH_PROG(GROFF, [groff])
1257 AC_PATH_PROG(GZIPBIN, [gzip])
1258 AC_PATH_PROG(PDFROFF, [pdfroff])
1259 AC_PATH_PROG(ZIP, [zip])
1260 AC_PATH_PROGS(OCAMLC, [ocamlc])
1261 AC_PATH_PROGS(OCAMLOPT, [ocamlopt])
1262 AC_PATH_PROGS(OCAMLDEP, [ocamldep])
1263 AC_PATH_PROGS(OCAMLDOC, [ocamldoc])
1264 AC_PATH_PROGS(GAS, [gas as])
1265
1266 dnl Get the version of the linker in use.
1267 AC_LINK_GET_VERSION
1268
1269 dnl Determine whether the linker supports the -R option.
1270 AC_LINK_USE_R
1271
1272 dnl Determine whether the compiler supports the -rdynamic option.
1273 AC_LINK_EXPORT_DYNAMIC
1274
1275 dnl Determine whether the linker supports the --version-script option.
1276 AC_LINK_VERSION_SCRIPT
1277
1278 dnl Check for libtool and the library that has dlopen function (which must come
1279 dnl before the AC_PROG_LIBTOOL check in order to enable dlopening libraries with
1280 dnl libtool).
1281 AC_LIBTOOL_DLOPEN
1282 AC_LIB_LTDL
1283
1284 AC_MSG_CHECKING([tool compatibility])
1285
1286 dnl Ensure that compilation tools are GCC or a GNU compatible compiler such as
1287 dnl ICC; we use GCC specific options in the makefiles so the compiler needs
1288 dnl to support those options.
1289 dnl "icc" emits gcc signatures
1290 dnl "icc -no-gcc" emits no gcc signature BUT is still compatible
1291 ICC=no
1292 IXX=no
1293 case $CC in
1294   icc*|icpc*)
1295     ICC=yes
1296     IXX=yes
1297     ;;
1298    *)
1299     ;;
1300 esac
1301
1302 if test "$GCC" != "yes" && test "$ICC" != "yes"
1303 then
1304   AC_MSG_ERROR([gcc|icc required but not found])
1305 fi
1306
1307 dnl Ensure that compilation tools are compatible with GCC extensions
1308 if test "$GXX" != "yes" && test "$IXX" != "yes"
1309 then
1310   AC_MSG_ERROR([g++|clang++|icc required but not found])
1311 fi
1312
1313 dnl Verify that GCC is version 3.0 or higher
1314 if test "$GCC" = "yes"
1315 then
1316   AC_COMPILE_IFELSE(
1317 [
1318   AC_LANG_SOURCE([[
1319     #if !defined(__GNUC__) || __GNUC__ < 3
1320     #error Unsupported GCC version
1321     #endif
1322   ]])
1323 ],
1324 [], [AC_MSG_ERROR([gcc 3.x required, but you have a lower version])])
1325 fi
1326
1327 dnl Check for GNU Make.  We use its extensions, so don't build without it
1328 if test -z "$llvm_cv_gnu_make_command"
1329 then
1330   AC_MSG_ERROR([GNU Make required but not found])
1331 fi
1332
1333 dnl Tool compatibility is okay if we make it here.
1334 AC_MSG_RESULT([ok])
1335
1336 dnl Check optional compiler flags.
1337 AC_MSG_CHECKING([optional compiler flags])
1338 CXX_FLAG_CHECK(NO_VARIADIC_MACROS, [-Wno-variadic-macros])
1339 CXX_FLAG_CHECK(NO_MISSING_FIELD_INITIALIZERS, [-Wno-missing-field-initializers])
1340 CXX_FLAG_CHECK(COVERED_SWITCH_DEFAULT, [-Wcovered-switch-default])
1341
1342 dnl GCC's potential uninitialized use analysis is weak and presents lots of
1343 dnl false positives, so disable it.
1344 NO_UNINITIALIZED=
1345 NO_MAYBE_UNINITIALIZED=
1346 if test "$GXX" = "yes"
1347 then
1348   CXX_FLAG_CHECK(NO_MAYBE_UNINITIALIZED, [-Wno-maybe-uninitialized])
1349   dnl gcc 4.7 introduced -Wmaybe-uninitialized to distinguish cases which are
1350   dnl known to be uninitialized from cases which might be uninitialized.  We
1351   dnl still want to catch the first kind of errors.
1352   if test -z "$NO_MAYBE_UNINITIALIZED"
1353   then
1354     CXX_FLAG_CHECK(NO_UNINITIALIZED, [-Wno-uninitialized])
1355   fi
1356 fi
1357 AC_MSG_RESULT([$NO_VARIADIC_MACROS $NO_MISSING_FIELD_INITIALIZERS $COVERED_SWITCH_DEFAULT $NO_UNINITIALIZED $NO_MAYBE_UNINITIALIZED])
1358
1359 AC_ARG_WITH([python],
1360             [AS_HELP_STRING([--with-python], [path to python])],
1361             [PYTHON="$withval"])
1362
1363 if test -n "$PYTHON" && test -x "$PYTHON" ; then
1364   AC_MSG_CHECKING([for python])
1365   AC_MSG_RESULT([user defined: $with_python])
1366 else
1367   if test -n "$PYTHON" ; then
1368     AC_MSG_WARN([specified python ($PYTHON) is not usable, searching path])
1369   fi
1370
1371   AC_PATH_PROG([PYTHON], [python python2 python26],
1372                [AC_MSG_RESULT([not found])
1373                 AC_MSG_ERROR([could not find python 2.5 or higher])])
1374 fi
1375
1376 AC_MSG_CHECKING([for python >= 2.5])
1377 ac_python_version=`$PYTHON -V 2>&1 | cut -d' ' -f2`
1378 ac_python_version_major=`echo $ac_python_version | cut -d'.' -f1`
1379 ac_python_version_minor=`echo $ac_python_version | cut -d'.' -f2`
1380 ac_python_version_patch=`echo $ac_python_version | cut -d'.' -f3`
1381 if test "$ac_python_version_major" -gt "2" || \
1382    (test "$ac_python_version_major" -eq "2" && \
1383     test "$ac_python_version_minor" -ge "5") ; then
1384   AC_MSG_RESULT([$PYTHON ($ac_python_version)])
1385 else
1386   AC_MSG_RESULT([not found])
1387   AC_MSG_FAILURE([found python $ac_python_version ($PYTHON); required >= 2.5])
1388 fi
1389
1390 dnl===-----------------------------------------------------------------------===
1391 dnl===
1392 dnl=== SECTION 5: Check for libraries
1393 dnl===
1394 dnl===-----------------------------------------------------------------------===
1395
1396 AC_CHECK_LIB(m,sin)
1397 if test "$llvm_cv_os_type" = "MingW" ; then
1398   AC_CHECK_LIB(imagehlp, main)
1399   AC_CHECK_LIB(psapi, main)
1400   AC_CHECK_LIB(shell32, main)
1401 fi
1402
1403 dnl dlopen() is required for plugin support.
1404 AC_SEARCH_LIBS(dlopen,dl,AC_DEFINE([HAVE_DLOPEN],[1],
1405                [Define if dlopen() is available on this platform.]),
1406                AC_MSG_WARN([dlopen() not found - disabling plugin support]))
1407
1408 dnl Search for the clock_gettime() function. Note that we rely on the POSIX
1409 dnl macros to detect whether clock_gettime is available, this just finds the
1410 dnl right libraries to link with.
1411 AC_SEARCH_LIBS(clock_gettime,rt)
1412
1413 dnl The curses library is optional; used for querying terminal info
1414 if test "$llvm_cv_enable_terminfo" = "yes" ; then
1415   dnl We need the has_color functionality in curses for it to be useful.
1416   AC_SEARCH_LIBS(setupterm,tinfo terminfo curses ncurses ncursesw,
1417                  AC_DEFINE([HAVE_TERMINFO],[1],
1418                            [Define if the setupterm() function is supported this platform.]))
1419 fi
1420
1421 dnl libffi is optional; used to call external functions from the interpreter
1422 if test "$llvm_cv_enable_libffi" = "yes" ; then
1423   AC_SEARCH_LIBS(ffi_call,ffi,AC_DEFINE([HAVE_FFI_CALL],[1],
1424                  [Define if libffi is available on this platform.]),
1425                  AC_MSG_ERROR([libffi not found - configure without --enable-libffi to compile without it]))
1426 fi
1427
1428 dnl mallinfo is optional; the code can compile (minus features) without it
1429 AC_SEARCH_LIBS(mallinfo,malloc,AC_DEFINE([HAVE_MALLINFO],[1],
1430                [Define if mallinfo() is available on this platform.]))
1431
1432 dnl pthread locking functions are optional - but llvm will not be thread-safe
1433 dnl without locks.
1434 if test "$LLVM_ENABLE_THREADS" -eq 1 && test "$ENABLE_PTHREADS" -eq 1 ; then
1435   AC_CHECK_LIB(pthread, pthread_mutex_init)
1436   AC_SEARCH_LIBS(pthread_mutex_lock,pthread,
1437                  AC_DEFINE([HAVE_PTHREAD_MUTEX_LOCK],[1],
1438                            [Have pthread_mutex_lock]))
1439   AC_SEARCH_LIBS(pthread_rwlock_init,pthread,
1440                  AC_DEFINE([HAVE_PTHREAD_RWLOCK_INIT],[1],
1441                  [Have pthread_rwlock_init]))
1442   AC_SEARCH_LIBS(pthread_getspecific,pthread,
1443                  AC_DEFINE([HAVE_PTHREAD_GETSPECIFIC],[1],
1444                  [Have pthread_getspecific]))
1445 fi
1446
1447 dnl zlib is optional; used for compression/uncompression
1448 if test "$LLVM_ENABLE_ZLIB" -eq 1 ; then
1449   AC_CHECK_LIB(z, compress2)
1450 fi
1451
1452 dnl Allow extra x86-disassembler library
1453 AC_ARG_WITH(udis86,
1454   AS_HELP_STRING([--with-udis86=<path>],
1455     [Use udis86 external x86 disassembler library]),
1456     [
1457       AC_SUBST(USE_UDIS86, [1])
1458       case "$withval" in
1459         /usr/lib|yes) ;;
1460         *) LDFLAGS="$LDFLAGS -L${withval}" ;;
1461       esac
1462       AC_CHECK_LIB(udis86, ud_init, [], [
1463         echo "Error! You need to have libudis86 around."
1464         exit -1
1465       ])
1466     ],
1467     AC_SUBST(USE_UDIS86, [0]))
1468 AC_DEFINE_UNQUOTED([USE_UDIS86],$USE_UDIS86,
1469                    [Define if use udis86 library])
1470
1471 dnl Allow OProfile support for JIT output.
1472 AC_ARG_WITH(oprofile,
1473   AS_HELP_STRING([--with-oprofile=<prefix>],
1474     [Tell OProfile >= 0.9.4 how to symbolize JIT output]),
1475     [
1476       AC_SUBST(USE_OPROFILE, [1])
1477       case "$withval" in
1478         /usr|yes) llvm_cv_oppath=/usr/lib/oprofile ;;
1479         no) llvm_cv_oppath=
1480             AC_SUBST(USE_OPROFILE, [0]) ;;
1481         *) llvm_cv_oppath="${withval}/lib/oprofile"
1482            CPPFLAGS="-I${withval}/include";;
1483       esac
1484       case $llvm_cv_os_type in
1485         Linux)
1486           if test -n "$llvm_cv_oppath" ; then
1487             LIBS="$LIBS -lopagent -L${llvm_cv_oppath} -Wl,-rpath,${llvm_cv_oppath}"
1488             dnl Work around http://bugs.debian.org/cgi-bin/bugreport.cgi?bug=537744:
1489             dnl libbfd is not included properly in libopagent in some Debian
1490             dnl versions.  If libbfd isn't found at all, we assume opagent works
1491             dnl anyway.
1492             AC_SEARCH_LIBS(bfd_init, bfd, [], [])
1493             AC_SEARCH_LIBS(op_open_agent, opagent, [], [
1494               echo "Error! You need to have libopagent around."
1495               exit -1
1496             ])
1497             AC_CHECK_HEADER([opagent.h], [], [
1498               echo "Error! You need to have opagent.h around."
1499               exit -1
1500               ])
1501           fi ;;
1502         *)
1503           AC_MSG_ERROR([OProfile support is available on Linux only.]) ;;
1504       esac
1505     ],
1506     [
1507       AC_SUBST(USE_OPROFILE, [0])
1508     ])
1509 AC_DEFINE_UNQUOTED([LLVM_USE_OPROFILE],$USE_OPROFILE,
1510                    [Define if we have the oprofile JIT-support library])
1511
1512 dnl Enable support for Intel JIT Events API.
1513 AC_ARG_WITH(intel-jitevents,
1514   AS_HELP_STRING([--with-intel-jitevents  Notify Intel JIT profiling API of generated code]),
1515     [
1516        case "$withval" in
1517           yes) AC_SUBST(USE_INTEL_JITEVENTS,[1]);;
1518           no)  AC_SUBST(USE_INTEL_JITEVENTS,[0]);;
1519           *) AC_MSG_ERROR([Invalid setting for --with-intel-jitevents. Use "yes" or "no"]);;
1520        esac
1521
1522       case $llvm_cv_os_type in
1523         Linux|Win32|Cygwin|MingW) ;;
1524         *) AC_MSG_ERROR([Intel JIT API support is available on Linux and Windows only.]);;
1525       esac
1526
1527       case "$llvm_cv_target_arch" in
1528         x86|x86_64) ;;
1529         *) AC_MSG_ERROR([Target architecture $llvm_cv_target_arch does not support Intel JIT Events API.]);;
1530       esac
1531     ],
1532     [
1533       AC_SUBST(USE_INTEL_JITEVENTS, [0])
1534     ])
1535 AC_DEFINE_UNQUOTED([LLVM_USE_INTEL_JITEVENTS],$USE_INTEL_JITEVENTS,
1536                    [Define if we have the Intel JIT API runtime support library])
1537
1538 dnl Check for libxml2
1539 dnl Right now we're just checking for the existence, we could also check for a
1540 dnl particular version via --version on xml2-config
1541 AC_CHECK_PROGS(XML2CONFIG, xml2-config)
1542
1543 AC_MSG_CHECKING(for libxml2 includes)
1544 if test "x$XML2CONFIG" = "x"; then
1545  AC_MSG_RESULT(xml2-config not found)
1546 else
1547  LIBXML2_INC=`$XML2CONFIG --cflags`
1548  AC_MSG_RESULT($LIBXML2_INC)
1549  AC_CHECK_LIB(xml2, xmlReadFile,[AC_DEFINE([CLANG_HAVE_LIBXML],1,[Define if we have libxml2])
1550                                 LIBXML2_LIBS="-lxml2"])
1551 fi
1552 AC_SUBST(LIBXML2_LIBS)
1553 AC_SUBST(LIBXML2_INC)
1554
1555 dnl===-----------------------------------------------------------------------===
1556 dnl===
1557 dnl=== SECTION 6: Check for header files
1558 dnl===
1559 dnl===-----------------------------------------------------------------------===
1560
1561 dnl First, use autoconf provided macros for specific headers that we need
1562 dnl We don't check for ancient stuff or things that are guaranteed to be there
1563 dnl by the C++ standard. We always use the <cfoo> versions of <foo.h> C headers.
1564 dnl Generally we're looking for POSIX headers.
1565 AC_HEADER_DIRENT
1566 AC_HEADER_MMAP_ANONYMOUS
1567 AC_HEADER_STAT
1568 AC_HEADER_SYS_WAIT
1569 AC_HEADER_TIME
1570
1571 AC_LANG_PUSH([C++])
1572 AC_CHECK_HEADERS([cxxabi.h])
1573 AC_LANG_POP([C++])
1574 AC_CHECK_HEADERS([dlfcn.h execinfo.h fcntl.h inttypes.h link.h])
1575 AC_CHECK_HEADERS([malloc.h setjmp.h signal.h stdint.h termios.h unistd.h])
1576 AC_CHECK_HEADERS([utime.h])
1577 AC_CHECK_HEADERS([sys/mman.h sys/param.h sys/resource.h sys/time.h sys/uio.h])
1578 AC_CHECK_HEADERS([sys/ioctl.h malloc/malloc.h mach/mach.h])
1579 AC_CHECK_HEADERS([valgrind/valgrind.h])
1580 AC_CHECK_HEADERS([fenv.h])
1581 AC_CHECK_DECLS([FE_ALL_EXCEPT, FE_INEXACT], [], [], [[#include <fenv.h>]])
1582 if test "$LLVM_ENABLE_THREADS" -eq 1 && test "$ENABLE_PTHREADS" -eq 1 ; then
1583   AC_CHECK_HEADERS(pthread.h,
1584                    AC_SUBST(HAVE_PTHREAD, 1),
1585                    AC_SUBST(HAVE_PTHREAD, 0))
1586 else
1587   AC_SUBST(HAVE_PTHREAD, 0)
1588 fi
1589 if test "$LLVM_ENABLE_ZLIB" -eq 1 ; then
1590   AC_CHECK_HEADERS(zlib.h,
1591                    AC_SUBST(HAVE_LIBZ, 1),
1592                    AC_SUBST(HAVE_LIBZ, 0))
1593 else
1594   AC_SUBST(HAVE_LIBZ, 0)
1595 fi
1596
1597 dnl Try to find ffi.h.
1598 if test "$llvm_cv_enable_libffi" = "yes" ; then
1599   AC_CHECK_HEADERS([ffi.h ffi/ffi.h])
1600 fi
1601
1602 dnl Try to find Darwin specific crash reporting libraries.
1603 AC_CHECK_HEADERS([CrashReporterClient.h])
1604
1605 dnl Try to find Darwin specific crash reporting global.
1606 AC_MSG_CHECKING([__crashreporter_info__])
1607 AC_LINK_IFELSE(
1608 [
1609   AC_LANG_SOURCE([[
1610     extern const char *__crashreporter_info__;
1611     int main() {
1612       __crashreporter_info__ = "test";
1613       return 0;
1614     }
1615   ]])
1616 ],
1617 [
1618   AC_MSG_RESULT([yes])
1619   AC_DEFINE([HAVE_CRASHREPORTER_INFO], [1], [can use __crashreporter_info__])
1620 ],
1621 [
1622   AC_MSG_RESULT([no])
1623   AC_DEFINE([HAVE_CRASHREPORTER_INFO], [0], [can use __crashreporter_info__])
1624 ])
1625
1626 dnl===-----------------------------------------------------------------------===
1627 dnl===
1628 dnl=== SECTION 7: Check for types and structures
1629 dnl===
1630 dnl===-----------------------------------------------------------------------===
1631
1632 AC_HUGE_VAL_CHECK
1633 AC_TYPE_PID_T
1634 AC_TYPE_SIZE_T
1635 AC_DEFINE_UNQUOTED([RETSIGTYPE],[void],[Define as the return type of signal handlers (`int' or `void').])
1636 AC_STRUCT_TM
1637 AC_CHECK_TYPES([int64_t],,AC_MSG_ERROR([Type int64_t required but not found]))
1638 AC_CHECK_TYPES([uint64_t],,
1639          AC_CHECK_TYPES([u_int64_t],,
1640          AC_MSG_ERROR([Type uint64_t or u_int64_t required but not found])))
1641
1642 dnl===-----------------------------------------------------------------------===
1643 dnl===
1644 dnl=== SECTION 8: Check for specific functions needed
1645 dnl===
1646 dnl===-----------------------------------------------------------------------===
1647
1648 AC_CHECK_FUNCS([backtrace ceilf floorf roundf rintf nearbyintf getcwd ])
1649 AC_CHECK_FUNCS([powf fmodf strtof round ])
1650 AC_CHECK_FUNCS([log log2 log10 exp exp2])
1651 AC_CHECK_FUNCS([getpagesize getrusage getrlimit setrlimit gettimeofday ])
1652 AC_CHECK_FUNCS([isatty mkdtemp mkstemp ])
1653 AC_CHECK_FUNCS([mktemp posix_spawn pread realpath sbrk setrlimit ])
1654 AC_CHECK_FUNCS([strerror strerror_r setenv arc4random ])
1655 AC_CHECK_FUNCS([strtoll strtoq sysconf malloc_zone_statistics ])
1656 AC_CHECK_FUNCS([setjmp longjmp sigsetjmp siglongjmp writev])
1657 AC_CHECK_FUNCS([futimes futimens])
1658 AC_C_PRINTF_A
1659 AC_FUNC_RAND48
1660
1661 dnl Check the declaration "Secure API" on Windows environments.
1662 AC_CHECK_DECLS([strerror_s])
1663
1664 dnl Check symbols in libgcc.a for JIT on Mingw.
1665 if test "$llvm_cv_os_type" = "MingW" ; then
1666   AC_CHECK_LIB(gcc,_alloca,AC_DEFINE([HAVE__ALLOCA],[1],[Have host's _alloca]))
1667   AC_CHECK_LIB(gcc,__alloca,AC_DEFINE([HAVE___ALLOCA],[1],[Have host's __alloca]))
1668   AC_CHECK_LIB(gcc,__chkstk,AC_DEFINE([HAVE___CHKSTK],[1],[Have host's __chkstk]))
1669   AC_CHECK_LIB(gcc,___chkstk,AC_DEFINE([HAVE____CHKSTK],[1],[Have host's ___chkstk]))
1670
1671   AC_CHECK_LIB(gcc,__ashldi3,AC_DEFINE([HAVE___ASHLDI3],[1],[Have host's __ashldi3]))
1672   AC_CHECK_LIB(gcc,__ashrdi3,AC_DEFINE([HAVE___ASHRDI3],[1],[Have host's __ashrdi3]))
1673   AC_CHECK_LIB(gcc,__divdi3,AC_DEFINE([HAVE___DIVDI3],[1],[Have host's __divdi3]))
1674   AC_CHECK_LIB(gcc,__fixdfdi,AC_DEFINE([HAVE___FIXDFDI],[1],[Have host's __fixdfdi]))
1675   AC_CHECK_LIB(gcc,__fixsfdi,AC_DEFINE([HAVE___FIXSFDI],[1],[Have host's __fixsfdi]))
1676   AC_CHECK_LIB(gcc,__floatdidf,AC_DEFINE([HAVE___FLOATDIDF],[1],[Have host's __floatdidf]))
1677   AC_CHECK_LIB(gcc,__lshrdi3,AC_DEFINE([HAVE___LSHRDI3],[1],[Have host's __lshrdi3]))
1678   AC_CHECK_LIB(gcc,__moddi3,AC_DEFINE([HAVE___MODDI3],[1],[Have host's __moddi3]))
1679   AC_CHECK_LIB(gcc,__udivdi3,AC_DEFINE([HAVE___UDIVDI3],[1],[Have host's __udivdi3]))
1680   AC_CHECK_LIB(gcc,__umoddi3,AC_DEFINE([HAVE___UMODDI3],[1],[Have host's __umoddi3]))
1681
1682   AC_CHECK_LIB(gcc,__main,AC_DEFINE([HAVE___MAIN],[1],[Have host's __main]))
1683   AC_CHECK_LIB(gcc,__cmpdi2,AC_DEFINE([HAVE___CMPDI2],[1],[Have host's __cmpdi2]))
1684 fi
1685
1686 dnl Check Win32 API EnumerateLoadedModules.
1687 if test "$llvm_cv_os_type" = "MingW" ; then
1688   AC_MSG_CHECKING([whether EnumerateLoadedModules() accepts new decl])
1689   AC_COMPILE_IFELSE(
1690 [
1691   AC_LANG_SOURCE([[
1692     #include <windows.h>
1693     #include <imagehlp.h>
1694     extern void foo(PENUMLOADED_MODULES_CALLBACK);
1695     extern void foo(BOOL(CALLBACK*)(PCSTR,ULONG_PTR,ULONG,PVOID));
1696   ]])
1697 ],
1698 [
1699   AC_MSG_RESULT([yes])
1700   llvm_cv_win32_elmcb_pcstr="PCSTR"
1701 ],
1702 [
1703   AC_MSG_RESULT([no])
1704   llvm_cv_win32_elmcb_pcstr="PSTR"
1705 ])
1706   AC_DEFINE_UNQUOTED([WIN32_ELMCB_PCSTR],$llvm_cv_win32_elmcb_pcstr,[Type of 1st arg on ELM Callback])
1707 fi
1708
1709 dnl Check for variations in the Standard C++ library and STL. These macros are
1710 dnl provided by LLVM in the autoconf/m4 directory.
1711 AC_FUNC_ISNAN
1712 AC_FUNC_ISINF
1713
1714 dnl Check for mmap support.We also need to know if /dev/zero is required to
1715 dnl be opened for allocating RWX memory.
1716 dnl Make sure we aren't attempting to configure for an unknown system
1717 if test "$llvm_cv_platform_type" = "Unix" ; then
1718   AC_FUNC_MMAP
1719   AC_FUNC_MMAP_FILE
1720   AC_NEED_DEV_ZERO_FOR_MMAP
1721
1722   if test "$ac_cv_func_mmap_fixed_mapped" = "no"
1723   then
1724     AC_MSG_WARN([mmap() of a fixed address required but not supported])
1725   fi
1726   if test "$ac_cv_func_mmap_file" = "no"
1727   then
1728     AC_MSG_WARN([mmap() of files required but not found])
1729   fi
1730 fi
1731
1732 dnl atomic builtins are required for threading support.
1733 AC_MSG_CHECKING(for GCC atomic builtins)
1734 dnl Since we'll be using these atomic builtins in C++ files we should test
1735 dnl the C++ compiler.
1736 AC_LANG_PUSH([C++])
1737 AC_LINK_IFELSE(
1738 [
1739   AC_LANG_SOURCE([[
1740     int main() {
1741       volatile unsigned long val = 1;
1742       __sync_synchronize();
1743       __sync_val_compare_and_swap(&val, 1, 0);
1744       __sync_add_and_fetch(&val, 1);
1745       __sync_sub_and_fetch(&val, 1);
1746       return 0;
1747     }
1748   ]])
1749 ],
1750 [
1751   AC_MSG_RESULT([yes])
1752   AC_DEFINE([LLVM_HAS_ATOMICS], [1], [Has gcc/MSVC atomic intrinsics])
1753 ],
1754 [
1755   AC_MSG_RESULT([no])
1756   AC_DEFINE([LLVM_HAS_ATOMICS], [0], [Has gcc/MSVC atomic intrinsics])
1757   AC_MSG_WARN([LLVM will be built thread-unsafe because atomic builtins are missing])
1758 ])
1759 AC_LANG_POP([C++])
1760
1761 dnl===-----------------------------------------------------------------------===
1762 dnl===
1763 dnl=== SECTION 9: Additional checks, variables, etc.
1764 dnl===
1765 dnl===-----------------------------------------------------------------------===
1766
1767 dnl Handle 32-bit linux systems running a 64-bit kernel.
1768 dnl This has to come after section 4 because it invokes the compiler.
1769 if test "$llvm_cv_os_type" = "Linux" -a "$llvm_cv_target_arch" = "x86_64" ; then
1770   AC_IS_LINUX_MIXED
1771   if test "$llvm_cv_linux_mixed" = "yes"; then
1772     llvm_cv_target_arch="x86"
1773     ARCH="x86"
1774   fi
1775 fi
1776
1777 dnl Check whether __dso_handle is present
1778 AC_CHECK_FUNCS([__dso_handle])
1779
1780 dnl Propagate the shared library extension that the libltdl checks did to
1781 dnl the Makefiles so we can use it there too
1782 AC_SUBST(SHLIBEXT,$libltdl_cv_shlibext)
1783
1784 dnl Propagate the run-time library path variable that the libltdl
1785 dnl checks found to the Makefiles so we can use it there too
1786 AC_SUBST(SHLIBPATH_VAR,$libltdl_cv_shlibpath_var)
1787
1788 dnl Translate the various configuration directories and other basic
1789 dnl information into substitutions that will end up in Makefile.config.in
1790 dnl that these configured values can be used by the makefiles
1791 if test "${prefix}" = "NONE" ; then
1792   prefix="/usr/local"
1793 fi
1794 eval LLVM_PREFIX="${prefix}";
1795 eval LLVM_BINDIR="${prefix}/bin";
1796 eval LLVM_DATADIR="${prefix}/share/llvm";
1797 eval LLVM_DOCSDIR="${prefix}/share/doc/llvm";
1798 eval LLVM_ETCDIR="${prefix}/etc/llvm";
1799 eval LLVM_INCLUDEDIR="${prefix}/include";
1800 eval LLVM_INFODIR="${prefix}/info";
1801 eval LLVM_MANDIR="${prefix}/man";
1802 LLVM_CONFIGTIME=`date`
1803 AC_SUBST(LLVM_PREFIX)
1804 AC_SUBST(LLVM_BINDIR)
1805 AC_SUBST(LLVM_DATADIR)
1806 AC_SUBST(LLVM_DOCSDIR)
1807 AC_SUBST(LLVM_ETCDIR)
1808 AC_SUBST(LLVM_INCLUDEDIR)
1809 AC_SUBST(LLVM_INFODIR)
1810 AC_SUBST(LLVM_MANDIR)
1811 AC_SUBST(LLVM_CONFIGTIME)
1812
1813 dnl Disable embedding timestamps in the build directory, with ENABLE_TIMESTAMPS.
1814 if test "${ENABLE_TIMESTAMPS}" = "0"; then
1815   LLVM_CONFIGTIME="(timestamp not enabled)"
1816 fi
1817
1818 dnl Place the various directories into the config.h file as #defines so that we
1819 dnl can know about the installation paths within LLVM.
1820 AC_DEFINE_UNQUOTED(LLVM_PREFIX,"$LLVM_PREFIX",
1821                    [Installation prefix directory])
1822 AC_DEFINE_UNQUOTED(LLVM_BINDIR, "$LLVM_BINDIR",
1823                    [Installation directory for binary executables])
1824 AC_DEFINE_UNQUOTED(LLVM_DATADIR, "$LLVM_DATADIR",
1825                    [Installation directory for data files])
1826 AC_DEFINE_UNQUOTED(LLVM_DOCSDIR, "$LLVM_DOCSDIR",
1827                    [Installation directory for documentation])
1828 AC_DEFINE_UNQUOTED(LLVM_ETCDIR, "$LLVM_ETCDIR",
1829                    [Installation directory for config files])
1830 AC_DEFINE_UNQUOTED(LLVM_INCLUDEDIR, "$LLVM_INCLUDEDIR",
1831                    [Installation directory for include files])
1832 AC_DEFINE_UNQUOTED(LLVM_INFODIR, "$LLVM_INFODIR",
1833                    [Installation directory for .info files])
1834 AC_DEFINE_UNQUOTED(LLVM_MANDIR, "$LLVM_MANDIR",
1835                    [Installation directory for man pages])
1836 AC_DEFINE_UNQUOTED(LLVM_CONFIGTIME, "$LLVM_CONFIGTIME",
1837                    [Time at which LLVM was configured])
1838 AC_DEFINE_UNQUOTED(LLVM_HOST_TRIPLE, "$host",
1839                    [Host triple LLVM will be executed on])
1840 AC_DEFINE_UNQUOTED(LLVM_DEFAULT_TARGET_TRIPLE, "$target",
1841                    [Target triple LLVM will generate code for by default])
1842
1843 dnl Determine which bindings to build.
1844 if test "$BINDINGS_TO_BUILD" = auto ; then
1845   BINDINGS_TO_BUILD=""
1846   if test "x$OCAMLC" != x -a "x$OCAMLDEP" != x ; then
1847     BINDINGS_TO_BUILD="ocaml $BINDINGS_TO_BUILD"
1848   fi
1849 fi
1850 AC_SUBST(BINDINGS_TO_BUILD,$BINDINGS_TO_BUILD)
1851
1852 dnl This isn't really configurey, but it avoids having to repeat the list in
1853 dnl other files.
1854 AC_SUBST(ALL_BINDINGS,ocaml)
1855
1856 dnl Do any work necessary to ensure that bindings have what they need.
1857 binding_prereqs_failed=0
1858 for a_binding in $BINDINGS_TO_BUILD ; do
1859   case "$a_binding" in
1860   ocaml)
1861     if test "x$OCAMLC" = x ; then
1862       AC_MSG_WARN([--enable-bindings=ocaml specified, but ocamlc not found. Try configure OCAMLC=/path/to/ocamlc])
1863       binding_prereqs_failed=1
1864     fi
1865     if test "x$OCAMLDEP" = x ; then
1866       AC_MSG_WARN([--enable-bindings=ocaml specified, but ocamldep not found. Try configure OCAMLDEP=/path/to/ocamldep])
1867       binding_prereqs_failed=1
1868     fi
1869     if test "x$OCAMLOPT" = x ; then
1870       AC_MSG_WARN([--enable-bindings=ocaml specified, but ocamlopt not found. Try configure OCAMLOPT=/path/to/ocamlopt])
1871       dnl ocamlopt is optional!
1872     fi
1873     if test "x$with_ocaml_libdir" != xauto ; then
1874       AC_SUBST(OCAML_LIBDIR,$with_ocaml_libdir)
1875     else
1876       ocaml_stdlib="`"$OCAMLC" -where`"
1877       if test "$LLVM_PREFIX" '<' "$ocaml_stdlib" -a "$ocaml_stdlib" '<' "$LLVM_PREFIX~"
1878       then
1879         # ocaml stdlib is beneath our prefix; use stdlib
1880         AC_SUBST(OCAML_LIBDIR,$ocaml_stdlib)
1881       else
1882         # ocaml stdlib is outside our prefix; use libdir/ocaml
1883         AC_SUBST(OCAML_LIBDIR,${prefix}/lib/ocaml)
1884       fi
1885     fi
1886     ;;
1887   esac
1888 done
1889 if test "$binding_prereqs_failed" = 1 ; then
1890   AC_MSG_ERROR([Prequisites for bindings not satisfied. Fix them or use configure --disable-bindings.])
1891 fi
1892
1893 dnl Determine whether the compiler supports -fvisibility-inlines-hidden.
1894 AC_CXX_USE_VISIBILITY_INLINES_HIDDEN
1895
1896 dnl Determine linker rpath flag
1897 if test "$llvm_cv_link_use_r" = "yes" ; then
1898   RPATH="-Wl,-R"
1899 else
1900   RPATH="-Wl,-rpath"
1901 fi
1902 AC_SUBST(RPATH)
1903
1904 dnl Determine linker rdynamic flag
1905 if test "$llvm_cv_link_use_export_dynamic" = "yes" ; then
1906   RDYNAMIC="-rdynamic"
1907 else
1908   RDYNAMIC=""
1909 fi
1910 AC_SUBST(RDYNAMIC)
1911
1912 dnl===-----------------------------------------------------------------------===
1913 dnl===
1914 dnl=== SECTION 10: Specify the output files and generate it
1915 dnl===
1916 dnl===-----------------------------------------------------------------------===
1917
1918 dnl Configure header files
1919 dnl WARNING: dnl If you add or remove any of the following config headers, then
1920 dnl you MUST also update Makefile so that the variable FilesToConfig
1921 dnl contains the same list of files as AC_CONFIG_HEADERS below. This ensures the
1922 dnl files can be updated automatically when their *.in sources change.
1923 AC_CONFIG_HEADERS([include/llvm/Config/config.h include/llvm/Config/llvm-config.h])
1924 AH_TOP([#ifndef CONFIG_H
1925 #define CONFIG_H])
1926 AH_BOTTOM([#endif])
1927
1928 AC_CONFIG_FILES([include/llvm/Config/Targets.def])
1929 AC_CONFIG_FILES([include/llvm/Config/AsmPrinters.def])
1930 AC_CONFIG_FILES([include/llvm/Config/AsmParsers.def])
1931 AC_CONFIG_FILES([include/llvm/Config/Disassemblers.def])
1932 AC_CONFIG_HEADERS([include/llvm/Support/DataTypes.h])
1933
1934 dnl Configure the makefile's configuration data
1935 AC_CONFIG_FILES([Makefile.config])
1936
1937 dnl Configure the RPM spec file for LLVM
1938 AC_CONFIG_FILES([llvm.spec])
1939
1940 dnl Configure doxygen's configuration file
1941 AC_CONFIG_FILES([docs/doxygen.cfg])
1942
1943 dnl Configure clang, if present
1944 if test "${clang_src_root}" = ""; then
1945   clang_src_root="$srcdir/tools/clang"
1946 fi
1947 if test -f ${clang_src_root}/README.txt; then
1948   dnl Use variables to stay under 80 columns.
1949   configh="include/clang/Config/config.h"
1950   doxy="docs/doxygen.cfg"
1951   AC_CONFIG_HEADERS([tools/clang/${configh}:${clang_src_root}/${configh}.in])
1952   AC_CONFIG_FILES([tools/clang/${doxy}:${clang_src_root}/${doxy}.in])
1953 fi
1954
1955 dnl OCaml findlib META file
1956 AC_CONFIG_FILES([bindings/ocaml/llvm/META.llvm])
1957
1958 dnl Add --program-prefix value to Makefile.rules. Already an ARG variable.
1959 test "x$program_prefix" = "xNONE" && program_prefix=""
1960 AC_SUBST([program_prefix])
1961
1962
1963 dnl Do special configuration of Makefiles
1964 AC_CONFIG_COMMANDS([setup],,[llvm_src="${srcdir}"])
1965 AC_CONFIG_MAKEFILE(Makefile)
1966 AC_CONFIG_MAKEFILE(Makefile.common)
1967 AC_CONFIG_MAKEFILE(examples/Makefile)
1968 AC_CONFIG_MAKEFILE(lib/Makefile)
1969 AC_CONFIG_MAKEFILE(test/Makefile)
1970 AC_CONFIG_MAKEFILE(test/Makefile.tests)
1971 AC_CONFIG_MAKEFILE(unittests/Makefile)
1972 AC_CONFIG_MAKEFILE(tools/Makefile)
1973 AC_CONFIG_MAKEFILE(utils/Makefile)
1974 AC_CONFIG_MAKEFILE(projects/Makefile)
1975 AC_CONFIG_MAKEFILE(bindings/Makefile)
1976 AC_CONFIG_MAKEFILE(bindings/ocaml/Makefile.ocaml)
1977
1978 dnl Finally, crank out the output
1979 AC_OUTPUT