autoconf/configure.ac

   1 dnl === configure.ac --------------------------------------------------------===
   2 dnl                     The LLVM Compiler Infrastructure
   3 dnl
   4 dnl This file was developed by the LLVM research group and is distributed under
   5 dnl the University of Illinois Open Source License. See LICENSE.TXT for details.
   6 dnl
   7 dnl===-----------------------------------------------------------------------===
   8 dnl This is the LLVM configuration script. It is processed by the autoconf
   9 dnl program to produce a script named configure. This script contains the
  10 dnl configuration checks that LLVM needs in order to support multiple platforms.
  11 dnl This file is composed of 10 sections per the recommended organization of
  12 dnl autoconf input defined in the autoconf documentation. As this file evolves,
  13 dnl please keep the various types of checks within their sections. The sections
  14 dnl are as follows:
  15 dnl
  16 dnl SECTION 1: Initialization & Setup
  17 dnl SECTION 2: Architecture, target, and host checks
  18 dnl SECTION 3: Command line arguments for the configure script.
  19 dnl SECTION 4: Check for programs we need and that they are the right version
  20 dnl SECTION 5: Check for libraries
  21 dnl SECTION 6: Check for header files
  22 dnl SECTION 7: Check for types and structures
  23 dnl SECTION 8: Check for specific functions needed
  24 dnl SECTION 9: Additional checks, variables, etc.
  25 dnl SECTION 10: Specify the output files and generate it
  26 dnl
  27 dnl===-----------------------------------------------------------------------===
  28 dnl===
  29 dnl=== SECTION 1: Initialization & Setup
  30 dnl===
  31 dnl===-----------------------------------------------------------------------===
  32 dnl Initialize autoconf and define the package name, version number and
  33 dnl email address for reporting bugs.
  34 AC_INIT([[llvm]],[[1.6cvs]],[llvmbugs@cs.uiuc.edu])
  35
  36 dnl Provide a copyright substitution and ensure the copyright notice is included
  37 dnl in the output of --version option of the generated configure script.
  38 AC_SUBST(LLVM_COPYRIGHT,["Copyright (c) 2003-2005 University of Illinois at Urbana-Champaign."])
  39 AC_COPYRIGHT($LLVM_COPYRIGHT)
  40
  41 dnl Indicate that we require autoconf 2.59 or later. Ths is needed because we
  42 dnl use some autoconf macros only available in 2.59.
  43 AC_PREREQ(2.59)
  44
  45 dnl Verify that the source directory is valid. This makes sure that we are
  46 dnl configuring LLVM and not some other package (it validates --srcdir argument)
  47 AC_CONFIG_SRCDIR([lib/VMCore/Module.cpp])
  48
  49 dnl Place all of the extra autoconf files into the config subdirectory. Tell
  50 dnl various tools where the m4 autoconf macros are.
  51 AC_CONFIG_AUX_DIR([autoconf])
  52
  53 dnl Quit if the source directory has already been configured.
  54 dnl NOTE: This relies upon undocumented autoconf behavior.
  55 if test ${srcdir} != "." ; then
  56   if test -f ${srcdir}/include/llvm/Config/config.h ; then
  57     AC_MSG_ERROR([Already configured in ${srcdir}])
  58   fi
  59 fi
  60
  61 dnl Configure all of the projects present in our source tree. While we could
  62 dnl just AC_CONFIG_SUBDIRS on the set of directories in projects that have a
  63 dnl configure script, that usage of the AC_CONFIG_SUBDIRS macro is deprecated.
  64 dnl Instead we match on the known projects.
  65 for i in `ls ${srcdir}/projects`
  66 do
  67   if test -d ${srcdir}/projects/${i} ; then
  68     case ${i} in
  69       "CVS") ;;
  70       "sample")       AC_CONFIG_SUBDIRS([projects/sample])    ;;
  71       "Stacker")      AC_CONFIG_SUBDIRS([projects/Stacker])   ;;
  72       "llvm-test")    AC_CONFIG_SUBDIRS([projects/llvm-test]) ;;
  73       "llvm-reopt")   AC_CONFIG_SUBDIRS([projects/llvm-reopt]);;
  74       "llvm-gcc")     AC_CONFIG_SUBDIRS([projects/llvm-gcc])  ;;
  75       "llvm-java")    AC_CONFIG_SUBDIRS([projects/llvm-java]) ;;
  76       "llvm-tv")      AC_CONFIG_SUBDIRS([projects/llvm-tv])   ;;
  77       "llvm-poolalloc") AC_CONFIG_SUBDIRS([projects/llvm-poolalloc]) ;;
  78       *)
  79         AC_MSG_WARN([Unknown project (${i}) won't be configured automatically])
  80         ;;
  81     esac
  82   fi
  83 done
  84
  85 dnl===-----------------------------------------------------------------------===
  86 dnl===
  87 dnl=== SECTION 2: Architecture, target, and host checks
  88 dnl===
  89 dnl===-----------------------------------------------------------------------===
  90
  91 dnl Check the target for which we're compiling and the host that will do the
  92 dnl compilations. This will tell us which LLVM compiler will be used for
  93 dnl compiling SSA into object code. This needs to be done early because
  94 dnl following tests depend on it.
  95 AC_CANONICAL_TARGET
  96
  97 dnl Determine the platform type and cache its value. This helps us configure
  98 dnl the System library to the correct build platform.
  99 AC_CACHE_CHECK([type of operating system we're on],
 100                [llvm_cv_os_type],
 101 [case $build in
 102   *-*-aix*)
 103     llvm_cv_os_type="AIX"
 104     llvm_cv_platform_type="Unix" ;;
 105   *-*-cygwin*)
 106     llvm_cv_os_type="Cygwin"
 107     llvm_cv_platform_type="Unix" ;;
 108   *-*-darwin*)
 109     llvm_cv_os_type="Darwin"
 110     llvm_cv_platform_type="Unix" ;;
 111   *-*-freebsd*)
 112     llvm_cv_os_type="FreeBSD"
 113     llvm_cv_platform_type="Unix" ;;
 114   *-*-hpux*)
 115     llvm_cv_os_type="HP-UX"
 116     llvm_cv_platform_type="Unix" ;;
 117   *-*-interix*)
 118     llvm_cv_os_type="Interix"
 119     llvm_cv_platform_type="Unix" ;;
 120   *-*-linux*)
 121     llvm_cv_os_type="Linux"
 122     llvm_cv_platform_type="Unix" ;;
 123   *-*-solaris*)
 124     llvm_cv_os_type="SunOS"
 125     llvm_cv_platform_type="Unix" ;;
 126   *-*-win32*)
 127     llvm_cv_os_type="Win32"
 128     llvm_cv_platform_type="Win32" ;;
 129   *-*-mingw*)
 130     llvm_cv_os_type="MingW"
 131     llvm_cv_platform_type="Win32" ;;
 132   *)
 133     llvm_cv_os_type="Unknown"
 134     llvm_cv_platform_type="Unknown" ;;
 135 esac])
 136
 137 dnl Make sure we aren't attempting to configure for an unknown system
 138 if test "$llvm_cv_os_type" = "Unknown" ; then
 139   AC_MSG_ERROR([Operating system is unknown, configure can't continue])
 140 fi
 141
 142 dnl Set the "OS" Makefile variable based on the platform type so the
 143 dnl makefile can configure itself to specific build hosts
 144 AC_SUBST(OS,$llvm_cv_os_type)
 145
 146 dnl Set the "LLVM_ON_*" variables based on llvm_cvs_platform_type
 147 dnl This is used by lib/System to determine the basic kind of implementation
 148 dnl to use.
 149 case $llvm_cv_platform_type in
 150   Unix)
 151     AC_DEFINE([LLVM_ON_UNIX],[1],[Define if this is Unixish platform])
 152     AC_SUBST(LLVM_ON_UNIX,[1])
 153     AC_SUBST(LLVM_ON_WIN32,[0])
 154     ;;
 155   Win32)
 156     AC_DEFINE([LLVM_ON_WIN32],[1],[Define if this is Win32ish platform])
 157     AC_SUBST(LLVM_ON_UNIX,[0])
 158     AC_SUBST(LLVM_ON_WIN32,[1])
 159     ;;
 160 esac
 161
 162 dnl Determine what our target architecture is and configure accordingly.
 163 dnl This will allow Makefiles to make a distinction between the hardware and
 164 dnl the OS.
 165 AC_CACHE_CHECK([target architecture],[llvm_cv_target_arch],
 166 [case $target in
 167   i?86-*)                 llvm_cv_target_arch="x86" ;;
 168   amd64-* | x86_64-*)     llvm_cv_target_arch="x86_64" ;;
 169   sparc*-*)               llvm_cv_target_arch="Sparc" ;;
 170   powerpc*-*)             llvm_cv_target_arch="PowerPC" ;;
 171   alpha*-*)               llvm_cv_target_arch="Alpha" ;;
 172   ia64-*)                 llvm_cv_target_arch="IA64" ;;
 173   *)                      llvm_cv_target_arch="Unknown" ;;
 174 esac])
 175
 176 if test "$llvm_cv_target_arch" = "Unknown" ; then
 177   AC_MSG_WARN([Configuring LLVM for an unknown target archicture])
 178 fi
 179
 180 dnl Define a substitution, ARCH, for the target architecture
 181 AC_SUBST(ARCH,$llvm_cv_target_arch)
 182
 183 dnl Check for the endianness of the target
 184 AC_C_BIGENDIAN(AC_SUBST([ENDIAN],[big]),AC_SUBST([ENDIAN],[little]))
 185
 186 dnl===-----------------------------------------------------------------------===
 187 dnl===
 188 dnl=== SECTION 3: Command line arguments for the configure script.
 189 dnl===
 190 dnl===-----------------------------------------------------------------------===
 191
 192 dnl --enable-optimized : check whether they want to do an optimized build:
 193 AC_ARG_ENABLE(optimized,
 194               AS_HELP_STRING([--enable-optimized,Compile with optimizations enabled (default is NO)]),,enableval=no)
 195 if test ${enableval} = "no" ; then
 196   AC_SUBST(ENABLE_OPTIMIZED,[[]])
 197 else
 198   AC_SUBST(ENABLE_OPTIMIZED,[[ENABLE_OPTIMIZED=1]])
 199 fi
 200
 201 dnl --enable-jit: check whether they want to enable the jit
 202 AC_ARG_ENABLE(jit,
 203   AS_HELP_STRING(--enable-jit,
 204                  [Enable Just In Time Compiling (default is YES)]),,
 205   enableval=default)
 206 if test ${enableval} = "no"
 207 then
 208   AC_SUBST(JIT,[[]])
 209 else
 210   case "$llvm_cv_target_arch" in
 211     x86)     AC_SUBST(JIT,[[TARGET_HAS_JIT=1]]) ;;
 212     Sparc)   AC_SUBST(JIT,[[TARGET_HAS_JIT=1]]) ;;
 213     PowerPC) AC_SUBST(JIT,[[TARGET_HAS_JIT=1]]) ;;
 214     x86_64)  AC_SUBST(JIT,[[]]) ;;
 215     Alpha)   AC_SUBST(JIT,[[TARGET_HAS_JIT=1]]) ;;
 216     IA64)    AC_SUBST(JIT,[[]]) ;;
 217     *)       AC_SUBST(JIT,[[]]) ;;
 218   esac
 219 fi
 220
 221 dnl Allow enablement of doxygen generated documentation
 222 AC_ARG_ENABLE(doxygen,
 223               AS_HELP_STRING([--enable-doxygen],
 224                              [Build doxygen documentation (default is NO)]),,
 225                              enableval=default)
 226 case "$enableval" in
 227   yes) AC_SUBST(ENABLE_DOXYGEN,[1]) ;;
 228   no)  AC_SUBST(ENABLE_DOXYGEN,[0]) ;;
 229   default) AC_SUBST(ENABLE_DOXYGEN,[0]) ;;
 230   *) AC_MSG_ERROR([Invalid setting for --enable-doxygen. Use "yes" or "no"]) ;;
 231 esac
 232
 233 dnl Allow specific targets to be specified for building (or not)
 234 TARGETS_TO_BUILD=""
 235 AC_ARG_ENABLE([targets],AS_HELP_STRING([--enable-target],
 236     [Build specific host targets: all,host-only,{target-name} (default=all)]),,
 237     enableval=all)
 238 case "$enableval" in
 239   all) TARGETS_TO_BUILD="X86 SparcV8 SparcV9 PowerPC Alpha IA64 Skeleton" ;;
 240   host-only)
 241     case "$llvm_cv_target_arch" in
 242       x86)     TARGETS_TO_BUILD="X86" ;;
 243       x86_64)  TARGETS_TO_BUILD="X86" ;;
 244       Sparc)   TARGETS_TO_BUILD="SparcV8 SparcV9" ;;
 245       PowerPC) TARGETS_TO_BUILD="PowerPC" ;;
 246       Alpha)   TARGETS_TO_BUILD="Alpha" ;;
 247       IA64)    TARGETS_TO_BUILD="IA64" ;;
 248       *)       AC_MSG_ERROR([Can not set target to build]) ;;
 249     esac
 250     ;;
 251   *)for a_target in `echo $enableval|sed -e 's/,/ /g' ` ; do
 252       case "$a_target" in
 253         x86)     TARGETS_TO_BUILD="X86 $TARGETS_TO_BUILD" ;;
 254         x86_64)  TARGETS_TO_BUILD="X86 $TARGETS_TO_BUILD" ;;
 255         sparc)   TARGETS_TO_BUILD="SparcV8 SparcV9 $TARGETS_TO_BUILD" ;;
 256         powerpc) TARGETS_TO_BUILD="PowerPC $TARGETS_TO_BUILD" ;;
 257         alpha)   TARGETS_TO_BUILD="Alpha $TARGETS_TO_BUILD" ;;
 258         ia64)    TARGETS_TO_BUILD="IA64 $TARGETS_TO_BUILD" ;;
 259         skeleton)TARGETS_TO_BUILD="Skeleton $TARGETS_TO_BUILD";;
 260         *) AC_MSG_ERROR([Unrecognized target $a_target]) ;;
 261       esac
 262   done
 263   ;;
 264 esac
 265 TARGETS_TO_BUILD="CBackend $TARGETS_TO_BUILD"
 266 AC_SUBST(TARGETS_TO_BUILD,$TARGETS_TO_BUILD)
 267
 268 dnl Allow a specific llvm-gcc/llvm-g++ pair to be used with this LLVM config.
 269 AC_ARG_WITH(llvmgccdir,
 270   AS_HELP_STRING([--with-llvmgccdir],
 271     [Specify location of llvm-gcc install dir (default searches PATH)]),,
 272     withval=default)
 273 case "$withval" in
 274   default) WITH_LLVMGCCDIR=default ;;
 275   /*)      WITH_LLVMGCCDIR=$withval ;;
 276   *) AC_MSG_ERROR([Invalid path for --with-llvmgccdir. Provide full path]) ;;
 277 esac
 278
 279
 280 dnl===-----------------------------------------------------------------------===
 281 dnl===
 282 dnl=== SECTION 4: Check for programs we need and that they are the right version
 283 dnl===
 284 dnl===-----------------------------------------------------------------------===
 285
 286 dnl Check for compilation tools
 287 AC_PROG_CPP
 288 AC_PROG_CC(gcc)
 289 AC_PROG_CXX(g++)
 290 AC_PROG_FLEX
 291 AC_PROG_BISON
 292
 293 dnl Check for the tools that the makefiles require
 294 AC_CHECK_GNU_MAKE
 295 AC_PROG_LN_S
 296 AC_PATH_PROG(CMP, [cmp], [cmp])
 297 AC_PATH_PROG(CP, [cp], [cp])
 298 AC_PATH_PROG(DATE, [date], [date])
 299 AC_PATH_PROG(FIND, [find], [find])
 300 AC_PATH_PROG(GREP, [grep], [grep])
 301 AC_PATH_PROG(MKDIR,[mkdir],[mkdir])
 302 AC_PATH_PROG(MV,   [mv],   [mv])
 303 AC_PROG_RANLIB
 304 AC_PATH_PROG(RM,   [rm],   [rm])
 305 AC_PATH_PROG(SED,  [sed],  [sed])
 306 AC_PATH_PROG(TAR,  [tar],  [gtar])
 307 AC_PATH_PROG(GRAPHVIZ, [Graphviz], [echo Graphviz])
 308 if test "$GRAPHVIZ" != "echo Graphviz" ; then
 309   AC_DEFINE([HAVE_GRAPHVIZ],[1],[Define if the Graphviz program is available])
 310   AC_DEFINE_UNQUOTED([LLVM_PATH_GRAPHVIZ],"$GRAPHVIZ",
 311    [Define to path to Graphviz program if found or 'echo Graphviz' otherwise])
 312 fi
 313 AC_PATH_PROG(GV, [gv], [echo gv])
 314 if test "$GRAPHVIZ" != "echo gv" ; then
 315   AC_DEFINE([HAVE_GV],[1],[Define if the gv program is available])
 316   AC_DEFINE_UNQUOTED([LLVM_PATH_GV],"$GV",
 317    [Define to path to gv program if found or 'echo gv' otherwise])
 318 fi
 319
 320 dnl Find the install program
 321 AC_PROG_INSTALL
 322
 323 dnl Checks for documentation and testing tools that we can do without. If these
 324 dnl are not found then they are set to "true" which always succeeds but does
 325 dnl nothing. This just lets the build output show that we could have done
 326 dnl something if the tool was available.
 327 AC_PATH_PROG(BZIP2,[bzip2],[true bzip2])
 328 AC_PATH_PROG(DOT,[dot],[true dot])
 329 AC_PATH_PROG(DOXYGEN,[doxygen],[true doxygen])
 330 AC_PATH_PROG(ETAGS,[etags],[true etags])
 331 AC_PATH_PROG(GROFF,[groff],[true groff])
 332 AC_PATH_PROG(GZIP,[gzip],[true gzip])
 333 AC_PATH_PROG(POD2HTML,[pod2html],[true pod2html])
 334 AC_PATH_PROG(POD2MAN,[pod2man],[true pod2man])
 335 AC_PATH_PROG(RUNTEST,[runtest],[true runtest])
 336 DJ_AC_PATH_TCLSH
 337 AC_PATH_PROG(ZIP,[zip],[true zip])
 338
 339 dnl Determine if the linker supports the -R option.
 340 AC_LINK_USE_R
 341
 342 dnl Check for libtool and the library that has dlopen function (which must come
 343 dnl before the AC_PROG_LIBTOOL check in order to enable dlopening libraries with
 344 dnl libtool).
 345 AC_LIBTOOL_DLOPEN
 346 AC_LIB_LTDL
 347 AC_PROG_LIBTOOL
 348
 349 if test "$lt_cv_dlopen_self" = "yes" ; then
 350   AC_DEFINE([CAN_DLOPEN_SELF],[1],
 351               [Define if dlopen(0) will open the symbols of the program])
 352 fi
 353
 354 dnl Check if we know how to tell etags we are using C++:
 355 etags_version=`$ETAGS --version 2>&1`
 356 case "$etags_version" in
 357         *[Ee]xuberant*) ETAGSFLAGS="--language-force=c++" ;;
 358         *GNU\ Emacs*) ETAGSFLAGS="-l c++" ;;
 359         *) ETAGSFLAGS="" ;;
 360 esac
 361 AC_SUBST(ETAGSFLAGS,$ETAGSFLAGS)
 362
 363 if test "$WITH_LLVMGCCDIR" = "default" ; then
 364   LLVMGCC="llvm-gcc${EXEEXT}"
 365   LLVMGXX="llvm-g++${EXEEXT}"
 366   AC_PATH_PROG(LLVMGCC, $LLVMGCC, [])
 367   AC_PATH_PROG(LLVMGXX, $LLVMGXX, [])
 368 else
 369   LLVMGCC="$WITH_LLVMGCCDIR/bin/llvm-gcc${EXEEXT}"
 370   LLVMGXX="$WITH_LLVMGCCDIR/bin/llvm-g++${EXEEXT}"
 371   AC_SUBST(LLVMGCC,$LLVMGCC)
 372   AC_SUBST(LLVMGXX,$LLVMGXX)
 373 fi
 374
 375 AC_MSG_CHECKING([tool compatibility])
 376
 377 dnl Ensure that compilation tools are GCC or a GNU compatible compiler such as
 378 dnl ICC; we use GCC specific options in the makefiles so the compiler needs
 379 dnl to support those options.
 380 dnl "icc" emits gcc signatures
 381 dnl "icc -no-gcc" emits no gcc signature BUT is still compatible
 382 ICC=no
 383 IXX=no
 384 case $CC in
 385   icc*|icpc*)
 386     ICC=yes
 387     IXX=yes
 388     ;;
 389    *)
 390     ;;
 391 esac
 392
 393 if test "$GCC" != "yes" && test "$ICC" != "yes"
 394 then
 395   AC_MSG_ERROR([gcc|icc required but not found])
 396 fi
 397
 398 dnl Ensure that compilation tools are GCC; we use GCC specific extensions
 399 if test "$GXX" != "yes" && test "$IXX" != "yes"
 400 then
 401   AC_MSG_ERROR([g++|icc required but not found])
 402 fi
 403
 404 dnl Verify that GCC is version 3.0 or higher
 405 if test "$GCC" = "yes"
 406 then
 407   gccmajor=`$CC --version | head -n 1 | sed 's/[[^0-9]]*\([[0-9.]]\).*/\1/'`
 408   if test "$gccmajor" -lt "3"
 409   then
 410     AC_MSG_ERROR([gcc 3.x required, but you have a lower version])
 411   fi
 412 fi
 413
 414 dnl Check for GNU Make.  We use its extensions, so don't build without it
 415 if test -z "$llvm_cv_gnu_make_command"
 416 then
 417   AC_MSG_ERROR([GNU Make required but not found])
 418 fi
 419
 420 dnl Tool compatibility is okay if we make it here.
 421 AC_MSG_RESULT([ok])
 422
 423 dnl===-----------------------------------------------------------------------===
 424 dnl===
 425 dnl=== SECTION 5: Check for libraries
 426 dnl===
 427 dnl===-----------------------------------------------------------------------===
 428
 429 dnl libelf is for sparc only; we can ignore it if we don't have it
 430 AC_CHECK_LIB(elf, elf_begin)
 431
 432
 433 dnl lt_dlopen may be required for plugin support.
 434 AC_SEARCH_LIBS(lt_dlopen,ltdl,AC_DEFINE([HAVE_LT_DLOPEN],[1],
 435               [Define if lt_dlopen() is available on this platform]),
 436               AC_MSG_WARN([lt_dlopen() not found - plugin support might
 437                            not be available]))
 438
 439 dnl dlopen() is required for plugin support.
 440 AC_SEARCH_LIBS(dlopen,dl,AC_DEFINE([HAVE_DLOPEN],[1],
 441                [Define if dlopen() is available on this platform.]),
 442                AC_MSG_WARN([dlopen() not found - disabling plugin support]))
 443
 444 dnl mallinfo is optional; the code can compile (minus features) without it
 445 AC_SEARCH_LIBS(mallinfo,malloc,AC_DEFINE([HAVE_MALLINFO],[1],
 446                [Define if mallinfo() is available on this platform.]))
 447
 448 dnl pthread locking functions are optional - but llvm will not be thread-safe
 449 dnl without locks.
 450 AC_CHECK_LIB(pthread,pthread_mutex_init)
 451 AC_SEARCH_LIBS(pthread_mutex_lock,pthread,
 452                AC_DEFINE([HAVE_PTHREAD_MUTEX_LOCK],[1],
 453                          [Have pthread_mutex_lock]))
 454
 455 dnl===-----------------------------------------------------------------------===
 456 dnl===
 457 dnl=== SECTION 6: Check for header files
 458 dnl===
 459 dnl===-----------------------------------------------------------------------===
 460
 461 dnl First, use autoconf provided macros for specific headers that we need
 462 dnl We don't check for ancient stuff or things that are guaranteed to be there
 463 dnl by the C++ standard. We always use the <cfoo> versions of <foo.h> C headers.
 464 dnl Generally we're looking for POSIX headers.
 465 AC_HEADER_DIRENT
 466 AC_HEADER_MMAP_ANONYMOUS
 467 AC_HEADER_STAT
 468 AC_HEADER_STDC
 469 AC_HEADER_SYS_WAIT
 470 AC_HEADER_TIME
 471
 472 AC_CHECK_HEADERS([dlfcn.h execinfo.h fcntl.h inttypes.h limits.h link.h])
 473 AC_CHECK_HEADERS([malloc.h pthread.h signal.h stdint.h unistd.h utime.h])
 474 AC_CHECK_HEADERS([windows.h])
 475 AC_CHECK_HEADERS([sys/mman.h sys/param.h sys/resource.h sys/time.h sys/types.h])
 476 AC_CHECK_HEADERS([rw/stdex/hash_map.h rw/stdex/hash_set.h])
 477
 478 dnl===-----------------------------------------------------------------------===
 479 dnl===
 480 dnl=== SECTION 7: Check for types and structures
 481 dnl===
 482 dnl===-----------------------------------------------------------------------===
 483
 484 AC_TYPE_PID_T
 485 AC_TYPE_SIZE_T
 486 AC_TYPE_SIGNAL
 487 AC_STRUCT_TM
 488 AC_CHECK_TYPES([int64_t],,AC_MSG_ERROR([Type int64_t required but not found]))
 489 AC_CHECK_TYPES([uint64_t],,
 490          AC_CHECK_TYPES([u_int64_t],,
 491          AC_MSG_ERROR([Type uint64_t or u_int64_t required but not found])))
 492
 493 dnl===-----------------------------------------------------------------------===
 494 dnl===
 495 dnl=== SECTION 8: Check for specific functions needed
 496 dnl===
 497 dnl===-----------------------------------------------------------------------===
 498
 499 AC_CHECK_FUNCS([backtrace getcwd getpagesize getrusage gettimeofday ])
 500 AC_CHECK_FUNCS([isatty mkdtemp mkstemp mktemp ])
 501 AC_CHECK_FUNCS([realpath sbrk setrlimit strdup strerror strerror_r ])
 502 AC_CHECK_FUNCS([strtoll strtoq sysconf])
 503 AC_C_PRINTF_A
 504 AC_FUNC_ALLOCA
 505 AC_FUNC_RAND48
 506
 507 dnl Check for variations in the Standard C++ library and STL. These macros are
 508 dnl provided by LLVM in the autoconf/m4 directory.
 509 AC_CXX_HAVE_HASH_MAP
 510 AC_CXX_HAVE_HASH_SET
 511 AC_CXX_HAVE_STD_ITERATOR
 512 AC_CXX_HAVE_BI_ITERATOR
 513 AC_CXX_HAVE_FWD_ITERATOR
 514 AC_FUNC_ISNAN
 515 AC_FUNC_ISINF
 516
 517 dnl Check for mmap and mprotect support. We need both to do the JIT and for
 518 dnl bytecode loading, etc. We also need to know if /dev/zero is required to
 519 dnl be opened for allocating RWX memory.
 520 AC_FUNC_MMAP
 521 AC_FUNC_MMAP_FILE
 522 AC_NEED_DEV_ZERO_FOR_MMAP
 523 AC_CHECK_FUNC(mprotect,,
 524               AC_MSG_ERROR([Function mprotect() required but not found]))
 525
 526 if test "$ac_cv_func_mmap_fixed_mapped" = "no"
 527 then
 528   AC_MSG_WARN([mmap() of a fixed address required but not supported])
 529 fi
 530 if test "$ac_cv_func_mmap_file" = "no"
 531 then
 532   AC_MSG_WARN([mmap() of files required but not found])
 533 fi
 534
 535 dnl===-----------------------------------------------------------------------===
 536 dnl===
 537 dnl=== SECTION 9: Additional checks, variables, etc.
 538 dnl===
 539 dnl===-----------------------------------------------------------------------===
 540
 541 dnl See if the llvm-gcc executable can compile to LLVM assembly
 542 AC_CACHE_CHECK([whether llvm-gcc is sane],[llvm_cv_llvmgcc_sanity],
 543 [llvm_cv_llvmgcc_sanity="no"
 544 if test -x "$LLVMGCC" ; then
 545   cp /dev/null conftest.c
 546   "$LLVMGCC" -S -o - conftest.c | grep implementation > /dev/null 2>&1
 547   if test $? -eq 0 ; then
 548     llvm_cv_llvmgcc_sanity="yes"
 549   fi
 550   rm conftest.c
 551 fi])
 552
 553 dnl Since we have a sane llvm-gcc, identify it and its sub-tools
 554 if test "$llvm_cv_llvmgcc_sanity" = "yes" ; then
 555   llvmcc1path=`"$LLVMGCC" --print-prog-name=cc1`
 556   AC_SUBST(LLVMCC1,$llvmcc1path)
 557   llvmcc1pluspath=`"$LLVMGCC" --print-prog-name=cc1plus`
 558   AC_SUBST(LLVMCC1PLUS,$llvmcc1pluspath)
 559   llvmgccdir=`echo "$llvmcc1path" | sed 's,/libexec/.*,,'`
 560   AC_SUBST(LLVMGCCDIR,$llvmgccdir)
 561 fi
 562
 563 dnl Propagate the shared library extension that the libltdl checks did to
 564 dnl the Makefiles so we can use it there too
 565 AC_SUBST(SHLIBEXT,$libltdl_cv_shlibext)
 566
 567 # Translate the various configuration directories and other basic
 568 # information into substitutions that will end up in Makefile.config.in
 569 # that these configured values can be used by the makefiles
 570 eval LLVM_PREFIX="${prefix}";
 571 eval LLVM_BINDIR="${prefix}/bin";
 572 eval LLVM_LIBDIR="${prefix}/lib";
 573 eval LLVM_DATADIR="${prefix}/share/llvm";
 574 eval LLVM_DOCSDIR="${prefix}/docs/llvm";
 575 eval LLVM_ETCDIR="${prefix}/etc/llvm";
 576 eval LLVM_INCLUDEDIR="${prefix}/include";
 577 eval LLVM_INFODIR="${prefix}/info";
 578 eval LLVM_MANDIR="${prefix}/man";
 579 LLVM_CONFIGTIME=`date`
 580 AC_SUBST(LLVM_PREFIX)
 581 AC_SUBST(LLVM_BINDIR)
 582 AC_SUBST(LLVM_LIBDIR)
 583 AC_SUBST(LLVM_DATADIR)
 584 AC_SUBST(LLVM_DOCSDIR)
 585 AC_SUBST(LLVM_ETCDIR)
 586 AC_SUBST(LLVM_INCLUDEDIR)
 587 AC_SUBST(LLVM_INFODIR)
 588 AC_SUBST(LLVM_MANDIR)
 589 AC_SUBST(LLVM_CONFIGTIME)
 590
 591 # Place the various directores into the config.h file as #defines so that we
 592 # can know about the installation paths within LLVM.
 593 AC_DEFINE_UNQUOTED(LLVM_PREFIX,"$LLVM_PREFIX",
 594                    [Installation prefix directory])
 595 AC_DEFINE_UNQUOTED(LLVM_BINDIR, "$LLVM_BINDIR",
 596                    [Installation directory for binary executables])
 597 AC_DEFINE_UNQUOTED(LLVM_LIBDIR, "$LLVM_LIBDIR",
 598                    [Installation directory for libraries])
 599 AC_DEFINE_UNQUOTED(LLVM_DATADIR, "$LLVM_DATADIR",
 600                    [Installation directory for data files])
 601 AC_DEFINE_UNQUOTED(LLVM_DATADIR, "$LLVM_DOCSDIR",
 602                    [Installation directory for documentation])
 603 AC_DEFINE_UNQUOTED(LLVM_ETCDIR, "$LLVM_ETCDIR",
 604                    [Installation directory for config files])
 605 AC_DEFINE_UNQUOTED(LLVM_INCLUDEDIR, "$LLVM_INCLUDEDIR",
 606                    [Installation directory for include files])
 607 AC_DEFINE_UNQUOTED(LLVM_INFODIR, "$LLVM_INFODIR",
 608                    [Installation directory for .info files])
 609 AC_DEFINE_UNQUOTED(LLVM_MANDIR, "$LLVM_MANDIR",
 610                    [Installation directory for man pages])
 611 AC_DEFINE_UNQUOTED(LLVM_CONFIGTIME, "$LLVM_CONFIGTIME",
 612                    [Time at which LLVM was configured])
 613
 614 dnl===-----------------------------------------------------------------------===
 615 dnl===
 616 dnl=== SECTION 10: Specify the output files and generate it
 617 dnl===
 618 dnl===-----------------------------------------------------------------------===
 619
 620 dnl Configure header files
 621 AC_CONFIG_HEADERS([include/llvm/Config/config.h])
 622 AC_CONFIG_HEADERS([include/llvm/Support/DataTypes.h])
 623 AC_CONFIG_HEADERS([include/llvm/ADT/hash_map])
 624 AC_CONFIG_HEADERS([include/llvm/ADT/hash_set])
 625 AC_CONFIG_HEADERS([include/llvm/ADT/iterator])
 626
 627 dnl Configure the makefile's configuration data
 628 AC_CONFIG_FILES([Makefile.config])
 629
 630 dnl Configure doxygen's configuration file
 631 AC_CONFIG_FILES([docs/doxygen.cfg])
 632
 633 dnl Do special configuration of Makefiles
 634 AC_CONFIG_COMMANDS([setup],,[llvm_src="${srcdir}"])
 635 AC_CONFIG_MAKEFILE(Makefile)
 636 AC_CONFIG_MAKEFILE(Makefile.common)
 637 AC_CONFIG_MAKEFILE(examples/Makefile)
 638 AC_CONFIG_MAKEFILE(lib/Makefile)
 639 AC_CONFIG_MAKEFILE(runtime/Makefile)
 640 AC_CONFIG_MAKEFILE(test/Makefile)
 641 AC_CONFIG_MAKEFILE(test/Makefile.tests)
 642 AC_CONFIG_MAKEFILE(tools/Makefile)
 643 AC_CONFIG_MAKEFILE(utils/Makefile)
 644 AC_CONFIG_MAKEFILE(projects/Makefile)
 645
 646 dnl Finally, crank out the output
 647 AC_OUTPUT
 648
 649 dnl Warn loudly if llvm-gcc was not obviously working
 650 if test "$llvm_cv_llvmgcc_sanity" = "no" ; then
 651  AC_MSG_WARN([***** llvm-gcc/llvm-g++ was not found, or does not appear to be ])
 652  AC_MSG_WARN([***** working. Please make sure you have llvmgcc and llvmg++ in])
 653  AC_MSG_WARN([***** your path before configuring LLVM. The runtime libraries])
 654  AC_MSG_WARN([***** (llvm/runtime) will not be built but you should be able to])
 655  AC_MSG_WARN([***** build the llvm tools.])
 656 fi