autoconf/configure.ac

   1 dnl === configure.ac --------------------------------------------------------===
   2 dnl                     The LLVM Compiler Infrastructure
   3 dnl
   4 dnl This file is distributed under the University of Illinois Open Source
   5 dnl License. See LICENSE.TXT for details.
   6 dnl
   7 dnl===-----------------------------------------------------------------------===
   8 dnl This is the LLVM configuration script. It is processed by the autoconf
   9 dnl program to produce a script named configure. This script contains the
  10 dnl configuration checks that LLVM needs in order to support multiple platforms.
  11 dnl This file is composed of 10 sections per the recommended organization of
  12 dnl autoconf input defined in the autoconf documentation. As this file evolves,
  13 dnl please keep the various types of checks within their sections. The sections
  14 dnl are as follows:
  15 dnl
  16 dnl SECTION 1: Initialization & Setup
  17 dnl SECTION 2: Architecture, target, and host checks
  18 dnl SECTION 3: Command line arguments for the configure script.
  19 dnl SECTION 4: Check for programs we need and that they are the right version
  20 dnl SECTION 5: Check for libraries
  21 dnl SECTION 6: Check for header files
  22 dnl SECTION 7: Check for types and structures
  23 dnl SECTION 8: Check for specific functions needed
  24 dnl SECTION 9: Additional checks, variables, etc.
  25 dnl SECTION 10: Specify the output files and generate it
  26 dnl
  27 dnl===-----------------------------------------------------------------------===
  28 dnl===
  29 dnl=== SECTION 1: Initialization & Setup
  30 dnl===
  31 dnl===-----------------------------------------------------------------------===
  32 dnl Initialize autoconf and define the package name, version number and
  33 dnl address for reporting bugs.
  34 AC_INIT([LLVM],[3.3svn],[http://llvm.org/bugs/])
  35 AC_DEFINE([LLVM_VERSION_MAJOR], [3], [Major version of the LLVM API])
  36 AC_DEFINE([LLVM_VERSION_MINOR], [3], [Minor version of the LLVM API])
  37
  38 dnl Provide a copyright substitution and ensure the copyright notice is included
  39 dnl in the output of --version option of the generated configure script.
  40 AC_SUBST(LLVM_COPYRIGHT,["Copyright (c) 2003-2013 University of Illinois at Urbana-Champaign."])
  41 AC_COPYRIGHT([Copyright (c) 2003-2013 University of Illinois at Urbana-Champaign.])
  42
  43 dnl Indicate that we require autoconf 2.60 or later.
  44 AC_PREREQ(2.60)
  45
  46 dnl Verify that the source directory is valid. This makes sure that we are
  47 dnl configuring LLVM and not some other package (it validates --srcdir argument)
  48 AC_CONFIG_SRCDIR([lib/IR/Module.cpp])
  49
  50 dnl Place all of the extra autoconf files into the config subdirectory. Tell
  51 dnl various tools where the m4 autoconf macros are.
  52 AC_CONFIG_AUX_DIR([autoconf])
  53
  54 dnl Quit if the source directory has already been configured.
  55 dnl NOTE: This relies upon undocumented autoconf behavior.
  56 if test ${srcdir} != "." ; then
  57   if test -f ${srcdir}/include/llvm/Config/config.h ; then
  58     AC_MSG_ERROR([Already configured in ${srcdir}])
  59   fi
  60 fi
  61
  62 dnl Default to empty (i.e. assigning the null string to) CFLAGS and CXXFLAGS,
  63 dnl instead of the autoconf default (for example, '-g -O2' for CC=gcc).
  64 ${CFLAGS=}
  65 ${CXXFLAGS=}
  66
  67 dnl We need to check for the compiler up here to avoid anything else
  68 dnl starting with a different one.
  69 AC_PROG_CC(clang llvm-gcc gcc)
  70 AC_PROG_CXX(clang++ llvm-g++ g++)
  71 AC_PROG_CPP
  72
  73 dnl If CXX is Clang, check that it can find and parse C++ standard library
  74 dnl headers.
  75 if test "$CXX" = "clang++" ; then
  76   AC_MSG_CHECKING([whether clang works])
  77   AC_LANG_PUSH([C++])
  78   dnl Note that space between 'include' and '(' is required.  There's a broken
  79   dnl regex in aclocal that otherwise will think that we call m4's include
  80   dnl builtin.
  81   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <limits>
  82 #if __has_include (<cxxabi.h>)
  83 #include <cxxabi.h>
  84 #endif
  85 #if __has_include (<unwind.h>)
  86 #include <unwind.h>
  87 #endif
  88 ]])],
  89 [
  90   AC_MSG_RESULT([yes])
  91 ],
  92 [
  93   AC_MSG_RESULT([no])
  94   AC_MSG_ERROR([Selected compiler could not find or parse C++ standard library headers.  Rerun with CC=c-compiler CXX=c++-compiler ./configure ...])
  95 ])
  96   AC_LANG_POP([C++])
  97 fi
  98
  99 dnl Configure all of the projects present in our source tree. While we could
 100 dnl just AC_CONFIG_SUBDIRS on the set of directories in projects that have a
 101 dnl configure script, that usage of the AC_CONFIG_SUBDIRS macro is deprecated.
 102 dnl Instead we match on the known projects.
 103
 104 dnl
 105 dnl One tricky part of doing this is that some projects depend upon other
 106 dnl projects.  For example, several projects rely upon the LLVM test suite.
 107 dnl We want to configure those projects first so that their object trees are
 108 dnl created before running the configure scripts of projects that depend upon
 109 dnl them.
 110 dnl
 111
 112 dnl Several projects use llvm-gcc, so configure that first
 113 if test -d ${srcdir}/projects/llvm-gcc ; then
 114   AC_CONFIG_SUBDIRS([projects/llvm-gcc])
 115 fi
 116
 117 dnl Several projects use the LLVM test suite, so configure it next.
 118 if test -d ${srcdir}/projects/test-suite ; then
 119   AC_CONFIG_SUBDIRS([projects/test-suite])
 120 fi
 121
 122 dnl llvm-test is the old name of the test-suite, kept here for backwards
 123 dnl compatibility
 124 if test -d ${srcdir}/projects/llvm-test ; then
 125   AC_CONFIG_SUBDIRS([projects/llvm-test])
 126 fi
 127
 128 dnl Some projects use poolalloc; configure that next
 129 if test -d ${srcdir}/projects/poolalloc ; then
 130   AC_CONFIG_SUBDIRS([projects/poolalloc])
 131 fi
 132
 133 if test -d ${srcdir}/projects/llvm-poolalloc ; then
 134   AC_CONFIG_SUBDIRS([projects/llvm-poolalloc])
 135 fi
 136
 137 dnl Check for all other projects
 138 for i in `ls ${srcdir}/projects`
 139 do
 140   if test -d ${srcdir}/projects/${i} ; then
 141     case ${i} in
 142       sample)       AC_CONFIG_SUBDIRS([projects/sample])    ;;
 143       privbracket)  AC_CONFIG_SUBDIRS([projects/privbracket]) ;;
 144       llvm-stacker) AC_CONFIG_SUBDIRS([projects/llvm-stacker]) ;;
 145       llvm-reopt)   AC_CONFIG_SUBDIRS([projects/llvm-reopt]);;
 146       llvm-java)    AC_CONFIG_SUBDIRS([projects/llvm-java]) ;;
 147       llvm-tv)      AC_CONFIG_SUBDIRS([projects/llvm-tv])   ;;
 148       safecode)     AC_CONFIG_SUBDIRS([projects/safecode]) ;;
 149       llvm-kernel)  AC_CONFIG_SUBDIRS([projects/llvm-kernel]) ;;
 150       compiler-rt)       ;;
 151       llvm-gcc)       ;;
 152       test-suite)     ;;
 153       llvm-test)      ;;
 154       poolalloc)      ;;
 155       llvm-poolalloc) ;;
 156       *)
 157         AC_MSG_WARN([Unknown project (${i}) won't be configured automatically])
 158         ;;
 159     esac
 160   fi
 161 done
 162
 163 dnl Disable the build of polly, even if it is checked out into tools/polly.
 164 AC_ARG_ENABLE(polly,
 165               AS_HELP_STRING([--enable-polly],
 166                              [Use polly if available (default is YES)]),,
 167                              enableval=default)
 168 case "$enableval" in
 169   yes) AC_SUBST(ENABLE_POLLY,[1]) ;;
 170   no)  AC_SUBST(ENABLE_POLLY,[0]) ;;
 171   default) AC_SUBST(ENABLE_POLLY,[1]) ;;
 172   *) AC_MSG_ERROR([Invalid setting for --enable-polly. Use "yes" or "no"]) ;;
 173 esac
 174
 175
 176 dnl Check if polly is checked out into tools/polly and configure it if
 177 dnl available.
 178 if (test -d ${srcdir}/tools/polly) && (test $ENABLE_POLLY -eq 1) ; then
 179   AC_SUBST(LLVM_HAS_POLLY,1)
 180   AC_CONFIG_SUBDIRS([tools/polly])
 181 fi
 182
 183 dnl===-----------------------------------------------------------------------===
 184 dnl===
 185 dnl=== SECTION 2: Architecture, target, and host checks
 186 dnl===
 187 dnl===-----------------------------------------------------------------------===
 188
 189 dnl Check the target for which we're compiling and the host that will do the
 190 dnl compilations. This will tell us which LLVM compiler will be used for
 191 dnl compiling SSA into object code. This needs to be done early because
 192 dnl following tests depend on it.
 193 AC_CANONICAL_TARGET
 194
 195 dnl Determine the platform type and cache its value. This helps us configure
 196 dnl the System library to the correct build platform.
 197 AC_CACHE_CHECK([type of operating system we're going to host on],
 198                [llvm_cv_os_type],
 199 [case $host in
 200   *-*-aix*)
 201     llvm_cv_link_all_option="-Wl,--whole-archive"
 202     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 203     llvm_cv_os_type="AIX"
 204     llvm_cv_platform_type="Unix" ;;
 205   *-*-irix*)
 206     llvm_cv_link_all_option="-Wl,--whole-archive"
 207     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 208     llvm_cv_os_type="IRIX"
 209     llvm_cv_platform_type="Unix" ;;
 210   *-*-cygwin*)
 211     llvm_cv_link_all_option="-Wl,--whole-archive"
 212     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 213     llvm_cv_os_type="Cygwin"
 214     llvm_cv_platform_type="Unix" ;;
 215   *-*-darwin*)
 216     llvm_cv_link_all_option="-Wl,-all_load"
 217     llvm_cv_no_link_all_option="-Wl,-noall_load"
 218     llvm_cv_os_type="Darwin"
 219     llvm_cv_platform_type="Unix" ;;
 220   *-*-minix*)
 221     llvm_cv_link_all_option="-Wl,-all_load"
 222     llvm_cv_no_link_all_option="-Wl,-noall_load"
 223     llvm_cv_os_type="Minix"
 224     llvm_cv_platform_type="Unix" ;;
 225   *-*-freebsd* | *-*-kfreebsd-gnu)
 226     llvm_cv_link_all_option="-Wl,--whole-archive"
 227     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 228     llvm_cv_os_type="FreeBSD"
 229     llvm_cv_platform_type="Unix" ;;
 230   *-*-openbsd*)
 231     llvm_cv_link_all_option="-Wl,--whole-archive"
 232     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 233     llvm_cv_os_type="OpenBSD"
 234     llvm_cv_platform_type="Unix" ;;
 235   *-*-netbsd*)
 236     llvm_cv_link_all_option="-Wl,--whole-archive"
 237     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 238     llvm_cv_os_type="NetBSD"
 239     llvm_cv_platform_type="Unix" ;;
 240   *-*-dragonfly*)
 241     llvm_cv_link_all_option="-Wl,--whole-archive"
 242     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 243     llvm_cv_os_type="DragonFly"
 244     llvm_cv_platform_type="Unix" ;;
 245   *-*-hpux*)
 246     llvm_cv_link_all_option="-Wl,--whole-archive"
 247     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 248     llvm_cv_os_type="HP-UX"
 249     llvm_cv_platform_type="Unix" ;;
 250   *-*-interix*)
 251     llvm_cv_link_all_option="-Wl,--whole-archive"
 252     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 253     llvm_cv_os_type="Interix"
 254     llvm_cv_platform_type="Unix" ;;
 255   *-*-linux*)
 256     llvm_cv_link_all_option="-Wl,--whole-archive"
 257     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 258     llvm_cv_os_type="Linux"
 259     llvm_cv_platform_type="Unix" ;;
 260   *-*-gnu*)
 261     llvm_cv_link_all_option="-Wl,--whole-archive"
 262     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 263     llvm_cv_os_type="GNU"
 264     llvm_cv_platform_type="Unix" ;;
 265   *-*-solaris*)
 266     llvm_cv_link_all_option="-Wl,-z,allextract"
 267     llvm_cv_no_link_all_option="-Wl,-z,defaultextract"
 268     llvm_cv_os_type="SunOS"
 269     llvm_cv_platform_type="Unix" ;;
 270   *-*-auroraux*)
 271     llvm_cv_link_all_option="-Wl,-z,allextract"
 272     llvm_cv_link_all_option="-Wl,-z,defaultextract"
 273     llvm_cv_os_type="AuroraUX"
 274     llvm_cv_platform_type="Unix" ;;
 275   *-*-win32*)
 276     llvm_cv_link_all_option="-Wl,--whole-archive"
 277     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 278     llvm_cv_os_type="Win32"
 279     llvm_cv_platform_type="Win32" ;;
 280   *-*-mingw*)
 281     llvm_cv_link_all_option="-Wl,--whole-archive"
 282     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 283     llvm_cv_os_type="MingW"
 284     llvm_cv_platform_type="Win32" ;;
 285   *-*-haiku*)
 286     llvm_cv_link_all_option="-Wl,--whole-archive"
 287     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 288     llvm_cv_os_type="Haiku"
 289     llvm_cv_platform_type="Unix" ;;
 290   *-unknown-eabi*)
 291     llvm_cv_link_all_option="-Wl,--whole-archive"
 292     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 293     llvm_cv_os_type="Freestanding"
 294     llvm_cv_platform_type="Unix" ;;
 295   *-unknown-elf*)
 296     llvm_cv_link_all_option="-Wl,--whole-archive"
 297     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 298     llvm_cv_os_type="Freestanding"
 299     llvm_cv_platform_type="Unix" ;;
 300   *)
 301     llvm_cv_link_all_option=""
 302     llvm_cv_no_link_all_option=""
 303     llvm_cv_os_type="Unknown"
 304     llvm_cv_platform_type="Unknown" ;;
 305 esac])
 306
 307 AC_CACHE_CHECK([type of operating system we're going to target],
 308                [llvm_cv_target_os_type],
 309 [case $target in
 310   *-*-aix*)
 311     llvm_cv_target_os_type="AIX" ;;
 312   *-*-irix*)
 313     llvm_cv_target_os_type="IRIX" ;;
 314   *-*-cygwin*)
 315     llvm_cv_target_os_type="Cygwin" ;;
 316   *-*-darwin*)
 317     llvm_cv_target_os_type="Darwin" ;;
 318   *-*-minix*)
 319     llvm_cv_target_os_type="Minix" ;;
 320   *-*-freebsd* | *-*-kfreebsd-gnu)
 321     llvm_cv_target_os_type="FreeBSD" ;;
 322   *-*-openbsd*)
 323     llvm_cv_target_os_type="OpenBSD" ;;
 324   *-*-netbsd*)
 325     llvm_cv_target_os_type="NetBSD" ;;
 326   *-*-dragonfly*)
 327     llvm_cv_target_os_type="DragonFly" ;;
 328   *-*-hpux*)
 329     llvm_cv_target_os_type="HP-UX" ;;
 330   *-*-interix*)
 331     llvm_cv_target_os_type="Interix" ;;
 332   *-*-linux*)
 333     llvm_cv_target_os_type="Linux" ;;
 334   *-*-gnu*)
 335     llvm_cv_target_os_type="GNU" ;;
 336   *-*-solaris*)
 337     llvm_cv_target_os_type="SunOS" ;;
 338   *-*-auroraux*)
 339     llvm_cv_target_os_type="AuroraUX" ;;
 340   *-*-win32*)
 341     llvm_cv_target_os_type="Win32" ;;
 342   *-*-mingw*)
 343     llvm_cv_target_os_type="MingW" ;;
 344   *-*-haiku*)
 345     llvm_cv_target_os_type="Haiku" ;;
 346   *-*-rtems*)
 347     llvm_cv_target_os_type="RTEMS" ;;
 348   *-*-nacl*)
 349     llvm_cv_target_os_type="NativeClient" ;;
 350   *-unknown-eabi*)
 351     llvm_cv_target_os_type="Freestanding" ;;
 352   *)
 353     llvm_cv_target_os_type="Unknown" ;;
 354 esac])
 355
 356 dnl Make sure we aren't attempting to configure for an unknown system
 357 if test "$llvm_cv_os_type" = "Unknown" ; then
 358   AC_MSG_ERROR([Operating system is unknown, configure can't continue])
 359 fi
 360
 361 dnl Set the "OS" Makefile variable based on the platform type so the
 362 dnl makefile can configure itself to specific build hosts
 363 AC_SUBST(OS,$llvm_cv_os_type)
 364 AC_SUBST(HOST_OS,$llvm_cv_os_type)
 365 AC_SUBST(TARGET_OS,$llvm_cv_target_os_type)
 366
 367 dnl Set the LINKALL and NOLINKALL Makefile variables based on the platform
 368 AC_SUBST(LINKALL,$llvm_cv_link_all_option)
 369 AC_SUBST(NOLINKALL,$llvm_cv_no_link_all_option)
 370
 371 dnl Set the "LLVM_ON_*" variables based on llvm_cv_platform_type
 372 dnl This is used by lib/Support to determine the basic kind of implementation
 373 dnl to use.
 374 case $llvm_cv_platform_type in
 375   Unix)
 376     AC_DEFINE([LLVM_ON_UNIX],[1],[Define if this is Unixish platform])
 377     AC_SUBST(LLVM_ON_UNIX,[1])
 378     AC_SUBST(LLVM_ON_WIN32,[0])
 379     ;;
 380   Win32)
 381     AC_DEFINE([LLVM_ON_WIN32],[1],[Define if this is Win32ish platform])
 382     AC_SUBST(LLVM_ON_UNIX,[0])
 383     AC_SUBST(LLVM_ON_WIN32,[1])
 384     ;;
 385 esac
 386
 387 dnl Determine what our target architecture is and configure accordingly.
 388 dnl This will allow Makefiles to make a distinction between the hardware and
 389 dnl the OS.
 390 AC_CACHE_CHECK([target architecture],[llvm_cv_target_arch],
 391 [case $target in
 392   i?86-*)                 llvm_cv_target_arch="x86" ;;
 393   amd64-* | x86_64-*)     llvm_cv_target_arch="x86_64" ;;
 394   sparc*-*)               llvm_cv_target_arch="Sparc" ;;
 395   powerpc*-*)             llvm_cv_target_arch="PowerPC" ;;
 396   arm*-*)                 llvm_cv_target_arch="ARM" ;;
 397   aarch64*-*)             llvm_cv_target_arch="AArch64" ;;
 398   mips-* | mips64-*)      llvm_cv_target_arch="Mips" ;;
 399   mipsel-* | mips64el-*)  llvm_cv_target_arch="Mips" ;;
 400   xcore-*)                llvm_cv_target_arch="XCore" ;;
 401   msp430-*)               llvm_cv_target_arch="MSP430" ;;
 402   hexagon-*)              llvm_cv_target_arch="Hexagon" ;;
 403   mblaze-*)               llvm_cv_target_arch="MBlaze" ;;
 404   nvptx-*)                llvm_cv_target_arch="NVPTX" ;;
 405   *)                      llvm_cv_target_arch="Unknown" ;;
 406 esac])
 407
 408 if test "$llvm_cv_target_arch" = "Unknown" ; then
 409   AC_MSG_WARN([Configuring LLVM for an unknown target archicture])
 410 fi
 411
 412 dnl Determine the LLVM native architecture for the target
 413 case "$llvm_cv_target_arch" in
 414     x86)     LLVM_NATIVE_ARCH="X86" ;;
 415     x86_64)  LLVM_NATIVE_ARCH="X86" ;;
 416     *)       LLVM_NATIVE_ARCH="$llvm_cv_target_arch" ;;
 417 esac
 418
 419 dnl Define a substitution, ARCH, for the target architecture
 420 AC_SUBST(ARCH,$llvm_cv_target_arch)
 421
 422 dnl Determine what our host architecture.
 423 dnl This will allow MCJIT regress tests runs only for supported
 424 dnl platforms.
 425 case $host in
 426   i?86-*)                 host_arch="x86" ;;
 427   amd64-* | x86_64-*)     host_arch="x86_64" ;;
 428   sparc*-*)               host_arch="Sparc" ;;
 429   powerpc*-*)             host_arch="PowerPC" ;;
 430   arm*-*)                 host_arch="ARM" ;;
 431   aarch64*-*)             host_arch="AArch64" ;;
 432   mips-* | mips64-*)      host_arch="Mips" ;;
 433   mipsel-* | mips64el-*)  host_arch="Mips" ;;
 434   xcore-*)                host_arch="XCore" ;;
 435   msp430-*)               host_arch="MSP430" ;;
 436   hexagon-*)              host_arch="Hexagon" ;;
 437   mblaze-*)               host_arch="MBlaze" ;;
 438   *)                      host_arch="Unknown" ;;
 439 esac
 440
 441 if test "$host_arch" = "Unknown" ; then
 442   AC_MSG_WARN([Configuring LLVM for an unknown host archicture])
 443 fi
 444
 445 AC_SUBST(HOST_ARCH,$host_arch)
 446
 447 dnl Check for the endianness of the target
 448 AC_C_BIGENDIAN(AC_SUBST([ENDIAN],[big]),AC_SUBST([ENDIAN],[little]))
 449
 450 dnl Check for build platform executable suffix if we're cross-compiling
 451 if test "$cross_compiling" = yes; then
 452   AC_SUBST(LLVM_CROSS_COMPILING, [1])
 453   AC_BUILD_EXEEXT
 454   ac_build_prefix=${build_alias}-
 455   AC_CHECK_PROG(BUILD_CXX, ${ac_build_prefix}g++, ${ac_build_prefix}g++)
 456   if test -z "$BUILD_CXX"; then
 457      AC_CHECK_PROG(BUILD_CXX, g++, g++)
 458      if test -z "$BUILD_CXX"; then
 459        AC_CHECK_PROG(BUILD_CXX, c++, c++, , , /usr/ucb/c++)
 460      fi
 461   fi
 462 else
 463   AC_SUBST(LLVM_CROSS_COMPILING, [0])
 464 fi
 465
 466 dnl Check to see if there's a .svn or .git directory indicating that this
 467 dnl build is being done from a checkout. This sets up several defaults for
 468 dnl the command line switches. When we build with a checkout directory,
 469 dnl we get a debug with assertions turned on. Without, we assume a source
 470 dnl release and we get an optimized build without assertions.
 471 dnl See --enable-optimized and --enable-assertions below
 472 if test -d ".svn" -o -d "${srcdir}/.svn" -o -d ".git" -o -d "${srcdir}/.git"; then
 473   cvsbuild="yes"
 474   optimize="no"
 475   AC_SUBST(CVSBUILD,[[CVSBUILD=1]])
 476 else
 477   cvsbuild="no"
 478   optimize="yes"
 479 fi
 480
 481 dnl===-----------------------------------------------------------------------===
 482 dnl===
 483 dnl=== SECTION 3: Command line arguments for the configure script.
 484 dnl===
 485 dnl===-----------------------------------------------------------------------===
 486
 487 dnl --enable-libcpp : check whether or not to use libc++ on the command line
 488 AC_ARG_ENABLE(libcpp,
 489               AS_HELP_STRING([--enable-libcpp],
 490                              [Use libc++ if available (default is NO)]),,
 491                              enableval=default)
 492 case "$enableval" in
 493   yes) AC_SUBST(ENABLE_LIBCPP,[1]) ;;
 494   no)  AC_SUBST(ENABLE_LIBCPP,[0]) ;;
 495   default) AC_SUBST(ENABLE_LIBCPP,[0]);;
 496   *) AC_MSG_ERROR([Invalid setting for --enable-libcpp. Use "yes" or "no"]) ;;
 497 esac
 498
 499 dnl --enable-cxx11 : check whether or not to use -std=c++11 on the command line
 500 AC_ARG_ENABLE(cxx11,
 501               AS_HELP_STRING([--enable-cxx11],
 502                              [Use c++11 if available (default is NO)]),,
 503                              enableval=default)
 504 case "$enableval" in
 505   yes) AC_SUBST(ENABLE_CXX11,[1]) ;;
 506   no)  AC_SUBST(ENABLE_CXX11,[0]) ;;
 507   default) AC_SUBST(ENABLE_CXX11,[0]);;
 508   *) AC_MSG_ERROR([Invalid setting for --enable-cxx11. Use "yes" or "no"]) ;;
 509 esac
 510
 511 dnl --enable-clang-arcmt: check whether to enable clang arcmt
 512 clang_arcmt="yes"
 513 AC_ARG_ENABLE(clang-arcmt,
 514               AS_HELP_STRING([--enable-clang-arcmt],
 515                              [Enable building of clang ARCMT (default is YES)]),
 516                              clang_arcmt="$enableval",
 517                              enableval="yes")
 518 case "$enableval" in
 519   yes) AC_SUBST(ENABLE_CLANG_ARCMT,[1]) ;;
 520   no)  AC_SUBST(ENABLE_CLANG_ARCMT,[0]) ;;
 521   default) AC_SUBST(ENABLE_CLANG_ARCMT,[1]);;
 522   *) AC_MSG_ERROR([Invalid setting for --enable-clang-arcmt. Use "yes" or "no"]) ;;
 523 esac
 524
 525 dnl --enable-clang-static-analyzer: check whether to enable static-analyzer
 526 clang_static_analyzer="yes"
 527 AC_ARG_ENABLE(clang-static-analyzer,
 528               AS_HELP_STRING([--enable-clang-static-analyzer],
 529                              [Enable building of clang Static Analyzer (default is YES)]),
 530                              clang_static_analyzer="$enableval",
 531                              enableval="yes")
 532 case "$enableval" in
 533   yes) AC_SUBST(ENABLE_CLANG_STATIC_ANALYZER,[1]) ;;
 534   no)  AC_SUBST(ENABLE_CLANG_STATIC_ANALYZER,[0]) ;;
 535   default) AC_SUBST(ENABLE_CLANG_STATIC_ANALYZER,[1]);;
 536   *) AC_MSG_ERROR([Invalid setting for --enable-clang-static-analyzer. Use "yes" or "no"]) ;;
 537 esac
 538
 539 dnl --enable-clang-rewriter: check whether to enable clang rewriter
 540 AC_ARG_ENABLE(clang-rewriter,
 541               AS_HELP_STRING([--enable-clang-rewriter],
 542                              [Enable building of clang rewriter (default is YES)]),,
 543                              enableval="yes")
 544 case "$enableval" in
 545   yes) AC_SUBST(ENABLE_CLANG_REWRITER,[1]) ;;
 546   no)
 547     if test ${clang_arcmt} != "no" ; then
 548       AC_MSG_ERROR([Cannot enable clang ARC Migration Tool while disabling rewriter.])
 549     fi
 550     if test ${clang_static_analyzer} != "no" ; then
 551       AC_MSG_ERROR([Cannot enable clang static analyzer while disabling rewriter.])
 552     fi
 553     AC_SUBST(ENABLE_CLANG_REWRITER,[0])
 554     ;;
 555   default) AC_SUBST(ENABLE_CLANG_REWRITER,[1]);;
 556   *) AC_MSG_ERROR([Invalid setting for --enable-clang-rewriter. Use "yes" or "no"]) ;;
 557 esac
 558
 559 dnl --enable-optimized : check whether they want to do an optimized build:
 560 AC_ARG_ENABLE(optimized, AS_HELP_STRING(
 561  --enable-optimized,[Compile with optimizations enabled (default is NO)]),,enableval=$optimize)
 562 if test ${enableval} = "no" ; then
 563   AC_SUBST(ENABLE_OPTIMIZED,[[]])
 564 else
 565   AC_SUBST(ENABLE_OPTIMIZED,[[ENABLE_OPTIMIZED=1]])
 566 fi
 567
 568 dnl --enable-profiling : check whether they want to do a profile build:
 569 AC_ARG_ENABLE(profiling, AS_HELP_STRING(
 570  --enable-profiling,[Compile with profiling enabled (default is NO)]),,enableval="no")
 571 if test ${enableval} = "no" ; then
 572   AC_SUBST(ENABLE_PROFILING,[[]])
 573 else
 574   AC_SUBST(ENABLE_PROFILING,[[ENABLE_PROFILING=1]])
 575 fi
 576
 577 dnl --enable-assertions : check whether they want to turn on assertions or not:
 578 AC_ARG_ENABLE(assertions,AS_HELP_STRING(
 579   --enable-assertions,[Compile with assertion checks enabled (default is YES)]),, enableval="yes")
 580 if test ${enableval} = "yes" ; then
 581   AC_SUBST(DISABLE_ASSERTIONS,[[]])
 582 else
 583   AC_SUBST(DISABLE_ASSERTIONS,[[DISABLE_ASSERTIONS=1]])
 584 fi
 585
 586 dnl --enable-werror : check whether we want Werror on by default
 587 AC_ARG_ENABLE(werror,AS_HELP_STRING(
 588   --enable-werror,[Compile with -Werror enabled (default is NO)]),, enableval="no")
 589 case "$enableval" in
 590   yes) AC_SUBST(ENABLE_WERROR,[1]) ;;
 591   no)  AC_SUBST(ENABLE_WERROR,[0]) ;;
 592   default) AC_SUBST(ENABLE_WERROR,[0]);;
 593   *) AC_MSG_ERROR([Invalid setting for --enable-werror. Use "yes" or "no"]) ;;
 594 esac
 595
 596 dnl --enable-expensive-checks : check whether they want to turn on expensive debug checks:
 597 AC_ARG_ENABLE(expensive-checks,AS_HELP_STRING(
 598   --enable-expensive-checks,[Compile with expensive debug checks enabled (default is NO)]),, enableval="no")
 599 if test ${enableval} = "yes" ; then
 600   AC_SUBST(ENABLE_EXPENSIVE_CHECKS,[[ENABLE_EXPENSIVE_CHECKS=1]])
 601   AC_SUBST(EXPENSIVE_CHECKS,[[yes]])
 602 else
 603   AC_SUBST(ENABLE_EXPENSIVE_CHECKS,[[]])
 604   AC_SUBST(EXPENSIVE_CHECKS,[[no]])
 605 fi
 606
 607 dnl --enable-debug-runtime : should runtime libraries have debug symbols?
 608 AC_ARG_ENABLE(debug-runtime,
 609    AS_HELP_STRING(--enable-debug-runtime,[Build runtime libs with debug symbols (default is NO)]),,enableval=no)
 610 if test ${enableval} = "no" ; then
 611   AC_SUBST(DEBUG_RUNTIME,[[]])
 612 else
 613   AC_SUBST(DEBUG_RUNTIME,[[DEBUG_RUNTIME=1]])
 614 fi
 615
 616 dnl --enable-debug-symbols : should even optimized compiler libraries
 617 dnl have debug symbols?
 618 AC_ARG_ENABLE(debug-symbols,
 619    AS_HELP_STRING(--enable-debug-symbols,[Build compiler with debug symbols (default is NO if optimization is on and YES if it's off)]),,enableval=no)
 620 if test ${enableval} = "no" ; then
 621   AC_SUBST(DEBUG_SYMBOLS,[[]])
 622 else
 623   AC_SUBST(DEBUG_SYMBOLS,[[DEBUG_SYMBOLS=1]])
 624 fi
 625
 626 dnl --enable-keep-symbols : do not strip installed executables
 627 AC_ARG_ENABLE(keep-symbols,
 628    AS_HELP_STRING(--enable-keep-symbols,[Do not strip installed executables)]),,enableval=no)
 629 if test ${enableval} = "no" ; then
 630   AC_SUBST(KEEP_SYMBOLS,[[]])
 631 else
 632   AC_SUBST(KEEP_SYMBOLS,[[KEEP_SYMBOLS=1]])
 633 fi
 634
 635 dnl --enable-jit: check whether they want to enable the jit
 636 AC_ARG_ENABLE(jit,
 637   AS_HELP_STRING(--enable-jit,
 638                  [Enable Just In Time Compiling (default is YES)]),,
 639   enableval=default)
 640 if test ${enableval} = "no"
 641 then
 642   AC_SUBST(JIT,[[]])
 643 else
 644   case "$llvm_cv_target_arch" in
 645     x86)         AC_SUBST(TARGET_HAS_JIT,1) ;;
 646     Sparc)       AC_SUBST(TARGET_HAS_JIT,0) ;;
 647     PowerPC)     AC_SUBST(TARGET_HAS_JIT,1) ;;
 648     x86_64)      AC_SUBST(TARGET_HAS_JIT,1) ;;
 649     ARM)         AC_SUBST(TARGET_HAS_JIT,1) ;;
 650     AArch64)     AC_SUBST(TARGET_HAS_JIT,0) ;;
 651     Mips)        AC_SUBST(TARGET_HAS_JIT,1) ;;
 652     XCore)       AC_SUBST(TARGET_HAS_JIT,0) ;;
 653     MSP430)      AC_SUBST(TARGET_HAS_JIT,0) ;;
 654     Hexagon)     AC_SUBST(TARGET_HAS_JIT,0) ;;
 655     MBlaze)      AC_SUBST(TARGET_HAS_JIT,0) ;;
 656     NVPTX)       AC_SUBST(TARGET_HAS_JIT,0) ;;
 657     *)           AC_SUBST(TARGET_HAS_JIT,0) ;;
 658   esac
 659 fi
 660
 661 dnl Allow enablement of building and installing docs
 662 AC_ARG_ENABLE(docs,
 663               AS_HELP_STRING([--enable-docs],
 664                              [Build documents (default is YES)]),,
 665                              enableval=default)
 666 case "$enableval" in
 667   yes) AC_SUBST(ENABLE_DOCS,[1]) ;;
 668   no)  AC_SUBST(ENABLE_DOCS,[0]) ;;
 669   default) AC_SUBST(ENABLE_DOCS,[1]) ;;
 670   *) AC_MSG_ERROR([Invalid setting for --enable-docs. Use "yes" or "no"]) ;;
 671 esac
 672
 673 dnl Allow enablement of doxygen generated documentation
 674 AC_ARG_ENABLE(doxygen,
 675               AS_HELP_STRING([--enable-doxygen],
 676                              [Build doxygen documentation (default is NO)]),,
 677                              enableval=default)
 678 case "$enableval" in
 679   yes) AC_SUBST(ENABLE_DOXYGEN,[1]) ;;
 680   no)  AC_SUBST(ENABLE_DOXYGEN,[0]) ;;
 681   default) AC_SUBST(ENABLE_DOXYGEN,[0]) ;;
 682   *) AC_MSG_ERROR([Invalid setting for --enable-doxygen. Use "yes" or "no"]) ;;
 683 esac
 684
 685 dnl Allow disablement of threads
 686 AC_ARG_ENABLE(threads,
 687               AS_HELP_STRING([--enable-threads],
 688                              [Use threads if available (default is YES)]),,
 689                              enableval=default)
 690 case "$enableval" in
 691   yes) AC_SUBST(LLVM_ENABLE_THREADS,[1]) ;;
 692   no)  AC_SUBST(LLVM_ENABLE_THREADS,[0]) ;;
 693   default) AC_SUBST(LLVM_ENABLE_THREADS,[1]) ;;
 694   *) AC_MSG_ERROR([Invalid setting for --enable-threads. Use "yes" or "no"]) ;;
 695 esac
 696 AC_DEFINE_UNQUOTED([LLVM_ENABLE_THREADS],$LLVM_ENABLE_THREADS,
 697                    [Define if threads enabled])
 698
 699 dnl Allow disablement of pthread.h
 700 AC_ARG_ENABLE(pthreads,
 701               AS_HELP_STRING([--enable-pthreads],
 702                              [Use pthreads if available (default is YES)]),,
 703                              enableval=default)
 704 case "$enableval" in
 705   yes) AC_SUBST(ENABLE_PTHREADS,[1]) ;;
 706   no)  AC_SUBST(ENABLE_PTHREADS,[0]) ;;
 707   default) AC_SUBST(ENABLE_PTHREADS,[1]) ;;
 708   *) AC_MSG_ERROR([Invalid setting for --enable-pthreads. Use "yes" or "no"]) ;;
 709 esac
 710
 711 dnl Allow building without position independent code
 712 AC_ARG_ENABLE(pic,
 713   AS_HELP_STRING([--enable-pic],
 714                  [Build LLVM with Position Independent Code (default is YES)]),,
 715                  enableval=default)
 716 case "$enableval" in
 717   yes) AC_SUBST(ENABLE_PIC,[1]) ;;
 718   no)  AC_SUBST(ENABLE_PIC,[0]) ;;
 719   default) AC_SUBST(ENABLE_PIC,[1]) ;;
 720   *) AC_MSG_ERROR([Invalid setting for --enable-pic. Use "yes" or "no"]) ;;
 721 esac
 722 AC_DEFINE_UNQUOTED([ENABLE_PIC],$ENABLE_PIC,
 723                    [Define if position independent code is enabled])
 724
 725 dnl Allow building a shared library and linking tools against it.
 726 AC_ARG_ENABLE(shared,
 727   AS_HELP_STRING([--enable-shared],
 728                  [Build a shared library and link tools against it (default is NO)]),,
 729                  enableval=default)
 730 case "$enableval" in
 731   yes) AC_SUBST(ENABLE_SHARED,[1]) ;;
 732   no)  AC_SUBST(ENABLE_SHARED,[0]) ;;
 733   default) AC_SUBST(ENABLE_SHARED,[0]) ;;
 734   *) AC_MSG_ERROR([Invalid setting for --enable-shared. Use "yes" or "no"]) ;;
 735 esac
 736
 737 dnl Allow libstdc++ is embedded in LLVM.dll.
 738 AC_ARG_ENABLE(embed-stdcxx,
 739   AS_HELP_STRING([--enable-embed-stdcxx],
 740                  [Build a shared library with embedded libstdc++ for Win32 DLL (default is NO)]),,
 741                  enableval=default)
 742 case "$enableval" in
 743   yes) AC_SUBST(ENABLE_EMBED_STDCXX,[1]) ;;
 744   no)  AC_SUBST(ENABLE_EMBED_STDCXX,[0]) ;;
 745   default) AC_SUBST(ENABLE_EMBED_STDCXX,[0]) ;;
 746   *) AC_MSG_ERROR([Invalid setting for --enable-embed-stdcxx. Use "yes" or "no"]) ;;
 747 esac
 748
 749 dnl Enable embedding timestamp information into build.
 750 AC_ARG_ENABLE(timestamps,
 751   AS_HELP_STRING([--enable-timestamps],
 752                  [Enable embedding timestamp information in build (default is YES)]),,
 753                  enableval=default)
 754 case "$enableval" in
 755   yes) AC_SUBST(ENABLE_TIMESTAMPS,[1]) ;;
 756   no)  AC_SUBST(ENABLE_TIMESTAMPS,[0]) ;;
 757   default) AC_SUBST(ENABLE_TIMESTAMPS,[1]) ;;
 758   *) AC_MSG_ERROR([Invalid setting for --enable-timestamps. Use "yes" or "no"]) ;;
 759 esac
 760 AC_DEFINE_UNQUOTED([ENABLE_TIMESTAMPS],$ENABLE_TIMESTAMPS,
 761                    [Define if timestamp information (e.g., __DATE__) is allowed])
 762
 763 dnl Enable embedding timestamp information into build.
 764
 765 AC_ARG_ENABLE(backtraces,
 766   AS_HELP_STRING([--enable-backtraces],
 767                  [Enable embedding backtraces on crash (default is YES)]),,
 768                  enableval=default)
 769 case "$enableval" in
 770   yes) AC_SUBST(ENABLE_BACKTRACES,[1]) ;;
 771   no)  AC_SUBST(ENABLE_BACKTRACES,[0]) ;;
 772   default) AC_SUBST(ENABLE_BACKTRACES,[1]) ;;
 773   *) AC_MSG_ERROR([Invalid setting for --enable-backtraces. Use "yes" or "no"]) ;;
 774 esac
 775 AC_DEFINE_UNQUOTED([ENABLE_BACKTRACES],$ENABLE_BACKTRACES,
 776                    [Define if you want backtraces on crash])
 777
 778 dnl Allow specific targets to be specified for building (or not)
 779 TARGETS_TO_BUILD=""
 780 AC_ARG_ENABLE([targets],AS_HELP_STRING([--enable-targets],
 781     [Build specific host targets: all or target1,target2,... Valid targets are:
 782      host, x86, x86_64, sparc, powerpc, arm, aarch64, mips, hexagon,
 783      xcore, msp430, nvptx, and cpp (default=all)]),,
 784     enableval=all)
 785 if test "$enableval" = host-only ; then
 786   enableval=host
 787 fi
 788 case "$enableval" in
 789   all) TARGETS_TO_BUILD="X86 Sparc PowerPC AArch64 ARM Mips XCore MSP430 CppBackend MBlaze NVPTX Hexagon" ;;
 790   *)for a_target in `echo $enableval|sed -e 's/,/ /g' ` ; do
 791       case "$a_target" in
 792         x86)      TARGETS_TO_BUILD="X86 $TARGETS_TO_BUILD" ;;
 793         x86_64)   TARGETS_TO_BUILD="X86 $TARGETS_TO_BUILD" ;;
 794         sparc)    TARGETS_TO_BUILD="Sparc $TARGETS_TO_BUILD" ;;
 795         powerpc)  TARGETS_TO_BUILD="PowerPC $TARGETS_TO_BUILD" ;;
 796         aarch64)  TARGETS_TO_BUILD="AArch64 $TARGETS_TO_BUILD" ;;
 797         arm)      TARGETS_TO_BUILD="ARM $TARGETS_TO_BUILD" ;;
 798         mips)     TARGETS_TO_BUILD="Mips $TARGETS_TO_BUILD" ;;
 799         mipsel)   TARGETS_TO_BUILD="Mips $TARGETS_TO_BUILD" ;;
 800         mips64)   TARGETS_TO_BUILD="Mips $TARGETS_TO_BUILD" ;;
 801         mips64el) TARGETS_TO_BUILD="Mips $TARGETS_TO_BUILD" ;;
 802         xcore)    TARGETS_TO_BUILD="XCore $TARGETS_TO_BUILD" ;;
 803         msp430)   TARGETS_TO_BUILD="MSP430 $TARGETS_TO_BUILD" ;;
 804         cpp)      TARGETS_TO_BUILD="CppBackend $TARGETS_TO_BUILD" ;;
 805         hexagon)  TARGETS_TO_BUILD="Hexagon $TARGETS_TO_BUILD" ;;
 806         mblaze)   TARGETS_TO_BUILD="MBlaze $TARGETS_TO_BUILD" ;;
 807         nvptx)    TARGETS_TO_BUILD="NVPTX $TARGETS_TO_BUILD" ;;
 808         host) case "$llvm_cv_target_arch" in
 809             x86)         TARGETS_TO_BUILD="X86 $TARGETS_TO_BUILD" ;;
 810             x86_64)      TARGETS_TO_BUILD="X86 $TARGETS_TO_BUILD" ;;
 811             Sparc)       TARGETS_TO_BUILD="Sparc $TARGETS_TO_BUILD" ;;
 812             PowerPC)     TARGETS_TO_BUILD="PowerPC $TARGETS_TO_BUILD" ;;
 813             ARM)         TARGETS_TO_BUILD="ARM $TARGETS_TO_BUILD" ;;
 814             Mips)        TARGETS_TO_BUILD="Mips $TARGETS_TO_BUILD" ;;
 815             MBlaze)      TARGETS_TO_BUILD="MBlaze $TARGETS_TO_BUILD" ;;
 816             XCore)       TARGETS_TO_BUILD="XCore $TARGETS_TO_BUILD" ;;
 817             MSP430)      TARGETS_TO_BUILD="MSP430 $TARGETS_TO_BUILD" ;;
 818             Hexagon)     TARGETS_TO_BUILD="Hexagon $TARGETS_TO_BUILD" ;;
 819             NVPTX)       TARGETS_TO_BUILD="NVPTX $TARGETS_TO_BUILD" ;;
 820             *)       AC_MSG_ERROR([Can not set target to build]) ;;
 821           esac ;;
 822         *) AC_MSG_ERROR([Unrecognized target $a_target]) ;;
 823       esac
 824   done
 825   ;;
 826 esac
 827
 828 AC_ARG_ENABLE([experimental-targets],AS_HELP_STRING([--enable-experimental-targets],
 829     [Build experimental host targets: disable or target1,target2,...
 830      (default=disable)]),,
 831     enableval=disable)
 832
 833 if test ${enableval} != "disable"
 834 then
 835   TARGETS_TO_BUILD="$enableval $TARGETS_TO_BUILD"
 836 fi
 837
 838 AC_SUBST(TARGETS_TO_BUILD,$TARGETS_TO_BUILD)
 839
 840 dnl Determine whether we are building LLVM support for the native architecture.
 841 dnl If so, define LLVM_NATIVE_ARCH to that LLVM target.
 842 for a_target in $TARGETS_TO_BUILD; do
 843   if test "$a_target" = "$LLVM_NATIVE_ARCH"; then
 844     AC_DEFINE_UNQUOTED(LLVM_NATIVE_ARCH, $LLVM_NATIVE_ARCH,
 845       [LLVM architecture name for the native architecture, if available])
 846     LLVM_NATIVE_TARGET="LLVMInitialize${LLVM_NATIVE_ARCH}Target"
 847     LLVM_NATIVE_TARGETINFO="LLVMInitialize${LLVM_NATIVE_ARCH}TargetInfo"
 848     LLVM_NATIVE_TARGETMC="LLVMInitialize${LLVM_NATIVE_ARCH}TargetMC"
 849     LLVM_NATIVE_ASMPRINTER="LLVMInitialize${LLVM_NATIVE_ARCH}AsmPrinter"
 850     if test -f ${srcdir}/lib/Target/${LLVM_NATIVE_ARCH}/AsmParser/Makefile ; then
 851       LLVM_NATIVE_ASMPARSER="LLVMInitialize${LLVM_NATIVE_ARCH}AsmParser"
 852     fi
 853     if test -f ${srcdir}/lib/Target/${LLVM_NATIVE_ARCH}/Disassembler/Makefile ; then
 854       LLVM_NATIVE_DISASSEMBLER="LLVMInitialize${LLVM_NATIVE_ARCH}Disassembler"
 855     fi
 856     AC_DEFINE_UNQUOTED(LLVM_NATIVE_TARGET, $LLVM_NATIVE_TARGET,
 857       [LLVM name for the native Target init function, if available])
 858     AC_DEFINE_UNQUOTED(LLVM_NATIVE_TARGETINFO, $LLVM_NATIVE_TARGETINFO,
 859       [LLVM name for the native TargetInfo init function, if available])
 860     AC_DEFINE_UNQUOTED(LLVM_NATIVE_TARGETMC, $LLVM_NATIVE_TARGETMC,
 861       [LLVM name for the native target MC init function, if available])
 862     AC_DEFINE_UNQUOTED(LLVM_NATIVE_ASMPRINTER, $LLVM_NATIVE_ASMPRINTER,
 863       [LLVM name for the native AsmPrinter init function, if available])
 864     if test -f ${srcdir}/lib/Target/${LLVM_NATIVE_ARCH}/AsmParser/Makefile ; then
 865       AC_DEFINE_UNQUOTED(LLVM_NATIVE_ASMPARSER, $LLVM_NATIVE_ASMPARSER,
 866        [LLVM name for the native AsmParser init function, if available])
 867     fi
 868     if test -f ${srcdir}/lib/Target/${LLVM_NATIVE_ARCH}/Disassembler/Makefile ; then
 869       AC_DEFINE_UNQUOTED(LLVM_NATIVE_DISASSEMBLER, $LLVM_NATIVE_DISASSEMBLER,
 870        [LLVM name for the native Disassembler init function, if available])
 871     fi
 872   fi
 873 done
 874
 875 dnl Build the LLVM_TARGET and LLVM_... macros for Targets.def and the individual
 876 dnl target feature def files.
 877 LLVM_ENUM_TARGETS=""
 878 LLVM_ENUM_ASM_PRINTERS=""
 879 LLVM_ENUM_ASM_PARSERS=""
 880 LLVM_ENUM_DISASSEMBLERS=""
 881 for target_to_build in $TARGETS_TO_BUILD; do
 882   LLVM_ENUM_TARGETS="LLVM_TARGET($target_to_build) $LLVM_ENUM_TARGETS"
 883   if test -f ${srcdir}/lib/Target/${target_to_build}/*AsmPrinter.cpp ; then
 884     LLVM_ENUM_ASM_PRINTERS="LLVM_ASM_PRINTER($target_to_build) $LLVM_ENUM_ASM_PRINTERS";
 885   fi
 886   if test -f ${srcdir}/lib/Target/${target_to_build}/AsmParser/Makefile ; then
 887     LLVM_ENUM_ASM_PARSERS="LLVM_ASM_PARSER($target_to_build) $LLVM_ENUM_ASM_PARSERS";
 888   fi
 889   if test -f ${srcdir}/lib/Target/${target_to_build}/Disassembler/Makefile ; then
 890     LLVM_ENUM_DISASSEMBLERS="LLVM_DISASSEMBLER($target_to_build) $LLVM_ENUM_DISASSEMBLERS";
 891   fi
 892 done
 893 AC_SUBST(LLVM_ENUM_TARGETS)
 894 AC_SUBST(LLVM_ENUM_ASM_PRINTERS)
 895 AC_SUBST(LLVM_ENUM_ASM_PARSERS)
 896 AC_SUBST(LLVM_ENUM_DISASSEMBLERS)
 897
 898 dnl Override the option to use for optimized builds.
 899 AC_ARG_WITH(optimize-option,
 900   AS_HELP_STRING([--with-optimize-option],
 901                  [Select the compiler options to use for optimized builds]),,
 902                  withval=default)
 903 AC_MSG_CHECKING([optimization flags])
 904 case "$withval" in
 905   default)
 906     case "$llvm_cv_os_type" in
 907     FreeBSD) optimize_option=-O2 ;;
 908     MingW) optimize_option=-O2 ;;
 909     *)     optimize_option=-O3 ;;
 910     esac ;;
 911   *) optimize_option="$withval" ;;
 912 esac
 913 AC_SUBST(OPTIMIZE_OPTION,$optimize_option)
 914 AC_MSG_RESULT([$optimize_option])
 915
 916 dnl Specify extra build options
 917 AC_ARG_WITH(extra-options,
 918   AS_HELP_STRING([--with-extra-options],
 919                  [Specify additional options to compile LLVM with]),,
 920                  withval=default)
 921 case "$withval" in
 922   default) EXTRA_OPTIONS= ;;
 923   *) EXTRA_OPTIONS=$withval ;;
 924 esac
 925 AC_SUBST(EXTRA_OPTIONS,$EXTRA_OPTIONS)
 926
 927 dnl Specify extra linker build options
 928 AC_ARG_WITH(extra-ld-options,
 929   AS_HELP_STRING([--with-extra-ld-options],
 930                  [Specify additional options to link LLVM with]),,
 931                  withval=default)
 932 case "$withval" in
 933   default) EXTRA_LD_OPTIONS= ;;
 934   *) EXTRA_LD_OPTIONS=$withval ;;
 935 esac
 936 AC_SUBST(EXTRA_LD_OPTIONS,$EXTRA_LD_OPTIONS)
 937
 938 dnl Allow specific bindings to be specified for building (or not)
 939 AC_ARG_ENABLE([bindings],AS_HELP_STRING([--enable-bindings],
 940     [Build specific language bindings: all,auto,none,{binding-name} (default=auto)]),,
 941     enableval=default)
 942 BINDINGS_TO_BUILD=""
 943 case "$enableval" in
 944   yes | default | auto) BINDINGS_TO_BUILD="auto" ;;
 945   all ) BINDINGS_TO_BUILD="ocaml" ;;
 946   none | no) BINDINGS_TO_BUILD="" ;;
 947   *)for a_binding in `echo $enableval|sed -e 's/,/ /g' ` ; do
 948       case "$a_binding" in
 949         ocaml) BINDINGS_TO_BUILD="ocaml $BINDINGS_TO_BUILD" ;;
 950         *) AC_MSG_ERROR([Unrecognized binding $a_binding]) ;;
 951       esac
 952   done
 953   ;;
 954 esac
 955
 956 dnl Allow the ocaml libdir to be overridden. This could go in a configure
 957 dnl script for bindings/ocaml/configure, except that its auto value depends on
 958 dnl OCAMLC, which is found here to support tests.
 959 AC_ARG_WITH([ocaml-libdir],
 960   [AS_HELP_STRING([--with-ocaml-libdir],
 961     [Specify install location for ocaml bindings (default is stdlib)])],
 962   [],
 963   [withval=auto])
 964 case "$withval" in
 965   auto) with_ocaml_libdir="$withval" ;;
 966   /* | [[A-Za-z]]:[[\\/]]*) with_ocaml_libdir="$withval" ;;
 967   *) AC_MSG_ERROR([Invalid path for --with-ocaml-libdir. Provide full path]) ;;
 968 esac
 969
 970 AC_ARG_WITH(clang-srcdir,
 971   AS_HELP_STRING([--with-clang-srcdir],
 972     [Directory to the out-of-tree Clang source]),,
 973     withval="-")
 974 case "$withval" in
 975   -) clang_src_root="" ;;
 976   /* | [[A-Za-z]]:[[\\/]]*) clang_src_root="$withval" ;;
 977   *) clang_src_root="$ac_pwd/$withval" ;;
 978 esac
 979 AC_SUBST(CLANG_SRC_ROOT,[$clang_src_root])
 980
 981 AC_ARG_WITH(clang-resource-dir,
 982   AS_HELP_STRING([--with-clang-resource-dir],
 983     [Relative directory from the Clang binary for resource files]),,
 984     withval="")
 985 AC_DEFINE_UNQUOTED(CLANG_RESOURCE_DIR,"$withval",
 986                    [Relative directory for resource files])
 987
 988 AC_ARG_WITH(c-include-dirs,
 989   AS_HELP_STRING([--with-c-include-dirs],
 990     [Colon separated list of directories clang will search for headers]),,
 991     withval="")
 992 AC_DEFINE_UNQUOTED(C_INCLUDE_DIRS,"$withval",
 993                    [Directories clang will search for headers])
 994
 995 # Clang normally uses the system c++ headers and libraries. With this option,
 996 # clang will use the ones provided by a gcc installation instead. This option should
 997 # be passed the same value that was used with --prefix when configuring gcc.
 998 AC_ARG_WITH(gcc-toolchain,
 999   AS_HELP_STRING([--with-gcc-toolchain],
1000     [Directory where gcc is installed.]),,
1001     withval="")
1002 AC_DEFINE_UNQUOTED(GCC_INSTALL_PREFIX,"$withval",
1003                    [Directory where gcc is installed.])
1004
1005 AC_ARG_WITH(default-sysroot,
1006   AS_HELP_STRING([--with-default-sysroot],
1007     [Add --sysroot=<path> to all compiler invocations.]),,
1008     withval="")
1009 AC_DEFINE_UNQUOTED(DEFAULT_SYSROOT,"$withval",
1010                    [Default <path> to all compiler invocations for --sysroot=<path>.])
1011
1012 dnl Allow linking of LLVM with GPLv3 binutils code.
1013 AC_ARG_WITH(binutils-include,
1014   AS_HELP_STRING([--with-binutils-include],
1015     [Specify path to binutils/include/ containing plugin-api.h file for gold plugin.]),,
1016   withval=default)
1017 case "$withval" in
1018   default) WITH_BINUTILS_INCDIR=default ;;
1019   /* | [[A-Za-z]]:[[\\/]]*)      WITH_BINUTILS_INCDIR=$withval ;;
1020   *) AC_MSG_ERROR([Invalid path for --with-binutils-include. Provide full path]) ;;
1021 esac
1022 if test "x$WITH_BINUTILS_INCDIR" != xdefault ; then
1023   AC_SUBST(BINUTILS_INCDIR,$WITH_BINUTILS_INCDIR)
1024   if test ! -f "$WITH_BINUTILS_INCDIR/plugin-api.h"; then
1025      echo "$WITH_BINUTILS_INCDIR/plugin-api.h"
1026      AC_MSG_ERROR([Invalid path to directory containing plugin-api.h.]);
1027   fi
1028 fi
1029
1030 dnl Specify the URL where bug reports should be submitted.
1031 AC_ARG_WITH(bug-report-url,
1032   AS_HELP_STRING([--with-bug-report-url],
1033     [Specify the URL where bug reports should be submitted (default=http://llvm.org/bugs/)]),,
1034     withval="http://llvm.org/bugs/")
1035 AC_DEFINE_UNQUOTED(BUG_REPORT_URL,"$withval",
1036                    [Bug report URL.])
1037
1038 dnl --enable-libffi : check whether the user wants to turn off libffi:
1039 AC_ARG_ENABLE(libffi,AS_HELP_STRING(
1040   --enable-libffi,[Check for the presence of libffi (default is NO)]),
1041   [case "$enableval" in
1042     yes) llvm_cv_enable_libffi="yes" ;;
1043     no)  llvm_cv_enable_libffi="no"  ;;
1044     *) AC_MSG_ERROR([Invalid setting for --enable-libffi. Use "yes" or "no"]) ;;
1045   esac],
1046   llvm_cv_enable_libffi=no)
1047
1048 AC_ARG_WITH(internal-prefix,
1049   AS_HELP_STRING([--with-internal-prefix],
1050     [Installation directory for internal files]),,
1051     withval="")
1052 AC_SUBST(INTERNAL_PREFIX,[$withval])
1053
1054 dnl===-----------------------------------------------------------------------===
1055 dnl===
1056 dnl=== SECTION 4: Check for programs we need and that they are the right version
1057 dnl===
1058 dnl===-----------------------------------------------------------------------===
1059
1060 AC_PROG_NM
1061 AC_SUBST(NM)
1062
1063 dnl Check for the tools that the makefiles require
1064 AC_CHECK_GNU_MAKE
1065 AC_PROG_LN_S
1066 AC_PATH_PROG(CMP, [cmp], [cmp])
1067 AC_PATH_PROG(CP, [cp], [cp])
1068 AC_PATH_PROG(DATE, [date], [date])
1069 AC_PATH_PROG(FIND, [find], [find])
1070 AC_PATH_PROG(GREP, [grep], [grep])
1071 AC_PATH_PROG(MKDIR,[mkdir],[mkdir])
1072 AC_PATH_PROG(MV,   [mv],   [mv])
1073 AC_PROG_RANLIB
1074 AC_CHECK_TOOL(AR, ar, false)
1075 AC_PATH_PROG(RM,   [rm],   [rm])
1076 AC_PATH_PROG(SED,  [sed],  [sed])
1077 AC_PATH_PROG(TAR,  [tar],  [gtar])
1078 AC_PATH_PROG(BINPWD,[pwd],  [pwd])
1079
1080 dnl Looking for misc. graph plotting software
1081 AC_PATH_PROG(GRAPHVIZ, [Graphviz], [echo Graphviz])
1082 if test "$GRAPHVIZ" != "echo Graphviz" ; then
1083   AC_DEFINE([HAVE_GRAPHVIZ],[1],[Define if the Graphviz program is available])
1084   dnl If we're targeting for mingw we should emit windows paths, not msys
1085   if test "$llvm_cv_os_type" = "MingW" ; then
1086     GRAPHVIZ=`echo $GRAPHVIZ | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
1087   fi
1088   AC_DEFINE_UNQUOTED([LLVM_PATH_GRAPHVIZ],"$GRAPHVIZ${EXEEXT}",
1089    [Define to path to Graphviz program if found or 'echo Graphviz' otherwise])
1090 fi
1091 AC_PATH_PROG(DOT, [dot], [echo dot])
1092 if test "$DOT" != "echo dot" ; then
1093   AC_DEFINE([HAVE_DOT],[1],[Define if the dot program is available])
1094   dnl If we're targeting for mingw we should emit windows paths, not msys
1095   if test "$llvm_cv_os_type" = "MingW" ; then
1096     DOT=`echo $DOT | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
1097   fi
1098   AC_DEFINE_UNQUOTED([LLVM_PATH_DOT],"$DOT${EXEEXT}",
1099    [Define to path to dot program if found or 'echo dot' otherwise])
1100 fi
1101 AC_PATH_PROG(FDP, [fdp], [echo fdp])
1102 if test "$FDP" != "echo fdp" ; then
1103   AC_DEFINE([HAVE_FDP],[1],[Define if the neat program is available])
1104   dnl If we're targeting for mingw we should emit windows paths, not msys
1105   if test "$llvm_cv_os_type" = "MingW" ; then
1106     FDP=`echo $FDP | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
1107   fi
1108   AC_DEFINE_UNQUOTED([LLVM_PATH_FDP],"$FDP${EXEEXT}",
1109    [Define to path to fdp program if found or 'echo fdp' otherwise])
1110 fi
1111 AC_PATH_PROG(NEATO, [neato], [echo neato])
1112 if test "$NEATO" != "echo neato" ; then
1113   AC_DEFINE([HAVE_NEATO],[1],[Define if the neat program is available])
1114   dnl If we're targeting for mingw we should emit windows paths, not msys
1115   if test "$llvm_cv_os_type" = "MingW" ; then
1116     NEATO=`echo $NEATO | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
1117   fi
1118   AC_DEFINE_UNQUOTED([LLVM_PATH_NEATO],"$NEATO${EXEEXT}",
1119    [Define to path to neato program if found or 'echo neato' otherwise])
1120 fi
1121 AC_PATH_PROG(TWOPI, [twopi], [echo twopi])
1122 if test "$TWOPI" != "echo twopi" ; then
1123   AC_DEFINE([HAVE_TWOPI],[1],[Define if the neat program is available])
1124   dnl If we're targeting for mingw we should emit windows paths, not msys
1125   if test "$llvm_cv_os_type" = "MingW" ; then
1126     TWOPI=`echo $TWOPI | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
1127   fi
1128   AC_DEFINE_UNQUOTED([LLVM_PATH_TWOPI],"$TWOPI${EXEEXT}",
1129    [Define to path to twopi program if found or 'echo twopi' otherwise])
1130 fi
1131 AC_PATH_PROG(CIRCO, [circo], [echo circo])
1132 if test "$CIRCO" != "echo circo" ; then
1133   AC_DEFINE([HAVE_CIRCO],[1],[Define if the neat program is available])
1134   dnl If we're targeting for mingw we should emit windows paths, not msys
1135   if test "$llvm_cv_os_type" = "MingW" ; then
1136     CIRCO=`echo $CIRCO | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
1137   fi
1138   AC_DEFINE_UNQUOTED([LLVM_PATH_CIRCO],"$CIRCO${EXEEXT}",
1139    [Define to path to circo program if found or 'echo circo' otherwise])
1140 fi
1141 AC_PATH_PROGS(GV, [gv gsview32], [echo gv])
1142 if test "$GV" != "echo gv" ; then
1143   AC_DEFINE([HAVE_GV],[1],[Define if the gv program is available])
1144   dnl If we're targeting for mingw we should emit windows paths, not msys
1145   if test "$llvm_cv_os_type" = "MingW" ; then
1146     GV=`echo $GV | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
1147   fi
1148   AC_DEFINE_UNQUOTED([LLVM_PATH_GV],"$GV${EXEEXT}",
1149    [Define to path to gv program if found or 'echo gv' otherwise])
1150 fi
1151 AC_PATH_PROG(DOTTY, [dotty], [echo dotty])
1152 if test "$DOTTY" != "echo dotty" ; then
1153   AC_DEFINE([HAVE_DOTTY],[1],[Define if the dotty program is available])
1154   dnl If we're targeting for mingw we should emit windows paths, not msys
1155   if test "$llvm_cv_os_type" = "MingW" ; then
1156     DOTTY=`echo $DOTTY | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
1157   fi
1158   AC_DEFINE_UNQUOTED([LLVM_PATH_DOTTY],"$DOTTY${EXEEXT}",
1159    [Define to path to dotty program if found or 'echo dotty' otherwise])
1160 fi
1161 AC_PATH_PROG(XDOT_PY, [xdot.py], [echo xdot.py])
1162 if test "$XDOT_PY" != "echo xdot.py" ; then
1163   AC_DEFINE([HAVE_XDOT_PY],[1],[Define if the xdot.py program is available])
1164   dnl If we're targeting for mingw we should emit windows paths, not msys
1165   if test "$llvm_cv_os_type" = "MingW" ; then
1166     XDOT_PY=`echo $XDOT_PY | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
1167   fi
1168   AC_DEFINE_UNQUOTED([LLVM_PATH_XDOT_PY],"$XDOT_PY${EXEEXT}",
1169    [Define to path to xdot.py program if found or 'echo xdot.py' otherwise])
1170 fi
1171
1172 dnl Find the install program
1173 AC_PROG_INSTALL
1174 dnl Prepend src dir to install path dir if it's a relative path
1175 dnl This is a hack for installs that take place in something other
1176 dnl than the top level.
1177 case "$INSTALL" in
1178  [[\\/$]]* | ?:[[\\/]]* ) ;;
1179  *)  INSTALL="\\\$(TOPSRCDIR)/$INSTALL" ;;
1180 esac
1181
1182 dnl Checks for documentation and testing tools that we can do without. If these
1183 dnl are not found then they are set to "true" which always succeeds but does
1184 dnl nothing. This just lets the build output show that we could have done
1185 dnl something if the tool was available.
1186 AC_PATH_PROG(BZIP2, [bzip2])
1187 AC_PATH_PROG(CAT, [cat])
1188 AC_PATH_PROG(DOXYGEN, [doxygen])
1189 AC_PATH_PROG(GROFF, [groff])
1190 AC_PATH_PROG(GZIPBIN, [gzip])
1191 AC_PATH_PROG(PDFROFF, [pdfroff])
1192 AC_PATH_PROG(ZIP, [zip])
1193 AC_PATH_PROGS(OCAMLC, [ocamlc])
1194 AC_PATH_PROGS(OCAMLOPT, [ocamlopt])
1195 AC_PATH_PROGS(OCAMLDEP, [ocamldep])
1196 AC_PATH_PROGS(OCAMLDOC, [ocamldoc])
1197 AC_PATH_PROGS(GAS, [gas as])
1198
1199 dnl Get the version of the linker in use.
1200 AC_LINK_GET_VERSION
1201
1202 dnl Determine whether the linker supports the -R option.
1203 AC_LINK_USE_R
1204
1205 dnl Determine whether the linker supports the -export-dynamic option.
1206 AC_LINK_EXPORT_DYNAMIC
1207
1208 dnl Determine whether the linker supports the --version-script option.
1209 AC_LINK_VERSION_SCRIPT
1210
1211 dnl Check for libtool and the library that has dlopen function (which must come
1212 dnl before the AC_PROG_LIBTOOL check in order to enable dlopening libraries with
1213 dnl libtool).
1214 AC_LIBTOOL_DLOPEN
1215 AC_LIB_LTDL
1216
1217 AC_MSG_CHECKING([tool compatibility])
1218
1219 dnl Ensure that compilation tools are GCC or a GNU compatible compiler such as
1220 dnl ICC; we use GCC specific options in the makefiles so the compiler needs
1221 dnl to support those options.
1222 dnl "icc" emits gcc signatures
1223 dnl "icc -no-gcc" emits no gcc signature BUT is still compatible
1224 ICC=no
1225 IXX=no
1226 case $CC in
1227   icc*|icpc*)
1228     ICC=yes
1229     IXX=yes
1230     ;;
1231    *)
1232     ;;
1233 esac
1234
1235 if test "$GCC" != "yes" && test "$ICC" != "yes"
1236 then
1237   AC_MSG_ERROR([gcc|icc required but not found])
1238 fi
1239
1240 dnl Ensure that compilation tools are compatible with GCC extensions
1241 if test "$GXX" != "yes" && test "$IXX" != "yes"
1242 then
1243   AC_MSG_ERROR([g++|clang++|icc required but not found])
1244 fi
1245
1246 dnl Verify that GCC is version 3.0 or higher
1247 if test "$GCC" = "yes"
1248 then
1249   AC_COMPILE_IFELSE(
1250 [
1251   AC_LANG_SOURCE([[
1252     #if !defined(__GNUC__) || __GNUC__ < 3
1253     #error Unsupported GCC version
1254     #endif
1255   ]])
1256 ],
1257 [], [AC_MSG_ERROR([gcc 3.x required, but you have a lower version])])
1258 fi
1259
1260 dnl Check for GNU Make.  We use its extensions, so don't build without it
1261 if test -z "$llvm_cv_gnu_make_command"
1262 then
1263   AC_MSG_ERROR([GNU Make required but not found])
1264 fi
1265
1266 dnl Tool compatibility is okay if we make it here.
1267 AC_MSG_RESULT([ok])
1268
1269 dnl Check optional compiler flags.
1270 AC_MSG_CHECKING([optional compiler flags])
1271 CXX_FLAG_CHECK(NO_VARIADIC_MACROS, [-Wno-variadic-macros])
1272 CXX_FLAG_CHECK(NO_MISSING_FIELD_INITIALIZERS, [-Wno-missing-field-initializers])
1273 CXX_FLAG_CHECK(NO_NESTED_ANON_TYPES, [-Wno-nested-anon-types])
1274 CXX_FLAG_CHECK(COVERED_SWITCH_DEFAULT, [-Wcovered-switch-default])
1275 dnl GCC's potential uninitialized use analysis is weak and presents lots of
1276 dnl false positives, so disable it.
1277 if test "$GXX" = "yes"
1278 then
1279   CXX_FLAG_CHECK(NO_MAYBE_UNINITIALIZED, [-Wno-maybe-uninitialized])
1280   dnl gcc 4.7 introduced -Wmaybe-uninitialized to distinguish cases which are
1281   dnl known to be uninitialized from cases which might be uninitialized.  We
1282   dnl still want to catch the first kind of errors.
1283   if test "$NO_MAYBE_UNINITIALIZED" != "-Wno-maybe-uninitialized"
1284   then
1285     CXX_FLAG_CHECK(NO_UNINITIALIZED, [-Wno-uninitialized])
1286   else
1287     dnl Some versions of gcc accept unsupported -W flags if there is
1288     dnl no warning but stop with an error when a warning is
1289     dnl encountered.  If this gcc is earlier than 4.7, just use
1290     dnl -Wno-uninitialized.
1291     gxx_version=`$CXX -dumpversion`
1292     gxx_version_major=`echo $gxx_version | cut -d'.' -f1`
1293     gxx_version_minor=`echo $gxx_version | cut -d'.' -f2`
1294     gxx_version_patch=`echo $gxx_version | cut -d'.' -f3`
1295
1296     if    test "$gxx_version_major" -ge "4" \
1297        && test "$gxx_version_minor" -ge "7"; then
1298       dnl AC_SUBST doesn't work with empty strings.
1299       NO_UNINITIALIZED=
1300     else
1301       NO_MAYBE_UNINITIALIZED=
1302       CXX_FLAG_CHECK(NO_UNINITIALIZED, [-Wno-uninitialized])
1303     fi
1304   fi
1305 else
1306   NO_UNINITIALIZED=
1307   NO_MAYBE_UNINITIALIZED=
1308 fi
1309 AC_MSG_RESULT([$NO_VARIADIC_MACROS $NO_MISSING_FIELD_INITIALIZERS $NO_NESTED_ANON_TYPES $COVERED_SWITCH_DEFAULT $NO_UNINITIALIZED $NO_MAYBE_UNINITIALIZED])
1310
1311 AC_ARG_WITH([python],
1312             [AS_HELP_STRING([--with-python], [path to python])],
1313             [PYTHON="$withval"])
1314
1315 if test -n "$PYTHON" && test -x "$PYTHON" ; then
1316   AC_MSG_CHECKING([for python])
1317   AC_MSG_RESULT([user defined: $with_python])
1318 else
1319   if test -n "$PYTHON" ; then
1320     AC_MSG_WARN([specified python ($PYTHON) is not usable, searching path])
1321   fi
1322
1323   AC_PATH_PROG([PYTHON], [python python2 python26],
1324                [AC_MSG_RESULT([not found])
1325                 AC_MSG_ERROR([could not find python 2.5 or higher])])
1326 fi
1327
1328 AC_MSG_CHECKING([for python >= 2.5])
1329 ac_python_version=`$PYTHON -c 'import sys; print sys.version.split()[[0]]'`
1330 ac_python_version_major=`echo $ac_python_version | cut -d'.' -f1`
1331 ac_python_version_minor=`echo $ac_python_version | cut -d'.' -f2`
1332 ac_python_version_patch=`echo $ac_python_version | cut -d'.' -f3`
1333 if   test "$ac_python_version_major" -eq "2" \
1334    && test "$ac_python_version_minor" -ge "5" ; then
1335   AC_MSG_RESULT([$PYTHON ($ac_python_version)])
1336 else
1337   AC_MSG_RESULT([not found])
1338   AC_MSG_FAILURE([found python $ac_python_version ($PYTHON); required >= 2.5])
1339 fi
1340
1341 dnl===-----------------------------------------------------------------------===
1342 dnl===
1343 dnl=== SECTION 5: Check for libraries
1344 dnl===
1345 dnl===-----------------------------------------------------------------------===
1346
1347 AC_CHECK_LIB(m,sin)
1348 if test "$llvm_cv_os_type" = "MingW" ; then
1349   AC_CHECK_LIB(imagehlp, main)
1350   AC_CHECK_LIB(psapi, main)
1351 fi
1352
1353 dnl dlopen() is required for plugin support.
1354 AC_SEARCH_LIBS(dlopen,dl,AC_DEFINE([HAVE_DLOPEN],[1],
1355                [Define if dlopen() is available on this platform.]),
1356                AC_MSG_WARN([dlopen() not found - disabling plugin support]))
1357
1358 dnl Search for the clock_gettime() function. Note that we rely on the POSIX
1359 dnl macros to detect whether clock_gettime is available, this just finds the
1360 dnl right libraries to link with.
1361 AC_SEARCH_LIBS(clock_gettime,rt)
1362
1363 dnl libffi is optional; used to call external functions from the interpreter
1364 if test "$llvm_cv_enable_libffi" = "yes" ; then
1365   AC_SEARCH_LIBS(ffi_call,ffi,AC_DEFINE([HAVE_FFI_CALL],[1],
1366                  [Define if libffi is available on this platform.]),
1367                  AC_MSG_ERROR([libffi not found - configure without --enable-libffi to compile without it]))
1368 fi
1369
1370 dnl mallinfo is optional; the code can compile (minus features) without it
1371 AC_SEARCH_LIBS(mallinfo,malloc,AC_DEFINE([HAVE_MALLINFO],[1],
1372                [Define if mallinfo() is available on this platform.]))
1373
1374 dnl pthread locking functions are optional - but llvm will not be thread-safe
1375 dnl without locks.
1376 if test "$LLVM_ENABLE_THREADS" -eq 1 && test "$ENABLE_PTHREADS" -eq 1 ; then
1377   AC_CHECK_LIB(pthread, pthread_mutex_init)
1378   AC_SEARCH_LIBS(pthread_mutex_lock,pthread,
1379                  AC_DEFINE([HAVE_PTHREAD_MUTEX_LOCK],[1],
1380                            [Have pthread_mutex_lock]))
1381   AC_SEARCH_LIBS(pthread_rwlock_init,pthread,
1382                  AC_DEFINE([HAVE_PTHREAD_RWLOCK_INIT],[1],
1383                  [Have pthread_rwlock_init]))
1384   AC_SEARCH_LIBS(pthread_getspecific,pthread,
1385                  AC_DEFINE([HAVE_PTHREAD_GETSPECIFIC],[1],
1386                  [Have pthread_getspecific]))
1387 fi
1388
1389 dnl Allow extra x86-disassembler library
1390 AC_ARG_WITH(udis86,
1391   AS_HELP_STRING([--with-udis86=<path>],
1392     [Use udis86 external x86 disassembler library]),
1393     [
1394       AC_SUBST(USE_UDIS86, [1])
1395       case "$withval" in
1396         /usr/lib|yes) ;;
1397         *) LDFLAGS="$LDFLAGS -L${withval}" ;;
1398       esac
1399       AC_CHECK_LIB(udis86, ud_init, [], [
1400         echo "Error! You need to have libudis86 around."
1401         exit -1
1402       ])
1403     ],
1404     AC_SUBST(USE_UDIS86, [0]))
1405 AC_DEFINE_UNQUOTED([USE_UDIS86],$USE_UDIS86,
1406                    [Define if use udis86 library])
1407
1408 dnl Allow OProfile support for JIT output.
1409 AC_ARG_WITH(oprofile,
1410   AS_HELP_STRING([--with-oprofile=<prefix>],
1411     [Tell OProfile >= 0.9.4 how to symbolize JIT output]),
1412     [
1413       AC_SUBST(USE_OPROFILE, [1])
1414       case "$withval" in
1415         /usr|yes) llvm_cv_oppath=/usr/lib/oprofile ;;
1416         no) llvm_cv_oppath=
1417             AC_SUBST(USE_OPROFILE, [0]) ;;
1418         *) llvm_cv_oppath="${withval}/lib/oprofile"
1419            CPPFLAGS="-I${withval}/include";;
1420       esac
1421       case $llvm_cv_os_type in
1422         Linux)
1423           if test -n "$llvm_cv_oppath" ; then
1424             LIBS="$LIBS -lopagent -L${llvm_cv_oppath} -Wl,-rpath,${llvm_cv_oppath}"
1425             dnl Work around http://bugs.debian.org/cgi-bin/bugreport.cgi?bug=537744:
1426             dnl libbfd is not included properly in libopagent in some Debian
1427             dnl versions.  If libbfd isn't found at all, we assume opagent works
1428             dnl anyway.
1429             AC_SEARCH_LIBS(bfd_init, bfd, [], [])
1430             AC_SEARCH_LIBS(op_open_agent, opagent, [], [
1431               echo "Error! You need to have libopagent around."
1432               exit -1
1433             ])
1434             AC_CHECK_HEADER([opagent.h], [], [
1435               echo "Error! You need to have opagent.h around."
1436               exit -1
1437               ])
1438           fi ;;
1439         *)
1440           AC_MSG_ERROR([OProfile support is available on Linux only.]) ;;
1441       esac
1442     ],
1443     [
1444       AC_SUBST(USE_OPROFILE, [0])
1445     ])
1446 AC_DEFINE_UNQUOTED([LLVM_USE_OPROFILE],$USE_OPROFILE,
1447                    [Define if we have the oprofile JIT-support library])
1448
1449 dnl Enable support for Intel JIT Events API.
1450 AC_ARG_WITH(intel-jitevents,
1451   AS_HELP_STRING([--with-intel-jitevents  Notify Intel JIT profiling API of generated code]),
1452     [
1453        case "$withval" in
1454           yes) AC_SUBST(USE_INTEL_JITEVENTS,[1]);;
1455           no)  AC_SUBST(USE_INTEL_JITEVENTS,[0]);;
1456           *) AC_MSG_ERROR([Invalid setting for --with-intel-jitevents. Use "yes" or "no"]);;
1457        esac
1458
1459       case $llvm_cv_os_type in
1460         Linux|Win32|Cygwin|MingW) ;;
1461         *) AC_MSG_ERROR([Intel JIT API support is available on Linux and Windows only.]);;
1462       esac
1463
1464       case "$llvm_cv_target_arch" in
1465         x86|x86_64) ;;
1466         *) AC_MSG_ERROR([Target architecture $llvm_cv_target_arch does not support Intel JIT Events API.]);;
1467       esac
1468     ],
1469     [
1470       AC_SUBST(USE_INTEL_JITEVENTS, [0])
1471     ])
1472 AC_DEFINE_UNQUOTED([LLVM_USE_INTEL_JITEVENTS],$USE_INTEL_JITEVENTS,
1473                    [Define if we have the Intel JIT API runtime support library])
1474
1475 dnl Check for libxml2
1476 dnl Right now we're just checking for the existence, we could also check for a
1477 dnl particular version via --version on xml2-config
1478 AC_CHECK_PROGS(XML2CONFIG, xml2-config)
1479
1480 AC_MSG_CHECKING(for libxml2 includes)
1481 if test "x$XML2CONFIG" = "x"; then
1482  AC_MSG_RESULT(xml2-config not found)
1483 else
1484  LIBXML2_INC=`$XML2CONFIG --cflags`
1485  AC_MSG_RESULT($LIBXML2_INC)
1486  AC_CHECK_LIB(xml2, xmlReadFile,[AC_DEFINE([CLANG_HAVE_LIBXML],1,[Define if we have libxml2])
1487                                 LIBXML2_LIBS="-lxml2"])
1488 fi
1489 AC_SUBST(LIBXML2_LIBS)
1490 AC_SUBST(LIBXML2_INC)
1491
1492 dnl===-----------------------------------------------------------------------===
1493 dnl===
1494 dnl=== SECTION 6: Check for header files
1495 dnl===
1496 dnl===-----------------------------------------------------------------------===
1497
1498 dnl First, use autoconf provided macros for specific headers that we need
1499 dnl We don't check for ancient stuff or things that are guaranteed to be there
1500 dnl by the C++ standard. We always use the <cfoo> versions of <foo.h> C headers.
1501 dnl Generally we're looking for POSIX headers.
1502 AC_HEADER_DIRENT
1503 AC_HEADER_MMAP_ANONYMOUS
1504 AC_HEADER_STAT
1505 AC_HEADER_SYS_WAIT
1506 AC_HEADER_TIME
1507
1508 AC_CHECK_HEADERS([dlfcn.h execinfo.h fcntl.h inttypes.h limits.h link.h])
1509 AC_CHECK_HEADERS([malloc.h setjmp.h signal.h stdint.h termios.h unistd.h])
1510 AC_CHECK_HEADERS([utime.h windows.h])
1511 AC_CHECK_HEADERS([sys/mman.h sys/param.h sys/resource.h sys/time.h sys/uio.h])
1512 AC_CHECK_HEADERS([sys/types.h sys/ioctl.h malloc/malloc.h mach/mach.h])
1513 AC_CHECK_HEADERS([valgrind/valgrind.h])
1514 AC_CHECK_HEADERS([fenv.h])
1515 if test "$LLVM_ENABLE_THREADS" -eq 1 && test "$ENABLE_PTHREADS" -eq 1 ; then
1516   AC_CHECK_HEADERS(pthread.h,
1517                    AC_SUBST(HAVE_PTHREAD, 1),
1518                    AC_SUBST(HAVE_PTHREAD, 0))
1519 else
1520   AC_SUBST(HAVE_PTHREAD, 0)
1521 fi
1522
1523 dnl Try to find ffi.h.
1524 if test "$llvm_cv_enable_libffi" = "yes" ; then
1525   AC_CHECK_HEADERS([ffi.h ffi/ffi.h])
1526 fi
1527
1528 dnl Try to find Darwin specific crash reporting libraries.
1529 AC_CHECK_HEADERS([CrashReporterClient.h])
1530
1531 dnl Try to find Darwin specific crash reporting global.
1532 AC_MSG_CHECKING([__crashreporter_info__])
1533 AC_LINK_IFELSE(
1534 [
1535   AC_LANG_SOURCE([[
1536     extern const char *__crashreporter_info__;
1537     int main() {
1538       __crashreporter_info__ = "test";
1539       return 0;
1540     }
1541   ]])
1542 ],
1543 [
1544   AC_MSG_RESULT([yes])
1545   AC_DEFINE([HAVE_CRASHREPORTER_INFO], [1], [can use __crashreporter_info__])
1546 ],
1547 [
1548   AC_MSG_RESULT([no])
1549   AC_DEFINE([HAVE_CRASHREPORTER_INFO], [0], [can use __crashreporter_info__])
1550 ])
1551
1552 dnl===-----------------------------------------------------------------------===
1553 dnl===
1554 dnl=== SECTION 7: Check for types and structures
1555 dnl===
1556 dnl===-----------------------------------------------------------------------===
1557
1558 AC_HUGE_VAL_CHECK
1559 AC_TYPE_PID_T
1560 AC_TYPE_SIZE_T
1561 AC_DEFINE_UNQUOTED([RETSIGTYPE],[void],[Define as the return type of signal handlers (`int' or `void').])
1562 AC_STRUCT_TM
1563 AC_CHECK_TYPES([int64_t],,AC_MSG_ERROR([Type int64_t required but not found]))
1564 AC_CHECK_TYPES([uint64_t],,
1565          AC_CHECK_TYPES([u_int64_t],,
1566          AC_MSG_ERROR([Type uint64_t or u_int64_t required but not found])))
1567
1568 dnl===-----------------------------------------------------------------------===
1569 dnl===
1570 dnl=== SECTION 8: Check for specific functions needed
1571 dnl===
1572 dnl===-----------------------------------------------------------------------===
1573
1574 AC_CHECK_FUNCS([backtrace ceilf floorf roundf rintf nearbyintf getcwd ])
1575 AC_CHECK_FUNCS([powf fmodf strtof round ])
1576 AC_CHECK_FUNCS([getpagesize getrusage getrlimit setrlimit gettimeofday ])
1577 AC_CHECK_FUNCS([isatty mkdtemp mkstemp ])
1578 AC_CHECK_FUNCS([mktemp posix_spawn pread realpath sbrk setrlimit strdup ])
1579 AC_CHECK_FUNCS([strerror strerror_r setenv arc4random ])
1580 AC_CHECK_FUNCS([strtoll strtoq sysconf malloc_zone_statistics ])
1581 AC_CHECK_FUNCS([setjmp longjmp sigsetjmp siglongjmp writev])
1582 AC_C_PRINTF_A
1583 AC_FUNC_RAND48
1584
1585 dnl Check the declaration "Secure API" on Windows environments.
1586 AC_CHECK_DECLS([strerror_s])
1587
1588 dnl Check symbols in libgcc.a for JIT on Mingw.
1589 if test "$llvm_cv_os_type" = "MingW" ; then
1590   AC_CHECK_LIB(gcc,_alloca,AC_DEFINE([HAVE__ALLOCA],[1],[Have host's _alloca]))
1591   AC_CHECK_LIB(gcc,__alloca,AC_DEFINE([HAVE___ALLOCA],[1],[Have host's __alloca]))
1592   AC_CHECK_LIB(gcc,__chkstk,AC_DEFINE([HAVE___CHKSTK],[1],[Have host's __chkstk]))
1593   AC_CHECK_LIB(gcc,___chkstk,AC_DEFINE([HAVE____CHKSTK],[1],[Have host's ___chkstk]))
1594
1595   AC_CHECK_LIB(gcc,__ashldi3,AC_DEFINE([HAVE___ASHLDI3],[1],[Have host's __ashldi3]))
1596   AC_CHECK_LIB(gcc,__ashrdi3,AC_DEFINE([HAVE___ASHRDI3],[1],[Have host's __ashrdi3]))
1597   AC_CHECK_LIB(gcc,__divdi3,AC_DEFINE([HAVE___DIVDI3],[1],[Have host's __divdi3]))
1598   AC_CHECK_LIB(gcc,__fixdfdi,AC_DEFINE([HAVE___FIXDFDI],[1],[Have host's __fixdfdi]))
1599   AC_CHECK_LIB(gcc,__fixsfdi,AC_DEFINE([HAVE___FIXSFDI],[1],[Have host's __fixsfdi]))
1600   AC_CHECK_LIB(gcc,__floatdidf,AC_DEFINE([HAVE___FLOATDIDF],[1],[Have host's __floatdidf]))
1601   AC_CHECK_LIB(gcc,__lshrdi3,AC_DEFINE([HAVE___LSHRDI3],[1],[Have host's __lshrdi3]))
1602   AC_CHECK_LIB(gcc,__moddi3,AC_DEFINE([HAVE___MODDI3],[1],[Have host's __moddi3]))
1603   AC_CHECK_LIB(gcc,__udivdi3,AC_DEFINE([HAVE___UDIVDI3],[1],[Have host's __udivdi3]))
1604   AC_CHECK_LIB(gcc,__umoddi3,AC_DEFINE([HAVE___UMODDI3],[1],[Have host's __umoddi3]))
1605
1606   AC_CHECK_LIB(gcc,__main,AC_DEFINE([HAVE___MAIN],[1],[Have host's __main]))
1607   AC_CHECK_LIB(gcc,__cmpdi2,AC_DEFINE([HAVE___CMPDI2],[1],[Have host's __cmpdi2]))
1608 fi
1609
1610 dnl Check Win32 API EnumerateLoadedModules.
1611 if test "$llvm_cv_os_type" = "MingW" ; then
1612   AC_MSG_CHECKING([whether EnumerateLoadedModules() accepts new decl])
1613   AC_COMPILE_IFELSE(
1614 [
1615   AC_LANG_SOURCE([[
1616     #include <windows.h>
1617     #include <imagehlp.h>
1618     extern void foo(PENUMLOADED_MODULES_CALLBACK);
1619     extern void foo(BOOL(CALLBACK*)(PCSTR,ULONG_PTR,ULONG,PVOID));
1620   ]])
1621 ],
1622 [
1623   AC_MSG_RESULT([yes])
1624   llvm_cv_win32_elmcb_pcstr="PCSTR"
1625 ],
1626 [
1627   AC_MSG_RESULT([no])
1628   llvm_cv_win32_elmcb_pcstr="PSTR"
1629 ])
1630   AC_DEFINE_UNQUOTED([WIN32_ELMCB_PCSTR],$llvm_cv_win32_elmcb_pcstr,[Type of 1st arg on ELM Callback])
1631 fi
1632
1633 dnl Check for variations in the Standard C++ library and STL. These macros are
1634 dnl provided by LLVM in the autoconf/m4 directory.
1635 AC_FUNC_ISNAN
1636 AC_FUNC_ISINF
1637
1638 dnl Check for mmap support.We also need to know if /dev/zero is required to
1639 dnl be opened for allocating RWX memory.
1640 dnl Make sure we aren't attempting to configure for an unknown system
1641 if test "$llvm_cv_platform_type" = "Unix" ; then
1642   AC_FUNC_MMAP
1643   AC_FUNC_MMAP_FILE
1644   AC_NEED_DEV_ZERO_FOR_MMAP
1645
1646   if test "$ac_cv_func_mmap_fixed_mapped" = "no"
1647   then
1648     AC_MSG_WARN([mmap() of a fixed address required but not supported])
1649   fi
1650   if test "$ac_cv_func_mmap_file" = "no"
1651   then
1652     AC_MSG_WARN([mmap() of files required but not found])
1653   fi
1654 fi
1655
1656 dnl atomic builtins are required for threading support.
1657 AC_MSG_CHECKING(for GCC atomic builtins)
1658 dnl Since we'll be using these atomic builtins in C++ files we should test
1659 dnl the C++ compiler.
1660 AC_LANG_PUSH([C++])
1661 AC_LINK_IFELSE(
1662 [
1663   AC_LANG_SOURCE([[
1664     int main() {
1665       volatile unsigned long val = 1;
1666       __sync_synchronize();
1667       __sync_val_compare_and_swap(&val, 1, 0);
1668       __sync_add_and_fetch(&val, 1);
1669       __sync_sub_and_fetch(&val, 1);
1670       return 0;
1671     }
1672   ]])
1673 ],
1674 [
1675   AC_MSG_RESULT([yes])
1676   AC_DEFINE([LLVM_HAS_ATOMICS], [1], [Has gcc/MSVC atomic intrinsics])
1677 ],
1678 [
1679   AC_MSG_RESULT([no])
1680   AC_DEFINE([LLVM_HAS_ATOMICS], [0], [Has gcc/MSVC atomic intrinsics])
1681   AC_MSG_WARN([LLVM will be built thread-unsafe because atomic builtins are missing])
1682 ])
1683 AC_LANG_POP([C++])
1684
1685 dnl===-----------------------------------------------------------------------===
1686 dnl===
1687 dnl=== SECTION 9: Additional checks, variables, etc.
1688 dnl===
1689 dnl===-----------------------------------------------------------------------===
1690
1691 dnl Handle 32-bit linux systems running a 64-bit kernel.
1692 dnl This has to come after section 4 because it invokes the compiler.
1693 if test "$llvm_cv_os_type" = "Linux" -a "$llvm_cv_target_arch" = "x86_64" ; then
1694   AC_IS_LINUX_MIXED
1695   if test "$llvm_cv_linux_mixed" = "yes"; then
1696     llvm_cv_target_arch="x86"
1697     ARCH="x86"
1698   fi
1699 fi
1700
1701 dnl Check whether __dso_handle is present
1702 AC_CHECK_FUNCS([__dso_handle])
1703
1704 dnl Propagate the shared library extension that the libltdl checks did to
1705 dnl the Makefiles so we can use it there too
1706 AC_SUBST(SHLIBEXT,$libltdl_cv_shlibext)
1707
1708 dnl Propagate the run-time library path variable that the libltdl
1709 dnl checks found to the Makefiles so we can use it there too
1710 AC_SUBST(SHLIBPATH_VAR,$libltdl_cv_shlibpath_var)
1711
1712 dnl Translate the various configuration directories and other basic
1713 dnl information into substitutions that will end up in Makefile.config.in
1714 dnl that these configured values can be used by the makefiles
1715 if test "${prefix}" = "NONE" ; then
1716   prefix="/usr/local"
1717 fi
1718 eval LLVM_PREFIX="${prefix}";
1719 eval LLVM_BINDIR="${prefix}/bin";
1720 eval LLVM_LIBDIR="${prefix}/lib";
1721 eval LLVM_DATADIR="${prefix}/share/llvm";
1722 eval LLVM_DOCSDIR="${prefix}/share/doc/llvm";
1723 eval LLVM_ETCDIR="${prefix}/etc/llvm";
1724 eval LLVM_INCLUDEDIR="${prefix}/include";
1725 eval LLVM_INFODIR="${prefix}/info";
1726 eval LLVM_MANDIR="${prefix}/man";
1727 LLVM_CONFIGTIME=`date`
1728 AC_SUBST(LLVM_PREFIX)
1729 AC_SUBST(LLVM_BINDIR)
1730 AC_SUBST(LLVM_LIBDIR)
1731 AC_SUBST(LLVM_DATADIR)
1732 AC_SUBST(LLVM_DOCSDIR)
1733 AC_SUBST(LLVM_ETCDIR)
1734 AC_SUBST(LLVM_INCLUDEDIR)
1735 AC_SUBST(LLVM_INFODIR)
1736 AC_SUBST(LLVM_MANDIR)
1737 AC_SUBST(LLVM_CONFIGTIME)
1738
1739 dnl Disable embedding timestamps in the build directory, with ENABLE_TIMESTAMPS.
1740 if test "${ENABLE_TIMESTAMPS}" = "0"; then
1741   LLVM_CONFIGTIME="(timestamp not enabled)"
1742 fi
1743
1744 dnl Place the various directories into the config.h file as #defines so that we
1745 dnl can know about the installation paths within LLVM.
1746 AC_DEFINE_UNQUOTED(LLVM_PREFIX,"$LLVM_PREFIX",
1747                    [Installation prefix directory])
1748 AC_DEFINE_UNQUOTED(LLVM_BINDIR, "$LLVM_BINDIR",
1749                    [Installation directory for binary executables])
1750 AC_DEFINE_UNQUOTED(LLVM_LIBDIR, "$LLVM_LIBDIR",
1751                    [Installation directory for libraries])
1752 AC_DEFINE_UNQUOTED(LLVM_DATADIR, "$LLVM_DATADIR",
1753                    [Installation directory for data files])
1754 AC_DEFINE_UNQUOTED(LLVM_DOCSDIR, "$LLVM_DOCSDIR",
1755                    [Installation directory for documentation])
1756 AC_DEFINE_UNQUOTED(LLVM_ETCDIR, "$LLVM_ETCDIR",
1757                    [Installation directory for config files])
1758 AC_DEFINE_UNQUOTED(LLVM_INCLUDEDIR, "$LLVM_INCLUDEDIR",
1759                    [Installation directory for include files])
1760 AC_DEFINE_UNQUOTED(LLVM_INFODIR, "$LLVM_INFODIR",
1761                    [Installation directory for .info files])
1762 AC_DEFINE_UNQUOTED(LLVM_MANDIR, "$LLVM_MANDIR",
1763                    [Installation directory for man pages])
1764 AC_DEFINE_UNQUOTED(LLVM_CONFIGTIME, "$LLVM_CONFIGTIME",
1765                    [Time at which LLVM was configured])
1766 AC_DEFINE_UNQUOTED(LLVM_HOSTTRIPLE, "$host",
1767                    [Host triple LLVM will be executed on])
1768 AC_DEFINE_UNQUOTED(LLVM_DEFAULT_TARGET_TRIPLE, "$target",
1769                    [Target triple LLVM will generate code for by default])
1770
1771 dnl Determine which bindings to build.
1772 if test "$BINDINGS_TO_BUILD" = auto ; then
1773   BINDINGS_TO_BUILD=""
1774   if test "x$OCAMLC" != x -a "x$OCAMLDEP" != x ; then
1775     BINDINGS_TO_BUILD="ocaml $BINDINGS_TO_BUILD"
1776   fi
1777 fi
1778 AC_SUBST(BINDINGS_TO_BUILD,$BINDINGS_TO_BUILD)
1779
1780 dnl This isn't really configurey, but it avoids having to repeat the list in
1781 dnl other files.
1782 AC_SUBST(ALL_BINDINGS,ocaml)
1783
1784 dnl Do any work necessary to ensure that bindings have what they need.
1785 binding_prereqs_failed=0
1786 for a_binding in $BINDINGS_TO_BUILD ; do
1787   case "$a_binding" in
1788   ocaml)
1789     if test "x$OCAMLC" = x ; then
1790       AC_MSG_WARN([--enable-bindings=ocaml specified, but ocamlc not found. Try configure OCAMLC=/path/to/ocamlc])
1791       binding_prereqs_failed=1
1792     fi
1793     if test "x$OCAMLDEP" = x ; then
1794       AC_MSG_WARN([--enable-bindings=ocaml specified, but ocamldep not found. Try configure OCAMLDEP=/path/to/ocamldep])
1795       binding_prereqs_failed=1
1796     fi
1797     if test "x$OCAMLOPT" = x ; then
1798       AC_MSG_WARN([--enable-bindings=ocaml specified, but ocamlopt not found. Try configure OCAMLOPT=/path/to/ocamlopt])
1799       dnl ocamlopt is optional!
1800     fi
1801     if test "x$with_ocaml_libdir" != xauto ; then
1802       AC_SUBST(OCAML_LIBDIR,$with_ocaml_libdir)
1803     else
1804       ocaml_stdlib="`"$OCAMLC" -where`"
1805       if test "$LLVM_PREFIX" '<' "$ocaml_stdlib" -a "$ocaml_stdlib" '<' "$LLVM_PREFIX~"
1806       then
1807         # ocaml stdlib is beneath our prefix; use stdlib
1808         AC_SUBST(OCAML_LIBDIR,$ocaml_stdlib)
1809       else
1810         # ocaml stdlib is outside our prefix; use libdir/ocaml
1811         AC_SUBST(OCAML_LIBDIR,$LLVM_LIBDIR/ocaml)
1812       fi
1813     fi
1814     ;;
1815   esac
1816 done
1817 if test "$binding_prereqs_failed" = 1 ; then
1818   AC_MSG_ERROR([Prequisites for bindings not satisfied. Fix them or use configure --disable-bindings.])
1819 fi
1820
1821 dnl Determine whether the compiler supports -fvisibility-inlines-hidden.
1822 AC_CXX_USE_VISIBILITY_INLINES_HIDDEN
1823
1824 dnl Determine linker rpath flag
1825 if test "$llvm_cv_link_use_r" = "yes" ; then
1826   RPATH="-Wl,-R"
1827 else
1828   RPATH="-Wl,-rpath"
1829 fi
1830 AC_SUBST(RPATH)
1831
1832 dnl Determine linker rdynamic flag
1833 if test "$llvm_cv_link_use_export_dynamic" = "yes" ; then
1834   RDYNAMIC="-Wl,-export-dynamic"
1835 else
1836   RDYNAMIC=""
1837 fi
1838 AC_SUBST(RDYNAMIC)
1839
1840 dnl===-----------------------------------------------------------------------===
1841 dnl===
1842 dnl=== SECTION 10: Specify the output files and generate it
1843 dnl===
1844 dnl===-----------------------------------------------------------------------===
1845
1846 dnl Configure header files
1847 dnl WARNING: dnl If you add or remove any of the following config headers, then
1848 dnl you MUST also update Makefile so that the variable FilesToConfig
1849 dnl contains the same list of files as AC_CONFIG_HEADERS below. This ensures the
1850 dnl files can be updated automatically when their *.in sources change.
1851 AC_CONFIG_HEADERS([include/llvm/Config/config.h include/llvm/Config/llvm-config.h])
1852 AH_TOP([#ifndef CONFIG_H
1853 #define CONFIG_H])
1854 AH_BOTTOM([#endif])
1855
1856 AC_CONFIG_FILES([include/llvm/Config/Targets.def])
1857 AC_CONFIG_FILES([include/llvm/Config/AsmPrinters.def])
1858 AC_CONFIG_FILES([include/llvm/Config/AsmParsers.def])
1859 AC_CONFIG_FILES([include/llvm/Config/Disassemblers.def])
1860 AC_CONFIG_HEADERS([include/llvm/Support/DataTypes.h])
1861
1862 dnl Configure the makefile's configuration data
1863 AC_CONFIG_FILES([Makefile.config])
1864
1865 dnl Configure the RPM spec file for LLVM
1866 AC_CONFIG_FILES([llvm.spec])
1867
1868 dnl Configure doxygen's configuration file
1869 AC_CONFIG_FILES([docs/doxygen.cfg])
1870
1871 dnl Configure clang, if present
1872 if test "${clang_src_root}" = ""; then
1873   clang_src_root="$srcdir/tools/clang"
1874 fi
1875 if test -f ${clang_src_root}/README.txt; then
1876   dnl Use variables to stay under 80 columns.
1877   configh="include/clang/Config/config.h"
1878   doxy="docs/doxygen.cfg"
1879   AC_CONFIG_HEADERS([tools/clang/${configh}:${clang_src_root}/${configh}.in])
1880   AC_CONFIG_FILES([tools/clang/${doxy}:${clang_src_root}/${doxy}.in])
1881 fi
1882
1883 dnl OCaml findlib META file
1884 AC_CONFIG_FILES([bindings/ocaml/llvm/META.llvm])
1885
1886 dnl Add --program-prefix value to Makefile.rules. Already an ARG variable.
1887 test "x$program_prefix" = "xNONE" && program_prefix=""
1888 AC_SUBST([program_prefix])
1889
1890
1891 dnl Do special configuration of Makefiles
1892 AC_CONFIG_COMMANDS([setup],,[llvm_src="${srcdir}"])
1893 AC_CONFIG_MAKEFILE(Makefile)
1894 AC_CONFIG_MAKEFILE(Makefile.common)
1895 AC_CONFIG_MAKEFILE(examples/Makefile)
1896 AC_CONFIG_MAKEFILE(lib/Makefile)
1897 AC_CONFIG_MAKEFILE(runtime/Makefile)
1898 AC_CONFIG_MAKEFILE(test/Makefile)
1899 AC_CONFIG_MAKEFILE(test/Makefile.tests)
1900 AC_CONFIG_MAKEFILE(unittests/Makefile)
1901 AC_CONFIG_MAKEFILE(tools/Makefile)
1902 AC_CONFIG_MAKEFILE(utils/Makefile)
1903 AC_CONFIG_MAKEFILE(projects/Makefile)
1904 AC_CONFIG_MAKEFILE(bindings/Makefile)
1905 AC_CONFIG_MAKEFILE(bindings/ocaml/Makefile.ocaml)
1906
1907 dnl Finally, crank out the output
1908 AC_OUTPUT