autoconf/configure.ac

   1 dnl === configure.ac --------------------------------------------------------===
   2 dnl                     The LLVM Compiler Infrastructure
   3 dnl
   4 dnl This file was developed by the LLVM research group and is distributed under
   5 dnl the University of Illinois Open Source License. See LICENSE.TXT for details.
   6 dnl
   7 dnl===-----------------------------------------------------------------------===
   8 dnl This is the LLVM configuration script. It is processed by the autoconf
   9 dnl program to produce a script named configure. This script contains the
  10 dnl configuration checks that LLVM needs in order to support multiple platforms.
  11 dnl This file is composed of 10 sections per the recommended organization of
  12 dnl autoconf input defined in the autoconf documentation. As this file evolves,
  13 dnl please keep the various types of checks within their sections. The sections
  14 dnl are as follows:
  15 dnl
  16 dnl SECTION 1: Initialization & Setup
  17 dnl SECTION 2: Architecture, target, and host checks
  18 dnl SECTION 3: Command line arguments for the configure script.
  19 dnl SECTION 4: Check for programs we need and that they are the right version
  20 dnl SECTION 5: Check for libraries
  21 dnl SECTION 6: Check for header files
  22 dnl SECTION 7: Check for types and structures
  23 dnl SECTION 8: Check for specific functions needed
  24 dnl SECTION 9: Additional checks, variables, etc.
  25 dnl SECTION 10: Specify the output files and generate it
  26 dnl
  27 dnl===-----------------------------------------------------------------------===
  28 dnl===
  29 dnl=== SECTION 1: Initialization & Setup
  30 dnl===
  31 dnl===-----------------------------------------------------------------------===
  32 dnl Initialize autoconf and define the package name, version number and
  33 dnl email address for reporting bugs.
  34 AC_INIT([[llvm]],[[1.4]],[llvmbugs@cs.uiuc.edu])
  35
  36 dnl Provide a copyright substitution and ensure the copyright notice is included
  37 dnl in the output of --version option of the generated configure script.
  38 AC_SUBST(LLVM_COPYRIGHT,["Copyright (c) 2003-2005 U University of Illinois at Urbana-Champaign."])
  39 AC_COPYRIGHT($LLVM_COPYRIGHT)
  40
  41 dnl Indicate that we require autoconf 2.59 or later. Ths is needed because we
  42 dnl use some autoconf macros only available in 2.59.
  43 AC_PREREQ(2.59)
  44
  45 dnl Verify that the source directory is valid. This makes sure that we are
  46 dnl configuring LLVM and not some other package (it validates --srcdir argument)
  47 AC_CONFIG_SRCDIR([lib/VMCore/Module.cpp])
  48
  49 dnl Place all of the extra autoconf files into the config subdirectory. Tell
  50 dnl various tools where the m4 autoconf macros are.
  51 AC_CONFIG_AUX_DIR([autoconf])
  52
  53 dnl Quit if the source directory has already been configured.
  54 dnl NOTE: This relies upon undocumented autoconf behavior.
  55 if test ${srcdir} != "." ; then
  56   if test -f ${srcdir}/include/llvm/Config/config.h ; then
  57     AC_MSG_ERROR([Already configured in ${srcdir}])
  58   fi
  59 fi
  60
  61 dnl Configure all of the projects present in our source tree. While we could
  62 dnl just AC_CONFIG_SUBDIRS on the set of directories in projects that have a
  63 dnl configure script, that usage of the AC_CONFIG_SUBDIRS macro is deprecated.
  64 dnl Instead we match on the known projects.
  65 for i in `ls ${srcdir}/projects`
  66 do
  67   if test -d ${srcdir}/projects/${i} ; then
  68     case ${i} in
  69       "CVS") ;;
  70       "sample")       AC_CONFIG_SUBDIRS([projects/sample])    ;;
  71       "Stacker")      AC_CONFIG_SUBDIRS([projects/Stacker])   ;;
  72       "llvm-test")    AC_CONFIG_SUBDIRS([projects/llvm-test]) ;;
  73       "llvm-reopt")   AC_CONFIG_SUBDIRS([projects/llvm-reopt]);;
  74       "llvm-gcc")     AC_CONFIG_SUBDIRS([projects/llvm-gcc])  ;;
  75       "Java")         AC_CONFIG_SUBDIRS([projects/Java])      ;;
  76       "llvm-tv")      AC_CONFIG_SUBDIRS([projects/llvm-tv])   ;;
  77       "llvm-fefw")    AC_CONFIG_SUBDIRS([projects/llvm-fefw]) ;;
  78       "poolalloc")    AC_CONFIG_SUBDIRS([projects/poolalloc]) ;;
  79       *)
  80         AC_MSG_WARN([Unknown project (${i}) won't be configured automatically])
  81         ;;
  82     esac
  83   fi
  84 done
  85
  86 dnl===-----------------------------------------------------------------------===
  87 dnl===
  88 dnl=== SECTION 2: Architecture, target, and host checks
  89 dnl===
  90 dnl===-----------------------------------------------------------------------===
  91
  92 dnl Check the target for which we're compiling and the host that will do the
  93 dnl compilations. This will tell us which LLVM compiler will be used for
  94 dnl compiling SSA into object code. This needs to be done early because
  95 dnl following tests depend on it.
  96 AC_CANONICAL_TARGET
  97
  98 dnl Determine the platform type and cache its value. This helps us configure
  99 dnl the System library to the correct build platform.
 100 AC_CACHE_CHECK([type of operating system we're on],
 101                [llvm_cv_os_type],
 102 [case $build in
 103   *-*-aix*)
 104     llvm_cv_os_type="AIX"
 105     llvm_cv_platform_type="Unix" ;;
 106   *-*-cygwin*)
 107     llvm_cv_os_type="Cygwin"
 108     llvm_cv_platform_type="Unix" ;;
 109   *-*-darwin*)
 110     llvm_cv_os_type="Darwin"
 111     llvm_cv_platform_type="Unix" ;;
 112   *-*-freebsd*)
 113     llvm_cv_os_type="FreeBSD"
 114     llvm_cv_platform_type="Unix" ;;
 115   *-*-interix*)
 116     llvm_cv_os_type="Interix"
 117     llvm_cv_platform_type="Unix" ;;
 118   *-*-linux*)
 119     llvm_cv_os_type="Linux"
 120     llvm_cv_platform_type="Unix" ;;
 121   *-*-solaris*)
 122     llvm_cv_os_type="SunOS"
 123     llvm_cv_platform_type="Unix" ;;
 124   *-*-win32*)
 125     llvm_cv_os_type="Win32"
 126     llvm_cv_platform_type="Win32" ;;
 127   *-*-mingw*)
 128     llvm_cv_os_type="MingW"
 129     llvm_cv_platform_type="Win32" ;;
 130   *)
 131     llvm_cv_os_type="Unknown"
 132     llvm_cv_platform_type="Unknown" ;;
 133 esac])
 134
 135 dnl Make sure we aren't attempting to configure for an unknown system
 136 if test "$llvm_cv_os_type" = "Unknown" ; then
 137   AC_MSG_ERROR([Operating system is unknown, configure can't continue])
 138 fi
 139
 140 dnl Set the "OS" Makefile variable based on the platform type so the
 141 dnl makefile can configure itself to specific build hosts
 142 AC_SUBST(OS,$llvm_cv_os_type)
 143
 144 dnl Set the "LLVM_ON_*" variables based on llvm_cvs_platform_type
 145 dnl This is used by lib/System to determine the basic kind of implementation
 146 dnl to use.
 147 case $llvm_cv_platform_type in
 148   Unix)
 149     AC_DEFINE([LLVM_ON_UNIX],[1],[Define if this is Unixish platform])
 150     ;;
 151   Win32)
 152     AC_DEFINE([LLVM_ON_WIN32],[1],[Define if this is Win32ish platform])
 153     ;;
 154 esac
 155
 156 dnl Make a link from lib/System/platform to lib/System/$llvm_cv_os_type
 157 dnl This helps the #inclusion of the system specific include files
 158 dnl for the operating system abstraction library, lib/System.
 159 AC_CONFIG_LINKS(lib/System/platform:lib/System/$llvm_cv_os_type)
 160
 161 dnl If we are targetting a Sparc machine running Solaris, pretend that it is
 162 dnl V9, since that is all that we support at the moment, and autoconf will only
 163 dnl tell us we're a sparc.
 164 case $target in
 165   sparc*-*-solaris*)  AC_SUBST(target,[[sparcv9-sun-solaris2.8]])
 166   ;;
 167 esac
 168
 169 dnl Determine what our target architecture is and configure accordingly.
 170 dnl This will allow Makefiles to make a distinction between the hardware and
 171 dnl the OS.
 172 AC_CACHE_CHECK([target architecture],[llvm_cv_target_arch],
 173 [case $target in
 174   i?86-*)                 llvm_cv_target_arch="x86" ;;
 175   amd64-* | x86_64-*)     llvm_cv_target_arch="AMD64" ;;
 176   sparc*-*)               llvm_cv_target_arch="Sparc" ;;
 177   powerpc*-*)             llvm_cv_target_arch="PowerPC" ;;
 178   *)                      llvm_cv_target_arch="Unknown" ;;
 179 esac])
 180
 181 if test "$llvm_cv_target_arch" = "Unknown" ; then
 182   AC_MSG_WARN([Configuring LLVM for an unknown target archicture])
 183 fi
 184
 185 dnl Define a substitution, ARCH, for the target architecture
 186 AC_SUBST(ARCH,$llvm_cv_target_arch)
 187
 188 dnl Check for the endianness of the target
 189 AC_C_BIGENDIAN(AC_SUBST([ENDIAN],[big]),AC_SUBST([ENDIAN],[little]))
 190
 191 dnl===-----------------------------------------------------------------------===
 192 dnl===
 193 dnl=== SECTION 3: Command line arguments for the configure script.
 194 dnl===
 195 dnl===-----------------------------------------------------------------------===
 196
 197 dnl --enable-optimized : check whether they want to do an optimized build:
 198 AC_ARG_ENABLE(optimized,
 199               AS_HELP_STRING([--enable-optimized,Compile with optimizations enabled (default is NO)]),,enableval=no)
 200 if test ${enableval} = "no" ; then
 201   AC_SUBST(ENABLE_OPTIMIZED,[[]])
 202 else
 203   AC_SUBST(ENABLE_OPTIMIZED,[[ENABLE_OPTIMIZED=1]])
 204 fi
 205
 206 dnl --enable-jit: check whether they want to enable the jit
 207 AC_ARG_ENABLE(jit,
 208   AS_HELP_STRING(--enable-jit,
 209                  [Enable Just In Time Compiling (default is YES)]),,
 210   enableval=default)
 211 if test ${enableval} = "no"
 212 then
 213   AC_SUBST(JIT,[[]])
 214 else
 215   case "$llvm_cv_target_arch" in
 216     x86)     AC_SUBST(JIT,[[TARGET_HAS_JIT=1]]) ;;
 217     Sparc)   AC_SUBST(JIT,[[TARGET_HAS_JIT=1]]) ;;
 218     PowerPC) AC_SUBST(JIT,[[TARGET_HAS_JIT=1]]) ;;
 219     AMD64)   AC_SUBST(JIT,[[]]) ;;
 220     *)       AC_SUBST(JIT,[[]]) ;;
 221   esac
 222 fi
 223
 224 dnl Allow enablement of doxygen generated documentation
 225 AC_ARG_ENABLE(doxygen,
 226               AS_HELP_STRING([--enable-doxygen],
 227                              [Build doxygen documentation (default is NO)]),,
 228                              enableval=default)
 229 case "$enableval" in
 230   yes) AC_SUBST(ENABLE_DOXYGEN,[1]) ;;
 231   no)  AC_SUBST(ENABLE_DOXYGEN,[0]) ;;
 232   default) AC_SUBST(ENABLE_DOXYGEN,[0]) ;;
 233   *) AC_MSG_ERROR([Invalid setting for --enable-doxygen. Use "yes" or "no"]) ;;
 234 esac
 235
 236 dnl Allow a specific llvm-gcc/llvm-g++ pair to be used with this LLVM config.
 237 AC_ARG_WITH(llvmgccdir,
 238   AS_HELP_STRING([--with-llvmgccdir],
 239     [Specify location of llvm-gcc install dir (default searches PATH)]),,
 240     withval=default)
 241 case "$withval" in
 242   default) WITH_LLVMGCCDIR=default ;;
 243   /*)      WITH_LLVMGCCDIR=$withval ;;
 244   *) AC_MSG_ERROR([Invalid path for --with-llvmgccdir. Provide full path]) ;;
 245 esac
 246
 247 dnl===-----------------------------------------------------------------------===
 248 dnl===
 249 dnl=== SECTION 4: Check for programs we need and that they are the right version
 250 dnl===
 251 dnl===-----------------------------------------------------------------------===
 252
 253 dnl Check for compilation tools
 254 AC_PROG_CPP
 255 AC_PROG_CC(gcc)
 256 AC_PROG_CXX(g++)
 257 AC_PROG_FLEX
 258 AC_PROG_BISON
 259
 260 dnl Check for the tools that the makefiles require
 261 AC_CHECK_GNU_MAKE
 262 AC_PROG_LN_S
 263 AC_PATH_PROG(CMP, [cmp], [cmp])
 264 AC_PATH_PROG(CP, [cp], [cp])
 265 AC_PATH_PROG(DATE, [date], [date])
 266 AC_PATH_PROG(FIND, [find], [find])
 267 AC_PATH_PROG(GREP, [grep], [grep])
 268 AC_PATH_PROG(MKDIR,[mkdir],[mkdir])
 269 AC_PATH_PROG(MV,   [mv],   [mv])
 270 AC_PATH_PROG(PAX,  [pax],  [pax])
 271 AC_PROG_RANLIB
 272 AC_PATH_PROG(RM,   [rm],   [rm])
 273 AC_PATH_PROG(SED,  [sed],  [sed])
 274 AC_PATH_PROG(TAR,  [tar],  [gtar])
 275
 276 dnl Find the install program
 277 AC_PROG_INSTALL
 278
 279 dnl Checks for documentation and testing tools that we can do without. If these
 280 dnl are not found then they are set to "true" which always succeeds but does
 281 dnl nothing. This just lets the build output show that we could have done
 282 dnl something if the tool was available.
 283 AC_PATH_PROG(BZIP2,[bzip2],[true bzip2])
 284 AC_PATH_PROG(DOT,[dot],[true dot])
 285 AC_PATH_PROG(DOXYGEN,[doxygen],[true doxygen])
 286 AC_PATH_PROG(ETAGS,[etags],[true etags])
 287 AC_PATH_PROG(GROFF,[groff],[true groff])
 288 AC_PATH_PROG(GZIP,[gzip],[true gzip])
 289 AC_PATH_PROG(POD2HTML,[pod2html],[true pod2html])
 290 AC_PATH_PROG(POD2MAN,[pod2man],[true pod2man])
 291 AC_PATH_PROG(RUNTEST,[runtest],[true runtest])
 292 DJ_AC_PATH_TCLSH
 293 AC_PATH_PROG(ZIP,[zip],[true zip])
 294
 295 dnl Determine if the linker supports the -R option.
 296 AC_LINK_USE_R
 297
 298 dnl Check for libtool and the library that has dlopen function (which must come
 299 dnl before the AC_PROG_LIBTOOL check in order to enable dlopening libraries with
 300 dnl libtool).
 301 AC_LIBTOOL_DLOPEN
 302 AC_LIB_LTDL
 303 AC_PROG_LIBTOOL
 304
 305 dnl Check if we know how to tell etags we are using C++:
 306 etags_version=`$ETAGS --version 2>&1`
 307 case "$etags_version" in
 308         *[Ee]xuberant*) ETAGSFLAGS="--language-force=c++" ;;
 309         *GNU\ Emacs*) ETAGSFLAGS="-l c++" ;;
 310         *) ETAGSFLAGS="" ;;
 311 esac
 312 AC_SUBST(ETAGSFLAGS,$ETAGSFLAGS)
 313
 314 if test "$WITH_LLVMGCCDIR" = "default" ; then
 315   AC_PATH_PROG(LLVMGCC, [llvm-gcc], [llvm-gcc])
 316   AC_PATH_PROG(LLVMGXX, [llvm-g++], [llvm-g++])
 317 else
 318   LLVMGCC=$WITH_LLVMGCCDIR/bin/llvm-gcc
 319   LLVMGXX=$WITH_LLVMGCCDIR/bin/llvm-g++
 320   AC_SUBST(LLVMGCC,$LLVMGCC)
 321   AC_SUBST(LLVMGXX,$LLVMGXX)
 322 fi
 323
 324 AC_MSG_CHECKING([tool compatibility])
 325
 326 dnl Ensure that compilation tools are GCC or a GNU compatible compiler such as
 327 dnl ICC; we use GCC specific options in the makefiles so the compiler needs
 328 dnl to support those options.
 329 dnl "icc" emits gcc signatures
 330 dnl "icc -no-gcc" emits no gcc signature BUT is still compatible
 331 ICC=no
 332 IXX=no
 333 case $CC in
 334   icc*|icpc*)
 335     ICC=yes
 336     IXX=yes
 337     ;;
 338    *)
 339     ;;
 340 esac
 341
 342 if test "$GCC" != "yes" && test "$ICC" != "yes"
 343 then
 344   AC_MSG_ERROR([gcc|icc required but not found])
 345 fi
 346
 347 dnl Ensure that compilation tools are GCC; we use GCC specific extensions
 348 if test "$GXX" != "yes" && test "$IXX" != "yes"
 349 then
 350   AC_MSG_ERROR([g++|icc required but not found])
 351 fi
 352
 353 dnl Verify that GCC is version 3.0 or higher
 354 if test "$GCC" = "yes"
 355 then
 356   gccmajor=`$CC --version | head -n 1 | awk '{print $NF;}' | cut -d. -f1`
 357   if test "$gccmajor" -lt "3"
 358   then
 359     AC_MSG_ERROR([gcc 3.x required, but you have a lower version])
 360   fi
 361 fi
 362
 363 dnl Check for GNU Make.  We use its extensions, so don't build without it
 364 if test -z "$llvm_cv_gnu_make_command"
 365 then
 366   AC_MSG_ERROR([GNU Make required but not found])
 367 fi
 368
 369 dnl Tool compatibility is okay if we make it here.
 370 AC_MSG_RESULT([ok])
 371
 372 dnl===-----------------------------------------------------------------------===
 373 dnl===
 374 dnl=== SECTION 5: Check for libraries
 375 dnl===
 376 dnl===-----------------------------------------------------------------------===
 377
 378 dnl libelf is for sparc only; we can ignore it if we don't have it
 379 AC_CHECK_LIB(elf, elf_begin)
 380
 381 dnl lt_dlopen may be required for plugin support.
 382 AC_SEARCH_LIBS(lt_dlopen,ltdl,AC_DEFINE([HAVE_LT_DLOPEN],[1],
 383               [Define if lt_dlopen() is available on this platform]),
 384               AC_MSG_WARN([lt_dlopen() not found - plugin support might
 385                            not be available]))
 386
 387 dnl dlopen() is required for plugin support.
 388 AC_SEARCH_LIBS(dlopen,dl,AC_DEFINE([HAVE_DLOPEN],[1],
 389                [Define if dlopen() is available on this platform.]),
 390                AC_MSG_WARN([dlopen() not found - disabling plugin support]))
 391
 392 dnl mallinfo is optional; the code can compile (minus features) without it
 393 AC_SEARCH_LIBS(mallinfo,malloc,AC_DEFINE([HAVE_MALLINFO],[1],
 394                [Define if mallinfo() is available on this platform.]))
 395
 396 dnl pthread locking functions are optional - but llvm will not be thread-safe
 397 dnl without locks.
 398 AC_SEARCH_LIBS(pthread_mutex_lock,pthread,
 399                AC_DEFINE([HAVE_PTHREAD_MUTEX_LOCK],[1],
 400                          [Have pthread_mutex_lock]))
 401
 402 dnl===-----------------------------------------------------------------------===
 403 dnl===
 404 dnl=== SECTION 6: Check for header files
 405 dnl===
 406 dnl===-----------------------------------------------------------------------===
 407
 408 dnl First, use autoconf provided macros for specific headers that we need
 409 dnl We don't check for ancient stuff or things that are guaranteed to be there
 410 dnl by the C++ standard. We always use the <cfoo> versions of <foo.h> C headers.
 411 dnl Generally we're looking for POSIX headers.
 412 AC_HEADER_DIRENT
 413 AC_HEADER_MMAP_ANONYMOUS
 414 AC_HEADER_STAT
 415 AC_HEADER_STDC
 416 AC_HEADER_SYS_WAIT
 417 AC_HEADER_TIME
 418
 419 AC_CHECK_HEADERS([dlfcn.h execinfo.h fcntl.h inttypes.h limits.h link.h])
 420 AC_CHECK_HEADERS([malloc.h signal.h stdint.h unistd.h utime.h windows.h])
 421 AC_CHECK_HEADERS([sys/mman.h sys/param.h sys/resource.h sys/time.h sys/types.h])
 422
 423 dnl===-----------------------------------------------------------------------===
 424 dnl===
 425 dnl=== SECTION 7: Check for types and structures
 426 dnl===
 427 dnl===-----------------------------------------------------------------------===
 428
 429 AC_TYPE_PID_T
 430 AC_TYPE_SIZE_T
 431 AC_TYPE_SIGNAL
 432 AC_STRUCT_TM
 433 AC_CHECK_TYPES([int64_t],,AC_MSG_ERROR([Type int64_t required but not found]))
 434 AC_CHECK_TYPES([uint64_t],,
 435          AC_CHECK_TYPES([u_int64_t],,
 436          AC_MSG_ERROR([Type uint64_t or u_int64_t required but not found])))
 437
 438 dnl===-----------------------------------------------------------------------===
 439 dnl===
 440 dnl=== SECTION 8: Check for specific functions needed
 441 dnl===
 442 dnl===-----------------------------------------------------------------------===
 443
 444 AC_CHECK_FUNCS([backtrace getcwd getpagesize getrusage gettimeofday isatty ])
 445 AC_CHECK_FUNCS([mkdtemp mkstemp mktemp ])
 446 AC_CHECK_FUNCS([realpath setrlimit strdup strerror strerror_r strtoll strtoq ])
 447 AC_CHECK_FUNCS([sysconf])
 448 AC_C_PRINTF_A
 449 AC_FUNC_ALLOCA
 450 AC_FUNC_RAND48
 451
 452 dnl Check for variations in the Standard C++ library and STL. These macros are
 453 dnl provided by LLVM in the autoconf/m4 directory.
 454 AC_CXX_HAVE_HASH_MAP
 455 AC_CXX_HAVE_HASH_SET
 456 AC_CXX_HAVE_STD_ITERATOR
 457 AC_CXX_HAVE_BI_ITERATOR
 458 AC_CXX_HAVE_FWD_ITERATOR
 459 AC_FUNC_ISNAN
 460 AC_FUNC_ISINF
 461
 462 dnl Check for mmap and mprotect support. We need both to do the JIT and for
 463 dnl bytecode loading, etc. We also need to know if /dev/zero is required to
 464 dnl be opened for allocating RWX memory.
 465 AC_FUNC_MMAP
 466 AC_FUNC_MMAP_FILE
 467 AC_NEED_DEV_ZERO_FOR_MMAP
 468 AC_CHECK_FUNC(mprotect,,
 469               AC_MSG_ERROR([Function mprotect() required but not found]))
 470
 471 if test "$ac_cv_func_mmap_fixed_mapped" = "no"
 472 then
 473   AC_MSG_WARN([mmap() required but not found])
 474 fi
 475 if test "$ac_cv_func_mmap_file" = "no"
 476 then
 477   AC_MSG_WARN([mmap() of files required but not found])
 478 fi
 479
 480 dnl===-----------------------------------------------------------------------===
 481 dnl===
 482 dnl=== SECTION 9: Additional checks, variables, etc.
 483 dnl===
 484 dnl===-----------------------------------------------------------------------===
 485
 486 dnl See if the llvm-gcc executable can compile to LLVM assembly
 487 AC_CACHE_CHECK([whether llvm-gcc is sane],[llvm_cv_llvmgcc_sanity],
 488 [llvm_cv_llvmgcc_sanity="no"
 489 if test -x "$LLVMGCC" ; then
 490   cp /dev/null conftest.c
 491   "$LLVMGCC" -S -o - conftest.c | grep implementation > /dev/null 2>&1
 492   if test $? -eq 0 ; then
 493     llvm_cv_llvmgcc_sanity="yes"
 494   fi
 495   rm conftest.c
 496 fi])
 497
 498 dnl Since we have a sane llvm-gcc, identify it and its sub-tools
 499 if test "$llvm_cv_llvmgcc_sanity" = "yes" ; then
 500   llvmcc1path=`"$LLVMGCC" --print-prog-name=cc1`
 501   AC_SUBST(LLVMCC1,$llvmcc1path)
 502   llvmcc1pluspath=`"$LLVMGCC" --print-prog-name=cc1plus`
 503   AC_SUBST(LLVMCC1PLUS,$llvmcc1pluspath)
 504   llvmgccdir=`echo "$llvmcc1path" | sed 's,/libexec/.*,,'`
 505   AC_SUBST(LLVMGCCDIR,$llvmgccdir)
 506 fi
 507
 508 dnl Propagate the shared library extension that the libltdl checks did to
 509 dnl the Makefiles so we can use it there too
 510 AC_SUBST(SHLIBEXT,$libltdl_cv_shlibext)
 511
 512 # Translate the various configuration directories and other basic
 513 # information into substitutions that will end up in Makefile.config.in
 514 # that these configured values can be used by the makefiles
 515 eval LLVM_PREFIX="${prefix}";
 516 eval LLVM_BINDIR="${prefix}/bin";
 517 eval LLVM_LIBDIR="${prefix}/lib";
 518 eval LLVM_DATADIR="${prefix}/share/llvm";
 519 eval LLVM_DOCSDIR="${prefix}/docs/llvm";
 520 eval LLVM_ETCDIR="${prefix}/etc/llvm";
 521 eval LLVM_INCLUDEDIR="${prefix}/include";
 522 eval LLVM_INFODIR="${prefix}/info";
 523 eval LLVM_MANDIR="${prefix}/man";
 524 LLVM_CONFIGTIME=`date`
 525 AC_SUBST(LLVM_PREFIX)
 526 AC_SUBST(LLVM_BINDIR)
 527 AC_SUBST(LLVM_LIBDIR)
 528 AC_SUBST(LLVM_DATADIR)
 529 AC_SUBST(LLVM_DOCSDIR)
 530 AC_SUBST(LLVM_ETCDIR)
 531 AC_SUBST(LLVM_INCLUDEDIR)
 532 AC_SUBST(LLVM_INFODIR)
 533 AC_SUBST(LLVM_MANDIR)
 534 AC_SUBST(LLVM_CONFIGTIME)
 535
 536 # Place the various directores into the config.h file as #defines so that we
 537 # can know about the installation paths within LLVM.
 538 AC_DEFINE_UNQUOTED(LLVM_PREFIX,"$LLVM_PREFIX",
 539                    [Installation prefix directory])
 540 AC_DEFINE_UNQUOTED(LLVM_BINDIR, "$LLVM_BINDIR",
 541                    [Installation directory for binary executables])
 542 AC_DEFINE_UNQUOTED(LLVM_LIBDIR, "$LLVM_LIBDIR",
 543                    [Installation directory for libraries])
 544 AC_DEFINE_UNQUOTED(LLVM_DATADIR, "$LLVM_DATADIR",
 545                    [Installation directory for data files])
 546 AC_DEFINE_UNQUOTED(LLVM_DATADIR, "$LLVM_DOCSDIR",
 547                    [Installation directory for documentation])
 548 AC_DEFINE_UNQUOTED(LLVM_ETCDIR, "$LLVM_ETCDIR",
 549                    [Installation directory for config files])
 550 AC_DEFINE_UNQUOTED(LLVM_INCLUDEDIR, "$LLVM_INCLUDEDIR",
 551                    [Installation directory for include files])
 552 AC_DEFINE_UNQUOTED(LLVM_INFODIR, "$LLVM_INFODIR",
 553                    [Installation directory for .info files])
 554 AC_DEFINE_UNQUOTED(LLVM_MANDIR, "$LLVM_MANDIR",
 555                    [Installation directory for man pages])
 556 AC_DEFINE_UNQUOTED(LLVM_CONFIGTIME, "$LLVM_CONFIGTIME",
 557                    [Time at which LLVM was configured])
 558
 559 dnl===-----------------------------------------------------------------------===
 560 dnl===
 561 dnl=== SECTION 10: Specify the output files and generate it
 562 dnl===
 563 dnl===-----------------------------------------------------------------------===
 564
 565 dnl Configure header files
 566 AC_CONFIG_HEADERS(include/llvm/Config/config.h)
 567
 568 AC_CONFIG_HEADERS([include/llvm/Support/DataTypes.h])
 569 AC_CONFIG_HEADERS([include/llvm/ADT/hash_map])
 570 AC_CONFIG_HEADERS([include/llvm/ADT/hash_set])
 571 AC_CONFIG_HEADERS([include/llvm/Support/ThreadSupport.h])
 572 AC_CONFIG_HEADERS([include/llvm/ADT/iterator])
 573
 574 dnl Configure the makefile's configuration data
 575 AC_CONFIG_FILES([Makefile.config])
 576
 577 dnl Configure llvmc's configuration files
 578 AC_CONFIG_FILES([tools/llvmc/st tools/llvmc/cpp tools/llvmc/ll tools/llvmc/c])
 579
 580 dnl Configure doxygen's configuration file
 581 AC_CONFIG_FILES([docs/doxygen.cfg])
 582
 583 dnl Do special configuration of Makefiles
 584 AC_CONFIG_MAKEFILE(Makefile)
 585 AC_CONFIG_MAKEFILE(Makefile.common)
 586 AC_CONFIG_MAKEFILE(examples/Makefile)
 587 AC_CONFIG_MAKEFILE(lib/Makefile)
 588 AC_CONFIG_MAKEFILE(runtime/Makefile)
 589 AC_CONFIG_MAKEFILE(test/Makefile)
 590 AC_CONFIG_MAKEFILE(test/Makefile.tests)
 591 AC_CONFIG_MAKEFILE(tools/Makefile)
 592 AC_CONFIG_MAKEFILE(utils/Makefile)
 593 AC_CONFIG_MAKEFILE(projects/Makefile)
 594
 595 dnl Finally, crank out the output
 596 AC_OUTPUT
 597
 598 dnl Warn loudly if llvm-gcc was not obviously working
 599 if test "$llvm_cv_llvmgcc_sanity" = "no" ; then
 600  AC_MSG_WARN([***** llvm-gcc/llvm-g++ was not found, or does not appear to be ])
 601  AC_MSG_WARN([***** working. Please make sure you have llvmgcc and llvmg++ in])
 602  AC_MSG_WARN([***** your path before configuring LLVM. The runtime libraries])
 603  AC_MSG_WARN([***** (llvm/runtime) will not be built but you should be able to])
 604  AC_MSG_WARN([***** build the llvm tools.])
 605 fi